libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/override.m4)
   8
   9 AC_PREREQ(2.59)
  10 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  11 AC_CONFIG_SRCDIR([static-object.mk])
  12
  13 AC_ARG_WITH(target-subdir,
  14 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  15 AC_ARG_WITH(cross-host,
  16 [  --with-cross-host=HOST           Configuring with a cross compiler])
  17 AC_ARG_WITH(ld,
  18 [  --with-ld               arrange to use the specified ld (full pathname)])
  19
  20 if test "${srcdir}" = "."; then
  21   if test -n "${with_build_subdir}"; then
  22     libgcc_topdir="${srcdir}/../.."
  23     with_target_subdir=
  24   elif test -z "${with_target_subdir}"; then
  25     libgcc_topdir="${srcdir}/.."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  29     else
  30       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   libgcc_topdir="${srcdir}/.."
  35 fi
  36 AC_SUBST(libgcc_topdir)
  37 AC_CONFIG_AUX_DIR($libgcc_topdir)
  38
  39 AC_ARG_ENABLE(shared,
  40 [  --disable-shared        don't provide a shared libgcc],
  41 [
  42   case $enable_shared in
  43   yes | no) ;;
  44   *)
  45     enable_shared=no
  46     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  47     for pkg in $enableval; do
  48       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  49         enable_shared=yes
  50       fi
  51     done
  52     IFS="$ac_save_ifs"
  53     ;;
  54   esac
  55 ], [enable_shared=yes])
  56 AC_SUBST(enable_shared)
  57
  58 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  59 AC_ARG_ENABLE(version-specific-runtime-libs,
  60 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  61 [case "$enableval" in
  62  yes) version_specific_libs=yes ;;
  63  no)  version_specific_libs=no ;;
  64  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  65  esac],
  66 [version_specific_libs=no])
  67 AC_MSG_RESULT($version_specific_libs)
  68
  69 AC_ARG_WITH(slibdir,
  70 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
  71 slibdir="$with_slibdir",
  72 if test "${version_specific_libs}" = yes; then
  73   slibdir='$(libsubdir)'
  74 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
  75   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
  76 else
  77   slibdir='$(libdir)'
  78 fi)
  79 AC_SUBST(slibdir)
  80
  81 AC_PROG_INSTALL
  82
  83 AC_PROG_AWK
  84 # We need awk; bail out if it's missing.
  85 case ${AWK} in
  86   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
  87 esac
  88
  89 AC_CANONICAL_HOST
  90 ACX_NONCANONICAL_HOST
  91 GCC_TOPLEV_SUBDIRS
  92
  93 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  94 dnl to call AC_CHECK_PROG.
  95 AC_CHECK_TOOL(AR, ar)
  96 AC_CHECK_TOOL(LIPO, lipo, :)
  97 AC_CHECK_TOOL(NM, nm)
  98 AC_CHECK_TOOL(RANLIB, ranlib, :)
  99 AC_CHECK_TOOL(STRIP, strip, :)
 100 AC_PROG_LN_S
 101
 102 GCC_NO_EXECUTABLES
 103 AC_PROG_CC
 104 AC_PROG_CPP_WERROR
 105
 106 # Check for decimal float support.
 107 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 108                [AC_COMPILE_IFELSE([_Decimal32 x;], [libgcc_cv_dfp=yes],
 109                                   [libgcc_cv_dfp=no])])
 110 decimal_float=$libgcc_cv_dfp
 111 AC_SUBST(decimal_float)
 112
 113 AC_ARG_ENABLE(decimal-float,
 114 [  --enable-decimal-float={no,yes,bid,dpd}
 115                         enable decimal float extension to C.  Selecting 'bid'
 116                         or 'dpd' choses which decimal floating point format
 117                         to use],
 118 [
 119   case $enable_decimal_float in
 120     yes | no | bid | dpd) ;;
 121     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
 122 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
 123   esac
 124 ],
 125 [
 126   case $host in
 127     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
 128       enable_decimal_float=yes
 129       ;;
 130     *)
 131       enable_decimal_float=no
 132       ;;
 133   esac
 134 ])
 135
 136 # x86's use BID format instead of DPD
 137 if test x$enable_decimal_float = xyes; then
 138   case $host in
 139     i?86*-*-linux* | x86_64*-*-linux*)
 140       enable_decimal_float=bid
 141       ;;
 142     *)
 143       enable_decimal_float=dpd
 144       ;;
 145   esac
 146 fi
 147 AC_SUBST(enable_decimal_float)
 148
 149 # Check for fixed-point support.
 150 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 151                [AC_COMPILE_IFELSE([_Sat _Fract x;], [libgcc_cv_fixed_point=yes],
 152                                   [libgcc_cv_fixed_point=no])])
 153 fixed_point=$libgcc_cv_fixed_point
 154 AC_SUBST(fixed_point)
 155
 156 # Collect host-machine-specific information.
 157 . ${srcdir}/config.host
 158
 159 # Check for visibility support.  This is after config.host so that
 160 # we can check for asm_hidden_op.
 161 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 162     libgcc_cv_hidden_visibility_attribute, [
 163         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 164         libgcc_cv_hidden_visibility_attribute=no
 165         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 166             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 167                 libgcc_cv_hidden_visibility_attribute=yes
 168             fi
 169         fi
 170         rm -f conftest.*
 171     ])
 172
 173 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 174     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 175 else
 176     vis_hide=
 177 fi
 178 AC_SUBST(vis_hide)
 179
 180 # See if we have thread-local storage.  We can only test assembler
 181 # sicne link-time and run-time tests require the newly built
 182 # gcc, which can't be used to build executable due to that libgcc
 183 # is yet to be built here.
 184 GCC_CHECK_CC_TLS
 185 set_have_cc_tls=
 186 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 187   set_have_cc_tls="-DHAVE_CC_TLS"
 188 fi
 189 AC_SUBST(set_have_cc_tls)
 190
 191 # Conditionalize the makefile for this target machine.
 192 tmake_file_=
 193 for f in ${tmake_file}
 194 do
 195         if test -f ${srcdir}/config/$f
 196         then
 197                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 198         fi
 199 done
 200 tmake_file="${tmake_file_}"
 201 AC_SUBST(tmake_file)
 202
 203 # Substitute configuration variables
 204 AC_SUBST(extra_parts)
 205 AC_SUBST(asm_hidden_op)
 206
 207 # We need multilib support.
 208 AC_CONFIG_FILES([Makefile])
 209 AC_CONFIG_COMMANDS([default],
 210   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 211 if test -n "$CONFIG_FILES"; then
 212   # FIXME: We shouldn't need to set ac_file
 213   ac_file=Makefile
 214   . ${libgcc_topdir}/config-ml.in
 215 fi]],
 216 [[srcdir=${srcdir}
 217 host=${host}
 218 with_target_subdir=${with_target_subdir}
 219 with_multisubdir=${with_multisubdir}
 220 ac_configure_args="--enable-multilib ${ac_configure_args}"
 221 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 222 libgcc_topdir=${libgcc_topdir}
 223 CC="${CC}"
 224 ]])
 225 AC_OUTPUT