libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/lib-ld.m4)
   8 sinclude(../config/override.m4)
   9 sinclude(../config/picflag.m4)
  10 sinclude(../config/dfp.m4)
  11 sinclude(../config/unwind_ipinfo.m4)
  12 sinclude(../config/gthr.m4)
  13
  14 AC_PREREQ(2.64)
  15 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  16 AC_CONFIG_SRCDIR([static-object.mk])
  17
  18 # The libgcc should not depend on any header files
  19 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  20   [m4_divert_text([DEFAULTS],
  21     [ac_includes_default='/* none */'])])
  22
  23 AC_ARG_WITH(target-subdir,
  24 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  25 AC_ARG_WITH(cross-host,
  26 [  --with-cross-host=HOST           Configuring with a cross compiler])
  27 AC_ARG_WITH(ld,
  28 [  --with-ld               arrange to use the specified ld (full pathname)])
  29
  30 if test "${srcdir}" = "."; then
  31   if test -n "${with_build_subdir}"; then
  32     libgcc_topdir="${srcdir}/../.."
  33     with_target_subdir=
  34   elif test -z "${with_target_subdir}"; then
  35     libgcc_topdir="${srcdir}/.."
  36   else
  37     if test "${with_target_subdir}" != "."; then
  38       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  39     else
  40       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  41     fi
  42   fi
  43 else
  44   libgcc_topdir="${srcdir}/.."
  45 fi
  46 AC_SUBST(libgcc_topdir)
  47 AC_CONFIG_AUX_DIR($libgcc_topdir)
  48 AC_CONFIG_HEADER(auto-target.h:config.in)
  49
  50 AC_ARG_ENABLE(shared,
  51 [  --disable-shared        don't provide a shared libgcc],
  52 [
  53   case $enable_shared in
  54   yes | no) ;;
  55   *)
  56     enable_shared=no
  57     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  58     for pkg in $enableval; do
  59       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  60         enable_shared=yes
  61       fi
  62     done
  63     IFS="$ac_save_ifs"
  64     ;;
  65   esac
  66 ], [enable_shared=yes])
  67 AC_SUBST(enable_shared)
  68
  69 AC_ARG_ENABLE(vtable-verify,
  70 [  --enable-vtable-verify    Enable vtable verification feature ],
  71 [case "$enableval" in
  72  yes) enable_vtable_verify=yes ;;
  73  no)  enable_vtable_verify=no ;;
  74  *)   enable_vtable_verify=no;;
  75  esac],
  76 [enable_vtable_verify=no])
  77 AC_SUBST(enable_vtable_verify)
  78
  79 AC_ARG_WITH(aix-soname,
  80 [AS_HELP_STRING([--with-aix-soname=aix|svr4|both],
  81     [shared library versioning (aka "SONAME") variant to provide on AIX])],
  82 [case "${host}:${enable_shared}" in
  83  power*-*-aix[[5-9]]*:yes)
  84    AC_MSG_CHECKING([which variant of shared library versioning to provide for shared libgcc])
  85    case ${withval} in
  86      aix|svr4|both) ;;
  87      *) AC_MSG_ERROR([Unknown argument to --with-aix-soname]);;
  88    esac
  89    AC_MSG_RESULT($withval)
  90    ;;
  91  *) with_aix_soname=aix ;;
  92  esac
  93 ], [with_aix_soname=aix])
  94 AC_SUBST(with_aix_soname)
  95
  96 GCC_PICFLAG
  97 AC_SUBST(PICFLAG)
  98
  99 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 100 AC_ARG_ENABLE(version-specific-runtime-libs,
 101 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
 102 [case "$enableval" in
 103  yes) version_specific_libs=yes ;;
 104  no)  version_specific_libs=no ;;
 105  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 106  esac],
 107 [version_specific_libs=no])
 108 AC_MSG_RESULT($version_specific_libs)
 109
 110 AC_ARG_WITH(slibdir,
 111 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
 112 slibdir="$with_slibdir",
 113 if test "${version_specific_libs}" = yes; then
 114   slibdir='$(libsubdir)'
 115 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
 116   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
 117 else
 118   slibdir='$(libdir)'
 119 fi)
 120 AC_SUBST(slibdir)
 121
 122 # Command-line options.
 123 # Very limited version of AC_MAINTAINER_MODE.
 124 AC_ARG_ENABLE([maintainer-mode],
 125   [AC_HELP_STRING([--enable-maintainer-mode],
 126                  [enable make rules and dependencies not useful (and
 127                   sometimes confusing) to the casual installer])],
 128   [case ${enable_maintainer_mode} in
 129      yes) MAINT='' ;;
 130      no) MAINT='#' ;;
 131      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
 132    esac
 133    maintainer_mode=${enableval}],
 134   [MAINT='#'])
 135 AC_SUBST([MAINT])dnl
 136
 137 AC_PROG_INSTALL
 138
 139 AC_PROG_AWK
 140 # We need awk; bail out if it's missing.
 141 case ${AWK} in
 142   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 143 esac
 144
 145 AC_CANONICAL_HOST
 146 ACX_NONCANONICAL_HOST
 147 ACX_NONCANONICAL_TARGET
 148 GCC_TOPLEV_SUBDIRS
 149
 150 # Calculate toolexeclibdir
 151 # Also toolexecdir, though it's only used in toolexeclibdir
 152 case ${version_specific_libs} in
 153   yes)
 154     # Need the gcc compiler version to know where to install libraries
 155     # and header files if --enable-version-specific-runtime-libs option
 156     # is selected.
 157     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 158     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 159     ;;
 160   no)
 161     if test -n "$with_cross_host" &&
 162        test x"$with_cross_host" != x"no"; then
 163       # Install a library built with a cross compiler in tooldir, not libdir.
 164       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 165       toolexeclibdir='$(toolexecdir)/lib'
 166     else
 167       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 168       toolexeclibdir='$(libdir)'
 169     fi
 170     multi_os_directory=`$CC -print-multi-os-directory`
 171     case $multi_os_directory in
 172       .) ;; # Avoid trailing /.
 173       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 174     esac
 175     ;;
 176 esac
 177 AC_SUBST(toolexecdir)
 178 AC_SUBST(toolexeclibdir)
 179
 180 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 181 dnl to call AC_CHECK_PROG.
 182 AC_CHECK_TOOL(AR, ar)
 183 AC_CHECK_TOOL(LIPO, lipo, :)
 184 AC_CHECK_TOOL(NM, nm)
 185 AC_CHECK_TOOL(RANLIB, ranlib, :)
 186 AC_CHECK_TOOL(STRIP, strip, :)
 187 AC_PROG_LN_S
 188
 189 GCC_NO_EXECUTABLES
 190 AC_PROG_CC
 191 AC_PROG_CPP_WERROR
 192
 193 AC_CHECK_SIZEOF([double])
 194 AC_CHECK_SIZEOF([long double])
 195 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 196 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 197 AC_SUBST(double_type_size)
 198 AC_SUBST(long_double_type_size)
 199
 200 AC_CHECK_HEADERS(inttypes.h stdint.h stdlib.h ftw.h \
 201         unistd.h sys/stat.h sys/types.h \
 202         string.h strings.h memory.h)
 203 AC_HEADER_STDC
 204
 205 # Check for decimal float support.
 206 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 207                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 208 #include <fenv.h>
 209 ]], [[
 210 _Decimal32 x;
 211 int fe_except =
 212   FE_INVALID|FE_DIVBYZERO|FE_OVERFLOW|FE_UNDERFLOW|FE_INEXACT;
 213 ]])],
 214                                   [libgcc_cv_dfp=yes],
 215                                   [libgcc_cv_dfp=no])])
 216 decimal_float=$libgcc_cv_dfp
 217 AC_SUBST(decimal_float)
 218
 219 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 220
 221 # Check for fixed-point support.
 222 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 223                [AC_COMPILE_IFELSE([_Sat _Fract x;], [libgcc_cv_fixed_point=yes],
 224                                   [libgcc_cv_fixed_point=no])])
 225 fixed_point=$libgcc_cv_fixed_point
 226 AC_SUBST(fixed_point)
 227
 228 # For platforms with the unwind ABI which includes an unwind library,
 229 # libunwind, we can choose to use the system libunwind.
 230 # config.gcc also contains tests of with_system_libunwind.
 231 GCC_CHECK_UNWIND_GETIPINFO
 232
 233 # The sjlj test is almost duplicated here and in libgo/configure.ac (for C),
 234 # libstdc++-v3/acinclude.m4 and libjava/configure.ac (for C++), and
 235 # libobjc/configure.ac (for Objective-C).
 236 # FIXME: This should be centralized in config/sjlj.m4.
 237 AC_ARG_ENABLE(sjlj-exceptions,
 238   AC_HELP_STRING([--enable-sjlj-exceptions],
 239                  [force use of builtin_setjmp for exceptions]),
 240   [case "$enableval" in
 241    yes|no|auto) ;;
 242    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 243    esac],
 244   [enable_sjlj_exceptions=auto])
 245
 246 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 247 [libgcc_cv_lib_sjlj_exceptions],
 248 [AC_LANG_CONFTEST(
 249   [AC_LANG_SOURCE([
 250 void bar ();
 251 void clean (int *);
 252 void foo ()
 253 {
 254   int i __attribute__ ((cleanup (clean)));
 255   bar();
 256 }
 257 ])])
 258 CFLAGS_hold=$CFLAGS
 259 CFLAGS="--save-temps -fexceptions"
 260 libgcc_cv_lib_sjlj_exceptions=unknown
 261 AS_IF([ac_fn_c_try_compile],
 262   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 263     libgcc_cv_lib_sjlj_exceptions=yes
 264   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 265     libgcc_cv_lib_sjlj_exceptions=no
 266   fi])
 267 CFLAGS=$CFLAGS_hold
 268 rm -f conftest*
 269 ])
 270
 271 if test "$enable_sjlj_exceptions" = "auto"; then
 272   enable_sjlj_exceptions=$libgcc_cv_lib_sjlj_exceptions
 273 fi
 274
 275 case $enable_sjlj_exceptions in
 276 yes)
 277   AC_DEFINE(LIBGCC_SJLJ_EXCEPTIONS, 1,
 278         [Define if the C compiler is configured for setjmp/longjmp exceptions.])
 279   ;;
 280 no)
 281   ;;
 282 *)
 283   AC_MSG_ERROR([unable to detect exception model])
 284   ;;
 285 esac
 286
 287 AC_ARG_ENABLE([explicit-exception-frame-registration],
 288   [AC_HELP_STRING([--enable-explicit-exception-frame-registration],
 289      [register exception tables explicitly at module start, for use
 290       e.g. for compatibility with installations without PT_GNU_EH_FRAME support])],
 291 [
 292 force_explicit_eh_registry=
 293 if test "$enable_explicit_exception_frame_registration" = yes; then
 294   if test "$enable_sjlj_exceptions" = yes; then
 295     AC_MSG_ERROR([Can't enable both of --enable-sjlj-exceptions
 296                   and --enable-explicit-exception-frame-registration])
 297   fi
 298   force_explicit_eh_registry=-DUSE_EH_FRAME_REGISTRY_ALWAYS
 299 fi
 300 ])
 301 AC_SUBST([force_explicit_eh_registry])
 302
 303 AC_LIB_PROG_LD_GNU
 304
 305 AC_MSG_CHECKING([for thread model used by GCC])
 306 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 307 AC_MSG_RESULT([$target_thread_file])
 308
 309 # Check for assembler CFI support.
 310 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 311                [AC_COMPILE_IFELSE(
 312 [asm("\n\
 313         .text\n\
 314         .cfi_startproc\n\
 315         .cfi_personality 0, symbol\n\
 316         .cfi_endproc");],
 317   [libgcc_cv_cfi=yes],
 318   [libgcc_cv_cfi=no])])
 319
 320 # Check 32bit or 64bit.  In the case of MIPS, this really determines the
 321 # word size rather than the address size.
 322 cat > conftest.c <<EOF
 323 #if defined(__x86_64__) || (!defined(__i386__) && defined(__LP64__)) \
 324     || defined(__mips64)
 325 host_address=64
 326 #else
 327 host_address=32
 328 #endif
 329 EOF
 330 eval `${CC-cc} -E conftest.c | grep host_address=`
 331 rm -f conftest.c
 332
 333 case ${host} in
 334 mips*-*-*)
 335   AC_CACHE_CHECK([whether the target is hard-float],
 336                  [libgcc_cv_mips_hard_float],
 337                  [AC_COMPILE_IFELSE(
 338     [#ifndef __mips_hard_float
 339      #error FOO
 340      #endif],
 341     [libgcc_cv_mips_hard_float=yes],
 342     [libgcc_cv_mips_hard_float=no])])
 343 esac
 344
 345 # Determine the version of glibc, if any, used on the target.
 346 AC_MSG_CHECKING([for target glibc version])
 347 AC_ARG_WITH([glibc-version],
 348   [AS_HELP_STRING([--with-glibc-version=M.N],
 349     [assume GCC used with glibc version M.N or later])], [
 350 if [echo "$with_glibc_version" | grep '^[0-9][0-9]*\.[0-9][0-9]*$']; then
 351   glibc_version_major=`echo "$with_glibc_version" | sed -e 's/\..*//'`
 352   glibc_version_minor=`echo "$with_glibc_version" | sed -e 's/.*\.//'`
 353 else
 354   AC_MSG_ERROR([option --with-glibc-version requires a version number M.N])
 355 fi], [
 356 AC_COMPUTE_INT([glibc_version_major], [__GLIBC__],
 357                                       [#include <features.h>],
 358                                       [glibc_version_major=0])
 359 AC_COMPUTE_INT([glibc_version_minor], [__GLIBC_MINOR__],
 360                                       [#include <features.h>],
 361                                       [glibc_version_minor=0])])
 362 AC_MSG_RESULT([$glibc_version_major.$glibc_version_minor])
 363
 364 # Determine floating-point type for powerpc*-*-linux*.
 365 # Single-precision-only FPRs are not a supported configuration for
 366 # this target, so are not allowed for in this test.
 367 case ${host} in
 368 powerpc*-*-linux*)
 369   cat > conftest.c <<EOF
 370 #ifdef __powerpc64__
 371 ppc_fp_type=64
 372 #elif defined _SOFT_FLOAT
 373 ppc_fp_type=soft
 374 #elif defined _SOFT_DOUBLE
 375 ppc_fp_type=e500v1
 376 #elif defined __NO_FPRS__
 377 ppc_fp_type=e500v2
 378 #else
 379 ppc_fp_type=hard
 380 #endif
 381 EOF
 382 eval `${CC-cc} -E conftest.c | grep ppc_fp_type=`
 383 rm -f conftest.c
 384 # glibc 2.19 and later provide all the soft-fp functions, with proper
 385 # interactions with <fenv.h> exception and rounding mode handling, so
 386 # make libgcc's versions into compat symbols if a recent enough glibc
 387 # version is being used.
 388 ppc_fp_compat=
 389 case ${ppc_fp_type} in
 390 soft|e500v1|e500v2)
 391   if test $glibc_version_major -gt 2 \
 392     || ( test $glibc_version_major -eq 2 \
 393         && test $glibc_version_minor -ge 19 ); then
 394     ppc_fp_compat="t-softfp-compat"
 395   fi
 396   ;;
 397 esac
 398 ;;
 399 esac
 400
 401 # Collect host-machine-specific information.
 402 . ${srcdir}/config.host
 403
 404 # Used for constructing correct paths for offload compilers.
 405 accel_dir_suffix=
 406 if test x"$enable_as_accelerator_for" != x; then
 407   accel_dir_suffix=/accel/${target_noncanonical}
 408   case "${target_noncanonical}" in
 409     *-intelmicemul-*)
 410       # In this case we expect offload compiler to be built as native, so we
 411       # need to change install directory for driver to be able to find libgcc.
 412       host_noncanonical=${enable_as_accelerator_for} ;;
 413   esac
 414 fi
 415 AC_SUBST(accel_dir_suffix)
 416
 417 if test x"$enable_offload_targets" != x; then
 418   extra_parts="${extra_parts} crtoffloadbegin.o crtoffloadend.o"
 419 fi
 420
 421 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 422 # This is after config.host so we can augment tmake_file.
 423 # Link with -nostartfiles -nodefaultlibs since neither are present while
 424 # building libgcc.
 425 case ${host} in
 426 i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 427   cat > conftest.s <<EOF
 428         .section        .eh_frame,"a",@unwind
 429         .zero   4
 430         .section        .jcr,"aw",@progbits
 431         .zero   8
 432 EOF
 433   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 434       tmake_file="${tmake_file} i386/t-crtstuff"
 435   fi
 436   ;;
 437 esac
 438
 439 # Check for visibility support.  This is after config.host so that
 440 # we can check for asm_hidden_op.
 441 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 442     libgcc_cv_hidden_visibility_attribute, [
 443         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 444         libgcc_cv_hidden_visibility_attribute=no
 445         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 446             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 447                 libgcc_cv_hidden_visibility_attribute=yes
 448             fi
 449         fi
 450         rm -f conftest.*
 451     ])
 452
 453 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 454     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 455 else
 456     vis_hide=
 457 fi
 458 AC_SUBST(vis_hide)
 459
 460 # See if we have thread-local storage.  We can only test assembler
 461 # since link-time and run-time tests require the newly built
 462 # gcc, which can't be used to build executable due to that libgcc
 463 # is yet to be built here.
 464 GCC_CHECK_CC_TLS
 465 set_have_cc_tls=
 466 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 467   set_have_cc_tls="-DHAVE_CC_TLS"
 468 fi
 469 AC_SUBST(set_have_cc_tls)
 470
 471 # See if we have emulated thread-local storage.
 472 GCC_CHECK_EMUTLS
 473 set_use_emutls=
 474 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 475   set_use_emutls="-DUSE_EMUTLS"
 476 fi
 477 AC_SUBST(set_use_emutls)
 478
 479 AC_CACHE_CHECK(for init priority support, libgcc_cv_init_priority, [
 480 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,
 481   [[void ip (void) __attribute__ ((constructor (1)));]])],
 482   [libgcc_cv_init_priority=yes],[libgcc_cv_init_priority=no])])
 483 if test $libgcc_cv_init_priority = yes; then
 484   AC_DEFINE(HAVE_INIT_PRIORITY, 1,
 485   [Define if the compiler supports init priority.])
 486 fi
 487
 488 # Conditionalize the sfp-machine.h header for this target machine.
 489 if test -z "${sfp_machine_header}"; then
 490         sfp_machine_header=$cpu_type/sfp-machine.h
 491         if test -f ${srcdir}/config/${sfp_machine_header}; then
 492                 :
 493         else
 494                 sfp_machine_header=no-sfp-machine.h
 495         fi
 496 fi
 497 AC_SUBST(sfp_machine_header)
 498
 499 # Conditionalize the makefile for this target machine.
 500 tmake_file_=
 501 for f in ${tmake_file}
 502 do
 503         if test -f ${srcdir}/config/$f
 504         then
 505                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 506         fi
 507 done
 508 tmake_file="${tmake_file_}"
 509 AC_SUBST(tmake_file)
 510
 511 # Likewise export definitions for libgcc_tm.h
 512 tm_file_=
 513 for f in ${tm_file}
 514 do
 515         tm_file_="${tm_file_} \$(srcdir)/config/$f"
 516 done
 517 tm_file="${tm_file_}"
 518 AC_SUBST(tm_file)
 519 AC_SUBST(tm_defines)
 520
 521 # Map from thread model to thread header.
 522 GCC_AC_THREAD_HEADER([$target_thread_file])
 523
 524 # Substitute configuration variables
 525 AC_SUBST(cpu_type)
 526 AC_SUBST(extra_parts)
 527 AC_SUBST(asm_hidden_op)
 528 AC_CONFIG_LINKS([enable-execute-stack.c:$enable_execute_stack])
 529 AC_CONFIG_LINKS([unwind.h:$unwind_header])
 530 AC_CONFIG_LINKS([md-unwind-support.h:config/$md_unwind_header])
 531 AC_CONFIG_LINKS([sfp-machine.h:config/$sfp_machine_header])
 532 AC_CONFIG_LINKS([gthr-default.h:$thread_header])
 533
 534 # We need multilib support.
 535 AC_CONFIG_FILES([Makefile])
 536 AC_CONFIG_COMMANDS([default],
 537   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 538 if test -n "$CONFIG_FILES"; then
 539   # FIXME: We shouldn't need to set ac_file
 540   ac_file=Makefile
 541   . ${libgcc_topdir}/config-ml.in
 542 fi]],
 543 [[srcdir=${srcdir}
 544 host=${host}
 545 with_target_subdir=${with_target_subdir}
 546 with_multisubdir=${with_multisubdir}
 547 ac_configure_args="--enable-multilib ${ac_configure_args}"
 548 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 549 libgcc_topdir=${libgcc_topdir}
 550 CC="${CC}"
 551 ]])
 552 AC_OUTPUT