libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_INIT(package-unused, version-unused,, libgo)
  10 AC_CONFIG_SRCDIR(Makefile.am)
  11 AC_CONFIG_HEADER(config.h)
  12
  13 libtool_VERSION=14:0:0
  14 AC_SUBST(libtool_VERSION)
  15
  16 AM_ENABLE_MULTILIB(, ..)
  17
  18 AC_CANONICAL_SYSTEM
  19 target_alias=${target_alias-$host_alias}
  20
  21 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist subdir-objects -Wall -Wno-portability -Wno-override])
  22 AH_TEMPLATE(PACKAGE, [Name of package])
  23 AH_TEMPLATE(VERSION, [Version number of package])
  24
  25 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  26 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  27 AC_PROG_CC
  28 AC_PROG_GO
  29 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  30
  31 AC_SUBST(CFLAGS)
  32
  33 case ${host} in
  34   *-*-aix*)
  35     # static hash tables crashes on AIX when libgo is built with O2
  36     CFLAGS="$CFLAGS -fno-section-anchors"
  37     GOCFLAGS="$GOCFLAGS -fno-section-anchors"
  38     ;;
  39 esac
  40
  41 AM_MAINTAINER_MODE
  42
  43 AC_PROG_LD
  44 AC_PROG_RANLIB
  45 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  46
  47 AC_LIBTOOL_DLOPEN
  48 AM_PROG_LIBTOOL
  49 AC_SUBST(enable_shared)
  50 AC_SUBST(enable_static)
  51
  52 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  53 AC_SUBST(CC_FOR_BUILD)
  54
  55 AC_PROG_AWK
  56
  57 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  58 AC_SUBST(WARN_FLAGS)
  59
  60 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  61                                       [turns on -Werror @<:@default=yes@:>@])])
  62 if test "x$enable_werror" != "xno"; then
  63   WERROR="-Werror"
  64 fi
  65 AC_SUBST(WERROR)
  66
  67 glibgo_toolexecdir=no
  68 glibgo_toolexeclibdir=no
  69
  70 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  71 AC_ARG_ENABLE([version-specific-runtime-libs],
  72   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  73                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  74   [case "$enableval" in
  75     yes) version_specific_libs=yes ;;
  76     no)  version_specific_libs=no ;;
  77     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  78    esac],
  79   [version_specific_libs=no])
  80 AC_MSG_RESULT($version_specific_libs)
  81
  82 # Version-specific runtime libs processing.
  83 if test $version_specific_libs = yes; then
  84   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  85   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  86 fi
  87
  88 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  89 # Install a library built with a cross compiler in tooldir, not libdir.
  90 if test -n "$with_cross_host" &&
  91    test x"$with_cross_host" != x"no"; then
  92   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  93   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  94 else
  95   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  96   nover_glibgo_toolexeclibdir='${libdir}'
  97 fi
  98 multi_os_directory=`$GOC -print-multi-os-directory`
  99 case $multi_os_directory in
 100   .) ;; # Avoid trailing /.
 101   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
 102 esac
 103
 104 if test x"$glibgo_toolexecdir" = x"no"; then
 105   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
 106   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 107 fi
 108
 109 AC_SUBST(glibgo_toolexecdir)
 110 AC_SUBST(glibgo_toolexeclibdir)
 111 AC_SUBST(nover_glibgo_toolexeclibdir)
 112
 113 # See if the user wants to configure without libffi.  Some
 114 # architectures don't support it.  FIXME: We should set a default
 115 # based on the host.
 116 AC_ARG_WITH(libffi,
 117   AS_HELP_STRING([--without-libffi],
 118                  [don't use libffi]),
 119   [:],
 120   [with_libffi=${with_libffi_default-yes}])
 121
 122 LIBFFI=
 123 LIBFFIINCS=
 124 if test "$with_libffi" != no; then
 125    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 126    LIBFFI=../libffi/libffi_convenience.la
 127    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 128 fi
 129 AC_SUBST(LIBFFI)
 130 AC_SUBST(LIBFFIINCS)
 131 AM_CONDITIONAL(USE_LIBFFI, test "$with_liffi" != "no")
 132
 133 # See if the user wants to configure without libatomic. This is useful if we are
 134 # on an architecture for which libgo does not need an atomic support library and
 135 # libatomic does not support our C compiler.
 136 AC_ARG_WITH(libatomic,
 137   AS_HELP_STRING([--without-libatomic],
 138                  [don't use libatomic]),
 139   [:],
 140   [with_libatomic=${with_libatomic_default-yes}])
 141
 142 LIBATOMIC=
 143 if test "$with_libatomic" != no; then
 144    LIBATOMIC=../libatomic/libatomic_convenience.la
 145 fi
 146 AC_SUBST(LIBATOMIC)
 147
 148 # Used to tell GNU make to include a file without telling automake to
 149 # include it.
 150 go_include="-include"
 151 AC_SUBST(go_include)
 152
 153 # All known GOOS values.  This is the union of all operating systems
 154 # supported by the gofrontend and all operating systems supported by
 155 # the gc toolchain.
 156 ALLGOOS="aix android darwin dragonfly freebsd hurd irix js linux netbsd openbsd plan9 rtems solaris windows"
 157
 158 is_darwin=no
 159 is_freebsd=no
 160 is_irix=no
 161 is_linux=no
 162 is_netbsd=no
 163 is_openbsd=no
 164 is_dragonfly=no
 165 is_rtems=no
 166 is_solaris=no
 167 is_aix=no
 168 GOOS=unknown
 169 case ${host} in
 170   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 171   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 172   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 173   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 174   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 175   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 176   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 177   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 178   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 179   *-*-aix*)      is_aix=yes;     GOOS=aix ;;
 180 esac
 181 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 182 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 183 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 184 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 185 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 186 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 187 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 188 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 189 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 190 AM_CONDITIONAL(LIBGO_IS_AIX, test $is_aix = yes)
 191 AM_CONDITIONAL(LIBGO_IS_BSD, test $is_darwin = yes -o $is_dragonfly = yes -o $is_freebsd = yes -o $is_netbsd = yes -o $is_openbsd = yes)
 192 AC_SUBST(GOOS)
 193 AC_SUBST(ALLGOOS)
 194
 195 dnl Test whether we need to use DejaGNU or whether we can use the
 196 dnl simpler gotest approach.  We can only use gotest for a native
 197 dnl build.
 198 USE_DEJAGNU=no
 199 case ${host} in
 200   *-*-rtems*) USE_DEJAGNU=yes ;;
 201   ${build}) ;;
 202   *) USE_DEJAGNU=yes ;;
 203 esac
 204 AC_SUBST(USE_DEJAGNU)
 205
 206 # All known GOARCH values.  This is the union of all architectures
 207 # supported by the gofrontend and all architectures supported by the
 208 # gc toolchain.
 209 # To add a new architecture:
 210 # - add it to this list
 211 # - if appropriate, add an entry to ALLGOARCHFAMILY below
 212 # - add an entry to the case on ${host} below to set GOARCH
 213 # - update goarchList in libgo/go/go/build/syslist.go
 214 # - update goarch.sh to report the values for this architecture
 215 # - update go-set-goarch in gcc/testsuite/go.test/go-test.exp
 216 # - update ptrSizeMap and intSizeMap in libgo/go/cmd/cgo/main.go
 217 # - update arch lists in libgo/match.sh
 218 # - update arch lists in libgo/testsuite/gotest
 219 # - update +build lines in several places
 220 #   - libgo/go/runtime/lfstack_NNbit.go
 221 #   - libgo/go/runtime/hashNN.go
 222 #   - libgo/go/runtime/unalignedN.go
 223 #   - libgo/go/syscall/endian_XX.go
 224 #   - possibly others
 225 # - possibly update files in libgo/go/internal/syscall/unix
 226 ALLGOARCH="386 alpha amd64 amd64p32 arm armbe arm64 arm64be ia64 m68k mips mipsle mips64 mips64le mips64p32 mips64p32le nios2 ppc ppc64 ppc64le riscv riscv64 s390 s390x sh shbe sparc sparc64 wasm"
 227
 228 # All known GOARCH family values.
 229 ALLGOARCHFAMILY="I386 ALPHA AMD64 ARM ARM64 IA64 M68K MIPS MIPS64 NIOS2 PPC PPC64 RISCV RISCV64 S390 S390X SH SPARC SPARC64 WASM"
 230
 231 GOARCH=unknown
 232 case ${host} in
 233   alpha*-*-*)
 234     GOARCH=alpha
 235     ;;
 236   aarch64-*-*)
 237     GOARCH=arm64
 238     ;;
 239   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 240     GOARCH=arm
 241     case ${host} in
 242       arm*b*-*-*)
 243         GOARCH=armbe
 244         ;;
 245     esac
 246     ;;
 247 changequote(,)dnl
 248   i[34567]86-*-* | x86_64-*-*)
 249 changequote([,])dnl
 250     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 251 #ifdef __x86_64__
 252 #error 64-bit
 253 #endif
 254 ])],
 255         [GOARCH=386],
 256         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 257 #ifdef __ILP32__
 258 #error x32
 259 #endif
 260 ])],
 261         [GOARCH=amd64],
 262         [GOARCH=amd64p32]))
 263     ;;
 264   ia64-*-*)
 265     GOARCH=ia64
 266     ;;
 267   m68k*-*-*)
 268     GOARCH=m68k
 269     ;;
 270   mips*-*-*)
 271     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 272 #if _MIPS_SIM != _ABIO32
 273 #error not o32
 274 #endif
 275 ])],
 276 [mips_abi="o32"],
 277         [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 278 #if _MIPS_SIM != _ABIN32
 279 #error not n32
 280 #endif
 281 ])],
 282 [mips_abi="n32"],
 283         [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 284 #if _MIPS_SIM != _ABI64
 285 #error not n64
 286 #endif
 287 ])],
 288 [mips_abi="n64"],
 289         [AC_MSG_ERROR([unknown MIPS ABI])
 290 [mips_abi="n32"]])])])
 291     case "$mips_abi" in
 292     "o32") GOARCH=mips ;;
 293     "n32") GOARCH=mips64p32 ;;
 294     "n64") GOARCH=mips64 ;;
 295     esac
 296     case "${host}" in
 297     mips*el-*-*)
 298         GOARCH="${GOARCH}le"
 299         ;;
 300     esac
 301     ;;
 302   nios2-*-*)
 303     GOARCH=nios2
 304     ;;
 305   rs6000*-*-* | powerpc*-*-*)
 306     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 307 #ifdef _ARCH_PPC64
 308 #error 64-bit
 309 #endif
 310 ])],
 311 [GOARCH=ppc],
 312     [
 313 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 314 #if defined(_BIG_ENDIAN) || defined(__BIG_ENDIAN__)
 315 #error 64be
 316 #endif
 317 ])],
 318 [GOARCH=ppc64le],
 319 [GOARCH=ppc64])])
 320     ;;
 321   riscv64-*-*)
 322     GOARCH=riscv64
 323     ;;
 324   s390*-*-*)
 325     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 326 #if defined(__s390x__)
 327 #error 64-bit
 328 #endif
 329 ])],
 330 [GOARCH=s390],
 331 [GOARCH=s390x])
 332     ;;
 333   sh3eb*-*-* | sh4eb*-*-*)
 334     GOARCH=shbe
 335     ;;
 336   sh3*-*-* | sh4*-*-*)
 337     GOARCH=sh
 338     ;;
 339   sparc*-*-*)
 340     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 341 #if defined(__sparcv9) || defined(__arch64__)
 342 #error 64-bit
 343 #endif
 344 ])],
 345 [GOARCH=sparc],
 346 [GOARCH=sparc64])
 347     ;;
 348 esac
 349 AC_SUBST(GOARCH)
 350 AC_SUBST(ALLGOARCH)
 351 AC_SUBST(ALLGOARCHFAMILY)
 352
 353 dnl Some files are only present when needed for specific architectures.
 354 GO_LIBCALL_OS_FILE=
 355 GO_LIBCALL_OS_ARCH_FILE=
 356 GO_SYSCALL_OS_FILE=
 357 GO_SYSCALL_OS_ARCH_FILE=
 358 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 359   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 360 fi
 361 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 362   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 363 fi
 364 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 365   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 366 fi
 367 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 368   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 369 fi
 370 AC_SUBST(GO_LIBCALL_OS_FILE)
 371 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 372 AC_SUBST(GO_SYSCALL_OS_FILE)
 373 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 374
 375 dnl Special flags used to generate sysinfo.go.
 376 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 377 case "$target" in
 378     mips-sgi-irix6.5*)
 379         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 380         # msghdr in <sys/socket.h>.
 381         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 382         ;;
 383     *-*-solaris2.1[[01]])
 384         # Solaris 10+ needs this so struct msghdr gets the msg_control
 385         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 386         # above doesn't work with C99.
 387         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 388         ;;
 389 esac
 390 AC_SUBST(OSCFLAGS)
 391
 392 dnl Check if assembler supports disabling hardware capability support.
 393 GCC_CHECK_ASSEMBLER_HWCAP
 394
 395 dnl Use -fsplit-stack when compiling C code if available.
 396 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 397 [libgo_cv_c_split_stack_supported],
 398 [CFLAGS_hold=$CFLAGS
 399 CFLAGS="$CFLAGS -fsplit-stack"
 400 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 401 [libgo_cv_c_split_stack_supported=yes],
 402 [libgo_cv_c_split_stack_supported=no])
 403 CFLAGS=$CFLAGS_hold])
 404
 405 dnl Make sure the linker permits -fsplit-stack.  Old versions of gold will
 406 dnl reject split-stack code calling non-split-stack code on targets
 407 dnl they don't support.
 408 AC_CACHE_CHECK([whether linker supports split/non-split linked together],
 409 [libgo_cv_c_linker_split_non_split],
 410 [cat > conftest1.c << EOF
 411 extern void f();
 412 int main() { f(); return 0; }
 413 EOF
 414 cat > conftest2.c << EOF
 415 void f() {}
 416 EOF
 417 $CC -c -fsplit-stack $CFLAGS $CPPFLAGS conftest1.c >/dev/null 2>&1
 418 $CC -c $CFLAGS $CPPFLAGS conftest2.c > /dev/null 2>&1
 419 if $CC -o conftest conftest1.$ac_objext conftest2.$ac_objext > /dev/null 2>&1; then
 420   libgo_cv_c_linker_split_non_split=yes
 421 else
 422   libgo_cv_c_linker_split_non_split=no
 423 fi
 424 rm -f conftest1.* conftest2.* conftest])
 425
 426 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes; then
 427   SPLIT_STACK=-fsplit-stack
 428   AC_DEFINE(USING_SPLIT_STACK, 1,
 429                 [Define if the compiler supports -fsplit-stack])
 430 else
 431   SPLIT_STACK=
 432 fi
 433 AC_SUBST(SPLIT_STACK)
 434 AM_CONDITIONAL(USING_SPLIT_STACK,
 435         test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes)
 436
 437 dnl If the compiler supports split-stack but the linker does not, then
 438 dnl we need to explicitly disable split-stack for Go.
 439 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = no; then
 440   GO_SPLIT_STACK=-fno-split-stack
 441 else
 442   GO_SPLIT_STACK=
 443 fi
 444 AC_SUBST(GO_SPLIT_STACK)
 445
 446 dnl Check whether the linker does stack munging when calling from
 447 dnl split-stack into non-split-stack code.  We check this by looking
 448 dnl at the --help output.  FIXME: This is only half right: it's
 449 dnl possible for the linker to support this for some targets but not
 450 dnl others.
 451 dnl This is slightly different from the above check, which is whether
 452 dnl the linker permits the call at all.
 453 AC_CACHE_CHECK([whether linker supports split stack],
 454 [libgo_cv_c_linker_supports_split_stack],
 455 [libgo_cv_c_linker_supports_split_stack=no
 456 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 457   libgo_cv_c_linker_supports_split_stack=yes
 458 fi])
 459 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 460   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 461             [Define if the linker support split stack adjustments])
 462 fi
 463
 464 AC_CACHE_CHECK([whether compiler is llgo],
 465 [libgo_cv_c_goc_is_llgo],
 466 [libgo_cv_c_goc_is_llgo=no
 467 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 468   libgo_cv_c_goc_is_llgo=yes
 469 fi])
 470 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 471
 472 dnl Test for the -lm library.
 473 MATH_LIBS=
 474 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 475 AC_SUBST(MATH_LIBS)
 476
 477 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 478 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 479   [libgo_cv_lib_sockets=
 480    libgo_check_both=no
 481    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 482    if test "$libgo_check_socket" = "yes"; then
 483      unset ac_cv_func_connect
 484      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 485                   libgo_check_both=yes)
 486    fi
 487    if test "$libgo_check_both" = "yes"; then
 488      libgo_old_libs=$LIBS
 489      LIBS="$LIBS -lsocket -lnsl"
 490      unset ac_cv_func_accept
 491      AC_CHECK_FUNC(accept,
 492                    [libgo_check_nsl=no
 493                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 494      unset ac_cv_func_accept
 495      LIBS=$libgo_old_libs
 496    fi
 497    unset ac_cv_func_gethostbyname
 498    libgo_old_libs="$LIBS"
 499    AC_CHECK_FUNC(gethostbyname, ,
 500                  [AC_CHECK_LIB(nsl, main,
 501                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 502    unset ac_cv_func_gethostbyname
 503    AC_CHECK_FUNC(sendfile, ,
 504                  [AC_CHECK_LIB(sendfile, main,
 505                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lsendfile"])])
 506    LIBS=$libgo_old_libs
 507 ])
 508 NET_LIBS="$libgo_cv_lib_sockets"
 509 AC_SUBST(NET_LIBS)
 510
 511 dnl Test whether the compiler supports the -pthread option.
 512 AC_CACHE_CHECK([whether -pthread is supported],
 513 [libgo_cv_lib_pthread],
 514 [CFLAGS_hold=$CFLAGS
 515 CFLAGS="$CFLAGS -pthread -L../libatomic/.libs"
 516 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 517 [libgo_cv_lib_pthread=yes],
 518 [libgo_cv_lib_pthread=no])
 519 CFLAGS=$CFLAGS_hold])
 520 PTHREAD_CFLAGS=
 521 if test "$libgo_cv_lib_pthread" = yes; then
 522   # RISC-V apparently adds -latomic when using -pthread.
 523   PTHREAD_CFLAGS="-pthread -L../libatomic/.libs"
 524 fi
 525 AC_SUBST(PTHREAD_CFLAGS)
 526
 527 dnl Test for the -lpthread library.
 528 PTHREAD_LIBS=
 529 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 530 AC_SUBST(PTHREAD_LIBS)
 531
 532 dnl Test if -lrt is required for sched_yield or nanosleep or clock_gettime.
 533 AC_SEARCH_LIBS([sched_yield], [rt])
 534 AC_SEARCH_LIBS([nanosleep], [rt])
 535 AC_SEARCH_LIBS([clock_gettime], [rt])
 536
 537 AC_C_BIGENDIAN
 538
 539 GCC_CHECK_UNWIND_GETIPINFO
 540
 541 AC_CHECK_HEADERS(port.h sched.h semaphore.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/event.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/ptrace.h linux/reboot.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 542
 543 AC_CHECK_HEADERS([netinet/icmp6.h], [], [],
 544 [#include <netinet/in.h>
 545 ])
 546
 547 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 548 [#ifdef HAVE_SYS_SOCKET_H
 549 #include <sys/socket.h>
 550 #endif
 551 ])
 552
 553 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 554
 555 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv unsetenv dl_iterate_phdr memmem)
 556 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 557 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 558
 559 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice syscall tee unlinkat unshare utimensat)
 560 AC_TYPE_OFF_T
 561 AC_CHECK_TYPES([loff_t])
 562
 563 LIBS_hold="$LIBS"
 564 LIBS="$LIBS -lm"
 565 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 566 LIBS="$LIBS_hold"
 567
 568 CFLAGS_hold="$CFLAGS"
 569 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 570 LIBS_hold="$LIBS"
 571 LIBS="$LIBS $PTHREAD_LIBS"
 572 AC_CHECK_FUNCS(sem_timedwait)
 573 CFLAGS="$CFLAGS_hold"
 574 LIBS="$LIBS_hold"
 575
 576 LIBS_hold="$LIBS"
 577 LIBS="$LIBS $MATH_LIBS"
 578 AC_CHECK_FUNCS(matherr)
 579 LIBS="$LIBS_hold"
 580
 581 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 582 [libgo_cv_func___sync_bool_compare_and_swap_4],
 583 [AC_LINK_IFELSE([AC_LANG_SOURCE([
 584 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 585 uint32 i;
 586 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 587 ])],
 588 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 589 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 590 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 591   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 592     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 593 fi
 594
 595 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 596 [libgo_cv_func___sync_bool_compare_and_swap_8],
 597 [AC_LINK_IFELSE([AC_LANG_SOURCE([
 598 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 599 uint64 i;
 600 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 601 ])],
 602 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 603 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 604 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 605   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 606     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 607 fi
 608
 609 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 610 [libgo_cv_func___sync_fetch_and_add_4],
 611 [AC_LINK_IFELSE([AC_LANG_SOURCE([
 612 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 613 uint32 i;
 614 int main() { return __sync_fetch_and_add (&i, 1); }
 615 ])],
 616 [libgo_cv_func___sync_fetch_and_add_4=yes],
 617 [libgo_cv_func___sync_fetch_and_add_4=no])])
 618 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 619   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 620     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 621 fi
 622
 623 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 624 [libgo_cv_func___sync_add_and_fetch_8],
 625 [AC_LINK_IFELSE([AC_LANG_SOURCE([
 626 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 627 uint64 i;
 628 int main() { return __sync_add_and_fetch (&i, 1); }
 629 ])],
 630 [libgo_cv_func___sync_add_and_fetch_8=yes],
 631 [libgo_cv_func___sync_add_and_fetch_8=no])])
 632 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 633   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 634     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 635 fi
 636
 637 dnl For x86 we want to use the -minline-all-stringops option to avoid
 638 dnl forcing a stack split when calling memcpy and friends.
 639 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 640 [libgo_cv_c_stringops],
 641 [CFLAGS_hold=$CFLAGS
 642 CFLAGS="$CFLAGS -minline-all-stringops"
 643 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 644 [libgo_cv_c_stringops=yes],
 645 [libgo_cv_c_stringops=no])
 646 CFLAGS=$CFLAGS_hold])
 647 STRINGOPS_FLAG=
 648 if test "$libgo_cv_c_stringops" = yes; then
 649   STRINGOPS_FLAG=-minline-all-stringops
 650 fi
 651 AC_SUBST(STRINGOPS_FLAG)
 652
 653 dnl For x86 we want to compile the math library with -mfancy-math-387
 654 dnl so that we can use the builtin instructions directly.
 655 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 656 [libgo_cv_c_fancymath],
 657 [CFLAGS_hold=$CFLAGS
 658 CFLAGS="$CFLAGS -mfancy-math-387"
 659 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 660 [libgo_cv_c_fancymath=yes],
 661 [libgo_cv_c_fancymath=no])
 662 CFLAGS=$CFLAGS_hold])
 663 MATH_FLAG=
 664 if test "$libgo_cv_c_fancymath" = yes; then
 665   MATH_FLAG="-mfancy-math-387"
 666 fi
 667 MATH_FLAG="${MATH_FLAG} -ffp-contract=off -fno-math-errno -fno-trapping-math"
 668 AC_SUBST(MATH_FLAG)
 669
 670 CFLAGS_hold=$CFLAGS
 671 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 672 AC_CHECK_TYPES([off64_t])
 673 CFLAGS=$CFLAGS_hold
 674
 675 dnl Work out the size of the epoll_events struct on GNU/Linux.
 676 AC_CACHE_CHECK([epoll_event size],
 677 [libgo_cv_c_epoll_event_size],
 678 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 679 [sizeof (struct epoll_event)],
 680 [#include <sys/epoll.h>],
 681 [libgo_cv_c_epoll_event_size=0])])
 682 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 683 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 684
 685 dnl Work out the offset of the fd field in the epoll_events struct on
 686 dnl GNU/Linux.
 687 AC_CACHE_CHECK([epoll_event data.fd offset],
 688 [libgo_cv_c_epoll_event_fd_offset],
 689 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 690 [offsetof (struct epoll_event, data.fd)],
 691 [#include <stddef.h>
 692 #include <sys/epoll.h>],
 693 [libgo_cv_c_epoll_event_fd_offset=0])])
 694 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 695 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 696
 697 dnl Check if <sys/stat.h> uses timespec_t for st_?tim members.  Introduced
 698 dnl in Solaris 11.4 for XPG7 compatibility.
 699 AC_EGREP_HEADER([timespec_t.*st_atim], [sys/stat.h],
 700                 [have_stat_timespec=yes], [have_stat_timespec=no])
 701 AM_CONDITIONAL(HAVE_STAT_TIMESPEC, test $have_stat_timespec = yes)
 702
 703 dnl See if struct exception is defined in <math.h>.
 704 AC_CHECK_TYPE([struct exception],
 705 [libgo_has_struct_exception=yes],
 706 [libgo_has_struct_exception=no],
 707 [#include <math.h>])
 708 if test "$libgo_has_struct_exception" = "yes"; then
 709   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 710             [Define to 1 if <math.h> defines struct exception])
 711 fi
 712
 713 dnl See whether setcontext changes the value of TLS variables.
 714 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 715 [libgo_cv_lib_setcontext_clobbers_tls],
 716 [CFLAGS_hold="$CFLAGS"
 717 CFLAGS="$PTHREAD_CFLAGS"
 718 LIBS_hold="$LIBS"
 719 LIBS="$LIBS $PTHREAD_LIBS"
 720 AC_CHECK_SIZEOF([void *])
 721 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 722 AC_RUN_IFELSE(
 723   [AC_LANG_SOURCE([
 724 #include <pthread.h>
 725 #include <stdlib.h>
 726 #include <ucontext.h>
 727 #include <unistd.h>
 728
 729 __thread int tls;
 730
 731 static char stack[[10 * 1024 * 1024]];
 732 static ucontext_t c;
 733
 734 /* Called via makecontext/setcontext.  */
 735
 736 static void
 737 cfn (void)
 738 {
 739   exit (tls);
 740 }
 741
 742 /* Called via pthread_create.  */
 743
 744 static void *
 745 tfn (void *dummy)
 746 {
 747   /* The thread should still see this value after calling
 748      setcontext.  */
 749   tls = 0;
 750
 751   setcontext (&c);
 752
 753   /* The call to setcontext should not return.  */
 754   abort ();
 755 }
 756
 757 int
 758 main ()
 759 {
 760   pthread_t tid;
 761
 762   /* The thread should not see this value.  */
 763   tls = 1;
 764
 765   if (getcontext (&c) < 0)
 766     abort ();
 767
 768   c.uc_stack.ss_sp = stack;
 769 #ifdef MAKECONTEXT_STACK_TOP
 770   c.uc_stack.ss_sp += sizeof stack;
 771 #endif
 772   c.uc_stack.ss_flags = 0;
 773   c.uc_stack.ss_size = sizeof stack;
 774   c.uc_link = NULL;
 775   makecontext (&c, cfn, 0);
 776
 777   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 778     abort ();
 779
 780   if (pthread_join (tid, NULL) != 0)
 781     abort ();
 782
 783   /* The thread should have called exit.  */
 784   abort ();
 785 }
 786 ])],
 787 [libgo_cv_lib_setcontext_clobbers_tls=no],
 788 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 789 [case "$target:$ptr_type_size" in
 790   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 791     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 792   *)
 793     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 794  esac
 795 ])
 796 CFLAGS="$CFLAGS_hold"
 797 LIBS="$LIBS_hold"
 798 ])
 799 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 800   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 801             [Define if setcontext clobbers TLS variables])
 802 fi
 803
 804 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 805 libgo_cv_ro_eh_frame, [
 806 libgo_cv_ro_eh_frame=no
 807 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 808 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 809   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 810     libgo_cv_ro_eh_frame=yes
 811   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 812        | grep -v '#write' > /dev/null; then
 813     libgo_cv_ro_eh_frame=yes
 814   fi
 815 fi
 816 rm -f conftest.*
 817 ])
 818 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 819   AC_DEFINE(EH_FRAME_FLAGS, "a",
 820             [Define to the flags needed for the .section .eh_frame directive.])
 821 else
 822   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 823             [Define to the flags needed for the .section .eh_frame directive.])
 824 fi
 825
 826 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 827 [libgo_cv_c_unused_arguments],
 828 [CFLAGS_hold=$CFLAGS
 829 CFLAGS="$CFLAGS -Qunused-arguments"
 830 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 831 [libgo_cv_c_unused_arguments=yes],
 832 [libgo_cv_c_unused_arguments=no])
 833 CFLAGS=$CFLAGS_hold])
 834
 835 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 836 libgo_cv_as_comdat_gnu, [
 837 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 838 CFLAGS_hold=$CFLAGS
 839 if test "$libgo_cv_c_unused_arguments" = yes; then
 840   CFLAGS="$CFLAGS -Qunused-arguments"
 841 fi
 842 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 843   libgo_cv_as_comdat_gnu=yes
 844 else
 845   libgo_cv_as_comdat_gnu=no
 846 fi
 847 CFLAGS=$CFLAGS_hold
 848 ])
 849 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 850   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 851             [Define if your assembler supports GNU comdat group syntax.])
 852 fi
 853
 854 AC_CACHE_CHECK([assembler supports pc related relocs],
 855 libgo_cv_as_x86_pcrel, [
 856 libgo_cv_as_x86_pcrel=yes
 857 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 858 CFLAGS_hold=$CFLAGS
 859 if test "$libgo_cv_c_unused_arguments" = yes; then
 860   CFLAGS="$CFLAGS -Qunused-arguments"
 861 fi
 862 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 863     libgo_cv_as_x86_pcrel=no
 864 fi
 865 CFLAGS=$CFLAGS_hold
 866 ])
 867 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 868   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 869             [Define if your assembler supports PC relative relocs.])
 870 fi
 871
 872 AC_CACHE_CHECK([assembler supports unwind section type],
 873 libgo_cv_as_x86_64_unwind_section_type, [
 874 libgo_cv_as_x86_64_unwind_section_type=yes
 875 echo '.section .eh_frame,"a",@unwind' > conftest.s
 876 CFLAGS_hold=$CFLAGS
 877 if test "$libgo_cv_c_unused_arguments" = yes; then
 878   CFLAGS="$CFLAGS -Qunused-arguments"
 879 fi
 880 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 881     libgo_cv_as_x86_64_unwind_section_type=no
 882 fi
 883 CFLAGS=$CFLAGS_hold
 884 ])
 885 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 886   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 887             [Define if your assembler supports unwind section type.])
 888 fi
 889
 890 AC_CACHE_CHECK([assembler supports AES instructions],
 891 libgo_cv_as_x86_aes, [
 892 libgo_cv_as_x86_aes=yes
 893 echo 'aesenc %xmm0, %xmm1' > conftest.s
 894 CFLAGS_hold=$CFLAGS
 895 if test "$libgo_cv_c_unused_arguments" = yes; then
 896   CFLAGS="$CFLAGS -Qunused-arguments"
 897 fi
 898 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i error > /dev/null; then
 899     libgo_cv_as_x86_aes=no
 900 fi
 901 CFLAGS=$CFLAGS_hold
 902 ])
 903 if test "x$libgo_cv_as_x86_aes" = xyes; then
 904   AC_DEFINE(HAVE_AS_X86_AES, 1,
 905             [Define if your assembler supports AES instructions.])
 906 fi
 907
 908 AC_CACHE_SAVE
 909
 910 if test ${multilib} = yes; then
 911   multilib_arg="--enable-multilib"
 912 else
 913   multilib_arg=
 914 fi
 915
 916 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 917
 918 AC_CONFIG_COMMANDS([default],
 919 [if test -n "$CONFIG_FILES"; then
 920    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 921    # that multilib installs will end up installed in the correct place.
 922    # The testsuite needs it for multilib-aware ABI baseline files.
 923    # To work around this not being passed down from config-ml.in ->
 924    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 925    # append it here.  Only modify Makefiles that have just been created.
 926    #
 927    # Also, get rid of this simulated-VPATH thing that automake does.
 928    cat > vpsed << \_EOF
 929 s!`test -f '$<' || echo '$(srcdir)/'`!!
 930 _EOF
 931    for i in $SUBDIRS; do
 932     case $CONFIG_FILES in
 933      *${i}/Makefile*)
 934        #echo "Adding MULTISUBDIR to $i/Makefile"
 935        sed -f vpsed $i/Makefile > tmp
 936        grep '^MULTISUBDIR =' Makefile >> tmp
 937        mv tmp $i/Makefile
 938        ;;
 939     esac
 940    done
 941    rm vpsed
 942  fi
 943 ],
 944 [
 945 # Variables needed in config.status (file generation) which aren't already
 946 # passed by autoconf.
 947 SUBDIRS="$SUBDIRS"
 948 ])
 949
 950 AC_OUTPUT