libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.64)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(browser-plugin,
  59   AS_HELP_STRING([--enable-browser-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) browser_plugin_enabled=yes ;;
  63       no)  browser_plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable browser plugin]);;
  65      esac],
  66     [browser_plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_WITH([antlr-jar],
  81             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  82             [
  83              ANTLR_JAR=$withval
  84             ],
  85             [
  86              ANTLR_JAR=
  87             ])
  88
  89 AC_MSG_CHECKING([for antlr.jar])
  90 if test "x$ANTLR_JAR" = x; then
  91     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  92         /usr/share/antlr/lib /usr/share/java /usr/lib;
  93     do
  94         if test -f "$antlr_lib_home/antlr.jar"; then
  95             # FIXME: version check for antlr needed without using a VM
  96             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  97             break
  98         fi
  99     done
 100     if test "x$ANTLR_JAR" = x; then
 101         AC_MSG_RESULT([not found])
 102     else
 103         AC_MSG_RESULT($ANTLR_JAR)
 104     fi
 105 else
 106     if test -f "${ANTLR_JAR}"; then
 107         AC_MSG_RESULT($ANTLR_JAR)
 108     else
 109         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 110     fi
 111 fi
 112 AC_SUBST(ANTLR_JAR)
 113
 114 AC_ARG_ENABLE([gjdoc],
 115               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 116               [case "${enableval}" in
 117                 yes) BUILD_GJDOC=yes ;;
 118                 no) BUILD_GJDOC=no ;;
 119                 *) BUILD_GJDOC=yes ;;
 120               esac],
 121               [BUILD_GJDOC=maybe])
 122
 123 AC_MSG_CHECKING([whether to build gjdoc])
 124 if test "x$BUILD_GJDOC" = xmaybe; then
 125     if test -f "${ANTLR_JAR}"; then
 126         BUILD_GJDOC=yes
 127         AC_MSG_RESULT(yes)
 128     else
 129         BUILD_GJDOC=no
 130         AC_MSG_RESULT([no, antlr.jar not found])
 131     fi
 132 else
 133     AC_MSG_RESULT($BUILD_GJDOC)
 134 fi
 135 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 136
 137 AC_ARG_ENABLE(java-maintainer-mode,
 138         AS_HELP_STRING([--enable-java-maintainer-mode],
 139         [allow rebuilding of .class and .h files]))
 140 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 141
 142 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 143 GCC_NO_EXECUTABLES
 144
 145 # For libstdc++-v3, -fno-builtin must be present here so that a
 146 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 147 # used in later tests.  This may not be necessary in libjava; I don't know.
 148 save_CXXFLAGS="$CXXFLAGS"
 149 CXXFLAGS="$CXXFLAGS -fno-builtin"
 150 AC_PROG_CC
 151 AC_PROG_CXX
 152 CXXFLAGS="$save_CXXFLAGS"
 153
 154 AM_INIT_AUTOMAKE([no-dist 1.9.0])
 155
 156 AC_CHECK_TOOL(AS, as)
 157 AC_CHECK_TOOL(LD, ld)
 158 AC_CHECK_TOOL(AR, ar)
 159 AC_CHECK_TOOL(RANLIB, ranlib, :)
 160 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 161 AC_PROG_AWK
 162 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 163 AC_PATH_PROG([ZIP], [zip], no)
 164 AC_PATH_PROG([UNZIP], [unzip], unzip)
 165
 166 # We need a jar that supports -@.  This is a GNU extension.
 167 if test "$JAR" != no; then
 168    rm -f config-test.jar
 169    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 170    if test -f config-test.jar; then
 171      rm -f config-test.jar
 172    else
 173      JAR=no
 174    fi
 175 fi
 176
 177 # Prefer the jar we found, but fall back to our jar script.
 178 if test "$JAR" = no; then
 179   if test "$ZIP" = no; then
 180     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 181   else
 182     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 183     JAR=`pwd`/scripts/jar
 184   fi
 185 fi
 186
 187 AC_PROG_INSTALL
 188
 189 AM_MAINTAINER_MODE
 190
 191 AC_EXEEXT
 192
 193 # configure.host sets the following important variables
 194 #       libgcj_cflags    - host specific C compiler flags
 195 #       libgcj_cxxflags  - host specific C++ compiler flags
 196 #       libgcj_javaflags - host specific Java compiler flags
 197 #       libgcj_sublib_ltflags - host specific Libtool flags
 198 #       libgcj_sublib_core_extra_deps - host specific extra
 199 #                          dependencies for core sublib
 200 #       (these last two only used when building sublibs)
 201 # and a number of others; see the list at the start of the file.
 202
 203 libgcj_cflags=
 204 libgcj_cxxflags=
 205 libgcj_javaflags=
 206 libgcj_sublib_ltflags=
 207 libgcj_sublib_core_extra_deps=
 208
 209 . ${srcdir}/configure.host
 210
 211 ACX_PROG_LD_GNU_SYMBOLIC
 212 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 213 if test -z "$libgcj_ld_symbolic"; then
 214   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 215 fi
 216
 217 LIBGCJ_CFLAGS="${libgcj_cflags}"
 218 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 219 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 220 LIBGCJ_SUBLIB_LTFLAGS="${libgcj_sublib_ltflags}"
 221 LIBGCJ_SUBLIB_CORE_EXTRA_DEPS="${libgcj_sublib_core_extra_deps}"
 222 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 223 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 224 AC_SUBST(LIBGCJ_CFLAGS)
 225 AC_SUBST(LIBGCJ_CXXFLAGS)
 226 AC_SUBST(LIBGCJ_JAVAFLAGS)
 227 AC_SUBST(LIBGCJ_SUBLIB_LTFLAGS)
 228 AC_SUBST(LIBGCJ_SUBLIB_CORE_EXTRA_DEPS)
 229 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 230 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 231
 232 # Only use libltdl for non-newlib builds.
 233 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 234    AC_LTDL_SHLIBPATH
 235 fi
 236
 237 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 238
 239 # Possibly build libgcj as many sub-libraries.
 240 AC_ARG_ENABLE(libgcj-sublibs,
 241   AS_HELP_STRING([--enable-libgcj-sublibs],
 242                  [build libgcj as many sub-libraries]))
 243
 244 if test -z "$enable_libgcj_sublibs"; then
 245    enable_libgcj_sublibs=$enable_libgcj_sublibs_default
 246 fi
 247 AM_CONDITIONAL(BUILD_SUBLIBS, test "$enable_libgcj_sublibs" = yes)
 248 if test "$enable_libgcj_sublibs" = yes ; then
 249   # In theory we could make do with only one override and simply
 250   # tag "_bc" onto the end of it when we use it to generate the
 251   # spec, but that's an ugly thing to do when there are multiple
 252   # words in the string and you're relying on the ordering to
 253   # append the correct one.
 254   libgcj_spec_lgcj_override="-lgcj-noncore -lgcj"
 255   libgcj_spec_lgcj_bc_override="-lgcj-noncore -lgcj_bc"
 256 fi
 257
 258
 259 # See if the user has requested runtime debugging.
 260 LIBGCJDEBUG="disable"
 261 AC_SUBST(LIBGCJDEBUG)
 262 AC_ARG_ENABLE(libgcj-debug,
 263   AS_HELP_STRING([--enable-libgcj-debug],
 264                  [enable runtime debugging code]),
 265   [if test "$enable_libgcj_debug" = yes; then
 266     AC_DEFINE(__GCJ_DEBUG, 1, [Define this if you want runtime debugging enabled.])
 267     LIBGCJDEBUG="enable"
 268   fi])
 269
 270 AC_ARG_WITH([escher],
 271          AS_HELP_STRING([--with-escher=ABS.PATH],
 272                         [specify path to escher dir or JAR for X peers]))
 273 case "$with_escher" in
 274 "")
 275         use_escher=false
 276         ;;
 277 "no")
 278         use_escher=false
 279         ;;
 280 "yes")
 281         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 282         ;;
 283 *)
 284         use_escher=true
 285         ;;
 286 esac
 287
 288 # Determine which AWT peer libraries to build
 289 AC_ARG_ENABLE(java-awt,
 290   AS_HELP_STRING([--enable-java-awt],
 291                  [list of AWT peer implementations to be built]))
 292
 293 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 294 use_xlib_awt=""
 295 use_gtk_awt=""
 296 use_qt_awt=""
 297 use_x_awt=""
 298 # The default toolkit to use is the first one specified.
 299 TOOLKIT=
 300 AC_SUBST(TOOLKIT)
 301
 302 for peer in $peerlibs ; do
 303   case $peer in
 304     xlib)
 305       if test "$no_x" = yes; then
 306         echo "*** xlib peers requested but no X library available" 1>&2
 307         exit 1
 308       else
 309         use_xlib_awt="yes"
 310         if test -z "$TOOLKIT"; then
 311            TOOLKIT=gnu.awt.xlib.XToolkit
 312         fi
 313       fi
 314       ;;
 315     gtk)
 316       if test "$no_x" = yes; then
 317          echo "*** gtk peers requested but no X library available" 1>&2
 318          exit 1
 319       else
 320          use_gtk_awt=yes
 321          if test -z "$TOOLKIT"; then
 322             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 323          fi
 324       fi
 325       ;;
 326     qt)
 327       if test "$no_x" = yes; then
 328          # Perhaps we should admit the possibility of embedded Qt.
 329          echo "*** Qt peers requested but no X library available" 1>&2
 330          exit 1
 331       else
 332          use_qt_awt=yes
 333          if test -z "$TOOLKIT"; then
 334             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 335          fi
 336       fi
 337       ;;
 338     x)
 339       use_x_awt=yes
 340       if test -z "$TOOLKIT"; then
 341          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 342       fi
 343       ;;
 344     no)
 345       use_xlib_awt=
 346       use_gtk_awt=
 347       use_qt_awt=
 348       use_x_awt=
 349       break
 350       ;;
 351     *)
 352       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 353       exit 1
 354   esac
 355 done
 356
 357 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 358 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 359
 360 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 361
 362 expanded_prefix=$prefix
 363 if test "X$prefix" = XNONE; then
 364   expanded_prefix=${ac_default_prefix}
 365 fi
 366
 367 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$expanded_prefix", [Installation prefix])
 368
 369 # Create standard.omit based on decisions we just made.
 370 cp $srcdir/standard.omit.in standard.omit
 371 if test "$use_xlib_awt" != yes; then
 372    echo gnu/awt/xlib >> standard.omit
 373    echo gnu/gcj/xlib >> standard.omit
 374 fi
 375 if test "$use_x_awt" != yes; then
 376    echo gnu/java/awt/peer/x >> standard.omit
 377 fi
 378
 379 # Tools that need to be compiled against classpath's tools classes
 380 : > vm-tools-packages
 381 for package in gnu/gcj/tools/gc_analyze ; do
 382     echo $package >> standard.omit
 383     echo $package >> vm-tools-packages
 384 done
 385
 386 if test -z "${with_multisubdir}"; then
 387    builddotdot=.
 388 else
 389    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 390 fi
 391
 392 NATIVE=yes
 393
 394 # Which gcj and host gcj (for ecjx) do we use?
 395 which_gcj=default
 396 host_exeext=${ac_exeext}
 397 GCJ_FOR_ECJX='$(GCJ)'
 398 GCC_FOR_ECJX='$(CXX)'
 399 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 400 if test -n "${with_cross_host}"; then
 401   # We are being configured with a cross compiler. We can't
 402   # use ac_exeext, because that is for the target platform.
 403   NATIVE=no
 404   cross_host_exeext=
 405   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 406   GCC_FOR_ECJX="${with_cross_host}-gcc"
 407   case "${with_cross_host}" in
 408      *mingw* | *cygwin*)
 409          cross_host_exeext=.exe
 410      ;;
 411   esac
 412   host_exeext=${cross_host_exeext}
 413   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 414      if test x"$build_noncanonical" = x"$with_cross_host"; then
 415         # Ordinary cross (host!=target and host=build)
 416         which_gcj=built
 417      else
 418         # Canadian cross (host!=target and host!=build)
 419         which_gcj=cross
 420      fi
 421   else
 422      which_gcj=cross
 423   fi
 424 else
 425   # We are being configured with a native or crossed-native compiler
 426   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 427      if test x"$build" = x"$host"; then
 428         # True native build (host=target and host=build)
 429         which_gcj=built
 430      else
 431         # Crossed-native build (host=target and host!=build)
 432         which_gcj=cross
 433      fi
 434   else
 435      which_gcj=path
 436   fi
 437 fi
 438 libgcjdir=`${PWDCMD-pwd}`
 439 case $GCJ in
 440 *" -B"*)
 441   # Just in case there is a comma in the build dir, quote it for the
 442   # sed command below.
 443   case $libgcjdir in
 444   *[[,\\]]*) qlibgcjdir=`echo "$libgcjdir" | sed 's:[[,\\]]:\\&:g'`;;
 445   *) qlibgcjdir=$libgcjdir;;
 446   esac
 447   GCJ=`echo "$GCJ" | sed "s, -B, -B$qlibgcjdir/&,"`
 448   ;;
 449 *)
 450   GCJ=$GCJ" -B$libgcjdir/"
 451   ;;
 452 esac
 453 case "${which_gcj}" in
 454    built)
 455       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 456    ;;
 457    cross)
 458       if test "x${with_newlib}" = "xyes"; then
 459          # FIXME (comment): Why is this needed?
 460          GCC_UNWIND_INCLUDE=
 461       fi
 462       GCJH='$(target_noncanonical)-gcjh'
 463    ;;
 464    path)
 465       GCJH=gcjh
 466    ;;
 467 esac
 468 JAVAC="$GCJ -C"
 469 export JAVAC
 470
 471 AC_SUBST(GCJ_FOR_ECJX)
 472 AC_SUBST(GCC_FOR_ECJX)
 473 AC_SUBST(GCJH)
 474 AC_SUBST(host_exeext)
 475
 476 # Create it, so that compile/link tests don't fail
 477 test -f libgcj.spec || touch libgcj.spec
 478
 479
 480
 481 # Set up to configure Classpath.
 482 # FIXME: no supported way to pass args in autoconf.
 483 # Disable tool wrappers to avoid ltdl.h configure check.
 484 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 485 ac_configure_args="$ac_configure_args --disable-load-library"
 486 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 487 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 488 dir1=`cd $srcdir && pwd`
 489 dir2=`pwd`
 490 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 491 ac_configure_args="$ac_configure_args --disable-core-jni"
 492 dnl FIXME?
 493 ac_configure_args="$ac_configure_args --disable-examples"
 494 ac_configure_args="$ac_configure_args --with-glibj=build"
 495 if test "$browser_plugin_enabled" != yes; then
 496   ac_configure_args="$ac_configure_args --disable-plugin"
 497 else
 498   ac_configure_args="$ac_configure_args --enable-plugin"
 499 fi
 500 if test "$gconf_enabled" != yes; then
 501   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 502   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 503 fi
 504 if test "$use_gtk_awt" != yes; then
 505   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 506 fi
 507 if test "$use_qt_awt" != yes; then
 508   ac_configure_args="$ac_configure_args --disable-qt-peer"
 509 else
 510   # We need this as qt is disabled by default in classpath.
 511   ac_configure_args="$ac_configure_args --enable-qt-peer"
 512 fi
 513 if test "$use_x_awt" != yes; then
 514   ac_configure_args="$ac_configure_args --without-escher"
 515 else
 516   # We need this as escher is disabled by default in classpath.
 517   if test "$use_escher" != true; then
 518     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 519   else
 520     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 521   fi
 522 fi
 523 if test "x$BUILD_GJDOC" = xno; then
 524   ac_configure_args="$ac_configure_args --disable-gjdoc"
 525 fi
 526 # -Werror causes unavoidable problems in code using alsa.
 527 ac_configure_args="$ac_configure_args --disable-regen-headers"
 528 ac_configure_args="$ac_configure_args --disable-Werror"
 529 dnl --with-gcj=$GCJ
 530 dnl --with-javah=$GCJH
 531 dnl gtk-cairo -- just export here...
 532 dnl --enable-regen-headers?
 533
 534 # Only use libltdl for non-newlib builds.
 535 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 536    AC_LIBLTDL_CONVENIENCE
 537    AC_LIBTOOL_DLOPEN
 538    DIRLTDL=libltdl
 539    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 540    # Sigh.  Libtool's macro doesn't do the right thing.
 541    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 542    # FIXME: this is a hack.
 543    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 544    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 545 fi
 546 AC_SUBST(INCLTDL)
 547 AC_SUBST(LIBLTDL)
 548 AC_SUBST(DIRLTDL)
 549 AC_PROG_LIBTOOL
 550 ACX_LT_HOST_FLAGS
 551 AM_PROG_GCJ
 552 AM_PROG_CC_C_O
 553
 554 AC_CONFIG_SUBDIRS(classpath libltdl)
 555
 556 # The -no-testsuite modules omit the test subdir.
 557 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 558
 559 # Should the runtime set system properties by examining the
 560 # environment variable GCJ_PROPERTIES?
 561 AC_ARG_ENABLE(getenv-properties,
 562   AS_HELP_STRING([--disable-getenv-properties],
 563                  [don't set system properties from GCJ_PROPERTIES]))
 564
 565 # Whether GCJ_PROPERTIES is used depends on the target.
 566 if test -z "$enable_getenv_properties"; then
 567    enable_getenv_properties=${enable_getenv_properties_default-yes}
 568 fi
 569 if test "$enable_getenv_properties" = no; then
 570    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 571      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 572 fi
 573
 574 # Whether we should use arguments to main()
 575 if test -z "$enable_main_args"; then
 576    enable_main_args=${enable_main_args_default-yes}
 577 fi
 578 if test "$enable_main_args" = no; then
 579    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 580 fi
 581
 582
 583 # Should we use hashtable-based synchronization?
 584 # Currently works only for Linux X86/ia64
 585 # Typically faster and more space-efficient
 586 AC_ARG_ENABLE(hash-synchronization,
 587   AS_HELP_STRING([--enable-hash-synchronization],
 588                  [use global hash table for monitor locks]))
 589
 590 if test -z "$enable_hash_synchronization"; then
 591    enable_hash_synchronization=$enable_hash_synchronization_default
 592 fi
 593
 594
 595 install_ecj_jar=no
 596 ECJ_BUILD_JAR=
 597 ECJ_JAR=
 598 AC_ARG_WITH(ecj-jar,
 599         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 600         [ECJ_JAR=$withval],
 601         [if test -f $multi_basedir/ecj.jar; then
 602            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 603            ECJ_JAR='$(jardir)/ecj.jar'
 604            install_ecj_jar=yes
 605          fi])
 606 AC_SUBST(ECJ_BUILD_JAR)
 607 AC_SUBST(ECJ_JAR)
 608 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 609 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 610
 611 AC_ARG_WITH(java-home,
 612   AS_HELP_STRING([--with-java-home=DIRECTORY],
 613                  [value of java.home system property]),
 614                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 615 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 616 AC_SUBST(JAVA_HOME)
 617
 618 suppress_libgcj_bc=no
 619 AC_ARG_ENABLE(libgcj-bc,
 620   AS_HELP_STRING([--enable-libgcj-bc],
 621                  [enable(default) or disable BC ABI for portions of libgcj]),
 622   [if test "$enable_libgcj_bc" = "no"; then
 623      suppress_libgcj_bc=yes
 624    fi])
 625 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 626
 627 build_libgcj_reduced_reflection=no
 628 AC_ARG_ENABLE(reduced-reflection,
 629   AS_HELP_STRING([--enable-reduced-reflection],
 630                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 631   [if test "$enable_reduced_reflection" = "yes"; then
 632      build_libgcj_reduced_reflection=yes
 633    fi])
 634 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 635
 636 # What is the native OS API for MinGW?
 637 AC_ARG_WITH(win32-nlsapi,
 638   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 639                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 640 [case "${withval}" in
 641   ansi) with_win32_nlsapi=ansi ;;
 642   unicows) with_win32_nlsapi=unicows ;;
 643   unicode) with_win32_nlsapi=unicode ;;
 644   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 645 esac],[with_win32_nlsapi=ansi])
 646
 647 case "${with_win32_nlsapi}" in
 648   unicows | unicode)
 649     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 650       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 651     ;;
 652 esac
 653
 654 # configure.host sets slow_pthread_self if the synchronization code should
 655 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 656 if test "${slow_pthread_self}" = "yes"; then
 657   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 658     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 659 fi
 660
 661 # Check for gc debugging.  This option is handled both here and in the GC.
 662 AC_ARG_ENABLE(gc-debug,
 663    AS_HELP_STRING([--enable-gc-debug],
 664                   [include full support for pointer backtracing etc.]),
 665 [ if test "$enable_gc_debug" = "yes"; then
 666     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 667               [Define if we want to use debug calls into the garbage collector.])
 668   fi])
 669
 670 # See if the user has the interpreter included.
 671 AC_ARG_ENABLE(interpreter,
 672   AS_HELP_STRING([--enable-interpreter],
 673                  [enable interpreter]),
 674   [if test "$enable_interpreter" = yes; then
 675     # This can also be set in configure.host.
 676     libgcj_interpreter=yes
 677   elif test "$enable_interpreter" = no; then
 678     libgcj_interpreter=no
 679   fi])
 680
 681 if test "$libgcj_interpreter" = yes; then
 682    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 683 fi
 684 INTERPRETER="$libgcj_interpreter"
 685 AC_SUBST(INTERPRETER)
 686 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 687
 688 AC_MSG_CHECKING([for exception model to use])
 689 AC_LANG_PUSH(C++)
 690 AC_ARG_ENABLE(sjlj-exceptions,
 691   AS_HELP_STRING([--enable-sjlj-exceptions],
 692                  [force use of builtin_setjmp for exceptions]),
 693 [:],
 694 [dnl Botheration.  Now we've got to detect the exception model.
 695 dnl Link tests against libgcc.a are problematic since -- at least
 696 dnl as of this writing -- we've not been given proper -L bits for
 697 dnl single-tree newlib and libgloss.
 698 dnl
 699 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 700 dnl conftest files before we got a change to grep them first.
 701 cat > conftest.$ac_ext << EOF
 702 [#]line __oline__ "configure"
 703 struct S { ~S(); };
 704 void bar();
 705 void foo()
 706 {
 707   S s;
 708   bar();
 709 }
 710 EOF
 711 old_CXXFLAGS="$CXXFLAGS"
 712 CXXFLAGS=-S
 713 if AC_TRY_EVAL(ac_compile); then
 714   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 715     enable_sjlj_exceptions=yes
 716   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 717     enable_sjlj_exceptions=no
 718   elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
 719     # ARM EH ABI.
 720     enable_sjlj_exceptions=no
 721   fi
 722 fi
 723 CXXFLAGS="$old_CXXFLAGS"
 724 rm -f conftest*])
 725 if test x$enable_sjlj_exceptions = xyes; then
 726   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 727         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 728   ac_exception_model_name=sjlj
 729 elif test x$enable_sjlj_exceptions = xno; then
 730   ac_exception_model_name="call frame"
 731 else
 732   AC_MSG_ERROR([unable to detect exception model])
 733 fi
 734 AC_LANG_POP(C++)
 735 AC_MSG_RESULT($ac_exception_model_name)
 736
 737 # If we are non using SJLJ exceptions, and this host does not have support
 738 # for unwinding from a signal handler, enable checked dereferences and divides.
 739 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 740   CHECKREFSPEC=-fcheck-references
 741   DIVIDESPEC=-fuse-divide-subroutine
 742   EXCEPTIONSPEC=
 743 fi
 744
 745 # See if the user wants to disable java.net.  This is the mildly
 746 # ugly way that we admit that target-side configuration sucks.
 747 AC_ARG_ENABLE(java-net,
 748   AS_HELP_STRING([--disable-java-net],
 749                  [disable java.net]))
 750
 751 # Whether java.net is built by default can depend on the target.
 752 if test -z "$enable_java_net"; then
 753    enable_java_net=${enable_java_net_default-yes}
 754 fi
 755 if test "$enable_java_net" = no; then
 756    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 757 fi
 758
 759 # See if the user wants to configure without libffi.  Some
 760 # architectures don't support it, and default values are set in
 761 # configure.host.
 762 AC_ARG_WITH(libffi,
 763   AS_HELP_STRING([--without-libffi],
 764                  [don't use libffi]),
 765   [:],
 766   [with_libffi=${with_libffi_default-yes}])
 767
 768 LIBFFI=
 769 LIBFFIINCS=
 770 if test "$with_libffi" != no; then
 771    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 772    LIBFFI=../libffi/libffi_convenience.la
 773    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 774 fi
 775 AC_SUBST(LIBFFI)
 776 AC_SUBST(LIBFFIINCS)
 777
 778 # See if the user wants to disable JVMPI support.
 779 AC_ARG_ENABLE(jvmpi,
 780   AS_HELP_STRING([--disable-jvmpi],
 781                  [disable JVMPI support]))
 782
 783 if test "$enable_jvmpi" != no; then
 784     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 785 fi
 786
 787 # If the target is an eCos system, use the appropriate eCos
 788 # I/O routines.
 789 # FIXME: this should not be a local option but a global target
 790 # system; at present there is no eCos target.
 791 TARGET_ECOS=${PROCESS-"no"}
 792 AC_ARG_WITH(ecos,
 793 [  --with-ecos             enable runtime eCos target support],
 794 TARGET_ECOS="$with_ecos"
 795 )
 796
 797 case "$TARGET_ECOS" in
 798    no) case "$host" in
 799       *mingw*)
 800             PLATFORM=Win32
 801             PLATFORMNET=Win32
 802             PLATFORMH=win32.h
 803         CHECK_FOR_BROKEN_MINGW_LD
 804       ;;
 805       *)
 806             PLATFORM=Posix
 807             PLATFORMNET=Posix
 808             PLATFORMH=posix.h
 809       ;;
 810       esac
 811       ;;
 812    *)
 813       PLATFORM=Ecos
 814       PLATFORMNET=NoNet
 815       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 816       PLATFORMH=posix.h
 817       ;;
 818 esac
 819 AC_SUBST(PLATFORM)
 820 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 821
 822 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 823                                       [Define if you have int32_t and uint32_t.]))
 824 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 825                                         [Define if you have int32_t and uint32_t.]))
 826 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 827                                           [Define if you have u_int32_t]))
 828 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 829                                            [Define if you have u_int32_t]))
 830
 831 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 832 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 833
 834 case "$host" in
 835   *-darwin*) DARWIN_CRT=true ;;
 836   *) DARWIN_CRT=false ;;
 837 esac
 838 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 839
 840 # This may not be defined in a non-ANS conformant embedded system.
 841 # FIXME: Should these case a runtime exception in that case?
 842 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 843                                   [Define is you have 'localtime' in <time.h>]))
 844
 845 # Create the subdirectory for natFile.cc, or the attempt
 846 # to create the link will fail.
 847 test -d java || mkdir java
 848 test -d java/io || mkdir java/io
 849 test -d gnu || mkdir gnu
 850 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 851
 852 # Likewise for natConcreteProcess.cc.
 853 test -d java/lang || mkdir java/lang
 854 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 855
 856 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 857 test -d java/net || mkdir java/net
 858 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 859 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 860
 861 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 862 test -d gnu/java || mkdir gnu/java
 863 test -d gnu/java/net || mkdir gnu/java/net
 864 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 865 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 866
 867 # Likewise for natVMPipe.cc and natVMSelector.cc.
 868 test -d gnu/java/nio || mkdir gnu/java/nio
 869 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 870 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 871
 872 # Likewise for natFileChannelImpl.cc
 873 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 874 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 875
 876 # Likewise for natVMSecureRandom.cc
 877 test -d gnu/java/security || mkdir gnu/java/security
 878 test -d gnu/java/security/jce || mkdir gnu/java/security/jce
 879 test -d gnu/java/security/jce/prng || mkdir gnu/java/security/jce/prng
 880 AC_CONFIG_LINKS(gnu/java/security/jce/prng/natVMSecureRandom.cc:gnu/java/security/jce/prng/natVMSecureRandom${FILE-${PLATFORM}}.cc)
 881
 882 case "${host}" in
 883     *mingw*)
 884       SYSTEMSPEC="-lgdi32 -lws2_32"
 885       if test "${with_win32_nlsapi}" = "unicows"; then
 886         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 887       fi
 888     ;;
 889     *-*-darwin[[912]]*)
 890       SYSTEMSPEC="%{!Zdynamiclib:%{!Zbundle:-allow_stack_execute}}"
 891     ;;
 892     *)
 893       SYSTEMSPEC=
 894     ;;
 895 esac
 896 AC_SUBST(SYSTEMSPEC)
 897
 898 AC_ARG_WITH(system-zlib,
 899   AS_HELP_STRING([--with-system-zlib],
 900                  [use installed libz]))
 901 ZLIBSPEC=
 902 AC_SUBST(ZLIBSPEC)
 903 ZLIBTESTSPEC=
 904 AC_SUBST(ZLIBTESTSPEC)
 905
 906 AC_PATH_XTRA
 907
 908 # FIXME: this should be _libs on some hosts.
 909 libsubdir=.libs
 910
 911 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 912
 913 LIBSTDCXXSPEC=
 914 # extra LD Flags which are required for targets
 915 case "${host}" in
 916 *-*-darwin[[0-7]].*)
 917     # For now we have to disable it on darwin[8-9] because it slows down
 918     # the linking phase. A possible bug in ld?
 919     # on Darwin -single_module speeds up loading of the dynamic libraries.
 920     extra_ldflags_libjava=-Wl,-single_module
 921     ;;
 922 arm*linux*eabi)
 923     # Some of the ARM unwinder code is actually in libstdc++.  We
 924     # could in principle replicate it in libgcj, but it's better to
 925     # have a dependency on libstdc++.
 926     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 927     LIBSTDCXXSPEC=-lstdc++
 928     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 929     ;;
 930 *-*-cygwin)
 931     extra_ldflags_libjava=-liconv
 932     ;;
 933 esac
 934
 935 LIBMATHSPEC=
 936 # extra LD Flags which are required for targets
 937 case "${host}" in
 938 *-*-darwin*)
 939      ;;
 940 *)
 941      LIBMATHSPEC=-lm
 942      ;;
 943 esac
 944
 945 # Check for --no-merge-exidx-entries, an ARM-specific linker option.
 946 AC_CACHE_CHECK([for --no-merge-exidx-entries], [libgcj_cv_exidx],
 947   [saved_ldflags="$LDFLAGS"
 948    LDFLAGS="${LDFLAGS} -Wl,--no-merge-exidx-entries"
 949    # The IRIX 6 ld doesn't recognize --no-merge-exidx-entries, but only
 950    # warns about unknown options, which breaks the testsuite.  So enable
 951    # AC_LANG_WERROR, but there's currently (autoconf 2.64) no way to turn
 952    # it off again.  As a workaround, save and restore werror flag like
 953    # AC_PATH_XTRA.
 954    ac_xsave_[]_AC_LANG_ABBREV[]_werror_flag=$ac_[]_AC_LANG_ABBREV[]_werror_flag
 955    AC_LANG_WERROR
 956    AC_LINK_IFELSE([int main(void){ return 0;} ],
 957                       [eval "libgcj_cv_exidx=yes"],
 958                       [eval "libgcj_cv_exidx=no"])
 959    ac_[]_AC_LANG_ABBREV[]_werror_flag=$ac_xsave_[]_AC_LANG_ABBREV[]_werror_flag
 960    LDFLAGS="${saved_ldflags}"]
 961 )
 962 if test "${libgcj_cv_exidx}" = "yes"; then
 963   SYSTEMSPEC="${SYSTEMSPEC} --no-merge-exidx-entries"
 964   extra_ldflags="${extra_ldflags} -Wl,--no-merge-exidx-entries"
 965 fi
 966
 967 AC_SUBST(extra_ldflags_libjava)
 968 AC_SUBST(extra_ldflags)
 969 AC_SUBST(LIBSTDCXXSPEC)
 970 AC_SUBST(LIBMATHSPEC)
 971
 972 AC_SUBST(LIBGCJTESTSPEC)
 973
 974 # Allow the GC to be disabled.  Can be useful when debugging.
 975 AC_MSG_CHECKING([for garbage collector to use])
 976 AC_ARG_ENABLE(java-gc,
 977   AS_HELP_STRING([--enable-java-gc=TYPE],
 978                  [choose garbage collector (default is boehm)]),
 979   [GC=$enableval],
 980   [GC=boehm])
 981 GCLIBS=
 982 GCINCS=
 983 GCDEPS=
 984 GCSPEC=
 985 JC1GCSPEC=
 986 GCTESTSPEC=
 987 case "$GC" in
 988  boehm)
 989     AC_MSG_RESULT(boehm)
 990     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 991     JC1GCSPEC='-fuse-boehm-gc'
 992     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 993     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 994     GCOBJS=boehm.lo
 995     GCHDR=boehm-gc.h
 996     # The POSIX thread support needs to know this.
 997     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 998     ;;
 999  no)
