libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=5:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  54                                       [turns on -Werror @<:@default=yes@:>@])])
  55 if test "x$enable_werror" != "xno"; then
  56   WERROR="-Werror"
  57 fi
  58 AC_SUBST(WERROR)
  59
  60 glibgo_toolexecdir=no
  61 glibgo_toolexeclibdir=no
  62
  63 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  64 AC_ARG_ENABLE([version-specific-runtime-libs],
  65   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  67   [case "$enableval" in
  68     yes) version_specific_libs=yes ;;
  69     no)  version_specific_libs=no ;;
  70     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71    esac],
  72   [version_specific_libs=no])
  73 AC_MSG_RESULT($version_specific_libs)
  74
  75 # Version-specific runtime libs processing.
  76 if test $version_specific_libs = yes; then
  77   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  78   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  79 fi
  80
  81 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  82 # Install a library built with a cross compiler in tooldir, not libdir.
  83 if test -n "$with_cross_host" &&
  84    test x"$with_cross_host" != x"no"; then
  85   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  86   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  87 else
  88   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  89   nover_glibgo_toolexeclibdir='${libdir}'
  90 fi
  91 multi_os_directory=`$CC -print-multi-os-directory`
  92 case $multi_os_directory in
  93   .) ;; # Avoid trailing /.
  94   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
  95 esac
  96
  97 if test x"$glibgo_toolexecdir" = x"no"; then
  98   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
  99   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 100 fi
 101
 102 AC_SUBST(glibgo_toolexecdir)
 103 AC_SUBST(glibgo_toolexeclibdir)
 104 AC_SUBST(nover_glibgo_toolexeclibdir)
 105
 106 # See if the user wants to configure without libffi.  Some
 107 # architectures don't support it.  FIXME: We should set a default
 108 # based on the host.
 109 AC_ARG_WITH(libffi,
 110   AS_HELP_STRING([--without-libffi],
 111                  [don't use libffi]),
 112   [:],
 113   [with_libffi=${with_libffi_default-yes}])
 114
 115 LIBFFI=
 116 LIBFFIINCS=
 117 if test "$with_libffi" != no; then
 118    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 119    LIBFFI=../libffi/libffi_convenience.la
 120    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 121 fi
 122 AC_SUBST(LIBFFI)
 123 AC_SUBST(LIBFFIINCS)
 124
 125 # Used to tell GNU make to include a file without telling automake to
 126 # include it.
 127 go_include="-include"
 128 AC_SUBST(go_include)
 129
 130 is_darwin=no
 131 is_freebsd=no
 132 is_irix=no
 133 is_linux=no
 134 is_netbsd=no
 135 is_openbsd=no
 136 is_rtems=no
 137 is_solaris=no
 138 GOOS=unknown
 139 case ${host} in
 140   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 141   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 142   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 143   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 144   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 145   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 146   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 147   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 148 esac
 149 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 150 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 151 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 152 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 153 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 154 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 155 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 156 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 157 AC_SUBST(GOOS)
 158
 159 dnl Test whether we need to use DejaGNU or whether we can use the
 160 dnl simpler gotest approach.  We can only use gotest for a native
 161 dnl build.
 162 USE_DEJAGNU=no
 163 case ${host} in
 164   *-*-rtems*) USE_DEJAGNU=yes ;;
 165   ${build}) ;;
 166   *) USE_DEJAGNU=yes ;;
 167 esac
 168 AC_SUBST(USE_DEJAGNU)
 169
 170 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 171 is_386=no
 172 is_alpha=no
 173 is_arm=no
 174 is_m68k=no
 175 mips_abi=unknown
 176 is_ppc=no
 177 is_ppc64=no
 178 is_sparc=no
 179 is_sparc64=no
 180 is_x86_64=no
 181 GOARCH=unknown
 182 case ${host} in
 183   alpha*-*-*)
 184     is_alpha=yes
 185     GOARCH=alpha
 186     ;;
 187   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 188     is_arm=yes
 189     GOARCH=arm
 190     ;;
 191 changequote(,)dnl
 192   i[34567]86-*-* | x86_64-*-*)
 193 changequote([,])dnl
 194     AC_COMPILE_IFELSE([
 195 #ifdef __x86_64__
 196 #error 64-bit
 197 #endif],
 198 [is_386=yes], [is_x86_64=yes])
 199     if test "$is_386" = "yes"; then
 200       GOARCH=386
 201     else
 202       GOARCH=amd64
 203     fi
 204     ;;
 205   m68k*-*-*)
 206     is_m68k=yes
 207     GOARCH=m68k
 208     ;;
 209   mips*-*-*)
 210     AC_COMPILE_IFELSE([
 211 #if _MIPS_SIM != _ABIO32
 212 #error not o32
 213 #endif],
 214 [mips_abi="o32"],
 215         [AC_COMPILE_IFELSE([
 216 #if _MIPS_SIM != _ABIN32
 217 #error not n32
 218 #endif],
 219 [mips_abi="n32"],
 220         [AC_COMPILE_IFELSE([
 221 #if _MIPS_SIM != _ABI64
 222 #error not n64
 223 #endif],
 224 [mips_abi="n64"],
 225         [AC_COMPILE_IFELSE([
 226 #if _MIPS_SIM != _ABIO64
 227 #error not o64
 228 #endif],
 229 [mips_abi="o64"],
 230         [AC_MSG_ERROR([unknown MIPS ABI])
 231 [mips_abi="n32"]])])])])
 232     case "$mips_abi" in
 233     "o32") GOARCH=mipso32 ;;
 234     "n32") GOARCH=mipsn32 ;;
 235     "n64") GOARCH=mipsn64 ;;
 236     "o64") GOARCH=mipso64 ;;
 237     esac
 238     ;;
 239   rs6000*-*-* | powerpc*-*-*)
 240     AC_COMPILE_IFELSE([
 241 #ifdef _ARCH_PPC64
 242 #error 64-bit
 243 #endif],
 244 [is_ppc=yes], [is_ppc64=yes])
 245     if test "$is_ppc" = "yes"; then
 246       GOARCH=ppc
 247     else
 248       GOARCH=ppc64
 249     fi
 250     ;;
 251   sparc*-*-*)
 252     AC_COMPILE_IFELSE([
 253 #if defined(__sparcv9) || defined(__arch64__)
 254 #error 64-bit
 255 #endif],
 256 [is_sparc=yes], [is_sparc64=yes])
 257     if test "$is_sparc" = "yes"; then
 258       GOARCH=sparc
 259     else
 260       GOARCH=sparc64
 261     fi
 262     ;;
 263 esac
 264 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 265 AM_CONDITIONAL(LIBGO_IS_ALPHA, test $is_alpha = yes)
 266 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 267 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 268 AM_CONDITIONAL(LIBGO_IS_MIPS, test $mips_abi != unknown)
 269 AM_CONDITIONAL(LIBGO_IS_MIPSO32, test $mips_abi = o32)
 270 AM_CONDITIONAL(LIBGO_IS_MIPSN32, test $mips_abi = n32)
 271 AM_CONDITIONAL(LIBGO_IS_MIPSN64, test $mips_abi = n64)
 272 AM_CONDITIONAL(LIBGO_IS_MIPSO64, test $mips_abi = o64)
 273 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 274 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 275 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 276 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 277 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 278 AC_SUBST(GOARCH)
 279
 280 dnl Some files are only present when needed for specific architectures.
 281 GO_LIBCALL_OS_FILE=
 282 GO_LIBCALL_OS_ARCH_FILE=
 283 GO_SYSCALL_OS_FILE=
 284 GO_SYSCALL_OS_ARCH_FILE=
 285 if test -f ${srcdir}/go/syscall/libcall_${GOOS}.go; then
 286   GO_LIBCALL_OS_FILE=go/syscall/libcall_${GOOS}.go
 287 fi
 288 if test -f ${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go; then
 289   GO_LIBCALL_OS_ARCH_FILE=go/syscall/libcall_${GOOS}_${GOARCH}.go
 290 fi
 291 if test -f ${srcdir}/go/syscall/syscall_${GOOS}.go; then
 292   GO_SYSCALL_OS_FILE=go/syscall/syscall_${GOOS}.go
 293 fi
 294 if test -f ${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go; then
 295   GO_SYSCALL_OS_ARCH_FILE=go/syscall/syscall_${GOOS}_${GOARCH}.go
 296 fi
 297 AC_SUBST(GO_LIBCALL_OS_FILE)
 298 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 299 AC_SUBST(GO_SYSCALL_OS_FILE)
 300 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 301
 302 dnl Special flags used to generate sysinfo.go.
 303 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 304 case "$target" in
 305     mips-sgi-irix6.5*)
 306         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 307         # msghdr in <sys/socket.h>.
 308         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 309         ;;
 310     *-*-solaris2.[[89]])
 311         # Solaris 8/9 need this so struct msghdr gets the msg_control
 312         # etc. fields in <sys/socket.h> (_XPG4_2).
 313         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D__EXTENSIONS__"
 314         ;;
 315     *-*-solaris2.1[[01]])
 316         # Solaris 10+ needs this so struct msghdr gets the msg_control
 317         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 318         # above doesn't work with C99.
 319         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 320         ;;
 321 esac
 322 AC_SUBST(OSCFLAGS)
 323
 324 dnl Use -fsplit-stack when compiling C code if available.
 325 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 326 [libgo_cv_c_split_stack_supported],
 327 [CFLAGS_hold=$CFLAGS
 328 CFLAGS="$CFLAGS -fsplit-stack"
 329 AC_COMPILE_IFELSE([[int i;]],
 330 [libgo_cv_c_split_stack_supported=yes],
 331 [libgo_cv_c_split_stack_supported=no])
 332 CFLAGS=$CFLAGS_hold])
 333 if test "$libgo_cv_c_split_stack_supported" = yes; then
 334   SPLIT_STACK=-fsplit-stack
 335   AC_DEFINE(USING_SPLIT_STACK, 1,
 336                 [Define if the compiler supports -fsplit-stack])
 337 else
 338   SPLIT_STACK=
 339 fi
 340 AC_SUBST(SPLIT_STACK)
 341 AM_CONDITIONAL(USING_SPLIT_STACK,
 342         test "$libgo_cv_c_split_stack_supported" = yes)
 343
 344 dnl Check whether the linker does stack munging when calling from
 345 dnl split-stack into non-split-stack code.  We check this by looking
 346 dnl at the --help output.  FIXME: This is only half right: it's
 347 dnl possible for the linker to support this for some targets but not
 348 dnl others.
 349 AC_CACHE_CHECK([whether linker supports split stack],
 350 [libgo_cv_c_linker_supports_split_stack],
 351 libgo_cv_c_linker_supports_split_stack=no
 352 if $LD --help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 353   libgo_cv_c_linker_supports_split_stack=yes
 354 fi)
 355 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 356   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 357             [Define if the linker support split stack adjustments])
 358 fi
 359
 360 dnl Test for the -lm library.
 361 MATH_LIBS=
 362 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 363 AC_SUBST(MATH_LIBS)
 364
 365 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 366 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 367   [libgo_cv_lib_sockets=
 368    libgo_check_both=no
 369    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 370    if test "$libgo_check_socket" = "yes"; then
 371      unset ac_cv_func_connect
 372      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 373                   libgo_check_both=yes)
 374    fi
 375    if test "$libgo_check_both" = "yes"; then
 376      libgo_old_libs=$LIBS
 377      LIBS="$LIBS -lsocket -lnsl"
 378      unset ac_cv_func_accept
 379      AC_CHECK_FUNC(accept,
 380                    [libgo_check_nsl=no
 381                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 382      unset ac_cv_func_accept
 383      LIBS=$libgo_old_libs
 384    fi
 385    unset ac_cv_func_gethostbyname
 386    libgo_old_libs="$LIBS"
 387    AC_CHECK_FUNC(gethostbyname, ,
 388                  [AC_CHECK_LIB(nsl, main,
 389                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 390    unset ac_cv_func_gethostbyname
 391    LIBS=$libgo_old_libs
 392 ])
 393 NET_LIBS="$libgo_cv_lib_sockets"
 394 AC_SUBST(NET_LIBS)
 395
 396 dnl Test whether the compiler supports the -pthread option.
 397 AC_CACHE_CHECK([whether -pthread is supported],
 398 [libgo_cv_lib_pthread],
 399 [CFLAGS_hold=$CFLAGS
 400 CFLAGS="$CFLAGS -pthread"
 401 AC_COMPILE_IFELSE([[int i;]],
 402 [libgo_cv_lib_pthread=yes],
 403 [libgo_cv_lib_pthread=no])
 404 CFLAGS=$CFLAGS_hold])
 405 PTHREAD_CFLAGS=
 406 if test "$libgo_cv_lib_pthread" = yes; then
 407   PTHREAD_CFLAGS=-pthread
 408 fi
 409 AC_SUBST(PTHREAD_CFLAGS)
 410
 411 dnl Test for the -lpthread library.
 412 PTHREAD_LIBS=
 413 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 414 AC_SUBST(PTHREAD_LIBS)
 415
 416 dnl Test if -lrt is required for sched_yield and/or nanosleep.
 417 AC_SEARCH_LIBS([sched_yield], [rt])
 418 AC_SEARCH_LIBS([nanosleep], [rt])
 419
 420 AC_C_BIGENDIAN
 421
 422 GCC_CHECK_UNWIND_GETIPINFO
 423
 424 AC_ARG_ENABLE(sjlj-exceptions,
 425   AC_HELP_STRING([--enable-sjlj-exceptions],
 426                  [force use of builtin_setjmp for exceptions]),
 427   [case "$enableval" in
 428    yes|no|auto) ;;
 429    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 430    esac],
 431   [enable_sjlj_exceptions=auto])
 432
 433 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 434 [libgo_cv_lib_sjlj_exceptions],
 435 [AC_LANG_CONFTEST(
 436   [AC_LANG_SOURCE([
 437 void bar ();
 438 void clean (int *);
 439 void foo ()
 440 {
 441   int i __attribute__ ((cleanup (clean)));
 442   bar();
 443 }
 444 ])])
 445 CFLAGS_hold=$CFLAGS
 446 CFLAGS="--save-temps -fexceptions"
 447 libgo_cv_lib_sjlj_exceptions=unknown
 448 AS_IF([ac_fn_c_try_compile],
 449   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 450     libgo_cv_lib_sjlj_exceptions=yes
 451   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 452     libgo_cv_lib_sjlj_exceptions=no
 453   fi])
 454 CFLAGS=$CFLAGS_hold
 455 rm -f conftest*
 456 ])
 457
 458 if test "$enable_sjlj_exceptions" = "auto"; then
 459   enable_sjlj_exceptions=$libgo_cv_lib_sjlj_exceptions
 460 fi
 461
 462 case $enable_sjlj_exceptions in
 463 yes)
 464   AC_DEFINE(LIBGO_SJLJ_EXCEPTIONS, 1,
 465         [Define if the C++ compiler is configured for setjmp/longjmp exceptions.])
 466   ;;
 467 no)
 468   ;;
 469 *)
 470   AC_MSG_ERROR([unable to detect exception model])
 471   ;;
 472 esac
 473
 474 AC_CHECK_HEADERS(sys/file.h sys/mman.h syscall.h sys/epoll.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/reboot.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 475
 476 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 477 [#ifdef HAVE_SYS_SOCKET_H
 478 #include <sys/socket.h>
 479 #endif
 480 ])
 481
 482 AC_CACHE_CHECK([whether <ustat.h> can be used],
 483 [libgo_cv_c_ustat_h],
 484 [CFLAGS_hold=$CFLAGS
 485 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 486 AC_COMPILE_IFELSE(
 487 [AC_LANG_SOURCE([
 488 #include <sys/types.h>
 489 #ifdef HAVE_LINUX_FILTER_H
 490 #include <linux/filter.h>
 491 #endif
 492 #include <ustat.h>
 493 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 494 CFLAGS=$CFLAGS_hold])
 495 if test $libgo_cv_c_ustat_h = yes; then
 496   AC_DEFINE(HAVE_USTAT_H, 1,
 497     [Define to 1 if you have the <ustat.h> header file and it works.])
 498 fi
 499
 500 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 501
 502 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv dl_iterate_phdr)
 503 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 504 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 505
 506 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat openat pipe2 removexattr renameat setxattr sync_file_range splice tee unlinkat unshare utimensat)
 507 AC_TYPE_OFF_T
 508 AC_CHECK_TYPES([loff_t])
 509
 510 LIBS_hold="$LIBS"
 511 LIBS="$LIBS -lm"
 512 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 513 LIBS="$LIBS_hold"
 514
 515 CFLAGS_hold="$CFLAGS"
 516 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 517 LIBS_hold="$LIBS"
 518 LIBS="$LIBS $PTHREAD_LIBS"
 519 AC_CHECK_FUNCS(sem_timedwait)
 520 CFLAGS="$CFLAGS_hold"
 521 LIBS="$LIBS_hold"
 522
 523 LIBS_hold="$LIBS"
 524 LIBS="$LIBS $MATH_LIBS"
 525 AC_CHECK_FUNCS(matherr)
 526 LIBS="$LIBS_hold"
 527
 528 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 529 [libgo_cv_func___sync_bool_compare_and_swap_4],
 530 [AC_LINK_IFELSE([
 531 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 532 uint32 i;
 533 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 534 ],
 535 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 536 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 537 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 538   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 539     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 540 fi
 541
 542 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 543 [libgo_cv_func___sync_bool_compare_and_swap_8],
 544 [AC_LINK_IFELSE([
 545 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 546 uint64 i;
 547 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 548 ],
 549 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 550 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 551 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 552   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 553     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 554 fi
 555
 556 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 557 [libgo_cv_func___sync_fetch_and_add_4],
 558 [AC_LINK_IFELSE([
 559 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 560 uint32 i;
 561 int main() { return __sync_fetch_and_add (&i, 1); }
 562 ],
 563 [libgo_cv_func___sync_fetch_and_add_4=yes],
 564 [libgo_cv_func___sync_fetch_and_add_4=no])])
 565 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 566   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 567     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 568 fi
 569
 570 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 571 [libgo_cv_func___sync_add_and_fetch_8],
 572 [AC_LINK_IFELSE([
 573 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 574 uint64 i;
 575 int main() { return __sync_add_and_fetch (&i, 1); }
 576 ],
 577 [libgo_cv_func___sync_add_and_fetch_8=yes],
 578 [libgo_cv_func___sync_add_and_fetch_8=no])])
 579 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 580   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 581     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 582 fi
 583
 584 dnl For x86 we want to use the -minline-all-stringops option to avoid
 585 dnl forcing a stack split when calling memcpy and friends.
 586 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 587 [libgo_cv_c_stringops],
 588 [CFLAGS_hold=$CFLAGS
 589 CFLAGS="$CFLAGS -minline-all-stringops"
 590 AC_COMPILE_IFELSE([int i;],
 591 [libgo_cv_c_stringops=yes],
 592 [libgo_cv_c_stringops=no])
 593 CFLAGS=$CFLAGS_hold])
 594 STRINGOPS_FLAG=
 595 if test "$libgo_cv_c_stringops" = yes; then
 596   STRINGOPS_FLAG=-minline-all-stringops
 597 fi
 598 AC_SUBST(STRINGOPS_FLAG)
 599
 600 dnl For x86 we want to compile the math library with -mfancy-math-387
 601 dnl -funsafe-math-optimizations so that we can use the builtin
 602 dnl instructions directly.
 603 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 604 [libgo_cv_c_fancymath],
 605 [CFLAGS_hold=$CFLAGS
 606 CFLAGS="$CFLAGS -mfancy-math-387"
 607 AC_COMPILE_IFELSE([int i;],
 608 [libgo_cv_c_fancymath=yes],
 609 [libgo_cv_c_fancymath=no])
 610 CFLAGS=$CFLAGS_hold])
 611 MATH_FLAG=
 612 if test "$libgo_cv_c_fancymath" = yes; then
 613   MATH_FLAG="-mfancy-math-387 -funsafe-math-optimizations"
 614 fi
 615 AC_SUBST(MATH_FLAG)
 616
 617 CFLAGS_hold=$CFLAGS
 618 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 619 AC_CHECK_TYPES([off64_t])
 620 CFLAGS=$CFLAGS_hold
 621
 622 dnl Work out the size of the epoll_events struct on GNU/Linux.
 623 AC_CACHE_CHECK([epoll_event size],
 624 [libgo_cv_c_epoll_event_size],
 625 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 626 [sizeof (struct epoll_event)],
 627 [#include <sys/epoll.h>],
 628 [libgo_cv_c_epoll_event_size=0])])
 629 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 630 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 631
 632 dnl Work out the offset of the fd field in the epoll_events struct on
 633 dnl GNU/Linux.
 634 AC_CACHE_CHECK([epoll_event data.fd offset],
 635 [libgo_cv_c_epoll_event_fd_offset],
 636 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 637 [offsetof (struct epoll_event, data.fd)],
 638 [#include <stddef.h>
 639 #include <sys/epoll.h>],
 640 [libgo_cv_c_epoll_event_fd_offset=0])])
 641 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 642 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 643
 644 dnl See if struct exception is defined in <math.h>.
 645 AC_CHECK_TYPE([struct exception],
 646 [libgo_has_struct_exception=yes],
 647 [libgo_has_struct_exception=no],
 648 [#include <math.h>])
 649 if test "$libgo_has_struct_exception" = "yes"; then
 650   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 651             [Define to 1 if <math.h> defines struct exception])
 652 fi
 653
 654 dnl Check if makecontext expects the uc_stack member of ucontext to point
 655 dnl to the top of the stack.
 656 case "$target" in
 657   sparc*-*-solaris2.[[89]]*)
 658     libgo_cv_lib_makecontext_stack_top=yes
 659     ;;
 660   *)
 661     libgo_cv_lib_makecontext_stack_top=no
 662     ;;
 663 esac
 664 if test "$libgo_cv_lib_makecontext_stack_top" = "yes"; then
 665   AC_DEFINE(MAKECONTEXT_STACK_TOP, 1,
 666             [Define if makecontext expects top of stack in uc_stack.])
 667 fi
 668
 669 dnl See whether setcontext changes the value of TLS variables.
 670 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 671 [libgo_cv_lib_setcontext_clobbers_tls],
 672 [CFLAGS_hold="$CFLAGS"
 673 CFLAGS="$PTHREAD_CFLAGS"
 674 LIBS_hold="$LIBS"
 675 LIBS="$LIBS $PTHREAD_LIBS"
 676 AC_CHECK_SIZEOF([void *])
 677 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 678 AC_RUN_IFELSE(
 679   [AC_LANG_SOURCE([
 680 #include <pthread.h>
 681 #include <stdlib.h>
 682 #include <ucontext.h>
 683 #include <unistd.h>
 684
 685 __thread int tls;
 686
 687 static char stack[[10 * 1024 * 1024]];
 688 static ucontext_t c;
 689
 690 /* Called via makecontext/setcontext.  */
 691
 692 static void
 693 cfn (void)
 694 {
 695   exit (tls);
 696 }
 697
 698 /* Called via pthread_create.  */
 699
 700 static void *
 701 tfn (void *dummy)
 702 {
 703   /* The thread should still see this value after calling
 704      setcontext.  */
 705   tls = 0;
 706
 707   setcontext (&c);
 708
 709   /* The call to setcontext should not return.  */
 710   abort ();
 711 }
 712
 713 int
 714 main ()
 715 {
 716   pthread_t tid;
 717
 718   /* The thread should not see this value.  */
 719   tls = 1;
 720
 721   if (getcontext (&c) < 0)
 722     abort ();
 723
 724   c.uc_stack.ss_sp = stack;
 725 #ifdef MAKECONTEXT_STACK_TOP
 726   c.uc_stack.ss_sp += sizeof stack;
 727 #endif
 728   c.uc_stack.ss_flags = 0;
 729   c.uc_stack.ss_size = sizeof stack;
 730   c.uc_link = NULL;
 731   makecontext (&c, cfn, 0);
 732
 733   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 734     abort ();
 735
 736   if (pthread_join (tid, NULL) != 0)
 737     abort ();
 738
 739   /* The thread should have called exit.  */
 740   abort ();
 741 }
 742 ])],
 743 [libgo_cv_lib_setcontext_clobbers_tls=no],
 744 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 745 [case "$target:$ptr_type_size" in
 746   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 747     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 748   *)
 749     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 750  esac
 751 ])
 752 CFLAGS="$CFLAGS_hold"
 753 LIBS="$LIBS_hold"
 754 ])
 755 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 756   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 757             [Define if setcontext clobbers TLS variables])
 758 fi
 759
 760 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 761 libgo_cv_ro_eh_frame, [
 762 libgo_cv_ro_eh_frame=no
 763 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 764 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 765   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 766     libgo_cv_ro_eh_frame=yes
 767   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 768        | grep -v '#write' > /dev/null; then
 769     libgo_cv_ro_eh_frame=yes
 770   fi
 771 fi
 772 rm -f conftest.*
 773 ])
 774 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 775   AC_DEFINE(EH_FRAME_FLAGS, "a",
 776             [Define to the flags needed for the .section .eh_frame directive.])
 777 else
 778   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 779             [Define to the flags needed for the .section .eh_frame directive.])
 780 fi
 781
 782 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 783 libgo_cv_as_comdat_gnu, [
 784 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 785 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 786   libgo_cv_as_comdat_gnu=yes
 787 else
 788   libgo_cv_as_comdat_gnu=no
 789 fi
 790 ])
 791 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 792   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 793             [Define if your assembler supports GNU comdat group syntax.])
 794 fi
 795
 796 AC_CACHE_CHECK([assembler supports pc related relocs],
 797 libgo_cv_as_x86_pcrel, [
 798 libgo_cv_as_x86_pcrel=yes
 799 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 800 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 801     libgo_cv_as_x86_pcrel=no
 802 fi
 803 ])
 804 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 805   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 806             [Define if your assembler supports PC relative relocs.])
 807 fi
 808
 809 AC_CACHE_CHECK([assembler supports unwind section type],
 810 libgo_cv_as_x86_64_unwind_section_type, [
 811 libgo_cv_as_x86_64_unwind_section_type=yes
 812 echo '.section .eh_frame,"a",@unwind' > conftest.s
 813 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 814     libgo_cv_as_x86_64_unwind_section_type=no
 815 fi
 816 ])
 817 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 818   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 819             [Define if your assembler supports unwind section type.])
 820 fi
 821
 822 AC_CACHE_SAVE
 823
 824 if test ${multilib} = yes; then
 825   multilib_arg="--enable-multilib"
 826 else
 827   multilib_arg=
 828 fi
 829
 830 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 831
 832 AC_CONFIG_COMMANDS([default],
 833 [if test -n "$CONFIG_FILES"; then
 834    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 835    # that multilib installs will end up installed in the correct place.
 836    # The testsuite needs it for multilib-aware ABI baseline files.
 837    # To work around this not being passed down from config-ml.in ->
 838    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 839    # append it here.  Only modify Makefiles that have just been created.
 840    #
 841    # Also, get rid of this simulated-VPATH thing that automake does.
 842    cat > vpsed << \_EOF
 843 s!`test -f '$<' || echo '$(srcdir)/'`!!
 844 _EOF
 845    for i in $SUBDIRS; do
 846     case $CONFIG_FILES in
 847      *${i}/Makefile*)
 848        #echo "Adding MULTISUBDIR to $i/Makefile"
 849        sed -f vpsed $i/Makefile > tmp
 850        grep '^MULTISUBDIR =' Makefile >> tmp
 851        mv tmp $i/Makefile
 852        ;;
 853     esac
 854    done
 855    rm vpsed
 856  fi
 857 ],
 858 [
 859 # Variables needed in config.status (file generation) which aren't already
 860 # passed by autoconf.
 861 SUBDIRS="$SUBDIRS"
 862 ])
 863
 864 AC_OUTPUT