gdb/testsuite/lib/completion-support.exp

   1 # Copyright 2017-2019 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # This file is part of the gdb testsuite.
  17
  18 # Any variable or procedure in the namespace whose name starts with
  19 # "_" is private to the module.  Do not use these.
  20
  21 namespace eval completion {
  22     variable bell_re "\\\x07"
  23
  24     # List of all quote chars.
  25     variable all_quotes_list {"'" "\""}
  26
  27     # List of all quote chars, including no-quote at all.
  28     variable maybe_quoted_list {"" "'" "\""}
  29
  30     variable keyword_list {"if" "task" "thread"}
  31
  32     variable explicit_opts_list \
  33         {"-function" "-label" "-line" "-qualified" "-source"}
  34 }
  35
  36 # Make a regular expression that matches a TAB completion list.
  37
  38 proc make_tab_completion_list_re { completion_list } {
  39     # readline separates the completion columns that fit on the same
  40     # line with whitespace.  Since we're testing under "set width
  41     # unlimited", all completions will be printed on the same line.
  42     # The amount of whitespace depends on the length of the widest
  43     # completion.  We could compute that here and expect the exact
  44     # number of ws characters between each completion match, but to
  45     # keep it simple, we accept any number of characters.
  46     set ws " +"
  47
  48     set completion_list_re ""
  49     foreach c $completion_list {
  50         append completion_list_re [string_to_regexp $c]
  51         append completion_list_re $ws
  52     }
  53     append completion_list_re $ws
  54
  55     return $completion_list_re
  56 }
  57
  58 # Make a regular expression that matches a "complete" command
  59 # completion list.  CMD_PREFIX is the command prefix added to each
  60 # completion match.
  61
  62 proc make_cmd_completion_list_re { cmd_prefix completion_list start_quote_char end_quote_char } {
  63
  64     set completion_list_re ""
  65     foreach c $completion_list {
  66         # The command prefix is included in all completion matches.
  67         append completion_list_re [string_to_regexp $cmd_prefix$start_quote_char$c$end_quote_char]
  68         append completion_list_re "\r\n"
  69     }
  70
  71     return $completion_list_re
  72 }
  73
  74 # Clear the input line.
  75
  76 proc clear_input_line { test } {
  77     global gdb_prompt
  78
  79     send_gdb "\003"
  80     gdb_test_multiple "" "$test (clearing input line)" {
  81         -re "Quit\r\n$gdb_prompt $" {
  82         }
  83     }
  84 }
  85
  86 # Test that completing LINE with TAB completes to nothing.
  87
  88 proc test_gdb_complete_tab_none { line } {
  89     set line_re [string_to_regexp $line]
  90
  91     set test "tab complete \"$line\""
  92     send_gdb "$line\t"
  93     gdb_test_multiple "" "$test" {
  94         -re "^$line_re$completion::bell_re$" {
  95             pass "$test"
  96         }
  97     }
  98
  99     clear_input_line $test
 100 }
 101
 102 # Test that completing INPUT_LINE with TAB completes to
 103 # COMPLETE_LINE_RE.  APPEND_CHAR_RE is the character expected to be
 104 # appended after EXPECTED_OUTPUT.  Normally that's a whitespace, but
 105 # in some cases it's some other character, like a colon.
 106
 107 proc test_gdb_complete_tab_unique { input_line complete_line_re append_char_re } {
 108
 109     set test "tab complete \"$input_line\""
 110     send_gdb "$input_line\t"
 111     gdb_test_multiple "" "$test" {
 112         -re "^$complete_line_re$append_char_re$" {
 113             pass "$test"
 114         }
 115     }
 116
 117     clear_input_line $test
 118 }
 119
 120 # Test that completing INPUT_LINE with TAB completes to "INPUT_LINE +
 121 # ADD_COMPLETED_LINE" and that it displays the completion matches in
 122 # COMPLETION_LIST.  If MAX_COMPLETIONS then we expect the completion
 123 # to hit the max-completions limit.
 124
 125 proc test_gdb_complete_tab_multiple { input_line add_completed_line \
 126                                           completion_list {max_completions 0}} {
 127     global gdb_prompt
 128
 129     set input_line_re [string_to_regexp $input_line]
 130     set add_completed_line_re [string_to_regexp $add_completed_line]
 131
 132     set expected_re [make_tab_completion_list_re $completion_list]
 133
 134     if {$max_completions} {
 135         append expected_re "\r\n"
 136         append expected_re \
 137             "\\*\\*\\* List may be truncated, max-completions reached\\. \\*\\*\\*"
 138     }
 139
 140     set test "tab complete \"$input_line\""
 141     send_gdb "$input_line\t"
 142     gdb_test_multiple "" "$test (first tab)" {
 143         -re "^${input_line_re}${completion::bell_re}$add_completed_line_re$" {
 144             send_gdb "\t"
 145             # If we auto-completed to an ambiguous prefix, we need an
 146             # extra tab to show the matches list.
 147             if {$add_completed_line != ""} {
 148                 send_gdb "\t"
 149                 set maybe_bell ${completion::bell_re}
 150             } else {
 151                 set maybe_bell ""
 152             }
 153             gdb_test_multiple "" "$test (second tab)" {
 154                 -re "^${maybe_bell}\r\n$expected_re\r\n$gdb_prompt " {
 155                     gdb_test_multiple "" "$test (second tab)" {
 156                         -re "^$input_line_re$add_completed_line_re$" {
 157                             pass "$test"
 158                         }
 159                     }
 160                 }
 161             }
 162         }
 163     }
 164
 165     clear_input_line $test
 166 }
 167
 168 # Test that completing LINE with the complete command completes to
 169 # nothing.
 170
 171 proc test_gdb_complete_cmd_none { line } {
 172     gdb_test_no_output "complete $line" "cmd complete \"$line\""
 173 }
 174
 175 # Test that completing LINE with the complete command completes to
 176 # COMPLETE_LINE_RE.
 177
 178 proc test_gdb_complete_cmd_unique { input_line complete_line_re } {
 179     global gdb_prompt
 180
 181     set cmd "complete $input_line"
 182     set cmd_re [string_to_regexp $cmd]
 183     set test "cmd complete \"$input_line\""
 184     gdb_test_multiple $cmd $test {
 185         -re "^$cmd_re\r\n$complete_line_re\r\n$gdb_prompt $" {
 186             pass $test
 187         }
 188     }
 189 }
 190
 191 # Test that completing "CMD_PREFIX + COMPLETION_WORD" with the
 192 # complete command displays the COMPLETION_LIST completion list.  Each
 193 # entry in the list should be prefixed by CMD_PREFIX.  If
 194 # MAX_COMPLETIONS then we expect the completion to hit the
 195 # max-completions limit.
 196
 197 proc test_gdb_complete_cmd_multiple { cmd_prefix completion_word completion_list {start_quote_char ""} {end_quote_char ""} {max_completions 0}} {
 198     global gdb_prompt
 199
 200     set expected_re [make_cmd_completion_list_re $cmd_prefix $completion_list $start_quote_char $end_quote_char]
 201
 202     if {$max_completions} {
 203         set cmd_prefix_re [string_to_regexp $cmd_prefix]
 204         append expected_re \
 205             "$cmd_prefix_re \\*\\*\\* List may be truncated, max-completions reached\\. \\*\\*\\*.*\r\n"
 206     }
 207
 208     set cmd_re [string_to_regexp "complete $cmd_prefix$completion_word"]
 209     set test "cmd complete \"$cmd_prefix$completion_word\""
 210     gdb_test_multiple "complete $cmd_prefix$completion_word" $test {
 211         -re "^$cmd_re\r\n$expected_re$gdb_prompt $" {
 212             pass $test
 213         }
 214     }
 215 }
 216
 217 # Test that completing LINE completes to nothing.
 218
 219 proc test_gdb_complete_none { input_line } {
 220     test_gdb_complete_tab_none $input_line
 221     test_gdb_complete_cmd_none $input_line
 222 }
 223
 224 # Test that completing INPUT_LINE completes to COMPLETE_LINE_RE.
 225 #
 226 # APPEND_CHAR is the character expected to be appended after
 227 # EXPECTED_OUTPUT when TAB completing.  Normally that's a whitespace,
 228 # but in some cases it's some other character, like a colon.
 229 #
 230 # If MAX_COMPLETIONS is true, then we expect the completion to hit the
 231 # max-completions limit.  Since we're expecting a unique completion
 232 # match, this will only be visible in the "complete" command output.
 233 # Tab completion will just auto-complete the only match and won't
 234 # display a match list.
 235 #
 236 # Note: usually it's more convenient to pass a literal string instead
 237 # of a regular expression (as COMPLETE_LINE_RE).  See
 238 # test_gdb_complete_unique below.
 239
 240 proc test_gdb_complete_unique_re { input_line complete_line_re {append_char " "} {max_completions 0}} {
 241     set append_char_re [string_to_regexp $append_char]
 242     test_gdb_complete_tab_unique $input_line $complete_line_re $append_char_re
 243
 244     # Trim INPUT_LINE and COMPLETE LINE, for the case we're completing
 245     # a command with leading whitespace.  Leading command whitespace
 246     # is discarded by GDB.
 247     set input_line [string trimleft $input_line]
 248     set expected_output_re [string trimleft $complete_line_re]
 249     if {$append_char_re != " "} {
 250         append expected_output_re $append_char_re
 251     }
 252     if {$max_completions} {
 253         set max_completion_reached_msg \
 254             "*** List may be truncated, max-completions reached. ***"
 255         set input_line_re \
 256             [string_to_regexp $input_line]
 257         set max_completion_reached_msg_re \
 258             [string_to_regexp $max_completion_reached_msg]
 259
 260         append expected_output_re \
 261             "\r\n$input_line_re $max_completion_reached_msg_re"
 262     }
 263
 264     test_gdb_complete_cmd_unique $input_line $expected_output_re
 265 }
 266
 267 # Like TEST_GDB_COMPLETE_UNIQUE_RE, but COMPLETE_LINE is a string, not
 268 # a regular expression.
 269
 270 proc test_gdb_complete_unique { input_line complete_line {append_char " "} {max_completions 0}} {
 271     set complete_line_re [string_to_regexp $complete_line]
 272     test_gdb_complete_unique_re $input_line $complete_line_re $append_char $max_completions
 273 }
 274
 275 # Test that completing "CMD_PREFIX + COMPLETION_WORD" adds
 276 # ADD_COMPLETED_LINE to the input line, and that it displays
 277 # COMPLETION_LIST as completion match list.  COMPLETION_WORD is the
 278 # completion word.  If MAX_COMPLETIONS then we expect the completion
 279 # to hit the max-completions limit.
 280
 281 proc test_gdb_complete_multiple {
 282   cmd_prefix completion_word add_completed_line completion_list
 283   {start_quote_char ""} {end_quote_char ""} {max_completions 0}
 284 } {
 285     test_gdb_complete_tab_multiple "$cmd_prefix$completion_word" $add_completed_line $completion_list $max_completions
 286     test_gdb_complete_cmd_multiple $cmd_prefix $completion_word $completion_list $start_quote_char $end_quote_char $max_completions
 287 }
 288
 289 # Test that all the substring prefixes of INPUT from [0..START) to
 290 # [0..END) complete to COMPLETION_RE (a regular expression).  If END
 291 # is ommitted, default to the length of INPUT.
 292
 293 proc test_complete_prefix_range_re {input completion_re start {end -1}} {
 294     if {$end == -1} {
 295         set end [string length $input]
 296     }
 297
 298     for {set i $start} {$i < $end} {incr i} {
 299         set line [string range $input 0 $i]
 300         test_gdb_complete_unique_re "$line" $completion_re
 301     }
 302 }
 303
 304 # Test that all the substring prefixes of COMPLETION from [0..START)
 305 # to [0..END) complete to COMPLETION.  If END is ommitted, default to
 306 # the length of COMPLETION.
 307
 308 proc test_complete_prefix_range {completion start {end -1}} {
 309     set completion_re [string_to_regexp $completion]
 310     test_complete_prefix_range_re $completion $completion_re $start $end
 311 }
 312
 313 # Find NEEDLE in HAYSTACK and return the index _after_ NEEDLE.  E.g.,
 314 # searching for "(" in "foo(int)" returns 4, which would be useful if
 315 # you want to find the "(" to try completing "foo(".
 316
 317 proc index_after {needle haystack} {
 318     set start [string first $needle $haystack]
 319     if {$start == -1} {
 320         error "could not find \"$needle\" in \"$haystack\""
 321     }
 322     return [expr $start + [string length $needle]]
 323 }
 324
 325 # Create a breakpoint using BREAK_COMMAND, and return the number
 326 # of locations found.
 327
 328 proc completion::_create_bp {break_command} {
 329     global gdb_prompt
 330     global decimal hex
 331
 332     set found_locations -1
 333
 334     set test "set breakpoint"
 335     gdb_test_multiple "$break_command" $test {
 336         -re "\\\(\($decimal\) locations\\\)\r\n$gdb_prompt $" {
 337             set found_locations "$expect_out(1,string)"
 338         }
 339         -re "Breakpoint $decimal at $hex: file .*, line .*$gdb_prompt $" {
 340             set found_locations 1
 341         }
 342         -re "Make breakpoint pending on future shared library load.*y or .n.. $" {
 343             send_gdb "n\n"
 344             gdb_test_multiple "" "$test (prompt)" {
 345                 -re "$gdb_prompt $" {
 346                 }
 347             }
 348             set found_locations 0
 349         }
 350         -re "invalid explicit location argument, \[^\r\n\]*\r\n$gdb_prompt $" {
 351             set found_locations 0
 352         }
 353         -re "Function \[^\r\n\]* not defined in \[^\r\n\]*\r\n$gdb_prompt $" {
 354             set found_locations 0
 355         }
 356     }
 357     return $found_locations
 358 }
 359
 360 # Return true if lists A and B have the same elements.  Order of
 361 # elements does not matter.
 362
 363 proc completion::_leq {a b} {
 364     return [expr {[lsort $a] eq [lsort $b]}]
 365 }
 366
 367 # Check that trying to create a breakpoint using BREAK_COMMAND fails.
 368
 369 proc check_setting_bp_fails {break_command} {
 370     with_test_prefix "\"$break_command\" creates no bp locations" {
 371         set found_locations [completion::_create_bp $break_command]
 372         gdb_assert {$found_locations == 0} "matches"
 373         if {$found_locations != 0} {
 374             delete_breakpoints
 375         }
 376     }
 377 }
 378
 379 # Check that creating the breakpoint using BREAK_COMMAND finds the
 380 # same breakpoint locations as completing BREAK_COMMAND.
 381 # COMPLETION_LIST is the expected completion match list.
 382
 383 proc check_bp_locations_match_list {break_command completion_list} {
 384     global gdb_prompt
 385     global hex
 386
 387     with_test_prefix "compare \"$break_command\" completion list with bp location list" {
 388         set num_locations [completion::_create_bp $break_command]
 389
 390         set found_list ""
 391
 392         set any "\[^\r\n\]*"
 393
 394         gdb_test_multiple "info breakpoint \$bpnum" "info breakpoint" {
 395             -re "in \(\[^\r\n\]*\) at " {
 396                 # A function location.
 397                 set found_location "$expect_out(1,string)"
 398                 lappend found_list $found_location
 399                 exp_continue
 400             }
 401             -re "breakpoint${any}keep${any}y${any}$hex\[ \t]*\(${any}\)\r\n" {
 402                 # A label location.
 403                 set found_location "$expect_out(1,string)"
 404                 lappend found_list $found_location
 405                 exp_continue
 406             }
 407             -re "$gdb_prompt $" {
 408             }
 409         }
 410
 411         gdb_assert {[completion::_leq $found_list $completion_list]} "matches"
 412
 413         delete_breakpoints
 414     }
 415 }
 416
 417 # Build linespec and explicit locations out of all the combinations of
 418 # SOURCES, FUNCTIONS and LABELS, with all combinations of possible
 419 # quoting and whitespace around separators, and run BODY_LINESPEC and
 420 # BODY_EXPLICIT in the context of the caller for each combination.  A
 421 # variable named "location" is set in the callers context with the
 422 # currently iterated location.
 423
 424 proc foreach_location_functions { sources functions body_linespec body_explicit } {
 425     upvar source source
 426     upvar function function
 427     upvar source_sep source_sep
 428     upvar location location
 429
 430     foreach source $sources {
 431         # Test with and without source quoting.
 432         foreach sqc $completion::maybe_quoted_list {
 433             if {$source == "" && $sqc != ""} {
 434                 # Invalid combination.
 435                 continue
 436             }
 437
 438             # Test with and without function quoting.
 439             foreach fqc $completion::maybe_quoted_list {
 440                 # Test known and unknown functions.
 441                 foreach function $functions {
 442                     # Linespec version.  Test with and without spacing
 443                     # after the source/colon colon separator.
 444                     foreach source_sep {"" ":" ": "} {
 445                         # Skip invalid combinations.
 446                         if {$source == "" && $source_sep != ""} {
 447                             continue
 448                         }
 449                         if {$source != "" && $source_sep == ""} {
 450                             continue
 451                         }
 452
 453                         set location "${sqc}${source}${sqc}${source_sep}${fqc}$function${fqc}"
 454                         uplevel 1 $body_linespec
 455                     }
 456
 457                     # Explicit locations version.
 458                     if {$source != ""} {
 459                         set loc_src "-source ${sqc}${source}${sqc} "
 460                     } else {
 461                         set loc_src ""
 462                     }
 463
 464                     set location "${loc_src}-function ${fqc}$function${fqc}"
 465                     uplevel 1 $body_explicit
 466                 }
 467             }
 468         }
 469     }
 470 }
 471
 472 # Same as foreach_locations_functions, but also iterate over
 473 # combinations of labels.
 474 proc foreach_location_labels { sources functions labels body_linespec body_explicit } {
 475     upvar source source
 476     upvar function function
 477     upvar label label
 478     upvar source_sep source_sep
 479     upvar label_sep label_sep
 480     upvar location location
 481
 482     # Test both with a known source file and without a source file
 483     # component.
 484     foreach_location_functions \
 485         $sources \
 486         $functions \
 487         {
 488             # Linespec version.  Test various spacing around the label
 489             # colon separator.
 490             set saved_location ${location}
 491             foreach label_sep {":" " :" ": " " : "} {
 492                 # Test both known and unknown label.
 493                 foreach label $labels {
 494                     set location "${saved_location}${label_sep}$label"
 495                     uplevel 1 $body_linespec
 496                 }
 497             }
 498         } \
 499         {
 500             # Explicit locations version.
 501             set saved_location ${location}
 502             foreach label $labels {
 503                 set location "${saved_location} -label $label"
 504                 uplevel 1 $body_explicit
 505             }
 506         }
 507 }
 508
 509 # Check that completion of INPUT_LINE results in GDB completing on all
 510 # command names.
 511 proc test_gdb_completion_offers_commands {input_line} {
 512     global gdb_prompt
 513
 514     # There are two many commands to usefully check here.  So we force
 515     # max-completions to 2, and check if those 2 come out.
 516
 517     # Save current max-completions.
 518     set max_completions 0
 519     set test "show max-completions"
 520     gdb_test_multiple $test $test {
 521         -re "Maximum number of completion candidates is (.*)\\.\r\n$gdb_prompt $" {
 522             set max_completions $expect_out(1,string)
 523         }
 524     }
 525
 526     # Force showing two commands.
 527     gdb_test_no_output "set max-completions 2" ""
 528
 529     test_gdb_complete_multiple $input_line "" "" {
 530         "!"
 531         "+"
 532     } "" "" 1
 533
 534     # Restore.
 535     gdb_test_no_output "set max-completions $max_completions" ""
 536 }