libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.64)
   4
   5 AC_INIT([libffi], [3.0.9], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44   alpha*-*-*)
  45         TARGET=ALPHA; TARGETDIR=alpha;
  46         # Support 128-bit long double, changeable via command-line switch.
  47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  48         ;;
  49
  50   arm*-*-*)
  51         TARGET=ARM; TARGETDIR=arm
  52         ;;
  53
  54   amd64-*-freebsd* | amd64-*-openbsd*)
  55         TARGET=X86_64; TARGETDIR=x86
  56         ;;
  57
  58   avr32*-*-*)
  59         TARGET=AVR32; TARGETDIR=avr32
  60         ;;
  61
  62   cris-*-*)
  63         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  64         ;;
  65
  66   frv-*-*)
  67         TARGET=FRV; TARGETDIR=frv
  68         ;;
  69
  70   hppa*-*-linux* | parisc*-*-linux*)
  71         TARGET=PA_LINUX; TARGETDIR=pa
  72         ;;
  73   hppa*64-*-hpux*)
  74         TARGET=PA64_HPUX; TARGETDIR=pa
  75         ;;
  76   hppa*-*-hpux*)
  77         TARGET=PA_HPUX; TARGETDIR=pa
  78         ;;
  79
  80   i?86-*-freebsd* | i?86-*-openbsd*)
  81         TARGET=X86_FREEBSD; TARGETDIR=x86
  82         ;;
  83   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2*)
  84         TARGET=X86_WIN32; TARGETDIR=x86
  85         # All mingw/cygwin/win32 builds require this for sharedlib
  86         AM_LTLDFLAGS="-no-undefined"
  87         ;;
  88   i?86-*-darwin*)
  89         TARGET=X86_DARWIN; TARGETDIR=x86
  90         ;;
  91   i?86-*-solaris2.1[[0-9]]*)
  92         TARGET=X86_64; TARGETDIR=x86
  93         ;;
  94   i?86-*-*)
  95         TARGET=X86; TARGETDIR=x86
  96         ;;
  97
  98   ia64*-*-*)
  99         TARGET=IA64; TARGETDIR=ia64
 100         ;;
 101
 102   m32r*-*-*)
 103         TARGET=M32R; TARGETDIR=m32r
 104         ;;
 105
 106   m68k-*-*)
 107         TARGET=M68K; TARGETDIR=m68k
 108         ;;
 109
 110   mips-sgi-irix5.* | mips-sgi-irix6.*)
 111         TARGET=MIPS; TARGETDIR=mips
 112         ;;
 113   mips*-*-linux*)
 114         # Support 128-bit long double for NewABI.
 115         HAVE_LONG_DOUBLE='defined(__mips64)'
 116         TARGET=MIPS; TARGETDIR=mips
 117         ;;
 118
 119   powerpc*-*-linux* | powerpc-*-sysv*)
 120         TARGET=POWERPC; TARGETDIR=powerpc
 121         ;;
 122   powerpc-*-beos*)
 123         TARGET=POWERPC; TARGETDIR=powerpc
 124         ;;
 125   powerpc-*-darwin*)
 126         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 127         ;;
 128   powerpc-*-aix* | rs6000-*-aix*)
 129         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 130         ;;
 131   powerpc-*-freebsd*)
 132         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 133         ;;
 134  powerpc64-*-freebsd*)
 135         TARGET=POWERPC; TARGETDIR=powerpc
 136         ;;
 137   powerpc*-*-rtems*)
 138         TARGET=POWERPC; TARGETDIR=powerpc
 139         ;;
 140
 141   s390-*-* | s390x-*-*)
 142         TARGET=S390; TARGETDIR=s390
 143         ;;
 144
 145   sh-*-* | sh[[34]]*-*-*)
 146         TARGET=SH; TARGETDIR=sh
 147         ;;
 148   sh64-*-* | sh5*-*-*)
 149         TARGET=SH64; TARGETDIR=sh64
 150         ;;
 151
 152   sparc*-*-*)
 153         TARGET=SPARC; TARGETDIR=sparc
 154         ;;
 155
 156   x86_64-*-darwin*)
 157         TARGET=X86_DARWIN; TARGETDIR=x86
 158         ;;
 159
 160   x86_64-*-cygwin* | x86_64-*-mingw*)
 161         TARGET=X86_WIN64; TARGETDIR=x86
 162         ;;
 163
 164   x86_64-*-*)
 165         TARGET=X86_64; TARGETDIR=x86
 166         ;;
 167 esac
 168
 169 AC_SUBST(AM_RUNTESTFLAGS)
 170 AC_SUBST(AM_LTLDFLAGS)
 171
 172 if test $TARGETDIR = unknown; then
 173   AC_MSG_ERROR(["libffi has not been ported to $host."])
 174 fi
 175
 176 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
 177 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 178 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 179 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
 180 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 181 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
 182 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 183 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 184 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 185 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 186 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 187 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 188 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 189 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 190 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 191 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 192 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
 193 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 194 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 195 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 196 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 197 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 198 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 199 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 200 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 201 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 202
 203 AC_HEADER_STDC
 204 AC_CHECK_FUNCS(memcpy)
 205 AC_FUNC_ALLOCA
 206
 207 AC_CHECK_SIZEOF(double)
 208 AC_CHECK_SIZEOF(long double)
 209
 210 # Also AC_SUBST this variable for ffi.h.
 211 if test -z "$HAVE_LONG_DOUBLE"; then
 212   HAVE_LONG_DOUBLE=0
 213   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 214     if test $ac_cv_sizeof_long_double != 0; then
 215       HAVE_LONG_DOUBLE=1
 216       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 217     fi
 218   fi
 219 fi
 220 AC_SUBST(HAVE_LONG_DOUBLE)
 221
 222 AC_C_BIGENDIAN
 223
 224 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
 225     libffi_cv_as_cfi_pseudo_op, [
 226     libffi_cv_as_cfi_pseudo_op=unknown
 227     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
 228                    [libffi_cv_as_cfi_pseudo_op=yes],
 229                    [libffi_cv_as_cfi_pseudo_op=no])
 230 ])
 231 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
 232     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
 233               [Define if your assembler supports .cfi_* directives.])
 234 fi
 235
 236 if test x$TARGET = xSPARC; then
 237     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 238         libffi_cv_as_sparc_ua_pcrel, [
 239         save_CFLAGS="$CFLAGS"
 240         save_LDFLAGS="$LDFLAGS"
 241         CFLAGS="$CFLAGS -fpic"
 242         LDFLAGS="$LDFLAGS -shared"
 243         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 244                     [libffi_cv_as_sparc_ua_pcrel=yes],
 245                     [libffi_cv_as_sparc_ua_pcrel=no])
 246         CFLAGS="$save_CFLAGS"
 247         LDFLAGS="$save_LDFLAGS"])
 248     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 249         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 250                   [Define if your assembler and linker support unaligned PC relative relocs.])
 251     fi
 252
 253     AC_CACHE_CHECK([assembler .register pseudo-op support],
 254        libffi_cv_as_register_pseudo_op, [
 255        libffi_cv_as_register_pseudo_op=unknown
 256        # Check if we have .register
 257        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 258                        [libffi_cv_as_register_pseudo_op=yes],
 259                        [libffi_cv_as_register_pseudo_op=no])
 260     ])
 261     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 262        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 263                [Define if your assembler supports .register.])
 264     fi
 265 fi
 266
 267 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
 268     AC_CACHE_CHECK([assembler supports pc related relocs],
 269         libffi_cv_as_x86_pcrel, [
 270         libffi_cv_as_x86_pcrel=yes
 271         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 272         if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 273             libffi_cv_as_x86_pcrel=no
 274         fi
 275         ])
 276     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
 277         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 278                   [Define if your assembler supports PC relative relocs.])
 279     fi
 280
 281     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
 282        libffi_cv_as_ascii_pseudo_op, [
 283        libffi_cv_as_ascii_pseudo_op=unknown
 284        # Check if we have .ascii
 285        AC_TRY_COMPILE([asm (".ascii \"string\"");],,
 286                        [libffi_cv_as_ascii_pseudo_op=yes],
 287                        [libffi_cv_as_ascii_pseudo_op=no])
 288     ])
 289     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
 290        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
 291                [Define if your assembler supports .ascii.])
 292     fi
 293
 294     AC_CACHE_CHECK([assembler .string pseudo-op support],
 295        libffi_cv_as_string_pseudo_op, [
 296        libffi_cv_as_string_pseudo_op=unknown
 297        # Check if we have .string
 298        AC_TRY_COMPILE([asm (".string \"string\"");],,
 299                        [libffi_cv_as_string_pseudo_op=yes],
 300                        [libffi_cv_as_string_pseudo_op=no])
 301     ])
 302     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
 303        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
 304                [Define if your assembler supports .string.])
 305     fi
 306 fi
 307
 308 case "$target" in
 309      *-apple-darwin10* | *-*-freebsd* | *-*-openbsd* | *-pc-solaris*)
 310        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
 311                  [Cannot use malloc on this target, so, we revert to
 312                    alternative means])
 313      ;;
 314 esac
 315
 316 if test x$TARGET = xX86_64; then
 317     AC_CACHE_CHECK([assembler supports unwind section type],
 318         libffi_cv_as_x86_64_unwind_section_type, [
 319         libffi_cv_as_x86_64_unwind_section_type=yes
 320         echo '.section .eh_frame,"a",@unwind' > conftest.s
 321         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 322             libffi_cv_as_x86_64_unwind_section_type=no
 323         fi
 324         ])
 325     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
 326         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 327                   [Define if your assembler supports unwind section type.])
 328     fi
 329 fi
 330
 331 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 332     libffi_cv_ro_eh_frame, [
 333         libffi_cv_ro_eh_frame=no
 334         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 335         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 336             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 337                 libffi_cv_ro_eh_frame=yes
 338             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 339                  | grep -v '#write' > /dev/null; then
 340                 libffi_cv_ro_eh_frame=yes
 341             fi
 342         fi
 343         rm -f conftest.*
 344     ])
 345 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 346     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 347               [Define if .eh_frame sections should be read-only.])
 348     AC_DEFINE(EH_FRAME_FLAGS, "a",
 349               [Define to the flags needed for the .section .eh_frame directive.])
 350 else
 351     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 352               [Define to the flags needed for the .section .eh_frame directive.])
 353 fi
 354
 355 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 356     libffi_cv_hidden_visibility_attribute, [
 357         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 358         libffi_cv_hidden_visibility_attribute=no
 359         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 360             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 361                 libffi_cv_hidden_visibility_attribute=yes
 362             fi
 363         fi
 364         rm -f conftest.*
 365     ])
 366 if test $libffi_cv_hidden_visibility_attribute = yes; then
 367     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 368               [Define if __attribute__((visibility("hidden"))) is supported.])
 369 fi
 370
 371 AH_BOTTOM([
 372 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 373 #ifdef LIBFFI_ASM
 374 #define FFI_HIDDEN(name) .hidden name
 375 #else
 376 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 377 #endif
 378 #else
 379 #ifdef LIBFFI_ASM
 380 #define FFI_HIDDEN(name)
 381 #else
 382 #define FFI_HIDDEN
 383 #endif
 384 #endif
 385 ])
 386
 387 AC_SUBST(TARGET)
 388 AC_SUBST(TARGETDIR)
 389
 390 AC_SUBST(SHELL)
 391
 392 AC_ARG_ENABLE(debug,
 393 [  --enable-debug          debugging mode],
 394   if test "$enable_debug" = "yes"; then
 395     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 396   fi)
 397
 398 AC_ARG_ENABLE(structs,
 399 [  --disable-structs       omit code for struct support],
 400   if test "$enable_structs" = "no"; then
 401     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 402   fi)
 403
 404 AC_ARG_ENABLE(raw-api,
 405 [  --disable-raw-api       make the raw api unavailable],
 406   if test "$enable_raw_api" = "no"; then
 407     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 408   fi)
 409
 410 AC_ARG_ENABLE(purify-safety,
 411 [  --enable-purify-safety  purify-safe mode],
 412   if test "$enable_purify_safety" = "yes"; then
 413     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 414   fi)
 415
 416 if test -n "$with_cross_host" &&
 417    test x"$with_cross_host" != x"no"; then
 418   toolexecdir='$(exec_prefix)/$(target_alias)'
 419   toolexeclibdir='$(toolexecdir)/lib'
 420 else
 421   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 422   toolexeclibdir='$(libdir)'
 423 fi
 424 multi_os_directory=`$CC -print-multi-os-directory`
 425 case $multi_os_directory in
 426   .) ;; # Avoid trailing /.
 427   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 428 esac
 429 AC_SUBST(toolexecdir)
 430 AC_SUBST(toolexeclibdir)
 431
 432 if test "${multilib}" = "yes"; then
 433   multilib_arg="--enable-multilib"
 434 else
 435   multilib_arg=
 436 fi
 437
 438 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 439 AC_CONFIG_COMMANDS(src, [
 440 test -d src || mkdir src
 441 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 442 ], [TARGETDIR="$TARGETDIR"])
 443
 444 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 445
 446 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile)
 447
 448 AC_OUTPUT