ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR(ldmain.c)
   6
   7 AC_CANONICAL_TARGET
   8 AC_ISC_POSIX
   9
  10 changequote(,)dnl
  11 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  12 changequote([,])dnl
  13 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  14 AM_MAINTAINER_MODE
  15
  16 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  17 AC_ARG_ENABLE(targets,
  18 [  --enable-targets        alternative target configurations],
  19 [case "${enableval}" in
  20   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  21             ;;
  22   no)       enable_targets= ;;
  23   *)        enable_targets=$enableval ;;
  24 esac])dnl
  25 AC_ARG_ENABLE(64-bit-bfd,
  26 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  27 [case "${enableval}" in
  28   yes)  want64=true  ;;
  29   no)   want64=false ;;
  30   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  31 esac],[want64=false])dnl
  32
  33 AC_ARG_WITH(sysroot,
  34 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  35 [
  36  case ${with_sysroot} in
  37  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  38  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  39  esac
  40
  41  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  42  use_sysroot=yes
  43
  44  if test "x$prefix" = xNONE; then
  45   test_prefix=/usr/local
  46  else
  47   test_prefix=$prefix
  48  fi
  49  if test "x$exec_prefix" = xNONE; then
  50   test_exec_prefix=$test_prefix
  51  else
  52   test_exec_prefix=$exec_prefix
  53  fi
  54  case ${TARGET_SYSTEM_ROOT} in
  55  "${test_prefix}"|"${test_prefix}/"*|\
  56  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  57  '${prefix}'|'${prefix}/'*|\
  58  '${exec_prefix}'|'${exec_prefix}/'*)
  59    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  60    TARGET_SYSTEM_ROOT_DEFINE="$t"
  61    ;;
  62  esac
  63 ], [
  64  use_sysroot=no
  65  TARGET_SYSTEM_ROOT=
  66  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  67 ])
  68 AC_SUBST(use_sysroot)
  69 AC_SUBST(TARGET_SYSTEM_ROOT)
  70 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  71
  72 dnl Use --enable-gold to decide if this linker should be the default.
  73 dnl "install_as_default" is set to false if gold is the default linker.
  74 dnl "installed_linker" is the installed BFD linker name.
  75 AC_ARG_ENABLE(gold,
  76 [[  --enable-gold[=ARG]     build gold [ARG={both}[/{gold,ld}]]]],
  77 [case "${enableval}" in
  78  yes|both/gold)
  79    install_as_default=no
  80    installed_linker=ld.bfd
  81    ;;
  82  both|both/ld)
  83    install_as_default=yes
  84    installed_linker=ld.bfd
  85    ;;
  86  *)
  87    AC_MSG_ERROR([invalid --enable-gold argument])
  88    ;;
  89  esac],
  90 [install_as_default=ld
  91  installed_linker=ld])
  92 AC_SUBST(install_as_default)
  93 AC_SUBST(installed_linker)
  94
  95 AC_ARG_ENABLE([got],
  96 AS_HELP_STRING([--enable-got=<type>],
  97                [GOT handling scheme (target, single, negative, multigot)]),
  98 [case "${enableval}" in
  99   target | single | negative | multigot)  got_handling=$enableval ;;
 100   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 101 esac],
 102 [got_handling=target])
 103
 104 case "${got_handling}" in
 105   target)
 106     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 107               [Define to choose default GOT handling scheme]) ;;
 108   single)
 109     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 110               [Define to choose default GOT handling scheme]) ;;
 111   negative)
 112     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 113               [Define to choose default GOT handling scheme]) ;;
 114   multigot)
 115     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 116               [Define to choose default GOT handling scheme]) ;;
 117   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 118 esac
 119
 120 AM_BINUTILS_WARNINGS
 121
 122 AC_CONFIG_HEADERS([config.h:config.in])
 123
 124 if test -z "$target" ; then
 125     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 126 fi
 127 if test -z "$host" ; then
 128     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 129 fi
 130
 131 # host-specific stuff:
 132
 133 AC_PROG_CC
 134 AC_GNU_SOURCE
 135 AC_USE_SYSTEM_EXTENSIONS
 136 ACX_LARGEFILE
 137 AC_PROG_INSTALL
 138
 139 LT_INIT
 140
 141 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi id bg"
 142 ZW_GNU_GETTEXT_SISTER_DIR
 143 AM_PO_SUBDIRS
 144
 145 AC_EXEEXT
 146
 147 AC_PROG_YACC
 148 AM_PROG_LEX
 149
 150 AM_MAINTAINER_MODE
 151 AM_CONDITIONAL(GENINSRC_NEVER, false)
 152 ACX_PROG_CMP_IGNORE_INITIAL
 153
 154 . ${srcdir}/configure.host
 155
 156 AC_SUBST(HDEFINES)
 157 AC_SUBST(HOSTING_CRT0)
 158 AC_SUBST(HOSTING_LIBS)
 159 AC_SUBST(NATIVE_LIB_DIRS)
 160
 161 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h sys/param.h)
 162 AC_CHECK_FUNCS(glob mkstemp realpath sbrk waitpid)
 163 AC_HEADER_DIRENT
 164
 165 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 166 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 167 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 168 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 169 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 170 if test $ld_cv_decl_getopt_unistd_h = yes; then
 171   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 172             [Is the prototype for getopt in <unistd.h> in the expected format?])
 173 fi
 174
 175 BFD_BINARY_FOPEN
 176
 177 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 178
 179 # Link in zlib if we can.  This is needed only for the bootstrap tests
 180 # right now, since those tests use libbfd, which depends on zlib.
 181 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 182
 183 # When converting linker scripts into strings for use in emulation
 184 # files, use astring.sed if the compiler supports ANSI string
 185 # concatenation, or ostring.sed otherwise.  This is to support the
 186 # broken Microsoft MSVC compiler, which limits the length of string
 187 # constants, while still supporting pre-ANSI compilers which do not
 188 # support string concatenation.
 189 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 190 AC_CACHE_VAL(ld_cv_string_concatenation,
 191 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 192   ld_cv_string_concatenation=yes,
 193   ld_cv_string_concatenation=no)])
 194 AC_MSG_RESULT($ld_cv_string_concatenation)
 195 if test "$ld_cv_string_concatenation" = "yes"; then
 196   STRINGIFY=astring.sed
 197 else
 198   STRINGIFY=ostring.sed
 199 fi
 200 AC_SUBST(STRINGIFY)
 201
 202 # target-specific stuff:
 203
 204 all_targets=
 205 EMUL=
 206 all_emuls=
 207 all_emul_extras=
 208 all_libpath=
 209
 210 dnl We need to get an arbitrary number of tdir definitions into
 211 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 212 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 213 dnl file.
 214 rm -f tdirs
 215
 216 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 217 do
 218   if test "$targ_alias" = "all"; then
 219     all_targets=true
 220   else
 221     # Canonicalize the secondary target names.
 222     result=`$ac_config_sub $targ_alias 2>/dev/null`
 223     if test -n "$result"; then
 224         targ=$result
 225     else
 226         targ=$targ_alias
 227     fi
 228
 229     . ${srcdir}/configure.tgt
 230
 231     if test "$targ" = "$target"; then
 232       EMUL=$targ_emul
 233     fi
 234
 235     if test x${want64} = xfalse; then
 236       . ${srcdir}/../bfd/config.bfd
 237     fi
 238
 239     if test x${want64} = xtrue; then
 240       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 241       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 242     fi
 243
 244     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 245         case " $all_emuls " in
 246         *" e${i}.o "*) ;;
 247         *)
 248           all_emuls="$all_emuls e${i}.o"
 249           eval result=\$tdir_$i
 250           test -z "$result" && result=$targ_alias
 251           echo tdir_$i=$result >> tdirs
 252           ;;
 253         esac
 254     done
 255
 256     for i in $targ_emul $targ_extra_libpath; do
 257         case " $all_libpath " in
 258         *" ${i} "*) ;;
 259         *)
 260           if test -z "$all_libpath"; then
 261             all_libpath=${i}
 262           else
 263             all_libpath="$all_libpath ${i}"
 264           fi
 265           ;;
 266         esac
 267     done
 268
 269     for i in $targ_extra_ofiles; do
 270         case " $all_emul_extras " in
 271         *" ${i} "*) ;;
 272         *)
 273           all_emul_extras="$all_emul_extras ${i}"
 274           ;;
 275         esac
 276     done
 277   fi
 278 done
 279
 280 AC_SUBST(EMUL)
 281
 282 TDIRS=tdirs
 283 AC_SUBST_FILE(TDIRS)
 284
 285 if test x${all_targets} = xtrue; then
 286   if test x${want64} = xfalse; then
 287     AC_CHECK_SIZEOF(long)
 288     if test "x${ac_cv_sizeof_long}" = "x8"; then
 289       want64=true
 290     fi
 291   fi
 292   if test x${want64} = xtrue; then
 293     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 294   else
 295     EMULATION_OFILES='$(ALL_EMULATIONS)'
 296   fi
 297   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 298 else
 299   EMULATION_OFILES=$all_emuls
 300   EMUL_EXTRA_OFILES=$all_emul_extras
 301 fi
 302 AC_SUBST(EMULATION_OFILES)
 303 AC_SUBST(EMUL_EXTRA_OFILES)
 304 AC_SUBST(LIB_PATH)
 305
 306 EMULATION_LIBPATH=$all_libpath
 307 AC_SUBST(EMULATION_LIBPATH)
 308
 309 if test x${enable_static} = xno; then
 310   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 311 else
 312   TESTBFDLIB="../bfd/.libs/libbfd.a"
 313 fi
 314 AC_SUBST(TESTBFDLIB)
 315
 316 target_vendor=${target_vendor=$host_vendor}
 317 case "$target_vendor" in
 318   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 319   *)  EXTRA_SHLIB_EXTENSION= ;;
 320 esac
 321
 322 case "$target_os" in
 323   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 324 esac
 325
 326 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 327   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 328    [Additional extension a shared object might have.])
 329 fi
 330
 331 dnl Required by html, pdf, install-pdf and install-html
 332 AC_SUBST(datarootdir)
 333 AC_SUBST(docdir)
 334 AC_SUBST(htmldir)
 335 AC_SUBST(pdfdir)
 336
 337 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 338 AC_OUTPUT