libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=10:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  54                                       [turns on -Werror @<:@default=yes@:>@])])
  55 if test "x$enable_werror" != "xno"; then
  56   WERROR="-Werror"
  57 fi
  58 AC_SUBST(WERROR)
  59
  60 glibgo_toolexecdir=no
  61 glibgo_toolexeclibdir=no
  62
  63 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  64 AC_ARG_ENABLE([version-specific-runtime-libs],
  65   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  67   [case "$enableval" in
  68     yes) version_specific_libs=yes ;;
  69     no)  version_specific_libs=no ;;
  70     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71    esac],
  72   [version_specific_libs=no])
  73 AC_MSG_RESULT($version_specific_libs)
  74
  75 # Version-specific runtime libs processing.
  76 if test $version_specific_libs = yes; then
  77   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  78   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  79 fi
  80
  81 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  82 # Install a library built with a cross compiler in tooldir, not libdir.
  83 if test -n "$with_cross_host" &&
  84    test x"$with_cross_host" != x"no"; then
  85   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  86   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  87 else
  88   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  89   nover_glibgo_toolexeclibdir='${libdir}'
  90 fi
  91 multi_os_directory=`$GOC -print-multi-os-directory`
  92 case $multi_os_directory in
  93   .) ;; # Avoid trailing /.
  94   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
  95 esac
  96
  97 if test x"$glibgo_toolexecdir" = x"no"; then
  98   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
  99   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 100 fi
 101
 102 AC_SUBST(glibgo_toolexecdir)
 103 AC_SUBST(glibgo_toolexeclibdir)
 104 AC_SUBST(nover_glibgo_toolexeclibdir)
 105
 106 # See if the user wants to configure without libffi.  Some
 107 # architectures don't support it.  FIXME: We should set a default
 108 # based on the host.
 109 AC_ARG_WITH(libffi,
 110   AS_HELP_STRING([--without-libffi],
 111                  [don't use libffi]),
 112   [:],
 113   [with_libffi=${with_libffi_default-yes}])
 114
 115 LIBFFI=
 116 LIBFFIINCS=
 117 if test "$with_libffi" != no; then
 118    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 119    LIBFFI=../libffi/libffi_convenience.la
 120    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 121 fi
 122 AC_SUBST(LIBFFI)
 123 AC_SUBST(LIBFFIINCS)
 124 AM_CONDITIONAL(USE_LIBFFI, test "$with_liffi" != "no")
 125
 126 # See if the user wants to configure without libatomic. This is useful if we are
 127 # on an architecture for which libgo does not need an atomic support library and
 128 # libatomic does not support our C compiler.
 129 AC_ARG_WITH(libatomic,
 130   AS_HELP_STRING([--without-libatomic],
 131                  [don't use libatomic]),
 132   [:],
 133   [with_libatomic=${with_libatomic_default-yes}])
 134
 135 LIBATOMIC=
 136 if test "$with_libatomic" != no; then
 137    LIBATOMIC=../libatomic/libatomic_convenience.la
 138 fi
 139 AC_SUBST(LIBATOMIC)
 140
 141 # Used to tell GNU make to include a file without telling automake to
 142 # include it.
 143 go_include="-include"
 144 AC_SUBST(go_include)
 145
 146 # All known GOOS values.  This is the union of all operating systems
 147 # supported by the gofrontend and all operating systems supported by
 148 # the gc toolchain.
 149 ALLGOOS="android darwin dragonfly freebsd irix linux netbsd openbsd plan9 rtems solaris windows"
 150
 151 is_darwin=no
 152 is_freebsd=no
 153 is_irix=no
 154 is_linux=no
 155 is_netbsd=no
 156 is_openbsd=no
 157 is_dragonfly=no
 158 is_rtems=no
 159 is_solaris=no
 160 GOOS=unknown
 161 case ${host} in
 162   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 163   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 164   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 165   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 166   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 167   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 168   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 169   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 170   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 171 esac
 172 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 173 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 174 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 175 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 176 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 177 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 178 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 179 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 180 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 181 AM_CONDITIONAL(LIBGO_IS_BSD, test $is_darwin = yes -o $is_dragonfly = yes -o $is_freebsd = yes -o $is_netbsd = yes -o $is_openbsd = yes)
 182 AC_SUBST(GOOS)
 183 AC_SUBST(ALLGOOS)
 184
 185 dnl Test whether we need to use DejaGNU or whether we can use the
 186 dnl simpler gotest approach.  We can only use gotest for a native
 187 dnl build.
 188 USE_DEJAGNU=no
 189 case ${host} in
 190   *-*-rtems*) USE_DEJAGNU=yes ;;
 191   ${build}) ;;
 192   *) USE_DEJAGNU=yes ;;
 193 esac
 194 AC_SUBST(USE_DEJAGNU)
 195
 196 # All known GOARCH values.  This is the union of all architectures
 197 # supported by the gofrontend and all architectures supported by the
 198 # gc toolchain.
 199 # N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 200 ALLGOARCH="386 alpha amd64 amd64p32 arm armbe arm64 arm64be ia64 m68k mipso32 mipsn32 mipso64 mipsn64 mips mipsle mips64 mips64le mips64p32 mips64pe32le ppc ppc64 ppc64le s390 s390x sparc sparc64"
 201
 202 # All known GOARCH_FAMILY values.
 203 ALLGOARCHFAMILY="I386 ALPHA AMD64 ARM ARM64 IA64 M68K MIPS MIPS64 PPC PPC64 S390 S390X SPARC SPARC64"
 204
 205 GOARCH=unknown
 206 GOARCH_FAMILY=unknown
 207 GOARCH_BIGENDIAN=0
 208 GOARCH_CACHELINESIZE=64
 209 GOARCH_PHYSPAGESIZE=4096
 210 GOARCH_PCQUANTUM=1
 211 GOARCH_INT64ALIGN=8
 212 GOARCH_HUGEPAGESIZE=0
 213 GOARCH_MINFRAMESIZE=0
 214 case ${host} in
 215   alpha*-*-*)
 216     GOARCH=alpha
 217     GOARCH_FAMILY=ALPHA
 218     GOARCH_PHYSPAGESIZE=8192
 219     GOARCH_PCQUANTUM=4
 220     ;;
 221   aarch64-*-*)
 222     GOARCH=arm64
 223     GOARCH_FAMILY=ARM64
 224     GOARCH_CACHELINESIZE=32
 225     GOARCH_PHYSPAGESIZE=65536
 226     GOARCH_PCQUANTUM=4
 227     GOARCH_MINFRAMESIZE=8
 228     ;;
 229   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 230     GOARCH=arm
 231     GOARCH_FAMILY=ARM
 232     GOARCH_CACHELINESIZE=32
 233     GOARCH_PCQUANTUM=4
 234     GOARCH_MINFRAMESIZE=4
 235     ;;
 236 changequote(,)dnl
 237   i[34567]86-*-* | x86_64-*-*)
 238 changequote([,])dnl
 239     AC_COMPILE_IFELSE([
 240 #ifdef __x86_64__
 241 #error 64-bit
 242 #endif],
 243 [GOARCH=386
 244 GOARCH_FAMILY=I386
 245 GOARCH_INT64ALIGN=4
 246 GOARCH_HUGEPAGESIZE="1 << 21"
 247 ],
 248 [GOARCH=amd64
 249 GOARCH_FAMILY=AMD64
 250 GOARCH_HUGEPAGESIZE="1 << 21"
 251 ])
 252     ;;
 253   ia64-*-*)
 254     GOARCH=ia64
 255     GOARCH_FAMILY=IA64
 256     GOARCH_CACHELINESIZE=16384
 257     GOARCH_PHYSPAGESIZE=65536
 258     ;;
 259   m68k*-*-*)
 260     GOARCH=m68k
 261     GOARCH_FAMILY=M68K
 262     GOARCH_BIGENDIAN=1
 263     GOARCH_CACHELINESIZE=16
 264     GOARCH_PCQUANTUM=4
 265     GOARCH_INT64ALIGN=2
 266     ;;
 267   mips*-*-*)
 268     AC_COMPILE_IFELSE([
 269 #if _MIPS_SIM != _ABIO32
 270 #error not o32
 271 #endif],
 272 [mips_abi="o32"],
 273         [AC_COMPILE_IFELSE([
 274 #if _MIPS_SIM != _ABIN32
 275 #error not n32
 276 #endif],
 277 [mips_abi="n32"],
 278         [AC_COMPILE_IFELSE([
 279 #if _MIPS_SIM != _ABI64
 280 #error not n64
 281 #endif],
 282 [mips_abi="n64"],
 283         [AC_COMPILE_IFELSE([
 284 #if _MIPS_SIM != _ABIO64
 285 #error not o64
 286 #endif],
 287 [mips_abi="o64"],
 288         [AC_MSG_ERROR([unknown MIPS ABI])
 289 [mips_abi="n32"]])])])])
 290     case "$mips_abi" in
 291     "o32") GOARCH=mipso32 ;;
 292     "n32") GOARCH=mipsn32 ;;
 293     "n64") GOARCH=mipsn64 ;;
 294     "o64") GOARCH=mipso64 ;;
 295     esac
 296     case "$mips_abi" in
 297     "o32" | "n32")
 298         GOARCH_FAMILY=MIPS
 299         GOARCH_MINFRAMESIZE=4
 300         ;;
 301     "n64" | "o64")
 302         GOARCH_FAMILY=MIPS64
 303         GOARCH_MINFRAMESIZE=8
 304         ;;
 305     esac
 306     case "${host}" in
 307     mips*el)
 308         ;;
 309     *)
 310         GOARCH_BIGENDIAN=1
 311         ;;
 312     esac
 313     GOARCH_CACHELINESIZE=32
 314     GOARCH_PHYSPAGESIZE=16384
 315     GOARCH_PCQUANTUM=4
 316     ;;
 317   rs6000*-*-* | powerpc*-*-*)
 318     AC_COMPILE_IFELSE([
 319 #ifdef _ARCH_PPC64
 320 #error 64-bit
 321 #endif],
 322 [GOARCH=ppc
 323 GOARCH_FAMILY=PPC
 324 GOARCH_BIGENDIAN=1
 325 ],
 326     [
 327 GOARCH_FAMILY=PPC64
 328 AC_COMPILE_IFELSE([
 329 #if defined(_BIG_ENDIAN) || defined(__BIG_ENDIAN__)
 330 #error 64be
 331 #endif],
 332 [GOARCH=ppc64le
 333 ],
 334 [GOARCH=ppc64
 335 GOARCH_BIGENDIAN=1
 336 ])])
 337     GOARCH_PHYSPAGESIZE=65536
 338     GOARCH_PCQUANTUM=4
 339     GOARCH_MINFRAMESIZE=32
 340     ;;
 341   s390*-*-*)
 342     AC_COMPILE_IFELSE([
 343 #if defined(__s390x__)
 344 #error 64-bit
 345 #endif],
 346 [GOARCH=s390
 347 GOARCH_FAMILY=S390
 348 GOARCH_MINFRAMESIZE=4
 349 ], [GOARCH=s390x
 350 GOARCH_FAMILY=S390X
 351 GOARCH_MINFRAMESIZE=8
 352 ])
 353     GOARCH_BIGENDIAN=1
 354     GOARCH_CACHELINESIZE=256
 355     GOARCH_PCQUANTUM=2
 356     ;;
 357   sparc*-*-*)
 358     AC_COMPILE_IFELSE([
 359 #if defined(__sparcv9) || defined(__arch64__)
 360 #error 64-bit
 361 #endif],
 362 [GOARCH=sparc
 363 GOARCH_FAMILY=SPARC
 364 ],
 365 [GOARCH=sparc64
 366 GOARCH_FAMILY=SPARC64
 367 ])
 368     GOARCH_BIGENDIAN=1
 369     GOARCH_PHYSPAGESIZE=8192
 370     GOARCH_PCQUANTUM=4
 371     ;;
 372 esac
 373 AC_SUBST(GOARCH)
 374 AC_SUBST(GOARCH_FAMILY)
 375 AC_SUBST(GOARCH_BIGENDIAN)
 376 AC_SUBST(GOARCH_CACHELINESIZE)
 377 AC_SUBST(GOARCH_PHYSPAGESIZE)
 378 AC_SUBST(GOARCH_PCQUANTUM)
 379 AC_SUBST(GOARCH_INT64ALIGN)
 380 AC_SUBST(GOARCH_HUGEPAGESIZE)
 381 AC_SUBST(GOARCH_MINFRAMESIZE)
 382 AC_SUBST(ALLGOARCH)
 383 AC_SUBST(ALLGOARCHFAMILY)
 384
 385 dnl Some files are only present when needed for specific architectures.
 386 GO_LIBCALL_OS_FILE=
 387 GO_LIBCALL_OS_ARCH_FILE=
 388 GO_SYSCALL_OS_FILE=
 389 GO_SYSCALL_OS_ARCH_FILE=
 390 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 391   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 392 fi
 393 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 394   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 395 fi
 396 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 397   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 398 fi
 399 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 400   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 401 fi
 402 AC_SUBST(GO_LIBCALL_OS_FILE)
 403 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 404 AC_SUBST(GO_SYSCALL_OS_FILE)
 405 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 406
 407 dnl Special flags used to generate sysinfo.go.
 408 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 409 case "$target" in
 410     mips-sgi-irix6.5*)
 411         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 412         # msghdr in <sys/socket.h>.
 413         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 414         ;;
 415     *-*-solaris2.1[[01]])
 416         # Solaris 10+ needs this so struct msghdr gets the msg_control
 417         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 418         # above doesn't work with C99.
 419         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 420         ;;
 421 esac
 422 AC_SUBST(OSCFLAGS)
 423
 424 dnl Use -fsplit-stack when compiling C code if available.
 425 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 426 [libgo_cv_c_split_stack_supported],
 427 [CFLAGS_hold=$CFLAGS
 428 CFLAGS="$CFLAGS -fsplit-stack"
 429 AC_COMPILE_IFELSE([[int i;]],
 430 [libgo_cv_c_split_stack_supported=yes],
 431 [libgo_cv_c_split_stack_supported=no])
 432 CFLAGS=$CFLAGS_hold])
 433
 434 dnl Make sure the linker permits -fsplit-stack.  Old versions of gold will
 435 dnl reject split-stack code calling non-split-stack code on targets
 436 dnl they don't support.
 437 AC_CACHE_CHECK([whether linker supports split/non-split linked together],
 438 [libgo_cv_c_linker_split_non_split],
 439 [cat > conftest1.c << EOF
 440 extern void f();
 441 int main() { f(); return 0; }
 442 EOF
 443 cat > conftest2.c << EOF
 444 void f() {}
 445 EOF
 446 $CC -c -fsplit-stack $CFLAGS $CPPFLAGS conftest1.c >/dev/null 2>&1
 447 $CC -c $CFLAGS $CPPFLAGS conftest2.c > /dev/null 2>&1
 448 if $CC -o conftest conftest1.$ac_objext conftest2.$ac_objext > /dev/null 2>&1; then
 449   libgo_cv_c_linker_split_non_split=yes
 450 else
 451   libgo_cv_c_linker_split_non_split=no
 452 fi
 453 rm -f conftest1.* conftest2.* conftest])
 454
 455 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes; then
 456   SPLIT_STACK=-fsplit-stack
 457   AC_DEFINE(USING_SPLIT_STACK, 1,
 458                 [Define if the compiler supports -fsplit-stack])
 459 else
 460   SPLIT_STACK=
 461 fi
 462 AC_SUBST(SPLIT_STACK)
 463 AM_CONDITIONAL(USING_SPLIT_STACK,
 464         test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes)
 465
 466 dnl If the compiler supports split-stack but the linker does not, then
 467 dnl we need to explicitly disable split-stack for Go.
 468 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = no; then
 469   GO_SPLIT_STACK=-fno-split-stack
 470 else
 471   GO_SPLIT_STACK=
 472 fi
 473 AC_SUBST(GO_SPLIT_STACK)
 474
 475 dnl Check whether the linker does stack munging when calling from
 476 dnl split-stack into non-split-stack code.  We check this by looking
 477 dnl at the --help output.  FIXME: This is only half right: it's
 478 dnl possible for the linker to support this for some targets but not
 479 dnl others.
 480 dnl This is slightly different from the above check, which is whether
 481 dnl the linker permits the call at all.
 482 AC_CACHE_CHECK([whether linker supports split stack],
 483 [libgo_cv_c_linker_supports_split_stack],
 484 [libgo_cv_c_linker_supports_split_stack=no
 485 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 486   libgo_cv_c_linker_supports_split_stack=yes
 487 fi])
 488 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 489   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 490             [Define if the linker support split stack adjustments])
 491 fi
 492
 493 AC_CACHE_CHECK([whether compiler is llgo],
 494 [libgo_cv_c_goc_is_llgo],
 495 [libgo_cv_c_goc_is_llgo=no
 496 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 497   libgo_cv_c_goc_is_llgo=yes
 498 fi])
 499 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 500
 501 dnl Test for the -lm library.
 502 MATH_LIBS=
 503 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 504 AC_SUBST(MATH_LIBS)
 505
 506 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 507 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 508   [libgo_cv_lib_sockets=
 509    libgo_check_both=no
 510    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 511    if test "$libgo_check_socket" = "yes"; then
 512      unset ac_cv_func_connect
 513      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 514                   libgo_check_both=yes)
 515    fi
 516    if test "$libgo_check_both" = "yes"; then
 517      libgo_old_libs=$LIBS
 518      LIBS="$LIBS -lsocket -lnsl"
 519      unset ac_cv_func_accept
 520      AC_CHECK_FUNC(accept,
 521                    [libgo_check_nsl=no
 522                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 523      unset ac_cv_func_accept
 524      LIBS=$libgo_old_libs
 525    fi
 526    unset ac_cv_func_gethostbyname
 527    libgo_old_libs="$LIBS"
 528    AC_CHECK_FUNC(gethostbyname, ,
 529                  [AC_CHECK_LIB(nsl, main,
 530                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 531    unset ac_cv_func_gethostbyname
 532    AC_CHECK_FUNC(sendfile, ,
 533                  [AC_CHECK_LIB(sendfile, main,
 534                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lsendfile"])])
 535    LIBS=$libgo_old_libs
 536 ])
 537 NET_LIBS="$libgo_cv_lib_sockets"
 538 AC_SUBST(NET_LIBS)
 539
 540 dnl Test whether the compiler supports the -pthread option.
 541 AC_CACHE_CHECK([whether -pthread is supported],
 542 [libgo_cv_lib_pthread],
 543 [CFLAGS_hold=$CFLAGS
 544 CFLAGS="$CFLAGS -pthread"
 545 AC_COMPILE_IFELSE([[int i;]],
 546 [libgo_cv_lib_pthread=yes],
 547 [libgo_cv_lib_pthread=no])
 548 CFLAGS=$CFLAGS_hold])
 549 PTHREAD_CFLAGS=
 550 if test "$libgo_cv_lib_pthread" = yes; then
 551   PTHREAD_CFLAGS=-pthread
 552 fi
 553 AC_SUBST(PTHREAD_CFLAGS)
 554
 555 dnl Test for the -lpthread library.
 556 PTHREAD_LIBS=
 557 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 558 AC_SUBST(PTHREAD_LIBS)
 559
 560 dnl Test if -lrt is required for sched_yield or nanosleep or clock_gettime.
 561 AC_SEARCH_LIBS([sched_yield], [rt])
 562 AC_SEARCH_LIBS([nanosleep], [rt])
 563 AC_SEARCH_LIBS([clock_gettime], [rt])
 564
 565 AC_C_BIGENDIAN
 566
 567 GCC_CHECK_UNWIND_GETIPINFO
 568
 569 AC_CHECK_HEADERS(port.h sched.h semaphore.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/event.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/reboot.h netinet/icmp6.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 570
 571 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 572 [#ifdef HAVE_SYS_SOCKET_H
 573 #include <sys/socket.h>
 574 #endif
 575 ])
 576
 577 AC_CACHE_CHECK([whether <ustat.h> can be used],
 578 [libgo_cv_c_ustat_h],
 579 [CFLAGS_hold=$CFLAGS
 580 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 581 AC_COMPILE_IFELSE(
 582 [AC_LANG_SOURCE([
 583 #include <sys/types.h>
 584 #ifdef HAVE_LINUX_FILTER_H
 585 #include <linux/filter.h>
 586 #endif
 587 #include <ustat.h>
 588 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 589 CFLAGS=$CFLAGS_hold])
 590 if test $libgo_cv_c_ustat_h = yes; then
 591   AC_DEFINE(HAVE_USTAT_H, 1,
 592     [Define to 1 if you have the <ustat.h> header file and it works.])
 593 fi
 594
 595 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 596
 597 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv unsetenv dl_iterate_phdr)
 598 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 599 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 600
 601 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice tee unlinkat unshare utimensat)
 602 AC_TYPE_OFF_T
 603 AC_CHECK_TYPES([loff_t])
 604
 605 LIBS_hold="$LIBS"
 606 LIBS="$LIBS -lm"
 607 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 608 LIBS="$LIBS_hold"
 609
 610 CFLAGS_hold="$CFLAGS"
 611 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 612 LIBS_hold="$LIBS"
 613 LIBS="$LIBS $PTHREAD_LIBS"
 614 AC_CHECK_FUNCS(sem_timedwait)
 615 CFLAGS="$CFLAGS_hold"
 616 LIBS="$LIBS_hold"
 617
 618 LIBS_hold="$LIBS"
 619 LIBS="$LIBS $MATH_LIBS"
 620 AC_CHECK_FUNCS(matherr)
 621 LIBS="$LIBS_hold"
 622
 623 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 624 [libgo_cv_func___sync_bool_compare_and_swap_4],
 625 [AC_LINK_IFELSE([
 626 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 627 uint32 i;
 628 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 629 ],
 630 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 631 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 632 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 633   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 634     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 635 fi
 636
 637 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 638 [libgo_cv_func___sync_bool_compare_and_swap_8],
 639 [AC_LINK_IFELSE([
 640 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 641 uint64 i;
 642 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 643 ],
 644 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 645 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 646 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 647   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 648     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 649 fi
 650
 651 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 652 [libgo_cv_func___sync_fetch_and_add_4],
 653 [AC_LINK_IFELSE([
 654 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 655 uint32 i;
 656 int main() { return __sync_fetch_and_add (&i, 1); }
 657 ],
 658 [libgo_cv_func___sync_fetch_and_add_4=yes],
 659 [libgo_cv_func___sync_fetch_and_add_4=no])])
 660 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 661   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 662     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 663 fi
 664
 665 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 666 [libgo_cv_func___sync_add_and_fetch_8],
 667 [AC_LINK_IFELSE([
 668 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 669 uint64 i;
 670 int main() { return __sync_add_and_fetch (&i, 1); }
 671 ],
 672 [libgo_cv_func___sync_add_and_fetch_8=yes],
 673 [libgo_cv_func___sync_add_and_fetch_8=no])])
 674 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 675   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 676     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 677 fi
 678
 679 dnl For x86 we want to use the -minline-all-stringops option to avoid
 680 dnl forcing a stack split when calling memcpy and friends.
 681 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 682 [libgo_cv_c_stringops],
 683 [CFLAGS_hold=$CFLAGS
 684 CFLAGS="$CFLAGS -minline-all-stringops"
 685 AC_COMPILE_IFELSE([int i;],
 686 [libgo_cv_c_stringops=yes],
 687 [libgo_cv_c_stringops=no])
 688 CFLAGS=$CFLAGS_hold])
 689 STRINGOPS_FLAG=
 690 if test "$libgo_cv_c_stringops" = yes; then
 691   STRINGOPS_FLAG=-minline-all-stringops
 692 fi
 693 AC_SUBST(STRINGOPS_FLAG)
 694
 695 dnl For x86 we want to compile the math library with -mfancy-math-387
 696 dnl -funsafe-math-optimizations so that we can use the builtin
 697 dnl instructions directly.
 698 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 699 [libgo_cv_c_fancymath],
 700 [CFLAGS_hold=$CFLAGS
 701 CFLAGS="$CFLAGS -mfancy-math-387"
 702 AC_COMPILE_IFELSE([int i;],
 703 [libgo_cv_c_fancymath=yes],
 704 [libgo_cv_c_fancymath=no])
 705 CFLAGS=$CFLAGS_hold])
 706 MATH_FLAG=
 707 if test "$libgo_cv_c_fancymath" = yes; then
 708   MATH_FLAG="-mfancy-math-387 -funsafe-math-optimizations"
 709 else
 710   MATH_FLAG="-ffp-contract=off"
 711 fi
 712 AC_SUBST(MATH_FLAG)
 713
 714 CFLAGS_hold=$CFLAGS
 715 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 716 AC_CHECK_TYPES([off64_t])
 717 CFLAGS=$CFLAGS_hold
 718
 719 dnl Work out the size of the epoll_events struct on GNU/Linux.
 720 AC_CACHE_CHECK([epoll_event size],
 721 [libgo_cv_c_epoll_event_size],
 722 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 723 [sizeof (struct epoll_event)],
 724 [#include <sys/epoll.h>],
 725 [libgo_cv_c_epoll_event_size=0])])
 726 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 727 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 728
 729 dnl Work out the offset of the fd field in the epoll_events struct on
 730 dnl GNU/Linux.
 731 AC_CACHE_CHECK([epoll_event data.fd offset],
 732 [libgo_cv_c_epoll_event_fd_offset],
 733 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 734 [offsetof (struct epoll_event, data.fd)],
 735 [#include <stddef.h>
 736 #include <sys/epoll.h>],
 737 [libgo_cv_c_epoll_event_fd_offset=0])])
 738 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 739 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 740
 741 dnl Check if <sys/stat.h> uses timespec_t for st_?tim members.  Introduced
 742 dnl in Solaris 12 for XPG7 compatibility.
 743 AC_EGREP_HEADER([timespec_t.*st_atim], [sys/stat.h],
 744                 [have_stat_timespec=yes], [have_stat_timespec=no])
 745 AM_CONDITIONAL(HAVE_STAT_TIMESPEC, test $have_stat_timespec = yes)
 746
 747 dnl See if struct exception is defined in <math.h>.
 748 AC_CHECK_TYPE([struct exception],
 749 [libgo_has_struct_exception=yes],
 750 [libgo_has_struct_exception=no],
 751 [#include <math.h>])
 752 if test "$libgo_has_struct_exception" = "yes"; then
 753   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 754             [Define to 1 if <math.h> defines struct exception])
 755 fi
 756
 757 dnl See whether setcontext changes the value of TLS variables.
 758 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 759 [libgo_cv_lib_setcontext_clobbers_tls],
 760 [CFLAGS_hold="$CFLAGS"
 761 CFLAGS="$PTHREAD_CFLAGS"
 762 LIBS_hold="$LIBS"
 763 LIBS="$LIBS $PTHREAD_LIBS"
 764 AC_CHECK_SIZEOF([void *])
 765 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 766 AC_RUN_IFELSE(
 767   [AC_LANG_SOURCE([
 768 #include <pthread.h>
 769 #include <stdlib.h>
 770 #include <ucontext.h>
 771 #include <unistd.h>
 772
 773 __thread int tls;
 774
 775 static char stack[[10 * 1024 * 1024]];
 776 static ucontext_t c;
 777
 778 /* Called via makecontext/setcontext.  */
 779
 780 static void
 781 cfn (void)
 782 {
 783   exit (tls);
 784 }
 785
 786 /* Called via pthread_create.  */
 787
 788 static void *
 789 tfn (void *dummy)
 790 {
 791   /* The thread should still see this value after calling
 792      setcontext.  */
 793   tls = 0;
 794
 795   setcontext (&c);
 796
 797   /* The call to setcontext should not return.  */
 798   abort ();
 799 }
 800
 801 int
 802 main ()
 803 {
 804   pthread_t tid;
 805
 806   /* The thread should not see this value.  */
 807   tls = 1;
 808
 809   if (getcontext (&c) < 0)
 810     abort ();
 811
 812   c.uc_stack.ss_sp = stack;
 813 #ifdef MAKECONTEXT_STACK_TOP
 814   c.uc_stack.ss_sp += sizeof stack;
 815 #endif
 816   c.uc_stack.ss_flags = 0;
 817   c.uc_stack.ss_size = sizeof stack;
 818   c.uc_link = NULL;
 819   makecontext (&c, cfn, 0);
 820
 821   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 822     abort ();
 823
 824   if (pthread_join (tid, NULL) != 0)
 825     abort ();
 826
 827   /* The thread should have called exit.  */
 828   abort ();
 829 }
 830 ])],
 831 [libgo_cv_lib_setcontext_clobbers_tls=no],
 832 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 833 [case "$target:$ptr_type_size" in
 834   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 835     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 836   *)
 837     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 838  esac
 839 ])
 840 CFLAGS="$CFLAGS_hold"
 841 LIBS="$LIBS_hold"
 842 ])
 843 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 844   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 845             [Define if setcontext clobbers TLS variables])
 846 fi
 847
 848 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 849 libgo_cv_ro_eh_frame, [
 850 libgo_cv_ro_eh_frame=no
 851 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 852 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 853   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 854     libgo_cv_ro_eh_frame=yes
 855   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 856        | grep -v '#write' > /dev/null; then
 857     libgo_cv_ro_eh_frame=yes
 858   fi
 859 fi
 860 rm -f conftest.*
 861 ])
 862 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 863   AC_DEFINE(EH_FRAME_FLAGS, "a",
 864             [Define to the flags needed for the .section .eh_frame directive.])
 865 else
 866   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 867             [Define to the flags needed for the .section .eh_frame directive.])
 868 fi
 869
 870 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 871 [libgo_cv_c_unused_arguments],
 872 [CFLAGS_hold=$CFLAGS
 873 CFLAGS="$CFLAGS -Qunused-arguments"
 874 AC_COMPILE_IFELSE([[int i;]],
 875 [libgo_cv_c_unused_arguments=yes],
 876 [libgo_cv_c_unused_arguments=no])
 877 CFLAGS=$CFLAGS_hold])
 878
 879 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 880 libgo_cv_as_comdat_gnu, [
 881 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 882 CFLAGS_hold=$CFLAGS
 883 if test "$libgo_cv_c_unused_arguments" = yes; then
 884   CFLAGS="$CFLAGS -Qunused-arguments"
 885 fi
 886 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 887   libgo_cv_as_comdat_gnu=yes
 888 else
 889   libgo_cv_as_comdat_gnu=no
 890 fi
 891 CFLAGS=$CFLAGS_hold
 892 ])
 893 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 894   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 895             [Define if your assembler supports GNU comdat group syntax.])
 896 fi
 897
 898 AC_CACHE_CHECK([assembler supports pc related relocs],
 899 libgo_cv_as_x86_pcrel, [
 900 libgo_cv_as_x86_pcrel=yes
 901 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 902 CFLAGS_hold=$CFLAGS
 903 if test "$libgo_cv_c_unused_arguments" = yes; then
 904   CFLAGS="$CFLAGS -Qunused-arguments"
 905 fi
 906 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 907     libgo_cv_as_x86_pcrel=no
 908 fi
 909 CFLAGS=$CFLAGS_hold
 910 ])
 911 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 912   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 913             [Define if your assembler supports PC relative relocs.])
 914 fi
 915
 916 AC_CACHE_CHECK([assembler supports unwind section type],
 917 libgo_cv_as_x86_64_unwind_section_type, [
 918 libgo_cv_as_x86_64_unwind_section_type=yes
 919 echo '.section .eh_frame,"a",@unwind' > conftest.s
 920 CFLAGS_hold=$CFLAGS
 921 if test "$libgo_cv_c_unused_arguments" = yes; then
 922   CFLAGS="$CFLAGS -Qunused-arguments"
 923 fi
 924 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 925     libgo_cv_as_x86_64_unwind_section_type=no
 926 fi
 927 CFLAGS=$CFLAGS_hold
 928 ])
 929 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 930   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 931             [Define if your assembler supports unwind section type.])
 932 fi
 933
 934 AC_CACHE_SAVE
 935
 936 if test ${multilib} = yes; then
 937   multilib_arg="--enable-multilib"
 938 else
 939   multilib_arg=
 940 fi
 941
 942 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 943
 944 AC_CONFIG_COMMANDS([default],
 945 [if test -n "$CONFIG_FILES"; then
 946    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 947    # that multilib installs will end up installed in the correct place.
 948    # The testsuite needs it for multilib-aware ABI baseline files.
 949    # To work around this not being passed down from config-ml.in ->
 950    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 951    # append it here.  Only modify Makefiles that have just been created.
 952    #
 953    # Also, get rid of this simulated-VPATH thing that automake does.
 954    cat > vpsed << \_EOF
 955 s!`test -f '$<' || echo '$(srcdir)/'`!!
 956 _EOF
 957    for i in $SUBDIRS; do
 958     case $CONFIG_FILES in
 959      *${i}/Makefile*)
 960        #echo "Adding MULTISUBDIR to $i/Makefile"
 961        sed -f vpsed $i/Makefile > tmp
 962        grep '^MULTISUBDIR =' Makefile >> tmp
 963        mv tmp $i/Makefile
 964        ;;
 965     esac
 966    done
 967    rm vpsed
 968  fi
 969 ],
 970 [
 971 # Variables needed in config.status (file generation) which aren't already
 972 # passed by autoconf.
 973 SUBDIRS="$SUBDIRS"
 974 ])
 975
 976 AC_OUTPUT