ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.13)
   4 AC_INIT(ldmain.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  17 AC_ARG_ENABLE(targets,
  18 [  --enable-targets        alternative target configurations],
  19 [case "${enableval}" in
  20   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  21             ;;
  22   no)       enable_targets= ;;
  23   *)        enable_targets=$enableval ;;
  24 esac])dnl
  25 AC_ARG_ENABLE(64-bit-bfd,
  26 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  27 [case "${enableval}" in
  28   yes)  want64=true  ;;
  29   no)   want64=false ;;
  30   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  31 esac],[want64=false])dnl
  32
  33 AC_ARG_WITH(sysroot,
  34 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  35 [
  36  case ${with_sysroot} in
  37  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  38  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  39  esac
  40
  41  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  42  use_sysroot=yes
  43
  44  if test "x$exec_prefix" = xNONE; then
  45   if test "x$prefix" = xNONE; then
  46    test_prefix=/usr/local
  47   else
  48    test_prefix=$prefix
  49   fi
  50  else
  51   test_prefix=$exec_prefix
  52  fi
  53  case ${TARGET_SYSTEM_ROOT} in
  54  "${test_prefix}"|"${test_prefix}/"*|\
  55  '${exec_prefix}'|'${exec_prefix}/'*)
  56    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  57    TARGET_SYSTEM_ROOT_DEFINE="$t"
  58    ;;
  59  esac
  60 ], [
  61  use_sysroot=no
  62  TARGET_SYSTEM_ROOT=
  63  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  64 ])
  65 AC_SUBST(use_sysroot)
  66 AC_SUBST(TARGET_SYSTEM_ROOT)
  67 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  68
  69 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  70
  71 AC_ARG_ENABLE(werror,
  72   [  --enable-werror    treat compile warnings as errors],
  73   [case "${enableval}" in
  74      yes | y) ERROR_ON_WARNING="yes" ;;
  75      no | n)  ERROR_ON_WARNING="no" ;;
  76      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
  77    esac])
  78
  79 # Enable -Werror by default, suppressing it only for --disable-werror
  80 # or --disable-build-warnings.
  81 if test "${ERROR_ON_WARNING}" != no
  82 then
  83   build_warnings="$build_warnings -Werror"
  84 fi
  85
  86 AC_ARG_ENABLE(build-warnings,
  87 [  --enable-build-warnings enable build-time compiler warnings if gcc is used],
  88 [case "${enableval}" in
  89   yes)  ;;
  90   no)   build_warnings="-w";;
  91   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  92         build_warnings="${build_warnings} ${t}";;
  93   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  94         build_warnings="${t} ${build_warnings}";;
  95   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  96 esac
  97 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  98   echo "Setting warning flags = $build_warnings" 6>&1
  99 fi])dnl
 100 WARN_CFLAGS=""
 101 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
 102     WARN_CFLAGS="${build_warnings}"
 103 fi
 104 AC_SUBST(WARN_CFLAGS)
 105
 106 AM_CONFIG_HEADER(config.h:config.in)
 107
 108 if test -z "$target" ; then
 109     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 110 fi
 111 if test -z "$host" ; then
 112     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 113 fi
 114
 115 # host-specific stuff:
 116
 117 AC_PROG_CC
 118 AC_PROG_INSTALL
 119
 120 ALL_LINGUAS="fr sv tr es da"
 121 CY_GNU_GETTEXT
 122
 123 AC_EXEEXT
 124
 125 AC_PROG_YACC
 126 AM_PROG_LEX
 127
 128 AM_MAINTAINER_MODE
 129
 130 . ${srcdir}/configure.host
 131
 132 AC_SUBST(HDEFINES)
 133 AC_SUBST(HOSTING_CRT0)
 134 AC_SUBST(HOSTING_LIBS)
 135 AC_SUBST(NATIVE_LIB_DIRS)
 136
 137 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h)
 138 AC_CHECK_FUNCS(sbrk realpath glob)
 139 AC_HEADER_DIRENT
 140
 141 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 142 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 143 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 144 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 145 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 146 if test $ld_cv_decl_getopt_unistd_h = yes; then
 147   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 148             [Is the prototype for getopt in <unistd.h> in the expected format?])
 149 fi
 150
 151 BFD_BINARY_FOPEN
 152
 153 BFD_NEED_DECLARATION(strstr)
 154 BFD_NEED_DECLARATION(free)
 155 BFD_NEED_DECLARATION(sbrk)
 156 BFD_NEED_DECLARATION(getenv)
 157 BFD_NEED_DECLARATION(environ)
 158
 159 # When converting linker scripts into strings for use in emulation
 160 # files, use astring.sed if the compiler supports ANSI string
 161 # concatenation, or ostring.sed otherwise.  This is to support the
 162 # broken Microsoft MSVC compiler, which limits the length of string
 163 # constants, while still supporting pre-ANSI compilers which do not
 164 # support string concatenation.
 165 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 166 AC_CACHE_VAL(ld_cv_string_concatenation,
 167 [AC_TRY_COMPILE(,[char *a = "a" "a";],
 168   [ld_cv_string_concatenation=yes],
 169   [ld_cv_string_concatenation=no])])
 170 AC_MSG_RESULT($ld_cv_string_concatenation)
 171 if test "$ld_cv_string_concatenation" = "yes"; then
 172   STRINGIFY=astring.sed
 173 else
 174   STRINGIFY=ostring.sed
 175 fi
 176 AC_SUBST(STRINGIFY)
 177
 178 # target-specific stuff:
 179
 180 all_targets=
 181 EMUL=
 182 all_emuls=
 183 all_emul_extras=
 184 all_libpath=
 185
 186 dnl We need to get an arbitrary number of tdir definitions into
 187 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 188 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 189 dnl file.
 190 rm -f tdirs
 191
 192 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 193 do
 194   if test "$targ_alias" = "all"; then
 195     all_targets=true
 196   else
 197     # Canonicalize the secondary target names.
 198     result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ_alias 2>/dev/null`
 199     if test -n "$result"; then
 200         targ=$result
 201     else
 202         targ=$targ_alias
 203     fi
 204
 205     . ${srcdir}/configure.tgt
 206
 207     if test "$targ" = "$target"; then
 208       EMUL=$targ_emul
 209     fi
 210
 211     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 212         case " $all_emuls " in
 213         *" e${i}.o "*) ;;
 214         *)
 215           all_emuls="$all_emuls e${i}.o"
 216           eval result=\$tdir_$i
 217           test -z "$result" && result=$targ_alias
 218           echo tdir_$i=$result >> tdirs
 219           ;;
 220         esac
 221     done
 222
 223     for i in $targ_emul $targ_extra_libpath; do
 224         case " $all_libpath " in
 225         *" ${i} "*) ;;
 226         *)
 227           if test -z "$all_libpath"; then
 228             all_libpath=${i}
 229           else
 230             all_libpath="$all_libpath ${i}"
 231           fi
 232           ;;
 233         esac
 234     done
 235
 236     for i in $targ_extra_ofiles; do
 237         case " $all_emul_extras " in
 238         *" ${i} "*) ;;
 239         *)
 240           all_emul_extras="$all_emul_extras ${i}"
 241           ;;
 242         esac
 243     done
 244   fi
 245 done
 246
 247 AC_SUBST(EMUL)
 248
 249 TDIRS=tdirs
 250 AC_SUBST_FILE(TDIRS)
 251
 252 dnl FIXME: We will build a 64 bit BFD for a 64 bit host or a 64 bit
 253 dnl target, and in those cases we should also build the 64 bit
 254 dnl emulations.
 255 if test x${all_targets} = xtrue; then
 256   if test x${want64} = xtrue; then
 257     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 258   else
 259     EMULATION_OFILES='$(ALL_EMULATIONS)'
 260   fi
 261   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 262 else
 263   EMULATION_OFILES=$all_emuls
 264   EMUL_EXTRA_OFILES=$all_emul_extras
 265 fi
 266 AC_SUBST(EMULATION_OFILES)
 267 AC_SUBST(EMUL_EXTRA_OFILES)
 268 AC_SUBST(LIB_PATH)
 269
 270 EMULATION_LIBPATH=$all_libpath
 271 AC_SUBST(EMULATION_LIBPATH)
 272
 273 if test x${enable_static} = xno; then
 274   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 275 else
 276   TESTBFDLIB="../bfd/.libs/libbfd.a"
 277 fi
 278 AC_SUBST(TESTBFDLIB)
 279
 280 target_vendor=${target_vendor=$host_vendor}
 281 case "$target_vendor" in
 282   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 283   *)  EXTRA_SHLIB_EXTENSION= ;;
 284 esac
 285
 286 case "$target_os" in
 287   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 288 esac
 289
 290 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 291   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 292    [Additional extension a shared object might have.])
 293 fi
 294
 295 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
 296 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])