libchill/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1997, 1998 Free Software Foundation, Inc.
   3 #   Contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GNU CC.
   6 #
   7 #GNU CHILL is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 2, or (at your option)
  10 #any later version.
  11 #
  12 #GNU CHILL is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GNU CHILL; see the file COPYING.  If not, write to
  19 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 #02111-1307, USA.
  21
  22 AC_PREREQ(2.12.1)
  23 AC_INIT(chillrt0.c)
  24
  25 if test "${srcdir}" = "." ; then
  26   if test "${with_target_subdir}" != "." ; then
  27     topsrcdir=${with_multisrctop}../..
  28   else
  29     topsrcdir=${with_multisrctop}..
  30   fi
  31 else
  32   topsrcdir=${srcdir}/..
  33 fi
  34 dnl This is needed for a multilibbed build in the source tree so
  35 dnl that install-sh and config.sub get found.
  36 AC_CONFIG_AUX_DIR($topsrcdir)
  37
  38 dnl Checks for programs.
  39 # For chill we'll set CC to point at the built gcc, but this will get it into
  40 # the makefiles
  41 AC_PROG_CC
  42
  43 test "$AR" || AR=ar
  44 AC_SUBST(AR)
  45 AC_PROG_MAKE_SET
  46
  47 dnl Checks for libraries.
  48
  49 dnl Checks for header files.
  50 # Sanity check for the cross-compilation case:
  51 AC_CHECK_HEADER(stdio.h,:,
  52   [AC_MSG_ERROR([Can't find stdio.h.
  53 You must have a usable C system for the target already installed, at least
  54 including headers and, preferably, the library, before you can configure
  55 the Chill runtime system.  If necessary, install gcc now with \`LANGUAGES=c',
  56 then the target library, then build with \`LANGUAGES=chill'.])])
  57
  58 AC_HEADER_STDC
  59
  60 AC_MSG_CHECKING(for posix)
  61 AC_CACHE_VAL(chill_cv_header_posix,
  62   AC_EGREP_CPP(yes,
  63   [#include <sys/types.h>
  64 #include <unistd.h>
  65 #ifdef _POSIX_VERSION
  66   yes
  67 #endif
  68 ],
  69   chill_cv_header_posix=yes,
  70   chill_cv_header_posix=no))
  71 AC_MSG_RESULT($chill_cv_header_posix)
  72
  73 # We can rely on the GNU library being posix-ish.  I guess checking the
  74 # header isn't actually like checking the functions, though...
  75 AC_MSG_CHECKING(for GNU library)
  76 AC_CACHE_VAL(chill_cv_lib_gnu,
  77   AC_EGREP_CPP(yes,
  78     [#include <stdio.h>
  79 #ifdef __GNU_LIBRARY__
  80   yes
  81 #endif
  82 ],
  83   chill_cv_lib_gnu=yes, chill_cv_lib_gnu=no))
  84 AC_MSG_RESULT($chill_cv_lib_gnu)
  85
  86 dnl Checks for library functions.
  87 AC_TYPE_SIGNAL
  88 # we'll get atexit by default
  89 if test $ac_cv_header_stdc != yes; then
  90 AC_CHECK_FUNC(atexit,
  91   AC_DEFINE(onexit,atexit),dnl just in case
  92   [AC_DEFINE(NO_ONEXIT)
  93   AC_CHECK_FUNC(onexit,,
  94     [AC_CHECK_FUNC(on_exit,
  95      AC_DEFINE(onexit,on_exit),)])])
  96 else true
  97 fi
  98
  99 # We need multilib support, but only if configuring for the target.
 100 AC_OUTPUT(Makefile,
 101 [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 102 if test -n "$CONFIG_FILES"; then
 103   if test -n "${with_target_subdir}"; then
 104     # FIXME: We shouldn't need to set ac_file
 105     ac_file=Makefile
 106     . ${topsrcdir}/config-ml.in
 107   fi
 108 fi],
 109 srcdir=${srcdir}
 110 host=${host}
 111 target=${target}
 112 with_target_subdir=${with_target_subdir}
 113 with_multisubdir=${with_multisubdir}
 114 ac_configure_args="--enable-multilib ${ac_configure_args}"
 115 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 116 topsrcdir=${topsrcdir}
 117 )
 118
 119
 120
 121 dnl Local Variables:
 122 dnl comment-start: "dnl "
 123 dnl comment-end: ""
 124 dnl comment-start-skip: "\\bdnl\\b\\s *"
 125 dnl End: