libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/lib-ld.m4)
   8 sinclude(../config/override.m4)
   9 sinclude(../config/picflag.m4)
  10 sinclude(../config/dfp.m4)
  11 sinclude(../config/unwind_ipinfo.m4)
  12
  13 AC_PREREQ(2.64)
  14 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  15 AC_CONFIG_SRCDIR([static-object.mk])
  16
  17 # The libgcc should not depend on any header files
  18 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  19   [m4_divert_text([DEFAULTS],
  20     [ac_includes_default='/* none */'])])
  21
  22 AC_ARG_WITH(target-subdir,
  23 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  24 AC_ARG_WITH(cross-host,
  25 [  --with-cross-host=HOST           Configuring with a cross compiler])
  26 AC_ARG_WITH(ld,
  27 [  --with-ld               arrange to use the specified ld (full pathname)])
  28
  29 if test "${srcdir}" = "."; then
  30   if test -n "${with_build_subdir}"; then
  31     libgcc_topdir="${srcdir}/../.."
  32     with_target_subdir=
  33   elif test -z "${with_target_subdir}"; then
  34     libgcc_topdir="${srcdir}/.."
  35   else
  36     if test "${with_target_subdir}" != "."; then
  37       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  38     else
  39       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  40     fi
  41   fi
  42 else
  43   libgcc_topdir="${srcdir}/.."
  44 fi
  45 AC_SUBST(libgcc_topdir)
  46 AC_CONFIG_AUX_DIR($libgcc_topdir)
  47 AC_CONFIG_HEADER(auto-target.h:config.in)
  48
  49 AC_ARG_ENABLE(shared,
  50 [  --disable-shared        don't provide a shared libgcc],
  51 [
  52   case $enable_shared in
  53   yes | no) ;;
  54   *)
  55     enable_shared=no
  56     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  57     for pkg in $enableval; do
  58       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  59         enable_shared=yes
  60       fi
  61     done
  62     IFS="$ac_save_ifs"
  63     ;;
  64   esac
  65 ], [enable_shared=yes])
  66 AC_SUBST(enable_shared)
  67
  68 GCC_PICFLAG
  69 AC_SUBST(PICFLAG)
  70
  71 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  72 AC_ARG_ENABLE(version-specific-runtime-libs,
  73 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  74 [case "$enableval" in
  75  yes) version_specific_libs=yes ;;
  76  no)  version_specific_libs=no ;;
  77  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  78  esac],
  79 [version_specific_libs=no])
  80 AC_MSG_RESULT($version_specific_libs)
  81
  82 AC_ARG_WITH(slibdir,
  83 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
  84 slibdir="$with_slibdir",
  85 if test "${version_specific_libs}" = yes; then
  86   slibdir='$(libsubdir)'
  87 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
  88   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
  89 else
  90   slibdir='$(libdir)'
  91 fi)
  92 AC_SUBST(slibdir)
  93
  94 # Command-line options.
  95 # Very limited version of AC_MAINTAINER_MODE.
  96 AC_ARG_ENABLE([maintainer-mode],
  97   [AC_HELP_STRING([--enable-maintainer-mode],
  98                  [enable make rules and dependencies not useful (and
  99                   sometimes confusing) to the casual installer])],
 100   [case ${enable_maintainer_mode} in
 101      yes) MAINT='' ;;
 102      no) MAINT='#' ;;
 103      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
 104    esac
 105    maintainer_mode=${enableval}],
 106   [MAINT='#'])
 107 AC_SUBST([MAINT])dnl
 108
 109 AC_PROG_INSTALL
 110
 111 AC_PROG_AWK
 112 # We need awk; bail out if it's missing.
 113 case ${AWK} in
 114   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 115 esac
 116
 117 AC_CANONICAL_HOST
 118 ACX_NONCANONICAL_HOST
 119 ACX_NONCANONICAL_TARGET
 120 GCC_TOPLEV_SUBDIRS
 121
 122 # Calculate toolexeclibdir
 123 # Also toolexecdir, though it's only used in toolexeclibdir
 124 case ${version_specific_libs} in
 125   yes)
 126     # Need the gcc compiler version to know where to install libraries
 127     # and header files if --enable-version-specific-runtime-libs option
 128     # is selected.
 129     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 130     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 131     ;;
 132   no)
 133     if test -n "$with_cross_host" &&
 134        test x"$with_cross_host" != x"no"; then
 135       # Install a library built with a cross compiler in tooldir, not libdir.
 136       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 137       toolexeclibdir='$(toolexecdir)/lib'
 138     else
 139       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 140       toolexeclibdir='$(libdir)'
 141     fi
 142     multi_os_directory=`$CC -print-multi-os-directory`
 143     case $multi_os_directory in
 144       .) ;; # Avoid trailing /.
 145       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 146     esac
 147     ;;
 148 esac
 149 AC_SUBST(toolexecdir)
 150 AC_SUBST(toolexeclibdir)
 151
 152 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 153 dnl to call AC_CHECK_PROG.
 154 AC_CHECK_TOOL(AR, ar)
 155 AC_CHECK_TOOL(LIPO, lipo, :)
 156 AC_CHECK_TOOL(NM, nm)
 157 AC_CHECK_TOOL(RANLIB, ranlib, :)
 158 AC_CHECK_TOOL(STRIP, strip, :)
 159 AC_PROG_LN_S
 160
 161 GCC_NO_EXECUTABLES
 162 AC_PROG_CC
 163 AC_PROG_CPP_WERROR
 164
 165 AC_CHECK_SIZEOF([double])
 166 AC_CHECK_SIZEOF([long double])
 167 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 168 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 169 AC_SUBST(double_type_size)
 170 AC_SUBST(long_double_type_size)
 171
 172 # Check for decimal float support.
 173 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 174                [AC_COMPILE_IFELSE([_Decimal32 x;], [libgcc_cv_dfp=yes],
 175                                   [libgcc_cv_dfp=no])])
 176 decimal_float=$libgcc_cv_dfp
 177 AC_SUBST(decimal_float)
 178
 179 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 180
 181 # Check for fixed-point support.
 182 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 183                [AC_COMPILE_IFELSE([_Sat _Fract x;], [libgcc_cv_fixed_point=yes],
 184                                   [libgcc_cv_fixed_point=no])])
 185 fixed_point=$libgcc_cv_fixed_point
 186 AC_SUBST(fixed_point)
 187
 188 # For platforms with the unwind ABI which includes an unwind library,
 189 # libunwind, we can choose to use the system libunwind.
 190 # config.gcc also contains tests of with_system_libunwind.
 191 GCC_CHECK_UNWIND_GETIPINFO
 192
 193 # The sjlj test is almost duplicated here and in libgo/configure.ac (for C),
 194 # libstdc++-v3/acinclude.m4 and libjava/configure.ac (for C++), and
 195 # libobjc/configure.ac (for Objective-C).
 196 # FIXME: This should be centralized in config/sjlj.m4.
 197 AC_ARG_ENABLE(sjlj-exceptions,
 198   AC_HELP_STRING([--enable-sjlj-exceptions],
 199                  [force use of builtin_setjmp for exceptions]),
 200   [case "$enableval" in
 201    yes|no|auto) ;;
 202    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 203    esac],
 204   [enable_sjlj_exceptions=auto])
 205
 206 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 207 [libgcc_cv_lib_sjlj_exceptions],
 208 [AC_LANG_CONFTEST(
 209   [AC_LANG_SOURCE([
 210 void bar ();
 211 void clean (int *);
 212 void foo ()
 213 {
 214   int i __attribute__ ((cleanup (clean)));
 215   bar();
 216 }
 217 ])])
 218 CFLAGS_hold=$CFLAGS
 219 CFLAGS="--save-temps -fexceptions"
 220 libgcc_cv_lib_sjlj_exceptions=unknown
 221 AS_IF([ac_fn_c_try_compile],
 222   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 223     libgcc_cv_lib_sjlj_exceptions=yes
 224   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 225     libgcc_cv_lib_sjlj_exceptions=no
 226   fi])
 227 CFLAGS=$CFLAGS_hold
 228 rm -f conftest*
 229 ])
 230
 231 if test "$enable_sjlj_exceptions" = "auto"; then
 232   enable_sjlj_exceptions=$libgcc_cv_lib_sjlj_exceptions
 233 fi
 234
 235 case $enable_sjlj_exceptions in
 236 yes)
 237   AC_DEFINE(LIBGCC_SJLJ_EXCEPTIONS, 1,
 238         [Define if the C compiler is configured for setjmp/longjmp exceptions.])
 239   ;;
 240 no)
 241   ;;
 242 *)
 243   AC_MSG_ERROR([unable to detect exception model])
 244   ;;
 245 esac
 246
 247 AC_LIB_PROG_LD_GNU
 248
 249 AC_MSG_CHECKING([for thread model used by GCC])
 250 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 251 AC_MSG_RESULT([$target_thread_file])
 252
 253 # Check for assembler CFI support.
 254 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 255                [AC_COMPILE_IFELSE(
 256 [asm("\n\
 257         .text\n\
 258         .cfi_startproc\n\
 259         .cfi_personality 0, symbol\n\
 260         .cfi_endproc");],
 261   [libgcc_cv_cfi=yes],
 262   [libgcc_cv_cfi=no])])
 263
 264 # Check 32bit or 64bit
 265 cat > conftest.c <<EOF
 266 #if defined(__x86_64__) || (!defined(__i386__) && defined(__LP64__))
 267 host_address=64
 268 #else
 269 host_address=32
 270 #endif
 271 EOF
 272 eval `${CC-cc} -E conftest.c | grep host_address=`
 273 rm -f conftest.c
 274
 275 # Collect host-machine-specific information.
 276 . ${srcdir}/config.host
 277
 278 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 279 # This is after config.host so we can augment tmake_file.
 280 # Link with -nostartfiles -nodefaultlibs since neither are present while
 281 # building libgcc.
 282 case ${host} in
 283 i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 284   cat > conftest.s <<EOF
 285         .section        .eh_frame,"a",@unwind
 286         .zero   4
 287         .section        .jcr,"aw",@progbits
 288         .zero   8
 289 EOF
 290   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 291       tmake_file="${tmake_file} i386/t-crtstuff"
 292   fi
 293   ;;
 294 esac
 295
 296 # Check for visibility support.  This is after config.host so that
 297 # we can check for asm_hidden_op.
 298 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 299     libgcc_cv_hidden_visibility_attribute, [
 300         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 301         libgcc_cv_hidden_visibility_attribute=no
 302         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 303             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 304                 libgcc_cv_hidden_visibility_attribute=yes
 305             fi
 306         fi
 307         rm -f conftest.*
 308     ])
 309
 310 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 311     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 312 else
 313     vis_hide=
 314 fi
 315 AC_SUBST(vis_hide)
 316
 317 # See if we have thread-local storage.  We can only test assembler
 318 # since link-time and run-time tests require the newly built
 319 # gcc, which can't be used to build executable due to that libgcc
 320 # is yet to be built here.
 321 GCC_CHECK_CC_TLS
 322 set_have_cc_tls=
 323 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 324   set_have_cc_tls="-DHAVE_CC_TLS"
 325 fi
 326 AC_SUBST(set_have_cc_tls)
 327
 328 # See if we have emulated thread-local storage.
 329 GCC_CHECK_EMUTLS
 330 set_use_emutls=
 331 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 332   set_use_emutls="-DUSE_EMUTLS"
 333 fi
 334 AC_SUBST(set_use_emutls)
 335
 336 AC_CACHE_CHECK(for init priority support, libgcc_cv_init_priority, [
 337 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,
 338   [[void ip (void) __attribute__ ((constructor (1)));]])],
 339   [libgcc_cv_init_priority=yes],[libgcc_cv_init_priority=no])])
 340 if test $libgcc_cv_init_priority = yes; then
 341   AC_DEFINE(HAVE_INIT_PRIORITY, 1,
 342   [Define if the compiler supports init priority.])
 343 fi
 344
 345 # Conditionalize the sfp-machine.h header for this target machine.
 346 if test -z "${sfp_machine_header}"; then
 347         sfp_machine_header=$cpu_type/sfp-machine.h
 348         if test -f ${srcdir}/config/${sfp_machine_header}; then
 349                 :
 350         else
 351                 sfp_machine_header=no-sfp-machine.h
 352         fi
 353 fi
 354 AC_SUBST(sfp_machine_header)
 355
 356 # Conditionalize the makefile for this target machine.
 357 tmake_file_=
 358 for f in ${tmake_file}
 359 do
 360         if test -f ${srcdir}/config/$f
 361         then
 362                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 363         fi
 364 done
 365 tmake_file="${tmake_file_}"
 366 AC_SUBST(tmake_file)
 367
 368 # Likewise export definitions for libgcc_tm.h
 369 tm_file_=
 370 for f in ${tm_file}
 371 do
 372         tm_file_="${tm_file_} \$(srcdir)/config/$f"
 373 done
 374 tm_file="${tm_file_}"
 375 AC_SUBST(tm_file)
 376 AC_SUBST(tm_defines)
 377
 378 # Map from thread model to thread header.
 379 case $target_thread_file in
 380     aix)        thread_header=config/rs6000/gthr-aix.h ;;
 381     dce)        thread_header=config/pa/gthr-dce.h ;;
 382     lynx)       thread_header=config/gthr-lynx.h ;;
 383     mipssde)    thread_header=config/mips/gthr-mipssde.h ;;
 384     posix)      thread_header=gthr-posix.h ;;
 385     rtems)      thread_header=config/gthr-rtems.h ;;
 386     single)     thread_header=gthr-single.h ;;
 387     tpf)        thread_header=config/s390/gthr-tpf.h ;;
 388     vxworks)    thread_header=config/gthr-vxworks.h ;;
 389     win32)      thread_header=config/i386/gthr-win32.h ;;
 390 esac
 391
 392 # Substitute configuration variables
 393 AC_SUBST(cpu_type)
 394 AC_SUBST(extra_parts)
 395 AC_SUBST(asm_hidden_op)
 396 AC_CONFIG_LINKS([enable-execute-stack.c:$enable_execute_stack])
 397 AC_CONFIG_LINKS([unwind.h:$unwind_header])
 398 AC_CONFIG_LINKS([md-unwind-support.h:config/$md_unwind_header])
 399 AC_CONFIG_LINKS([sfp-machine.h:config/$sfp_machine_header])
 400 AC_CONFIG_LINKS([gthr-default.h:$thread_header])
 401
 402 # We need multilib support.
 403 AC_CONFIG_FILES([Makefile])
 404 AC_CONFIG_COMMANDS([default],
 405   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 406 if test -n "$CONFIG_FILES"; then
 407   # FIXME: We shouldn't need to set ac_file
 408   ac_file=Makefile
 409   . ${libgcc_topdir}/config-ml.in
 410 fi]],
 411 [[srcdir=${srcdir}
 412 host=${host}
 413 with_target_subdir=${with_target_subdir}
 414 with_multisubdir=${with_multisubdir}
 415 ac_configure_args="--enable-multilib ${ac_configure_args}"
 416 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 417 libgcc_topdir=${libgcc_topdir}
 418 CC="${CC}"
 419 ]])
 420 AC_OUTPUT