gdbsupport/common.m4

   1 dnl Autoconf configure snippets for common.
   2 dnl Copyright (C) 1995-2022 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Invoke configury needed by the files in 'common'.
  20 AC_DEFUN([GDB_AC_COMMON], [
  21   # Set the 'development' global.
  22   . $srcdir/../bfd/development.sh
  23
  24   AC_HEADER_STDC
  25   AC_FUNC_ALLOCA
  26
  27   WIN32APILIBS=
  28   case ${host} in
  29     *mingw32*)
  30       AC_DEFINE(USE_WIN32API, 1,
  31                 [Define if we should use the Windows API, instead of the
  32                  POSIX API.  On Windows, we use the Windows API when
  33                  building for MinGW, but the POSIX API when building
  34                  for Cygwin.])
  35       WIN32APILIBS="-lws2_32"
  36       ;;
  37   esac
  38
  39   dnl Note that this requires codeset.m4, which is included
  40   dnl by the users of common.m4.
  41   AM_LANGINFO_CODESET
  42
  43   AC_CHECK_HEADERS(linux/perf_event.h locale.h memory.h signal.h dnl
  44                    sys/resource.h sys/socket.h dnl
  45                    sys/un.h sys/wait.h dnl
  46                    thread_db.h wait.h dnl
  47                    termios.h dnl
  48                    dlfcn.h dnl
  49                    linux/elf.h proc_service.h dnl
  50                    poll.h sys/poll.h sys/select.h)
  51
  52   AC_FUNC_MMAP
  53   AC_FUNC_FORK
  54   AC_CHECK_FUNCS([fdwalk getrlimit pipe pipe2 poll socketpair sigaction \
  55                   ptrace64 sbrk setns sigaltstack sigprocmask \
  56                   setpgid setpgrp getrusage getauxval sigtimedwait])
  57
  58   # This is needed for RHEL 5 and uclibc-ng < 1.0.39.
  59   # These did not define ADDR_NO_RANDOMIZE in sys/personality.h,
  60   # only in linux/personality.h.
  61   AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
  62
  63   AC_CHECK_DECLS([strstr])
  64
  65   # ----------------------- #
  66   # Checks for structures.  #
  67   # ----------------------- #
  68
  69   AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
  70
  71   # On FreeBSD we need libutil for the kinfo_get* functions.  On
  72   # GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
  73   # Figure out which one to use.
  74   AC_SEARCH_LIBS(kinfo_getfile, util util-freebsd)
  75
  76   # Define HAVE_KINFO_GETFILE if kinfo_getfile is available.
  77   AC_CHECK_FUNCS(kinfo_getfile)
  78
  79   # ----------------------- #
  80   # Check for threading.    #
  81   # ----------------------- #
  82
  83   AC_ARG_ENABLE(threading,
  84     AS_HELP_STRING([--enable-threading], [include support for parallel processing of data (yes/no)]),
  85     [case "$enableval" in
  86     yes) want_threading=yes ;;
  87     no) want_threading=no ;;
  88     *) AC_MSG_ERROR([bad value $enableval for threading]) ;;
  89     esac],
  90     [want_threading=yes])
  91
  92   # Check for std::thread.  This does not work on some platforms, like
  93   # mingw and DJGPP.
  94   AC_LANG_PUSH([C++])
  95   AX_PTHREAD([threads=yes], [threads=no])
  96   save_LIBS="$LIBS"
  97   LIBS="$PTHREAD_LIBS $LIBS"
  98   save_CXXFLAGS="$CXXFLAGS"
  99   CXXFLAGS="$PTHREAD_CFLAGS $save_CXXFLAGS"
 100   AC_CACHE_CHECK([for std::thread],
 101                  gdb_cv_cxx_std_thread,
 102                  [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 103   [[#include <thread>
 104     void callback() { }]],
 105   [[std::thread t(callback);]])],
 106                                 gdb_cv_cxx_std_thread=yes,
 107                                 gdb_cv_cxx_std_thread=no)])
 108
 109   if test "$threads" = "yes"; then
 110     # This check must be here, while LIBS includes any necessary
 111     # threading library.
 112     AC_CHECK_FUNCS([pthread_sigmask pthread_setname_np])
 113   fi
 114   LIBS="$save_LIBS"
 115   CXXFLAGS="$save_CXXFLAGS"
 116
 117   if test "$want_threading" = "yes"; then
 118     if test "$gdb_cv_cxx_std_thread" = "yes"; then
 119       AC_DEFINE(CXX_STD_THREAD, 1,
 120                 [Define to 1 if std::thread works.])
 121     fi
 122   fi
 123   AC_LANG_POP
 124
 125   dnl Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't
 126   dnl do since sigsetjmp might only be defined as a macro.
 127   AC_CACHE_CHECK(
 128     [for sigsetjmp],
 129     [gdb_cv_func_sigsetjmp],
 130     [AC_COMPILE_IFELSE(
 131        [AC_LANG_PROGRAM(
 132           [#include <setjmp.h>],
 133           [sigjmp_buf env;
 134            while (! sigsetjmp (env, 1))
 135              siglongjmp (env, 1);]
 136         )],
 137        [gdb_cv_func_sigsetjmp=yes],
 138        [gdb_cv_func_sigsetjmp=no]
 139      )]
 140   )
 141   if test "$gdb_cv_func_sigsetjmp" = "yes"; then
 142     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 143   fi
 144
 145   AC_ARG_WITH(intel_pt,
 146     AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
 147     [], [with_intel_pt=auto])
 148   AC_MSG_CHECKING([whether to use intel pt])
 149   AC_MSG_RESULT([$with_intel_pt])
 150
 151   if test "${with_intel_pt}" = no; then
 152     AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
 153     HAVE_LIBIPT=no
 154   else
 155     AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 156   #include <linux/perf_event.h>
 157   #ifndef PERF_ATTR_SIZE_VER5
 158   # error
 159   #endif
 160     ]])], [perf_event=yes], [perf_event=no])
 161     if test "$perf_event" != yes; then
 162       if test "$with_intel_pt" = yes; then
 163         AC_MSG_ERROR([linux/perf_event.h missing or too old])
 164       else
 165         AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
 166       fi
 167     fi
 168
 169     AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
 170     if test "$HAVE_LIBIPT" != yes; then
 171       if test "$with_intel_pt" = yes; then
 172         AC_MSG_ERROR([libipt is missing or unusable])
 173       else
 174         AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
 175       fi
 176     else
 177       save_LIBS=$LIBS
 178       LIBS="$LIBS $LIBIPT"
 179       AC_CHECK_FUNCS(pt_insn_event)
 180       AC_CHECK_MEMBERS([struct pt_insn.enabled, struct pt_insn.resynced], [], [],
 181                        [#include <intel-pt.h>])
 182       LIBS=$save_LIBS
 183     fi
 184   fi
 185
 186   # Check if the compiler and runtime support printing long longs.
 187
 188   AC_CACHE_CHECK([for long long support in printf],
 189                  gdb_cv_printf_has_long_long,
 190                  [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 191   [[char buf[32];
 192     long long l = 0;
 193     l = (l << 16) + 0x0123;
 194     l = (l << 16) + 0x4567;
 195     l = (l << 16) + 0x89ab;
 196     l = (l << 16) + 0xcdef;
 197     sprintf (buf, "0x%016llx", l);
 198     return (strcmp ("0x0123456789abcdef", buf));]])],
 199                                 gdb_cv_printf_has_long_long=yes,
 200                                 gdb_cv_printf_has_long_long=no,
 201                                 gdb_cv_printf_has_long_long=no)])
 202   if test "$gdb_cv_printf_has_long_long" = yes; then
 203     AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
 204               [Define to 1 if the "%ll" format works to print long longs.])
 205   fi
 206
 207   BFD_SYS_PROCFS_H
 208   if test "$ac_cv_header_sys_procfs_h" = yes; then
 209     BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 210     BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 211     BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 212     BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 213     BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 214     BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 215     BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 216     BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
 217   fi
 218 ])