gdb/testsuite/lib/range-stepping-support.exp

   1 # Copyright 2013-2015 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # Execute command CMD and check that GDB sends the expected number of
  17 # vCont;s and vCont;r packets.  Returns 0 if the test passes,
  18 # otherwise returns 1.
  19
  20 proc exec_cmd_expect_vCont_count { cmd exp_vCont_s exp_vCont_r } {
  21     global gdb_prompt
  22
  23     gdb_test_no_output "set debug remote 1" ""
  24
  25     set test "${cmd}: vCont;s=${exp_vCont_s} vCont;r=${exp_vCont_r}"
  26     set r_counter 0
  27     set s_counter 0
  28     set ret 1
  29     gdb_test_multiple $cmd $test {
  30         -re "vCont;s\[^\r\n\]*Packet received: T\[\[:xdigit:\]\]\[\[:xdigit:\]\]" {
  31             incr s_counter
  32             exp_continue
  33         }
  34         -re "vCont;r\[^\r\n\]*Packet received: T\[\[:xdigit:\]\]\[\[:xdigit:\]\]" {
  35             incr r_counter
  36             exp_continue
  37         }
  38         -re "\r\n" {
  39             # Prevent overflowing the expect buffer.
  40             exp_continue
  41         }
  42         -re "$gdb_prompt $" {
  43             if { $r_counter == ${exp_vCont_r} && $s_counter == ${exp_vCont_s} } {
  44                 pass $test
  45                 set ret 0
  46             } else {
  47                 fail $test
  48             }
  49         }
  50     }
  51
  52     gdb_test_no_output "set debug remote 0" ""
  53     return $ret
  54 }
  55
  56 # Check whether range stepping is supported by the target.
  57
  58 proc gdb_range_stepping_enabled { } {
  59     global gdb_prompt
  60
  61     set command "set range-stepping on"
  62     set message "probe range-stepping support"
  63     gdb_test_multiple $command $message {
  64         -re "Range stepping is not supported.*\r\n$gdb_prompt $" {
  65             pass $message
  66             return 0
  67         }
  68         -re "^$command\r\n$gdb_prompt $" {
  69             pass $message
  70             return 1
  71         }
  72     }
  73
  74     return 0
  75 }