libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=1:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign -Wall])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  46 AC_SUBST(WARN_FLAGS)
  47
  48 dnl FIXME: This should be controlled by --enable-maintainer-mode.
  49 WERROR="-Werror"
  50 AC_SUBST(WERROR)
  51
  52 glibgo_toolexecdir=no
  53 glibgo_toolexeclibdir=no
  54 glibgo_prefixdir=$prefix
  55
  56 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  57 AC_ARG_ENABLE([version-specific-runtime-libs],
  58   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  59                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  60   [case "$enableval" in
  61     yes) version_specific_libs=yes ;;
  62     no)  version_specific_libs=no ;;
  63     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  64    esac],
  65   [version_specific_libs=no])
  66 AC_MSG_RESULT($version_specific_libs)
  67
  68 # Version-specific runtime libs processing.
  69 if test $version_specific_libs = yes; then
  70   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  71   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  72 fi
  73
  74 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  75 # Install a library built with a cross compiler in tooldir, not libdir.
  76 if test x"$glibgo_toolexecdir" = x"no"; then
  77   if test -n "$with_cross_host" &&
  78      test x"$with_cross_host" != x"no"; then
  79     glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  80     glibgo_toolexeclibdir='${toolexecdir}/lib'
  81   else
  82     glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  83     glibgo_toolexeclibdir='${libdir}'
  84   fi
  85   multi_os_directory=`$CC -print-multi-os-directory`
  86   case $multi_os_directory in
  87     .) ;; # Avoid trailing /.
  88     *) glibgo_toolexeclibdir=$glibgo_toolexeclibdir/$multi_os_directory ;;
  89   esac
  90 fi
  91
  92 AC_SUBST(glibgo_prefixdir)
  93 AC_SUBST(glibgo_toolexecdir)
  94 AC_SUBST(glibgo_toolexeclibdir)
  95
  96 # See if the user wants to configure without libffi.  Some
  97 # architectures don't support it.  FIXME: We should set a default
  98 # based on the host.
  99 AC_ARG_WITH(libffi,
 100   AS_HELP_STRING([--without-libffi],
 101                  [don't use libffi]),
 102   [:],
 103   [with_libffi=${with_libffi_default-yes}])
 104
 105 LIBFFI=
 106 LIBFFIINCS=
 107 if test "$with_libffi" != no; then
 108    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 109    LIBFFI=../libffi/libffi_convenience.la
 110    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 111 fi
 112 AC_SUBST(LIBFFI)
 113 AC_SUBST(LIBFFIINCS)
 114
 115 is_darwin=no
 116 is_freebsd=no
 117 is_linux=no
 118 is_rtems=no
 119 is_solaris=no
 120 GOOS=unknown
 121 case ${host} in
 122   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 123   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 124   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 125   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 126   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 127 esac
 128 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 129 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 130 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 131 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 132 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 133 AC_SUBST(GOOS)
 134
 135 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 136 is_386=no
 137 is_arm=no
 138 is_sparc=no
 139 is_sparc64=no
 140 is_x86_64=no
 141 GOARCH=unknown
 142 case ${host} in
 143 changequote(,)dnl
 144   i[34567]86-*-* | x86_64-*-*)
 145 changequote([,])dnl
 146     AC_PREPROC_IFELSE([
 147 #ifdef __x86_64__
 148 #error 64-bit
 149 #endif],
 150 [is_386=yes], [is_x86_64=yes])
 151     if test "$is_386" = "yes"; then
 152       is_386=yes
 153       GOARCH=386
 154     else
 155       is_x86_64=yes
 156       GOARCH=amd64
 157     fi
 158     ;;
 159   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 160     is_arm=yes
 161     GOARCH=arm
 162     ;;
 163   sparc*-*-*)
 164     AC_PREPROC_IFELSE([
 165 #if defined(__sparcv9) || defined(__arch64__)
 166 #error 64-bit
 167 #endif],
 168 [is_sparc=yes], [is_sparc64=yes])
 169     if test "$is_sparc" = "yes"; then
 170       is_sparc=yes
 171       GOARCH=sparc
 172     else
 173       is_sparc64=yes
 174       GOARCH=sparc64
 175     fi
 176     ;;
 177 esac
 178 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 179 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 180 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 181 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 182 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 183 AC_SUBST(GOARCH)
 184
 185 dnl Use -fsplit-stack when compiling C code if available.
 186 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 187 [libgo_cv_c_split_stack_supported],
 188 [CFLAGS_hold=$CFLAGS
 189 CFLAGS="$CFLAGS -fsplit-stack"
 190 AC_COMPILE_IFELSE([[int i;]],
 191 [libgo_cv_c_split_stack_supported=yes],
 192 [libgo_cv_c_split_stack_supported=no])
 193 CFLAGS=$CFLAGS_hold])
 194 if test "$libgo_cv_c_split_stack_supported" = yes; then
 195   SPLIT_STACK=-fsplit-stack
 196   AC_DEFINE(USING_SPLIT_STACK, 1,
 197                 [Define if the compiler supports -fsplit-stack])
 198 else
 199   SPLIT_STACK=
 200 fi
 201 AC_SUBST(SPLIT_STACK)
 202 AM_CONDITIONAL(USING_SPLIT_STACK,
 203         test "$libgo_cv_c_split_stack_supported" = yes)
 204
 205 dnl Check whether the linker does stack munging when calling from
 206 dnl split-stack into non-split-stack code.  We check this by looking
 207 dnl at the --help output.  FIXME: This is only half right: it's
 208 dnl possible for the linker to support this for some targets but not
 209 dnl others.
 210 AC_CACHE_CHECK([whether linker supports split stack],
 211 [libgo_cv_c_linker_supports_split_stack],
 212 libgo_cv_c_linker_supports_split_stack=no
 213 if $LD --help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 214   libgo_cv_c_linker_supports_split_stack=yes
 215 fi)
 216 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 217   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 218             [Define if the linker support split stack adjustments])
 219 fi
 220
 221 dnl Test for the -lm library.
 222 MATH_LIBS=
 223 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 224 AC_SUBST(MATH_LIBS)
 225
 226 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 227 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 228   [libgo_cv_lib_sockets=
 229    libgo_check_both=no
 230    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 231    if test "$libgo_check_socket" = "yes"; then
 232      unset ac_cv_func_connect
 233      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 234                   libgo_check_both=yes)
 235    fi
 236    if test "$libgo_check_both" = "yes"; then
 237      libgo_old_libs=$LIBS
 238      LIBS="$LIBS -lsocket -lnsl"
 239      unset ac_cv_func_accept
 240      AC_CHECK_FUNC(accept,
 241                    [libgo_check_nsl=no
 242                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 243      unset ac_cv_func_accept
 244      LIBS=$libgo_old_libs
 245    fi
 246    unset ac_cv_func_gethostbyname
 247    libgo_old_libs="$LIBS"
 248    AC_CHECK_FUNC(gethostbyname, ,
 249                  [AC_CHECK_LIB(nsl, main,
 250                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 251    unset ac_cv_func_gethostbyname
 252    LIBS=$libgo_old_libs
 253 ])
 254 NET_LIBS="$libgo_cv_lib_sockets"
 255 AC_SUBST(NET_LIBS)
 256
 257 dnl Test whether the compiler supports the -pthread option.
 258 AC_CACHE_CHECK([whether -pthread is supported],
 259 [libgo_cv_lib_pthread],
 260 [CFLAGS_hold=$CFLAGS
 261 CFLAGS="$CFLAGS -pthread"
 262 AC_COMPILE_IFELSE([[int i;]],
 263 [libgo_cv_lib_pthread=yes],
 264 [libgo_cv_lib_pthread=no])
 265 CFLAGS=$CFLAGS_hold])
 266 PTHREAD_CFLAGS=
 267 if test "$libgo_cv_lib_pthread" = yes; then
 268   PTHREAD_CFLAGS=-pthread
 269 fi
 270 AC_SUBST(PTHREAD_CFLAGS)
 271
 272 dnl Test for the -lpthread library.
 273 PTHREAD_LIBS=
 274 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 275 AC_SUBST(PTHREAD_LIBS)
 276
 277 dnl Test if -lrt is required for sched_yield.
 278 AC_SEARCH_LIBS([sched_yield], [rt])
 279
 280 AC_C_BIGENDIAN
 281
 282 GCC_CHECK_UNWIND_GETIPINFO
 283
 284 AC_CHECK_HEADERS(sys/mman.h syscall.h sys/epoll.h sys/ptrace.h sys/user.h sys/utsname.h)
 285 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 286 AC_CHECK_FUNCS(srandom random strsignal)
 287
 288 dnl For x86 we want to use the -minline-all-stringops option to avoid
 289 dnl forcing a stack split when calling memcpy and friends.
 290 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 291 [libgo_cv_c_stringops],
 292 [CFLAGS_hold=$CFLAGS
 293 CFLAGS="$CFLAGS -minline-all-stringops"
 294 AC_COMPILE_IFELSE([int i;],
 295 [libgo_cv_c_stringops=yes],
 296 [libgo_cv_c_stringops=no])
 297 CFLAGS=$CFLAGS_hold])
 298 STRINGOPS_FLAG=
 299 if test "$libgo_cv_c_stringops" = yes; then
 300   STRINGOPS_FLAG=-minline-all-stringops
 301 fi
 302 AC_SUBST(STRINGOPS_FLAG)
 303
 304 CFLAGS_hold=$CFLAGS
 305 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 306 AC_CHECK_TYPES(off64_t)
 307 CFLAGS=$CFLAGS_hold
 308
 309 AC_CACHE_SAVE
 310
 311 if test ${multilib} = yes; then
 312   multilib_arg="--enable-multilib"
 313 else
 314   multilib_arg=
 315 fi
 316
 317 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 318
 319 AC_CONFIG_COMMANDS([default],
 320 [if test -n "$CONFIG_FILES"; then
 321    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 322    # that multilib installs will end up installed in the correct place.
 323    # The testsuite needs it for multilib-aware ABI baseline files.
 324    # To work around this not being passed down from config-ml.in ->
 325    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 326    # append it here.  Only modify Makefiles that have just been created.
 327    #
 328    # Also, get rid of this simulated-VPATH thing that automake does.
 329    cat > vpsed << \_EOF
 330 s!`test -f '$<' || echo '$(srcdir)/'`!!
 331 _EOF
 332    for i in $SUBDIRS; do
 333     case $CONFIG_FILES in
 334      *${i}/Makefile*)
 335        #echo "Adding MULTISUBDIR to $i/Makefile"
 336        sed -f vpsed $i/Makefile > tmp
 337        grep '^MULTISUBDIR =' Makefile >> tmp
 338        mv tmp $i/Makefile
 339        ;;
 340     esac
 341    done
 342    rm vpsed
 343  fi
 344 ],
 345 [
 346 # Variables needed in config.status (file generation) which aren't already
 347 # passed by autoconf.
 348 SUBDIRS="$SUBDIRS"
 349 ])
 350
 351 AC_OUTPUT