ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2021 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 AC_INIT([ld], BFD_VERSION)
  22 AC_CONFIG_SRCDIR(ldmain.c)
  23
  24 AC_CANONICAL_TARGET
  25 AC_CANONICAL_BUILD
  26
  27 AM_INIT_AUTOMAKE
  28 AM_MAINTAINER_MODE
  29
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_PROG_GREP
  33 AC_GNU_SOURCE
  34 AC_USE_SYSTEM_EXTENSIONS
  35 AC_PROG_INSTALL
  36
  37 LT_INIT
  38 ACX_LARGEFILE
  39
  40 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  41 AC_ARG_ENABLE(targets,
  42 [  --enable-targets        alternative target configurations],
  43 [case "${enableval}" in
  44   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  45             ;;
  46   no)       enable_targets= ;;
  47   *)        enable_targets=$enableval ;;
  48 esac])dnl
  49 AC_ARG_ENABLE(64-bit-bfd,
  50 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  51 [case "${enableval}" in
  52   yes)  want64=true  ;;
  53   no)   want64=false ;;
  54   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  55 esac],[want64=false])dnl
  56
  57 AC_ARG_WITH(sysroot,
  58 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  59 [
  60  case ${with_sysroot} in
  61  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  62  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  63  esac
  64
  65  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  66  use_sysroot=yes
  67
  68  if test "x$prefix" = xNONE; then
  69   test_prefix=/usr/local
  70  else
  71   test_prefix=$prefix
  72  fi
  73  if test "x$exec_prefix" = xNONE; then
  74   test_exec_prefix=$test_prefix
  75  else
  76   test_exec_prefix=$exec_prefix
  77  fi
  78  case ${TARGET_SYSTEM_ROOT} in
  79  "${test_prefix}"|"${test_prefix}/"*|\
  80  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  81  '${prefix}'|'${prefix}/'*|\
  82  '${exec_prefix}'|'${exec_prefix}/'*)
  83    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  84    TARGET_SYSTEM_ROOT_DEFINE="$t"
  85    ;;
  86  esac
  87 ], [
  88  use_sysroot=no
  89  TARGET_SYSTEM_ROOT=
  90  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  91 ])
  92 AC_SUBST(use_sysroot)
  93 AC_SUBST(TARGET_SYSTEM_ROOT)
  94 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  95
  96 dnl Use --enable-gold to decide if this linker should be the default.
  97 dnl "install_as_default" is set to false if gold is the default linker.
  98 dnl "installed_linker" is the installed BFD linker name.
  99 AC_ARG_ENABLE(gold,
 100 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
 101 [case "${enableval}" in
 102  default)
 103    install_as_default=no
 104    installed_linker=ld.bfd
 105    ;;
 106  yes|no)
 107    install_as_default=yes
 108    installed_linker=ld.bfd
 109    ;;
 110  *)
 111    AC_MSG_ERROR([invalid --enable-gold argument])
 112    ;;
 113  esac],
 114 [install_as_default=yes
 115  installed_linker=ld.bfd])
 116 AC_SUBST(install_as_default)
 117 AC_SUBST(installed_linker)
 118
 119 AC_ARG_ENABLE([got],
 120 AS_HELP_STRING([--enable-got=<type>],
 121                [GOT handling scheme (target, single, negative, multigot)]),
 122 [case "${enableval}" in
 123   target | single | negative | multigot)  got_handling=$enableval ;;
 124   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 125 esac],
 126 [got_handling=target])
 127
 128 case "${got_handling}" in
 129   target)
 130     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 131               [Define to choose default GOT handling scheme]) ;;
 132   single)
 133     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 134               [Define to choose default GOT handling scheme]) ;;
 135   negative)
 136     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 137               [Define to choose default GOT handling scheme]) ;;
 138   multigot)
 139     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 140               [Define to choose default GOT handling scheme]) ;;
 141   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 142 esac
 143
 144 # PR gas/19109
 145 # Decide the default method for compressing debug sections.
 146 ac_default_compressed_debug_sections=unset
 147 # Provide a configure time option to override our default.
 148 AC_ARG_ENABLE(compressed_debug_sections,
 149               AS_HELP_STRING([--enable-compressed-debug-sections={all,ld,none}],
 150               [compress debug sections by default])],
 151 [case ,"${enableval}", in
 152   ,yes, | ,all, | *,ld,*) ac_default_compressed_debug_sections=yes ;;
 153   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
 154 esac])dnl
 155
 156 # Decide setting DT_RUNPATH instead of DT_RPATH by default
 157 ac_default_new_dtags=unset
 158 # Provide a configure time option to override our default.
 159 AC_ARG_ENABLE(new_dtags,
 160               AS_HELP_STRING([--enable-new-dtags],
 161               [set DT_RUNPATH instead of DT_RPATH by default])],
 162 [case "${enableval}" in
 163   yes) ac_default_new_dtags=1 ;;
 164   no) ac_default_new_dtags=0 ;;
 165 esac])dnl
 166
 167 # Decide if -z relro should be enabled in ELF linker by default.
 168 ac_default_ld_z_relro=unset
 169 # Provide a configure time option to override our default.
 170 AC_ARG_ENABLE(relro,
 171               AS_HELP_STRING([--enable-relro],
 172               [enable -z relro in ELF linker by default]),
 173 [case "${enableval}" in
 174   yes)  ac_default_ld_z_relro=1 ;;
 175   no)  ac_default_ld_z_relro=0 ;;
 176 esac])dnl
 177
 178 # Decide if DT_TEXTREL check should be enabled in ELF linker.
 179 ac_default_ld_textrel_check=unset
 180 AC_ARG_ENABLE([textrel-check],
 181               AC_HELP_STRING([--enable-textrel-check=@<:@yes|no|warning|error@:>@],
 182                              [enable DT_TEXTREL check in ELF linker]),
 183 [case "${enableval}" in
 184   yes|no|warning|error) ac_default_ld_textrel_check=${enableval} ;;
 185 esac])
 186
 187 # Decide if -z separate-code should be enabled in ELF linker by default.
 188 ac_default_ld_z_separate_code=unset
 189 AC_ARG_ENABLE(separate-code,
 190               AS_HELP_STRING([--enable-separate-code],
 191               [enable -z separate-code in ELF linker by default]),
 192 [case "${enableval}" in
 193   yes) ac_default_ld_z_separate_code=1 ;;
 194   no) ac_default_ld_z_separate_code=0 ;;
 195 esac])
 196
 197 # Decide if --error-handling-script should be supported.
 198 ac_support_error_handling_script=unset
 199 AC_ARG_ENABLE(error-handling-script,
 200               AS_HELP_STRING([--enable-error-handling-script],
 201               [enable/disable support for the --error-handling-script option]),
 202 [case "${enableval}" in
 203   yes) ac_support_error_handling_script=1 ;;
 204   no)  ac_support_error_handling_script=0 ;;
 205 esac])
 206
 207 # Decide which "--hash-style" to use by default
 208 # Provide a configure time option to override our default.
 209 AC_ARG_ENABLE([default-hash-style],
 210 AS_HELP_STRING([--enable-default-hash-style={sysv,gnu,both}],
 211                [use this default hash style]),
 212 [case "${enable_default_hash_style}" in
 213   sysv | gnu | both) ;;
 214   *) AC_MSG_ERROR([bad value ${enable_default_hash_style} for enable-default-hash-style option]) ;;
 215 esac],
 216 [case "${target}" in
 217   # Enable gnu hash only on GNU targets, but not mips
 218   mips*-*-*) enable_default_hash_style=sysv ;;
 219   *-*-gnu* | *-*-linux* | *-*-nacl*) enable_default_hash_style=both ;;
 220   *) enable_default_hash_style=sysv ;;
 221 esac])
 222
 223 case "${enable_default_hash_style}" in
 224   sysv | both) ac_default_emit_sysv_hash=1 ;;
 225   *) ac_default_emit_sysv_hash=0 ;;
 226 esac
 227
 228 case "${enable_default_hash_style}" in
 229   gnu | both) ac_default_emit_gnu_hash=1 ;;
 230   *) ac_default_emit_gnu_hash=0 ;;
 231 esac
 232
 233 AC_ARG_ENABLE(initfini-array,
 234 [  --disable-initfini-array do not use .init_array/.fini_array sections],
 235 [case "${enableval}" in
 236  yes|no) ;;
 237  *) AC_MSG_ERROR([invalid --enable-initfini-array argument]) ;;
 238  esac], [enable_initfini_array=yes])
 239 AC_SUBST(enable_initfini_array)
 240 if test $enable_initfini_array = yes; then
 241   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 242     [Define .init_array/.fini_array sections are available and working.])
 243 fi
 244
 245 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
 246 if test "${enable_libctf}" = yes; then
 247     AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
 248 fi
 249 AM_CONDITIONAL(ENABLE_LIBCTF, test "${enable_libctf}" = yes)
 250 AC_SUBST(enable_libctf)
 251
 252 AM_BINUTILS_WARNINGS
 253
 254 AM_LC_MESSAGES
 255
 256 AC_CONFIG_HEADERS([config.h:config.in])
 257
 258 # PR 14072
 259 AH_VERBATIM([00_CONFIG_H_CHECK],
 260 [/* Check that config.h is #included before system headers
 261    (this works only for glibc, but that should be enough).  */
 262 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 263 #  error config.h must be #included before system headers
 264 #endif
 265 #define __CONFIG_H__ 1])
 266
 267 if test -z "$target" ; then
 268     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 269 fi
 270 if test -z "$host" ; then
 271     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 272 fi
 273
 274 # host-specific stuff:
 275
 276 ALL_LINGUAS="bg da de es fi fr ga id it ja pt_BR ru sr sv tr uk vi zh_CN zh_TW"
 277 ZW_GNU_GETTEXT_SISTER_DIR
 278 AM_PO_SUBDIRS
 279
 280 AC_EXEEXT
 281
 282 AC_PROG_YACC
 283 AM_PROG_LEX
 284
 285 AM_MAINTAINER_MODE
 286 AM_CONDITIONAL(GENINSRC_NEVER, false)
 287 ACX_PROG_CMP_IGNORE_INITIAL
 288
 289 . ${srcdir}/configure.host
 290
 291 AC_SUBST(HDEFINES)
 292 AC_SUBST(NATIVE_LIB_DIRS)
 293
 294 # We use headers from include/ that check various HAVE_*_H macros, thus
 295 # should ensure they are set by configure.  This is true even when C99
 296 # guarantees they are available.
 297 # sha1.h and md4.h test HAVE_LIMITS_H, HAVE_SYS_TYPES_H and HAVE_STDINT_H
 298 # plugin-api.h tests HAVE_STDINT_H and HAVE_INTTYPES_H
 299 # Besides those, we need to check anything used in ld/ not in C99.
 300 AC_CHECK_HEADERS(fcntl.h elf-hints.h limits.h inttypes.h stdint.h \
 301                  sys/file.h sys/mman.h sys/param.h sys/stat.h sys/time.h \
 302                  sys/types.h unistd.h)
 303 AC_CHECK_FUNCS(close glob lseek mkstemp open realpath sbrk waitpid)
 304
 305 BFD_BINARY_FOPEN
 306
 307 AC_CHECK_DECLS([asprintf, environ, sbrk])
 308
 309 AC_FUNC_MMAP
 310
 311 AC_SEARCH_LIBS([dlopen], [dl])
 312
 313 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 314 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 315 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 316 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 317 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 318 if test $ld_cv_decl_getopt_unistd_h = yes; then
 319   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 320             [Is the prototype for getopt in <unistd.h> in the expected format?])
 321 fi
 322
 323 # Link in zlib if we can.  This allows us to read and write
 324 # compressed CTF sections.
 325 AM_ZLIB
 326
 327 # When converting linker scripts into strings for use in emulation
 328 # files, use astring.sed if the compiler supports ANSI string
 329 # concatenation, or ostring.sed otherwise.  This is to support the
 330 # broken Microsoft MSVC compiler, which limits the length of string
 331 # constants, while still supporting pre-ANSI compilers which do not
 332 # support string concatenation.
 333 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 334 AC_CACHE_VAL(ld_cv_string_concatenation,
 335 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 336   ld_cv_string_concatenation=yes,
 337   ld_cv_string_concatenation=no)])
 338 AC_MSG_RESULT($ld_cv_string_concatenation)
 339 if test "$ld_cv_string_concatenation" = "yes"; then
 340   STRINGIFY=astring.sed
 341 else
 342   STRINGIFY=ostring.sed
 343 fi
 344 AC_SUBST(STRINGIFY)
 345
 346 # target-specific stuff:
 347
 348 all_targets=
 349 EMUL=
 350 all_emuls=
 351 all_emul_extras=
 352 all_libpath=
 353 TDIRS=
 354
 355 # If the host is 64-bit, then we enable 64-bit targets by default.
 356 # This is consistent with what ../bfd/configure.ac does.
 357 if test x${want64} = xfalse; then
 358   AC_CHECK_SIZEOF(void *)
 359   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 360     want64=true
 361   fi
 362 fi
 363
 364 elf_list_options=false
 365 elf_shlib_list_options=false
 366 elf_plt_unwind_list_options=false
 367 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 368 do
 369   if test "$targ_alias" = "all"; then
 370     all_targets=true
 371     elf_list_options=true
 372     elf_shlib_list_options=true
 373     elf_plt_unwind_list_options=true
 374   else
 375     # Canonicalize the secondary target names.
 376     result=`$ac_config_sub $targ_alias 2>/dev/null`
 377     if test -n "$result"; then
 378         targ=$result
 379     else
 380         targ=$targ_alias
 381     fi
 382
 383     . ${srcdir}/configure.tgt
 384
 385     if test "$targ" = "$target"; then
 386       EMUL=$targ_emul
 387     fi
 388
 389     if test x${want64} = xfalse; then
 390       . ${srcdir}/../bfd/config.bfd
 391     fi
 392
 393     if test x${want64} = xtrue; then
 394       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 395       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 396     fi
 397
 398     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 399         case " $all_emuls " in
 400         *" e${i}.o "*) ;;
 401         *)
 402           all_emuls="$all_emuls e${i}.o"
 403           eval result=\$tdir_$i
 404           test -z "$result" && result=$targ_alias
 405           TDIRS="$TDIRS
 406 tdir_$i=$result"
 407           case "${i}" in
 408           *elf*)
 409             elf_list_options=true
 410             ;;
 411           *)
 412             if $GREP "TEMPLATE_NAME=elf" ${srcdir}/emulparams/${i}.sh >/dev/null 2>/dev/null; then
 413               elf_list_options=true
 414             fi
 415             ;;
 416           esac
 417           if test "$elf_list_options" = "true"; then
 418             source_sh()
 419             {
 420               . $1
 421             }
 422             source_sh ${srcdir}/emulparams/${i}.sh
 423             if test x${GENERATE_SHLIB_SCRIPT} = xyes; then
 424               elf_shlib_list_options=true
 425             fi
 426             if test x${PLT_UNWIND} = xyes; then
 427               elf_plt_unwind_list_options=true
 428             fi
 429           fi
 430           ;;
 431         esac
 432     done
 433
 434     for i in $targ_emul $targ_extra_libpath; do
 435         case " $all_libpath " in
 436         *" ${i} "*) ;;
 437         *)
 438           if test -z "$all_libpath"; then
 439             all_libpath=${i}
 440           else
 441             all_libpath="$all_libpath ${i}"
 442           fi
 443           ;;
 444         esac
 445     done
 446
 447     for i in $targ_extra_ofiles; do
 448         case " $all_emul_extras " in
 449         *" ${i} "*) ;;
 450         *)
 451           all_emul_extras="$all_emul_extras ${i}"
 452           ;;
 453         esac
 454     done
 455
 456   fi
 457 done
 458
 459 if test x$ac_default_compressed_debug_sections = xyes ; then
 460   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 461 fi
 462
 463 if test "${ac_default_new_dtags}" = unset; then
 464   ac_default_new_dtags=0
 465 fi
 466 AC_DEFINE_UNQUOTED(DEFAULT_NEW_DTAGS,
 467   $ac_default_new_dtags,
 468   [Define to 1 if you want to set DT_RUNPATH instead of DT_RPATH by default.])
 469
 470 if test "${ac_default_ld_z_relro}" = unset; then
 471   ac_default_ld_z_relro=0
 472 fi
 473 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_RELRO,
 474   $ac_default_ld_z_relro,
 475   [Define to 1 if you want to enable -z relro in ELF linker by default.])
 476
 477 ac_default_ld_textrel_check_warning=0
 478 case "${ac_default_ld_textrel_check}" in
 479   unset|no)
 480     ac_default_ld_textrel_check=textrel_check_none
 481     ;;
 482   yes|warning)
 483     ac_default_ld_textrel_check=textrel_check_warning
 484     ac_default_ld_textrel_check_warning=1
 485     ;;
 486   error)
 487     ac_default_ld_textrel_check=textrel_check_error
 488     ;;
 489 esac
 490 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK,
 491   $ac_default_ld_textrel_check,
 492   [The default method for DT_TEXTREL check in ELF linker.])
 493 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK_WARNING,
 494   $ac_default_ld_textrel_check_warning,
 495   [Define to 1 if DT_TEXTREL check is warning in ELF linker by default.])
 496
 497 if test "${ac_default_ld_z_separate_code}" = unset; then
 498   ac_default_ld_z_separate_code=0
 499 fi
 500 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_SEPARATE_CODE,
 501   $ac_default_ld_z_separate_code,
 502   [Define to 1 if you want to enable -z separate-code in ELF linker by default.])
 503
 504 if test "${ac_support_error_handling_script}" = unset; then
 505   ac_support_error_handling_script=1
 506 fi
 507 AC_DEFINE_UNQUOTED(SUPPORT_ERROR_HANDLING_SCRIPT,
 508   $ac_support_error_handling_script,
 509   [Define to 1 if you want to support the --error-handling-script command line option.])
 510
 511 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_SYSV_HASH],
 512   [$ac_default_emit_sysv_hash],
 513   [Define to 1 if you want to emit sysv hash in the ELF linker by default.])
 514
 515 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_GNU_HASH],
 516   [$ac_default_emit_gnu_hash],
 517   [Define to 1 if you want to emit gnu hash in the ELF linker by default.])
 518
 519 AC_SUBST(elf_list_options)
 520 AC_SUBST(elf_shlib_list_options)
 521 AC_SUBST(elf_plt_unwind_list_options)
 522 AC_SUBST(EMUL)
 523
 524 AC_SUBST(TDIRS)
 525 AM_SUBST_NOTMAKE(TDIRS)
 526
 527 if test x${all_targets} = xtrue; then
 528   if test x${want64} = xtrue; then
 529     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 530     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 531   else
 532     EMULATION_OFILES='$(ALL_EMULATIONS)'
 533     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 534   fi
 535 else
 536   EMULATION_OFILES=$all_emuls
 537   EMUL_EXTRA_OFILES=$all_emul_extras
 538 fi
 539 AC_SUBST(EMULATION_OFILES)
 540 AC_SUBST(EMUL_EXTRA_OFILES)
 541 AC_SUBST(LIB_PATH)
 542
 543 EMULATION_LIBPATH=$all_libpath
 544 AC_SUBST(EMULATION_LIBPATH)
 545
 546 if test x${enable_static} = xno; then
 547   TESTBFDLIB="-Wl,--rpath,../bfd/.libs ../bfd/.libs/libbfd.so"
 548   TESTCTFLIB="-Wl,--rpath,../libctf/.libs ../libctf/.libs/libctf.so"
 549 else
 550   TESTBFDLIB="../bfd/.libs/libbfd.a"
 551   TESTCTFLIB="../libctf/.libs/libctf.a"
 552 fi
 553 if test "${enable_libctf}" = no; then
 554     TESTCTFLIB=
 555 fi
 556 AC_SUBST(TESTBFDLIB)
 557 AC_SUBST(TESTCTFLIB)
 558
 559 target_vendor=${target_vendor=$host_vendor}
 560 case "$target_vendor" in
 561   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 562   *)  EXTRA_SHLIB_EXTENSION= ;;
 563 esac
 564
 565 case "$target_os" in
 566   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 567 esac
 568
 569 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 570   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 571    [Additional extension a shared object might have.])
 572 fi
 573
 574 AC_CONFIG_COMMANDS([default],
 575 [[
 576 case "$srcdir" in
 577   .) srcdirpre= ;;
 578   *) srcdirpre='$(srcdir)/' ;;
 579 esac
 580 POFILES=
 581 GMOFILES=
 582 for lang in dummy $OBSOLETE_ALL_LINGUAS; do
 583   if test $lang != dummy; then
 584     POFILES="$POFILES $srcdirpre$lang.po"
 585     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 586   fi
 587 done
 588 sed -e '/^SRC-POTFILES =/r po/SRC-POTFILES' \
 589     -e '/^BLD-POTFILES =/r po/BLD-POTFILES' \
 590     -e "s,@POFILES@,$POFILES," \
 591     -e "s,@GMOFILES@,$GMOFILES," \
 592     po/Makefile.in > po/Makefile]],[[]])
 593
 594 dnl Required by html, pdf, install-pdf and install-html
 595 AC_SUBST(datarootdir)
 596 AC_SUBST(docdir)
 597 AC_SUBST(htmldir)
 598 AC_SUBST(pdfdir)
 599
 600 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 601 AC_OUTPUT
 602
 603 GNU_MAKE_JOBSERVER