libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=5:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  54                                       [turns on -Werror @<:@default=yes@:>@])])
  55 if test "x$enable_werror" != "xno"; then
  56   WERROR="-Werror"
  57 fi
  58 AC_SUBST(WERROR)
  59
  60 glibgo_toolexecdir=no
  61 glibgo_toolexeclibdir=no
  62
  63 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  64 AC_ARG_ENABLE([version-specific-runtime-libs],
  65   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  67   [case "$enableval" in
  68     yes) version_specific_libs=yes ;;
  69     no)  version_specific_libs=no ;;
  70     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71    esac],
  72   [version_specific_libs=no])
  73 AC_MSG_RESULT($version_specific_libs)
  74
  75 # Version-specific runtime libs processing.
  76 if test $version_specific_libs = yes; then
  77   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  78   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  79 fi
  80
  81 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  82 # Install a library built with a cross compiler in tooldir, not libdir.
  83 if test -n "$with_cross_host" &&
  84    test x"$with_cross_host" != x"no"; then
  85   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  86   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  87 else
  88   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  89   nover_glibgo_toolexeclibdir='${libdir}'
  90 fi
  91 multi_os_directory=`$CC -print-multi-os-directory`
  92 case $multi_os_directory in
  93   .) ;; # Avoid trailing /.
  94   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
  95 esac
  96
  97 if test x"$glibgo_toolexecdir" = x"no"; then
  98   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
  99   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 100 fi
 101
 102 AC_SUBST(glibgo_toolexecdir)
 103 AC_SUBST(glibgo_toolexeclibdir)
 104 AC_SUBST(nover_glibgo_toolexeclibdir)
 105
 106 # See if the user wants to configure without libffi.  Some
 107 # architectures don't support it.  FIXME: We should set a default
 108 # based on the host.
 109 AC_ARG_WITH(libffi,
 110   AS_HELP_STRING([--without-libffi],
 111                  [don't use libffi]),
 112   [:],
 113   [with_libffi=${with_libffi_default-yes}])
 114
 115 LIBFFI=
 116 LIBFFIINCS=
 117 if test "$with_libffi" != no; then
 118    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 119    LIBFFI=../libffi/libffi_convenience.la
 120    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 121 fi
 122 AC_SUBST(LIBFFI)
 123 AC_SUBST(LIBFFIINCS)
 124
 125 # Used to tell GNU make to include a file without telling automake to
 126 # include it.
 127 go_include="-include"
 128 AC_SUBST(go_include)
 129
 130 is_darwin=no
 131 is_freebsd=no
 132 is_irix=no
 133 is_linux=no
 134 is_netbsd=no
 135 is_openbsd=no
 136 is_dragonfly=no
 137 is_rtems=no
 138 is_solaris=no
 139 GOOS=unknown
 140 case ${host} in
 141   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 142   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 143   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 144   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 145   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 146   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 147   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 148   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 149   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 150 esac
 151 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 152 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 153 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 154 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 155 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 156 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 157 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 158 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 159 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 160 AC_SUBST(GOOS)
 161
 162 dnl Test whether we need to use DejaGNU or whether we can use the
 163 dnl simpler gotest approach.  We can only use gotest for a native
 164 dnl build.
 165 USE_DEJAGNU=no
 166 case ${host} in
 167   *-*-rtems*) USE_DEJAGNU=yes ;;
 168   ${build}) ;;
 169   *) USE_DEJAGNU=yes ;;
 170 esac
 171 AC_SUBST(USE_DEJAGNU)
 172
 173 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 174 is_386=no
 175 is_alpha=no
 176 is_arm=no
 177 is_arm64=no
 178 is_m68k=no
 179 mips_abi=unknown
 180 is_ppc=no
 181 is_ppc64=no
 182 is_sparc=no
 183 is_sparc64=no
 184 is_x86_64=no
 185 GOARCH=unknown
 186 case ${host} in
 187   alpha*-*-*)
 188     is_alpha=yes
 189     GOARCH=alpha
 190     ;;
 191   aarch64-*-*)
 192     is_arm64=yes
 193     GOARCH=arm64
 194     ;;
 195   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 196     is_arm=yes
 197     GOARCH=arm
 198     ;;
 199 changequote(,)dnl
 200   i[34567]86-*-* | x86_64-*-*)
 201 changequote([,])dnl
 202     AC_COMPILE_IFELSE([
 203 #ifdef __x86_64__
 204 #error 64-bit
 205 #endif],
 206 [is_386=yes], [is_x86_64=yes])
 207     if test "$is_386" = "yes"; then
 208       GOARCH=386
 209     else
 210       GOARCH=amd64
 211     fi
 212     ;;
 213   m68k*-*-*)
 214     is_m68k=yes
 215     GOARCH=m68k
 216     ;;
 217   mips*-*-*)
 218     AC_COMPILE_IFELSE([
 219 #if _MIPS_SIM != _ABIO32
 220 #error not o32
 221 #endif],
 222 [mips_abi="o32"],
 223         [AC_COMPILE_IFELSE([
 224 #if _MIPS_SIM != _ABIN32
 225 #error not n32
 226 #endif],
 227 [mips_abi="n32"],
 228         [AC_COMPILE_IFELSE([
 229 #if _MIPS_SIM != _ABI64
 230 #error not n64
 231 #endif],
 232 [mips_abi="n64"],
 233         [AC_COMPILE_IFELSE([
 234 #if _MIPS_SIM != _ABIO64
 235 #error not o64
 236 #endif],
 237 [mips_abi="o64"],
 238         [AC_MSG_ERROR([unknown MIPS ABI])
 239 [mips_abi="n32"]])])])])
 240     case "$mips_abi" in
 241     "o32") GOARCH=mipso32 ;;
 242     "n32") GOARCH=mipsn32 ;;
 243     "n64") GOARCH=mipsn64 ;;
 244     "o64") GOARCH=mipso64 ;;
 245     esac
 246     ;;
 247   rs6000*-*-* | powerpc*-*-*)
 248     AC_COMPILE_IFELSE([
 249 #ifdef _ARCH_PPC64
 250 #error 64-bit
 251 #endif],
 252 [is_ppc=yes], [is_ppc64=yes])
 253     if test "$is_ppc" = "yes"; then
 254       GOARCH=ppc
 255     else
 256       GOARCH=ppc64
 257     fi
 258     ;;
 259   sparc*-*-*)
 260     AC_COMPILE_IFELSE([
 261 #if defined(__sparcv9) || defined(__arch64__)
 262 #error 64-bit
 263 #endif],
 264 [is_sparc=yes], [is_sparc64=yes])
 265     if test "$is_sparc" = "yes"; then
 266       GOARCH=sparc
 267     else
 268       GOARCH=sparc64
 269     fi
 270     ;;
 271 esac
 272 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 273 AM_CONDITIONAL(LIBGO_IS_ALPHA, test $is_alpha = yes)
 274 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 275 AM_CONDITIONAL(LIBGO_IS_ARM64, test $is_arm64 = yes)
 276 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 277 AM_CONDITIONAL(LIBGO_IS_MIPS, test $mips_abi != unknown)
 278 AM_CONDITIONAL(LIBGO_IS_MIPSO32, test $mips_abi = o32)
 279 AM_CONDITIONAL(LIBGO_IS_MIPSN32, test $mips_abi = n32)
 280 AM_CONDITIONAL(LIBGO_IS_MIPSN64, test $mips_abi = n64)
 281 AM_CONDITIONAL(LIBGO_IS_MIPSO64, test $mips_abi = o64)
 282 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 283 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 284 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 285 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 286 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 287 AC_SUBST(GOARCH)
 288
 289 dnl Some files are only present when needed for specific architectures.
 290 GO_LIBCALL_OS_FILE=
 291 GO_LIBCALL_OS_ARCH_FILE=
 292 GO_SYSCALL_OS_FILE=
 293 GO_SYSCALL_OS_ARCH_FILE=
 294 if test -f ${srcdir}/go/syscall/libcall_${GOOS}.go; then
 295   GO_LIBCALL_OS_FILE=go/syscall/libcall_${GOOS}.go
 296 fi
 297 if test -f ${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go; then
 298   GO_LIBCALL_OS_ARCH_FILE=go/syscall/libcall_${GOOS}_${GOARCH}.go
 299 fi
 300 if test -f ${srcdir}/go/syscall/syscall_${GOOS}.go; then
 301   GO_SYSCALL_OS_FILE=go/syscall/syscall_${GOOS}.go
 302 fi
 303 if test -f ${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go; then
 304   GO_SYSCALL_OS_ARCH_FILE=go/syscall/syscall_${GOOS}_${GOARCH}.go
 305 fi
 306 AC_SUBST(GO_LIBCALL_OS_FILE)
 307 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 308 AC_SUBST(GO_SYSCALL_OS_FILE)
 309 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 310
 311 dnl Special flags used to generate sysinfo.go.
 312 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 313 case "$target" in
 314     mips-sgi-irix6.5*)
 315         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 316         # msghdr in <sys/socket.h>.
 317         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 318         ;;
 319     *-*-solaris2.1[[01]])
 320         # Solaris 10+ needs this so struct msghdr gets the msg_control
 321         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 322         # above doesn't work with C99.
 323         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 324         ;;
 325 esac
 326 AC_SUBST(OSCFLAGS)
 327
 328 dnl Use -fsplit-stack when compiling C code if available.
 329 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 330 [libgo_cv_c_split_stack_supported],
 331 [CFLAGS_hold=$CFLAGS
 332 CFLAGS="$CFLAGS -fsplit-stack"
 333 AC_COMPILE_IFELSE([[int i;]],
 334 [libgo_cv_c_split_stack_supported=yes],
 335 [libgo_cv_c_split_stack_supported=no])
 336 CFLAGS=$CFLAGS_hold])
 337 if test "$libgo_cv_c_split_stack_supported" = yes; then
 338   SPLIT_STACK=-fsplit-stack
 339   AC_DEFINE(USING_SPLIT_STACK, 1,
 340                 [Define if the compiler supports -fsplit-stack])
 341 else
 342   SPLIT_STACK=
 343 fi
 344 AC_SUBST(SPLIT_STACK)
 345 AM_CONDITIONAL(USING_SPLIT_STACK,
 346         test "$libgo_cv_c_split_stack_supported" = yes)
 347
 348 dnl Check whether the linker does stack munging when calling from
 349 dnl split-stack into non-split-stack code.  We check this by looking
 350 dnl at the --help output.  FIXME: This is only half right: it's
 351 dnl possible for the linker to support this for some targets but not
 352 dnl others.
 353 AC_CACHE_CHECK([whether linker supports split stack],
 354 [libgo_cv_c_linker_supports_split_stack],
 355 [libgo_cv_c_linker_supports_split_stack=no
 356 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 357   libgo_cv_c_linker_supports_split_stack=yes
 358 fi])
 359 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 360   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 361             [Define if the linker support split stack adjustments])
 362 fi
 363
 364 dnl Test for the -lm library.
 365 MATH_LIBS=
 366 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 367 AC_SUBST(MATH_LIBS)
 368
 369 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 370 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 371   [libgo_cv_lib_sockets=
 372    libgo_check_both=no
 373    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 374    if test "$libgo_check_socket" = "yes"; then
 375      unset ac_cv_func_connect
 376      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 377                   libgo_check_both=yes)
 378    fi
 379    if test "$libgo_check_both" = "yes"; then
 380      libgo_old_libs=$LIBS
 381      LIBS="$LIBS -lsocket -lnsl"
 382      unset ac_cv_func_accept
 383      AC_CHECK_FUNC(accept,
 384                    [libgo_check_nsl=no
 385                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 386      unset ac_cv_func_accept
 387      LIBS=$libgo_old_libs
 388    fi
 389    unset ac_cv_func_gethostbyname
 390    libgo_old_libs="$LIBS"
 391    AC_CHECK_FUNC(gethostbyname, ,
 392                  [AC_CHECK_LIB(nsl, main,
 393                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 394    unset ac_cv_func_gethostbyname
 395    LIBS=$libgo_old_libs
 396 ])
 397 NET_LIBS="$libgo_cv_lib_sockets"
 398 AC_SUBST(NET_LIBS)
 399
 400 dnl Test whether the compiler supports the -pthread option.
 401 AC_CACHE_CHECK([whether -pthread is supported],
 402 [libgo_cv_lib_pthread],
 403 [CFLAGS_hold=$CFLAGS
 404 CFLAGS="$CFLAGS -pthread"
 405 AC_COMPILE_IFELSE([[int i;]],
 406 [libgo_cv_lib_pthread=yes],
 407 [libgo_cv_lib_pthread=no])
 408 CFLAGS=$CFLAGS_hold])
 409 PTHREAD_CFLAGS=
 410 if test "$libgo_cv_lib_pthread" = yes; then
 411   PTHREAD_CFLAGS=-pthread
 412 fi
 413 AC_SUBST(PTHREAD_CFLAGS)
 414
 415 dnl Test for the -lpthread library.
 416 PTHREAD_LIBS=
 417 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 418 AC_SUBST(PTHREAD_LIBS)
 419
 420 dnl Test if -lrt is required for sched_yield and/or nanosleep.
 421 AC_SEARCH_LIBS([sched_yield], [rt])
 422 AC_SEARCH_LIBS([nanosleep], [rt])
 423
 424 AC_C_BIGENDIAN
 425
 426 GCC_CHECK_UNWIND_GETIPINFO
 427
 428 AC_ARG_ENABLE(sjlj-exceptions,
 429   AC_HELP_STRING([--enable-sjlj-exceptions],
 430                  [force use of builtin_setjmp for exceptions]),
 431   [case "$enableval" in
 432    yes|no|auto) ;;
 433    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 434    esac],
 435   [enable_sjlj_exceptions=auto])
 436
 437 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 438 [libgo_cv_lib_sjlj_exceptions],
 439 [AC_LANG_CONFTEST(
 440   [AC_LANG_SOURCE([
 441 void bar ();
 442 void clean (int *);
 443 void foo ()
 444 {
 445   int i __attribute__ ((cleanup (clean)));
 446   bar();
 447 }
 448 ])])
 449 CFLAGS_hold=$CFLAGS
 450 CFLAGS="--save-temps -fexceptions"
 451 libgo_cv_lib_sjlj_exceptions=unknown
 452 AS_IF([ac_fn_c_try_compile],
 453   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 454     libgo_cv_lib_sjlj_exceptions=yes
 455   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 456     libgo_cv_lib_sjlj_exceptions=no
 457   fi])
 458 CFLAGS=$CFLAGS_hold
 459 rm -f conftest*
 460 ])
 461
 462 if test "$enable_sjlj_exceptions" = "auto"; then
 463   enable_sjlj_exceptions=$libgo_cv_lib_sjlj_exceptions
 464 fi
 465
 466 case $enable_sjlj_exceptions in
 467 yes)
 468   AC_DEFINE(LIBGO_SJLJ_EXCEPTIONS, 1,
 469         [Define if the C++ compiler is configured for setjmp/longjmp exceptions.])
 470   ;;
 471 no)
 472   ;;
 473 *)
 474   AC_MSG_ERROR([unable to detect exception model])
 475   ;;
 476 esac
 477
 478 AC_CHECK_HEADERS(sys/file.h sys/mman.h syscall.h sys/epoll.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/reboot.h netinet/icmp6.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 479
 480 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 481 [#ifdef HAVE_SYS_SOCKET_H
 482 #include <sys/socket.h>
 483 #endif
 484 ])
 485
 486 AC_CACHE_CHECK([whether <ustat.h> can be used],
 487 [libgo_cv_c_ustat_h],
 488 [CFLAGS_hold=$CFLAGS
 489 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 490 AC_COMPILE_IFELSE(
 491 [AC_LANG_SOURCE([
 492 #include <sys/types.h>
 493 #ifdef HAVE_LINUX_FILTER_H
 494 #include <linux/filter.h>
 495 #endif
 496 #include <ustat.h>
 497 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 498 CFLAGS=$CFLAGS_hold])
 499 if test $libgo_cv_c_ustat_h = yes; then
 500   AC_DEFINE(HAVE_USTAT_H, 1,
 501     [Define to 1 if you have the <ustat.h> header file and it works.])
 502 fi
 503
 504 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 505
 506 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv dl_iterate_phdr)
 507 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 508 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 509
 510 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice tee unlinkat unshare utimensat)
 511 AC_TYPE_OFF_T
 512 AC_CHECK_TYPES([loff_t])
 513
 514 LIBS_hold="$LIBS"
 515 LIBS="$LIBS -lm"
 516 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 517 LIBS="$LIBS_hold"
 518
 519 CFLAGS_hold="$CFLAGS"
 520 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 521 LIBS_hold="$LIBS"
 522 LIBS="$LIBS $PTHREAD_LIBS"
 523 AC_CHECK_FUNCS(sem_timedwait)
 524 CFLAGS="$CFLAGS_hold"
 525 LIBS="$LIBS_hold"
 526
 527 LIBS_hold="$LIBS"
 528 LIBS="$LIBS $MATH_LIBS"
 529 AC_CHECK_FUNCS(matherr)
 530 LIBS="$LIBS_hold"
 531
 532 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 533 [libgo_cv_func___sync_bool_compare_and_swap_4],
 534 [AC_LINK_IFELSE([
 535 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 536 uint32 i;
 537 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 538 ],
 539 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 540 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 541 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 542   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 543     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 544 fi
 545
 546 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 547 [libgo_cv_func___sync_bool_compare_and_swap_8],
 548 [AC_LINK_IFELSE([
 549 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 550 uint64 i;
 551 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 552 ],
 553 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 554 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 555 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 556   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 557     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 558 fi
 559
 560 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 561 [libgo_cv_func___sync_fetch_and_add_4],
 562 [AC_LINK_IFELSE([
 563 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 564 uint32 i;
 565 int main() { return __sync_fetch_and_add (&i, 1); }
 566 ],
 567 [libgo_cv_func___sync_fetch_and_add_4=yes],
 568 [libgo_cv_func___sync_fetch_and_add_4=no])])
 569 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 570   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 571     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 572 fi
 573
 574 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 575 [libgo_cv_func___sync_add_and_fetch_8],
 576 [AC_LINK_IFELSE([
 577 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 578 uint64 i;
 579 int main() { return __sync_add_and_fetch (&i, 1); }
 580 ],
 581 [libgo_cv_func___sync_add_and_fetch_8=yes],
 582 [libgo_cv_func___sync_add_and_fetch_8=no])])
 583 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 584   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 585     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 586 fi
 587
 588 dnl For x86 we want to use the -minline-all-stringops option to avoid
 589 dnl forcing a stack split when calling memcpy and friends.
 590 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 591 [libgo_cv_c_stringops],
 592 [CFLAGS_hold=$CFLAGS
 593 CFLAGS="$CFLAGS -minline-all-stringops"
 594 AC_COMPILE_IFELSE([int i;],
 595 [libgo_cv_c_stringops=yes],
 596 [libgo_cv_c_stringops=no])
 597 CFLAGS=$CFLAGS_hold])
 598 STRINGOPS_FLAG=
 599 if test "$libgo_cv_c_stringops" = yes; then
 600   STRINGOPS_FLAG=-minline-all-stringops
 601 fi
 602 AC_SUBST(STRINGOPS_FLAG)
 603
 604 dnl For x86 we want to compile the math library with -mfancy-math-387
 605 dnl -funsafe-math-optimizations so that we can use the builtin
 606 dnl instructions directly.
 607 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 608 [libgo_cv_c_fancymath],
 609 [CFLAGS_hold=$CFLAGS
 610 CFLAGS="$CFLAGS -mfancy-math-387"
 611 AC_COMPILE_IFELSE([int i;],
 612 [libgo_cv_c_fancymath=yes],
 613 [libgo_cv_c_fancymath=no])
 614 CFLAGS=$CFLAGS_hold])
 615 MATH_FLAG=
 616 if test "$libgo_cv_c_fancymath" = yes; then
 617   MATH_FLAG="-mfancy-math-387 -funsafe-math-optimizations"
 618 else
 619   MATH_FLAG="-ffp-contract=off"
 620 fi
 621 AC_SUBST(MATH_FLAG)
 622
 623 CFLAGS_hold=$CFLAGS
 624 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 625 AC_CHECK_TYPES([off64_t])
 626 CFLAGS=$CFLAGS_hold
 627
 628 dnl Work out the size of the epoll_events struct on GNU/Linux.
 629 AC_CACHE_CHECK([epoll_event size],
 630 [libgo_cv_c_epoll_event_size],
 631 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 632 [sizeof (struct epoll_event)],
 633 [#include <sys/epoll.h>],
 634 [libgo_cv_c_epoll_event_size=0])])
 635 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 636 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 637
 638 dnl Work out the offset of the fd field in the epoll_events struct on
 639 dnl GNU/Linux.
 640 AC_CACHE_CHECK([epoll_event data.fd offset],
 641 [libgo_cv_c_epoll_event_fd_offset],
 642 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 643 [offsetof (struct epoll_event, data.fd)],
 644 [#include <stddef.h>
 645 #include <sys/epoll.h>],
 646 [libgo_cv_c_epoll_event_fd_offset=0])])
 647 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 648 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 649
 650 dnl See if struct exception is defined in <math.h>.
 651 AC_CHECK_TYPE([struct exception],
 652 [libgo_has_struct_exception=yes],
 653 [libgo_has_struct_exception=no],
 654 [#include <math.h>])
 655 if test "$libgo_has_struct_exception" = "yes"; then
 656   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 657             [Define to 1 if <math.h> defines struct exception])
 658 fi
 659
 660 dnl See whether setcontext changes the value of TLS variables.
 661 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 662 [libgo_cv_lib_setcontext_clobbers_tls],
 663 [CFLAGS_hold="$CFLAGS"
 664 CFLAGS="$PTHREAD_CFLAGS"
 665 LIBS_hold="$LIBS"
 666 LIBS="$LIBS $PTHREAD_LIBS"
 667 AC_CHECK_SIZEOF([void *])
 668 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 669 AC_RUN_IFELSE(
 670   [AC_LANG_SOURCE([
 671 #include <pthread.h>
 672 #include <stdlib.h>
 673 #include <ucontext.h>
 674 #include <unistd.h>
 675
 676 __thread int tls;
 677
 678 static char stack[[10 * 1024 * 1024]];
 679 static ucontext_t c;
 680
 681 /* Called via makecontext/setcontext.  */
 682
 683 static void
 684 cfn (void)
 685 {
 686   exit (tls);
 687 }
 688
 689 /* Called via pthread_create.  */
 690
 691 static void *
 692 tfn (void *dummy)
 693 {
 694   /* The thread should still see this value after calling
 695      setcontext.  */
 696   tls = 0;
 697
 698   setcontext (&c);
 699
 700   /* The call to setcontext should not return.  */
 701   abort ();
 702 }
 703
 704 int
 705 main ()
 706 {
 707   pthread_t tid;
 708
 709   /* The thread should not see this value.  */
 710   tls = 1;
 711
 712   if (getcontext (&c) < 0)
 713     abort ();
 714
 715   c.uc_stack.ss_sp = stack;
 716 #ifdef MAKECONTEXT_STACK_TOP
 717   c.uc_stack.ss_sp += sizeof stack;
 718 #endif
 719   c.uc_stack.ss_flags = 0;
 720   c.uc_stack.ss_size = sizeof stack;
 721   c.uc_link = NULL;
 722   makecontext (&c, cfn, 0);
 723
 724   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 725     abort ();
 726
 727   if (pthread_join (tid, NULL) != 0)
 728     abort ();
 729
 730   /* The thread should have called exit.  */
 731   abort ();
 732 }
 733 ])],
 734 [libgo_cv_lib_setcontext_clobbers_tls=no],
 735 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 736 [case "$target:$ptr_type_size" in
 737   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 738     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 739   *)
 740     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 741  esac
 742 ])
 743 CFLAGS="$CFLAGS_hold"
 744 LIBS="$LIBS_hold"
 745 ])
 746 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 747   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 748             [Define if setcontext clobbers TLS variables])
 749 fi
 750
 751 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 752 libgo_cv_ro_eh_frame, [
 753 libgo_cv_ro_eh_frame=no
 754 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 755 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 756   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 757     libgo_cv_ro_eh_frame=yes
 758   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 759        | grep -v '#write' > /dev/null; then
 760     libgo_cv_ro_eh_frame=yes
 761   fi
 762 fi
 763 rm -f conftest.*
 764 ])
 765 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 766   AC_DEFINE(EH_FRAME_FLAGS, "a",
 767             [Define to the flags needed for the .section .eh_frame directive.])
 768 else
 769   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 770             [Define to the flags needed for the .section .eh_frame directive.])
 771 fi
 772
 773 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 774 libgo_cv_as_comdat_gnu, [
 775 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 776 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 777   libgo_cv_as_comdat_gnu=yes
 778 else
 779   libgo_cv_as_comdat_gnu=no
 780 fi
 781 ])
 782 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 783   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 784             [Define if your assembler supports GNU comdat group syntax.])
 785 fi
 786
 787 AC_CACHE_CHECK([assembler supports pc related relocs],
 788 libgo_cv_as_x86_pcrel, [
 789 libgo_cv_as_x86_pcrel=yes
 790 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 791 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 792     libgo_cv_as_x86_pcrel=no
 793 fi
 794 ])
 795 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 796   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 797             [Define if your assembler supports PC relative relocs.])
 798 fi
 799
 800 AC_CACHE_CHECK([assembler supports unwind section type],
 801 libgo_cv_as_x86_64_unwind_section_type, [
 802 libgo_cv_as_x86_64_unwind_section_type=yes
 803 echo '.section .eh_frame,"a",@unwind' > conftest.s
 804 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 805     libgo_cv_as_x86_64_unwind_section_type=no
 806 fi
 807 ])
 808 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 809   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 810             [Define if your assembler supports unwind section type.])
 811 fi
 812
 813 AC_CACHE_SAVE
 814
 815 if test ${multilib} = yes; then
 816   multilib_arg="--enable-multilib"
 817 else
 818   multilib_arg=
 819 fi
 820
 821 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 822
 823 AC_CONFIG_COMMANDS([default],
 824 [if test -n "$CONFIG_FILES"; then
 825    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 826    # that multilib installs will end up installed in the correct place.
 827    # The testsuite needs it for multilib-aware ABI baseline files.
 828    # To work around this not being passed down from config-ml.in ->
 829    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 830    # append it here.  Only modify Makefiles that have just been created.
 831    #
 832    # Also, get rid of this simulated-VPATH thing that automake does.
 833    cat > vpsed << \_EOF
 834 s!`test -f '$<' || echo '$(srcdir)/'`!!
 835 _EOF
 836    for i in $SUBDIRS; do
 837     case $CONFIG_FILES in
 838      *${i}/Makefile*)
 839        #echo "Adding MULTISUBDIR to $i/Makefile"
 840        sed -f vpsed $i/Makefile > tmp
 841        grep '^MULTISUBDIR =' Makefile >> tmp
 842        mv tmp $i/Makefile
 843        ;;
 844     esac
 845    done
 846    rm vpsed
 847  fi
 848 ],
 849 [
 850 # Variables needed in config.status (file generation) which aren't already
 851 # passed by autoconf.
 852 SUBDIRS="$SUBDIRS"
 853 ])
 854
 855 AC_OUTPUT