libbacktrace/configure.ac

   1 # configure.ac -- Backtrace configure script.
   2 # Copyright (C) 2012-2019 Free Software Foundation, Inc.
   3
   4 # Redistribution and use in source and binary forms, with or without
   5 # modification, are permitted provided that the following conditions are
   6 # met:
   7
   8 #     (1) Redistributions of source code must retain the above copyright
   9 #     notice, this list of conditions and the following disclaimer.
  10
  11 #     (2) Redistributions in binary form must reproduce the above copyright
  12 #     notice, this list of conditions and the following disclaimer in
  13 #     the documentation and/or other materials provided with the
  14 #     distribution.
  15
  16 #     (3) The name of the author may not be used to
  17 #     endorse or promote products derived from this software without
  18 #     specific prior written permission.
  19
  20 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  21 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  22 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  23 # DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT,
  24 # INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  25 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  26 # SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
  28 # STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING
  29 # IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  30 # POSSIBILITY OF SUCH DAMAGE.
  31
  32 AC_INIT(package-unused, version-unused,, libbacktrace)
  33 AC_CONFIG_SRCDIR(backtrace.h)
  34 AC_CONFIG_HEADER(config.h)
  35
  36 if test -n "${with_target_subdir}"; then
  37   AM_ENABLE_MULTILIB(, ..)
  38 fi
  39
  40 AC_CANONICAL_SYSTEM
  41 target_alias=${target_alias-$host_alias}
  42
  43 AC_USE_SYSTEM_EXTENSIONS
  44
  45 libtool_VERSION=1:0:0
  46 AC_SUBST(libtool_VERSION)
  47
  48 # 1.11.1: Require that version of automake.
  49 # foreign: Don't require README, INSTALL, NEWS, etc.
  50 # no-define: Don't define PACKAGE and VERSION.
  51 # no-dependencies: Don't generate automatic dependencies.
  52 #    (because it breaks when using bootstrap-lean, since some of the
  53 #    headers are gone at "make install" time).
  54 # -Wall: Issue all automake warnings.
  55 # -Wno-portability: Don't warn about constructs supported by GNU make.
  56 #    (because GCC requires GNU make anyhow).
  57 AM_INIT_AUTOMAKE([1.11.1 foreign no-dist no-define no-dependencies -Wall -Wno-portability])
  58
  59 AM_MAINTAINER_MODE
  60
  61 AC_ARG_WITH(target-subdir,
  62 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  63
  64 # We must force CC to /not/ be precious variables; otherwise
  65 # the wrong, non-multilib-adjusted value will be used in multilibs.
  66 # As a side effect, we have to subst CFLAGS ourselves.
  67 m4_rename([_AC_ARG_VAR_PRECIOUS],[backtrace_PRECIOUS])
  68 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  69 AC_PROG_CC
  70 m4_rename_force([backtrace_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  71
  72 AC_SUBST(CFLAGS)
  73
  74 AC_PROG_RANLIB
  75
  76 AC_PROG_AWK
  77 case "$AWK" in
  78 "") AC_MSG_ERROR([can't build without awk]) ;;
  79 esac
  80
  81 AC_CHECK_PROG(DWZ, dwz, dwz)
  82 AM_CONDITIONAL(HAVE_DWZ, test "$DWZ" != "")
  83
  84 LT_INIT
  85 AM_PROG_LIBTOOL
  86
  87 AC_SYS_LARGEFILE
  88
  89 backtrace_supported=yes
  90
  91 if test -n "${with_target_subdir}"; then
  92   # We are compiling a GCC library.  We can assume that the unwind
  93   # library exists.
  94   BACKTRACE_FILE="backtrace.lo simple.lo"
  95 else
  96   AC_CHECK_HEADER([unwind.h],
  97     [AC_CHECK_FUNC([_Unwind_Backtrace],
  98                    [BACKTRACE_FILE="backtrace.lo simple.lo"],
  99                    [BACKTRACE_FILE="nounwind.lo"
 100                     backtrace_supported=no])],
 101     [BACKTRACE_FILE="nounwind.lo"
 102      backtrace_supported=no])
 103 fi
 104 AC_SUBST(BACKTRACE_FILE)
 105
 106 EXTRA_FLAGS=
 107 if test -n "${with_target_subdir}"; then
 108   EXTRA_FLAGS="-funwind-tables -frandom-seed=\$@"
 109 else
 110   AC_CACHE_CHECK([for -funwind-tables option],
 111     [libbacktrace_cv_c_unwind_tables],
 112     [CFLAGS_hold="$CFLAGS"
 113      CFLAGS="$CFLAGS -funwind-tables"
 114      AC_COMPILE_IFELSE(
 115        [AC_LANG_PROGRAM([static int f() { return 0; }], [return f();])],
 116        [libbacktrace_cv_c_unwind_tables=yes],
 117        [libbacktrace_cv_c_unwind_tables=no])
 118      CFLAGS="$CFLAGS_hold"])
 119   if test "$libbacktrace_cv_c_unwind_tables" = "yes"; then
 120     EXTRA_FLAGS=-funwind-tables
 121   fi
 122   AC_CACHE_CHECK([for -frandom-seed=string option],
 123     [libbacktrace_cv_c_random_seed_string],
 124     [CFLAGS_hold="$CFLAGS"
 125      CFLAGS="$CFLAGS -frandom-seed=conftest.lo"
 126      AC_COMPILE_IFELSE(
 127        [AC_LANG_PROGRAM([], [return 0;])],
 128        [libbacktrace_cv_c_random_seed_string=yes],
 129        [libbacktrace_cv_c_random_seed_string=no])
 130      CFLAGS="$CFLAGS_hold"])
 131   if test "$libbacktrace_cv_c_random_seed_string" = "yes"; then
 132     EXTRA_FLAGS="$EXTRA_FLAGS -frandom-seed=\$@"
 133   fi
 134 fi
 135
 136 if test -n "${with_target_subdir}"; then
 137   # Add CET specific flags is Intel CET is enabled.
 138   GCC_CET_FLAGS(CET_FLAGS)
 139   EXTRA_FLAGS="$EXTRA_FLAGS $CET_FLAGS"
 140 fi
 141 AC_SUBST(EXTRA_FLAGS)
 142
 143 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
 144                           -Wmissing-prototypes -Wold-style-definition \
 145                           -Wmissing-format-attribute -Wcast-qual],
 146                           [WARN_FLAGS])
 147
 148 if test -n "${with_target_subdir}"; then
 149   WARN_FLAGS="$WARN_FLAGS -Werror"
 150 fi
 151
 152 AC_SUBST(WARN_FLAGS)
 153
 154 if test -n "${with_target_subdir}"; then
 155   GCC_CHECK_UNWIND_GETIPINFO
 156 else
 157   ac_save_CFFLAGS="$CFLAGS"
 158   CFLAGS="$CFLAGS -Werror-implicit-function-declaration"
 159   AC_MSG_CHECKING([for _Unwind_GetIPInfo])
 160   AC_LINK_IFELSE(
 161     [AC_LANG_PROGRAM(
 162        [#include "unwind.h"
 163         struct _Unwind_Context *context;
 164         int ip_before_insn = 0;],
 165         [return _Unwind_GetIPInfo (context, &ip_before_insn);])],
 166         [have_unwind_getipinfo=yes], [have_unwind_getipinfo=no])
 167   CFLAGS="$ac_save_CFLAGS"
 168   AC_MSG_RESULT([$have_unwind_getipinfo])
 169   if test "$have_unwind_getipinfo" = "yes"; then
 170     AC_DEFINE(HAVE_GETIPINFO, 1, [Define if _Unwind_GetIPInfo is available.])
 171   fi
 172 fi
 173
 174 # Enable --enable-host-shared.
 175 AC_ARG_ENABLE(host-shared,
 176 [AS_HELP_STRING([--enable-host-shared],
 177                 [build host code as shared libraries])],
 178 [PIC_FLAG=-fPIC], [PIC_FLAG=])
 179 AC_SUBST(PIC_FLAG)
 180
 181 # Test for __sync support.
 182 AC_CACHE_CHECK([__sync extensions],
 183 [libbacktrace_cv_sys_sync],
 184 [if test -n "${with_target_subdir}"; then
 185    case "${host}" in
 186    hppa*-*-hpux*) libbacktrace_cv_sys_sync=no ;;
 187    *) libbacktrace_cv_sys_sync=yes ;;
 188    esac
 189  else
 190    AC_LINK_IFELSE(
 191      [AC_LANG_PROGRAM([int i;],
 192                       [__sync_bool_compare_and_swap (&i, i, i);
 193                        __sync_lock_test_and_set (&i, 1);
 194                        __sync_lock_release (&i);])],
 195      [libbacktrace_cv_sys_sync=yes],
 196      [libbacktrace_cv_sys_sync=no])
 197  fi])
 198 BACKTRACE_SUPPORTS_THREADS=0
 199 if test "$libbacktrace_cv_sys_sync" = "yes"; then
 200   BACKTRACE_SUPPORTS_THREADS=1
 201   AC_DEFINE([HAVE_SYNC_FUNCTIONS], 1,
 202             [Define to 1 if you have the __sync functions])
 203 fi
 204 AC_SUBST(BACKTRACE_SUPPORTS_THREADS)
 205
 206 # Test for __atomic support.
 207 AC_CACHE_CHECK([__atomic extensions],
 208 [libbacktrace_cv_sys_atomic],
 209 [if test -n "${with_target_subdir}"; then
 210    libbacktrace_cv_sys_atomic=yes
 211  else
 212    AC_LINK_IFELSE(
 213      [AC_LANG_PROGRAM([int i;],
 214                       [__atomic_load_n (&i, __ATOMIC_ACQUIRE);
 215                        __atomic_store_n (&i, 1, __ATOMIC_RELEASE);])],
 216      [libbacktrace_cv_sys_atomic=yes],
 217      [libbacktrace_cv_sys_atomic=no])
 218  fi])
 219 if test "$libbacktrace_cv_sys_atomic" = "yes"; then
 220   AC_DEFINE([HAVE_ATOMIC_FUNCTIONS], 1,
 221             [Define to 1 if you have the __atomic functions])
 222 fi
 223
 224 # The library needs to be able to read the executable itself.  Compile
 225 # a file to determine the executable format.  The awk script
 226 # filetype.awk prints out the file type.
 227 AC_CACHE_CHECK([output filetype],
 228 [libbacktrace_cv_sys_filetype],
 229 [filetype=
 230 AC_COMPILE_IFELSE(
 231   [AC_LANG_PROGRAM([int i;], [int j;])],
 232   [filetype=`${AWK} -f $srcdir/filetype.awk conftest.$ac_objext`],
 233   [AC_MSG_FAILURE([compiler failed])])
 234 libbacktrace_cv_sys_filetype=$filetype])
 235
 236 # Match the file type to decide what files to compile.
 237 FORMAT_FILE=
 238 backtrace_supports_data=yes
 239 case "$libbacktrace_cv_sys_filetype" in
 240 elf*) FORMAT_FILE="elf.lo" ;;
 241 pecoff) FORMAT_FILE="pecoff.lo"
 242         backtrace_supports_data=no
 243         ;;
 244 xcoff*) FORMAT_FILE="xcoff.lo"
 245         backtrace_supports_data=no
 246         ;;
 247 *) AC_MSG_WARN([could not determine output file type])
 248    FORMAT_FILE="unknown.lo"
 249    backtrace_supported=no
 250    ;;
 251 esac
 252 AC_SUBST(FORMAT_FILE)
 253
 254 # ELF defines.
 255 elfsize=
 256 case "$libbacktrace_cv_sys_filetype" in
 257 elf32) elfsize=32 ;;
 258 elf64) elfsize=64 ;;
 259 *)     elfsize=unused
 260 esac
 261 AC_DEFINE_UNQUOTED([BACKTRACE_ELF_SIZE], [$elfsize], [ELF size: 32 or 64])
 262 AM_CONDITIONAL(HAVE_ELF, test "$FORMAT_FILE" = "elf.lo")
 263
 264 # XCOFF defines.
 265 xcoffsize=
 266 case "$libbacktrace_cv_sys_filetype" in
 267 xcoff32) xcoffsize=32 ;;
 268 xcoff64) xcoffsize=64 ;;
 269 *)       xcoffsize=unused
 270 esac
 271 AC_DEFINE_UNQUOTED([BACKTRACE_XCOFF_SIZE], [$xcoffsize], [XCOFF size: 32 or 64])
 272
 273 BACKTRACE_SUPPORTED=0
 274 if test "$backtrace_supported" = "yes"; then
 275   BACKTRACE_SUPPORTED=1
 276 fi
 277 AC_SUBST(BACKTRACE_SUPPORTED)
 278
 279 BACKTRACE_SUPPORTS_DATA=0
 280 if test "$backtrace_supports_data" = "yes"; then
 281   BACKTRACE_SUPPORTS_DATA=1
 282 fi
 283 AC_SUBST(BACKTRACE_SUPPORTS_DATA)
 284
 285 GCC_HEADER_STDINT(gstdint.h)
 286
 287 AC_CHECK_HEADERS(sys/mman.h)
 288 if test "$ac_cv_header_sys_mman_h" = "no"; then
 289   have_mmap=no
 290 else
 291   if test -n "${with_target_subdir}"; then
 292     # When built as a GCC target library, we can't do a link test.  We
 293     # simply assume that if we have mman.h, we have mmap.
 294     have_mmap=yes
 295     case "${host}" in
 296     *-*-msdosdjgpp)
 297         # DJGPP has sys/man.h, but no mmap
 298         have_mmap=no ;;
 299     esac
 300   else
 301     AC_CHECK_FUNC(mmap, [have_mmap=yes], [have_mmap=no])
 302   fi
 303 fi
 304 if test "$have_mmap" = "no"; then
 305   VIEW_FILE=read.lo
 306   ALLOC_FILE=alloc.lo
 307 else
 308   VIEW_FILE=mmapio.lo
 309   AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 310 #include <sys/mman.h>
 311 #if !defined(MAP_ANONYMOUS) && !defined(MAP_ANON)
 312   #error no MAP_ANONYMOUS
 313 #endif
 314 ])], [ALLOC_FILE=mmap.lo], [ALLOC_FILE=alloc.lo])
 315 fi
 316 AC_SUBST(VIEW_FILE)
 317 AC_SUBST(ALLOC_FILE)
 318
 319 BACKTRACE_USES_MALLOC=0
 320 if test "$ALLOC_FILE" = "alloc.lo"; then
 321   BACKTRACE_USES_MALLOC=1
 322 fi
 323 AC_SUBST(BACKTRACE_USES_MALLOC)
 324
 325 # Check for dl_iterate_phdr.
 326 AC_CHECK_HEADERS(link.h)
 327 if test "$ac_cv_header_link_h" = "no"; then
 328   have_dl_iterate_phdr=no
 329 else
 330   if test -n "${with_target_subdir}"; then
 331     # When built as a GCC target library, we can't do a link test.
 332     AC_EGREP_HEADER([dl_iterate_phdr], [link.h], [have_dl_iterate_phdr=yes],
 333                     [have_dl_iterate_phdr=no])
 334   else
 335     AC_CHECK_FUNC([dl_iterate_phdr], [have_dl_iterate_phdr=yes],
 336                   [have_dl_iterate_phdr=no])
 337   fi
 338 fi
 339 if test "$have_dl_iterate_phdr" = "yes"; then
 340   AC_DEFINE(HAVE_DL_ITERATE_PHDR, 1, [Define if dl_iterate_phdr is available.])
 341 fi
 342
 343 # Check for loadquery.
 344 AC_CHECK_HEADERS(sys/ldr.h)
 345 if test "$ac_cv_header_sys_ldr_h" = "no"; then
 346   have_loadquery=no
 347 else
 348   if test -n "${with_target_subdir}"; then
 349     # When built as a GCC target library, we can't do a link test.
 350     AC_EGREP_HEADER([loadquery], [sys/ldr.h], [have_loadquery=yes],
 351                     [have_loadquery=no])
 352   else
 353     AC_CHECK_FUNC([loadquery], [have_loadquery=yes],
 354                   [have_loadquery=no])
 355   fi
 356 fi
 357 if test "$have_loadquery" = "yes"; then
 358   AC_DEFINE(HAVE_LOADQUERY, 1, [Define if AIX loadquery is available.])
 359 fi
 360
 361 # Check for the fcntl function.
 362 if test -n "${with_target_subdir}"; then
 363    case "${host}" in
 364    *-*-mingw*) have_fcntl=no ;;
 365    *) have_fcntl=yes ;;
 366    esac
 367 else
 368   AC_CHECK_FUNC(fcntl, [have_fcntl=yes], [have_fcntl=no])
 369 fi
 370 if test "$have_fcntl" = "yes"; then
 371   AC_DEFINE([HAVE_FCNTL], 1,
 372             [Define to 1 if you have the fcntl function])
 373 fi
 374
 375 AC_CHECK_DECLS(strnlen)
 376 AC_CHECK_FUNCS(lstat readlink)
 377
 378 # Check for getexecname function.
 379 if test -n "${with_target_subdir}"; then
 380    case "${host}" in
 381    *-*-solaris2*) have_getexecname=yes ;;
 382    *) have_getexecname=no ;;
 383    esac
 384 else
 385   AC_CHECK_FUNC(getexecname, [have_getexecname=yes], [have_getexecname=no])
 386 fi
 387 if test "$have_getexecname" = "yes"; then
 388   AC_DEFINE(HAVE_GETEXECNAME, 1, [Define if getexecname is available.])
 389 fi
 390
 391 # Check for the clock_gettime function.
 392 AC_CHECK_FUNCS(clock_gettime)
 393 clock_gettime_link=
 394 # At least for glibc, clock_gettime is in librt.  But don't
 395 # pull that in if it still doesn't give us the function we want.  This
 396 # test is copied from libgomp, and modified to not link in -lrt as
 397 # we're using this for test timing only.
 398 if test "$ac_cv_func_clock_gettime" = no; then
 399   AC_CHECK_LIB(rt, clock_gettime,
 400     [CLOCK_GETTIME_LINK=-lrt
 401      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 402                [Define to 1 if you have the `clock_gettime' function.])])
 403 fi
 404 AC_SUBST(CLOCK_GETTIME_LINK)
 405
 406 dnl Test whether the compiler supports the -pthread option.
 407 AC_CACHE_CHECK([whether -pthread is supported],
 408 [libgo_cv_lib_pthread],
 409 [CFLAGS_hold=$CFLAGS
 410 CFLAGS="$CFLAGS -pthread"
 411 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 412 [libgo_cv_lib_pthread=yes],
 413 [libgo_cv_lib_pthread=no])
 414 CFLAGS=$CFLAGS_hold])
 415 PTHREAD_CFLAGS=
 416 if test "$libgo_cv_lib_pthread" = yes; then
 417   PTHREAD_CFLAGS=-pthread
 418 fi
 419 AC_SUBST(PTHREAD_CFLAGS)
 420
 421 AM_CONDITIONAL(HAVE_PTHREAD, test "$libgo_cv_lib_pthread" = yes)
 422
 423 AC_CHECK_LIB([z], [compress],
 424     [AC_DEFINE(HAVE_ZLIB, 1, [Define if -lz is available.])])
 425 AM_CONDITIONAL(HAVE_ZLIB, test "$ac_cv_lib_z_compress" = yes)
 426
 427 dnl Test whether the linker supports the --compress_debug_sections option.
 428 AC_CACHE_CHECK([whether --compress-debug-sections is supported],
 429 [libgo_cv_ld_compress],
 430 [LDFLAGS_hold=$LDFLAGS
 431 LDFLAGS="$LDFLAGS -Wl,--compress-debug-sections=zlib-gnu"
 432 AC_LINK_IFELSE([AC_LANG_PROGRAM(,)],
 433 [libgo_cv_ld_compress=yes],
 434 [libgo_cv_ld_compress=no])
 435 LDFLAGS=$LDFLAGS_hold])
 436 AM_CONDITIONAL(HAVE_COMPRESSED_DEBUG, test "$libgo_cv_ld_compress" = yes)
 437
 438 AC_ARG_VAR(OBJCOPY, [location of objcopy])
 439 AC_CHECK_PROG(OBJCOPY, objcopy, objcopy,)
 440 AC_CHECK_PROG(READELF, readelf, readelf)
 441 AC_CACHE_CHECK([whether objcopy supports debuglink],
 442 [libbacktrace_cv_objcopy_debuglink],
 443 [if test -n "${with_target_subdir}"; then
 444   libbacktrace_cv_objcopy_debuglink=no
 445 elif ${OBJCOPY} --add-gnu-debuglink=x /bin/ls /tmp/ls$$; then
 446   rm -f /tmp/ls$$
 447   libbacktrace_cv_objcopy_debuglink=yes
 448 else
 449   libbacktrace_cv_objcopy_debuglink=no
 450 fi])
 451 AM_CONDITIONAL(HAVE_OBJCOPY_DEBUGLINK, test "$libbacktrace_cv_objcopy_debuglink" = yes)
 452
 453 AC_CACHE_CHECK([whether tests can run],
 454   [libbacktrace_cv_sys_native],
 455   [AC_RUN_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 456      [libbacktrace_cv_sys_native=yes],
 457      [libbacktrace_cv_sys_native=no],
 458      [libbacktrace_cv_sys_native=no])])
 459 AM_CONDITIONAL(NATIVE, test "$libbacktrace_cv_sys_native" = "yes")
 460
 461 if test "${multilib}" = "yes"; then
 462   multilib_arg="--enable-multilib"
 463 else
 464   multilib_arg=
 465 fi
 466
 467 AC_CONFIG_FILES(Makefile backtrace-supported.h)
 468 AC_CONFIG_FILES(install-debuginfo-for-buildid.sh, chmod +x install-debuginfo-for-buildid.sh)
 469
 470 # We need multilib support, but only if configuring for the target.
 471 AC_CONFIG_COMMANDS([default],
 472 [if test -n "$CONFIG_FILES"; then
 473    if test -n "${with_target_subdir}"; then
 474      # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 475      # that multilib installs will end up installed in the correct place.
 476      # The testsuite needs it for multilib-aware ABI baseline files.
 477      # To work around this not being passed down from config-ml.in ->
 478      # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 479      # append it here.  Only modify Makefiles that have just been created.
 480      #
 481      # Also, get rid of this simulated-VPATH thing that automake does.
 482      cat > vpsed << \_EOF
 483   s!`test -f '$<' || echo '$(srcdir)/'`!!
 484 _EOF
 485      for i in $SUBDIRS; do
 486       case $CONFIG_FILES in
 487        *${i}/Makefile*)
 488          #echo "Adding MULTISUBDIR to $i/Makefile"
 489          sed -f vpsed $i/Makefile > tmp
 490          grep '^MULTISUBDIR =' Makefile >> tmp
 491          mv tmp $i/Makefile
 492          ;;
 493       esac
 494      done
 495      rm vpsed
 496    fi
 497  fi
 498 ],
 499 [
 500 # Variables needed in config.status (file generation) which aren't already
 501 # passed by autoconf.
 502 SUBDIRS="$SUBDIRS"
 503 ])
 504
 505 AC_OUTPUT