libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/override.m4)
   8 sinclude(../config/dfp.m4)
   9
  10 AC_PREREQ(2.64)
  11 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  12 AC_CONFIG_SRCDIR([static-object.mk])
  13
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(cross-host,
  17 [  --with-cross-host=HOST           Configuring with a cross compiler])
  18 AC_ARG_WITH(ld,
  19 [  --with-ld               arrange to use the specified ld (full pathname)])
  20
  21 if test "${srcdir}" = "."; then
  22   if test -n "${with_build_subdir}"; then
  23     libgcc_topdir="${srcdir}/../.."
  24     with_target_subdir=
  25   elif test -z "${with_target_subdir}"; then
  26     libgcc_topdir="${srcdir}/.."
  27   else
  28     if test "${with_target_subdir}" != "."; then
  29       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  30     else
  31       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  32     fi
  33   fi
  34 else
  35   libgcc_topdir="${srcdir}/.."
  36 fi
  37 AC_SUBST(libgcc_topdir)
  38 AC_CONFIG_AUX_DIR($libgcc_topdir)
  39
  40 AC_ARG_ENABLE(shared,
  41 [  --disable-shared        don't provide a shared libgcc],
  42 [
  43   case $enable_shared in
  44   yes | no) ;;
  45   *)
  46     enable_shared=no
  47     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  48     for pkg in $enableval; do
  49       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  50         enable_shared=yes
  51       fi
  52     done
  53     IFS="$ac_save_ifs"
  54     ;;
  55   esac
  56 ], [enable_shared=yes])
  57 AC_SUBST(enable_shared)
  58
  59 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  60 AC_ARG_ENABLE(version-specific-runtime-libs,
  61 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  62 [case "$enableval" in
  63  yes) version_specific_libs=yes ;;
  64  no)  version_specific_libs=no ;;
  65  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  66  esac],
  67 [version_specific_libs=no])
  68 AC_MSG_RESULT($version_specific_libs)
  69
  70 AC_ARG_WITH(slibdir,
  71 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
  72 slibdir="$with_slibdir",
  73 if test "${version_specific_libs}" = yes; then
  74   slibdir='$(libsubdir)'
  75 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
  76   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
  77 else
  78   slibdir='$(libdir)'
  79 fi)
  80 AC_SUBST(slibdir)
  81
  82 # Command-line options.
  83 # Very limited version of AC_MAINTAINER_MODE.
  84 AC_ARG_ENABLE([maintainer-mode],
  85   [AC_HELP_STRING([--enable-maintainer-mode],
  86                  [enable make rules and dependencies not useful (and
  87                   sometimes confusing) to the casual installer])],
  88   [case ${enable_maintainer_mode} in
  89      yes) MAINT='' ;;
  90      no) MAINT='#' ;;
  91      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
  92    esac
  93    maintainer_mode=${enableval}],
  94   [MAINT='#'])
  95 AC_SUBST([MAINT])dnl
  96
  97 AC_PROG_INSTALL
  98
  99 AC_PROG_AWK
 100 # We need awk; bail out if it's missing.
 101 case ${AWK} in
 102   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 103 esac
 104
 105 AC_CANONICAL_HOST
 106 ACX_NONCANONICAL_HOST
 107 ACX_NONCANONICAL_TARGET
 108 GCC_TOPLEV_SUBDIRS
 109
 110 # Calculate toolexeclibdir
 111 # Also toolexecdir, though it's only used in toolexeclibdir
 112 case ${version_specific_libs} in
 113   yes)
 114     # Need the gcc compiler version to know where to install libraries
 115     # and header files if --enable-version-specific-runtime-libs option
 116     # is selected.
 117     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 118     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 119     ;;
 120   no)
 121     if test -n "$with_cross_host" &&
 122        test x"$with_cross_host" != x"no"; then
 123       # Install a library built with a cross compiler in tooldir, not libdir.
 124       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 125       toolexeclibdir='$(toolexecdir)/lib'
 126     else
 127       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 128       toolexeclibdir='$(libdir)'
 129     fi
 130     multi_os_directory=`$CC -print-multi-os-directory`
 131     case $multi_os_directory in
 132       .) ;; # Avoid trailing /.
 133       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 134     esac
 135     ;;
 136 esac
 137 AC_SUBST(toolexecdir)
 138 AC_SUBST(toolexeclibdir)
 139
 140 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 141 dnl to call AC_CHECK_PROG.
 142 AC_CHECK_TOOL(AR, ar)
 143 AC_CHECK_TOOL(LIPO, lipo, :)
 144 AC_CHECK_TOOL(NM, nm)
 145 AC_CHECK_TOOL(RANLIB, ranlib, :)
 146 AC_CHECK_TOOL(STRIP, strip, :)
 147 AC_PROG_LN_S
 148
 149 GCC_NO_EXECUTABLES
 150 AC_PROG_CC
 151 AC_PROG_CPP_WERROR
 152
 153 # Check for decimal float support.
 154 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 155                [AC_COMPILE_IFELSE([_Decimal32 x;], [libgcc_cv_dfp=yes],
 156                                   [libgcc_cv_dfp=no])])
 157 decimal_float=$libgcc_cv_dfp
 158 AC_SUBST(decimal_float)
 159
 160 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 161
 162 # Check for fixed-point support.
 163 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 164                [AC_COMPILE_IFELSE([_Sat _Fract x;], [libgcc_cv_fixed_point=yes],
 165                                   [libgcc_cv_fixed_point=no])])
 166 fixed_point=$libgcc_cv_fixed_point
 167 AC_SUBST(fixed_point)
 168
 169 # Check for assembler CFI support.
 170 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 171                [AC_COMPILE_IFELSE(
 172 [asm("\n\
 173         .text\n\
 174         .cfi_startproc\n\
 175         .cfi_personality 0, symbol\n\
 176         .cfi_endproc");],
 177   [libgcc_cv_cfi=yes],
 178   [libgcc_cv_cfi=no])])
 179
 180 # Check 32bit or 64bit for x86.
 181 case ${host} in
 182 i?86*-*-* | x86_64*-*-*)
 183   cat > conftest.c <<EOF
 184 #ifdef __x86_64__
 185 host_address=64
 186 #else
 187 host_address=32
 188 #endif
 189 EOF
 190     eval `${CC-cc} -E conftest.c | grep host_address=`
 191     rm -f conftest.c
 192     ;;
 193 esac
 194
 195 # Collect host-machine-specific information.
 196 . ${srcdir}/config.host
 197
 198 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 199 # This is after config.host so we can augment tmake_file.
 200 # Link with -nostartfiles -nodefaultlibs since neither are present while
 201 # building libgcc.
 202 case ${host} in
 203 i?86-*-solaris2*)
 204   cat > conftest.s <<EOF
 205         .section        .eh_frame,"a",@unwind
 206         .zero   4
 207         .section        .jcr,"aw",@progbits
 208         .zero   8
 209 EOF
 210   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 211       # configure expects config files in libgcc/config, so need a relative
 212       # path here.
 213       tmake_file="${tmake_file} ../../gcc/config/i386/t-crtstuff"
 214   fi
 215   ;;
 216 esac
 217
 218 # Check for visibility support.  This is after config.host so that
 219 # we can check for asm_hidden_op.
 220 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 221     libgcc_cv_hidden_visibility_attribute, [
 222         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 223         libgcc_cv_hidden_visibility_attribute=no
 224         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 225             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 226                 libgcc_cv_hidden_visibility_attribute=yes
 227             fi
 228         fi
 229         rm -f conftest.*
 230     ])
 231
 232 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 233     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 234 else
 235     vis_hide=
 236 fi
 237 AC_SUBST(vis_hide)
 238
 239 # See if we have thread-local storage.  We can only test assembler
 240 # sicne link-time and run-time tests require the newly built
 241 # gcc, which can't be used to build executable due to that libgcc
 242 # is yet to be built here.
 243 GCC_CHECK_CC_TLS
 244 set_have_cc_tls=
 245 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 246   set_have_cc_tls="-DHAVE_CC_TLS"
 247 fi
 248 AC_SUBST(set_have_cc_tls)
 249
 250 # See if we have emulated thread-local storage.
 251 GCC_CHECK_EMUTLS
 252 set_use_emutls=
 253 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 254   set_use_emutls="-DUSE_EMUTLS"
 255 fi
 256 AC_SUBST(set_use_emutls)
 257
 258 # Conditionalize the makefile for this target machine.
 259 tmake_file_=
 260 for f in ${tmake_file}
 261 do
 262         if test -f ${srcdir}/config/$f
 263         then
 264                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 265         fi
 266 done
 267 tmake_file="${tmake_file_}"
 268 AC_SUBST(tmake_file)
 269
 270 # Substitute configuration variables
 271 AC_SUBST(extra_parts)
 272 AC_SUBST(asm_hidden_op)
 273
 274 # We need multilib support.
 275 AC_CONFIG_FILES([Makefile])
 276 AC_CONFIG_COMMANDS([default],
 277   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 278 if test -n "$CONFIG_FILES"; then
 279   # FIXME: We shouldn't need to set ac_file
 280   ac_file=Makefile
 281   . ${libgcc_topdir}/config-ml.in
 282 fi]],
 283 [[srcdir=${srcdir}
 284 host=${host}
 285 with_target_subdir=${with_target_subdir}
 286 with_multisubdir=${with_multisubdir}
 287 ac_configure_args="--enable-multilib ${ac_configure_args}"
 288 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 289 libgcc_topdir=${libgcc_topdir}
 290 CC="${CC}"
 291 ]])
 292 AC_OUTPUT