gdb/testsuite/lib/gdbserver-support.exp

   1 # Copyright 2000, 2002, 2003, 2004, 2005, 2006, 2007, 2008
   2 # Free Software Foundation, Inc.
   3
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 # This file is based on config/gdbserver.exp, which was written by
  18 # Michael Snyder (msnyder@redhat.com).
  19
  20 #
  21 # To be addressed or set in your baseboard config file:
  22 #
  23 #   set_board_info gdb_protocol "remote"
  24 #       Unles you have a gdbserver that uses a different protocol...
  25 #
  26 #   set_board_info gdb_server_prog
  27 #       This will be the path to the gdbserver program you want to test.
  28 #       Defaults to "gdbserver".
  29 #
  30 #   set_board_info sockethost
  31 #       The name of the host computer whose socket is being used.
  32 #       Defaults to "localhost".  Note: old gdbserver requires
  33 #       that you define this, but libremote/gdbserver does not.
  34 #
  35 #   set_board_info gdb,socketport
  36 #       Port id to use for socket connection.  If not set explicitly,
  37 #       it will start at "2345" and increment for each use.
  38 #
  39
  40 #
  41 # gdb_target_cmd
  42 # Send gdb the "target" command
  43 #
  44 proc gdb_target_cmd { targetname serialport } {
  45     global gdb_prompt
  46
  47     set serialport_re [string_to_regexp $serialport]
  48     for {set i 1} {$i <= 3} {incr i} {
  49         send_gdb "target $targetname $serialport\n"
  50         gdb_expect 60 {
  51             -re "A program is being debugged already.*ill it.*y or n. $" {
  52                 send_gdb "y\n"
  53                 exp_continue
  54             }
  55             -re "unknown host.*$gdb_prompt" {
  56                 verbose "Couldn't look up $serialport"
  57             }
  58             -re "Couldn't establish connection to remote.*$gdb_prompt $" {
  59                 verbose "Connection failed"
  60             }
  61             -re "Remote MIPS debugging.*$gdb_prompt" {
  62                 verbose "Set target to $targetname"
  63                 return 0
  64             }
  65             -re "Remote debugging using .*$serialport_re.*$gdb_prompt $" {
  66                 verbose "Set target to $targetname"
  67                 return 0
  68             }
  69             -re "Remote target $targetname connected to.*$gdb_prompt $" {
  70                 verbose "Set target to $targetname"
  71                 return 0
  72             }
  73             -re "Connected to.*$gdb_prompt $" {
  74                 verbose "Set target to $targetname"
  75                 return 0
  76             }
  77             -re "Ending remote.*$gdb_prompt $" { }
  78             -re "Connection refused.*$gdb_prompt $" {
  79                 verbose "Connection refused by remote target.  Pausing, and trying again."
  80                 sleep 30
  81                 continue
  82             }
  83             -re "Timeout reading from remote system.*$gdb_prompt $" {
  84                 verbose "Got timeout error from gdb."
  85             }
  86             -notransfer -re "Remote debugging using .*\r\n> $" {
  87                 # We got an unexpected prompt while creating the target.
  88                 # Leave it there for the test to diagnose.
  89                 return 1
  90             }
  91             timeout {
  92                 send_gdb "\ 3"
  93                 break
  94             }
  95         }
  96     }
  97     return 1
  98 }
  99
 100
 101 global portnum
 102 set portnum "2345"
 103
 104 # Locate the gdbserver binary.  Returns "" if gdbserver could not be found.
 105
 106 proc find_gdbserver { } {
 107   global GDB
 108   global GDBSERVER
 109
 110   if [info exists GDBSERVER] {
 111     return ${GDBSERVER}
 112   }
 113
 114   if [target_info exists gdb_server_prog] {
 115     return [target_info gdb_server_prog]
 116   }
 117
 118   set gdbserver "${GDB}server"
 119   if { [file isdirectory $gdbserver] } {
 120     append gdbserver "/gdbserver"
 121   }
 122
 123   if { [file executable $gdbserver] } {
 124     return $gdbserver
 125   }
 126
 127   return ""
 128 }
 129
 130 # Return non-zero if we should skip gdbserver-specific tests.
 131
 132 proc skip_gdbserver_tests { } {
 133   if { [find_gdbserver] == "" } {
 134     return 1
 135   }
 136
 137   return 0
 138 }
 139
 140 # Download the currently loaded program to the target if necessary.
 141 # Return the target system filename.
 142
 143 proc gdbserver_download { } {
 144     global gdbserver_host_exec
 145     global gdbserver_host_mtime
 146     global gdbserver_server_exec
 147     global last_loaded_file
 148
 149     set host_exec $last_loaded_file
 150
 151     # If we already downloaded a file to the target, see if we can reuse it.
 152     set reuse 0
 153     if { [info exists gdbserver_server_exec] } {
 154         set reuse 1
 155
 156         # If the file has changed, we can not.
 157         if { $host_exec != $gdbserver_host_exec } {
 158             set reuse 0
 159         }
 160
 161         # If the mtime has changed, we can not.
 162         if { [file mtime $host_exec] != $gdbserver_host_mtime } {
 163             set reuse 0
 164         }
 165     }
 166
 167     if { $reuse == 0 } {
 168         set gdbserver_host_exec $host_exec
 169         set gdbserver_host_mtime [file mtime $host_exec]
 170         if [is_remote target] {
 171             set gdbserver_server_exec [gdb_download $host_exec]
 172         } else {
 173             set gdbserver_server_exec $host_exec
 174         }
 175     }
 176
 177     return $gdbserver_server_exec
 178 }
 179
 180 # Start a gdbserver process with initial OPTIONS and trailing ARGUMENTS.
 181 # The port will be filled in between them automatically.
 182 #
 183 # Returns the target protocol and socket to connect to.
 184
 185 proc gdbserver_start { options arguments } {
 186     global portnum
 187
 188     # Port id -- either specified in baseboard file, or managed here.
 189     if [target_info exists gdb,socketport] {
 190         set portnum [target_info gdb,socketport]
 191     } else {
 192         # Bump the port number to avoid conflicts with hung ports.
 193         incr portnum
 194     }
 195
 196     # Extract the local and remote host ids from the target board struct.
 197     if [target_info exists sockethost] {
 198         set debughost [target_info sockethost]
 199     } else {
 200         set debughost "localhost:"
 201     }
 202
 203     # Extract the protocol
 204     if [target_info exists gdb_protocol] {
 205         set protocol [target_info gdb_protocol]
 206     } else {
 207         set protocol "remote"
 208     }
 209
 210     set gdbserver [find_gdbserver]
 211
 212     # Export the host:port pair.
 213     set gdbport $debughost$portnum
 214
 215     # Fire off the debug agent.
 216     set gdbserver_command "$gdbserver"
 217     if { $options != "" } {
 218         append gdbserver_command " $options"
 219     }
 220     append gdbserver_command " :$portnum"
 221     if { $arguments != "" } {
 222         append gdbserver_command " $arguments"
 223     }
 224
 225     set server_spawn_id [remote_spawn target $gdbserver_command]
 226
 227     # Wait for the server to open its TCP socket, so that GDB can connect.
 228     expect {
 229         -i $server_spawn_id
 230         -notransfer
 231         -re "Listening on" { }
 232     }
 233
 234     # We can't just call close, because if gdbserver is local then that means
 235     # that it will get a SIGHUP.  Doing it this way could also allow us to
 236     # get at the inferior's input or output if necessary, and means that we
 237     # don't need to redirect output.
 238     expect_background {
 239         -i $server_spawn_id
 240         full_buffer { }
 241         eof {
 242             # The spawn ID is already closed now (but not yet waited for).
 243             wait -i $expect_out(spawn_id)
 244         }
 245     }
 246
 247     return [list $protocol $gdbport]
 248 }
 249
 250 # Start a gdbserver process running SERVER_EXEC, and connect GDB
 251 # to it.  CHILD_ARGS are passed to the inferior.
 252 #
 253 # Returns the target protocol and socket to connect to.
 254
 255 proc gdbserver_spawn { child_args } {
 256     set target_exec [gdbserver_download]
 257
 258     # Fire off the debug agent.  This flavour of gdbserver takes as
 259     # arguments the port information, the name of the executable file to
 260     # be debugged, and any arguments.
 261     set arguments "$target_exec"
 262     if { $child_args != "" } {
 263         append arguments " $child_args"
 264     }
 265     return [gdbserver_start "" $arguments]
 266 }
 267
 268 # Start a gdbserver process running HOST_EXEC and pass CHILD_ARGS
 269 # to it.  Return 0 on success, or non-zero on failure.
 270
 271 proc gdbserver_run { child_args } {
 272     global gdbserver_protocol
 273     global gdbserver_gdbport
 274
 275     # Kill anything running before we try to start gdbserver, in case
 276     # we are sharing a serial connection.
 277     global gdb_prompt
 278     send_gdb "kill\n"
 279     gdb_expect 120 {
 280         -re "Kill the program being debugged. .y or n. $" {
 281             send_gdb "y\n"
 282             verbose "\t\tKilling previous program being debugged"
 283             exp_continue
 284         }
 285         -re "$gdb_prompt $" {
 286             # OK.
 287         }
 288     }
 289
 290     set res [gdbserver_spawn $child_args]
 291     set gdbserver_protocol [lindex $res 0]
 292     set gdbserver_gdbport [lindex $res 1]
 293
 294     return [gdb_target_cmd $gdbserver_protocol $gdbserver_gdbport]
 295 }
 296
 297 # Reconnect to the previous gdbserver session.
 298
 299 proc gdbserver_reconnect { } {
 300     global gdbserver_protocol
 301     global gdbserver_gdbport
 302
 303     return [gdb_target_cmd $gdbserver_protocol $gdbserver_gdbport]
 304 }
 305
 306 # Start and connect to a gdbserver in extended mode.
 307 proc gdbserver_start_extended { } {
 308     set res [gdbserver_start "--multi" ""]
 309     set gdbserver_protocol "extended-[lindex $res 0]"
 310     set gdbserver_gdbport [lindex $res 1]
 311
 312     return [gdb_target_cmd $gdbserver_protocol $gdbserver_gdbport]
 313 }