gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2020 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT
  22 AC_CONFIG_SRCDIR([server.cc])
  23 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  24
  25 AM_MAINTAINER_MODE
  26
  27 AC_PROG_CC
  28 AC_PROG_CXX
  29 AC_USE_SYSTEM_EXTENSIONS
  30 AC_SYS_LARGEFILE
  31 AM_PROG_INSTALL_STRIP
  32
  33 # Set build, build_cpu, build_vendor and build_os.
  34 AC_CANONICAL_BUILD
  35
  36 # Set host, host_cpu, host_vendor, and host_os.
  37 AC_CANONICAL_HOST
  38
  39 # Set target, target_cpu, target_vendor, and target_os.
  40 AC_CANONICAL_TARGET
  41
  42 AC_PROG_INSTALL
  43 AC_CHECK_TOOL(AR, ar)
  44 AC_PROG_RANLIB
  45
  46 AC_ARG_PROGRAM
  47
  48 # We require a C++11 compiler.  Check if one is available, and if
  49 # necessary, set CXX_DIALECT to some -std=xxx switch.
  50 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  51
  52 AC_HEADER_STDC
  53
  54 GDB_AC_COMMON
  55 # This is set by GDB_AC_COMMON.
  56 AC_SUBST(WIN32APILIBS)
  57
  58 GDB_AC_SELFTEST
  59
  60 ACX_NONCANONICAL_TARGET
  61 ACX_NONCANONICAL_HOST
  62
  63 # Dependency checking.
  64 ZW_CREATE_DEPDIR
  65
  66 dnl Set up for gettext.
  67 ZW_GNU_GETTEXT_SISTER_DIR
  68
  69 # Create sub-directories for objects and dependencies.
  70 CONFIG_SRC_SUBDIR="arch gdbsupport nat target"
  71 AC_SUBST(CONFIG_SRC_SUBDIR)
  72
  73 AC_CONFIG_COMMANDS([gdbdepdir],[
  74   for subdir in ${CONFIG_SRC_SUBDIR}
  75   do
  76       $SHELL $ac_aux_dir/mkinstalldirs $subdir/$DEPDIR
  77   done],
  78   [ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR CONFIG_SRC_SUBDIR="$CONFIG_SRC_SUBDIR"])
  79
  80 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  81
  82 AC_CHECK_HEADERS(termios.h sys/reg.h string.h dnl
  83                  sys/procfs.h linux/elf.h dnl
  84                  fcntl.h signal.h sys/file.h dnl
  85                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
  86                  netinet/tcp.h arpa/inet.h ws2tcpip.h)
  87 AC_FUNC_FORK
  88 AC_CHECK_FUNCS(pread pwrite pread64)
  89
  90 # Check the return and argument types of ptrace.
  91 GDB_AC_PTRACE
  92
  93 # Check for UST
  94 ustlibs=""
  95 ustinc=""
  96
  97 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
  98                           Equivalent to --with-ust-include=PATH/include
  99                           plus --with-ust-lib=PATH/lib])
 100 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
 101 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
 102
 103 case $with_ust in
 104   no)
 105     ustlibs=
 106     ustinc=
 107     ;;
 108   "" | yes)
 109     ustlibs=" -lust "
 110     ustinc=""
 111     ;;
 112   *)
 113     ustlibs="-L$with_ust/lib -lust"
 114     ustinc="-I$with_ust/include "
 115     ;;
 116 esac
 117 if test "x$with_ust_include" != x; then
 118   ustinc="-I$with_ust_include "
 119 fi
 120 if test "x$with_ust_lib" != x; then
 121   ustlibs="-L$with_ust_lib -lust"
 122 fi
 123
 124 if test "x$with_ust" != "xno"; then
 125   saved_CFLAGS="$CFLAGS"
 126   CFLAGS="$CFLAGS $ustinc"
 127   AC_MSG_CHECKING([for ust])
 128   AC_COMPILE_IFELSE(
 129     [AC_LANG_PROGRAM(
 130        [
 131 #define CONFIG_UST_GDB_INTEGRATION
 132 #include <ust/ust.h>
 133        ],
 134        []
 135      )],
 136     [AC_MSG_RESULT([yes]);
 137      AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 138     [AC_MSG_RESULT([no])
 139      ustlibs= ; ustinc= ]
 140   )
 141   CFLAGS="$saved_CFLAGS"
 142 fi
 143
 144 # Flags needed for UST
 145 AC_SUBST(ustlibs)
 146 AC_SUBST(ustinc)
 147
 148 AM_GDB_WARNINGS
 149
 150 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 151 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 152 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 153 dnl augment LIBS.
 154 old_LIBS="$LIBS"
 155 LIBS="$LIBS -ldl"
 156 AC_CHECK_FUNCS(dladdr)
 157 LIBS="$old_LIBS"
 158
 159 libiberty_INIT
 160
 161 AC_CHECK_DECLS([perror, vasprintf, vsnprintf])
 162
 163 AC_CHECK_TYPES(socklen_t, [], [],
 164 [#include <sys/types.h>
 165 #if HAVE_SYS_SOCKET_H
 166 # include <sys/socket.h>
 167 #elif HAVE_WS2TCPIP_H
 168 # include <ws2tcpip.h>
 169 #endif
 170 ])
 171
 172 case "${target}" in
 173   *-android*)
 174     # Starting with NDK version 9, <elf.h> actually includes definitions
 175     # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes
 176     # <sys/exec_elf.h> which defines some of the ELF types incorrectly,
 177     # leading to conflicts with the defintions from <linux/elf.h>.
 178     # This makes it impossible for us to include both <elf.h> and
 179     # <linux/elf.h>, which means that, in practice, we do not have
 180     # access to Elf32_auxv_t and Elf64_auxv_t on this platform.
 181     # Therefore, do not try to auto-detect availability, as it would
 182     # get it wrong on this platform.
 183     ;;
 184   *)
 185     AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 186     #include <elf.h>
 187     )
 188 esac
 189
 190 ACX_PKGVERSION([GDB])
 191 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 192 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 193 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 194
 195 # Check for various supplementary target information (beyond the
 196 # triplet) which might affect the choices in configure.srv.
 197 case "${target}" in
 198 changequote(,)dnl
 199   i[34567]86-*-linux*)
 200 changequote([,])dnl
 201     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 202                    [save_CPPFLAGS="$CPPFLAGS"
 203                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 204                     AC_EGREP_CPP([got it], [
 205 #if __x86_64__
 206 got it
 207 #endif
 208                  ], [gdb_cv_i386_is_x86_64=yes],
 209                     [gdb_cv_i386_is_x86_64=no])
 210                     CPPFLAGS="$save_CPPFLAGS"])
 211     ;;
 212
 213   x86_64-*-linux*)
 214     AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32],
 215                    [save_CPPFLAGS="$CPPFLAGS"
 216                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 217                     AC_EGREP_CPP([got it], [
 218 #if __x86_64__ && __ILP32__
 219 got it
 220 #endif
 221                  ], [gdb_cv_x86_is_x32=yes],
 222                     [gdb_cv_x86_is_x32=no])
 223                     CPPFLAGS="$save_CPPFLAGS"])
 224     ;;
 225
 226   m68k-*-*)
 227     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 228                    [save_CPPFLAGS="$CPPFLAGS"
 229                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 230                     AC_EGREP_CPP([got it], [
 231 #ifdef __mcoldfire__
 232 got it
 233 #endif
 234                  ], [gdb_cv_m68k_is_coldfire=yes],
 235                     [gdb_cv_m68k_is_coldfire=no])
 236                     CPPFLAGS="$save_CPPFLAGS"])
 237     ;;
 238 esac
 239
 240 . ${srcdir}/configure.srv
 241
 242 if test "${srv_mingwce}" = "yes"; then
 243   LIBS="$LIBS -lws2"
 244 elif test "${srv_mingw}" = "yes"; then
 245   # WIN32APILIBS is set by GDB_AC_COMMON.
 246   LIBS="$LIBS $WIN32APILIBS"
 247 fi
 248
 249 if test "${srv_linux_usrregs}" = "yes"; then
 250   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 251             [Define if the target supports PTRACE_PEEKUSR for register ]
 252             [access.])
 253 fi
 254
 255 if test "${srv_linux_regsets}" = "yes"; then
 256   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 257             [Define if the target supports register sets.])
 258
 259   AC_MSG_CHECKING(for PTRACE_GETREGS)
 260   AC_CACHE_VAL(
 261     [gdbsrv_cv_have_ptrace_getregs],
 262     [AC_COMPILE_IFELSE(
 263        [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETREGS;])],
 264        [gdbsrv_cv_have_ptrace_getregs=yes],
 265        [gdbsrv_cv_have_ptrace_getregs=no]
 266      )]
 267   )
 268   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 269   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 270     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 271               [Define if the target supports PTRACE_GETREGS for register ]
 272               [access.])
 273   fi
 274
 275   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 276   AC_CACHE_VAL(
 277     [gdbsrv_cv_have_ptrace_getfpxregs],
 278     [AC_COMPILE_IFELSE(
 279        [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETFPXREGS;])],
 280        [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 281        [gdbsrv_cv_have_ptrace_getfpxregs=no]
 282      )]
 283   )
 284   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 285   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 286     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 287               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 288               [register access.])
 289   fi
 290 fi
 291
 292 if test "${srv_linux_btrace}" = "yes"; then
 293   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 294             [Define if the target supports branch tracing.])
 295 fi
 296
 297 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 298 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 299   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 300 fi
 301
 302 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 303 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 304   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 305 fi
 306
 307 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 308 dnl needs it (and gdbreplay doesn't).
 309 old_LIBS="$LIBS"
 310 AC_CHECK_LIB(dl, dlopen)
 311 LIBS="$old_LIBS"
 312
 313 srv_thread_depfiles=
 314 srv_libs=
 315
 316 if test "$srv_linux_thread_db" = "yes"; then
 317   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 318     srv_libs="-ldl"
 319     AC_MSG_CHECKING(for the dynamic export flag)
 320     old_LDFLAGS="$LDFLAGS"
 321     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 322     # supported there.
 323     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 324     LDFLAGS="$LDFLAGS $RDYNAMIC"
 325     AC_LINK_IFELSE(
 326       [AC_LANG_PROGRAM([],[])],
 327       [found="-Wl,--dynamic-list"
 328        RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 329       [RDYNAMIC="-rdynamic"
 330        LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 331        AC_LINK_IFELSE(
 332          [AC_LANG_PROGRAM([], [])],
 333          [found="-rdynamic"],
 334          [found="no"
 335           RDYNAMIC=""]
 336        )]
 337     )
 338     AC_SUBST(RDYNAMIC)
 339     LDFLAGS="$old_LDFLAGS"
 340     AC_MSG_RESULT($found)
 341   else
 342     srv_libs="-lthread_db"
 343   fi
 344
 345   srv_thread_depfiles="thread-db.o proc-service.o"
 346   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 347   AC_CACHE_CHECK(
 348     [for TD_VERSION],
 349     [gdbsrv_cv_have_td_version],
 350     [AC_COMPILE_IFELSE(
 351        [AC_LANG_PROGRAM([#include <thread_db.h>], [TD_VERSION;])],
 352        [gdbsrv_cv_have_td_version=yes],
 353        [gdbsrv_cv_have_td_version=no]
 354      )]
 355   )
 356   if test "$gdbsrv_cv_have_td_version" = yes; then
 357     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 358   fi
 359 fi
 360
 361 AC_ARG_WITH(libthread-db,
 362 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 363 [srv_libthread_db_path="${withval}"
 364   srv_libs="$srv_libthread_db_path"
 365 ])
 366
 367 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 368   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 369 fi
 370
 371 if test "$srv_xmlfiles" != ""; then
 372   srv_xmlbuiltin="xml-builtin.o"
 373   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 374
 375   tmp_xmlfiles=$srv_xmlfiles
 376   srv_xmlfiles=""
 377   for f in $tmp_xmlfiles; do
 378     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 379   done
 380 fi
 381
 382 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles"
 383 GDBSERVER_LIBS="$srv_libs"
 384
 385 dnl Check whether the target supports __sync_*_compare_and_swap.
 386 AC_CACHE_CHECK(
 387   [whether the target supports __sync_*_compare_and_swap],
 388   [gdbsrv_cv_have_sync_builtins],
 389   [AC_LINK_IFELSE(
 390      [AC_LANG_PROGRAM(
 391         [],
 392         [int foo, bar;
 393          bar = __sync_val_compare_and_swap(&foo, 0, 1);]
 394       )],
 395      [gdbsrv_cv_have_sync_builtins=yes],
 396      [gdbsrv_cv_have_sync_builtins=no]
 397    )]
 398 )
 399 if test "$gdbsrv_cv_have_sync_builtins" = yes; then
 400   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 401     [Define to 1 if the target supports __sync_*_compare_and_swap])
 402 fi
 403
 404 dnl Check for -fvisibility=hidden support in the compiler.
 405 saved_cflags="$CFLAGS"
 406 CFLAGS="$CFLAGS -fvisibility=hidden"
 407 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 408                         [gdbsrv_cv_have_visibility_hidden=yes],
 409                         [gdbsrv_cv_have_visibility_hidden=no])
 410 CFLAGS="$saved_cflags"
 411
 412 IPA_DEPFILES=""
 413 extra_libraries=""
 414
 415 # check whether to enable the inprocess agent
 416 if test "$ipa_obj" != "" \
 417    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 418    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 419    have_ipa=true
 420 else
 421    have_ipa=false
 422 fi
 423
 424 AC_ARG_ENABLE(inprocess-agent,
 425 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 426 [case "$enableval" in
 427   yes) want_ipa=true ;;
 428   no) want_ipa=false ;;
 429   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 430 esac],
 431 [want_ipa=$have_ipa])
 432
 433 if $want_ipa ; then
 434    if $have_ipa ; then
 435      IPA_DEPFILES="$ipa_obj"
 436      extra_libraries="$extra_libraries libinproctrace.so"
 437    else
 438      AC_MSG_ERROR([inprocess agent not supported for this target])
 439    fi
 440 fi
 441
 442 AC_SUBST(GDBSERVER_DEPFILES)
 443 AC_SUBST(GDBSERVER_LIBS)
 444 AC_SUBST(srv_xmlbuiltin)
 445 AC_SUBST(srv_xmlfiles)
 446 AC_SUBST(IPA_DEPFILES)
 447 AC_SUBST(extra_libraries)
 448
 449 GNULIB=../gnulib/import
 450
 451 GNULIB_STDINT_H=
 452 if test x"$STDINT_H" != x; then
 453   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 454 fi
 455 AC_SUBST(GNULIB_STDINT_H)
 456
 457 AC_CONFIG_FILES([Makefile])
 458
 459 AC_OUTPUT