libbacktrace/configure.ac

   1 # configure.ac -- Backtrace configure script.
   2 # Copyright (C) 2012-2020 Free Software Foundation, Inc.
   3
   4 # Redistribution and use in source and binary forms, with or without
   5 # modification, are permitted provided that the following conditions are
   6 # met:
   7
   8 #     (1) Redistributions of source code must retain the above copyright
   9 #     notice, this list of conditions and the following disclaimer.
  10
  11 #     (2) Redistributions in binary form must reproduce the above copyright
  12 #     notice, this list of conditions and the following disclaimer in
  13 #     the documentation and/or other materials provided with the
  14 #     distribution.
  15
  16 #     (3) The name of the author may not be used to
  17 #     endorse or promote products derived from this software without
  18 #     specific prior written permission.
  19
  20 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  21 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  22 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  23 # DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT,
  24 # INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  25 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  26 # SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
  28 # STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING
  29 # IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  30 # POSSIBILITY OF SUCH DAMAGE.
  31
  32 AC_INIT(package-unused, version-unused,, libbacktrace)
  33 AC_CONFIG_SRCDIR(backtrace.h)
  34 AC_CONFIG_HEADER(config.h)
  35
  36 if test -n "${with_target_subdir}"; then
  37   AM_ENABLE_MULTILIB(, ..)
  38 fi
  39
  40 AC_CANONICAL_SYSTEM
  41 target_alias=${target_alias-$host_alias}
  42
  43 AC_USE_SYSTEM_EXTENSIONS
  44
  45 libtool_VERSION=1:0:0
  46 AC_SUBST(libtool_VERSION)
  47
  48 # 1.11.1: Require that version of automake.
  49 # foreign: Don't require README, INSTALL, NEWS, etc.
  50 # no-define: Don't define PACKAGE and VERSION.
  51 # no-dependencies: Don't generate automatic dependencies.
  52 #    (because it breaks when using bootstrap-lean, since some of the
  53 #    headers are gone at "make install" time).
  54 # -Wall: Issue all automake warnings.
  55 # -Wno-portability: Don't warn about constructs supported by GNU make.
  56 #    (because GCC requires GNU make anyhow).
  57 AM_INIT_AUTOMAKE([1.11.1 foreign no-dist no-define no-dependencies -Wall -Wno-portability])
  58
  59 AM_MAINTAINER_MODE
  60
  61 AC_ARG_WITH(target-subdir,
  62 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  63
  64 # We must force CC to /not/ be precious variables; otherwise
  65 # the wrong, non-multilib-adjusted value will be used in multilibs.
  66 # As a side effect, we have to subst CFLAGS ourselves.
  67 m4_rename([_AC_ARG_VAR_PRECIOUS],[backtrace_PRECIOUS])
  68 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  69 AC_PROG_CC
  70 m4_rename_force([backtrace_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  71
  72 AC_SUBST(CFLAGS)
  73
  74 AC_PROG_RANLIB
  75
  76 AC_PROG_AWK
  77 case "$AWK" in
  78 "") AC_MSG_ERROR([can't build without awk]) ;;
  79 esac
  80
  81 AC_CHECK_PROG(DWZ, dwz, dwz)
  82 AM_CONDITIONAL(HAVE_DWZ, test "$DWZ" != "")
  83
  84 LT_INIT
  85 AM_PROG_LIBTOOL
  86
  87 AC_SYS_LARGEFILE
  88
  89 backtrace_supported=yes
  90
  91 if test -n "${with_target_subdir}"; then
  92   # We are compiling a GCC library.  We can assume that the unwind
  93   # library exists.
  94   BACKTRACE_FILE="backtrace.lo simple.lo"
  95 else
  96   AC_CHECK_HEADER([unwind.h],
  97     [AC_CHECK_FUNC([_Unwind_Backtrace],
  98                    [BACKTRACE_FILE="backtrace.lo simple.lo"],
  99                    [BACKTRACE_FILE="nounwind.lo"
 100                     backtrace_supported=no])],
 101     [BACKTRACE_FILE="nounwind.lo"
 102      backtrace_supported=no])
 103 fi
 104 AC_SUBST(BACKTRACE_FILE)
 105
 106 EXTRA_FLAGS=
 107 if test -n "${with_target_subdir}"; then
 108   EXTRA_FLAGS="-funwind-tables -frandom-seed=\$@"
 109 else
 110   AC_CACHE_CHECK([for -funwind-tables option],
 111     [libbacktrace_cv_c_unwind_tables],
 112     [CFLAGS_hold="$CFLAGS"
 113      CFLAGS="$CFLAGS -funwind-tables"
 114      AC_COMPILE_IFELSE(
 115        [AC_LANG_PROGRAM([static int f() { return 0; }], [return f();])],
 116        [libbacktrace_cv_c_unwind_tables=yes],
 117        [libbacktrace_cv_c_unwind_tables=no])
 118      CFLAGS="$CFLAGS_hold"])
 119   if test "$libbacktrace_cv_c_unwind_tables" = "yes"; then
 120     EXTRA_FLAGS=-funwind-tables
 121   fi
 122   AC_CACHE_CHECK([for -frandom-seed=string option],
 123     [libbacktrace_cv_c_random_seed_string],
 124     [CFLAGS_hold="$CFLAGS"
 125      CFLAGS="$CFLAGS -frandom-seed=conftest.lo"
 126      AC_COMPILE_IFELSE(
 127        [AC_LANG_PROGRAM([], [return 0;])],
 128        [libbacktrace_cv_c_random_seed_string=yes],
 129        [libbacktrace_cv_c_random_seed_string=no])
 130      CFLAGS="$CFLAGS_hold"])
 131   if test "$libbacktrace_cv_c_random_seed_string" = "yes"; then
 132     EXTRA_FLAGS="$EXTRA_FLAGS -frandom-seed=\$@"
 133   fi
 134 fi
 135
 136 if test -n "${with_target_subdir}"; then
 137   # Add CET specific flags is Intel CET is enabled.
 138   GCC_CET_FLAGS(CET_FLAGS)
 139   EXTRA_FLAGS="$EXTRA_FLAGS $CET_FLAGS"
 140 fi
 141 AC_SUBST(EXTRA_FLAGS)
 142
 143 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
 144                           -Wmissing-prototypes -Wold-style-definition \
 145                           -Wmissing-format-attribute -Wcast-qual],
 146                           [WARN_FLAGS])
 147
 148 if test -n "${with_target_subdir}"; then
 149   WARN_FLAGS="$WARN_FLAGS -Werror"
 150 fi
 151
 152 AC_SUBST(WARN_FLAGS)
 153
 154 if test -n "${with_target_subdir}"; then
 155   GCC_CHECK_UNWIND_GETIPINFO
 156 else
 157   ac_save_CFFLAGS="$CFLAGS"
 158   CFLAGS="$CFLAGS -Werror-implicit-function-declaration"
 159   AC_MSG_CHECKING([for _Unwind_GetIPInfo])
 160   AC_LINK_IFELSE(
 161     [AC_LANG_PROGRAM(
 162        [#include "unwind.h"
 163         struct _Unwind_Context *context;
 164         int ip_before_insn = 0;],
 165         [return _Unwind_GetIPInfo (context, &ip_before_insn);])],
 166         [have_unwind_getipinfo=yes], [have_unwind_getipinfo=no])
 167   CFLAGS="$ac_save_CFLAGS"
 168   AC_MSG_RESULT([$have_unwind_getipinfo])
 169   if test "$have_unwind_getipinfo" = "yes"; then
 170     AC_DEFINE(HAVE_GETIPINFO, 1, [Define if _Unwind_GetIPInfo is available.])
 171   fi
 172 fi
 173
 174 # Enable --enable-host-shared.
 175 AC_ARG_ENABLE(host-shared,
 176 [AS_HELP_STRING([--enable-host-shared],
 177                 [build host code as shared libraries])],
 178 [PIC_FLAG=-fPIC], [PIC_FLAG=])
 179 AC_SUBST(PIC_FLAG)
 180
 181 # Test for __sync support.
 182 AC_CACHE_CHECK([__sync extensions],
 183 [libbacktrace_cv_sys_sync],
 184 [if test -n "${with_target_subdir}"; then
 185    case "${host}" in
 186    hppa*-*-hpux*) libbacktrace_cv_sys_sync=no ;;
 187    *) libbacktrace_cv_sys_sync=yes ;;
 188    esac
 189  else
 190    AC_LINK_IFELSE(
 191      [AC_LANG_PROGRAM([int i;],
 192                       [__sync_bool_compare_and_swap (&i, i, i);
 193                        __sync_lock_test_and_set (&i, 1);
 194                        __sync_lock_release (&i);])],
 195      [libbacktrace_cv_sys_sync=yes],
 196      [libbacktrace_cv_sys_sync=no])
 197  fi])
 198 BACKTRACE_SUPPORTS_THREADS=0
 199 if test "$libbacktrace_cv_sys_sync" = "yes"; then
 200   BACKTRACE_SUPPORTS_THREADS=1
 201   AC_DEFINE([HAVE_SYNC_FUNCTIONS], 1,
 202             [Define to 1 if you have the __sync functions])
 203 fi
 204 AC_SUBST(BACKTRACE_SUPPORTS_THREADS)
 205
 206 # Test for __atomic support.
 207 AC_CACHE_CHECK([__atomic extensions],
 208 [libbacktrace_cv_sys_atomic],
 209 [if test -n "${with_target_subdir}"; then
 210    libbacktrace_cv_sys_atomic=yes
 211  else
 212    AC_LINK_IFELSE(
 213      [AC_LANG_PROGRAM([int i;],
 214                       [__atomic_load_n (&i, __ATOMIC_ACQUIRE);
 215                        __atomic_store_n (&i, 1, __ATOMIC_RELEASE);])],
 216      [libbacktrace_cv_sys_atomic=yes],
 217      [libbacktrace_cv_sys_atomic=no])
 218  fi])
 219 if test "$libbacktrace_cv_sys_atomic" = "yes"; then
 220   AC_DEFINE([HAVE_ATOMIC_FUNCTIONS], 1,
 221             [Define to 1 if you have the __atomic functions])
 222 fi
 223
 224 # The library needs to be able to read the executable itself.  Compile
 225 # a file to determine the executable format.  The awk script
 226 # filetype.awk prints out the file type.
 227 AC_CACHE_CHECK([output filetype],
 228 [libbacktrace_cv_sys_filetype],
 229 [filetype=
 230 AC_COMPILE_IFELSE(
 231   [AC_LANG_PROGRAM([int i;], [int j;])],
 232   [filetype=`${AWK} -f $srcdir/filetype.awk conftest.$ac_objext`],
 233   [AC_MSG_FAILURE([compiler failed])])
 234 libbacktrace_cv_sys_filetype=$filetype])
 235
 236 # Match the file type to decide what files to compile.
 237 FORMAT_FILE=
 238 backtrace_supports_data=yes
 239 case "$libbacktrace_cv_sys_filetype" in
 240 elf*) FORMAT_FILE="elf.lo" ;;
 241 macho) FORMAT_FILE="macho.lo" ;;
 242 pecoff) FORMAT_FILE="pecoff.lo"
 243         backtrace_supports_data=no
 244         ;;
 245 xcoff*) FORMAT_FILE="xcoff.lo"
 246         backtrace_supports_data=no
 247         ;;
 248 *) AC_MSG_WARN([could not determine output file type])
 249    FORMAT_FILE="unknown.lo"
 250    backtrace_supported=no
 251    ;;
 252 esac
 253 AC_SUBST(FORMAT_FILE)
 254
 255 # ELF defines.
 256 elfsize=
 257 case "$libbacktrace_cv_sys_filetype" in
 258 elf32) elfsize=32 ;;
 259 elf64) elfsize=64 ;;
 260 *)     elfsize=unused
 261 esac
 262 AC_DEFINE_UNQUOTED([BACKTRACE_ELF_SIZE], [$elfsize], [ELF size: 32 or 64])
 263 AM_CONDITIONAL(HAVE_ELF, test "$FORMAT_FILE" = "elf.lo")
 264
 265 # XCOFF defines.
 266 xcoffsize=
 267 case "$libbacktrace_cv_sys_filetype" in
 268 xcoff32) xcoffsize=32 ;;
 269 xcoff64) xcoffsize=64 ;;
 270 *)       xcoffsize=unused
 271 esac
 272 AC_DEFINE_UNQUOTED([BACKTRACE_XCOFF_SIZE], [$xcoffsize], [XCOFF size: 32 or 64])
 273
 274 BACKTRACE_SUPPORTED=0
 275 if test "$backtrace_supported" = "yes"; then
 276   BACKTRACE_SUPPORTED=1
 277 fi
 278 AC_SUBST(BACKTRACE_SUPPORTED)
 279
 280 BACKTRACE_SUPPORTS_DATA=0
 281 if test "$backtrace_supports_data" = "yes"; then
 282   BACKTRACE_SUPPORTS_DATA=1
 283 fi
 284 AC_SUBST(BACKTRACE_SUPPORTS_DATA)
 285
 286 GCC_HEADER_STDINT(gstdint.h)
 287
 288 AC_CHECK_HEADERS(sys/mman.h)
 289 if test "$ac_cv_header_sys_mman_h" = "no"; then
 290   have_mmap=no
 291 else
 292   if test -n "${with_target_subdir}"; then
 293     # When built as a GCC target library, we can't do a link test.  We
 294     # simply assume that if we have mman.h, we have mmap.
 295     have_mmap=yes
 296     case "${host}" in
 297     *-*-msdosdjgpp)
 298         # DJGPP has sys/man.h, but no mmap
 299         have_mmap=no ;;
 300     esac
 301   else
 302     AC_CHECK_FUNC(mmap, [have_mmap=yes], [have_mmap=no])
 303   fi
 304 fi
 305 if test "$have_mmap" = "no"; then
 306   VIEW_FILE=read.lo
 307   ALLOC_FILE=alloc.lo
 308 else
 309   VIEW_FILE=mmapio.lo
 310   AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 311 #include <sys/mman.h>
 312 #if !defined(MAP_ANONYMOUS) && !defined(MAP_ANON)
 313   #error no MAP_ANONYMOUS
 314 #endif
 315 ])], [ALLOC_FILE=mmap.lo], [ALLOC_FILE=alloc.lo])
 316 fi
 317 AC_SUBST(VIEW_FILE)
 318 AC_SUBST(ALLOC_FILE)
 319
 320 BACKTRACE_USES_MALLOC=0
 321 if test "$ALLOC_FILE" = "alloc.lo"; then
 322   BACKTRACE_USES_MALLOC=1
 323 fi
 324 AC_SUBST(BACKTRACE_USES_MALLOC)
 325
 326 # Check for dl_iterate_phdr.
 327 AC_CHECK_HEADERS(link.h)
 328 if test "$ac_cv_header_link_h" = "no"; then
 329   have_dl_iterate_phdr=no
 330 else
 331   if test -n "${with_target_subdir}"; then
 332     # When built as a GCC target library, we can't do a link test.
 333     AC_EGREP_HEADER([dl_iterate_phdr], [link.h], [have_dl_iterate_phdr=yes],
 334                     [have_dl_iterate_phdr=no])
 335   else
 336     AC_CHECK_FUNC([dl_iterate_phdr], [have_dl_iterate_phdr=yes],
 337                   [have_dl_iterate_phdr=no])
 338   fi
 339 fi
 340 if test "$have_dl_iterate_phdr" = "yes"; then
 341   AC_DEFINE(HAVE_DL_ITERATE_PHDR, 1, [Define if dl_iterate_phdr is available.])
 342 fi
 343
 344 # Check for header file for Mach-O image functions.
 345 AC_CHECK_HEADERS(mach-o/dyld.h)
 346
 347 # Check for loadquery.
 348 AC_CHECK_HEADERS(sys/ldr.h)
 349 if test "$ac_cv_header_sys_ldr_h" = "no"; then
 350   have_loadquery=no
 351 else
 352   if test -n "${with_target_subdir}"; then
 353     # When built as a GCC target library, we can't do a link test.
 354     AC_EGREP_HEADER([loadquery], [sys/ldr.h], [have_loadquery=yes],
 355                     [have_loadquery=no])
 356   else
 357     AC_CHECK_FUNC([loadquery], [have_loadquery=yes],
 358                   [have_loadquery=no])
 359   fi
 360 fi
 361 if test "$have_loadquery" = "yes"; then
 362   AC_DEFINE(HAVE_LOADQUERY, 1, [Define if AIX loadquery is available.])
 363 fi
 364
 365 # Check for the fcntl function.
 366 if test -n "${with_target_subdir}"; then
 367    case "${host}" in
 368    *-*-mingw*) have_fcntl=no ;;
 369    *) have_fcntl=yes ;;
 370    esac
 371 else
 372   AC_CHECK_FUNC(fcntl, [have_fcntl=yes], [have_fcntl=no])
 373 fi
 374 if test "$have_fcntl" = "yes"; then
 375   AC_DEFINE([HAVE_FCNTL], 1,
 376             [Define to 1 if you have the fcntl function])
 377 fi
 378
 379 AC_CHECK_DECLS(strnlen)
 380 AC_CHECK_FUNCS(lstat readlink)
 381
 382 # Check for getexecname function.
 383 if test -n "${with_target_subdir}"; then
 384    case "${host}" in
 385    *-*-solaris2*) have_getexecname=yes ;;
 386    *) have_getexecname=no ;;
 387    esac
 388 else
 389   AC_CHECK_FUNC(getexecname, [have_getexecname=yes], [have_getexecname=no])
 390 fi
 391 if test "$have_getexecname" = "yes"; then
 392   AC_DEFINE(HAVE_GETEXECNAME, 1, [Define if getexecname is available.])
 393 fi
 394
 395 # Check for sysctl definitions.
 396
 397 AC_CACHE_CHECK([for KERN_PROC],
 398 [libbacktrace_cv_proc],
 399 [AC_COMPILE_IFELSE(
 400   [AC_LANG_PROGRAM([
 401 #include <sys/types.h>
 402 #include <sys/sysctl.h>
 403 ], [int mib0 = CTL_KERN; int mib1 = KERN_PROC; int mib2 = KERN_PROC_PATHNAME;])],
 404   [libbacktrace_cv_proc=yes],
 405   [libbacktrace_cv_proc=no])])
 406 if test "$libbacktrace_cv_proc" = "yes"; then
 407   AC_DEFINE([HAVE_KERN_PROC], 1,
 408             [Define to 1 if you have KERN_PROC and KERN_PROC_PATHNAME in <sys/sysctl.h>.])
 409 fi
 410
 411 AC_CACHE_CHECK([for KERN_PROG_ARGS],
 412 [libbacktrace_cv_procargs],
 413 [AC_COMPILE_IFELSE(
 414   [AC_LANG_PROGRAM([
 415 #include <sys/types.h>
 416 #include <sys/sysctl.h>
 417 ], [int mib0 = CTL_KERN; int mib1 = KERN_PROC_ARGS; int mib2 = KERN_PROC_PATHNAME;])],
 418   [libbacktrace_cv_procargs=yes],
 419   [libbacktrace_cv_procargs=no])])
 420 if test "$libbacktrace_cv_procargs" = "yes"; then
 421   AC_DEFINE([HAVE_KERN_PROC_ARGS], 1,
 422             [Define to 1 if you have KERN_PROCARGS and KERN_PROC_PATHNAME in <sys/sysctl.h>.])
 423 fi
 424
 425 # Check for the clock_gettime function.
 426 AC_CHECK_FUNCS(clock_gettime)
 427 clock_gettime_link=
 428 # At least for glibc, clock_gettime is in librt.  But don't
 429 # pull that in if it still doesn't give us the function we want.  This
 430 # test is copied from libgomp, and modified to not link in -lrt as
 431 # we're using this for test timing only.
 432 if test "$ac_cv_func_clock_gettime" = no; then
 433   AC_CHECK_LIB(rt, clock_gettime,
 434     [CLOCK_GETTIME_LINK=-lrt
 435      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 436                [Define to 1 if you have the `clock_gettime' function.])])
 437 fi
 438 AC_SUBST(CLOCK_GETTIME_LINK)
 439
 440 dnl Test whether the compiler supports the -pthread option.
 441 AC_CACHE_CHECK([whether -pthread is supported],
 442 [libgo_cv_lib_pthread],
 443 [CFLAGS_hold=$CFLAGS
 444 CFLAGS="$CFLAGS -pthread"
 445 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 446 [libgo_cv_lib_pthread=yes],
 447 [libgo_cv_lib_pthread=no])
 448 CFLAGS=$CFLAGS_hold])
 449 PTHREAD_CFLAGS=
 450 if test "$libgo_cv_lib_pthread" = yes; then
 451   PTHREAD_CFLAGS=-pthread
 452 fi
 453 AC_SUBST(PTHREAD_CFLAGS)
 454
 455 AM_CONDITIONAL(HAVE_PTHREAD, test "$libgo_cv_lib_pthread" = yes)
 456
 457 dnl Test whether the compiler supports the -gdwarf-5 option.
 458 AC_CACHE_CHECK([whether -gdwarf-5 is supported],
 459 [libbacktrace_cv_lib_dwarf5],
 460 [CFLAGS_hold=$CFLAGS
 461 CFLAGS="$CFLAGS -gdwarf-5"
 462 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 463 [libbacktrace_cv_lib_dwarf5=yes],
 464 [libbacktrace_cv_lib_dwarf5=no])
 465 CFLAGS=$CFLAGS_hold])
 466 AM_CONDITIONAL(HAVE_DWARF5, test "$libbacktrace_cv_lib_dwarf5" = yes)
 467
 468 AC_CHECK_LIB([z], [compress],
 469     [AC_DEFINE(HAVE_ZLIB, 1, [Define if -lz is available.])])
 470 AM_CONDITIONAL(HAVE_ZLIB, test "$ac_cv_lib_z_compress" = yes)
 471
 472 dnl Test whether the linker supports the --compress_debug_sections option.
 473 AC_CACHE_CHECK([whether --compress-debug-sections is supported],
 474 [libgo_cv_ld_compress],
 475 [LDFLAGS_hold=$LDFLAGS
 476 LDFLAGS="$LDFLAGS -Wl,--compress-debug-sections=zlib-gnu"
 477 AC_LINK_IFELSE([AC_LANG_PROGRAM(,)],
 478 [libgo_cv_ld_compress=yes],
 479 [libgo_cv_ld_compress=no])
 480 LDFLAGS=$LDFLAGS_hold])
 481 AM_CONDITIONAL(HAVE_COMPRESSED_DEBUG, test "$libgo_cv_ld_compress" = yes)
 482
 483 AC_ARG_VAR(OBJCOPY, [location of objcopy])
 484 AC_CHECK_PROG(OBJCOPY, objcopy, objcopy,)
 485 AC_CHECK_PROG(READELF, readelf, readelf)
 486 AC_CACHE_CHECK([whether objcopy supports debuglink],
 487 [libbacktrace_cv_objcopy_debuglink],
 488 [if test -n "${with_target_subdir}"; then
 489   libbacktrace_cv_objcopy_debuglink=no
 490 elif ! test -n "${OBJCOPY}"; then
 491   libbacktrace_cv_objcopy_debuglink=no
 492 elif ${OBJCOPY} --add-gnu-debuglink=x /bin/ls /tmp/ls$$; then
 493   rm -f /tmp/ls$$
 494   libbacktrace_cv_objcopy_debuglink=yes
 495 else
 496   libbacktrace_cv_objcopy_debuglink=no
 497 fi])
 498 AM_CONDITIONAL(HAVE_OBJCOPY_DEBUGLINK, test "$libbacktrace_cv_objcopy_debuglink" = yes)
 499
 500 AC_ARG_VAR(DSYMUTIL, [location of dsymutil])
 501 AC_CHECK_PROG(DSYMUTIL, dsymutil, dsymutil)
 502 AM_CONDITIONAL(HAVE_DSYMUTIL, test -n "${DSYMUTIL}")
 503
 504 AC_CACHE_CHECK([whether tests can run],
 505   [libbacktrace_cv_sys_native],
 506   [AC_RUN_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 507      [libbacktrace_cv_sys_native=yes],
 508      [libbacktrace_cv_sys_native=no],
 509      [libbacktrace_cv_sys_native=no])])
 510 AM_CONDITIONAL(NATIVE, test "$libbacktrace_cv_sys_native" = "yes")
 511
 512 if test "${multilib}" = "yes"; then
 513   multilib_arg="--enable-multilib"
 514 else
 515   multilib_arg=
 516 fi
 517
 518 AC_CONFIG_FILES(Makefile backtrace-supported.h)
 519 AC_CONFIG_FILES(install-debuginfo-for-buildid.sh, chmod +x install-debuginfo-for-buildid.sh)
 520
 521 # We need multilib support, but only if configuring for the target.
 522 AC_CONFIG_COMMANDS([default],
 523 [if test -n "$CONFIG_FILES"; then
 524    if test -n "${with_target_subdir}"; then
 525      # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 526      # that multilib installs will end up installed in the correct place.
 527      # The testsuite needs it for multilib-aware ABI baseline files.
 528      # To work around this not being passed down from config-ml.in ->
 529      # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 530      # append it here.  Only modify Makefiles that have just been created.
 531      #
 532      # Also, get rid of this simulated-VPATH thing that automake does.
 533      cat > vpsed << \_EOF
 534   s!`test -f '$<' || echo '$(srcdir)/'`!!
 535 _EOF
 536      for i in $SUBDIRS; do
 537       case $CONFIG_FILES in
 538        *${i}/Makefile*)
 539          #echo "Adding MULTISUBDIR to $i/Makefile"
 540          sed -f vpsed $i/Makefile > tmp
 541          grep '^MULTISUBDIR =' Makefile >> tmp
 542          mv tmp $i/Makefile
 543          ;;
 544       esac
 545      done
 546      rm vpsed
 547    fi
 548  fi
 549 ],
 550 [
 551 # Variables needed in config.status (file generation) which aren't already
 552 # passed by autoconf.
 553 SUBDIRS="$SUBDIRS"
 554 ])
 555
 556 AC_OUTPUT