libitm/acinclude.m4

   1 dnl ----------------------------------------------------------------------
   2 dnl This whole bit snagged from libgfortran.
   3
   4 dnl Check whether the target supports __sync_*_compare_and_swap.
   5 AC_DEFUN([LIBITM_CHECK_SYNC_BUILTINS], [
   6   AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
   7                  libitm_cv_have_sync_builtins, [
   8   AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
   9               libitm_cv_have_sync_builtins=yes, libitm_cv_have_sync_builtins=no)])
  10   if test $libitm_cv_have_sync_builtins = yes; then
  11     AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
  12               [Define to 1 if the target supports __sync_*_compare_and_swap])
  13   fi])
  14
  15 dnl Check whether the target supports 64-bit __sync_*_compare_and_swap.
  16 AC_DEFUN([LIBITM_CHECK_64BIT_SYNC_BUILTINS], [
  17   AC_CACHE_CHECK([whether the target supports 64-bit __sync_*_compare_and_swap],
  18                  libitm_cv_have_64bit_sync_builtins, [
  19   AC_TRY_LINK([#include <stdint.h>],
  20     [uint64_t foo, bar;
  21      bar = __sync_val_compare_and_swap(&foo, 0, 1);],
  22     libitm_cv_have_64bit_sync_builtins=yes,
  23     libitm_cv_have_64bit_sync_builtins=no)])
  24     if test $libitm_cv_have_64bit_sync_builtins = yes; then
  25       AC_DEFINE(HAVE_64BIT_SYNC_BUILTINS, 1,
  26                 [Define to 1 if the target supports 64-bit __sync_*_compare_and_swap])
  27   fi])
  28
  29 dnl Check whether the target supports hidden visibility.
  30 AC_DEFUN([LIBITM_CHECK_ATTRIBUTE_VISIBILITY], [
  31   AC_CACHE_CHECK([whether the target supports hidden visibility],
  32                  libitm_cv_have_attribute_visibility, [
  33   save_CFLAGS="$CFLAGS"
  34   CFLAGS="$CFLAGS -Werror"
  35   AC_TRY_COMPILE([void __attribute__((visibility("hidden"))) foo(void) { }],
  36                  [], libitm_cv_have_attribute_visibility=yes,
  37                  libitm_cv_have_attribute_visibility=no)
  38   CFLAGS="$save_CFLAGS"])
  39   if test $libitm_cv_have_attribute_visibility = yes; then
  40     AC_DEFINE(HAVE_ATTRIBUTE_VISIBILITY, 1,
  41       [Define to 1 if the target supports __attribute__((visibility(...))).])
  42   fi])
  43
  44 dnl Check whether the target supports dllexport
  45 AC_DEFUN([LIBITM_CHECK_ATTRIBUTE_DLLEXPORT], [
  46   AC_CACHE_CHECK([whether the target supports dllexport],
  47                  libitm_cv_have_attribute_dllexport, [
  48   save_CFLAGS="$CFLAGS"
  49   CFLAGS="$CFLAGS -Werror"
  50   AC_TRY_COMPILE([void __attribute__((dllexport)) foo(void) { }],
  51                  [], libitm_cv_have_attribute_dllexport=yes,
  52                  libitm_cv_have_attribute_dllexport=no)
  53   CFLAGS="$save_CFLAGS"])
  54   if test $libitm_cv_have_attribute_dllexport = yes; then
  55     AC_DEFINE(HAVE_ATTRIBUTE_DLLEXPORT, 1,
  56       [Define to 1 if the target supports __attribute__((dllexport)).])
  57   fi])
  58
  59 dnl Check whether the target supports symbol aliases.
  60 AC_DEFUN([LIBITM_CHECK_ATTRIBUTE_ALIAS], [
  61   AC_CACHE_CHECK([whether the target supports symbol aliases],
  62                  libitm_cv_have_attribute_alias, [
  63   AC_TRY_LINK([
  64 void foo(void) { }
  65 extern void bar(void) __attribute__((alias("foo")));],
  66     [bar();], libitm_cv_have_attribute_alias=yes, libitm_cv_have_attribute_alias=no)])
  67   if test $libitm_cv_have_attribute_alias = yes; then
  68     AC_DEFINE(HAVE_ATTRIBUTE_ALIAS, 1,
  69       [Define to 1 if the target supports __attribute__((alias(...))).])
  70   fi])
  71
  72 dnl Check how size_t is mangled.
  73 AC_DEFUN([LIBITM_CHECK_SIZE_T_MANGLING], [
  74   AC_CACHE_CHECK([how size_t is mangled],
  75                  libitm_cv_size_t_mangling, [
  76     AC_TRY_COMPILE([], [extern __SIZE_TYPE__ x; extern unsigned long x;],
  77                    [libitm_cv_size_t_mangling=m], [
  78       AC_TRY_COMPILE([], [extern __SIZE_TYPE__ x; extern unsigned int x;],
  79                      [libitm_cv_size_t_mangling=j], [
  80         AC_TRY_COMPILE([],
  81                        [extern __SIZE_TYPE__ x; extern unsigned long long x;],
  82                        [libitm_cv_size_t_mangling=y], [
  83           AC_TRY_COMPILE([],
  84                          [extern __SIZE_TYPE__ x; extern unsigned short x;],
  85                          [libitm_cv_size_t_mangling=t],
  86                          [libitm_cv_size_t_mangling=x])
  87         ])
  88       ])
  89     ])
  90   ])
  91   if test $libitm_cv_size_t_mangling = x; then
  92     AC_MSG_ERROR([Unknown underlying type for size_t])
  93   fi
  94   AC_DEFINE_UNQUOTED(MANGLE_SIZE_T, [$libitm_cv_size_t_mangling],
  95     [Define to the letter to which size_t is mangled.])
  96 ])
  97
  98 dnl Check if as supports AVX instructions.
  99 AC_DEFUN([LIBITM_CHECK_AS_AVX], [
 100 case "${target_cpu}" in
 101 i[[34567]]86 | x86_64)
 102   AC_CACHE_CHECK([if the assembler supports AVX], libitm_cv_as_avx, [
 103     AC_TRY_COMPILE([], [asm("vzeroupper");],
 104                    [libitm_cv_as_avx=yes], [libitm_cv_as_avx=no])
 105   ])
 106   if test x$libitm_cv_as_avx = xyes; then
 107     AC_DEFINE(HAVE_AS_AVX, 1, [Define to 1 if the assembler supports AVX.])
 108   fi
 109   ;;
 110 esac])
 111
 112 dnl Check if as supports RTM instructions.
 113 AC_DEFUN([LIBITM_CHECK_AS_RTM], [
 114 case "${target_cpu}" in
 115 i[[34567]]86 | x86_64)
 116   AC_CACHE_CHECK([if the assembler supports RTM], libitm_cv_as_rtm, [
 117     AC_TRY_COMPILE([], [asm("1: xbegin 1b; xend");],
 118                    [libitm_cv_as_rtm=yes], [libitm_cv_as_rtm=no])
 119   ])
 120   if test x$libitm_cv_as_rtm = xyes; then
 121     AC_DEFINE(HAVE_AS_RTM, 1, [Define to 1 if the assembler supports RTM.])
 122   fi
 123   ;;
 124 esac])
 125
 126 dnl Check if as supports HTM instructions.
 127 AC_DEFUN([LIBITM_CHECK_AS_HTM], [
 128 case "${target_cpu}" in
 129 powerpc*)
 130   AC_CACHE_CHECK([if the assembler supports HTM], libitm_cv_as_htm, [
 131     AC_TRY_COMPILE([], [asm("tbegin. 0; tend. 0");],
 132                    [libitm_cv_as_htm=yes], [libitm_cv_as_htm=no])
 133   ])
 134   if test x$libitm_cv_as_htm = xyes; then
 135     AC_DEFINE(HAVE_AS_HTM, 1, [Define to 1 if the assembler supports HTM.])
 136   fi
 137   ;;
 138 s390*)
 139   AC_CACHE_CHECK([if the assembler supports HTM], libitm_cv_as_htm, [
 140     save_CFLAGS="$CFLAGS"
 141     CFLAGS="$CFLAGS -march=zEC12"
 142     AC_TRY_COMPILE([], [asm("tbegin 0,0; tend");],
 143                    [libitm_cv_as_htm=yes], [libitm_cv_as_htm=no])
 144     CFLAGS="$save_CFLAGS"])
 145   if test x$libitm_cv_as_htm = xyes; then
 146     AC_DEFINE(HAVE_AS_HTM, 1, [Define to 1 if the assembler supports HTM.])
 147   fi
 148   ;;
 149 esac])
 150
 151 sinclude(../libtool.m4)
 152 dnl The lines below arrange for aclocal not to bring an installed
 153 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
 154 dnl add a definition of LIBTOOL to Makefile.in.
 155 ifelse(,,,[AC_SUBST(LIBTOOL)
 156 AC_DEFUN([AM_PROG_LIBTOOL])
 157 AC_DEFUN([AC_LIBTOOL_DLOPEN])
 158 AC_DEFUN([AC_PROG_LD])
 159 ])
 160
 161 dnl ----------------------------------------------------------------------
 162 dnl This whole bit snagged from libstdc++-v3.
 163
 164 dnl
 165 dnl LIBITM_ENABLE
 166 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 167 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 168 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 169 dnl
 170 dnl See docs/html/17_intro/configury.html#enable for documentation.
 171 dnl
 172 m4_define([LIBITM_ENABLE],[dnl
 173 m4_define([_g_switch],[--enable-$1])dnl
 174 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 175  AC_ARG_ENABLE($1,_g_help,
 176   m4_bmatch([$5],
 177    [^permit ],
 178      [[
 179       case "$enableval" in
 180        m4_bpatsubst([$5],[permit ])) ;;
 181        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 182           dnl Idea for future:  generate a URL pointing to
 183           dnl "onlinedocs/configopts.html#whatever"
 184       esac
 185      ]],
 186    [^$],
 187      [[
 188       case "$enableval" in
 189        yes|no) ;;
 190        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 191       esac
 192      ]],
 193    [[$5]]),
 194   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 195 m4_undefine([_g_switch])dnl
 196 m4_undefine([_g_help])dnl
 197 ])
 198
 199
 200 dnl
 201 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 202 dnl the native linker is in use, all variables will be defined to something
 203 dnl safe (like an empty string).
 204 dnl
 205 dnl Defines:
 206 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 207 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 208 dnl  LD (as a side effect of testing)
 209 dnl Sets:
 210 dnl  with_gnu_ld
 211 dnl  libitm_ld_is_gold (possibly)
 212 dnl  libitm_gnu_ld_version (possibly)
 213 dnl
 214 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 215 dnl set libitm_gnu_ld_version to 12345.  Zeros cause problems.
 216 dnl
 217 AC_DEFUN([LIBITM_CHECK_LINKER_FEATURES], [
 218   # If we're not using GNU ld, then there's no point in even trying these
 219   # tests.  Check for that first.  We should have already tested for gld
 220   # by now (in libtool), but require it now just to be safe...
 221   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 222   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 223   AC_REQUIRE([AC_PROG_LD])
 224   AC_REQUIRE([AC_PROG_AWK])
 225
 226   # The name set by libtool depends on the version of libtool.  Shame on us
 227   # for depending on an impl detail, but c'est la vie.  Older versions used
 228   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 229   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 230   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 231   # set (hence we're using an older libtool), then set it.
 232   if test x${with_gnu_ld+set} != xset; then
 233     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 234       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 235       with_gnu_ld=no
 236     else
 237       with_gnu_ld=$ac_cv_prog_gnu_ld
 238     fi
 239   fi
 240
 241   # Start by getting the version number.  I think the libtool test already
 242   # does some of this, but throws away the result.
 243   libitm_ld_is_gold=no
 244   if $LD --version 2>/dev/null | grep 'GNU gold'> /dev/null 2>&1; then
 245     libitm_ld_is_gold=yes
 246   fi
 247   changequote(,)
 248   ldver=`$LD --version 2>/dev/null |
 249          sed -e 's/GNU gold /GNU ld /;s/GNU ld version /GNU ld /;s/GNU ld ([^)]*) /GNU ld /;s/GNU ld \([0-9.][0-9.]*\).*/\1/; q'`
 250   changequote([,])
 251   libitm_gnu_ld_version=`echo $ldver | \
 252          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 253
 254   # Set --gc-sections.
 255   if test "$with_gnu_ld" = "notbroken"; then
 256     # GNU ld it is!  Joy and bunny rabbits!
 257
 258     # All these tests are for C++; save the language and the compiler flags.
 259     # Need to do this so that g++ won't try to link in libstdc++
 260     ac_test_CFLAGS="${CFLAGS+set}"
 261     ac_save_CFLAGS="$CFLAGS"
 262     CFLAGS='-x c++  -Wl,--gc-sections'
 263
 264     # Check for -Wl,--gc-sections
 265     # XXX This test is broken at the moment, as symbols required for linking
 266     # are now in libsupc++ (not built yet).  In addition, this test has
 267     # cored on solaris in the past.  In addition, --gc-sections doesn't
 268     # really work at the moment (keeps on discarding used sections, first
 269     # .eh_frame and now some of the glibc sections for iconv).
 270     # Bzzzzt.  Thanks for playing, maybe next time.
 271     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 272     AC_TRY_RUN([
 273      int main(void)
 274      {
 275        try { throw 1; }
 276        catch (...) { };
 277        return 0;
 278      }
 279     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 280     if test "$ac_test_CFLAGS" = set; then
 281       CFLAGS="$ac_save_CFLAGS"
 282     else
 283       # this is the suspicious part
 284       CFLAGS=''
 285     fi
 286     if test "$ac_sectionLDflags" = "yes"; then
 287       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 288     fi
 289     AC_MSG_RESULT($ac_sectionLDflags)
 290   fi
 291
 292   # Set linker optimization flags.
 293   if test x"$with_gnu_ld" = x"yes"; then
 294     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 295   fi
 296
 297   AC_SUBST(SECTION_LDFLAGS)
 298   AC_SUBST(OPT_LDFLAGS)
 299 ])
 300
 301
 302 dnl
 303 dnl Add version tags to symbols in shared library (or not), additionally
 304 dnl marking other symbols as private/local (or not).
 305 dnl
 306 dnl --enable-symvers=style adds a version script to the linker call when
 307 dnl       creating the shared library.  The choice of version script is
 308 dnl       controlled by 'style'.
 309 dnl --disable-symvers does not.
 310 dnl  +  Usage:  LIBITM_ENABLE_SYMVERS[(DEFAULT)]
 311 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
 312 dnl       choose a default style based on linker characteristics.  Passing
 313 dnl       'no' disables versioning.
 314 dnl
 315 AC_DEFUN([LIBITM_ENABLE_SYMVERS], [
 316
 317 LIBITM_ENABLE(symvers,yes,[=STYLE],
 318   [enables symbol versioning of the shared library],
 319   [permit yes|no|gnu*|sun])
 320
 321 # If we never went through the LIBITM_CHECK_LINKER_FEATURES macro, then we
 322 # don't know enough about $LD to do tricks...
 323 AC_REQUIRE([LIBITM_CHECK_LINKER_FEATURES])
 324
 325 # Turn a 'yes' into a suitable default.
 326 if test x$enable_symvers = xyes ; then
 327   # FIXME  The following test is too strict, in theory.
 328   if test $enable_shared = no || test "x$LD" = x; then
 329     enable_symvers=no
 330   else
 331     if test $with_gnu_ld = yes ; then
 332       enable_symvers=gnu
 333     else
 334       case ${target_os} in
 335         # Sun symbol versioning exists since Solaris 2.5.
 336         solaris2.[[5-9]]* | solaris2.1[[0-9]]*)
 337           enable_symvers=sun ;;
 338         *)
 339           enable_symvers=no ;;
 340       esac
 341     fi
 342   fi
 343 fi
 344
 345 # Check if 'sun' was requested on non-Solaris 2 platforms.
 346 if test x$enable_symvers = xsun ; then
 347   case ${target_os} in
 348     solaris2*)
 349       # All fine.
 350       ;;
 351     *)
 352       # Unlikely to work.
 353       AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
 354       AC_MSG_WARN([=== you are not targetting Solaris 2.])
 355       AC_MSG_WARN([=== Symbol versioning will be disabled.])
 356       enable_symvers=no
 357       ;;
 358   esac
 359 fi
 360
 361 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
 362 if test $enable_symvers != no; then
 363   AC_MSG_CHECKING([for shared libgcc])
 364   ac_save_CFLAGS="$CFLAGS"
 365   CFLAGS=' -lgcc_s'
 366   AC_TRY_LINK(, [return 0;], libitm_shared_libgcc=yes, libitm_shared_libgcc=no)
 367   CFLAGS="$ac_save_CFLAGS"
 368   if test $libitm_shared_libgcc = no; then
 369     cat > conftest.c <<EOF
 370 int main (void) { return 0; }
 371 EOF
 372 changequote(,)dnl
 373     libitm_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 374                              -shared -shared-libgcc -o conftest.so \
 375                              conftest.c -v 2>&1 >/dev/null \
 376                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
 377 changequote([,])dnl
 378     rm -f conftest.c conftest.so
 379     if test x${libitm_libgcc_s_suffix+set} = xset; then
 380       CFLAGS=" -lgcc_s$libitm_libgcc_s_suffix"
 381       AC_TRY_LINK(, [return 0;], libitm_shared_libgcc=yes)
 382       CFLAGS="$ac_save_CFLAGS"
 383     fi
 384   fi
 385   AC_MSG_RESULT($libitm_shared_libgcc)
 386 fi
 387
 388 # For GNU ld, we need at least this version.  The format is described in
 389 # LIBITM_CHECK_LINKER_FEATURES above.
 390 libitm_min_gnu_ld_version=21400
 391 # XXXXXXXXXXX libitm_gnu_ld_version=21390
 392
 393 # Check to see if unspecified "yes" value can win, given results above.
 394 # Change "yes" into either "no" or a style name.
 395 if test $enable_symvers != no && test $libitm_shared_libgcc = yes; then
 396   if test $with_gnu_ld = yes; then
 397     if test $libitm_gnu_ld_version -ge $libitm_min_gnu_ld_version ; then
 398       enable_symvers=gnu
 399     elif test $libitm_ld_is_gold = yes ; then
 400       enable_symvers=gnu
 401     else
 402       # The right tools, the right setup, but too old.  Fallbacks?
 403       AC_MSG_WARN(=== Linker version $libitm_gnu_ld_version is too old for)
 404       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
 405       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
 406       AC_MSG_WARN(=== $libitm_min_gnu_ld_version or later and rebuild GCC.)
 407       if test $libitm_gnu_ld_version -ge 21200 ; then
 408         # Globbing fix is present, proper block support is not.
 409         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
 410         dnl enable_symvers=???
 411         AC_MSG_WARN([=== Symbol versioning will be disabled.])
 412         enable_symvers=no
 413       else
 414         # 2.11 or older.
 415         AC_MSG_WARN([=== Symbol versioning will be disabled.])
 416         enable_symvers=no
 417       fi
 418     fi
 419   elif test $enable_symvers = sun; then
 420     : All interesting versions of Sun ld support sun style symbol versioning.
 421   else
 422     # just fail for now
 423     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
 424     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
 425     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
 426     AC_MSG_WARN([=== Symbol versioning will be disabled.])
 427     enable_symvers=no
 428   fi
 429 fi
 430
 431 AM_CONDITIONAL(LIBITM_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
 432 AM_CONDITIONAL(LIBITM_BUILD_VERSIONED_SHLIB_GNU, test $enable_symvers = gnu)
 433 AM_CONDITIONAL(LIBITM_BUILD_VERSIONED_SHLIB_SUN, test $enable_symvers = sun)
 434 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
 435 ])