libjava/acinclude.m4

   1 AC_DEFUN(LIBGCJ_CONFIGURE,
   2 [
   3 dnl Default to --enable-multilib
   4 AC_ARG_ENABLE(multilib,
   5 [  --enable-multilib       build many library versions (default)],
   6 [case "${enableval}" in
   7   yes) multilib=yes ;;
   8   no)  multilib=no ;;
   9   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  10  esac], [multilib=yes])dnl
  11
  12 dnl We may get other options which we dont document:
  13 dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
  14
  15 if test "[$]{srcdir}" = "."; then
  16   if test "[$]{with_target_subdir}" != "."; then
  17     libgcj_basedir="[$]{srcdir}/[$]{with_multisrctop}../$1"
  18   else
  19     libgcj_basedir="[$]{srcdir}/[$]{with_multisrctop}$1"
  20   fi
  21 else
  22   libgcj_basedir="[$]{srcdir}/$1"
  23 fi
  24 AC_SUBST(libgcj_basedir)
  25
  26 AC_CANONICAL_HOST
  27
  28 dnl This shouldn't be needed, as long as top-level dependencies are
  29 dnl defined correctly and shared-library paths are set up so that
  30 dnl execution tests succeed.  FIXME.
  31 define([AC_PROG_CC_WORKS],[])
  32 define([AC_PROG_CXX_WORKS],[])
  33
  34 AC_PROG_CC
  35 AC_PROG_CXX
  36
  37 dnl version is pulled out to make it a bit easier to change using sed.
  38 version=0.0.7
  39 dnl Still use "libjava" here to placate dejagnu.
  40 AM_INIT_AUTOMAKE(libjava, $version)
  41
  42 # AC_CHECK_TOOL does AC_REQUIRE (AC_CANONICAL_BUILD).  If we dont
  43 # run it explicitly here, it will be run implicitly before
  44 # LIBGCJ_CONFIGURE, which doesn't work because that means that it will
  45 # be run before AC_CANONICAL_HOST.
  46 AC_CANONICAL_BUILD
  47
  48 AC_CHECK_TOOL(AS, as)
  49 AC_CHECK_TOOL(AR, ar)
  50 AC_CHECK_TOOL(RANLIB, ranlib, :)
  51
  52 AC_PROG_INSTALL
  53
  54 AM_MAINTAINER_MODE
  55
  56 # We need AC_EXEEXT to keep automake happy in cygnus mode.  However,
  57 # at least currently, we never actually build a program, so we never
  58 # need to use $(EXEEXT).  Moreover, the test for EXEEXT normally
  59 # fails, because we are probably configuring with a cross compiler
  60 # which cant create executables.  So we include AC_EXEEXT to keep
  61 # automake happy, but we dont execute it, since we dont care about
  62 # the result.
  63 if false; then
  64   AC_EXEEXT
  65 fi
  66
  67 # configure.host sets the following important variables
  68 #       libgcj_cflags    - host specific C compiler flags
  69 #       libgcj_cxxflags  - host specific C++ compiler flags
  70 #       libgcj_javaflags - host specific Java compiler flags
  71
  72 libgcj_cflags=
  73 libgcj_cxxflags=
  74 libgcj_javaflags=
  75
  76 . [$]{libgcj_basedir}/configure.host
  77
  78 case [$]{libgcj_basedir} in
  79 /* | [A-Za-z]:[/\\]*) libgcj_flagbasedir=[$]{libgcj_basedir} ;;
  80 *) libgcj_flagbasedir='[$](top_builddir)/'[$]{libgcj_basedir} ;;
  81 esac
  82
  83 LIBGCJ_CFLAGS="[$]{libgcj_cflags}"
  84 LIBGCJ_CXXFLAGS="[$]{libgcj_cxxflags}"
  85 LIBGCJ_JAVAFLAGS="[$]{libgcj_javaflags}"
  86 AC_SUBST(LIBGCJ_CFLAGS)
  87 AC_SUBST(LIBGCJ_CXXFLAGS)
  88 AC_SUBST(LIBGCJ_JAVAFLAGS)
  89 ])dnl
  90
  91 sinclude(../libtool.m4)
  92 dnl The lines below arrange for aclocal not to bring libtool.m4
  93 dnl AM_PROG_LIBTOOL into aclocal.m4, while still arranging for automake
  94 dnl to add a definition of LIBTOOL to Makefile.in.
  95 ifelse(yes,no,[
  96 AC_DEFUN([AM_PROG_LIBTOOL],)
  97 AC_DEFUN([AC_LIBTOOL_DLOPEN],)
  98 AC_DEFUN([AC_LIBLTDL_CONVENIENCE],)
  99 AC_DEFUN([LT_AC_PROG_GCJ],)
 100 AC_SUBST(GCJ)
 101 AC_SUBST(LIBTOOL)
 102 ])