libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.59)
   4
   5 AC_INIT([libffi], [3.0.8], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44   alpha*-*-*)
  45         TARGET=ALPHA; TARGETDIR=alpha;
  46         # Support 128-bit long double, changable via command-line switch.
  47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  48         ;;
  49
  50   arm*-*-*)
  51         TARGET=ARM; TARGETDIR=arm
  52         ;;
  53
  54   amd64-*-freebsd*)
  55         TARGET=X86_64; TARGETDIR=x86
  56         ;;
  57
  58   cris-*-*)
  59         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  60         ;;
  61
  62   frv-*-*)
  63         TARGET=FRV; TARGETDIR=frv
  64         ;;
  65
  66   hppa*-*-linux* | parisc*-*-linux*)
  67         TARGET=PA_LINUX; TARGETDIR=pa
  68         ;;
  69   hppa*64-*-hpux*)
  70         TARGET=PA64_HPUX; TARGETDIR=pa
  71         ;;
  72   hppa*-*-hpux*)
  73         TARGET=PA_HPUX; TARGETDIR=pa
  74         ;;
  75
  76   i386-*-freebsd* | i386-*-openbsd*)
  77         TARGET=X86_FREEBSD; TARGETDIR=x86
  78         ;;
  79   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw*)
  80         TARGET=X86_WIN32; TARGETDIR=x86
  81         ;;
  82   i?86-*-darwin*)
  83         TARGET=X86_DARWIN; TARGETDIR=x86
  84         ;;
  85   i?86-*-solaris2.1[[0-9]]*)
  86         TARGET=X86_64; TARGETDIR=x86
  87         ;;
  88   i?86-*-*)
  89         TARGET=X86; TARGETDIR=x86
  90         ;;
  91
  92   ia64*-*-*)
  93         TARGET=IA64; TARGETDIR=ia64
  94         ;;
  95
  96   m32r*-*-*)
  97         TARGET=M32R; TARGETDIR=m32r
  98         ;;
  99
 100   m68k-*-*)
 101         TARGET=M68K; TARGETDIR=m68k
 102         ;;
 103
 104   mips-sgi-irix5.* | mips-sgi-irix6.*)
 105         TARGET=MIPS; TARGETDIR=mips
 106         ;;
 107   mips*-*-linux*)
 108         TARGET=MIPS; TARGETDIR=mips
 109         ;;
 110
 111   powerpc*-*-linux* | powerpc-*-sysv*)
 112         TARGET=POWERPC; TARGETDIR=powerpc
 113         ;;
 114   powerpc-*-beos*)
 115         TARGET=POWERPC; TARGETDIR=powerpc
 116         ;;
 117   powerpc-*-darwin*)
 118         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 119         ;;
 120   powerpc-*-aix* | rs6000-*-aix*)
 121         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 122         ;;
 123   powerpc-*-freebsd*)
 124         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 125         ;;
 126   powerpc*-*-rtems*)
 127         TARGET=POWERPC; TARGETDIR=powerpc
 128         ;;
 129
 130   s390-*-* | s390x-*-*)
 131         TARGET=S390; TARGETDIR=s390
 132         ;;
 133
 134   sh-*-* | sh[[34]]*-*-*)
 135         TARGET=SH; TARGETDIR=sh
 136         ;;
 137   sh64-*-* | sh5*-*-*)
 138         TARGET=SH64; TARGETDIR=sh64
 139         ;;
 140
 141   sparc*-*-*)
 142         TARGET=SPARC; TARGETDIR=sparc
 143         ;;
 144
 145   x86_64-*-darwin*)
 146         TARGET=X86_DARWIN; TARGETDIR=x86
 147         ;;
 148   x86_64-*-cygwin* | x86_64-*-mingw*)
 149         TARGET=X86_WIN64; TARGETDIR=x86
 150         ;;
 151   x86_64-*-*)
 152         TARGET=X86_64; TARGETDIR=x86
 153         ;;
 154 esac
 155
 156 AC_SUBST(AM_RUNTESTFLAGS)
 157
 158 if test $TARGETDIR = unknown; then
 159   AC_MSG_ERROR(["libffi has not been ported to $host."])
 160 fi
 161
 162 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
 163 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 164 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 165 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
 166 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 167 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
 168 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 169 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 170 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 171 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 172 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 173 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 174 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 175 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 176 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 177 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 178 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 179 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 180 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 181 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 182 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 183 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 184 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 185 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 186 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 187
 188 AC_HEADER_STDC
 189 AC_CHECK_FUNCS(memcpy)
 190 AC_FUNC_ALLOCA
 191
 192 AC_CHECK_SIZEOF(double)
 193 AC_CHECK_SIZEOF(long double)
 194
 195 # Also AC_SUBST this variable for ffi.h.
 196 if test -z "$HAVE_LONG_DOUBLE"; then
 197   HAVE_LONG_DOUBLE=0
 198   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 199     if test $ac_cv_sizeof_long_double != 0; then
 200       HAVE_LONG_DOUBLE=1
 201       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 202     fi
 203   fi
 204 fi
 205 AC_SUBST(HAVE_LONG_DOUBLE)
 206
 207 AC_C_BIGENDIAN
 208
 209 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
 210     libffi_cv_as_cfi_pseudo_op, [
 211     libffi_cv_as_cfi_pseudo_op=unknown
 212     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
 213                    [libffi_cv_as_cfi_pseudo_op=yes],
 214                    [libffi_cv_as_cfi_pseudo_op=no])
 215 ])
 216 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
 217     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
 218               [Define if your assembler supports .cfi_* directives.])
 219 fi
 220
 221 if test x$TARGET = xSPARC; then
 222     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 223         libffi_cv_as_sparc_ua_pcrel, [
 224         save_CFLAGS="$CFLAGS"
 225         save_LDFLAGS="$LDFLAGS"
 226         CFLAGS="$CFLAGS -fpic"
 227         LDFLAGS="$LDFLAGS -shared"
 228         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 229                     [libffi_cv_as_sparc_ua_pcrel=yes],
 230                     [libffi_cv_as_sparc_ua_pcrel=no])
 231         CFLAGS="$save_CFLAGS"
 232         LDFLAGS="$save_LDFLAGS"])
 233     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 234         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 235                   [Define if your assembler and linker support unaligned PC relative relocs.])
 236     fi
 237
 238     AC_CACHE_CHECK([assembler .register pseudo-op support],
 239        libffi_cv_as_register_pseudo_op, [
 240        libffi_cv_as_register_pseudo_op=unknown
 241        # Check if we have .register
 242        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 243                        [libffi_cv_as_register_pseudo_op=yes],
 244                        [libffi_cv_as_register_pseudo_op=no])
 245     ])
 246     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 247        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 248                [Define if your assembler supports .register.])
 249     fi
 250 fi
 251
 252 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
 253     AC_CACHE_CHECK([assembler supports pc related relocs],
 254         libffi_cv_as_x86_pcrel, [
 255         libffi_cv_as_x86_pcrel=yes
 256         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 257         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 258             libffi_cv_as_x86_pcrel=no
 259         fi
 260         ])
 261     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
 262         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 263                   [Define if your assembler supports PC relative relocs.])
 264     fi
 265 fi
 266
 267 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 268     libffi_cv_ro_eh_frame, [
 269         libffi_cv_ro_eh_frame=no
 270         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 271         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 272             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 273                 libffi_cv_ro_eh_frame=yes
 274             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 275                  | grep -v '#write' > /dev/null; then
 276                 libffi_cv_ro_eh_frame=yes
 277             fi
 278         fi
 279         rm -f conftest.*
 280     ])
 281 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 282     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 283               [Define if .eh_frame sections should be read-only.])
 284     AC_DEFINE(EH_FRAME_FLAGS, "a",
 285               [Define to the flags needed for the .section .eh_frame directive.])
 286 else
 287     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 288               [Define to the flags needed for the .section .eh_frame directive.])
 289 fi
 290
 291 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 292     libffi_cv_hidden_visibility_attribute, [
 293         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 294         libffi_cv_hidden_visibility_attribute=no
 295         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 296             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 297                 libffi_cv_hidden_visibility_attribute=yes
 298             fi
 299         fi
 300         rm -f conftest.*
 301     ])
 302 if test $libffi_cv_hidden_visibility_attribute = yes; then
 303     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 304               [Define if __attribute__((visibility("hidden"))) is supported.])
 305 fi
 306
 307 AH_BOTTOM([
 308 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 309 #ifdef LIBFFI_ASM
 310 #define FFI_HIDDEN(name) .hidden name
 311 #else
 312 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 313 #endif
 314 #else
 315 #ifdef LIBFFI_ASM
 316 #define FFI_HIDDEN(name)
 317 #else
 318 #define FFI_HIDDEN
 319 #endif
 320 #endif
 321 ])
 322
 323 AC_SUBST(TARGET)
 324 AC_SUBST(TARGETDIR)
 325
 326 AC_SUBST(SHELL)
 327
 328 AC_ARG_ENABLE(debug,
 329 [  --enable-debug          debugging mode],
 330   if test "$enable_debug" = "yes"; then
 331     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 332   fi)
 333
 334 AC_ARG_ENABLE(structs,
 335 [  --disable-structs       omit code for struct support],
 336   if test "$enable_structs" = "no"; then
 337     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 338   fi)
 339
 340 AC_ARG_ENABLE(raw-api,
 341 [  --disable-raw-api       make the raw api unavailable],
 342   if test "$enable_raw_api" = "no"; then
 343     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 344   fi)
 345
 346 AC_ARG_ENABLE(purify-safety,
 347 [  --enable-purify-safety  purify-safe mode],
 348   if test "$enable_purify_safety" = "yes"; then
 349     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 350   fi)
 351
 352 if test -n "$with_cross_host" &&
 353    test x"$with_cross_host" != x"no"; then
 354   toolexecdir='$(exec_prefix)/$(target_alias)'
 355   toolexeclibdir='$(toolexecdir)/lib'
 356 else
 357   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 358   toolexeclibdir='$(libdir)'
 359 fi
 360 multi_os_directory=`$CC -print-multi-os-directory`
 361 case $multi_os_directory in
 362   .) ;; # Avoid trailing /.
 363   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 364 esac
 365 AC_SUBST(toolexecdir)
 366 AC_SUBST(toolexeclibdir)
 367
 368 if test "${multilib}" = "yes"; then
 369   multilib_arg="--enable-multilib"
 370 else
 371   multilib_arg=
 372 fi
 373
 374 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 375 AC_CONFIG_COMMANDS(src, [
 376 test -d src || mkdir src
 377 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 378 ], [TARGETDIR="$TARGETDIR"])
 379
 380 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 381
 382 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile)
 383
 384 AC_OUTPUT