gnattools/configure.ac

   1 # Configure script for libada.
   2 #   Copyright 2003, 2004 Free Software Foundation, Inc.
   3 #
   4 # This file is free software; you can redistribute it and/or modify it
   5 # under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  17
  18 AC_INIT
  19 AC_PREREQ([2.59])
  20
  21 AC_CONFIG_SRCDIR([Makefile.in])
  22
  23 # Command-line options.
  24 # Very limited version of AC_MAINTAINER_MODE.
  25 AC_ARG_ENABLE([maintainer-mode],
  26   [AC_HELP_STRING([--enable-maintainer-mode],
  27                  [enable make rules and dependencies not useful (and
  28                   sometimes confusing) to the casual installer])],
  29   [case ${enable_maintainer_mode} in
  30      yes) MAINT='' ;;
  31      no) MAINT='#' ;;
  32      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
  33    esac
  34    maintainer_mode=${enableval}],
  35   [MAINT='#'])
  36 AC_SUBST([MAINT])dnl
  37
  38 # Start of actual configure tests
  39
  40 AC_PROG_INSTALL
  41
  42 AC_CANONICAL_BUILD
  43 AC_CANONICAL_HOST
  44 AC_CANONICAL_TARGET
  45
  46 sinclude(../config/acx.m4)
  47 ACX_NONCANONICAL_TARGET
  48
  49 # Need to pass this down for now :-P
  50 AC_PROG_LN_S
  51
  52 # Determine x_ada_cflags
  53 case $host in
  54   hppa*) x_ada_cflags=-mdisable-indexing ;;
  55   *) x_ada_cflags= ;;
  56 esac
  57 AC_SUBST([x_ada_cflags])
  58
  59 # Determine what to build for 'gnattools'
  60 if test $build = $target ; then
  61   # Note that build=target is almost certainly the wrong test; FIXME
  62   default_gnattools_target="gnattools-native"
  63 else
  64   default_gnattools_target="gnattools-cross"
  65 fi
  66 AC_SUBST([default_gnattools_target])
  67
  68 # Target-specific stuff (defaults)
  69 TOOLS_TARGET_PAIRS=
  70 AC_SUBST(TOOLS_TARGET_PAIRS)
  71 EXTRA_GNATTOOLS=
  72 AC_SUBST(EXTRA_GNATTOOLS)
  73
  74 # Per-target case statement
  75 # -------------------------
  76 case "${target}" in
  77   alpha*-dec-vx*) # Unlike all other Vxworks
  78     ;;
  79   m68k*-wrs-vx* \
  80   | powerpc*-wrs-vxworks \
  81   | sparc*-wrs-vx* \
  82   | *86-wrs-vxworks \
  83   | xscale*-wrs-vx* \
  84   | xscale*-wrs-coff \
  85   | mips*-wrs-vx*)
  86     TOOLS_TARGET_PAIRS="mlib-tgt-specific.adb<mlib-tgt-vxworks.adb"
  87     ;;
  88   sparc-sun-solaris*)
  89     TOOLS_TARGET_PAIRS="mlib-tgt-specific.adb<mlib-tgt-solaris.adb"
  90     ;;
  91   *86-*-solaris2*)
  92     TOOLS_TARGET_PAIRS="mlib-tgt-specific.adb<mlib-tgt-solaris.adb"
  93     ;;
  94   *86-*-linux* \
  95   | powerpc*-*-linux* \
  96   | *ia64-*-linux* \
  97   | alpha*-*-linux* \
  98   | sparc*-*-linux* \
  99   | hppa*-*-linux* \
 100   | *x86_64-*-linux*)
 101     TOOLS_TARGET_PAIRS="\
 102     mlib-tgt-specific.adb<mlib-tgt-linux.adb \
 103     indepsw.adb<indepsw-gnu.adb"
 104     ;;
 105   s390*-*-linux*)
 106     TOOLS_TARGET_PAIRS="mlib-tgt-specific.adb<mlib-tgt-linux.adb"
 107     ;;
 108   *86-*-freebsd*)
 109     TOOLS_TARGET_PAIRS="\
 110     mlib-tgt-specific.adb<mlib-tgt-linux.adb \
 111     indepsw.adb<indepsw-gnu.adb"
 112     ;;
 113   mips-sgi-irix*)
 114     TOOLS_TARGET_PAIRS="mlib-tgt-specific.adb<mlib-tgt-irix.adb"
 115     ;;
 116   hppa*-hp-hpux10*) # Unlike hpux11
 117     ;;
 118   hppa*-hp-hpux11*)
 119     TOOLS_TARGET_PAIRS="mlib-tgt-specific.adb<mlib-tgt-hpux.adb"
 120     ;;
 121   *-ibm-aix*)
 122     TOOLS_TARGET_PAIRS="\
 123     mlib-tgt-specific.adb<mlib-tgt-aix.adb \
 124     indepsw.adb<indepsw-aix.adb"
 125     ;;
 126   alpha*-dec-osf*)
 127     TOOLS_TARGET_PAIRS="mlib-tgt-specific.adb<mlib-tgt-tru64.adb"
 128     ;;
 129   alpha*-dec-vms* | alpha*-dec-openvms* | alpha*-dec-vms* \
 130   | alpha*-hp-vms* | alpha*-hp-openvms* | alpha*-hp-vms*)
 131     TOOLS_TARGET_PAIRS="\
 132     mlib-tgt-specific.adb<mlib-tgt-vms-alpha.adb \
 133     symbols.adb<symbols-vms.adb \
 134     symbols-processing.adb<symbols-processing-vms-alpha.adb"
 135
 136     EXTRA_GNATTOOLS='../../gnatlbr$(exeext) ../../gnatsym$(exeext)'
 137     ;;
 138   ia64*-dec-vms* | ia64*-dec-openvms* | ia64*-dec-vms* \
 139   | ia64*-hp-vms* | ia64*-hp-openvms* | ia64*-hp-vms*)
 140     TOOLS_TARGET_PAIRS="\
 141     mlib-tgt-specific.adb<mlib-tgt-vms-ia64.adb \
 142     symbols.adb<symbols-vms.adb \
 143     symbols-processing.adb<symbols-processing-vms-ia64.adb"
 144
 145     EXTRA_GNATTOOLS='../../gnatlbr$(exeext) ../../gnatsym$(exeext)'
 146     ;;
 147   *-*-cygwin32* | *-*-mingw32* | *-*-pe)
 148     TOOLS_TARGET_PAIRS="\
 149     mlib-tgt-specific.adb<mlib-tgt-mingw.adb \
 150     indepsw.adb<indepsw-mingw.adb"
 151     EXTRA_GNATTOOLS='../../gnatdll$(exeext)'
 152     ;;
 153   powerpc-*-darwin* | *86-*-darwin*)
 154     TOOLS_TARGET_PAIRS="mlib-tgt-specific.adb<mlib-tgt-darwin.adb"
 155     ;;
 156   *-*-lynxos)
 157     TOOLS_TARGET_PAIRS="\
 158     mlib-tgt-specific.adb<mlib-tgt-lynxos.adb \
 159     indepsw.adb<indepsw-gnu.adb"
 160     ;;
 161 esac
 162
 163 # Output: create a Makefile.
 164 AC_CONFIG_FILES([Makefile])
 165
 166 AC_OUTPUT