libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=10:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  54                                       [turns on -Werror @<:@default=yes@:>@])])
  55 if test "x$enable_werror" != "xno"; then
  56   WERROR="-Werror"
  57 fi
  58 AC_SUBST(WERROR)
  59
  60 glibgo_toolexecdir=no
  61 glibgo_toolexeclibdir=no
  62
  63 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  64 AC_ARG_ENABLE([version-specific-runtime-libs],
  65   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  67   [case "$enableval" in
  68     yes) version_specific_libs=yes ;;
  69     no)  version_specific_libs=no ;;
  70     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71    esac],
  72   [version_specific_libs=no])
  73 AC_MSG_RESULT($version_specific_libs)
  74
  75 # Version-specific runtime libs processing.
  76 if test $version_specific_libs = yes; then
  77   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  78   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  79 fi
  80
  81 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  82 # Install a library built with a cross compiler in tooldir, not libdir.
  83 if test -n "$with_cross_host" &&
  84    test x"$with_cross_host" != x"no"; then
  85   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  86   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  87 else
  88   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  89   nover_glibgo_toolexeclibdir='${libdir}'
  90 fi
  91 multi_os_directory=`$GOC -print-multi-os-directory`
  92 case $multi_os_directory in
  93   .) ;; # Avoid trailing /.
  94   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
  95 esac
  96
  97 if test x"$glibgo_toolexecdir" = x"no"; then
  98   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
  99   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 100 fi
 101
 102 AC_SUBST(glibgo_toolexecdir)
 103 AC_SUBST(glibgo_toolexeclibdir)
 104 AC_SUBST(nover_glibgo_toolexeclibdir)
 105
 106 # See if the user wants to configure without libffi.  Some
 107 # architectures don't support it.  FIXME: We should set a default
 108 # based on the host.
 109 AC_ARG_WITH(libffi,
 110   AS_HELP_STRING([--without-libffi],
 111                  [don't use libffi]),
 112   [:],
 113   [with_libffi=${with_libffi_default-yes}])
 114
 115 LIBFFI=
 116 LIBFFIINCS=
 117 if test "$with_libffi" != no; then
 118    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 119    LIBFFI=../libffi/libffi_convenience.la
 120    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 121 fi
 122 AC_SUBST(LIBFFI)
 123 AC_SUBST(LIBFFIINCS)
 124
 125 # See if the user wants to configure without libatomic. This is useful if we are
 126 # on an architecture for which libgo does not need an atomic support library and
 127 # libatomic does not support our C compiler.
 128 AC_ARG_WITH(libatomic,
 129   AS_HELP_STRING([--without-libatomic],
 130                  [don't use libatomic]),
 131   [:],
 132   [with_libatomic=${with_libatomic_default-yes}])
 133
 134 LIBATOMIC=
 135 if test "$with_libatomic" != no; then
 136    LIBATOMIC=../libatomic/libatomic_convenience.la
 137 fi
 138 AC_SUBST(LIBATOMIC)
 139
 140 # Used to tell GNU make to include a file without telling automake to
 141 # include it.
 142 go_include="-include"
 143 AC_SUBST(go_include)
 144
 145 # All known GOOS values.  This is the union of all operating systems
 146 # supported by the gofrontend and all operating systems supported by
 147 # the gc toolchain.
 148 ALLGOOS="android darwin dragonfly freebsd irix linux netbsd openbsd plan9 rtems solaris windows"
 149
 150 is_darwin=no
 151 is_freebsd=no
 152 is_irix=no
 153 is_linux=no
 154 is_netbsd=no
 155 is_openbsd=no
 156 is_dragonfly=no
 157 is_rtems=no
 158 is_solaris=no
 159 GOOS=unknown
 160 case ${host} in
 161   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 162   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 163   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 164   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 165   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 166   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 167   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 168   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 169   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 170 esac
 171 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 172 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 173 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 174 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 175 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 176 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 177 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 178 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 179 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 180 AM_CONDITIONAL(LIBGO_IS_BSD, test $is_darwin = yes -o $is_dragonfly = yes -o $is_freebsd = yes -o $is_netbsd = yes -o $is_openbsd = yes)
 181 AC_SUBST(GOOS)
 182 AC_SUBST(ALLGOOS)
 183
 184 dnl Test whether we need to use DejaGNU or whether we can use the
 185 dnl simpler gotest approach.  We can only use gotest for a native
 186 dnl build.
 187 USE_DEJAGNU=no
 188 case ${host} in
 189   *-*-rtems*) USE_DEJAGNU=yes ;;
 190   ${build}) ;;
 191   *) USE_DEJAGNU=yes ;;
 192 esac
 193 AC_SUBST(USE_DEJAGNU)
 194
 195 # All known GOARCH values.  This is the union of all architectures
 196 # supported by the gofrontend and all architectures supported by the
 197 # gc toolchain.
 198 # N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 199 ALLGOARCH="386 alpha amd64 amd64p32 arm armbe arm64 arm64be ia64 m68k mipso32 mipsn32 mipso64 mipsn64 mips mipsle mips64 mips64le mips64p32 mips64pe32le ppc ppc64 ppc64le s390 s390x sparc sparc64"
 200
 201 # All known GOARCH_FAMILY values.
 202 ALLGOARCHFAMILY="I386 ALPHA AMD64 ARM ARM64 IA64 M68K MIPS MIPS64 PPC PPC64 S390 S390X SPARC SPARC64"
 203
 204 GOARCH=unknown
 205 GOARCH_FAMILY=unknown
 206 GOARCH_BIGENDIAN=0
 207 GOARCH_CACHELINESIZE=64
 208 GOARCH_PHYSPAGESIZE=4096
 209 GOARCH_PCQUANTUM=1
 210 GOARCH_INT64ALIGN=8
 211 GOARCH_HUGEPAGESIZE=0
 212 GOARCH_MINFRAMESIZE=0
 213 case ${host} in
 214   alpha*-*-*)
 215     GOARCH=alpha
 216     GOARCH_FAMILY=ALPHA
 217     GOARCH_PHYSPAGESIZE=8192
 218     GOARCH_PCQUANTUM=4
 219     ;;
 220   aarch64-*-*)
 221     GOARCH=arm64
 222     GOARCH_FAMILY=ARM64
 223     GOARCH_CACHELINESIZE=32
 224     GOARCH_PHYSPAGESIZE=65536
 225     GOARCH_PCQUANTUM=4
 226     GOARCH_MINFRAMESIZE=8
 227     ;;
 228   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 229     GOARCH=arm
 230     GOARCH_FAMILY=ARM
 231     GOARCH_CACHELINESIZE=32
 232     GOARCH_PCQUANTUM=4
 233     GOARCH_INT64ALIGN=4
 234     GOARCH_MINFRAMESIZE=4
 235     ;;
 236 changequote(,)dnl
 237   i[34567]86-*-* | x86_64-*-*)
 238 changequote([,])dnl
 239     AC_COMPILE_IFELSE([
 240 #ifdef __x86_64__
 241 #error 64-bit
 242 #endif],
 243 [GOARCH=386
 244 GOARCH_FAMILY=I386
 245 GOARCH_INT64ALIGN=4
 246 GOARCH_HUGEPAGESIZE="1 << 21"
 247 ],
 248 [GOARCH=amd64
 249 GOARCH_FAMILY=AMD64
 250 GOARCH_HUGEPAGESIZE="1 << 21"
 251 ])
 252     ;;
 253   ia64-*-*)
 254     GOARCH=ia64
 255     GOARCH_FAMILY=IA64
 256     GOARCH_CACHELINESIZE=16384
 257     GOARCH_PHYSPAGESIZE=8192
 258     ;;
 259   m68k*-*-*)
 260     GOARCH=m68k
 261     GOARCH_FAMILY=M68K
 262     GOARCH_BIGENDIAN=1
 263     GOARCH_CACHELINESIZE=16
 264     GOARCH_PCQUANTUM=4
 265     GOARCH_INT64ALIGN=4
 266     ;;
 267   mips*-*-*)
 268     AC_COMPILE_IFELSE([
 269 #if _MIPS_SIM != _ABIO32
 270 #error not o32
 271 #endif],
 272 [mips_abi="o32"],
 273         [AC_COMPILE_IFELSE([
 274 #if _MIPS_SIM != _ABIN32
 275 #error not n32
 276 #endif],
 277 [mips_abi="n32"],
 278         [AC_COMPILE_IFELSE([
 279 #if _MIPS_SIM != _ABI64
 280 #error not n64
 281 #endif],
 282 [mips_abi="n64"],
 283         [AC_COMPILE_IFELSE([
 284 #if _MIPS_SIM != _ABIO64
 285 #error not o64
 286 #endif],
 287 [mips_abi="o64"],
 288         [AC_MSG_ERROR([unknown MIPS ABI])
 289 [mips_abi="n32"]])])])])
 290     case "$mips_abi" in
 291     "o32") GOARCH=mipso32 ;;
 292     "n32") GOARCH=mipsn32 ;;
 293     "n64") GOARCH=mipsn64 ;;
 294     "o64") GOARCH=mipso64 ;;
 295     esac
 296     case "$mips_abi" in
 297     "o32" | "n32")
 298         GOARCH_FAMILY=MIPS
 299         GOARCH_INT64ALIGN=4
 300         GOARCH_MINFRAMESIZE=4
 301         ;;
 302     "n64" | "o64")
 303         GOARCH_FAMILY=MIPS64
 304         GOARCH_MINFRAMESIZE=8
 305         ;;
 306     esac
 307     case "${host}" in
 308     mips*el)
 309         ;;
 310     *)
 311         GOARCH_BIGENDIAN=1
 312         ;;
 313     esac
 314     GOARCH_CACHELINESIZE=32
 315     GOARCH_PHYSPAGESIZE=16384
 316     GOARCH_PCQUANTUM=4
 317     ;;
 318   rs6000*-*-* | powerpc*-*-*)
 319     AC_COMPILE_IFELSE([
 320 #ifdef _ARCH_PPC64
 321 #error 64-bit
 322 #endif],
 323 [GOARCH=ppc
 324 GOARCH_FAMILY=PPC
 325 GOARCH_BIGENDIAN=1
 326 GOARCH_INT64ALIGN=4
 327 ],
 328     [
 329 GOARCH_FAMILY=PPC64
 330 AC_COMPILE_IFELSE([
 331 #if defined(_BIG_ENDIAN) || defined(__BIG_ENDIAN__)
 332 #error 64be
 333 #endif],
 334 [GOARCH=ppc64le
 335 ],
 336 [GOARCH=ppc64
 337 GOARCH_BIGENDIAN=1
 338 ])])
 339     GOARCH_PHYSPAGESIZE=65536
 340     GOARCH_PCQUANTUM=4
 341     GOARCH_MINFRAMESIZE=32
 342     ;;
 343   s390*-*-*)
 344     AC_COMPILE_IFELSE([
 345 #if defined(__s390x__)
 346 #error 64-bit
 347 #endif],
 348 [GOARCH=s390
 349 GOARCH_FAMILY=S390
 350 GOARCH_INT64ALIGN=4
 351 GOARCH_MINFRAMESIZE=4
 352 ], [GOARCH=s390x
 353 GOARCH_FAMILY=S390X
 354 GOARCH_MINFRAMESIZE=8
 355 ])
 356     GOARCH_BIGENDIAN=1
 357     GOARCH_CACHELINESIZE=256
 358     GOARCH_PCQUANTUM=2
 359     ;;
 360   sparc*-*-*)
 361     AC_COMPILE_IFELSE([
 362 #if defined(__sparcv9) || defined(__arch64__)
 363 #error 64-bit
 364 #endif],
 365 [GOARCH=sparc
 366 GOARCH_FAMILY=SPARC
 367 GOARCH_INT64ALIGN=4
 368 ],
 369 [GOARCH=sparc64
 370 GOARCH_FAMILY=SPARC64
 371 ])
 372     GOARCH_BIGENDIAN=1
 373     GOARCH_PHYSPAGESIZE=8192
 374     GOARCH_PCQUANTUM=4
 375     ;;
 376 esac
 377 AC_SUBST(GOARCH)
 378 AC_SUBST(GOARCH_FAMILY)
 379 AC_SUBST(GOARCH_BIGENDIAN)
 380 AC_SUBST(GOARCH_CACHELINESIZE)
 381 AC_SUBST(GOARCH_PHYSPAGESIZE)
 382 AC_SUBST(GOARCH_PCQUANTUM)
 383 AC_SUBST(GOARCH_INT64ALIGN)
 384 AC_SUBST(GOARCH_HUGEPAGESIZE)
 385 AC_SUBST(GOARCH_MINFRAMESIZE)
 386 AC_SUBST(ALLGOARCH)
 387 AC_SUBST(ALLGOARCHFAMILY)
 388
 389 dnl Some files are only present when needed for specific architectures.
 390 GO_LIBCALL_OS_FILE=
 391 GO_LIBCALL_OS_ARCH_FILE=
 392 GO_SYSCALL_OS_FILE=
 393 GO_SYSCALL_OS_ARCH_FILE=
 394 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 395   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 396 fi
 397 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 398   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 399 fi
 400 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 401   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 402 fi
 403 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 404   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 405 fi
 406 AC_SUBST(GO_LIBCALL_OS_FILE)
 407 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 408 AC_SUBST(GO_SYSCALL_OS_FILE)
 409 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 410
 411 dnl Special flags used to generate sysinfo.go.
 412 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 413 case "$target" in
 414     mips-sgi-irix6.5*)
 415         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 416         # msghdr in <sys/socket.h>.
 417         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 418         ;;
 419     *-*-solaris2.1[[01]])
 420         # Solaris 10+ needs this so struct msghdr gets the msg_control
 421         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 422         # above doesn't work with C99.
 423         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 424         ;;
 425 esac
 426 AC_SUBST(OSCFLAGS)
 427
 428 dnl Use -fsplit-stack when compiling C code if available.
 429 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 430 [libgo_cv_c_split_stack_supported],
 431 [CFLAGS_hold=$CFLAGS
 432 CFLAGS="$CFLAGS -fsplit-stack"
 433 AC_COMPILE_IFELSE([[int i;]],
 434 [libgo_cv_c_split_stack_supported=yes],
 435 [libgo_cv_c_split_stack_supported=no])
 436 CFLAGS=$CFLAGS_hold])
 437
 438 dnl Make sure the linker permits -fsplit-stack.  Old versions of gold will
 439 dnl reject split-stack code calling non-split-stack code on targets
 440 dnl they don't support.
 441 AC_CACHE_CHECK([whether linker supports split/non-split linked together],
 442 [libgo_cv_c_linker_split_non_split],
 443 [cat > conftest1.c << EOF
 444 extern void f();
 445 int main() { f(); return 0; }
 446 EOF
 447 cat > conftest2.c << EOF
 448 void f() {}
 449 EOF
 450 $CC -c -fsplit-stack $CFLAGS $CPPFLAGS conftest1.c
 451 $CC -c $CFLAGS $CPPFLAGS conftest2.c
 452 if $CC -o conftest conftest1.$ac_objext conftest2.$ac_objext; then
 453   libgo_cv_c_linker_split_non_split=yes
 454 else
 455   libgo_cv_c_linker_split_non_split=no
 456 fi
 457 rm -f conftest1.* conftest2.* conftest])
 458
 459 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes; then
 460   SPLIT_STACK=-fsplit-stack
 461   AC_DEFINE(USING_SPLIT_STACK, 1,
 462                 [Define if the compiler supports -fsplit-stack])
 463 else
 464   SPLIT_STACK=
 465 fi
 466 AC_SUBST(SPLIT_STACK)
 467 AM_CONDITIONAL(USING_SPLIT_STACK,
 468         test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes)
 469
 470 dnl If the compiler supports split-stack but the linker does not, then
 471 dnl we need to explicitly disable split-stack for Go.
 472 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = no; then
 473   GO_SPLIT_STACK=-fno-split-stack
 474 else
 475   GO_SPLIT_STACK=
 476 fi
 477 AC_SUBST(GO_SPLIT_STACK)
 478
 479 dnl Check whether the linker does stack munging when calling from
 480 dnl split-stack into non-split-stack code.  We check this by looking
 481 dnl at the --help output.  FIXME: This is only half right: it's
 482 dnl possible for the linker to support this for some targets but not
 483 dnl others.
 484 dnl This is slightly different from the above check, which is whether
 485 dnl the linker permits the call at all.
 486 AC_CACHE_CHECK([whether linker supports split stack],
 487 [libgo_cv_c_linker_supports_split_stack],
 488 [libgo_cv_c_linker_supports_split_stack=no
 489 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 490   libgo_cv_c_linker_supports_split_stack=yes
 491 fi])
 492 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 493   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 494             [Define if the linker support split stack adjustments])
 495 fi
 496
 497 AC_CACHE_CHECK([whether compiler is llgo],
 498 [libgo_cv_c_goc_is_llgo],
 499 [libgo_cv_c_goc_is_llgo=no
 500 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 501   libgo_cv_c_goc_is_llgo=yes
 502 fi])
 503 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 504
 505 dnl Test for the -lm library.
 506 MATH_LIBS=
 507 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 508 AC_SUBST(MATH_LIBS)
 509
 510 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 511 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 512   [libgo_cv_lib_sockets=
 513    libgo_check_both=no
 514    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 515    if test "$libgo_check_socket" = "yes"; then
 516      unset ac_cv_func_connect
 517      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 518                   libgo_check_both=yes)
 519    fi
 520    if test "$libgo_check_both" = "yes"; then
 521      libgo_old_libs=$LIBS
 522      LIBS="$LIBS -lsocket -lnsl"
 523      unset ac_cv_func_accept
 524      AC_CHECK_FUNC(accept,
 525                    [libgo_check_nsl=no
 526                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 527      unset ac_cv_func_accept
 528      LIBS=$libgo_old_libs
 529    fi
 530    unset ac_cv_func_gethostbyname
 531    libgo_old_libs="$LIBS"
 532    AC_CHECK_FUNC(gethostbyname, ,
 533                  [AC_CHECK_LIB(nsl, main,
 534                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 535    unset ac_cv_func_gethostbyname
 536    AC_CHECK_FUNC(sendfile, ,
 537                  [AC_CHECK_LIB(sendfile, main,
 538                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lsendfile"])])
 539    LIBS=$libgo_old_libs
 540 ])
 541 NET_LIBS="$libgo_cv_lib_sockets"
 542 AC_SUBST(NET_LIBS)
 543
 544 dnl Test whether the compiler supports the -pthread option.
 545 AC_CACHE_CHECK([whether -pthread is supported],
 546 [libgo_cv_lib_pthread],
 547 [CFLAGS_hold=$CFLAGS
 548 CFLAGS="$CFLAGS -pthread"
 549 AC_COMPILE_IFELSE([[int i;]],
 550 [libgo_cv_lib_pthread=yes],
 551 [libgo_cv_lib_pthread=no])
 552 CFLAGS=$CFLAGS_hold])
 553 PTHREAD_CFLAGS=
 554 if test "$libgo_cv_lib_pthread" = yes; then
 555   PTHREAD_CFLAGS=-pthread
 556 fi
 557 AC_SUBST(PTHREAD_CFLAGS)
 558
 559 dnl Test for the -lpthread library.
 560 PTHREAD_LIBS=
 561 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 562 AC_SUBST(PTHREAD_LIBS)
 563
 564 dnl Test if -lrt is required for sched_yield or nanosleep or clock_gettime.
 565 AC_SEARCH_LIBS([sched_yield], [rt])
 566 AC_SEARCH_LIBS([nanosleep], [rt])
 567 AC_SEARCH_LIBS([clock_gettime], [rt])
 568
 569 AC_C_BIGENDIAN
 570
 571 GCC_CHECK_UNWIND_GETIPINFO
 572
 573 AC_CHECK_HEADERS(sched.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/reboot.h netinet/icmp6.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 574
 575 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 576 [#ifdef HAVE_SYS_SOCKET_H
 577 #include <sys/socket.h>
 578 #endif
 579 ])
 580
 581 AC_CACHE_CHECK([whether <ustat.h> can be used],
 582 [libgo_cv_c_ustat_h],
 583 [CFLAGS_hold=$CFLAGS
 584 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 585 AC_COMPILE_IFELSE(
 586 [AC_LANG_SOURCE([
 587 #include <sys/types.h>
 588 #ifdef HAVE_LINUX_FILTER_H
 589 #include <linux/filter.h>
 590 #endif
 591 #include <ustat.h>
 592 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 593 CFLAGS=$CFLAGS_hold])
 594 if test $libgo_cv_c_ustat_h = yes; then
 595   AC_DEFINE(HAVE_USTAT_H, 1,
 596     [Define to 1 if you have the <ustat.h> header file and it works.])
 597 fi
 598
 599 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 600
 601 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv unsetenv dl_iterate_phdr)
 602 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 603 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 604
 605 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice tee unlinkat unshare utimensat)
 606 AC_TYPE_OFF_T
 607 AC_CHECK_TYPES([loff_t])
 608
 609 LIBS_hold="$LIBS"
 610 LIBS="$LIBS -lm"
 611 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 612 LIBS="$LIBS_hold"
 613
 614 CFLAGS_hold="$CFLAGS"
 615 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 616 LIBS_hold="$LIBS"
 617 LIBS="$LIBS $PTHREAD_LIBS"
 618 AC_CHECK_FUNCS(sem_timedwait)
 619 CFLAGS="$CFLAGS_hold"
 620 LIBS="$LIBS_hold"
 621
 622 LIBS_hold="$LIBS"
 623 LIBS="$LIBS $MATH_LIBS"
 624 AC_CHECK_FUNCS(matherr)
 625 LIBS="$LIBS_hold"
 626
 627 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 628 [libgo_cv_func___sync_bool_compare_and_swap_4],
 629 [AC_LINK_IFELSE([
 630 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 631 uint32 i;
 632 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 633 ],
 634 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 635 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 636 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 637   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 638     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 639 fi
 640
 641 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 642 [libgo_cv_func___sync_bool_compare_and_swap_8],
 643 [AC_LINK_IFELSE([
 644 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 645 uint64 i;
 646 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 647 ],
 648 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 649 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 650 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 651   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 652     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 653 fi
 654
 655 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 656 [libgo_cv_func___sync_fetch_and_add_4],
 657 [AC_LINK_IFELSE([
 658 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 659 uint32 i;
 660 int main() { return __sync_fetch_and_add (&i, 1); }
 661 ],
 662 [libgo_cv_func___sync_fetch_and_add_4=yes],
 663 [libgo_cv_func___sync_fetch_and_add_4=no])])
 664 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 665   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 666     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 667 fi
 668
 669 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 670 [libgo_cv_func___sync_add_and_fetch_8],
 671 [AC_LINK_IFELSE([
 672 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 673 uint64 i;
 674 int main() { return __sync_add_and_fetch (&i, 1); }
 675 ],
 676 [libgo_cv_func___sync_add_and_fetch_8=yes],
 677 [libgo_cv_func___sync_add_and_fetch_8=no])])
 678 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 679   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 680     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 681 fi
 682
 683 dnl For x86 we want to use the -minline-all-stringops option to avoid
 684 dnl forcing a stack split when calling memcpy and friends.
 685 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 686 [libgo_cv_c_stringops],
 687 [CFLAGS_hold=$CFLAGS
 688 CFLAGS="$CFLAGS -minline-all-stringops"
 689 AC_COMPILE_IFELSE([int i;],
 690 [libgo_cv_c_stringops=yes],
 691 [libgo_cv_c_stringops=no])
 692 CFLAGS=$CFLAGS_hold])
 693 STRINGOPS_FLAG=
 694 if test "$libgo_cv_c_stringops" = yes; then
 695   STRINGOPS_FLAG=-minline-all-stringops
 696 fi
 697 AC_SUBST(STRINGOPS_FLAG)
 698
 699 dnl For x86 we want to compile the math library with -mfancy-math-387
 700 dnl -funsafe-math-optimizations so that we can use the builtin
 701 dnl instructions directly.
 702 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 703 [libgo_cv_c_fancymath],
 704 [CFLAGS_hold=$CFLAGS
 705 CFLAGS="$CFLAGS -mfancy-math-387"
 706 AC_COMPILE_IFELSE([int i;],
 707 [libgo_cv_c_fancymath=yes],
 708 [libgo_cv_c_fancymath=no])
 709 CFLAGS=$CFLAGS_hold])
 710 MATH_FLAG=
 711 if test "$libgo_cv_c_fancymath" = yes; then
 712   MATH_FLAG="-mfancy-math-387 -funsafe-math-optimizations"
 713 else
 714   MATH_FLAG="-ffp-contract=off"
 715 fi
 716 AC_SUBST(MATH_FLAG)
 717
 718 CFLAGS_hold=$CFLAGS
 719 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 720 AC_CHECK_TYPES([off64_t])
 721 CFLAGS=$CFLAGS_hold
 722
 723 dnl Work out the size of the epoll_events struct on GNU/Linux.
 724 AC_CACHE_CHECK([epoll_event size],
 725 [libgo_cv_c_epoll_event_size],
 726 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 727 [sizeof (struct epoll_event)],
 728 [#include <sys/epoll.h>],
 729 [libgo_cv_c_epoll_event_size=0])])
 730 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 731 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 732
 733 dnl Work out the offset of the fd field in the epoll_events struct on
 734 dnl GNU/Linux.
 735 AC_CACHE_CHECK([epoll_event data.fd offset],
 736 [libgo_cv_c_epoll_event_fd_offset],
 737 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 738 [offsetof (struct epoll_event, data.fd)],
 739 [#include <stddef.h>
 740 #include <sys/epoll.h>],
 741 [libgo_cv_c_epoll_event_fd_offset=0])])
 742 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 743 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 744
 745 dnl Check if <sys/stat.h> uses timespec_t for st_?tim members.  Introduced
 746 dnl in Solaris 12 for XPG7 compatibility.
 747 AC_EGREP_HEADER([timespec_t.*st_atim], [sys/stat.h],
 748                 [have_stat_timespec=yes], [have_stat_timespec=no])
 749 AM_CONDITIONAL(HAVE_STAT_TIMESPEC, test $have_stat_timespec = yes)
 750
 751 dnl See if struct exception is defined in <math.h>.
 752 AC_CHECK_TYPE([struct exception],
 753 [libgo_has_struct_exception=yes],
 754 [libgo_has_struct_exception=no],
 755 [#include <math.h>])
 756 if test "$libgo_has_struct_exception" = "yes"; then
 757   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 758             [Define to 1 if <math.h> defines struct exception])
 759 fi
 760
 761 dnl See whether setcontext changes the value of TLS variables.
 762 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 763 [libgo_cv_lib_setcontext_clobbers_tls],
 764 [CFLAGS_hold="$CFLAGS"
 765 CFLAGS="$PTHREAD_CFLAGS"
 766 LIBS_hold="$LIBS"
 767 LIBS="$LIBS $PTHREAD_LIBS"
 768 AC_CHECK_SIZEOF([void *])
 769 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 770 AC_RUN_IFELSE(
 771   [AC_LANG_SOURCE([
 772 #include <pthread.h>
 773 #include <stdlib.h>
 774 #include <ucontext.h>
 775 #include <unistd.h>
 776
 777 __thread int tls;
 778
 779 static char stack[[10 * 1024 * 1024]];
 780 static ucontext_t c;
 781
 782 /* Called via makecontext/setcontext.  */
 783
 784 static void
 785 cfn (void)
 786 {
 787   exit (tls);
 788 }
 789
 790 /* Called via pthread_create.  */
 791
 792 static void *
 793 tfn (void *dummy)
 794 {
 795   /* The thread should still see this value after calling
 796      setcontext.  */
 797   tls = 0;
 798
 799   setcontext (&c);
 800
 801   /* The call to setcontext should not return.  */
 802   abort ();
 803 }
 804
 805 int
 806 main ()
 807 {
 808   pthread_t tid;
 809
 810   /* The thread should not see this value.  */
 811   tls = 1;
 812
 813   if (getcontext (&c) < 0)
 814     abort ();
 815
 816   c.uc_stack.ss_sp = stack;
 817 #ifdef MAKECONTEXT_STACK_TOP
 818   c.uc_stack.ss_sp += sizeof stack;
 819 #endif
 820   c.uc_stack.ss_flags = 0;
 821   c.uc_stack.ss_size = sizeof stack;
 822   c.uc_link = NULL;
 823   makecontext (&c, cfn, 0);
 824
 825   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 826     abort ();
 827
 828   if (pthread_join (tid, NULL) != 0)
 829     abort ();
 830
 831   /* The thread should have called exit.  */
 832   abort ();
 833 }
 834 ])],
 835 [libgo_cv_lib_setcontext_clobbers_tls=no],
 836 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 837 [case "$target:$ptr_type_size" in
 838   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 839     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 840   *)
 841     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 842  esac
 843 ])
 844 CFLAGS="$CFLAGS_hold"
 845 LIBS="$LIBS_hold"
 846 ])
 847 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 848   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 849             [Define if setcontext clobbers TLS variables])
 850 fi
 851
 852 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 853 libgo_cv_ro_eh_frame, [
 854 libgo_cv_ro_eh_frame=no
 855 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 856 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 857   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 858     libgo_cv_ro_eh_frame=yes
 859   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 860        | grep -v '#write' > /dev/null; then
 861     libgo_cv_ro_eh_frame=yes
 862   fi
 863 fi
 864 rm -f conftest.*
 865 ])
 866 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 867   AC_DEFINE(EH_FRAME_FLAGS, "a",
 868             [Define to the flags needed for the .section .eh_frame directive.])
 869 else
 870   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 871             [Define to the flags needed for the .section .eh_frame directive.])
 872 fi
 873
 874 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 875 [libgo_cv_c_unused_arguments],
 876 [CFLAGS_hold=$CFLAGS
 877 CFLAGS="$CFLAGS -Qunused-arguments"
 878 AC_COMPILE_IFELSE([[int i;]],
 879 [libgo_cv_c_unused_arguments=yes],
 880 [libgo_cv_c_unused_arguments=no])
 881 CFLAGS=$CFLAGS_hold])
 882
 883 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 884 libgo_cv_as_comdat_gnu, [
 885 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 886 CFLAGS_hold=$CFLAGS
 887 if test "$libgo_cv_c_unused_arguments" = yes; then
 888   CFLAGS="$CFLAGS -Qunused-arguments"
 889 fi
 890 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 891   libgo_cv_as_comdat_gnu=yes
 892 else
 893   libgo_cv_as_comdat_gnu=no
 894 fi
 895 CFLAGS=$CFLAGS_hold
 896 ])
 897 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 898   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 899             [Define if your assembler supports GNU comdat group syntax.])
 900 fi
 901
 902 AC_CACHE_CHECK([assembler supports pc related relocs],
 903 libgo_cv_as_x86_pcrel, [
 904 libgo_cv_as_x86_pcrel=yes
 905 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 906 CFLAGS_hold=$CFLAGS
 907 if test "$libgo_cv_c_unused_arguments" = yes; then
 908   CFLAGS="$CFLAGS -Qunused-arguments"
 909 fi
 910 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 911     libgo_cv_as_x86_pcrel=no
 912 fi
 913 CFLAGS=$CFLAGS_hold
 914 ])
 915 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 916   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 917             [Define if your assembler supports PC relative relocs.])
 918 fi
 919
 920 AC_CACHE_CHECK([assembler supports unwind section type],
 921 libgo_cv_as_x86_64_unwind_section_type, [
 922 libgo_cv_as_x86_64_unwind_section_type=yes
 923 echo '.section .eh_frame,"a",@unwind' > conftest.s
 924 CFLAGS_hold=$CFLAGS
 925 if test "$libgo_cv_c_unused_arguments" = yes; then
 926   CFLAGS="$CFLAGS -Qunused-arguments"
 927 fi
 928 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 929     libgo_cv_as_x86_64_unwind_section_type=no
 930 fi
 931 CFLAGS=$CFLAGS_hold
 932 ])
 933 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 934   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 935             [Define if your assembler supports unwind section type.])
 936 fi
 937
 938 AC_CACHE_SAVE
 939
 940 if test ${multilib} = yes; then
 941   multilib_arg="--enable-multilib"
 942 else
 943   multilib_arg=
 944 fi
 945
 946 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 947
 948 AC_CONFIG_COMMANDS([default],
 949 [if test -n "$CONFIG_FILES"; then
 950    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 951    # that multilib installs will end up installed in the correct place.
 952    # The testsuite needs it for multilib-aware ABI baseline files.
 953    # To work around this not being passed down from config-ml.in ->
 954    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 955    # append it here.  Only modify Makefiles that have just been created.
 956    #
 957    # Also, get rid of this simulated-VPATH thing that automake does.
 958    cat > vpsed << \_EOF
 959 s!`test -f '$<' || echo '$(srcdir)/'`!!
 960 _EOF
 961    for i in $SUBDIRS; do
 962     case $CONFIG_FILES in
 963      *${i}/Makefile*)
 964        #echo "Adding MULTISUBDIR to $i/Makefile"
 965        sed -f vpsed $i/Makefile > tmp
 966        grep '^MULTISUBDIR =' Makefile >> tmp
 967        mv tmp $i/Makefile
 968        ;;
 969     esac
 970    done
 971    rm vpsed
 972  fi
 973 ],
 974 [
 975 # Variables needed in config.status (file generation) which aren't already
 976 # passed by autoconf.
 977 SUBDIRS="$SUBDIRS"
 978 ])
 979
 980 AC_OUTPUT