ld/scripttempl/elfm68hc12.sc

   1 #
   2 # Unusual variables checked by this code:
   3 #       NOP - four byte opcode for no-op (defaults to 0)
   4 #       DATA_ADDR - if end-of-text-plus-one-page isn't right for data start
   5 #       OTHER_READWRITE_SECTIONS - other than .data .bss .ctors .sdata ...
   6 #               (e.g., .PARISC.global)
   7 #       OTHER_SECTIONS - at the end
   8 #       EXECUTABLE_SYMBOLS - symbols that must be defined for an
   9 #               executable (e.g., _DYNAMIC_LINK)
  10 #       TEXT_START_SYMBOLS - symbols that appear at the start of the
  11 #               .text section.
  12 #       DATA_START_SYMBOLS - symbols that appear at the start of the
  13 #               .data section.
  14 #       OTHER_BSS_SYMBOLS - symbols that appear at the start of the
  15 #               .bss section besides __bss_start.
  16 #       EMBEDDED - whether this is for an embedded system.
  17 #
  18 # When adding sections, do note that the names of some sections are used
  19 # when specifying the start address of the next.
  20 #
  21 test -z "$ENTRY" && ENTRY=_start
  22 test -z "${BIG_OUTPUT_FORMAT}" && BIG_OUTPUT_FORMAT=${OUTPUT_FORMAT}
  23 test -z "${LITTLE_OUTPUT_FORMAT}" && LITTLE_OUTPUT_FORMAT=${OUTPUT_FORMAT}
  24 if [ -z "$MACHINE" ]; then OUTPUT_ARCH=${ARCH}; else OUTPUT_ARCH=${ARCH}:${MACHINE}; fi
  25 test "$LD_FLAG" = "N" && DATA_ADDR=.
  26
  27 CTOR=".ctors ${CONSTRUCTING-0} :
  28   {
  29     ${CONSTRUCTING+ PROVIDE (__CTOR_LIST__ = .); }
  30     ${CONSTRUCTING+${CTOR_START}}
  31     *(.ctors)
  32     /* We don't want to include the .ctor section from
  33        from the crtend.o file until after the sorted ctors.
  34        The .ctor section from the crtend file contains the
  35        end of ctors marker and it must be last
  36
  37     KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
  38     KEEP (*(SORT(.ctors.*)))
  39     KEEP (*(.ctors)) */
  40
  41     ${CONSTRUCTING+${CTOR_END}}
  42     ${CONSTRUCTING+ PROVIDE(__CTOR_END__ = .); }
  43   } ${RELOCATING+ > ${TEXT_MEMORY}}"
  44
  45 DTOR="  .dtors  ${CONSTRUCTING-0} :
  46   {
  47     ${CONSTRUCTING+ PROVIDE(__DTOR_LIST__ = .); }
  48     *(.dtors)
  49     /*
  50     KEEP (*crtbegin.o(.dtors))
  51     KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
  52     KEEP (*(SORT(.dtors.*)))
  53     KEEP (*(.dtors)) */
  54     ${CONSTRUCTING+ PROVIDE(__DTOR_END__ = .); }
  55   } ${RELOCATING+ > ${TEXT_MEMORY}}"
  56
  57
  58 VECTORS="
  59   /* If the 'vectors_addr' symbol is defined, it indicates the start address
  60      of interrupt vectors.  This depends on the 68HC11 operating mode:
  61
  62                         Addr
  63      Single chip        0xffc0
  64      Extended mode      0xffc0
  65      Bootstrap          0x00c0
  66      Test               0xbfc0
  67
  68      In general, the vectors address is 0xffc0.  This can be overriden
  69      with the '-defsym vectors_addr=0xbfc0' ld option.
  70
  71      Note: for the bootstrap mode, the interrupt vectors are at 0xbfc0 but
  72      they are redirected to 0x00c0 by the internal PROM.  Application's vectors
  73      must also consist of jump instructions (see Motorola's manual).  */
  74
  75   PROVIDE (_vectors_addr = DEFINED (vectors_addr) ? vectors_addr : 0xffc0);
  76   .vectors DEFINED (vectors_addr) ? vectors_addr : 0xffc0 :
  77   {
  78     *(.vectors)
  79   }"
  80
  81 #
  82 # We provide two emulations: a fixed on that defines some memory banks
  83 # and a configurable one that includes a user provided memory definition.
  84 #
  85 case $GENERIC_BOARD in
  86   yes|1|YES)
  87         MEMORY_DEF="
  88 /* Get memory banks definition from some user configuration file.
  89    This file must be located in some linker directory (search path
  90    with -L<dir>). See fixed memory banks emulation script.  */
  91 INCLUDE memory.x;
  92 "
  93         ;;
  94   *)
  95 MEMORY_DEF="
  96 /* Fixed definition of the available memory banks.
  97    See generic emulation script for a user defined configuration.  */
  98 MEMORY
  99 {
 100   page0 (rwx) : ORIGIN = 0x0, LENGTH = 256
 101   text  (rx)  : ORIGIN = ${ROM_START_ADDR}, LENGTH = ${ROM_SIZE}
 102   data        : ORIGIN = ${RAM_START_ADDR}, LENGTH = ${RAM_SIZE}
 103 }
 104
 105 /* Setup the stack on the top of the data memory bank.  */
 106 PROVIDE (_stack = ${RAM_START_ADDR} + ${RAM_SIZE} - 1);
 107 "
 108         ;;
 109 esac
 110
 111 STARTUP_CODE="
 112     /* Startup code.  */
 113     *(.install0)        /* Section should setup the stack pointer.  */
 114     *(.install1)        /* Place holder for applications.  */
 115     *(.install2)        /* Optional installation of data sections in RAM.  */
 116     *(.install3)        /* Place holder for applications.  */
 117     *(.install4)        /* Section that calls the main.  */
 118 "
 119
 120 FINISH_CODE="
 121     /* Finish code.  */
 122     *(.fini0)           /* Beginning of finish code (_exit symbol).  */
 123     *(.fini1)           /* Place holder for applications.  */
 124     *(.fini2)           /* C++ destructors.  */
 125     *(.fini3)           /* Place holder for applications.  */
 126     *(.fini4)           /* Runtime exit.  */
 127 "
 128
 129 PRE_COMPUTE_DATA_SIZE="
 130 /* SCz: this does not work yet... This is supposed to force the loading
 131    of _map_data.o (from libgcc.a) when the .data section is not empty.
 132    By doing so, this should bring the code that copies the .data section
 133    from ROM to RAM at init time.
 134
 135   ___pre_comp_data_size = SIZEOF(.data);
 136   __install_data_sections = ___pre_comp_data_size > 0 ?
 137                 __map_data_sections : 0;
 138 */
 139 "
 140
 141 INSTALL_RELOC="
 142   .install0 0 : { *(.install0) }
 143   .install1 0 : { *(.install1) }
 144   .install2 0 : { *(.install2) }
 145   .install3 0 : { *(.install3) }
 146   .install4 0 : { *(.install4) }
 147 "
 148
 149 FINISH_RELOC="
 150   .fini0 0 : { *(.fini0) }
 151   .fini1 0 : { *(.fini1) }
 152   .fini2 0 : { *(.fini2) }
 153   .fini3 0 : { *(.fini3) }
 154   .fini4 0 : { *(.fini4) }
 155 "
 156
 157 BSS_DATA_RELOC="
 158   .data1 0 : { *(.data1) }
 159
 160   /* We want the small data sections together, so single-instruction offsets
 161      can access them all, and initialized data all before uninitialized, so
 162      we can shorten the on-disk segment size.  */
 163   .sdata   0 : { *(.sdata) }
 164   .sbss    0 : { *(.sbss) }
 165   .scommon 0 : { *(.scommon) }
 166 "
 167
 168 SOFT_REGS_RELOC="
 169   .softregs 0 : { *(.softregs) }
 170 "
 171
 172 cat <<EOF
 173 ${RELOCATING+/* Linker script for 68HC12 executable (PROM).  */}
 174 ${RELOCATING-/* Linker script for 68HC12 object file (ld -r).  */}
 175
 176 OUTPUT_FORMAT("${OUTPUT_FORMAT}", "${BIG_OUTPUT_FORMAT}",
 177               "${LITTLE_OUTPUT_FORMAT}")
 178 OUTPUT_ARCH(${OUTPUT_ARCH})
 179 ENTRY(${ENTRY})
 180
 181 ${RELOCATING+${LIB_SEARCH_DIRS}}
 182 ${RELOCATING+${EXECUTABLE_SYMBOLS}}
 183 ${RELOCATING+${MEMORY_DEF}}
 184
 185 SECTIONS
 186 {
 187   .hash        ${RELOCATING-0} : { *(.hash)             }
 188   .dynsym      ${RELOCATING-0} : { *(.dynsym)           }
 189   .dynstr      ${RELOCATING-0} : { *(.dynstr)           }
 190   .gnu.version          ${RELOCATING-0} : { *(.gnu.version) }
 191   .gnu.version_d        ${RELOCATING-0} : { *(.gnu.version_d) }
 192   .gnu.version_r        ${RELOCATING-0} : { *(.gnu.version_r) }
 193
 194   .rel.text    ${RELOCATING-0} :
 195     {
 196       *(.rel.text)
 197       ${RELOCATING+*(.rel.text.*)}
 198       ${RELOCATING+*(.rel.gnu.linkonce.t.*)}
 199     }
 200   .rela.text   ${RELOCATING-0} :
 201     {
 202       *(.rela.text)
 203       ${RELOCATING+*(.rela.text.*)}
 204       ${RELOCATING+*(.rela.gnu.linkonce.t.*)}
 205     }
 206   .rel.data    ${RELOCATING-0} :
 207     {
 208       *(.rel.data)
 209       ${RELOCATING+*(.rel.data.*)}
 210       ${RELOCATING+*(.rel.gnu.linkonce.d.*)}
 211     }
 212   .rela.data   ${RELOCATING-0} :
 213     {
 214       *(.rela.data)
 215       ${RELOCATING+*(.rela.data.*)}
 216       ${RELOCATING+*(.rela.gnu.linkonce.d.*)}
 217     }
 218   .rel.rodata  ${RELOCATING-0} :
 219     {
 220       *(.rel.rodata)
 221       ${RELOCATING+*(.rel.rodata.*)}
 222       ${RELOCATING+*(.rel.gnu.linkonce.r.*)}
 223     }
 224   .rela.rodata ${RELOCATING-0} :
 225     {
 226       *(.rela.rodata)
 227       ${RELOCATING+*(.rela.rodata.*)}
 228       ${RELOCATING+*(.rela.gnu.linkonce.r.*)}
 229     }
 230   .rel.sdata   ${RELOCATING-0} :
 231     {
 232       *(.rel.sdata)
 233       ${RELOCATING+*(.rel.sdata.*)}
 234       ${RELOCATING+*(.rel.gnu.linkonce.s.*)}
 235     }
 236   .rela.sdata   ${RELOCATING-0} :
 237     {
 238       *(.rela.sdata)
 239       ${RELOCATING+*(.rela.sdata.*)}
 240       ${RELOCATING+*(.rela.gnu.linkonce.s.*)}
 241     }
 242   .rel.sbss    ${RELOCATING-0} :
 243     {
 244       *(.rel.sbss)
 245       ${RELOCATING+*(.rel.sbss.*)}
 246       ${RELOCATING+*(.rel.gnu.linkonce.sb.*)}
 247     }
 248   .rela.sbss   ${RELOCATING-0} :
 249     {
 250       *(.rela.sbss)
 251       ${RELOCATING+*(.rela.sbss.*)}
 252       ${RELOCATING+*(.rel.gnu.linkonce.sb.*)}
 253     }
 254   .rel.bss     ${RELOCATING-0} :
 255     {
 256       *(.rel.bss)
 257       ${RELOCATING+*(.rel.bss.*)}
 258       ${RELOCATING+*(.rel.gnu.linkonce.b.*)}
 259     }
 260   .rela.bss    ${RELOCATING-0} :
 261     {
 262       *(.rela.bss)
 263       ${RELOCATING+*(.rela.bss.*)}
 264       ${RELOCATING+*(.rela.gnu.linkonce.b.*)}
 265     }
 266   .rela.stext           ${RELOCATING-0} : { *(.rela.stest) }
 267   .rela.etext           ${RELOCATING-0} : { *(.rela.etest) }
 268   .rela.sdata           ${RELOCATING-0} : { *(.rela.sdata) }
 269   .rela.edata           ${RELOCATING-0} : { *(.rela.edata) }
 270   .rela.eit_v           ${RELOCATING-0} : { *(.rela.eit_v) }
 271   .rela.ebss            ${RELOCATING-0} : { *(.rela.ebss) }
 272   .rela.srodata         ${RELOCATING-0} : { *(.rela.srodata) }
 273   .rela.erodata         ${RELOCATING-0} : { *(.rela.erodata) }
 274   .rela.got             ${RELOCATING-0} : { *(.rela.got) }
 275   .rela.ctors           ${RELOCATING-0} : { *(.rela.ctors) }
 276   .rela.dtors           ${RELOCATING-0} : { *(.rela.dtors) }
 277   .rela.init            ${RELOCATING-0} : { *(.rela.init) }
 278   .rela.fini            ${RELOCATING-0} : { *(.rela.fini) }
 279   .rela.plt             ${RELOCATING-0} : { *(.rela.plt) }
 280
 281   .rel.stext            ${RELOCATING-0} : { *(.rel.stest) }
 282   .rel.etext            ${RELOCATING-0} : { *(.rel.etest) }
 283   .rel.sdata            ${RELOCATING-0} : { *(.rel.sdata) }
 284   .rel.edata            ${RELOCATING-0} : { *(.rel.edata) }
 285   .rel.ebss             ${RELOCATING-0} : { *(.rel.ebss) }
 286   .rel.eit_v            ${RELOCATING-0} : { *(.rel.eit_v) }
 287   .rel.srodata          ${RELOCATING-0} : { *(.rel.srodata) }
 288   .rel.erodata          ${RELOCATING-0} : { *(.rel.erodata) }
 289   .rel.got              ${RELOCATING-0} : { *(.rel.got) }
 290   .rel.ctors            ${RELOCATING-0} : { *(.rel.ctors) }
 291   .rel.dtors            ${RELOCATING-0} : { *(.rel.dtors) }
 292   .rel.init             ${RELOCATING-0} : { *(.rel.init) }
 293   .rel.fini             ${RELOCATING-0} : { *(.rel.fini) }
 294   .rel.plt              ${RELOCATING-0} : { *(.rel.plt) }
 295
 296   /* Concatenate .page0 sections.  Put them in the page0 memory bank
 297      unless we are creating a relocatable file.  */
 298   .page0 :
 299   {
 300     *(.page0)
 301   } ${RELOCATING+ > page0}
 302
 303   /* Start of text section.  */
 304   .stext ${RELOCATING-0} :
 305   {
 306     *(.stext)
 307   } ${RELOCATING+ > ${TEXT_MEMORY}}
 308
 309   .init ${RELOCATING-0} :
 310   {
 311     *(.init)
 312   } ${RELOCATING+=${NOP-0}}
 313
 314   ${RELOCATING-${INSTALL_RELOC}}
 315   ${RELOCATING-${FINISH_RELOC}}
 316
 317   .text ${RELOCATING-0}:
 318   {
 319     /* Put startup code at beginning so that _start keeps same address.  */
 320     ${RELOCATING+${STARTUP_CODE}}
 321
 322     ${RELOCATING+*(.init)}
 323     *(.text)
 324     ${RELOCATING+*(.text.*)}
 325     /* .gnu.warning sections are handled specially by elf32.em.  */
 326     *(.gnu.warning)
 327     ${RELOCATING+*(.gnu.linkonce.t.*)}
 328
 329     ${RELOCATING+${FINISH_CODE}}
 330
 331     ${RELOCATING+_etext = .;}
 332     ${RELOCATING+PROVIDE (etext = .);}
 333
 334   } ${RELOCATING+ > ${TEXT_MEMORY}}
 335
 336   .eh_frame ${RELOCATING-0} :
 337   {
 338     KEEP (*(.eh_frame))
 339   } ${RELOCATING+ > ${TEXT_MEMORY}}
 340
 341   .rodata  ${RELOCATING-0} :
 342   {
 343     *(.rodata)
 344     ${RELOCATING+*(.rodata.*)}
 345     ${RELOCATING+*(.gnu.linkonce.r*)}
 346   } ${RELOCATING+ > ${TEXT_MEMORY}}
 347
 348   .rodata1 ${RELOCATING-0} :
 349   {
 350     *(.rodata1)
 351   } ${RELOCATING+ > ${TEXT_MEMORY}}
 352
 353   /* Constructor and destructor tables are in ROM.  */
 354   ${RELOCATING+${CTOR}}
 355   ${RELOCATING+${DTOR}}
 356
 357   .jcr ${RELOCATING-0} :
 358   {
 359     KEEP (*(.jcr))
 360   } ${RELOCATING+ > ${TEXT_MEMORY}}
 361
 362   /* Start of the data section image in ROM.  */
 363   ${RELOCATING+__data_image = .;}
 364   ${RELOCATING+PROVIDE (__data_image = .);}
 365
 366   /* All read-only sections that normally go in PROM must be above.
 367      We construct the DATA image section in PROM at end of all these
 368      read-only sections.  The data image must be copied at init time.
 369      Refer to GNU ld, Section 3.6.8.2 Output Section LMA.  */
 370   .data  ${RELOCATING-0} : ${RELOCATING+AT (__data_image)}
 371   {
 372     ${RELOCATING+__data_section_start = .;}
 373     ${RELOCATING+PROVIDE (__data_section_start = .);}
 374
 375     ${RELOCATING+${DATA_START_SYMBOLS}}
 376     ${RELOCATING+*(.sdata)}
 377     *(.data)
 378     ${RELOCATING+*(.data.*)}
 379     ${RELOCATING+*(.data1)}
 380     ${RELOCATING+*(.gnu.linkonce.d.*)}
 381     ${CONSTRUCTING+CONSTRUCTORS}
 382
 383     ${RELOCATING+_edata  =  .;}
 384     ${RELOCATING+PROVIDE (edata = .);}
 385   } ${RELOCATING+ > ${DATA_MEMORY}}
 386
 387   ${RELOCATING+__data_section_size = SIZEOF(.data);}
 388   ${RELOCATING+PROVIDE (__data_section_size = SIZEOF(.data));}
 389   ${RELOCATING+__data_image_end = __data_image + __data_section_size;}
 390
 391   ${RELOCATING+${PRE_COMPUTE_DATA_SIZE}}
 392
 393   /* .install ${RELOCATING-0}:
 394   {
 395     . = _data_image_end;
 396   } ${RELOCATING+ > ${TEXT_MEMORY}} */
 397
 398   /* Relocation for some bss and data sections.  */
 399   ${RELOCATING-${BSS_DATA_RELOC}}
 400   ${RELOCATING-${SOFT_REGS_RELOC}}
 401
 402   .bss ${RELOCATING-0} :
 403   {
 404     ${RELOCATING+__bss_start = .;}
 405     ${RELOCATING+*(.softregs)}
 406     ${RELOCATING+*(.sbss)}
 407     ${RELOCATING+*(.scommon)}
 408
 409     *(.dynbss)
 410     *(.bss)
 411     ${RELOCATING+*(.bss.*)}
 412     ${RELOCATING+*(.gnu.linkonce.b.*)}
 413     *(COMMON)
 414     ${RELOCATING+PROVIDE (_end = .);}
 415   } ${RELOCATING+ > ${DATA_MEMORY}}
 416   ${RELOCATING+__bss_size = SIZEOF(.bss);}
 417   ${RELOCATING+PROVIDE (__bss_size = SIZEOF(.bss));}
 418
 419   .eeprom ${RELOCATING-0} :
 420   {
 421     *(.eeprom)
 422     *(.eeprom.*)
 423   } ${RELOCATING+ > ${EEPROM_MEMORY}}
 424
 425   ${RELOCATING+${VECTORS}}
 426
 427   /* Stabs debugging sections.  */
 428   .stab          0 : { *(.stab) }
 429   .stabstr       0 : { *(.stabstr) }
 430   .stab.excl     0 : { *(.stab.excl) }
 431   .stab.exclstr  0 : { *(.stab.exclstr) }
 432   .stab.index    0 : { *(.stab.index) }
 433   .stab.indexstr 0 : { *(.stab.indexstr) }
 434
 435   .comment       0 : { *(.comment) }
 436
 437   /* DWARF debug sections.
 438      Symbols in the DWARF debugging sections are relative to the beginning
 439      of the section so we begin them at 0.
 440      Treatment of DWARF debug section must be at end of the linker
 441      script to avoid problems when there are undefined symbols. It's necessary
 442      to avoid that the DWARF section is relocated before such undefined
 443      symbols are found.  */
 444
 445   /* DWARF 1 */
 446   .debug         0 : { *(.debug) }
 447   .line          0 : { *(.line) }
 448
 449   /* GNU DWARF 1 extensions */
 450   .debug_srcinfo 0 : { *(.debug_srcinfo) }
 451   .debug_sfnames 0 : { *(.debug_sfnames) }
 452
 453   /* DWARF 1.1 and DWARF 2 */
 454   .debug_aranges  0 : { *(.debug_aranges) }
 455   .debug_pubnames 0 : { *(.debug_pubnames) }
 456
 457   /* DWARF 2 */
 458   .debug_info     0 : { *(.debug_info) *(.gnu.linkonce.wi.*) }
 459   .debug_abbrev   0 : { *(.debug_abbrev) }
 460   .debug_line     0 : { *(.debug_line) }
 461   .debug_frame    0 : { *(.debug_frame) }
 462   .debug_str      0 : { *(.debug_str) }
 463   .debug_loc      0 : { *(.debug_loc) }
 464   .debug_macinfo  0 : { *(.debug_macinfo) }
 465 }
 466 EOF