libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/lib-ld.m4)
   8 sinclude(../config/override.m4)
   9 sinclude(../config/picflag.m4)
  10 sinclude(../config/dfp.m4)
  11 sinclude(../config/unwind_ipinfo.m4)
  12 sinclude(../config/gthr.m4)
  13 sinclude(../config/sjlj.m4)
  14 sinclude(../config/cet.m4)
  15
  16 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  17 AC_CONFIG_SRCDIR([static-object.mk])
  18
  19 # The libgcc should not depend on any header files
  20 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  21   [m4_divert_text([DEFAULTS],
  22     [ac_includes_default='/* none */'])])
  23
  24 AC_ARG_WITH(target-subdir,
  25 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  26 AC_ARG_WITH(cross-host,
  27 [  --with-cross-host=HOST           Configuring with a cross compiler])
  28 AC_ARG_WITH(ld,
  29 [  --with-ld               arrange to use the specified ld (full pathname)])
  30
  31 if test "${srcdir}" = "."; then
  32   if test -n "${with_build_subdir}"; then
  33     libgcc_topdir="${srcdir}/../.."
  34     with_target_subdir=
  35   elif test -z "${with_target_subdir}"; then
  36     libgcc_topdir="${srcdir}/.."
  37   else
  38     if test "${with_target_subdir}" != "."; then
  39       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  40     else
  41       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  42     fi
  43   fi
  44 else
  45   libgcc_topdir="${srcdir}/.."
  46 fi
  47 AC_SUBST(libgcc_topdir)
  48 AC_CONFIG_AUX_DIR($libgcc_topdir)
  49 AC_CONFIG_HEADER(auto-target.h:config.in)
  50
  51 AC_ARG_ENABLE(shared,
  52 [  --disable-shared        don't provide a shared libgcc],
  53 [
  54   case $enable_shared in
  55   yes | no) ;;
  56   *)
  57     enable_shared=no
  58     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  59     for pkg in $enableval; do
  60       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  61         enable_shared=yes
  62       fi
  63     done
  64     IFS="$ac_save_ifs"
  65     ;;
  66   esac
  67 ], [enable_shared=yes])
  68 AC_SUBST(enable_shared)
  69
  70 AC_ARG_ENABLE(gcov,
  71 [  --disable-gcov          don't provide libgcov and related host tools],
  72 [], [enable_gcov=yes])
  73 AC_SUBST(enable_gcov)
  74
  75 AC_ARG_ENABLE(vtable-verify,
  76 [  --enable-vtable-verify    Enable vtable verification feature ],
  77 [case "$enableval" in
  78  yes) enable_vtable_verify=yes ;;
  79  no)  enable_vtable_verify=no ;;
  80  *)   enable_vtable_verify=no;;
  81  esac],
  82 [enable_vtable_verify=no])
  83 AC_SUBST(enable_vtable_verify)
  84
  85 AC_ARG_WITH(aix-soname,
  86 [AS_HELP_STRING([--with-aix-soname=aix|svr4|both],
  87     [shared library versioning (aka "SONAME") variant to provide on AIX])],
  88 [case "${host}:${enable_shared}" in
  89  power*-*-aix[[5-9]]*:yes)
  90    AC_MSG_CHECKING([which variant of shared library versioning to provide for shared libgcc])
  91    case ${withval} in
  92      aix|svr4|both) ;;
  93      *) AC_MSG_ERROR([Unknown argument to --with-aix-soname]);;
  94    esac
  95    AC_MSG_RESULT($withval)
  96    ;;
  97  *) with_aix_soname=aix ;;
  98  esac
  99 ], [with_aix_soname=aix])
 100 AC_SUBST(with_aix_soname)
 101
 102 GCC_PICFLAG
 103 AC_SUBST(PICFLAG)
 104
 105 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 106 AC_ARG_ENABLE(version-specific-runtime-libs,
 107 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
 108 [case "$enableval" in
 109  yes) version_specific_libs=yes ;;
 110  no)  version_specific_libs=no ;;
 111  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 112  esac],
 113 [version_specific_libs=no])
 114 AC_MSG_RESULT($version_specific_libs)
 115
 116 AC_ARG_WITH(slibdir,
 117 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
 118 slibdir="$with_slibdir",
 119 if test "${version_specific_libs}" = yes; then
 120   slibdir='$(libsubdir)'
 121 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
 122   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
 123 else
 124   slibdir='$(libdir)'
 125 fi)
 126 AC_SUBST(slibdir)
 127
 128 # Command-line options.
 129 # Very limited version of AC_MAINTAINER_MODE.
 130 AC_ARG_ENABLE([maintainer-mode],
 131   [AC_HELP_STRING([--enable-maintainer-mode],
 132                  [enable make rules and dependencies not useful (and
 133                   sometimes confusing) to the casual installer])],
 134   [case ${enable_maintainer_mode} in
 135      yes) MAINT='' ;;
 136      no) MAINT='#' ;;
 137      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
 138    esac
 139    maintainer_mode=${enableval}],
 140   [MAINT='#'])
 141 AC_SUBST([MAINT])dnl
 142
 143 AC_PROG_INSTALL
 144
 145 AC_PROG_AWK
 146 # We need awk; bail out if it's missing.
 147 case ${AWK} in
 148   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 149 esac
 150
 151 AC_CANONICAL_HOST
 152 ACX_NONCANONICAL_HOST
 153 ACX_NONCANONICAL_TARGET
 154 GCC_TOPLEV_SUBDIRS
 155
 156 # Calculate toolexeclibdir
 157 # Also toolexecdir, though it's only used in toolexeclibdir
 158 case ${version_specific_libs} in
 159   yes)
 160     # Need the gcc compiler version to know where to install libraries
 161     # and header files if --enable-version-specific-runtime-libs option
 162     # is selected.
 163     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 164     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 165     ;;
 166   no)
 167     if test -n "$with_cross_host" &&
 168        test x"$with_cross_host" != x"no"; then
 169       # Install a library built with a cross compiler in tooldir, not libdir.
 170       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 171       toolexeclibdir='$(toolexecdir)/lib'
 172     else
 173       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 174       toolexeclibdir='$(libdir)'
 175     fi
 176     multi_os_directory=`$CC -print-multi-os-directory`
 177     case $multi_os_directory in
 178       .) ;; # Avoid trailing /.
 179       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 180     esac
 181     ;;
 182 esac
 183 AC_SUBST(toolexecdir)
 184 AC_SUBST(toolexeclibdir)
 185
 186 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 187 dnl to call AC_CHECK_PROG.
 188 AC_CHECK_TOOL(AR, ar)
 189 AC_CHECK_TOOL(LIPO, lipo, :)
 190 AC_CHECK_TOOL(NM, nm)
 191 AC_CHECK_TOOL(RANLIB, ranlib, :)
 192 AC_CHECK_TOOL(STRIP, strip, :)
 193 AC_PROG_LN_S
 194
 195 GCC_NO_EXECUTABLES
 196 AC_PROG_CC
 197 AC_PROG_CPP_WERROR
 198
 199 AC_SYS_LARGEFILE
 200
 201 AC_CHECK_SIZEOF([double])
 202 AC_CHECK_SIZEOF([long double])
 203 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 204 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 205 AC_SUBST(double_type_size)
 206 AC_SUBST(long_double_type_size)
 207
 208 AC_CHECK_HEADERS(inttypes.h stdint.h stdlib.h ftw.h \
 209         unistd.h sys/stat.h sys/types.h \
 210         string.h strings.h memory.h sys/auxv.h)
 211 AC_HEADER_STDC
 212
 213 # Check for decimal float support.
 214 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 215                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 216 #include <fenv.h>
 217 ]], [[
 218 _Decimal32 x;
 219 int fe_except =
 220   FE_INVALID|FE_DIVBYZERO|FE_OVERFLOW|FE_UNDERFLOW|FE_INEXACT;
 221 ]])],
 222                                   [libgcc_cv_dfp=yes],
 223                                   [libgcc_cv_dfp=no])])
 224 decimal_float=$libgcc_cv_dfp
 225 AC_SUBST(decimal_float)
 226
 227 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 228
 229 # Check for fixed-point support.
 230 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 231                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Sat _Fract x;])],
 232                                   [libgcc_cv_fixed_point=yes],
 233                                   [libgcc_cv_fixed_point=no])])
 234 fixed_point=$libgcc_cv_fixed_point
 235 AC_SUBST(fixed_point)
 236
 237 # For platforms with the unwind ABI which includes an unwind library,
 238 # libunwind, we can choose to use the system libunwind.
 239 # config.gcc also contains tests of with_system_libunwind.
 240 GCC_CHECK_UNWIND_GETIPINFO
 241
 242 # Check if the compiler is configured for setjmp/longjmp exceptions.
 243 GCC_CHECK_SJLJ_EXCEPTIONS
 244
 245 GCC_CET_FLAGS(CET_FLAGS)
 246 AC_SUBST(CET_FLAGS)
 247
 248 AC_ARG_ENABLE([explicit-exception-frame-registration],
 249   [AC_HELP_STRING([--enable-explicit-exception-frame-registration],
 250      [register exception tables explicitly at module start, for use
 251       e.g. for compatibility with installations without PT_GNU_EH_FRAME support])],
 252 [
 253 force_explicit_eh_registry=
 254 if test "$enable_explicit_exception_frame_registration" = yes; then
 255   if test $ac_cv_sjlj_exceptions = yes; then
 256     AC_MSG_ERROR([Can't --enable-explicit-exception-frame-registration
 257                   with setjmp/longjmp exceptions])
 258   fi
 259   force_explicit_eh_registry=-DUSE_EH_FRAME_REGISTRY_ALWAYS
 260 fi
 261 ])
 262 AC_SUBST([force_explicit_eh_registry])
 263
 264 AC_ARG_ENABLE([tm-clone-registry],
 265 [  --disable-tm-clone-registry    disable TM clone registry],
 266 [
 267 use_tm_clone_registry=
 268 if test "$enable_tm_clone_registry" = no; then
 269   use_tm_clone_registry=-DUSE_TM_CLONE_REGISTRY=0
 270 fi
 271 ],
 272 [
 273 use_tm_clone_registry=
 274 case $target in
 275   msp430*elfbare)
 276    use_tm_clone_registry=-DUSE_TM_CLONE_REGISTRY=0
 277    ;;
 278 esac
 279 ])
 280 AC_SUBST([use_tm_clone_registry])
 281
 282 AC_LIB_PROG_LD_GNU
 283
 284 AC_MSG_CHECKING([for thread model used by GCC])
 285 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 286 AC_MSG_RESULT([$target_thread_file])
 287
 288 # Check for assembler CFI support.
 289 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 290                [AC_COMPILE_IFELSE(
 291 [AC_LANG_SOURCE([asm("\n\
 292         .text\n\
 293         .cfi_startproc\n\
 294         .cfi_personality 0, symbol\n\
 295         .cfi_endproc");])],
 296   [libgcc_cv_cfi=yes],
 297   [libgcc_cv_cfi=no])])
 298
 299 # Check 32bit or 64bit.  In the case of MIPS, this really determines the
 300 # word size rather than the address size.
 301 cat > conftest.c <<EOF
 302 #if defined(__x86_64__) || (!defined(__i386__) && defined(__LP64__)) \
 303     || defined(__mips64)
 304 host_address=64
 305 #else
 306 host_address=32
 307 #endif
 308 EOF
 309 eval `${CC-cc} -E conftest.c | grep host_address=`
 310 rm -f conftest.c
 311
 312 case ${host} in
 313 mips*-*-*)
 314   AC_CACHE_CHECK([whether the target is hard-float],
 315                  [libgcc_cv_mips_hard_float],
 316                  [AC_COMPILE_IFELSE(
 317     [AC_LANG_SOURCE([#ifndef __mips_hard_float
 318      #error FOO
 319      #endif
 320     ])],
 321     [libgcc_cv_mips_hard_float=yes],
 322     [libgcc_cv_mips_hard_float=no])])
 323 esac
 324
 325 case ${host} in
 326 *-*-solaris2*)
 327   # Check for system-provided CRTs on Solaris 11.4.
 328   AC_CACHE_CHECK([system-provided CRTs on Solaris],
 329                  [libgcc_cv_solaris_crts],
 330     [libgcc_cv_solaris_crts=no
 331      libgcc_sysroot="`${CC} -print-sysroot`"
 332      libgcc_libdir="$libgcc_sysroot/usr/lib"
 333      # At the time they were added, gcrt1.o became a symlink for backwards
 334      # compatibility on x86, while crt1.o was added on sparc, so check for that.
 335      case ${host} in
 336        i?86-*-solaris2* | x86_64-*-solaris2*)
 337          if test -h "$libgcc_libdir/gcrt1.o"; then libgcc_cv_solaris_crts=yes; fi
 338          ;;
 339        sparc*-*-solaris2*)
 340          if test -f "$libgcc_libdir/crt1.o"; then libgcc_cv_solaris_crts=yes; fi
 341          ;;
 342      esac])
 343   if test $libgcc_cv_solaris_crts = yes; then
 344     AC_DEFINE(HAVE_SOLARIS_CRTS, 1,
 345       [Define if the system-provided CRTs are present on Solaris.])
 346   fi
 347   ;;
 348 esac
 349
 350 # Determine the version of glibc, if any, used on the target.
 351 AC_MSG_CHECKING([for target glibc version])
 352 AC_ARG_WITH([glibc-version],
 353   [AS_HELP_STRING([--with-glibc-version=M.N],
 354     [assume GCC used with glibc version M.N or later])], [
 355 if [echo "$with_glibc_version" | grep '^[0-9][0-9]*\.[0-9][0-9]*$']; then
 356   glibc_version_major=`echo "$with_glibc_version" | sed -e 's/\..*//'`
 357   glibc_version_minor=`echo "$with_glibc_version" | sed -e 's/.*\.//'`
 358 else
 359   AC_MSG_ERROR([option --with-glibc-version requires a version number M.N])
 360 fi], [
 361 AC_COMPUTE_INT([glibc_version_major], [__GLIBC__],
 362                                       [#include <features.h>],
 363                                       [glibc_version_major=0])
 364 AC_COMPUTE_INT([glibc_version_minor], [__GLIBC_MINOR__],
 365                                       [#include <features.h>],
 366                                       [glibc_version_minor=0])])
 367 AC_MSG_RESULT([$glibc_version_major.$glibc_version_minor])
 368
 369 # Determine floating-point type for powerpc*-*-linux*.
 370 # Single-precision-only FPRs are not a supported configuration for
 371 # this target, so are not allowed for in this test.
 372 case ${host} in
 373 powerpc*-*-linux*)
 374   cat > conftest.c <<EOF
 375 #ifdef __powerpc64__
 376 ppc_fp_type=64
 377 #elif defined _SOFT_FLOAT
 378 ppc_fp_type=soft
 379 #elif defined _SOFT_DOUBLE
 380 ppc_fp_type=e500v1
 381 #elif defined __NO_FPRS__
 382 ppc_fp_type=e500v2
 383 #else
 384 ppc_fp_type=hard
 385 #endif
 386 EOF
 387 eval `${CC-cc} -E conftest.c | grep ppc_fp_type=`
 388 rm -f conftest.c
 389 # glibc 2.19 and later provide all the soft-fp functions, with proper
 390 # interactions with <fenv.h> exception and rounding mode handling, so
 391 # make libgcc's versions into compat symbols if a recent enough glibc
 392 # version is being used.
 393 ppc_fp_compat=
 394 case ${ppc_fp_type} in
 395 soft|e500v1|e500v2)
 396   if test $glibc_version_major -gt 2 \
 397     || ( test $glibc_version_major -eq 2 \
 398         && test $glibc_version_minor -ge 19 ); then
 399     ppc_fp_compat="t-softfp-compat"
 400   fi
 401   ;;
 402 esac
 403 ;;
 404 esac
 405
 406 case ${host} in
 407 # At present, we cannot turn -mfloat128 on via #pragma GCC target, so just
 408 # check if we have VSX (ISA 2.06) support to build the software libraries, and
 409 # whether the assembler can handle xsaddqp for hardware support.  Also check if
 410 # a new glibc is being used so that __builtin_cpu_supports can be used.
 411 powerpc*-*-linux*)
 412   saved_CFLAGS="$CFLAGS"
 413   CFLAGS="$CFLAGS -mabi=altivec -mvsx -mfloat128"
 414   AC_CACHE_CHECK([for PowerPC ISA 2.06 to build __float128 libraries],
 415                  [libgcc_cv_powerpc_float128],
 416                  [AC_COMPILE_IFELSE(
 417     [AC_LANG_SOURCE([vector double dadd (vector double a, vector double b) { return a + b; }])],
 418     [libgcc_cv_powerpc_float128=yes],
 419     [libgcc_cv_powerpc_float128=no])])
 420
 421   CFLAGS="$CFLAGS -mpower9-vector -mfloat128-hardware"
 422   AC_CACHE_CHECK([for PowerPC ISA 3.0 to build hardware __float128 libraries],
 423                  [libgcc_cv_powerpc_float128_hw],
 424                  [AC_COMPILE_IFELSE(
 425     [AC_LANG_SOURCE([#include <sys/auxv.h>
 426      #ifndef AT_PLATFORM
 427      #error "AT_PLATFORM is not defined"
 428      #endif
 429      #ifndef __BUILTIN_CPU_SUPPORTS__
 430      #error "__builtin_cpu_supports is not available"
 431      #endif
 432      vector unsigned char add (vector unsigned char a, vector unsigned char b)
 433      {
 434        vector unsigned char ret;
 435        __asm__ ("xsaddqp %0,%1,%2" : "=v" (ret) : "v" (a), "v" (b));
 436        return ret;
 437      }
 438      void *add_resolver (void) { return (void *) add; }
 439      __float128 add_ifunc (__float128, __float128)
 440         __attribute__ ((__ifunc__ ("add_resolver")));])],
 441     [libgcc_cv_powerpc_float128_hw=yes],
 442     [libgcc_cv_powerpc_float128_hw=no])])
 443   CFLAGS="$saved_CFLAGS"
 444 esac
 445
 446 # Collect host-machine-specific information.
 447 . ${srcdir}/config.host
 448
 449 # Used for constructing correct paths for offload compilers.
 450 accel_dir_suffix=
 451 real_host_noncanonical=${host_noncanonical}
 452 if test x"$enable_as_accelerator_for" != x; then
 453   accel_dir_suffix=/accel/${target_noncanonical}
 454   real_host_noncanonical=${enable_as_accelerator_for}
 455 fi
 456 AC_SUBST(accel_dir_suffix)
 457 AC_SUBST(real_host_noncanonical)
 458
 459 if test x"$enable_offload_targets" != x; then
 460   extra_parts="${extra_parts} crtoffloadbegin.o crtoffloadend.o crtoffloadtable.o"
 461 fi
 462
 463 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 464 # This is after config.host so we can augment tmake_file.
 465 # Link with -nostartfiles -nodefaultlibs since neither are present while
 466 # building libgcc.
 467 case ${host} in
 468 i?86-*-solaris2* | x86_64-*-solaris2*)
 469   cat > conftest.s <<EOF
 470         .section        .eh_frame,"a",@unwind
 471         .zero   4
 472         .section        .jcr,"aw",@progbits
 473         .zero   8
 474 EOF
 475   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 476       tmake_file="${tmake_file} i386/t-crtstuff"
 477   fi
 478   ;;
 479 esac
 480
 481 # Check if Solaris linker support v2 linker mapfile syntax.
 482 # Link with -nostartfiles -nodefaultlibs since neither are present while
 483 # building libgcc.
 484 case ${host} in
 485 *-*-solaris2*)
 486   solaris_ld_v2_maps=no
 487   echo 'int main(void) {return 0;}' > conftest.c
 488   echo '$mapfile_version 2' > conftest.map
 489   if AC_TRY_COMMAND([${CC-cc} -nostartfiles -nodefaultlibs -Wl,-M,conftest.map -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
 490       solaris_ld_v2_maps=yes
 491   fi
 492   ;;
 493 esac
 494 AC_SUBST(solaris_ld_v2_maps)
 495
 496 # Check if xtensa target is configured for windowed ABI and thus needs to use
 497 # custom unwind code.
 498 # This is after config.host so we can augment tmake_file.
 499 case ${host} in
 500 xtensa*-*)
 501   cat > conftest.c <<EOF
 502         #ifdef __XTENSA_CALL0_ABI__
 503         #error
 504         #endif
 505 EOF
 506   if AC_TRY_COMMAND(${CC-cc} -E -o conftest.i conftest.c 1>&AS_MESSAGE_LOG_FD); then
 507       tmake_file="${tmake_file} xtensa/t-windowed"
 508   fi
 509   ;;
 510 esac
 511
 512 # Check for visibility support.  This is after config.host so that
 513 # we can check for asm_hidden_op.
 514 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 515     libgcc_cv_hidden_visibility_attribute, [
 516         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 517         libgcc_cv_hidden_visibility_attribute=no
 518         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 519             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 520                 libgcc_cv_hidden_visibility_attribute=yes
 521             fi
 522         fi
 523         rm -f conftest.*
 524     ])
 525
 526 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 527     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 528     AC_DEFINE_UNQUOTED(AS_HIDDEN_DIRECTIVE, $asm_hidden_op, [Define to the .hidden-like directive if it exists.])
 529 else
 530     vis_hide=
 531 fi
 532 AC_SUBST(vis_hide)
 533
 534 # Check for .cfi_sections .debug_frame support.
 535 AC_CACHE_CHECK([for .cfi_sections .debug_frame],
 536     libgcc_cv_cfi_sections_directive, [
 537         echo 'int foo (int, char *);' > conftest.c
 538         echo 'int bar (int x) { char *y = __builtin_alloca (x); return foo (x + 1, y) + 1; }' >> conftest.c
 539         libgcc_cv_cfi_sections_directive=no
 540         if AC_TRY_COMMAND(${CC-cc} -Werror -g -fno-asynchronous-unwind-tables -fno-unwind-tables -fno-exceptions -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 541             if grep "\\.cfi_sections.*\\.debug_frame" conftest.s >/dev/null; then
 542                 libgcc_cv_cfi_sections_directive=yes
 543             fi
 544         fi
 545         rm -f conftest.*
 546     ])
 547 if test $libgcc_cv_cfi_sections_directive = yes; then
 548     AC_DEFINE(HAVE_AS_CFI_SECTIONS, 1, [Define to 1 if the assembler supports .cfi_sections .debug_frame directive.])
 549 fi
 550
 551 # See if we have thread-local storage.  We can only test assembler
 552 # since link-time and run-time tests require the newly built
 553 # gcc, which can't be used to build executable due to that libgcc
 554 # is yet to be built here.
 555 GCC_CHECK_CC_TLS
 556 set_have_cc_tls=
 557 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 558   set_have_cc_tls="-DHAVE_CC_TLS"
 559 fi
 560 AC_SUBST(set_have_cc_tls)
 561
 562 # See if we have emulated thread-local storage.
 563 GCC_CHECK_EMUTLS
 564 set_use_emutls=
 565 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 566   set_use_emutls="-DUSE_EMUTLS"
 567 fi
 568 AC_SUBST(set_use_emutls)
 569
 570 dnl Check if as supports AVX instructions.
 571 AC_DEFUN([LIBGCC_CHECK_AS_AVX], [
 572 case "${target}" in
 573 i[[34567]]86-*-* | x86_64-*-*)
 574   AC_CACHE_CHECK([if the assembler supports AVX], libgcc_cv_as_avx, [
 575     AC_TRY_COMPILE([], [asm("vzeroupper");],
 576                    [libgcc_cv_as_avx=yes], [libgcc_cv_as_avx=no])
 577   ])
 578   if test x$libgcc_cv_as_avx = xyes; then
 579     AC_DEFINE(HAVE_AS_AVX, 1, [Define to 1 if the assembler supports AVX.])
 580   fi
 581   ;;
 582 esac])
 583 LIBGCC_CHECK_AS_AVX
 584
 585 dnl Check if as supports RTM instructions.
 586 AC_CACHE_CHECK(for init priority support, libgcc_cv_init_priority, [
 587 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,
 588   [[void ip (void) __attribute__ ((constructor (1)));]])],
 589   [libgcc_cv_init_priority=yes],[libgcc_cv_init_priority=no])])
 590 if test $libgcc_cv_init_priority = yes; then
 591   AC_DEFINE(HAVE_INIT_PRIORITY, 1,
 592   [Define if the compiler supports init priority.])
 593 fi
 594
 595 # Conditionalize the sfp-machine.h header for this target machine.
 596 if test -z "${sfp_machine_header}"; then
 597         sfp_machine_header=$cpu_type/sfp-machine.h
 598         if test -f ${srcdir}/config/${sfp_machine_header}; then
 599                 :
 600         else
 601                 sfp_machine_header=no-sfp-machine.h
 602         fi
 603 fi
 604 AC_SUBST(sfp_machine_header)
 605
 606 # Conditionalize the makefile for this target machine.
 607 tmake_file_=
 608 for f in ${tmake_file}
 609 do
 610         if test -f ${srcdir}/config/$f
 611         then
 612                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 613         fi
 614 done
 615 tmake_file="${tmake_file_}"
 616 AC_SUBST(tmake_file)
 617
 618 # Likewise export definitions for libgcc_tm.h
 619 tm_file_=
 620 for f in ${tm_file}
 621 do
 622         tm_file_="${tm_file_} \$(srcdir)/config/$f"
 623 done
 624 tm_file="${tm_file_}"
 625 AC_SUBST(tm_file)
 626 AC_SUBST(tm_defines)
 627
 628 # Map from thread model to thread header.
 629 GCC_AC_THREAD_HEADER([$target_thread_file])
 630
 631 # Determine what GCC version number to use in filesystem paths.
 632 GCC_BASE_VER
 633
 634 # Substitute configuration variables
 635 AC_SUBST(cpu_type)
 636 AC_SUBST(extra_parts)
 637 AC_SUBST(asm_hidden_op)
 638 AC_SUBST(enable_execute_stack)
 639 AC_SUBST(unwind_header)
 640 AC_SUBST(md_unwind_header)
 641 AC_SUBST(sfp_machine_header)
 642 AC_SUBST(thread_header)
 643
 644 # We need multilib support.
 645 AC_CONFIG_FILES([Makefile])
 646 AC_CONFIG_COMMANDS([default],
 647   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 648 if test -n "$CONFIG_FILES"; then
 649   # FIXME: We shouldn't need to set ac_file
 650   ac_file=Makefile
 651   . ${libgcc_topdir}/config-ml.in
 652 fi]],
 653 [[srcdir=${srcdir}
 654 host=${host}
 655 with_target_subdir=${with_target_subdir}
 656 with_multisubdir=${with_multisubdir}
 657 ac_configure_args="--enable-multilib ${ac_configure_args}"
 658 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 659 libgcc_topdir=${libgcc_topdir}
 660 CC="${CC}"
 661 ]])
 662 AC_OUTPUT