libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.64)
   4
   5 AC_INIT([libffi], [3.0.9], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44   alpha*-*-*)
  45         TARGET=ALPHA; TARGETDIR=alpha;
  46         # Support 128-bit long double, changeable via command-line switch.
  47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  48         ;;
  49
  50   arm*-*-*)
  51         TARGET=ARM; TARGETDIR=arm
  52         ;;
  53
  54   amd64-*-freebsd* | amd64-*-openbsd*)
  55         TARGET=X86_64; TARGETDIR=x86
  56         ;;
  57
  58   avr32*-*-*)
  59         TARGET=AVR32; TARGETDIR=avr32
  60         ;;
  61
  62   cris-*-*)
  63         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  64         ;;
  65
  66   frv-*-*)
  67         TARGET=FRV; TARGETDIR=frv
  68         ;;
  69
  70   hppa*-*-linux* | parisc*-*-linux*)
  71         TARGET=PA_LINUX; TARGETDIR=pa
  72         ;;
  73   hppa*64-*-hpux*)
  74         TARGET=PA64_HPUX; TARGETDIR=pa
  75         ;;
  76   hppa*-*-hpux*)
  77         TARGET=PA_HPUX; TARGETDIR=pa
  78         ;;
  79
  80   i?86-*-freebsd* | i?86-*-openbsd*)
  81         TARGET=X86_FREEBSD; TARGETDIR=x86
  82         ;;
  83   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2*)
  84         TARGET=X86_WIN32; TARGETDIR=x86
  85         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
  86         # We must also check with_cross_host to decide if this is a native
  87         # or cross-build and select where to install dlls appropriately.
  88         if test -n "$with_cross_host" &&
  89            test x"$with_cross_host" != x"no"; then
  90           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
  91         else
  92           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
  93         fi
  94         ;;
  95   i?86-*-darwin*)
  96         TARGET=X86_DARWIN; TARGETDIR=x86
  97         ;;
  98   i?86-*-solaris2.1[[0-9]]*)
  99         TARGET=X86_64; TARGETDIR=x86
 100         ;;
 101   i?86-*-*)
 102         TARGET=X86; TARGETDIR=x86
 103         ;;
 104
 105   ia64*-*-*)
 106         TARGET=IA64; TARGETDIR=ia64
 107         ;;
 108
 109   m32r*-*-*)
 110         TARGET=M32R; TARGETDIR=m32r
 111         ;;
 112
 113   m68k-*-*)
 114         TARGET=M68K; TARGETDIR=m68k
 115         ;;
 116
 117   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
 118         TARGET=MIPS; TARGETDIR=mips
 119         ;;
 120   mips*-*-linux*)
 121         # Support 128-bit long double for NewABI.
 122         HAVE_LONG_DOUBLE='defined(__mips64)'
 123         TARGET=MIPS; TARGETDIR=mips
 124         ;;
 125
 126   powerpc*-*-linux* | powerpc-*-sysv*)
 127         TARGET=POWERPC; TARGETDIR=powerpc
 128         ;;
 129   powerpc-*-beos*)
 130         TARGET=POWERPC; TARGETDIR=powerpc
 131         ;;
 132   powerpc-*-darwin*)
 133         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 134         ;;
 135   powerpc-*-aix* | rs6000-*-aix*)
 136         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 137         ;;
 138   powerpc-*-freebsd*)
 139         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 140         ;;
 141  powerpc64-*-freebsd*)
 142         TARGET=POWERPC; TARGETDIR=powerpc
 143         ;;
 144   powerpc*-*-rtems*)
 145         TARGET=POWERPC; TARGETDIR=powerpc
 146         ;;
 147
 148   s390-*-* | s390x-*-*)
 149         TARGET=S390; TARGETDIR=s390
 150         ;;
 151
 152   sh-*-* | sh[[34]]*-*-*)
 153         TARGET=SH; TARGETDIR=sh
 154         ;;
 155   sh64-*-* | sh5*-*-*)
 156         TARGET=SH64; TARGETDIR=sh64
 157         ;;
 158
 159   sparc*-*-*)
 160         TARGET=SPARC; TARGETDIR=sparc
 161         ;;
 162
 163   x86_64-*-darwin*)
 164         TARGET=X86_DARWIN; TARGETDIR=x86
 165         ;;
 166
 167   x86_64-*-cygwin* | x86_64-*-mingw*)
 168         TARGET=X86_WIN64; TARGETDIR=x86
 169         ;;
 170
 171   x86_64-*-*)
 172         TARGET=X86_64; TARGETDIR=x86
 173         ;;
 174 esac
 175
 176 AC_SUBST(AM_RUNTESTFLAGS)
 177 AC_SUBST(AM_LTLDFLAGS)
 178
 179 if test $TARGETDIR = unknown; then
 180   AC_MSG_ERROR(["libffi has not been ported to $host."])
 181 fi
 182
 183 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
 184 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 185 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 186 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
 187 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 188 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
 189 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 190 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 191 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 192 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 193 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 194 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 195 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 196 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 197 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 198 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 199 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
 200 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 201 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 202 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 203 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 204 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 205 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 206 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 207 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 208 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 209
 210 AC_HEADER_STDC
 211 AC_CHECK_FUNCS(memcpy)
 212 AC_FUNC_ALLOCA
 213
 214 AC_CHECK_SIZEOF(double)
 215 AC_CHECK_SIZEOF(long double)
 216
 217 # Also AC_SUBST this variable for ffi.h.
 218 if test -z "$HAVE_LONG_DOUBLE"; then
 219   HAVE_LONG_DOUBLE=0
 220   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 221     if test $ac_cv_sizeof_long_double != 0; then
 222       HAVE_LONG_DOUBLE=1
 223       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 224     fi
 225   fi
 226 fi
 227 AC_SUBST(HAVE_LONG_DOUBLE)
 228
 229 AC_C_BIGENDIAN
 230
 231 GCC_AS_CFI_PSEUDO_OP
 232
 233 if test x$TARGET = xSPARC; then
 234     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 235         libffi_cv_as_sparc_ua_pcrel, [
 236         save_CFLAGS="$CFLAGS"
 237         save_LDFLAGS="$LDFLAGS"
 238         CFLAGS="$CFLAGS -fpic"
 239         LDFLAGS="$LDFLAGS -shared"
 240         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 241                     [libffi_cv_as_sparc_ua_pcrel=yes],
 242                     [libffi_cv_as_sparc_ua_pcrel=no])
 243         CFLAGS="$save_CFLAGS"
 244         LDFLAGS="$save_LDFLAGS"])
 245     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 246         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 247                   [Define if your assembler and linker support unaligned PC relative relocs.])
 248     fi
 249
 250     AC_CACHE_CHECK([assembler .register pseudo-op support],
 251        libffi_cv_as_register_pseudo_op, [
 252        libffi_cv_as_register_pseudo_op=unknown
 253        # Check if we have .register
 254        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 255                        [libffi_cv_as_register_pseudo_op=yes],
 256                        [libffi_cv_as_register_pseudo_op=no])
 257     ])
 258     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 259        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 260                [Define if your assembler supports .register.])
 261     fi
 262 fi
 263
 264 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
 265     AC_CACHE_CHECK([assembler supports pc related relocs],
 266         libffi_cv_as_x86_pcrel, [
 267         libffi_cv_as_x86_pcrel=yes
 268         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 269         if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 270             libffi_cv_as_x86_pcrel=no
 271         fi
 272         ])
 273     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
 274         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 275                   [Define if your assembler supports PC relative relocs.])
 276     fi
 277
 278     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
 279        libffi_cv_as_ascii_pseudo_op, [
 280        libffi_cv_as_ascii_pseudo_op=unknown
 281        # Check if we have .ascii
 282        AC_TRY_COMPILE([asm (".ascii \\"string\\"");],,
 283                        [libffi_cv_as_ascii_pseudo_op=yes],
 284                        [libffi_cv_as_ascii_pseudo_op=no])
 285     ])
 286     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
 287        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
 288                [Define if your assembler supports .ascii.])
 289     fi
 290
 291     AC_CACHE_CHECK([assembler .string pseudo-op support],
 292        libffi_cv_as_string_pseudo_op, [
 293        libffi_cv_as_string_pseudo_op=unknown
 294        # Check if we have .string
 295        AC_TRY_COMPILE([asm (".string \\"string\\"");],,
 296                        [libffi_cv_as_string_pseudo_op=yes],
 297                        [libffi_cv_as_string_pseudo_op=no])
 298     ])
 299     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
 300        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
 301                [Define if your assembler supports .string.])
 302     fi
 303 fi
 304
 305 case "$target" in
 306      *-apple-darwin10* | *-*-freebsd* | *-*-openbsd* | *-pc-solaris*)
 307        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
 308                  [Cannot use malloc on this target, so, we revert to
 309                    alternative means])
 310      ;;
 311 esac
 312
 313 if test x$TARGET = xX86_64; then
 314     AC_CACHE_CHECK([assembler supports unwind section type],
 315         libffi_cv_as_x86_64_unwind_section_type, [
 316         libffi_cv_as_x86_64_unwind_section_type=yes
 317         echo '.section .eh_frame,"a",@unwind' > conftest.s
 318         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 319             libffi_cv_as_x86_64_unwind_section_type=no
 320         fi
 321         ])
 322     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
 323         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 324                   [Define if your assembler supports unwind section type.])
 325     fi
 326 fi
 327
 328 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 329     libffi_cv_ro_eh_frame, [
 330         libffi_cv_ro_eh_frame=no
 331         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 332         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 333             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 334                 libffi_cv_ro_eh_frame=yes
 335             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 336                  | grep -v '#write' > /dev/null; then
 337                 libffi_cv_ro_eh_frame=yes
 338             fi
 339         fi
 340         rm -f conftest.*
 341     ])
 342 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 343     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 344               [Define if .eh_frame sections should be read-only.])
 345     AC_DEFINE(EH_FRAME_FLAGS, "a",
 346               [Define to the flags needed for the .section .eh_frame directive.])
 347 else
 348     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 349               [Define to the flags needed for the .section .eh_frame directive.])
 350 fi
 351
 352 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 353     libffi_cv_hidden_visibility_attribute, [
 354         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 355         libffi_cv_hidden_visibility_attribute=no
 356         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 357             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 358                 libffi_cv_hidden_visibility_attribute=yes
 359             fi
 360         fi
 361         rm -f conftest.*
 362     ])
 363 if test $libffi_cv_hidden_visibility_attribute = yes; then
 364     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 365               [Define if __attribute__((visibility("hidden"))) is supported.])
 366 fi
 367
 368 AH_BOTTOM([
 369 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 370 #ifdef LIBFFI_ASM
 371 #define FFI_HIDDEN(name) .hidden name
 372 #else
 373 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 374 #endif
 375 #else
 376 #ifdef LIBFFI_ASM
 377 #define FFI_HIDDEN(name)
 378 #else
 379 #define FFI_HIDDEN
 380 #endif
 381 #endif
 382 ])
 383
 384 AC_SUBST(TARGET)
 385 AC_SUBST(TARGETDIR)
 386
 387 AC_SUBST(SHELL)
 388
 389 AC_ARG_ENABLE(debug,
 390 [  --enable-debug          debugging mode],
 391   if test "$enable_debug" = "yes"; then
 392     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 393   fi)
 394
 395 AC_ARG_ENABLE(structs,
 396 [  --disable-structs       omit code for struct support],
 397   if test "$enable_structs" = "no"; then
 398     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 399   fi)
 400
 401 AC_ARG_ENABLE(raw-api,
 402 [  --disable-raw-api       make the raw api unavailable],
 403   if test "$enable_raw_api" = "no"; then
 404     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 405   fi)
 406
 407 AC_ARG_ENABLE(purify-safety,
 408 [  --enable-purify-safety  purify-safe mode],
 409   if test "$enable_purify_safety" = "yes"; then
 410     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 411   fi)
 412
 413 if test -n "$with_cross_host" &&
 414    test x"$with_cross_host" != x"no"; then
 415   toolexecdir='$(exec_prefix)/$(target_alias)'
 416   toolexeclibdir='$(toolexecdir)/lib'
 417 else
 418   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 419   toolexeclibdir='$(libdir)'
 420 fi
 421 multi_os_directory=`$CC -print-multi-os-directory`
 422 case $multi_os_directory in
 423   .) ;; # Avoid trailing /.
 424   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 425 esac
 426 AC_SUBST(toolexecdir)
 427 AC_SUBST(toolexeclibdir)
 428
 429 if test "${multilib}" = "yes"; then
 430   multilib_arg="--enable-multilib"
 431 else
 432   multilib_arg=
 433 fi
 434
 435 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 436 AC_CONFIG_COMMANDS(src, [
 437 test -d src || mkdir src
 438 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 439 ], [TARGETDIR="$TARGETDIR"])
 440
 441 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 442
 443 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile)
 444
 445 AC_OUTPUT