libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=11:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 case ${host} in
  35   *-*-aix*)
  36     # static hash tables crashes on AIX when libgo is built with O2
  37     CFLAGS="$CFLAGS -fno-section-anchors"
  38     GOCFLAGS="$GOCFLAGS -fno-section-anchors"
  39     ;;
  40 esac
  41
  42 AM_MAINTAINER_MODE
  43
  44 AC_PROG_LD
  45 AC_PROG_RANLIB
  46 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  47
  48 AC_LIBTOOL_DLOPEN
  49 AM_PROG_LIBTOOL
  50 AC_SUBST(enable_shared)
  51 AC_SUBST(enable_static)
  52
  53 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  54 AC_SUBST(CC_FOR_BUILD)
  55
  56 AC_PROG_AWK
  57
  58 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  59 AC_SUBST(WARN_FLAGS)
  60
  61 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  62                                       [turns on -Werror @<:@default=yes@:>@])])
  63 if test "x$enable_werror" != "xno"; then
  64   WERROR="-Werror"
  65 fi
  66 AC_SUBST(WERROR)
  67
  68 glibgo_toolexecdir=no
  69 glibgo_toolexeclibdir=no
  70
  71 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  72 AC_ARG_ENABLE([version-specific-runtime-libs],
  73   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  74                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  75   [case "$enableval" in
  76     yes) version_specific_libs=yes ;;
  77     no)  version_specific_libs=no ;;
  78     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  79    esac],
  80   [version_specific_libs=no])
  81 AC_MSG_RESULT($version_specific_libs)
  82
  83 # Version-specific runtime libs processing.
  84 if test $version_specific_libs = yes; then
  85   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  86   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  87 fi
  88
  89 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  90 # Install a library built with a cross compiler in tooldir, not libdir.
  91 if test -n "$with_cross_host" &&
  92    test x"$with_cross_host" != x"no"; then
  93   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  94   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  95 else
  96   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  97   nover_glibgo_toolexeclibdir='${libdir}'
  98 fi
  99 multi_os_directory=`$GOC -print-multi-os-directory`
 100 case $multi_os_directory in
 101   .) ;; # Avoid trailing /.
 102   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
 103 esac
 104
 105 if test x"$glibgo_toolexecdir" = x"no"; then
 106   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
 107   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 108 fi
 109
 110 AC_SUBST(glibgo_toolexecdir)
 111 AC_SUBST(glibgo_toolexeclibdir)
 112 AC_SUBST(nover_glibgo_toolexeclibdir)
 113
 114 # See if the user wants to configure without libffi.  Some
 115 # architectures don't support it.  FIXME: We should set a default
 116 # based on the host.
 117 AC_ARG_WITH(libffi,
 118   AS_HELP_STRING([--without-libffi],
 119                  [don't use libffi]),
 120   [:],
 121   [with_libffi=${with_libffi_default-yes}])
 122
 123 LIBFFI=
 124 LIBFFIINCS=
 125 if test "$with_libffi" != no; then
 126    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 127    LIBFFI=../libffi/libffi_convenience.la
 128    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 129 fi
 130 AC_SUBST(LIBFFI)
 131 AC_SUBST(LIBFFIINCS)
 132 AM_CONDITIONAL(USE_LIBFFI, test "$with_liffi" != "no")
 133
 134 # See if the user wants to configure without libatomic. This is useful if we are
 135 # on an architecture for which libgo does not need an atomic support library and
 136 # libatomic does not support our C compiler.
 137 AC_ARG_WITH(libatomic,
 138   AS_HELP_STRING([--without-libatomic],
 139                  [don't use libatomic]),
 140   [:],
 141   [with_libatomic=${with_libatomic_default-yes}])
 142
 143 LIBATOMIC=
 144 if test "$with_libatomic" != no; then
 145    LIBATOMIC=../libatomic/libatomic_convenience.la
 146 fi
 147 AC_SUBST(LIBATOMIC)
 148
 149 # Used to tell GNU make to include a file without telling automake to
 150 # include it.
 151 go_include="-include"
 152 AC_SUBST(go_include)
 153
 154 # All known GOOS values.  This is the union of all operating systems
 155 # supported by the gofrontend and all operating systems supported by
 156 # the gc toolchain.
 157 ALLGOOS="aix android darwin dragonfly freebsd irix linux netbsd openbsd plan9 rtems solaris windows"
 158
 159 is_darwin=no
 160 is_freebsd=no
 161 is_irix=no
 162 is_linux=no
 163 is_netbsd=no
 164 is_openbsd=no
 165 is_dragonfly=no
 166 is_rtems=no
 167 is_solaris=no
 168 is_aix=no
 169 GOOS=unknown
 170 case ${host} in
 171   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 172   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 173   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 174   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 175   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 176   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 177   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 178   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 179   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 180   *-*-aix*)      is_aix=yes;     GOOS=aix ;;
 181 esac
 182 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 183 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 184 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 185 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 186 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 187 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 188 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 189 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 190 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 191 AM_CONDITIONAL(LIBGO_IS_AIX, test $is_aix = yes)
 192 AM_CONDITIONAL(LIBGO_IS_BSD, test $is_darwin = yes -o $is_dragonfly = yes -o $is_freebsd = yes -o $is_netbsd = yes -o $is_openbsd = yes)
 193 AC_SUBST(GOOS)
 194 AC_SUBST(ALLGOOS)
 195
 196 dnl Test whether we need to use DejaGNU or whether we can use the
 197 dnl simpler gotest approach.  We can only use gotest for a native
 198 dnl build.
 199 USE_DEJAGNU=no
 200 case ${host} in
 201   *-*-rtems*) USE_DEJAGNU=yes ;;
 202   ${build}) ;;
 203   *) USE_DEJAGNU=yes ;;
 204 esac
 205 AC_SUBST(USE_DEJAGNU)
 206
 207 # All known GOARCH values.  This is the union of all architectures
 208 # supported by the gofrontend and all architectures supported by the
 209 # gc toolchain.
 210 # N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 211 ALLGOARCH="386 alpha amd64 amd64p32 arm armbe arm64 arm64be ia64 m68k mips mipsle mips64 mips64le mips64p32 mips64p32le ppc ppc64 ppc64le s390 s390x sparc sparc64"
 212
 213 # All known GOARCH_FAMILY values.
 214 ALLGOARCHFAMILY="I386 ALPHA AMD64 ARM ARM64 IA64 M68K MIPS MIPS64 PPC PPC64 S390 S390X SPARC SPARC64"
 215
 216 GOARCH=unknown
 217 GOARCH_FAMILY=unknown
 218 GOARCH_BIGENDIAN=0
 219 GOARCH_CACHELINESIZE=64
 220 GOARCH_PHYSPAGESIZE=4096
 221 GOARCH_PCQUANTUM=1
 222 GOARCH_INT64ALIGN=8
 223 GOARCH_HUGEPAGESIZE=0
 224 GOARCH_MINFRAMESIZE=0
 225 case ${host} in
 226   alpha*-*-*)
 227     GOARCH=alpha
 228     GOARCH_FAMILY=ALPHA
 229     GOARCH_PHYSPAGESIZE=8192
 230     GOARCH_PCQUANTUM=4
 231     ;;
 232   aarch64-*-*)
 233     GOARCH=arm64
 234     GOARCH_FAMILY=ARM64
 235     GOARCH_CACHELINESIZE=32
 236     GOARCH_PHYSPAGESIZE=65536
 237     GOARCH_PCQUANTUM=4
 238     GOARCH_MINFRAMESIZE=8
 239     ;;
 240   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 241     GOARCH=arm
 242     GOARCH_FAMILY=ARM
 243     GOARCH_CACHELINESIZE=32
 244     GOARCH_PCQUANTUM=4
 245     GOARCH_MINFRAMESIZE=4
 246     ;;
 247 changequote(,)dnl
 248   i[34567]86-*-* | x86_64-*-*)
 249 changequote([,])dnl
 250     AC_COMPILE_IFELSE([
 251 #ifdef __x86_64__
 252 #error 64-bit
 253 #endif],
 254 [GOARCH=386
 255 GOARCH_FAMILY=I386
 256 GOARCH_INT64ALIGN=4
 257 GOARCH_HUGEPAGESIZE="1 << 21"
 258 ],
 259 [GOARCH=amd64
 260 GOARCH_FAMILY=AMD64
 261 GOARCH_HUGEPAGESIZE="1 << 21"
 262 ])
 263     ;;
 264   ia64-*-*)
 265     GOARCH=ia64
 266     GOARCH_FAMILY=IA64
 267     GOARCH_CACHELINESIZE=16384
 268     GOARCH_PHYSPAGESIZE=65536
 269     ;;
 270   m68k*-*-*)
 271     GOARCH=m68k
 272     GOARCH_FAMILY=M68K
 273     GOARCH_BIGENDIAN=1
 274     GOARCH_CACHELINESIZE=16
 275     GOARCH_PCQUANTUM=4
 276     GOARCH_INT64ALIGN=2
 277     ;;
 278   mips*-*-*)
 279     AC_COMPILE_IFELSE([
 280 #if _MIPS_SIM != _ABIO32
 281 #error not o32
 282 #endif],
 283 [mips_abi="o32"],
 284         [AC_COMPILE_IFELSE([
 285 #if _MIPS_SIM != _ABIN32
 286 #error not n32
 287 #endif],
 288 [mips_abi="n32"],
 289         [AC_COMPILE_IFELSE([
 290 #if _MIPS_SIM != _ABI64
 291 #error not n64
 292 #endif],
 293 [mips_abi="n64"],
 294         [AC_MSG_ERROR([unknown MIPS ABI])
 295 [mips_abi="n32"]])])])
 296     case "$mips_abi" in
 297     "o32") GOARCH=mips ;;
 298     "n32") GOARCH=mips64p32 ;;
 299     "n64") GOARCH=mips64 ;;
 300     esac
 301     case "$mips_abi" in
 302     "o32" | "n32")
 303         GOARCH_FAMILY=MIPS
 304         GOARCH_MINFRAMESIZE=4
 305         ;;
 306     "n64")
 307         GOARCH_FAMILY=MIPS64
 308         GOARCH_MINFRAMESIZE=8
 309         ;;
 310     esac
 311     case "${host}" in
 312     mips*el-*-*)
 313         GOARCH="${GOARCH}le"
 314         ;;
 315     *)
 316         GOARCH_BIGENDIAN=1
 317         ;;
 318     esac
 319     GOARCH_CACHELINESIZE=32
 320     GOARCH_PHYSPAGESIZE=16384
 321     GOARCH_PCQUANTUM=4
 322     ;;
 323   rs6000*-*-* | powerpc*-*-*)
 324     AC_COMPILE_IFELSE([
 325 #ifdef _ARCH_PPC64
 326 #error 64-bit
 327 #endif],
 328 [GOARCH=ppc
 329 GOARCH_FAMILY=PPC
 330 GOARCH_BIGENDIAN=1
 331 ],
 332     [
 333 GOARCH_FAMILY=PPC64
 334 AC_COMPILE_IFELSE([
 335 #if defined(_BIG_ENDIAN) || defined(__BIG_ENDIAN__)
 336 #error 64be
 337 #endif],
 338 [GOARCH=ppc64le
 339 ],
 340 [GOARCH=ppc64
 341 GOARCH_BIGENDIAN=1
 342 ])])
 343     GOARCH_PHYSPAGESIZE=65536
 344     GOARCH_PCQUANTUM=4
 345     GOARCH_MINFRAMESIZE=32
 346     ;;
 347   s390*-*-*)
 348     AC_COMPILE_IFELSE([
 349 #if defined(__s390x__)
 350 #error 64-bit
 351 #endif],
 352 [GOARCH=s390
 353 GOARCH_FAMILY=S390
 354 GOARCH_MINFRAMESIZE=4
 355 ], [GOARCH=s390x
 356 GOARCH_FAMILY=S390X
 357 GOARCH_MINFRAMESIZE=8
 358 ])
 359     GOARCH_BIGENDIAN=1
 360     GOARCH_CACHELINESIZE=256
 361     GOARCH_PCQUANTUM=2
 362     ;;
 363   sparc*-*-*)
 364     AC_COMPILE_IFELSE([
 365 #if defined(__sparcv9) || defined(__arch64__)
 366 #error 64-bit
 367 #endif],
 368 [GOARCH=sparc
 369 GOARCH_FAMILY=SPARC
 370 ],
 371 [GOARCH=sparc64
 372 GOARCH_FAMILY=SPARC64
 373 ])
 374     GOARCH_BIGENDIAN=1
 375     GOARCH_PHYSPAGESIZE=8192
 376     GOARCH_PCQUANTUM=4
 377     ;;
 378 esac
 379 AC_SUBST(GOARCH)
 380 AC_SUBST(GOARCH_FAMILY)
 381 AC_SUBST(GOARCH_BIGENDIAN)
 382 AC_SUBST(GOARCH_CACHELINESIZE)
 383 AC_SUBST(GOARCH_PHYSPAGESIZE)
 384 AC_SUBST(GOARCH_PCQUANTUM)
 385 AC_SUBST(GOARCH_INT64ALIGN)
 386 AC_SUBST(GOARCH_HUGEPAGESIZE)
 387 AC_SUBST(GOARCH_MINFRAMESIZE)
 388 AC_SUBST(ALLGOARCH)
 389 AC_SUBST(ALLGOARCHFAMILY)
 390
 391 dnl Some files are only present when needed for specific architectures.
 392 GO_LIBCALL_OS_FILE=
 393 GO_LIBCALL_OS_ARCH_FILE=
 394 GO_SYSCALL_OS_FILE=
 395 GO_SYSCALL_OS_ARCH_FILE=
 396 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 397   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 398 fi
 399 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 400   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 401 fi
 402 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 403   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 404 fi
 405 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 406   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 407 fi
 408 AC_SUBST(GO_LIBCALL_OS_FILE)
 409 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 410 AC_SUBST(GO_SYSCALL_OS_FILE)
 411 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 412
 413 dnl Special flags used to generate sysinfo.go.
 414 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 415 case "$target" in
 416     mips-sgi-irix6.5*)
 417         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 418         # msghdr in <sys/socket.h>.
 419         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 420         ;;
 421     *-*-solaris2.1[[01]])
 422         # Solaris 10+ needs this so struct msghdr gets the msg_control
 423         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 424         # above doesn't work with C99.
 425         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 426         ;;
 427 esac
 428 AC_SUBST(OSCFLAGS)
 429
 430 dnl Check if assembler supports disabling hardware capability support.
 431 GCC_CHECK_ASSEMBLER_HWCAP
 432
 433 dnl Use -fsplit-stack when compiling C code if available.
 434 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 435 [libgo_cv_c_split_stack_supported],
 436 [CFLAGS_hold=$CFLAGS
 437 CFLAGS="$CFLAGS -fsplit-stack"
 438 AC_COMPILE_IFELSE([[int i;]],
 439 [libgo_cv_c_split_stack_supported=yes],
 440 [libgo_cv_c_split_stack_supported=no])
 441 CFLAGS=$CFLAGS_hold])
 442
 443 dnl Make sure the linker permits -fsplit-stack.  Old versions of gold will
 444 dnl reject split-stack code calling non-split-stack code on targets
 445 dnl they don't support.
 446 AC_CACHE_CHECK([whether linker supports split/non-split linked together],
 447 [libgo_cv_c_linker_split_non_split],
 448 [cat > conftest1.c << EOF
 449 extern void f();
 450 int main() { f(); return 0; }
 451 EOF
 452 cat > conftest2.c << EOF
 453 void f() {}
 454 EOF
 455 $CC -c -fsplit-stack $CFLAGS $CPPFLAGS conftest1.c >/dev/null 2>&1
 456 $CC -c $CFLAGS $CPPFLAGS conftest2.c > /dev/null 2>&1
 457 if $CC -o conftest conftest1.$ac_objext conftest2.$ac_objext > /dev/null 2>&1; then
 458   libgo_cv_c_linker_split_non_split=yes
 459 else
 460   libgo_cv_c_linker_split_non_split=no
 461 fi
 462 rm -f conftest1.* conftest2.* conftest])
 463
 464 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes; then
 465   SPLIT_STACK=-fsplit-stack
 466   AC_DEFINE(USING_SPLIT_STACK, 1,
 467                 [Define if the compiler supports -fsplit-stack])
 468 else
 469   SPLIT_STACK=
 470 fi
 471 AC_SUBST(SPLIT_STACK)
 472 AM_CONDITIONAL(USING_SPLIT_STACK,
 473         test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes)
 474
 475 dnl If the compiler supports split-stack but the linker does not, then
 476 dnl we need to explicitly disable split-stack for Go.
 477 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = no; then
 478   GO_SPLIT_STACK=-fno-split-stack
 479 else
 480   GO_SPLIT_STACK=
 481 fi
 482 AC_SUBST(GO_SPLIT_STACK)
 483
 484 dnl Check whether the linker does stack munging when calling from
 485 dnl split-stack into non-split-stack code.  We check this by looking
 486 dnl at the --help output.  FIXME: This is only half right: it's
 487 dnl possible for the linker to support this for some targets but not
 488 dnl others.
 489 dnl This is slightly different from the above check, which is whether
 490 dnl the linker permits the call at all.
 491 AC_CACHE_CHECK([whether linker supports split stack],
 492 [libgo_cv_c_linker_supports_split_stack],
 493 [libgo_cv_c_linker_supports_split_stack=no
 494 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 495   libgo_cv_c_linker_supports_split_stack=yes
 496 fi])
 497 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 498   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 499             [Define if the linker support split stack adjustments])
 500 fi
 501
 502 AC_CACHE_CHECK([whether compiler is llgo],
 503 [libgo_cv_c_goc_is_llgo],
 504 [libgo_cv_c_goc_is_llgo=no
 505 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 506   libgo_cv_c_goc_is_llgo=yes
 507 fi])
 508 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 509
 510 dnl Test for the -lm library.
 511 MATH_LIBS=
 512 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 513 AC_SUBST(MATH_LIBS)
 514
 515 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 516 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 517   [libgo_cv_lib_sockets=
 518    libgo_check_both=no
 519    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 520    if test "$libgo_check_socket" = "yes"; then
 521      unset ac_cv_func_connect
 522      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 523                   libgo_check_both=yes)
 524    fi
 525    if test "$libgo_check_both" = "yes"; then
 526      libgo_old_libs=$LIBS
 527      LIBS="$LIBS -lsocket -lnsl"
 528      unset ac_cv_func_accept
 529      AC_CHECK_FUNC(accept,
 530                    [libgo_check_nsl=no
 531                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 532      unset ac_cv_func_accept
 533      LIBS=$libgo_old_libs
 534    fi
 535    unset ac_cv_func_gethostbyname
 536    libgo_old_libs="$LIBS"
 537    AC_CHECK_FUNC(gethostbyname, ,
 538                  [AC_CHECK_LIB(nsl, main,
 539                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 540    unset ac_cv_func_gethostbyname
 541    AC_CHECK_FUNC(sendfile, ,
 542                  [AC_CHECK_LIB(sendfile, main,
 543                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lsendfile"])])
 544    LIBS=$libgo_old_libs
 545 ])
 546 NET_LIBS="$libgo_cv_lib_sockets"
 547 AC_SUBST(NET_LIBS)
 548
 549 dnl Test whether the compiler supports the -pthread option.
 550 AC_CACHE_CHECK([whether -pthread is supported],
 551 [libgo_cv_lib_pthread],
 552 [CFLAGS_hold=$CFLAGS
 553 CFLAGS="$CFLAGS -pthread"
 554 AC_COMPILE_IFELSE([[int i;]],
 555 [libgo_cv_lib_pthread=yes],
 556 [libgo_cv_lib_pthread=no])
 557 CFLAGS=$CFLAGS_hold])
 558 PTHREAD_CFLAGS=
 559 if test "$libgo_cv_lib_pthread" = yes; then
 560   PTHREAD_CFLAGS=-pthread
 561 fi
 562 AC_SUBST(PTHREAD_CFLAGS)
 563
 564 dnl Test for the -lpthread library.
 565 PTHREAD_LIBS=
 566 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 567 AC_SUBST(PTHREAD_LIBS)
 568
 569 dnl Test if -lrt is required for sched_yield or nanosleep or clock_gettime.
 570 AC_SEARCH_LIBS([sched_yield], [rt])
 571 AC_SEARCH_LIBS([nanosleep], [rt])
 572 AC_SEARCH_LIBS([clock_gettime], [rt])
 573
 574 AC_C_BIGENDIAN
 575
 576 GCC_CHECK_UNWIND_GETIPINFO
 577
 578 AC_CHECK_HEADERS(port.h sched.h semaphore.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/event.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/ptrace.h linux/reboot.h netinet/icmp6.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 579
 580 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 581 [#ifdef HAVE_SYS_SOCKET_H
 582 #include <sys/socket.h>
 583 #endif
 584 ])
 585
 586 AC_CACHE_CHECK([whether <ustat.h> can be used],
 587 [libgo_cv_c_ustat_h],
 588 [CFLAGS_hold=$CFLAGS
 589 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 590 AC_COMPILE_IFELSE(
 591 [AC_LANG_SOURCE([
 592 #include <sys/types.h>
 593 #ifdef HAVE_LINUX_FILTER_H
 594 #include <linux/filter.h>
 595 #endif
 596 #include <ustat.h>
 597 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 598 CFLAGS=$CFLAGS_hold])
 599 if test $libgo_cv_c_ustat_h = yes; then
 600   AC_DEFINE(HAVE_USTAT_H, 1,
 601     [Define to 1 if you have the <ustat.h> header file and it works.])
 602 fi
 603
 604 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 605
 606 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv unsetenv dl_iterate_phdr)
 607 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 608 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 609
 610 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice syscall tee unlinkat unshare utimensat)
 611 AC_TYPE_OFF_T
 612 AC_CHECK_TYPES([loff_t])
 613
 614 LIBS_hold="$LIBS"
 615 LIBS="$LIBS -lm"
 616 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 617 LIBS="$LIBS_hold"
 618
 619 CFLAGS_hold="$CFLAGS"
 620 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 621 LIBS_hold="$LIBS"
 622 LIBS="$LIBS $PTHREAD_LIBS"
 623 AC_CHECK_FUNCS(sem_timedwait)
 624 CFLAGS="$CFLAGS_hold"
 625 LIBS="$LIBS_hold"
 626
 627 LIBS_hold="$LIBS"
 628 LIBS="$LIBS $MATH_LIBS"
 629 AC_CHECK_FUNCS(matherr)
 630 LIBS="$LIBS_hold"
 631
 632 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 633 [libgo_cv_func___sync_bool_compare_and_swap_4],
 634 [AC_LINK_IFELSE([
 635 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 636 uint32 i;
 637 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 638 ],
 639 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 640 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 641 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 642   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 643     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 644 fi
 645
 646 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 647 [libgo_cv_func___sync_bool_compare_and_swap_8],
 648 [AC_LINK_IFELSE([
 649 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 650 uint64 i;
 651 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 652 ],
 653 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 654 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 655 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 656   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 657     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 658 fi
 659
 660 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 661 [libgo_cv_func___sync_fetch_and_add_4],
 662 [AC_LINK_IFELSE([
 663 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 664 uint32 i;
 665 int main() { return __sync_fetch_and_add (&i, 1); }
 666 ],
 667 [libgo_cv_func___sync_fetch_and_add_4=yes],
 668 [libgo_cv_func___sync_fetch_and_add_4=no])])
 669 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 670   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 671     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 672 fi
 673
 674 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 675 [libgo_cv_func___sync_add_and_fetch_8],
 676 [AC_LINK_IFELSE([
 677 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 678 uint64 i;
 679 int main() { return __sync_add_and_fetch (&i, 1); }
 680 ],
 681 [libgo_cv_func___sync_add_and_fetch_8=yes],
 682 [libgo_cv_func___sync_add_and_fetch_8=no])])
 683 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 684   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 685     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 686 fi
 687
 688 dnl For x86 we want to use the -minline-all-stringops option to avoid
 689 dnl forcing a stack split when calling memcpy and friends.
 690 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 691 [libgo_cv_c_stringops],
 692 [CFLAGS_hold=$CFLAGS
 693 CFLAGS="$CFLAGS -minline-all-stringops"
 694 AC_COMPILE_IFELSE([int i;],
 695 [libgo_cv_c_stringops=yes],
 696 [libgo_cv_c_stringops=no])
 697 CFLAGS=$CFLAGS_hold])
 698 STRINGOPS_FLAG=
 699 if test "$libgo_cv_c_stringops" = yes; then
 700   STRINGOPS_FLAG=-minline-all-stringops
 701 fi
 702 AC_SUBST(STRINGOPS_FLAG)
 703
 704 dnl For x86 we want to compile the math library with -mfancy-math-387
 705 dnl -funsafe-math-optimizations so that we can use the builtin
 706 dnl instructions directly.
 707 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 708 [libgo_cv_c_fancymath],
 709 [CFLAGS_hold=$CFLAGS
 710 CFLAGS="$CFLAGS -mfancy-math-387"
 711 AC_COMPILE_IFELSE([int i;],
 712 [libgo_cv_c_fancymath=yes],
 713 [libgo_cv_c_fancymath=no])
 714 CFLAGS=$CFLAGS_hold])
 715 MATH_FLAG=
 716 if test "$libgo_cv_c_fancymath" = yes; then
 717   MATH_FLAG="-mfancy-math-387 -funsafe-math-optimizations"
 718 else
 719   MATH_FLAG="-ffp-contract=off"
 720 fi
 721 AC_SUBST(MATH_FLAG)
 722
 723 CFLAGS_hold=$CFLAGS
 724 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 725 AC_CHECK_TYPES([off64_t])
 726 CFLAGS=$CFLAGS_hold
 727
 728 dnl Work out the size of the epoll_events struct on GNU/Linux.
 729 AC_CACHE_CHECK([epoll_event size],
 730 [libgo_cv_c_epoll_event_size],
 731 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 732 [sizeof (struct epoll_event)],
 733 [#include <sys/epoll.h>],
 734 [libgo_cv_c_epoll_event_size=0])])
 735 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 736 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 737
 738 dnl Work out the offset of the fd field in the epoll_events struct on
 739 dnl GNU/Linux.
 740 AC_CACHE_CHECK([epoll_event data.fd offset],
 741 [libgo_cv_c_epoll_event_fd_offset],
 742 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 743 [offsetof (struct epoll_event, data.fd)],
 744 [#include <stddef.h>
 745 #include <sys/epoll.h>],
 746 [libgo_cv_c_epoll_event_fd_offset=0])])
 747 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 748 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 749
 750 dnl Check if <sys/stat.h> uses timespec_t for st_?tim members.  Introduced
 751 dnl in Solaris 12 for XPG7 compatibility.
 752 AC_EGREP_HEADER([timespec_t.*st_atim], [sys/stat.h],
 753                 [have_stat_timespec=yes], [have_stat_timespec=no])
 754 AM_CONDITIONAL(HAVE_STAT_TIMESPEC, test $have_stat_timespec = yes)
 755
 756 dnl See if struct exception is defined in <math.h>.
 757 AC_CHECK_TYPE([struct exception],
 758 [libgo_has_struct_exception=yes],
 759 [libgo_has_struct_exception=no],
 760 [#include <math.h>])
 761 if test "$libgo_has_struct_exception" = "yes"; then
 762   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 763             [Define to 1 if <math.h> defines struct exception])
 764 fi
 765
 766 dnl See whether setcontext changes the value of TLS variables.
 767 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 768 [libgo_cv_lib_setcontext_clobbers_tls],
 769 [CFLAGS_hold="$CFLAGS"
 770 CFLAGS="$PTHREAD_CFLAGS"
 771 LIBS_hold="$LIBS"
 772 LIBS="$LIBS $PTHREAD_LIBS"
 773 AC_CHECK_SIZEOF([void *])
 774 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 775 AC_RUN_IFELSE(
 776   [AC_LANG_SOURCE([
 777 #include <pthread.h>
 778 #include <stdlib.h>
 779 #include <ucontext.h>
 780 #include <unistd.h>
 781
 782 __thread int tls;
 783
 784 static char stack[[10 * 1024 * 1024]];
 785 static ucontext_t c;
 786
 787 /* Called via makecontext/setcontext.  */
 788
 789 static void
 790 cfn (void)
 791 {
 792   exit (tls);
 793 }
 794
 795 /* Called via pthread_create.  */
 796
 797 static void *
 798 tfn (void *dummy)
 799 {
 800   /* The thread should still see this value after calling
 801      setcontext.  */
 802   tls = 0;
 803
 804   setcontext (&c);
 805
 806   /* The call to setcontext should not return.  */
 807   abort ();
 808 }
 809
 810 int
 811 main ()
 812 {
 813   pthread_t tid;
 814
 815   /* The thread should not see this value.  */
 816   tls = 1;
 817
 818   if (getcontext (&c) < 0)
 819     abort ();
 820
 821   c.uc_stack.ss_sp = stack;
 822 #ifdef MAKECONTEXT_STACK_TOP
 823   c.uc_stack.ss_sp += sizeof stack;
 824 #endif
 825   c.uc_stack.ss_flags = 0;
 826   c.uc_stack.ss_size = sizeof stack;
 827   c.uc_link = NULL;
 828   makecontext (&c, cfn, 0);
 829
 830   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 831     abort ();
 832
 833   if (pthread_join (tid, NULL) != 0)
 834     abort ();
 835
 836   /* The thread should have called exit.  */
 837   abort ();
 838 }
 839 ])],
 840 [libgo_cv_lib_setcontext_clobbers_tls=no],
 841 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 842 [case "$target:$ptr_type_size" in
 843   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 844     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 845   *)
 846     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 847  esac
 848 ])
 849 CFLAGS="$CFLAGS_hold"
 850 LIBS="$LIBS_hold"
 851 ])
 852 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 853   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 854             [Define if setcontext clobbers TLS variables])
 855 fi
 856
 857 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 858 libgo_cv_ro_eh_frame, [
 859 libgo_cv_ro_eh_frame=no
 860 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 861 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 862   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 863     libgo_cv_ro_eh_frame=yes
 864   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 865        | grep -v '#write' > /dev/null; then
 866     libgo_cv_ro_eh_frame=yes
 867   fi
 868 fi
 869 rm -f conftest.*
 870 ])
 871 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 872   AC_DEFINE(EH_FRAME_FLAGS, "a",
 873             [Define to the flags needed for the .section .eh_frame directive.])
 874 else
 875   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 876             [Define to the flags needed for the .section .eh_frame directive.])
 877 fi
 878
 879 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 880 [libgo_cv_c_unused_arguments],
 881 [CFLAGS_hold=$CFLAGS
 882 CFLAGS="$CFLAGS -Qunused-arguments"
 883 AC_COMPILE_IFELSE([[int i;]],
 884 [libgo_cv_c_unused_arguments=yes],
 885 [libgo_cv_c_unused_arguments=no])
 886 CFLAGS=$CFLAGS_hold])
 887
 888 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 889 libgo_cv_as_comdat_gnu, [
 890 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 891 CFLAGS_hold=$CFLAGS
 892 if test "$libgo_cv_c_unused_arguments" = yes; then
 893   CFLAGS="$CFLAGS -Qunused-arguments"
 894 fi
 895 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 896   libgo_cv_as_comdat_gnu=yes
 897 else
 898   libgo_cv_as_comdat_gnu=no
 899 fi
 900 CFLAGS=$CFLAGS_hold
 901 ])
 902 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 903   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 904             [Define if your assembler supports GNU comdat group syntax.])
 905 fi
 906
 907 AC_CACHE_CHECK([assembler supports pc related relocs],
 908 libgo_cv_as_x86_pcrel, [
 909 libgo_cv_as_x86_pcrel=yes
 910 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 911 CFLAGS_hold=$CFLAGS
 912 if test "$libgo_cv_c_unused_arguments" = yes; then
 913   CFLAGS="$CFLAGS -Qunused-arguments"
 914 fi
 915 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 916     libgo_cv_as_x86_pcrel=no
 917 fi
 918 CFLAGS=$CFLAGS_hold
 919 ])
 920 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 921   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 922             [Define if your assembler supports PC relative relocs.])
 923 fi
 924
 925 AC_CACHE_CHECK([assembler supports unwind section type],
 926 libgo_cv_as_x86_64_unwind_section_type, [
 927 libgo_cv_as_x86_64_unwind_section_type=yes
 928 echo '.section .eh_frame,"a",@unwind' > conftest.s
 929 CFLAGS_hold=$CFLAGS
 930 if test "$libgo_cv_c_unused_arguments" = yes; then
 931   CFLAGS="$CFLAGS -Qunused-arguments"
 932 fi
 933 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 934     libgo_cv_as_x86_64_unwind_section_type=no
 935 fi
 936 CFLAGS=$CFLAGS_hold
 937 ])
 938 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 939   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 940             [Define if your assembler supports unwind section type.])
 941 fi
 942
 943 AC_CACHE_CHECK([assembler supports AES instructions],
 944 libgo_cv_as_x86_aes, [
 945 libgo_cv_as_x86_aes=yes
 946 echo 'aesenc %xmm0, %xmm1' > conftest.s
 947 CFLAGS_hold=$CFLAGS
 948 if test "$libgo_cv_c_unused_arguments" = yes; then
 949   CFLAGS="$CFLAGS -Qunused-arguments"
 950 fi
 951 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i error > /dev/null; then
 952     libgo_cv_as_x86_aes=no
 953 fi
 954 CFLAGS=$CFLAGS_hold
 955 ])
 956 if test "x$libgo_cv_as_x86_aes" = xyes; then
 957   AC_DEFINE(HAVE_AS_X86_AES, 1,
 958             [Define if your assembler supports AES instructions.])
 959 fi
 960
 961 AC_CACHE_SAVE
 962
 963 if test ${multilib} = yes; then
 964   multilib_arg="--enable-multilib"
 965 else
 966   multilib_arg=
 967 fi
 968
 969 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 970
 971 AC_CONFIG_COMMANDS([default],
 972 [if test -n "$CONFIG_FILES"; then
 973    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 974    # that multilib installs will end up installed in the correct place.
 975    # The testsuite needs it for multilib-aware ABI baseline files.
 976    # To work around this not being passed down from config-ml.in ->
 977    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 978    # append it here.  Only modify Makefiles that have just been created.
 979    #
 980    # Also, get rid of this simulated-VPATH thing that automake does.
 981    cat > vpsed << \_EOF
 982 s!`test -f '$<' || echo '$(srcdir)/'`!!
 983 _EOF
 984    for i in $SUBDIRS; do
 985     case $CONFIG_FILES in
 986      *${i}/Makefile*)
 987        #echo "Adding MULTISUBDIR to $i/Makefile"
 988        sed -f vpsed $i/Makefile > tmp
 989        grep '^MULTISUBDIR =' Makefile >> tmp
 990        mv tmp $i/Makefile
 991        ;;
 992     esac
 993    done
 994    rm vpsed
 995  fi
 996 ],
 997 [
 998 # Variables needed in config.status (file generation) which aren't already
 999 # passed by autoconf.
1000 SUBDIRS="$SUBDIRS"
1001 ])
1002
1003 AC_OUTPUT