1000     AC_MSG_RESULT(none)
1001     GCHDR=no-gc.h
1002     ;;
1003  *)
1004     AC_MSG_ERROR([unrecognized collector "$GC"])
1005     ;;
1006 esac
1007 AC_SUBST(GCLIBS)
1008 AC_SUBST(GCINCS)
1009 AC_SUBST(GCDEPS)
1010 AC_SUBST(GCSPEC)
1011 AC_SUBST(JC1GCSPEC)
1012 AC_SUBST(GCTESTSPEC)
1013 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
1014 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
1015 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
1016
1017
1018 AC_MSG_CHECKING([for thread model used by GCC])
1019 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
1020 AC_MSG_RESULT([$THREADS])
1021
1022 case "$THREADS" in
1023  no | none | single)
1024     THREADS=none
1025     ;;
1026  aix | posix | posix95 | pthreads)
1027     THREADS=posix
1028     case "$host" in
1029      *-*-linux*)
1030         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
1031         ;;
1032     esac
1033     ;;
1034  win32)
1035     ;;
1036  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
1037     AC_MSG_ERROR(thread package $THREADS not yet supported)
1038     ;;
1039  *)
1040     AC_MSG_ERROR($THREADS is an unknown thread package)
1041     ;;
1042 esac
1043
1044 THREADCXXFLAGS=
1045 THREADLDFLAGS=
1046 THREADLIBS=
1047 THREADINCS=
1048 THREADDEPS=
1049 THREADH=
1050 THREADSPEC=
1051 THREADSTARTFILESPEC=
1052 case "$THREADS" in
1053  posix)
1054     case "$host" in
1055      *-*-cygwin*)
1056         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
1057         ;;
1058      *-*-freebsd[[1234]]*)
1059         # Before FreeBSD 5, it didn't have -lpthread (or any library which
1060         # merely adds pthread_* functions) but it does have a -pthread switch
1061         # which is required at link-time to select -lc_r *instead* of -lc.
1062         THREADLDFLAGS=-pthread
1063         # Don't set THREADSPEC here as might be expected since -pthread is
1064         # not processed when found within a spec file, it must come from
1065         # the command line.  For now, the user must provide the -pthread
1066         # switch to link code compiled with gcj.  In future, consider adding
1067         # support for weak references to pthread_* functions ala gthr.h API.
1068         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
1069         ;;
1070      *-*-freebsd*)
1071         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
1072         # systems which support threads and -lpthread.
1073         THREADLDFLAGS=-pthread
1074         THREADSPEC=-lpthread
1075         ;;
1076      alpha*-dec-osf* | hppa*-hp-hpux*)
1077         THREADCXXFLAGS=-pthread
1078         # boehm-gc needs some functions from librt, so link that too.
1079         THREADLIBS='-lpthread -lrt'
1080         THREADSPEC='-lpthread -lrt'
1081         ;;
1082      *-*-solaris2.8)
1083         # Always use alternate thread library on Solaris 8.  Need libthread
1084         # for TLS support.
1085         # Need -Wl,-R to get it through libtool ...
1086         THREADLIBS='-L/usr/lib/lwp$(MULTISUBDIR) -Wl,-R -Wl,/usr/lib/lwp$(MULTISUBDIR) -lpthread -lthread'
1087         # ... while ld only accepts -R.
1088         THREADSPEC='-L/usr/lib/lwp%{m64:/64} -R/usr/lib/lwp%{m64:/64} -lpthread -lthread'
1089         ;;
1090      *-*-solaris2.9)
1091         # As on Solaris 8, need libthread for TLS support.
1092         THREADLIBS='-lpthread -lthread'
1093         THREADSPEC='-lpthread -lthread'
1094         ;;
1095      *-*-darwin*)
1096         # Don't set THREADLIBS or THREADSPEC as Darwin already
1097         # provides pthread via libSystem.
1098         ;;
1099      *)
1100         THREADLIBS=-lpthread
1101         THREADSPEC=-lpthread
1102         ;;
1103     esac
1104     THREADH=posix-threads.h
1105     # MIT pthreads doesn't seem to have the mutexattr functions.
1106     # But for now we don't check for it.  We just assume you aren't
1107     # using MIT pthreads.
1108     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1109
1110     # If we're using the Boehm GC, then we happen to know that it
1111     # defines _REENTRANT, so we don't bother.  Eww.
1112     if test "$GC" != boehm; then
1113        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1114     fi
1115     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1116     ;;
1117
1118  win32)
1119     THREADH=win32-threads.h
1120     THREADCXXFLAGS=-mthreads
1121     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1122     # But we do not want the executables created to be dependent on
1123     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1124     # exception handling contexts.  The following kludge achieves this effect
1125     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1126     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1127     # A workaround is to explicitly use -mthreads while linking Java programs.
1128     # See PR libgcj/28263.
1129     #
1130     # FIXME: In Java we are able to detect thread death at the end of
1131     # Thread.run() so we should be able to clean up the exception handling
1132     # contexts ourselves.
1133     THREADSTARTFILESPEC='crtmt%O%s'
1134     ;;
1135
1136  none)
1137     THREADH=no-threads.h
1138     ;;
1139 esac
1140 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1141 AC_SUBST(THREADLIBS)
1142 AC_SUBST(THREADINCS)
1143 AC_SUBST(THREADDEPS)
1144 AC_SUBST(THREADSPEC)
1145 AC_SUBST(THREADSTARTFILESPEC)
1146 AC_SUBST(THREADLDFLAGS)
1147 AC_SUBST(THREADCXXFLAGS)
1148 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1149 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1150 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1151 if test "$enable_shared" != yes; then
1152   use_libgcj_bc=no
1153 fi
1154 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1155
1156 if test -d sysdep; then true; else mkdir sysdep; fi
1157 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1158 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1159 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1160
1161 LIBGCJ_SPEC_LGCJ=-lgcj
1162 LIBGCJ_SPEC_LGCJ_BC=-lgcj_bc
1163 if test x"$libgcj_spec_lgcj_override" != x ; then
1164   LIBGCJ_SPEC_LGCJ=$libgcj_spec_lgcj_override
1165 fi
1166 if test x"$libgcj_spec_lgcj_bc_override" != x ; then
1167   LIBGCJ_SPEC_LGCJ_BC=$libgcj_spec_lgcj_bc_override
1168 fi
1169 LIBGCJ_SPEC="%{s-bc-abi:} $LIBGCJ_SPEC_LGCJ"
1170 if test "$use_libgcj_bc" = yes; then
1171   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:$LIBGCJ_SPEC_LGCJ;:$LIBGCJ_SPEC_LGCJ_BC}"
1172   LIBGCJ_BC_SPEC="%{findirect-dispatch:-fPIC}"
1173 fi
1174 AC_SUBST(LIBGCJ_SPEC)
1175 AC_SUBST(LIBGCJ_BC_SPEC)
1176
1177 HASH_SYNC_SPEC=
1178 # Hash synchronization is only useful with posix threads right now.
1179 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1180    HASH_SYNC_SPEC=-fhash-synchronization
1181    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1182 fi
1183 AC_SUBST(HASH_SYNC_SPEC)
1184
1185 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1186
1187 # We're in the tree with gcc, and need to include some of its headers.
1188 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1189
1190 if test "x${with_newlib}" = "xyes"; then
1191    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1192    # may not work correctly, because the compiler may not be able to
1193    # link executables.
1194
1195    # We assume newlib.  This lets us hard-code the functions we know
1196    # we'll have.
1197    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1198    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1199    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1200    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1201    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1202    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1203    # This is only for POSIX threads.
1204    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1205
1206    # Assume we do not have getuid and friends.
1207    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1208    PLATFORMNET=NoNet
1209 else
1210    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1211                    localtime_r getpwuid_r getcwd \
1212                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1213                    nl_langinfo setlocale \
1214                    inet_pton uname inet_ntoa \
1215                    getrlimit sigaction ftruncate mmap \
1216                    getifaddrs])
1217    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1218    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1219    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1220    AC_CHECK_LIB(dl, dladdr, [
1221        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1222        AC_CHECK_LIB(dld, dladdr, [
1223        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1224
1225    if test x"$cross_compiling" = x"no"; then
1226      AC_CHECK_FILES(/proc/self/exe, [
1227        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1228      AC_CHECK_FILES(/proc/self/maps, [
1229        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1230          [Define if you have /proc/self/maps])])
1231    else
1232      case $host in
1233      *-linux*)
1234        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1235        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1236        ;;
1237      esac
1238    fi
1239
1240    AM_ICONV
1241    AM_LC_MESSAGES
1242    AC_STRUCT_TIMEZONE
1243
1244    AC_CHECK_FUNCS(gethostbyname_r, [
1245      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1246        [Define if you have the 'gethostbyname_r' function.])
1247      # There are two different kinds of gethostbyname_r.
1248      # We look for the one that returns `int'.
1249      # Hopefully this check is robust enough.
1250      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1251        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1252
1253      case " $GCINCS " in
1254      *" -D_REENTRANT "*) ;;
1255      *)
1256         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1257         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1258         [libjava_cv_gethostbyname_r_needs_reentrant],
1259         [ AC_LANG_PUSH(C++)
1260           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1261             [[gethostbyname_r("", 0, 0);]])],
1262             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1263                 CPPFLAGS_SAVE="$CPPFLAGS"
1264                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1265                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1266                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1267                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1268                 CPPFLAGS="$CPPFLAGS_SAVE"
1269           ])
1270           AC_LANG_POP(C++)
1271         ])
1272         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1273           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1274         fi
1275      ;;
1276      esac
1277
1278      AC_CACHE_CHECK([for struct hostent_data],
1279         [libjava_cv_struct_hostent_data], [dnl
1280         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1281 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1282 # define _REENTRANT 1
1283 #endif
1284 #include <netdb.h>]], [[struct hostent_data data;]])],
1285           [libjava_cv_struct_hostent_data=yes],
1286           [libjava_cv_struct_hostent_data=no])])
1287      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1288        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1289          [Define if struct hostent_data is defined in netdb.h])
1290      fi
1291    ])
1292
1293    # FIXME: libjava source code expects to find a prototype for
1294    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1295    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1296    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1297    # linkage check is enough, yet C++ code requires proper prototypes.)
1298    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1299    AC_CHECK_FUNCS(gethostbyaddr_r, [
1300      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1301        [Define if you have the 'gethostbyaddr_r' function.])
1302      # There are two different kinds of gethostbyaddr_r.
1303      # We look for the one that returns `int'.
1304      # Hopefully this check is robust enough.
1305      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1306        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1307          [Define if gethostbyaddr_r returns 'int'.])])])])
1308
1309    AC_CHECK_FUNCS(gethostname, [
1310      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1311        [Define if you have the 'gethostname' function.])
1312      AC_EGREP_HEADER(gethostname, unistd.h, [
1313        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1314          [Define if gethostname is declared in <unistd.h>.])])])
1315
1316    AC_CHECK_FUNCS(usleep, [
1317      AC_EGREP_HEADER(usleep, unistd.h, [
1318        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1319           [Define if usleep is declared in <unistd.h>.])])])
1320
1321    # Look for these functions in the thread library, but only bother
1322    # if using POSIX threads.
1323    if test "$THREADS" = posix; then
1324       save_LIBS="$LIBS"
1325       LIBS="$LIBS $THREADLIBS"
1326
1327       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1328       # Solaris 7 the name librt is preferred.
1329       AC_CHECK_FUNCS(sched_yield, , [
1330         AC_CHECK_LIB(rt, sched_yield, [
1331           AC_DEFINE(HAVE_SCHED_YIELD)
1332           THREADLIBS="$THREADLIBS -lrt"
1333           THREADSPEC="$THREADSPEC -lrt"], [
1334           AC_CHECK_LIB(posix4, sched_yield, [
1335             AC_DEFINE(HAVE_SCHED_YIELD)
1336             THREADLIBS="$THREADLIBS -lposix4"
1337             THREADSPEC="$THREADSPEC -lposix4"])])])
1338
1339       AC_CHECK_LIB(rt, clock_gettime, [
1340          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1341          case "$THREADSPEC" in
1342            *-lrt*) ;;
1343            *)
1344              THREADSPEC="$THREADSPEC -lrt"
1345              THREADLIBS="$THREADLIBS -lrt"
1346              ;;
1347          esac])
1348
1349       LIBS="$save_LIBS"
1350
1351       # We can save a little space at runtime if the mutex has m_count
1352       # or __m_count.  This is a nice hack for Linux.
1353       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1354           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1355         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1356              [Define if pthread_mutex_t has m_count member.]), [
1357         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1358             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1359           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1360             [Define if pthread_mutex_t has __m_count member.]))])
1361    fi
1362
1363    # We require a way to get the time.
1364    time_found=no
1365    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1366    if test "$time_found" = no; then
1367       AC_MSG_ERROR([no function found to get the time])
1368    fi
1369
1370    AC_CHECK_FUNCS(memmove)
1371
1372    # We require memcpy.
1373    memcpy_found=no
1374    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1375    if test "$memcpy_found" = no; then
1376       AC_MSG_ERROR([memcpy is required])
1377    fi
1378    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1379    AC_CHECK_LIB(dl, dlopen, [
1380        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1381        AC_CHECK_LIB(dld, dlopen, [
1382        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1383
1384    # Some library-finding code we stole from Tcl.
1385    #--------------------------------------------------------------------
1386    #    Check for the existence of the -lsocket and -lnsl libraries.
1387    #    The order here is important, so that they end up in the right
1388    #    order in the command line generated by make.  Here are some
1389    #    special considerations:
1390    #    1. Use "connect" and "accept" to check for -lsocket, and
1391    #       "gethostbyname" to check for -lnsl.
1392    #    2. Use each function name only once:  can't redo a check because
1393    #       autoconf caches the results of the last check and won't redo it.
1394    #    3. Use -lnsl and -lsocket only if they supply procedures that
1395    #       aren't already present in the normal libraries.  This is because
1396    #       IRIX 5.2 has libraries, but they aren't needed and they're
1397    #       bogus:  they goof up name resolution if used.
1398    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1399    #       To get around this problem, check for both libraries together
1400    #       if -lsocket doesn't work by itself.
1401    #--------------------------------------------------------------------
1402
1403    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1404     [gcj_cv_lib_sockets=
1405      gcj_checkBoth=0
1406      unset ac_cv_func_connect
1407      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1408      if test "$gcj_checkSocket" = 1; then
1409          unset ac_cv_func_connect
1410          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1411                       gcj_checkBoth=1)
1412      fi
1413      if test "$gcj_checkBoth" = 1; then
1414          gcj_oldLibs=$LIBS
1415          LIBS="$LIBS -lsocket -lnsl"
1416          unset ac_cv_func_accept
1417          AC_CHECK_FUNC(accept,
1418                        [gcj_checkNsl=0
1419                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1420          unset ac_cv_func_accept
1421          LIBS=$gcj_oldLibs
1422      fi
1423      unset ac_cv_func_gethostbyname
1424      gcj_oldLibs=$LIBS
1425      LIBS="$LIBS $gcj_cv_lib_sockets"
1426      AC_CHECK_FUNC(gethostbyname, ,
1427                    [AC_CHECK_LIB(nsl, main,
1428                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1429      unset ac_cv_func_gethostbyname
1430      LIBS=$gcj_oldLIBS
1431    ])
1432    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1433
1434    if test "$with_system_zlib" = yes; then
1435       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1436    fi
1437
1438    # Test for Gtk stuff, if asked for.
1439    if test "$use_gtk_awt" = yes; then
1440       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1441       AC_SUBST(GTK_CFLAGS)
1442       AC_SUBST(GTK_LIBS)
1443
1444       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1445       AC_SUBST(GLIB_CFLAGS)
1446       AC_SUBST(GLIB_LIBS)
1447
1448       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1449       AC_SUBST(LIBART_CFLAGS)
1450       AC_SUBST(LIBART_LIBS)
1451
1452       # We require the XTest Extension to support java.awt.Robot.
1453       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1454                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1455                    [${X_LIBS}])
1456    fi
1457
1458    # On Solaris, and maybe other architectures, the Boehm collector
1459    # requires -ldl.
1460    if test "$GC" = boehm; then
1461       case "${host}" in
1462           mips-sgi-irix6*)
1463             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1464             # libgcj.spec is used, so override here
1465             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1466           ;;
1467           *-*-darwin*)
1468           ;;
1469           *)
1470             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1471           ;;
1472       esac
1473    fi
1474 fi
1475
1476 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1477 case $build in
1478     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1479     *)         CLASSPATH_SEPARATOR=':' ;;
1480 esac
1481 AC_SUBST(CLASSPATH_SEPARATOR)
1482
1483 # We must search the source tree for java.lang, since we still don't
1484 # have libgcj.jar nor java/lang/*.class
1485 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1486 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1487
1488 # Since some classes depend on this one, we need its source available
1489 # before we can do any GCJ compilation test :-(
1490 if test ! -f gnu/classpath/Configuration.java; then
1491   test -d gnu || mkdir gnu
1492   test -d gnu/classpath || mkdir gnu/classpath
1493   # Note that it is not crucial that all the values here be correct.
1494   sed -e "s,@prefix@,$expanded_prefix," \
1495       -e "s,@VERSION@,$VERSION," \
1496       -e "s,@LIBDEBUG@,false," \
1497       -e "s,@INIT_LOAD_LIBRARY@,false," \
1498       -e "s,@@,$LIBGCJDEBUG," \
1499       -e "s,@default_toolkit@,$TOOLKIT," \
1500       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1501       -e "s,@GTK_CAIRO_ENABLED@,false," \
1502       -e "s,@ECJ_JAR@,," \
1503       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1504         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1505         > gnu/classpath/Configuration.java
1506   # We do not want to redirect the output of the grep below to /dev/null,
1507   # but we add /dev/null to the input list so that grep will print the
1508   # filename of Configuration.java in case it finds any matches.
1509   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1510     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1511   fi
1512 fi
1513
1514 LT_AC_PROG_GCJ
1515
1516 # Now remove it.
1517 rm -f gnu/classpath/Configuration.java
1518
1519 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1520
1521 AC_CHECK_SIZEOF(void *)
1522
1523 AC_C_BIGENDIAN
1524
1525 ZLIBS=
1526 SYS_ZLIBS=
1527 ZINCS=
1528
1529 if test -z "$ZLIBSPEC"; then
1530    # Use zlib from the GCC tree.
1531    ZINCS='-I$(top_srcdir)/../zlib'
1532    ZLIBS=../zlib/libzgcj_convenience.la
1533 else
1534    # System's zlib.
1535    SYS_ZLIBS="$ZLIBSPEC"
1536 fi
1537 AC_SUBST(ZLIBS)
1538 AC_SUBST(SYS_ZLIBS)
1539 AC_SUBST(ZINCS)
1540 AC_SUBST(DIVIDESPEC)
1541 AC_SUBST(CHECKREFSPEC)
1542 AC_SUBST(EXCEPTIONSPEC)
1543 AC_SUBST(BACKTRACESPEC)
1544 AC_SUBST(IEEESPEC)
1545 AC_SUBST(ATOMICSPEC)
1546
1547 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1548 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1549 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1550 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1551 AC_SUBST(GCC_UNWIND_INCLUDE)
1552
1553 # Process the option "--enable-version-specific-runtime-libs"
1554 # Calculate toolexeclibdir
1555 case ${version_specific_libs} in
1556   yes)
1557     # Need the gcc compiler version to know where to install libraries
1558     # and header files if --enable-version-specific-runtime-libs option
1559     # is selected.
1560     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1561     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1562     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1563     toolexeclibdir=$toolexecmainlibdir
1564     ;;
1565   no)
1566     if test -n "$with_cross_host" &&
1567        test x"$with_cross_host" != x"no"; then
1568       # Install a library built with a cross compiler in tooldir, not libdir.
1569       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1570       toolexecmainlibdir='$(toolexecdir)/lib'
1571     else
1572       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1573       toolexecmainlibdir='$(libdir)'
1574     fi
1575     multi_os_directory=`$CC -print-multi-os-directory`
1576     case $multi_os_directory in
1577       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1578       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1579     esac
1580     ;;
1581 esac
1582 AC_SUBST(toolexecdir)
1583 AC_SUBST(toolexecmainlibdir)
1584 AC_SUBST(toolexeclibdir)
1585
1586 # Determine gcj and libgcj version number.
1587 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1588 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1589 GCJVERSION=$gcjversion
1590 AC_SUBST(GCJVERSION)
1591 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1592
1593 # Determine where the standard .db file and GNU Classpath JNI
1594 # libraries are found.
1595 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1596 multi_os_directory=`$CC -print-multi-os-directory`
1597 case $multi_os_directory in
1598   .)
1599    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1600    ;;
1601   *)
1602    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1603    ;;
1604 esac
1605 AC_SUBST(dbexecdir)
1606 AC_SUBST(gcjsubdir)
1607
1608 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1609 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1610
1611 TL_AC_GXX_INCLUDE_DIR
1612
1613 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1614 # On that system, sys/ioctl.h will not include sys/filio.h unless
1615 # BSD_COMP is defined; just including sys/filio.h is simpler.
1616 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1617 # for now.  If you change this, you also must update natFile.cc.
1618 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1619                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1620                   sys/socket.h netinet/in.h arpa/inet.h netdb.h \
1621                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1622                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1623
1624 # sys/socket.h is a prerequisite for net/if.h on Solaris.
1625 AC_CHECK_HEADERS(net/if.h, [], [], [
1626 #ifdef HAVE_SYS_SOCKET_H
1627 #include <sys/socket.h>
1628 #endif
1629 ])
1630
1631 AC_CHECK_HEADERS(inttypes.h, [
1632     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1633     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1634 ])
1635
1636 AC_CHECK_TYPE([ssize_t], [int])
1637 AC_CHECK_TYPE([magic_t], [
1638     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1639 #ifdef HAVE_MAGIC_H
1640 #include <magic.h>
1641 #endif])
1642
1643 AC_MSG_CHECKING([for in_addr_t])
1644 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1645 #if STDC_HEADERS
1646 #include <stdlib.h>
1647 #include <stddef.h>
1648 #endif
1649 #if HAVE_NETINET_IN_H
1650 #include <netinet/in.h>
1651 #endif]], [[in_addr_t foo;]])],
1652   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1653      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1654    AC_MSG_RESULT(yes)],
1655   [AC_MSG_RESULT(no)])
1656
1657 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1658 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1659   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1660      [Define if struct ip_mreq is defined in netinet/in.h.])
1661    AC_MSG_RESULT(yes)],
1662   [AC_MSG_RESULT(no)])
1663
1664 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1665 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1666   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1667      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1668    AC_MSG_RESULT(yes)],
1669   [AC_MSG_RESULT(no)])
1670
1671 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1672 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1673   [AC_DEFINE(HAVE_INET6, 1,
1674      [Define if inet6 structures are defined in netinet/in.h.])
1675    AC_MSG_RESULT(yes)],
1676   [AC_MSG_RESULT(no)])
1677
1678 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1679 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1680 #include <sys/types.h>
1681 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1682   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1683    AC_MSG_RESULT(yes)],
1684   [AC_MSG_RESULT(no)])
1685
1686 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1687 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1688   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1689    AC_MSG_RESULT(yes)],
1690   [AC_MSG_RESULT(no)
1691    AC_MSG_CHECKING([for global timezone variable])
1692    dnl FIXME: we don't want a link check here because that won't work
1693    dnl when cross-compiling.  So instead we make an assumption that
1694    dnl the header file will mention timezone if it exists.
1695    dnl Don't find the win32 function timezone
1696    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1697      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1698       AC_MSG_RESULT(yes)],
1699      [AC_MSG_RESULT(no)
1700        AC_MSG_CHECKING([for global _timezone variable])
1701        dnl FIXME: As above, don't want link check
1702        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1703          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1704             [Define if your platform has the global _timezone variable.])
1705           AC_MSG_RESULT(yes)],
1706           [AC_MSG_RESULT(no)])])])
1707
1708 AC_CHECK_PROGS(PERL, perl, false)
1709
1710 SYSDEP_SOURCES=
1711 SIGNAL_HANDLER_AUX=
1712
1713 case "${host}" in
1714  i?86-*-linux*)
1715     SIGNAL_HANDLER=include/i386-signal.h
1716     ;;
1717  *-*-solaris2*)
1718     SIGNAL_HANDLER=include/solaris-signal.h
1719     ;;
1720 # ia64-*)
1721 #    SYSDEP_SOURCES=sysdep/ia64.c
1722 #    test -d sysdep || mkdir sysdep
1723 #    ;;
1724  hppa*-*-linux*)
1725     SIGNAL_HANDLER=include/pa-signal.h
1726     ;;
1727  hppa*-hp-hpux*)
1728     SIGNAL_HANDLER=include/hppa-signal.h
1729     ;;
1730  ia64-*-linux*)
1731     SIGNAL_HANDLER=include/dwarf2-signal.h
1732     ;;
1733  powerpc*-*-linux*)
1734     SIGNAL_HANDLER=include/powerpc-signal.h
1735     ;;
1736  alpha*-*-linux*)
1737     SIGNAL_HANDLER=include/dwarf2-signal.h
1738     ;;
1739  s390*-*-linux*)
1740     SIGNAL_HANDLER=include/s390-signal.h
1741     ;;
1742  x86_64*-*-linux*)
1743     SIGNAL_HANDLER=include/x86_64-signal.h
1744     SIGNAL_HANDLER_AUX=include/i386-signal.h
1745     ;;
1746  sparc*-*-linux*)
1747     SIGNAL_HANDLER=include/dwarf2-signal.h
1748     ;;
1749  sh*-*-linux*)
1750     SIGNAL_HANDLER=include/sh-signal.h
1751     ;;
1752  *mingw*)
1753     SIGNAL_HANDLER=include/win32-signal.h
1754     ;;
1755  mips*-*-linux*)
1756     SIGNAL_HANDLER=include/mips-signal.h
1757     ;;
1758  m68*-*-linux*)
1759     SIGNAL_HANDLER=include/dwarf2-signal.h
1760     ;;
1761  powerpc*-*-darwin* | i?86-*-darwin[[912]]* | x86_64-*-darwin[[912]]*)
1762     SIGNAL_HANDLER=include/darwin-signal.h
1763     ;;
1764  powerpc*-*-aix*)
1765     SIGNAL_HANDLER=include/aix-signal.h
1766     ;;
1767  *)
1768     SIGNAL_HANDLER=include/default-signal.h
1769     ;;
1770 esac
1771
1772 # If we're using sjlj exceptions, forget what we just learned.
1773 if test "$enable_sjlj_exceptions" = yes; then
1774    SIGNAL_HANDLER=include/default-signal.h
1775    SIGNAL_HANDLER_AUX=
1776 fi
1777
1778 AC_SUBST(SYSDEP_SOURCES)
1779
1780 if test -z "$SIGNAL_HANDLER_AUX"; then
1781   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1782 fi
1783
1784 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1785                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1786
1787 if test "${multilib}" = "yes"; then
1788   multilib_arg="--enable-multilib"
1789 else
1790   multilib_arg=
1791 fi
1792
1793 # See if we support thread-local storage.
1794 GCC_CHECK_TLS
1795
1796 # For _Unwind_GetIPInfo.
1797 GCC_CHECK_UNWIND_GETIPINFO
1798
1799 # See if linker supports anonymous version scripts.
1800 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1801   [libjava_cv_anon_version_script],
1802   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1803    libjava_cv_anon_version_script=no
1804    CFLAGS="$CFLAGS -fPIC";
1805    LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1806    echo '{ global: globalsymb*; local: *; };' > conftest.map
1807    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1808                [libjava_cv_anon_version_script=gnu], [])
1809    if test x$libjava_cv_anon_version_script = xno; then
1810      case "$target_os" in
1811        solaris2*)
1812          LDFLAGS="$save_LDFLAGS"
1813          LDFLAGS="$LDFLAGS -shared -Wl,-M,conftest.map"
1814          # Sun ld doesn't understand wildcards here.
1815          echo '{ global: globalsymbol; local: *; };' > conftest.map
1816          AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1817                      [libjava_cv_anon_version_script=sun], [])
1818          ;;
1819      esac
1820    fi
1821    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1822   ])
1823 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" != no)
1824 AM_CONDITIONAL(ANONVERSCRIPT_GNU, test "$libjava_cv_anon_version_script" = gnu)
1825 AM_CONDITIONAL(ANONVERSCRIPT_SUN, test "$libjava_cv_anon_version_script" = sun)
1826
1827 # Check if linker supports static linking on a per library basis
1828 LD_START_STATIC_SPEC=
1829 LD_FINISH_STATIC_SPEC=
1830 if $LD --help 2>&1 | grep -- -call_shared >/dev/null 2>&1; then
1831   if $LD --help 2>&1 | grep -- -non_shared >/dev/null 2>&1; then
1832     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1833     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1834   fi
1835 fi
1836 AC_SUBST(LD_START_STATIC_SPEC)
1837 AC_SUBST(LD_FINISH_STATIC_SPEC)
1838
1839 here=`${PWDCMD-pwd}`
1840 AC_SUBST(here)
1841
1842 # We get this from the environment.
1843 AC_SUBST(GCJFLAGS)
1844
1845 AC_ARG_WITH([python-dir],
1846             AS_HELP_STRING([--with-python-dir],
1847                            [the location to install Python modules. This path should NOT include the prefix.]),
1848             [with_python_dir=$withval], [with_python_dir=""])
1849
1850 if test "x${with_python_dir}" = "x"
1851 then
1852   # Needed for installing Python modules during make install.
1853   python_mod_dir="\${prefix}/share/python"
1854   # Needed for substituting into aot-compile*
1855   python_mod_dir_expanded="${expanded_prefix}/share/python"
1856 else
1857   python_mod_dir="\${prefix}${with_python_dir}"
1858   python_mod_dir_expanded="${expanded_prefix}${with_python_dir}"
1859 fi
1860 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1861 AC_SUBST(python_mod_dir)
1862 AC_SUBST(python_mod_dir_expanded)
1863
1864 # needed for aot-compile-rpm
1865 MAKE=`which make`
1866 AC_SUBST(MAKE)
1867
1868 AC_ARG_ENABLE([aot-compile-rpm],
1869   [AS_HELP_STRING([--enable-aot-compile-rpm],
1870                  [enable installation of aot-compile-rpm [default=no]])],
1871   [case "${enableval}" in
1872     yes) AOT_RPM_ENABLED=yes ;;
1873     no)  AOT_RPM_ENABLED=no ;;
1874     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1875   esac],
1876   [AOT_RPM_ENABLED=no]
1877 )
1878 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1879
1880 AC_ARG_ENABLE([java-home],
1881   [AS_HELP_STRING([--enable-java-home],
1882                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1883   [case "${enableval}" in
1884     yes) JAVA_HOME_ENABLED=yes ;;
1885     no)  JAVA_HOME_ENABLED=no ;;
1886     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1887   esac],
1888   [JAVA_HOME_ENABLED=no]
1889 )
1890 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1891
1892 # Only do these checks if java-home above is enabled.
1893 if test "x${JAVA_HOME_ENABLED}" = xyes
1894 then
1895
1896   AC_ARG_WITH([gcc-suffix],
1897               AS_HELP_STRING([--with-gcc-suffix],
1898                              [the GCC tool suffix (defaults to empty string)]),
1899               [gcc_suffix=$withval], [gcc_suffix=""])
1900   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1901   AC_SUBST(gcc_suffix)
1902
1903   AC_ARG_WITH([arch-directory],
1904               AS_HELP_STRING([--with-arch-directory],
1905                              [the arch directory under jre/lib (defaults to auto-detect)]),
1906               [host_cpu=$withval], [host_cpu=""])
1907
1908   AC_ARG_WITH([os-directory],
1909               AS_HELP_STRING([--with-os-directory],
1910                              [the os directory under include (defaults to auto-detect)]),
1911               [host_os=$withval], [host_os=""])
1912
1913   AC_ARG_WITH([origin-name],
1914               AS_HELP_STRING([--with-origin-name],
1915                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1916               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1917   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1918
1919   AC_ARG_WITH([arch-suffix],
1920               AS_HELP_STRING([--with-arch-suffix],
1921                              [the arch directory suffix (default is the empty string]),
1922               [arch_suffix=$withval], [arch_suffix=""])
1923   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1924
1925   AC_ARG_WITH([jvm-root-dir],
1926               AS_HELP_STRING([--with-jvm-root-dir],
1927                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1928               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1929   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1930
1931   AC_ARG_WITH([jvm-jar-dir],
1932               AS_HELP_STRING([--with-jvm-jar-dir],
1933                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1934               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1935   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1936
1937   JAVA_VERSION=1.5.0
1938   BUILD_VERSION=0
1939   AC_SUBST(JAVA_VERSION)
1940   AC_SUBST(BUILD_VERSION)
1941   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1942
1943   jre_dir=jre
1944   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1945   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1946
1947   JVM_ROOT_DIR=${jvm_root_dir}
1948   AC_SUBST(JVM_ROOT_DIR)
1949   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1950
1951   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1952   AC_SUBST(JVM_JAR_ROOT_DIR)
1953   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1954
1955   JVM_JAR_DIR=${jvm_jar_dir}
1956   AC_SUBST(JVM_JAR_DIR)
1957   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1958
1959   JRE_DIR=${jre_dir}
1960   AC_SUBST(JRE_DIR)
1961
1962   JRE_LNK=${jre_lnk}
1963   AC_SUBST(JRE_LNK)
1964
1965   SDK_LNK=${sdk_lnk}
1966   AC_SUBST(SDK_LNK)
1967
1968   SDK_BIN_DIR=${jvm_root_dir}/bin
1969   AC_SUBST(SDK_BIN_DIR)
1970   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1971
1972   SDK_LIB_DIR=${jvm_root_dir}/lib
1973   AC_SUBST(SDK_LIB_DIR)
1974   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1975
1976   SDK_INCLUDE_DIR=${jvm_root_dir}/include
1977   AC_SUBST(SDK_INCLUDE_DIR)
1978   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1979
1980   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1981   AC_SUBST(JRE_BIN_DIR)
1982   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1983
1984   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1985   AC_SUBST(JRE_LIB_DIR)
1986   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
1987
1988   # Find gcj prefix using gcj found in PATH.
1989   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
1990
1991   # Where do the gcj binaries live?
1992   # For jhbuild based builds, they all live in a sibling of bin called
1993   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
1994   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
1995   AC_SUBST(GCJ_BIN_DIR)
1996   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
1997
1998   AC_MSG_RESULT(host is ${host})
1999   if test "x${host_cpu}" = "x"
2000   then
2001     case ${host} in
2002       *-mingw* | *-cygwin*)
2003         host_cpu=x86;;
2004       i486-* | i586-* | i686-*)
2005         host_cpu=i386;;
2006       x86_64-*)
2007         host_cpu=amd64;;
2008       *)
2009         host_cpu=${host_cpu};;
2010     esac
2011   fi
2012   AC_MSG_RESULT(arch directory: ${host_cpu})
2013   CPU=${host_cpu}
2014   AC_SUBST(CPU)
2015
2016   if test "x${host_os}" = "x"
2017   then
2018     case ${host} in
2019       *-mingw* | *-cygwin*)
2020         host_os=win32;;
2021       *-linux*)
2022         host_os=linux;;
2023       *)
2024         host_os=${host_os};;
2025     esac
2026   fi
2027   echo os directory: ${host_os}
2028   OS=${host_os}
2029   AC_SUBST(OS)
2030
2031   # make an expanded $libdir, for substituting into
2032   # scripts (and other non-Makefile things).
2033   LIBDIR=$libdir
2034   if test "x${exec_prefix}" = "xNONE"
2035   then
2036       lib_exec_prefix=$expanded_prefix
2037   else
2038       lib_exec_prefix=$exec_prefix
2039   fi
2040   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
2041   AC_SUBST(LIBDIR)
2042 fi
2043
2044 AC_CONFIG_FILES([
2045 Makefile
2046 libgcj.pc
2047 libgcj.spec
2048 libgcj-test.spec
2049 gcj/Makefile
2050 include/Makefile
2051 testsuite/Makefile
2052 contrib/aotcompile.py
2053 contrib/aot-compile
2054 contrib/aot-compile-rpm
2055 contrib/generate-cacerts.pl
2056 contrib/rebuild-gcj-db
2057 ])
2058
2059 if test ${multilib} = yes; then
2060   multilib_arg="--enable-multilib"
2061 else
2062   multilib_arg=
2063 fi
2064
2065 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
2066 AC_OUTPUT