libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(plugin,
  59   AS_HELP_STRING([--enable-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) plugin_enabled=yes ;;
  63       no)  plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  65      esac],
  66     [plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_WITH([antlr-jar],
  81             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  82             [
  83              ANTLR_JAR=$withval
  84             ],
  85             [
  86              ANTLR_JAR=
  87             ])
  88
  89 AC_MSG_CHECKING([for antlr.jar])
  90 if test "x$ANTLR_JAR" = x; then
  91     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  92         /usr/share/antlr/lib /usr/share/java /usr/lib;
  93     do
  94         if test -f "$antlr_lib_home/antlr.jar"; then
  95             # FIXME: version check for antlr needed without using a VM
  96             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  97             break
  98         fi
  99     done
 100     if test "x$ANTLR_JAR" = x; then
 101         AC_MSG_RESULT([not found])
 102     else
 103         AC_MSG_RESULT($ANTLR_JAR)
 104     fi
 105 else
 106     if test -f "${ANTLR_JAR}"; then
 107         AC_MSG_RESULT($ANTLR_JAR)
 108     else
 109         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 110     fi
 111 fi
 112 AC_SUBST(ANTLR_JAR)
 113
 114 AC_ARG_ENABLE([gjdoc],
 115               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 116               [case "${enableval}" in
 117                 yes) BUILD_GJDOC=yes ;;
 118                 no) BUILD_GJDOC=no ;;
 119                 *) BUILD_GJDOC=yes ;;
 120               esac],
 121               [BUILD_GJDOC=maybe])
 122
 123 AC_MSG_CHECKING([whether to build gjdoc])
 124 if test "x$BUILD_GJDOC" = xmaybe; then
 125     if test -f "${ANTLR_JAR}"; then
 126         BUILD_GJDOC=yes
 127         AC_MSG_RESULT(yes)
 128     else
 129         BUILD_GJDOC=no
 130         AC_MSG_RESULT([no, antlr.jar not found])
 131     fi
 132 else
 133     AC_MSG_RESULT($BUILD_GJDOC)
 134 fi
 135 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 136
 137 AC_ARG_ENABLE(java-maintainer-mode,
 138         AS_HELP_STRING([--enable-java-maintainer-mode],
 139         [allow rebuilding of .class and .h files]))
 140 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 141
 142 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 143 GCC_NO_EXECUTABLES
 144
 145 # (1) We use an abnormal CXX (without library references), so we
 146 # must cache it under a different name.
 147 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
 148 # the non-multilib-adjusted value will be used in multilibs.
 149 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
 150 # (4) As another side effect, automake doesn't automatically include them
 151 # in Makefile.in.
 152 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
 153 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 154 # used in later tests.  This may not be necessary in libjava; I don't know.
 155 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 156 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 157 save_CXXFLAGS="$CXXFLAGS"
 158 CXXFLAGS="$CXXFLAGS -fno-builtin"
 159 AC_PROG_CC
 160 AC_PROG_CXX
 161 CXXFLAGS="$save_CXXFLAGS"
 162 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 163 AC_SUBST(CFLAGS)
 164 AC_SUBST(CXXFLAGS)
 165 AC_SUBST(LDFLAGS)
 166
 167 AM_INIT_AUTOMAKE([1.9.0])
 168
 169 AC_CHECK_TOOL(AS, as)
 170 AC_CHECK_TOOL(LD, ld)
 171 AC_CHECK_TOOL(AR, ar)
 172 AC_CHECK_TOOL(RANLIB, ranlib, :)
 173 AC_PROG_AWK
 174 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 175 AC_PATH_PROG([ZIP], [zip], no)
 176 AC_PATH_PROG([UNZIP], [unzip], unzip)
 177
 178 # We need a jar that supports -@.  This is a GNU extension.
 179 if test "$JAR" != no; then
 180    rm -f config-test.jar
 181    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 182    if test -f config-test.jar; then
 183      rm -f config-test.jar
 184    else
 185      JAR=no
 186    fi
 187 fi
 188
 189 # Prefer the jar we found, but fall back to our jar script.
 190 if test "$JAR" = no; then
 191   if test "$ZIP" = no; then
 192     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 193   else
 194     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 195     JAR=`pwd`/scripts/jar
 196   fi
 197 fi
 198
 199 AC_PROG_INSTALL
 200
 201 AM_MAINTAINER_MODE
 202
 203 AC_EXEEXT
 204
 205 # configure.host sets the following important variables
 206 #       libgcj_cflags    - host specific C compiler flags
 207 #       libgcj_cxxflags  - host specific C++ compiler flags
 208 #       libgcj_javaflags - host specific Java compiler flags
 209
 210 libgcj_cflags=
 211 libgcj_cxxflags=
 212 libgcj_javaflags=
 213
 214 . ${srcdir}/configure.host
 215
 216 ACX_PROG_LD_GNU_SYMBOLIC
 217 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 218 if test -z "$libgcj_ld_symbolic"; then
 219   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 220 fi
 221
 222 LIBGCJ_CFLAGS="${libgcj_cflags}"
 223 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 224 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 225 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 226 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 227 AC_SUBST(LIBGCJ_CFLAGS)
 228 AC_SUBST(LIBGCJ_CXXFLAGS)
 229 AC_SUBST(LIBGCJ_JAVAFLAGS)
 230 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 231 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 232
 233 # Only use libltdl for non-newlib builds.
 234 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 235    AC_LTDL_SHLIBPATH
 236 fi
 237
 238 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 239
 240 # See if the user has requested runtime debugging.
 241 LIBGCJDEBUG="disable"
 242 AC_SUBST(LIBGCJDEBUG)
 243 AC_ARG_ENABLE(libgcj-debug,
 244   AS_HELP_STRING([--enable-libgcj-debug],
 245                  [enable runtime debugging code]),
 246   [if test "$enable_libgcj_debug" = yes; then
 247     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 248     LIBGCJDEBUG="enable"
 249   fi])
 250
 251 AC_ARG_WITH([escher],
 252          AS_HELP_STRING([--with-escher=ABS.PATH],
 253                         [specify path to escher dir or JAR for X peers]))
 254 case "$with_escher" in
 255 "")
 256         use_escher=false
 257         ;;
 258 "no")
 259         use_escher=false
 260         ;;
 261 "yes")
 262         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 263         ;;
 264 *)
 265         use_escher=true
 266         ;;
 267 esac
 268
 269 # Determine which AWT peer libraries to build
 270 AC_ARG_ENABLE(java-awt,
 271   AS_HELP_STRING([--enable-java-awt],
 272                  [list of AWT peer implementations to be built]))
 273
 274 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 275 use_xlib_awt=""
 276 use_gtk_awt=""
 277 use_qt_awt=""
 278 use_x_awt=""
 279 # The default toolkit to use is the first one specified.
 280 TOOLKIT=
 281 AC_SUBST(TOOLKIT)
 282
 283 for peer in $peerlibs ; do
 284   case $peer in
 285     xlib)
 286       if test "$no_x" = yes; then
 287         echo "*** xlib peers requested but no X library available" 1>&2
 288         exit 1
 289       else
 290         use_xlib_awt="yes"
 291         if test -z "$TOOLKIT"; then
 292            TOOLKIT=gnu.awt.xlib.XToolkit
 293         fi
 294       fi
 295       ;;
 296     gtk)
 297       if test "$no_x" = yes; then
 298          echo "*** gtk peers requested but no X library available" 1>&2
 299          exit 1
 300       else
 301          use_gtk_awt=yes
 302          if test -z "$TOOLKIT"; then
 303             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 304          fi
 305       fi
 306       ;;
 307     qt)
 308       if test "$no_x" = yes; then
 309          # Perhaps we should admit the possibility of embedded Qt.
 310          echo "*** Qt peers requested but no X library available" 1>&2
 311          exit 1
 312       else
 313          use_qt_awt=yes
 314          if test -z "$TOOLKIT"; then
 315             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 316          fi
 317       fi
 318       ;;
 319     x)
 320       use_x_awt=yes
 321       if test -z "$TOOLKIT"; then
 322          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 323       fi
 324       ;;
 325     no)
 326       use_xlib_awt=
 327       use_gtk_awt=
 328       use_qt_awt=
 329       use_x_awt=
 330       break
 331       ;;
 332     *)
 333       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 334       exit 1
 335   esac
 336 done
 337
 338 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 339 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 340
 341 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 342
 343 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
 344
 345 # Create standard.omit based on decisions we just made.
 346 cp $srcdir/standard.omit.in standard.omit
 347 if test "$use_xlib_awt" != yes; then
 348    echo gnu/awt/xlib >> standard.omit
 349    echo gnu/gcj/xlib >> standard.omit
 350 fi
 351 if test "$use_x_awt" != yes; then
 352    echo gnu/java/awt/peer/x >> standard.omit
 353 fi
 354
 355 # Tools that need to be compiled against classpath's tools classes
 356 : > vm-tools-packages
 357 for package in gnu/gcj/tools/gc_analyze ; do
 358     echo $package >> standard.omit
 359     echo $package >> vm-tools-packages
 360 done
 361
 362 if test -z "${with_multisubdir}"; then
 363    builddotdot=.
 364 else
 365    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 366 fi
 367
 368 NATIVE=yes
 369
 370 # Which gcj and host gcj (for ecjx) do we use?
 371 which_gcj=default
 372 host_exeext=${ac_exeext}
 373 GCJ_FOR_ECJX=
 374 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 375 if test -n "${with_cross_host}"; then
 376   # We are being configured with a cross compiler. We can't
 377   # use ac_exeext, because that is for the target platform.
 378   NATIVE=no
 379   cross_host_exeext=
 380   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 381   case "${with_cross_host}" in
 382      *mingw* | *cygwin*)
 383          cross_host_exeext=.exe
 384      ;;
 385   esac
 386   host_exeext=${cross_host_exeext}
 387   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 388      if test x"$build_noncanonical" = x"$with_cross_host"; then
 389         # Ordinary cross (host!=target and host=build)
 390         which_gcj=built
 391      else
 392         # Canadian cross (host!=target and host!=build)
 393         which_gcj=cross
 394      fi
 395   else
 396      which_gcj=cross
 397   fi
 398 else
 399   # We are being configured with a native or crossed-native compiler
 400   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 401      if test x"$build" = x"$host"; then
 402         # True native build (host=target and host=build)
 403         which_gcj=built
 404      else
 405         # Crossed-native build (host=target and host!=build)
 406         which_gcj=cross
 407      fi
 408   else
 409      which_gcj=path
 410   fi
 411 fi
 412 case "${which_gcj}" in
 413    built)
 414       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 415       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 416    ;;
 417    cross)
 418       if test "x${with_newlib}" = "xyes"; then
 419          # FIXME (comment): Why is this needed?
 420          GCC_UNWIND_INCLUDE=
 421          GCJ="${target_noncanonical}-gcj"
 422       else
 423          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 424       fi
 425       GCJH='$(target_noncanonical)-gcjh'
 426    ;;
 427    path)
 428       GCJ="gcj -B`${PWDCMD-pwd}`/"
 429       GCJH=gcjh
 430    ;;
 431 esac
 432 JAVAC="$GCJ -C"
 433 export JAVAC
 434
 435 AC_SUBST(GCJ_FOR_ECJX)
 436 AC_SUBST(GCJH)
 437 AC_SUBST(host_exeext)
 438
 439 # Create it, so that compile/link tests don't fail
 440 test -f libgcj.spec || touch libgcj.spec
 441
 442
 443
 444 # Set up to configure Classpath.
 445 # FIXME: no supported way to pass args in autoconf.
 446 # Disable tool wrappers to avoid ltdl.h configure check.
 447 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 448 ac_configure_args="$ac_configure_args --disable-load-library"
 449 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 450 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 451 dir1=`cd $srcdir && pwd`
 452 dir2=`pwd`
 453 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 454 ac_configure_args="$ac_configure_args --disable-core-jni"
 455 dnl FIXME?
 456 ac_configure_args="$ac_configure_args --disable-examples"
 457 ac_configure_args="$ac_configure_args --with-glibj=build"
 458 if test "$plugin_enabled" != yes; then
 459   ac_configure_args="$ac_configure_args --disable-plugin"
 460 fi
 461 if test "$gconf_enabled" != yes; then
 462   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 463   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 464 fi
 465 if test "$use_gtk_awt" != yes; then
 466   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 467 fi
 468 if test "$use_qt_awt" != yes; then
 469   ac_configure_args="$ac_configure_args --disable-qt-peer"
 470 else
 471   # We need this as qt is disabled by default in classpath.
 472   ac_configure_args="$ac_configure_args --enable-qt-peer"
 473 fi
 474 if test "$use_x_awt" != yes; then
 475   ac_configure_args="$ac_configure_args --without-escher"
 476 else
 477   # We need this as escher is disabled by default in classpath.
 478   if test "$use_escher" != true; then
 479     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 480   else
 481     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 482   fi
 483 fi
 484 if test "x$BUILD_GJDOC" = xno; then
 485   ac_configure_args="$ac_configure_args --disable-gjdoc"
 486 fi
 487 # -Werror causes unavoidable problems in code using alsa.
 488 ac_configure_args="$ac_configure_args --disable-regen-headers"
 489 ac_configure_args="$ac_configure_args --disable-Werror"
 490 dnl --with-gcj=$GCJ
 491 dnl --with-javah=$GCJH
 492 dnl gtk-cairo -- just export here...
 493 dnl --enable-regen-headers?
 494
 495 # Only use libltdl for non-newlib builds.
 496 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 497    AC_LIBLTDL_CONVENIENCE
 498    AC_LIBTOOL_DLOPEN
 499    DIRLTDL=libltdl
 500    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 501    # Sigh.  Libtool's macro doesn't do the right thing.
 502    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 503    # FIXME: this is a hack.
 504    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 505    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 506 fi
 507 AC_SUBST(INCLTDL)
 508 AC_SUBST(LIBLTDL)
 509 AC_SUBST(DIRLTDL)
 510 AC_PROG_LIBTOOL
 511 AM_PROG_GCJ
 512 AM_PROG_CC_C_O
 513
 514 AC_CONFIG_SUBDIRS(classpath libltdl)
 515
 516 # The -no-testsuite modules omit the test subdir.
 517 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 518
 519 # Should the runtime set system properties by examining the
 520 # environment variable GCJ_PROPERTIES?
 521 AC_ARG_ENABLE(getenv-properties,
 522   AS_HELP_STRING([--disable-getenv-properties],
 523                  [don't set system properties from GCJ_PROPERTIES]))
 524
 525 # Whether GCJ_PROPERTIES is used depends on the target.
 526 if test -z "$enable_getenv_properties"; then
 527    enable_getenv_properties=${enable_getenv_properties_default-yes}
 528 fi
 529 if test "$enable_getenv_properties" = no; then
 530    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 531      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 532 fi
 533
 534 # Whether we should use arguments to main()
 535 if test -z "$enable_main_args"; then
 536    enable_main_args=${enable_main_args_default-yes}
 537 fi
 538 if test "$enable_main_args" = no; then
 539    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 540 fi
 541
 542
 543 # Should we use hashtable-based synchronization?
 544 # Currently works only for Linux X86/ia64
 545 # Typically faster and more space-efficient
 546 AC_ARG_ENABLE(hash-synchronization,
 547   AS_HELP_STRING([--enable-hash-synchronization],
 548                  [use global hash table for monitor locks]))
 549
 550 if test -z "$enable_hash_synchronization"; then
 551    enable_hash_synchronization=$enable_hash_synchronization_default
 552 fi
 553
 554
 555 install_ecj_jar=no
 556 ECJ_BUILD_JAR=
 557 ECJ_JAR=
 558 AC_ARG_WITH(ecj-jar,
 559         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 560         [ECJ_JAR=$withval],
 561         [if test -f $multi_basedir/ecj.jar; then
 562            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 563            ECJ_JAR='$(jardir)/ecj.jar'
 564            install_ecj_jar=yes
 565          fi])
 566 AC_SUBST(ECJ_BUILD_JAR)
 567 AC_SUBST(ECJ_JAR)
 568 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 569 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 570
 571 AC_ARG_WITH(java-home,
 572   AS_HELP_STRING([--with-java-home=DIRECTORY],
 573                  [value of java.home system property]),
 574                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 575 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 576 AC_SUBST(JAVA_HOME)
 577
 578 suppress_libgcj_bc=no
 579 AC_ARG_ENABLE(libgcj-bc,
 580   AS_HELP_STRING([--enable-libgcj-bc],
 581                  [enable(default) or disable BC ABI for portions of libgcj]),
 582   [if test "$enable_libgcj_bc" = "no"; then
 583      suppress_libgcj_bc=yes
 584    fi])
 585 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 586
 587 build_libgcj_reduced_reflection=no
 588 AC_ARG_ENABLE(reduced-reflection,
 589   AS_HELP_STRING([--enable-reduced-reflection],
 590                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 591   [if test "$enable_reduced_reflection" = "yes"; then
 592      build_libgcj_reduced_reflection=yes
 593    fi])
 594 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 595
 596 # What is the native OS API for MinGW?
 597 AC_ARG_WITH(win32-nlsapi,
 598   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 599                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 600 [case "${withval}" in
 601   ansi) with_win32_nlsapi=ansi ;;
 602   unicows) with_win32_nlsapi=unicows ;;
 603   unicode) with_win32_nlsapi=unicode ;;
 604   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 605 esac],[with_win32_nlsapi=ansi])
 606
 607 case "${with_win32_nlsapi}" in
 608   unicows | unicode)
 609     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 610       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 611     ;;
 612 esac
 613
 614 # configure.host sets slow_pthread_self if the synchronization code should
 615 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 616 if test "${slow_pthread_self}" = "yes"; then
 617   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 618     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 619 fi
 620
 621 # Check for gc debugging.  This option is handled both here and in the GC.
 622 AC_ARG_ENABLE(gc-debug,
 623    AS_HELP_STRING([--enable-gc-debug],
 624                   [include full support for pointer backtracing etc.]),
 625 [ if test "$enable_gc_debug" = "yes"; then
 626     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 627               [Define if we want to use debug calls into the garbage collector.])
 628   fi])
 629
 630 # See if the user has the interpreter included.
 631 AC_ARG_ENABLE(interpreter,
 632   AS_HELP_STRING([--enable-interpreter],
 633                  [enable interpreter]),
 634   [if test "$enable_interpreter" = yes; then
 635     # This can also be set in configure.host.
 636     libgcj_interpreter=yes
 637   elif test "$enable_interpreter" = no; then
 638     libgcj_interpreter=no
 639   fi])
 640
 641 if test "$libgcj_interpreter" = yes; then
 642    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 643 fi
 644 INTERPRETER="$libgcj_interpreter"
 645 AC_SUBST(INTERPRETER)
 646 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 647
 648 AC_MSG_CHECKING([for exception model to use])
 649 AC_LANG_PUSH(C++)
 650 AC_ARG_ENABLE(sjlj-exceptions,
 651   AS_HELP_STRING([--enable-sjlj-exceptions],
 652                  [force use of builtin_setjmp for exceptions]),
 653 [:],
 654 [dnl Botheration.  Now we've got to detect the exception model.
 655 dnl Link tests against libgcc.a are problematic since -- at least
 656 dnl as of this writing -- we've not been given proper -L bits for
 657 dnl single-tree newlib and libgloss.
 658 dnl
 659 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 660 dnl conftest files before we got a change to grep them first.
 661 cat > conftest.$ac_ext << EOF
 662 [#]line __oline__ "configure"
 663 struct S { ~S(); };
 664 void bar();
 665 void foo()
 666 {
 667   S s;
 668   bar();
 669 }
 670 EOF
 671 old_CXXFLAGS="$CXXFLAGS"
 672 CXXFLAGS=-S
 673 if AC_TRY_EVAL(ac_compile); then
 674   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 675     enable_sjlj_exceptions=yes
 676   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 677     enable_sjlj_exceptions=no
 678   elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
 679     # ARM EH ABI.
 680     enable_sjlj_exceptions=no
 681   fi
 682 fi
 683 CXXFLAGS="$old_CXXFLAGS"
 684 rm -f conftest*])
 685 if test x$enable_sjlj_exceptions = xyes; then
 686   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 687         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 688   ac_exception_model_name=sjlj
 689 elif test x$enable_sjlj_exceptions = xno; then
 690   ac_exception_model_name="call frame"
 691 else
 692   AC_MSG_ERROR([unable to detect exception model])
 693 fi
 694 AC_LANG_POP(C++)
 695 AC_MSG_RESULT($ac_exception_model_name)
 696
 697 # If we are non using SJLJ exceptions, and this host does not have support
 698 # for unwinding from a signal handler, enable checked dereferences and divides.
 699 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 700   CHECKREFSPEC=-fcheck-references
 701   DIVIDESPEC=-fuse-divide-subroutine
 702   EXCEPTIONSPEC=
 703 fi
 704
 705 # See if the user wants to disable java.net.  This is the mildly
 706 # ugly way that we admit that target-side configuration sucks.
 707 AC_ARG_ENABLE(java-net,
 708   AS_HELP_STRING([--disable-java-net],
 709                  [disable java.net]))
 710
 711 # Whether java.net is built by default can depend on the target.
 712 if test -z "$enable_java_net"; then
 713    enable_java_net=${enable_java_net_default-yes}
 714 fi
 715 if test "$enable_java_net" = no; then
 716    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 717 fi
 718
 719 # See if the user wants to configure without libffi.  Some
 720 # architectures don't support it, and default values are set in
 721 # configure.host.
 722 AC_ARG_WITH(libffi,
 723   AS_HELP_STRING([--without-libffi],
 724                  [don't use libffi]),
 725   [:],
 726   [with_libffi=${with_libffi_default-yes}])
 727
 728 LIBFFI=
 729 LIBFFIINCS=
 730 if test "$with_libffi" != no; then
 731    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 732    LIBFFI=../libffi/libffi_convenience.la
 733    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 734 fi
 735 AC_SUBST(LIBFFI)
 736 AC_SUBST(LIBFFIINCS)
 737
 738 # See if the user wants to disable JVMPI support.
 739 AC_ARG_ENABLE(jvmpi,
 740   AS_HELP_STRING([--disable-jvmpi],
 741                  [disable JVMPI support]))
 742
 743 if test "$enable_jvmpi" != no; then
 744     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 745 fi
 746
 747 # If the target is an eCos system, use the appropriate eCos
 748 # I/O routines.
 749 # FIXME: this should not be a local option but a global target
 750 # system; at present there is no eCos target.
 751 TARGET_ECOS=${PROCESS-"no"}
 752 AC_ARG_WITH(ecos,
 753 [  --with-ecos             enable runtime eCos target support],
 754 TARGET_ECOS="$with_ecos"
 755 )
 756
 757 case "$TARGET_ECOS" in
 758    no) case "$host" in
 759       *mingw*)
 760             PLATFORM=Win32
 761             PLATFORMNET=Win32
 762             PLATFORMH=win32.h
 763         CHECK_FOR_BROKEN_MINGW_LD
 764       ;;
 765       *)
 766             PLATFORM=Posix
 767             PLATFORMNET=Posix
 768             PLATFORMH=posix.h
 769       ;;
 770       esac
 771       ;;
 772    *)
 773       PLATFORM=Ecos
 774       PLATFORMNET=NoNet
 775       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 776       PLATFORMH=posix.h
 777       ;;
 778 esac
 779 AC_SUBST(PLATFORM)
 780 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 781
 782 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 783                                       [Define if you have int32_t and uint32_t.]))
 784 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 785                                         [Define if you have int32_t and uint32_t.]))
 786 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 787                                           [Define if you have u_int32_t]))
 788 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 789                                            [Define if you have u_int32_t]))
 790
 791 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 792 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 793
 794 case "$host" in
 795   *-darwin*) DARWIN_CRT=true ;;
 796   *) DARWIN_CRT=false ;;
 797 esac
 798 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 799
 800 # This may not be defined in a non-ANS conformant embedded system.
 801 # FIXME: Should these case a runtime exception in that case?
 802 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 803                                   [Define is you have 'localtime' in <time.h>]))
 804
 805 # Create the subdirectory for natFile.cc, or the attempt
 806 # to create the link will fail.
 807 test -d java || mkdir java
 808 test -d java/io || mkdir java/io
 809 test -d gnu || mkdir gnu
 810 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 811
 812 # Likewise for natConcreteProcess.cc.
 813 test -d java/lang || mkdir java/lang
 814 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 815
 816 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 817 test -d java/net || mkdir java/net
 818 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 819 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 820
 821 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 822 test -d gnu/java || mkdir gnu/java
 823 test -d gnu/java/net || mkdir gnu/java/net
 824 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 825 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 826
 827 # Likewise for natVMPipe.cc and natVMSelector.cc.
 828 test -d gnu/java/nio || mkdir gnu/java/nio
 829 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 830 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 831
 832 # Likewise for natFileChannelImpl.cc
 833 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 834 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 835
 836 # Likewise for natVMSecureRandom.cc
 837 test -d gnu/java/security/jce/prng || mkdir gnu/java/security/jce/prng
 838 AC_CONFIG_LINKS(gnu/java/security/jce/prng/natVMSecureRandom.cc:gnu/java/security/jce/prng/natVMSecureRandom${FILE-${PLATFORM}}.cc)
 839
 840 case "${host}" in
 841     *mingw*)
 842       SYSTEMSPEC="-lgdi32 -lws2_32"
 843       if test "${with_win32_nlsapi}" = "unicows"; then
 844         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 845       fi
 846     ;;
 847     *)
 848       SYSTEMSPEC=
 849     ;;
 850 esac
 851 AC_SUBST(SYSTEMSPEC)
 852
 853 AC_ARG_WITH(system-zlib,
 854   AS_HELP_STRING([--with-system-zlib],
 855                  [use installed libz]))
 856 ZLIBSPEC=
 857 AC_SUBST(ZLIBSPEC)
 858 ZLIBTESTSPEC=
 859 AC_SUBST(ZLIBTESTSPEC)
 860
 861 AC_PATH_XTRA
 862
 863 # FIXME: this should be _libs on some hosts.
 864 libsubdir=.libs
 865
 866 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 867
 868 LIBSTDCXXSPEC=
 869 # extra LD Flags which are required for targets
 870 case "${host}" in
 871 *-*-darwin[[0-7]].*)
 872     # For now we have to disable it on darwin[8-9] because it slows down
 873     # the linking phase. A possible bug in ld?
 874     # on Darwin -single_module speeds up loading of the dynamic libraries.
 875     extra_ldflags_libjava=-Wl,-single_module
 876     ;;
 877 *-*-darwin[[912]]*)
 878     extra_gij_ldflags=-Wl,-allow_stack_execute
 879     ;;
 880 arm*linux*eabi)
 881     # Some of the ARM unwinder code is actually in libstdc++.  We
 882     # could in principle replicate it in libgcj, but it's better to
 883     # have a dependency on libstdc++.
 884     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 885     LIBSTDCXXSPEC=-lstdc++
 886     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 887     ;;
 888 esac
 889 AC_SUBST(extra_ldflags_libjava)
 890 AC_SUBST(extra_gij_ldflags)
 891 AC_SUBST(extra_ldflags)
 892 AC_SUBST(LIBSTDCXXSPEC)
 893
 894 AC_SUBST(LIBGCJTESTSPEC)
 895
 896 # Allow the GC to be disabled.  Can be useful when debugging.
 897 AC_MSG_CHECKING([for garbage collector to use])
 898 AC_ARG_ENABLE(java-gc,
 899   AS_HELP_STRING([--enable-java-gc=TYPE],
 900                  [choose garbage collector (default is boehm)]),
 901   [GC=$enableval],
 902   [GC=boehm])
 903 GCLIBS=
 904 GCINCS=
 905 GCDEPS=
 906 GCSPEC=
 907 JC1GCSPEC=
 908 GCTESTSPEC=
 909 case "$GC" in
 910  boehm)
 911     AC_MSG_RESULT(boehm)
 912     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 913     JC1GCSPEC='-fuse-boehm-gc'
 914     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 915     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 916     GCOBJS=boehm.lo
 917     GCHDR=boehm-gc.h
 918     # The POSIX thread support needs to know this.
 919     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 920     ;;
 921  no)
 922     AC_MSG_RESULT(none)
 923     GCHDR=no-gc.h
 924     ;;
 925  *)
 926     AC_MSG_ERROR([unrecognized collector "$GC"])
 927     ;;
 928 esac
 929 AC_SUBST(GCLIBS)
 930 AC_SUBST(GCINCS)
 931 AC_SUBST(GCDEPS)
 932 AC_SUBST(GCSPEC)
 933 AC_SUBST(JC1GCSPEC)
 934 AC_SUBST(GCTESTSPEC)
 935 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 936 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 937 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 938
 939
 940 AC_MSG_CHECKING([for thread model used by GCC])
 941 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 942 AC_MSG_RESULT([$THREADS])
 943
 944 case "$THREADS" in
 945  no | none | single)
 946     THREADS=none
 947     ;;
 948  aix | posix | posix95 | pthreads)
 949     THREADS=posix
 950     case "$host" in
 951      *-*-linux*)
 952         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 953         ;;
 954     esac
 955     ;;
 956  win32)
 957     ;;
 958  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 959     AC_MSG_ERROR(thread package $THREADS not yet supported)
 960     ;;
 961  *)
 962     AC_MSG_ERROR($THREADS is an unknown thread package)
 963     ;;
 964 esac
 965
 966 THREADCXXFLAGS=
 967 THREADLDFLAGS=
 968 THREADLIBS=
 969 THREADINCS=
 970 THREADDEPS=
 971 THREADH=
 972 THREADSPEC=
 973 THREADSTARTFILESPEC=
 974 case "$THREADS" in
 975  posix)
 976     case "$host" in
 977      *-*-cygwin*)
 978         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 979         ;;
 980      *-*-freebsd[[1234]]*)
 981         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 982         # merely adds pthread_* functions) but it does have a -pthread switch
 983         # which is required at link-time to select -lc_r *instead* of -lc.
 984         THREADLDFLAGS=-pthread
 985         # Don't set THREADSPEC here as might be expected since -pthread is
 986         # not processed when found within a spec file, it must come from
 987         # the command line.  For now, the user must provide the -pthread
 988         # switch to link code compiled with gcj.  In future, consider adding
 989         # support for weak references to pthread_* functions ala gthr.h API.
 990         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 991         ;;
 992      *-*-freebsd*)
 993         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 994         # systems which support threads and -lpthread.
 995         THREADLDFLAGS=-pthread
 996         THREADSPEC=-lpthread
 997         ;;
 998      alpha*-dec-osf* | hppa*-hp-hpux*)
 999         THREADCXXFLAGS=-pthread
1000         # boehm-gc needs some functions from librt, so link that too.
1001         THREADLIBS='-lpthread -lrt'
1002         THREADSPEC='-lpthread -lrt'
1003         ;;
1004      *)
1005         THREADLIBS=-lpthread
1006         THREADSPEC=-lpthread
1007         ;;
1008     esac
1009     THREADH=posix-threads.h
1010     # MIT pthreads doesn't seem to have the mutexattr functions.
1011     # But for now we don't check for it.  We just assume you aren't
1012     # using MIT pthreads.
1013     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1014
1015     # If we're using the Boehm GC, then we happen to know that it
1016     # defines _REENTRANT, so we don't bother.  Eww.
1017     if test "$GC" != boehm; then
1018        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1019     fi
1020     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1021     ;;
1022
1023  win32)
1024     THREADH=win32-threads.h
1025     THREADCXXFLAGS=-mthreads
1026     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1027     # But we do not want the executables created to be dependent on
1028     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1029     # exception handling contexts.  The following kludge achieves this effect
1030     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1031     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1032     # A workaround is to explicitly use -mthreads while linking Java programs.
1033     # See PR libgcj/28263.
1034     #
1035     # FIXME: In Java we are able to detect thread death at the end of
1036     # Thread.run() so we should be able to clean up the exception handling
1037     # contexts ourselves.
1038     THREADSTARTFILESPEC='crtmt%O%s'
1039     ;;
1040
1041  none)
1042     THREADH=no-threads.h
1043     ;;
1044 esac
1045 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1046 AC_SUBST(THREADLIBS)
1047 AC_SUBST(THREADINCS)
1048 AC_SUBST(THREADDEPS)
1049 AC_SUBST(THREADSPEC)
1050 AC_SUBST(THREADSTARTFILESPEC)
1051 AC_SUBST(THREADLDFLAGS)
1052 AC_SUBST(THREADCXXFLAGS)
1053 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1054 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1055 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1056 if test "$enable_shared" != yes; then
1057   use_libgcj_bc=no
1058 fi
1059 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1060
1061 if test -d sysdep; then true; else mkdir sysdep; fi
1062 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1063 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1064 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1065
1066 LIBGCJ_SPEC="%{s-bc-abi:} -lgcj"
1067 if test "$use_libgcj_bc" = yes; then
1068   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:-lgcj;:-lgcj_bc}"
1069 fi
1070 AC_SUBST(LIBGCJ_SPEC)
1071
1072 HASH_SYNC_SPEC=
1073 # Hash synchronization is only useful with posix threads right now.
1074 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1075    HASH_SYNC_SPEC=-fhash-synchronization
1076    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1077 fi
1078 AC_SUBST(HASH_SYNC_SPEC)
1079
1080 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1081
1082 # We're in the tree with gcc, and need to include some of its headers.
1083 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1084
1085 if test "x${with_newlib}" = "xyes"; then
1086    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1087    # may not work correctly, because the compiler may not be able to
1088    # link executables.
1089
1090    # We assume newlib.  This lets us hard-code the functions we know
1091    # we'll have.
1092    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1093    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1094    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1095    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1096    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1097    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1098    # This is only for POSIX threads.
1099    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1100
1101    # Assume we do not have getuid and friends.
1102    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1103    PLATFORMNET=NoNet
1104 else
1105    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1106                    localtime_r getpwuid_r getcwd \
1107                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1108                    nl_langinfo setlocale \
1109                    inet_pton uname inet_ntoa \
1110                    getrlimit sigaction ftruncate mmap \
1111                    getifaddrs])
1112    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1113    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1114    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1115    AC_CHECK_LIB(dl, dladdr, [
1116        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1117        AC_CHECK_LIB(dld, dladdr, [
1118        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1119
1120    if test x"$cross_compiling" = x"no"; then
1121      AC_CHECK_FILES(/proc/self/exe, [
1122        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1123      AC_CHECK_FILES(/proc/self/maps, [
1124        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1125          [Define if you have /proc/self/maps])])
1126    else
1127      case $host in
1128      *-linux*)
1129        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1130        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1131        ;;
1132      esac
1133    fi
1134
1135    AM_ICONV
1136    AM_LC_MESSAGES
1137    AC_STRUCT_TIMEZONE
1138
1139    AC_CHECK_FUNCS(gethostbyname_r, [
1140      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1141        [Define if you have the 'gethostbyname_r' function.])
1142      # There are two different kinds of gethostbyname_r.
1143      # We look for the one that returns `int'.
1144      # Hopefully this check is robust enough.
1145      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1146        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1147
1148      case " $GCINCS " in
1149      *" -D_REENTRANT "*) ;;
1150      *)
1151         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1152         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1153         [libjava_cv_gethostbyname_r_needs_reentrant],
1154         [ AC_LANG_PUSH(C++)
1155           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1156             [[gethostbyname_r("", 0, 0);]])],
1157             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1158                 CPPFLAGS_SAVE="$CPPFLAGS"
1159                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1160                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1161                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1162                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1163                 CPPFLAGS="$CPPFLAGS_SAVE"
1164           ])
1165           AC_LANG_POP(C++)
1166         ])
1167         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1168           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1169         fi
1170      ;;
1171      esac
1172
1173      AC_CACHE_CHECK([for struct hostent_data],
1174         [libjava_cv_struct_hostent_data], [dnl
1175         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1176 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1177 # define _REENTRANT 1
1178 #endif
1179 #include <netdb.h>]], [[struct hostent_data data;]])],
1180           [libjava_cv_struct_hostent_data=yes],
1181           [libjava_cv_struct_hostent_data=no])])
1182      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1183        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1184          [Define if struct hostent_data is defined in netdb.h])
1185      fi
1186    ])
1187
1188    # FIXME: libjava source code expects to find a prototype for
1189    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1190    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1191    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1192    # linkage check is enough, yet C++ code requires proper prototypes.)
1193    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1194    AC_CHECK_FUNCS(gethostbyaddr_r, [
1195      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1196        [Define if you have the 'gethostbyaddr_r' function.])
1197      # There are two different kinds of gethostbyaddr_r.
1198      # We look for the one that returns `int'.
1199      # Hopefully this check is robust enough.
1200      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1201        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1202          [Define if gethostbyaddr_r returns 'int'.])])])])
1203
1204    AC_CHECK_FUNCS(gethostname, [
1205      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1206        [Define if you have the 'gethostname' function.])
1207      AC_EGREP_HEADER(gethostname, unistd.h, [
1208        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1209          [Define if gethostname is declared in <unistd.h>.])])])
1210
1211    AC_CHECK_FUNCS(usleep, [
1212      AC_EGREP_HEADER(usleep, unistd.h, [
1213        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1214           [Define if usleep is declared in <unistd.h>.])])])
1215
1216    # Look for these functions in the thread library, but only bother
1217    # if using POSIX threads.
1218    if test "$THREADS" = posix; then
1219       save_LIBS="$LIBS"
1220       LIBS="$LIBS $THREADLIBS"
1221
1222       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1223       # Solaris 7 the name librt is preferred.
1224       AC_CHECK_FUNCS(sched_yield, , [
1225         AC_CHECK_LIB(rt, sched_yield, [
1226           AC_DEFINE(HAVE_SCHED_YIELD)
1227           THREADLIBS="$THREADLIBS -lrt"
1228           THREADSPEC="$THREADSPEC -lrt"], [
1229           AC_CHECK_LIB(posix4, sched_yield, [
1230             AC_DEFINE(HAVE_SCHED_YIELD)
1231             THREADLIBS="$THREADLIBS -lposix4"
1232             THREADSPEC="$THREADSPEC -lposix4"])])])
1233
1234       AC_CHECK_LIB(rt, clock_gettime, [
1235          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1236          case "$THREADSPEC" in
1237            *-lrt*) ;;
1238            *)
1239              THREADSPEC="$THREADSPEC -lrt"
1240              THREADLIBS="$THREADLIBS -lrt"
1241              ;;
1242          esac])
1243
1244       LIBS="$save_LIBS"
1245
1246       # We can save a little space at runtime if the mutex has m_count
1247       # or __m_count.  This is a nice hack for Linux.
1248       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1249           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1250         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1251              [Define if pthread_mutex_t has m_count member.]), [
1252         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1253             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1254           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1255             [Define if pthread_mutex_t has __m_count member.]))])
1256    fi
1257
1258    # We require a way to get the time.
1259    time_found=no
1260    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1261    if test "$time_found" = no; then
1262       AC_MSG_ERROR([no function found to get the time])
1263    fi
1264
1265    AC_CHECK_FUNCS(memmove)
1266
1267    # We require memcpy.
1268    memcpy_found=no
1269    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1270    if test "$memcpy_found" = no; then
1271       AC_MSG_ERROR([memcpy is required])
1272    fi
1273    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1274    AC_CHECK_LIB(dl, dlopen, [
1275        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1276        AC_CHECK_LIB(dld, dlopen, [
1277        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1278
1279    # Some library-finding code we stole from Tcl.
1280    #--------------------------------------------------------------------
1281    #    Check for the existence of the -lsocket and -lnsl libraries.
1282    #    The order here is important, so that they end up in the right
1283    #    order in the command line generated by make.  Here are some
1284    #    special considerations:
1285    #    1. Use "connect" and "accept" to check for -lsocket, and
1286    #       "gethostbyname" to check for -lnsl.
1287    #    2. Use each function name only once:  can't redo a check because
1288    #       autoconf caches the results of the last check and won't redo it.
1289    #    3. Use -lnsl and -lsocket only if they supply procedures that
1290    #       aren't already present in the normal libraries.  This is because
1291    #       IRIX 5.2 has libraries, but they aren't needed and they're
1292    #       bogus:  they goof up name resolution if used.
1293    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1294    #       To get around this problem, check for both libraries together
1295    #       if -lsocket doesn't work by itself.
1296    #--------------------------------------------------------------------
1297
1298    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1299     [gcj_cv_lib_sockets=
1300      gcj_checkBoth=0
1301      unset ac_cv_func_connect
1302      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1303      if test "$gcj_checkSocket" = 1; then
1304          unset ac_cv_func_connect
1305          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1306                       gcj_checkBoth=1)
1307      fi
1308      if test "$gcj_checkBoth" = 1; then
1309          gcj_oldLibs=$LIBS
1310          LIBS="$LIBS -lsocket -lnsl"
1311          unset ac_cv_func_accept
1312          AC_CHECK_FUNC(accept,
1313                        [gcj_checkNsl=0
1314                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1315          unset ac_cv_func_accept
1316          LIBS=$gcj_oldLibs
1317      fi
1318      unset ac_cv_func_gethostbyname
1319      gcj_oldLibs=$LIBS
1320      LIBS="$LIBS $gcj_cv_lib_sockets"
1321      AC_CHECK_FUNC(gethostbyname, ,
1322                    [AC_CHECK_LIB(nsl, main,
1323                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1324      unset ac_cv_func_gethostbyname
1325      LIBS=$gcj_oldLIBS
1326    ])
1327    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1328
1329    if test "$with_system_zlib" = yes; then
1330       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1331    fi
1332
1333    # Test for Gtk stuff, if asked for.
1334    if test "$use_gtk_awt" = yes; then
1335       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1336       AC_SUBST(GTK_CFLAGS)
1337       AC_SUBST(GTK_LIBS)
1338
1339       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1340       AC_SUBST(GLIB_CFLAGS)
1341       AC_SUBST(GLIB_LIBS)
1342
1343       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1344       AC_SUBST(LIBART_CFLAGS)
1345       AC_SUBST(LIBART_LIBS)
1346
1347       # We require the XTest Extension to support java.awt.Robot.
1348       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1349                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1350                    [${X_LIBS}])
1351    fi
1352
1353    # On Solaris, and maybe other architectures, the Boehm collector
1354    # requires -ldl.
1355    if test "$GC" = boehm; then
1356       case "${host}" in
1357           mips-sgi-irix6*)
1358             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1359             # libgcj.spec is used, so override here
1360             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1361           ;;
1362           *)
1363             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1364           ;;
1365       esac
1366    fi
1367 fi
1368
1369 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1370 case $build in
1371     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1372     *)         CLASSPATH_SEPARATOR=':' ;;
1373 esac
1374 AC_SUBST(CLASSPATH_SEPARATOR)
1375
1376 # We must search the source tree for java.lang, since we still don't
1377 # have libgcj.jar nor java/lang/*.class
1378 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1379 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1380
1381 # Since some classes depend on this one, we need its source available
1382 # before we can do any GCJ compilation test :-(
1383 if test ! -f gnu/classpath/Configuration.java; then
1384   test -d gnu || mkdir gnu
1385   test -d gnu/classpath || mkdir gnu/classpath
1386   # Note that it is not crucial that all the values here be correct.
1387   sed -e "s,@prefix@,$prefix," \
1388       -e "s,@VERSION@,$VERSION," \
1389       -e "s,@LIBDEBUG@,false," \
1390       -e "s,@INIT_LOAD_LIBRARY@,false," \
1391       -e "s,@@,$LIBGCJDEBUG," \
1392       -e "s,@default_toolkit@,$TOOLKIT," \
1393       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1394       -e "s,@GTK_CAIRO_ENABLED@,false," \
1395       -e "s,@ECJ_JAR@,," \
1396       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1397         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1398         > gnu/classpath/Configuration.java
1399   # We do not want to redirect the output of the grep below to /dev/null,
1400   # but we add /dev/null to the input list so that grep will print the
1401   # filename of Configuration.java in case it finds any matches.
1402   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1403     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1404   fi
1405 fi
1406
1407 LT_AC_PROG_GCJ
1408
1409 # Now remove it.
1410 rm -f gnu/classpath/Configuration.java
1411
1412 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1413
1414 AC_CHECK_SIZEOF(void *)
1415
1416 AC_C_BIGENDIAN
1417
1418 ZLIBS=
1419 SYS_ZLIBS=
1420 ZINCS=
1421
1422 if test -z "$ZLIBSPEC"; then
1423    # Use zlib from the GCC tree.
1424    ZINCS='-I$(top_srcdir)/../zlib'
1425    ZLIBS=../zlib/libzgcj_convenience.la
1426 else
1427    # System's zlib.
1428    SYS_ZLIBS="$ZLIBSPEC"
1429 fi
1430 AC_SUBST(ZLIBS)
1431 AC_SUBST(SYS_ZLIBS)
1432 AC_SUBST(ZINCS)
1433 AC_SUBST(DIVIDESPEC)
1434 AC_SUBST(CHECKREFSPEC)
1435 AC_SUBST(EXCEPTIONSPEC)
1436 AC_SUBST(BACKTRACESPEC)
1437 AC_SUBST(IEEESPEC)
1438
1439 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1440 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1441 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1442 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1443 AC_SUBST(GCC_UNWIND_INCLUDE)
1444
1445 # Process the option "--enable-version-specific-runtime-libs"
1446 # Calculate toolexeclibdir
1447 case ${version_specific_libs} in
1448   yes)
1449     # Need the gcc compiler version to know where to install libraries
1450     # and header files if --enable-version-specific-runtime-libs option
1451     # is selected.
1452     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1453     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1454     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1455     toolexeclibdir=$toolexecmainlibdir
1456     ;;
1457   no)
1458     if test -n "$with_cross_host" &&
1459        test x"$with_cross_host" != x"no"; then
1460       # Install a library built with a cross compiler in tooldir, not libdir.
1461       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1462       toolexecmainlibdir='$(toolexecdir)/lib'
1463     else
1464       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1465       toolexecmainlibdir='$(libdir)'
1466     fi
1467     multi_os_directory=`$CC -print-multi-os-directory`
1468     case $multi_os_directory in
1469       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1470       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1471     esac
1472     ;;
1473 esac
1474 AC_SUBST(toolexecdir)
1475 AC_SUBST(toolexecmainlibdir)
1476 AC_SUBST(toolexeclibdir)
1477
1478 # Determine gcj and libgcj version number.
1479 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1480 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1481 GCJVERSION=$gcjversion
1482 AC_SUBST(GCJVERSION)
1483 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1484
1485 # Determine where the standard .db file and GNU Classpath JNI
1486 # libraries are found.
1487 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1488 multi_os_directory=`$CC -print-multi-os-directory`
1489 case $multi_os_directory in
1490   .)
1491    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1492    ;;
1493   *)
1494    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1495    ;;
1496 esac
1497 AC_SUBST(dbexecdir)
1498 AC_SUBST(gcjsubdir)
1499
1500 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1501 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1502
1503 TL_AC_GXX_INCLUDE_DIR
1504
1505 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1506 # On that system, sys/ioctl.h will not include sys/filio.h unless
1507 # BSD_COMP is defined; just including sys/filio.h is simpler.
1508 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1509 # for now.  If you change this, you also must update natFile.cc.
1510 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1511                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1512                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1513                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1514                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1515 AC_CHECK_HEADERS(inttypes.h, [
1516     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1517     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1518 ])
1519
1520 AC_CHECK_TYPE([ssize_t], [int])
1521 AC_CHECK_TYPE([magic_t], [
1522     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1523 #ifdef HAVE_MAGIC_H
1524 #include <magic.h>
1525 #endif])
1526
1527 AC_MSG_CHECKING([for in_addr_t])
1528 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1529 #if STDC_HEADERS
1530 #include <stdlib.h>
1531 #include <stddef.h>
1532 #endif
1533 #if HAVE_NETINET_IN_H
1534 #include <netinet/in.h>
1535 #endif]], [[in_addr_t foo;]])],
1536   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1537      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1538    AC_MSG_RESULT(yes)],
1539   [AC_MSG_RESULT(no)])
1540
1541 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1542 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1543   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1544      [Define if struct ip_mreq is defined in netinet/in.h.])
1545    AC_MSG_RESULT(yes)],
1546   [AC_MSG_RESULT(no)])
1547
1548 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1549 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1550   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1551      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1552    AC_MSG_RESULT(yes)],
1553   [AC_MSG_RESULT(no)])
1554
1555 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1556 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1557   [AC_DEFINE(HAVE_INET6, 1,
1558      [Define if inet6 structures are defined in netinet/in.h.])
1559    AC_MSG_RESULT(yes)],
1560   [AC_MSG_RESULT(no)])
1561
1562 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1563 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1564 #include <sys/types.h>
1565 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1566   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1567    AC_MSG_RESULT(yes)],
1568   [AC_MSG_RESULT(no)])
1569
1570 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1571 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1572   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1573    AC_MSG_RESULT(yes)],
1574   [AC_MSG_RESULT(no)
1575    AC_MSG_CHECKING([for global timezone variable])
1576    dnl FIXME: we don't want a link check here because that won't work
1577    dnl when cross-compiling.  So instead we make an assumption that
1578    dnl the header file will mention timezone if it exists.
1579    dnl Don't find the win32 function timezone
1580    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1581      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1582       AC_MSG_RESULT(yes)],
1583      [AC_MSG_RESULT(no)
1584        AC_MSG_CHECKING([for global _timezone variable])
1585        dnl FIXME: As above, don't want link check
1586        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1587          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1588             [Define if your platform has the global _timezone variable.])
1589           AC_MSG_RESULT(yes)],
1590           [AC_MSG_RESULT(no)])])])
1591
1592 AC_CHECK_PROGS(PERL, perl, false)
1593
1594 SYSDEP_SOURCES=
1595 SIGNAL_HANDLER_AUX=
1596
1597 case "${host}" in
1598  i?86-*-linux*)
1599     SIGNAL_HANDLER=include/i386-signal.h
1600     ;;
1601  sparc*-sun-solaris*)
1602     SIGNAL_HANDLER=include/sparc-signal.h
1603     ;;
1604 # ia64-*)
1605 #    SYSDEP_SOURCES=sysdep/ia64.c
1606 #    test -d sysdep || mkdir sysdep
1607 #    ;;
1608  hppa*-*-linux*)
1609     SIGNAL_HANDLER=include/pa-signal.h
1610     ;;
1611  hppa*-hp-hpux*)
1612     SIGNAL_HANDLER=include/hppa-signal.h
1613     ;;
1614  ia64-*-linux*)
1615     SIGNAL_HANDLER=include/dwarf2-signal.h
1616     ;;
1617  powerpc*-*-linux*)
1618     SIGNAL_HANDLER=include/powerpc-signal.h
1619     ;;
1620  alpha*-*-linux*)
1621     SIGNAL_HANDLER=include/dwarf2-signal.h
1622     ;;
1623  s390*-*-linux*)
1624     SIGNAL_HANDLER=include/s390-signal.h
1625     ;;
1626  x86_64*-*-linux*)
1627     SIGNAL_HANDLER=include/x86_64-signal.h
1628     SIGNAL_HANDLER_AUX=include/i386-signal.h
1629     ;;
1630  sparc*-*-linux*)
1631     SIGNAL_HANDLER=include/dwarf2-signal.h
1632     ;;
1633  sh*-*-linux*)
1634     SIGNAL_HANDLER=include/sh-signal.h
1635     ;;
1636  *mingw*)
1637     SIGNAL_HANDLER=include/win32-signal.h
1638     ;;
1639  mips*-*-linux*)
1640     SIGNAL_HANDLER=include/mips-signal.h
1641     ;;
1642  m68*-*-linux*)
1643     SIGNAL_HANDLER=include/dwarf2-signal.h
1644     ;;
1645  powerpc*-*-darwin* | i?86-*-darwin[[912]]* | x86_64-*-darwin[[912]]*)
1646     SIGNAL_HANDLER=include/darwin-signal.h
1647     ;;
1648  powerpc*-*-aix*)
1649     SIGNAL_HANDLER=include/aix-signal.h
1650     ;;
1651  *)
1652     SIGNAL_HANDLER=include/default-signal.h
1653     ;;
1654 esac
1655
1656 # If we're using sjlj exceptions, forget what we just learned.
1657 if test "$enable_sjlj_exceptions" = yes; then
1658    SIGNAL_HANDLER=include/default-signal.h
1659    SIGNAL_HANDLER_AUX=
1660 fi
1661
1662 AC_SUBST(SYSDEP_SOURCES)
1663
1664 if test -z "$SIGNAL_HANDLER_AUX"; then
1665   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1666 fi
1667
1668 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1669                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1670
1671 if test "${multilib}" = "yes"; then
1672   multilib_arg="--enable-multilib"
1673 else
1674   multilib_arg=
1675 fi
1676
1677 # See if we support thread-local storage.
1678 GCC_CHECK_TLS
1679
1680 # For _Unwind_GetIPInfo.
1681 GCC_CHECK_UNWIND_GETIPINFO
1682
1683 # See if linker supports anonymous version scripts.
1684 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1685   [libjava_cv_anon_version_script],
1686   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1687    libjava_cv_anon_version_script=no
1688    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1689    echo '{ global: globalsymb*; local: *; };' > conftest.map
1690    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1691                [libjava_cv_anon_version_script=yes], [])
1692    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1693   ])
1694 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1695
1696 # Check if linker supports static linking on a per library basis
1697 LD_START_STATIC_SPEC=
1698 LD_FINISH_STATIC_SPEC=
1699 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1700   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1701     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1702     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1703   fi
1704 fi
1705 AC_SUBST(LD_START_STATIC_SPEC)
1706 AC_SUBST(LD_FINISH_STATIC_SPEC)
1707
1708 here=`${PWDCMD-pwd}`
1709 AC_SUBST(here)
1710
1711 # We get this from the environment.
1712 AC_SUBST(GCJFLAGS)
1713
1714 AC_ARG_WITH([python-dir],
1715             AS_HELP_STRING([--with-python-dir],
1716                            [the location to install Python modules. This path should NOT include the prefix.]),
1717             [with_python_dir=$withval], [with_python_dir=""])
1718
1719 if test "x${with_python_dir}" = "x"
1720 then
1721   # Needed for installing Python modules during make install.
1722   python_mod_dir="\${prefix}/share/python"
1723   # Needed for substituting into aot-compile*
1724   python_mod_dir_expanded="${prefix}/share/python"
1725 else
1726   python_mod_dir="\${prefix}${with_python_dir}"
1727   python_mod_dir_expanded="${prefix}${with_python_dir}"
1728 fi
1729 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1730 AC_SUBST(python_mod_dir)
1731 AC_SUBST(python_mod_dir_expanded)
1732
1733 # needed for aot-compile-rpm
1734 MAKE=`which make`
1735 AC_SUBST(MAKE)
1736
1737 AC_ARG_ENABLE([aot-compile-rpm],
1738   [AS_HELP_STRING([--enable-aot-compile-rpm],
1739                  [enable installation of aot-compile-rpm [default=no]])],
1740   [case "${enableval}" in
1741     yes) AOT_RPM_ENABLED=yes ;;
1742     no)  AOT_RPM_ENABLED=no ;;
1743     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1744   esac],
1745   [AOT_RPM_ENABLED=no]
1746 )
1747 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1748
1749 AC_ARG_ENABLE([java-home],
1750   [AS_HELP_STRING([--enable-java-home],
1751                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1752   [case "${enableval}" in
1753     yes) JAVA_HOME_ENABLED=yes ;;
1754     no)  JAVA_HOME_ENABLED=no ;;
1755     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1756   esac],
1757   [JAVA_HOME_ENABLED=no]
1758 )
1759 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1760
1761 # Only do these checks if java-home above is enabled.
1762 if test "x${JAVA_HOME_ENABLED}" = xyes
1763 then
1764
1765   AC_ARG_WITH([gcc-suffix],
1766               AS_HELP_STRING([--with-gcc-suffix],
1767                              [the GCC tool suffix (defaults to empty string)]),
1768               [gcc_suffix=$withval], [gcc_suffix=""])
1769   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1770   AC_SUBST(gcc_suffix)
1771
1772   AC_ARG_WITH([arch-directory],
1773               AS_HELP_STRING([--with-arch-directory],
1774                              [the arch directory under jre/lib (defaults to auto-detect)]),
1775               [host_cpu=$withval], [host_cpu=""])
1776
1777   AC_ARG_WITH([os-directory],
1778               AS_HELP_STRING([--with-os-directory],
1779                              [the os directory under include (defaults to auto-detect)]),
1780               [host_os=$withval], [host_os=""])
1781
1782   AC_ARG_WITH([origin-name],
1783               AS_HELP_STRING([--with-origin-name],
1784                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1785               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1786   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1787
1788   AC_ARG_WITH([arch-suffix],
1789               AS_HELP_STRING([--with-arch-suffix],
1790                              [the arch directory suffix (default is the empty string]),
1791               [arch_suffix=$withval], [arch_suffix=""])
1792   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1793
1794   AC_ARG_WITH([jvm-root-dir],
1795               AS_HELP_STRING([--with-jvm-root-dir],
1796                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1797               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1798   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1799
1800   AC_ARG_WITH([jvm-jar-dir],
1801               AS_HELP_STRING([--with-jvm-jar-dir],
1802                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1803               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1804   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1805
1806   JAVA_VERSION=1.5.0
1807   BUILD_VERSION=0
1808   AC_SUBST(JAVA_VERSION)
1809   AC_SUBST(BUILD_VERSION)
1810   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1811
1812   jre_dir=jre
1813   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1814   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1815
1816   JVM_ROOT_DIR=${jvm_root_dir}
1817   AC_SUBST(JVM_ROOT_DIR)
1818   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1819
1820   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1821   AC_SUBST(JVM_JAR_ROOT_DIR)
1822   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1823
1824   JVM_JAR_DIR=${jvm_jar_dir}
1825   AC_SUBST(JVM_JAR_DIR)
1826   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1827
1828   JRE_DIR=${jre_dir}
1829   AC_SUBST(JRE_DIR)
1830
1831   JRE_LNK=${jre_lnk}
1832   AC_SUBST(JRE_LNK)
1833
1834   SDK_LNK=${sdk_lnk}
1835   AC_SUBST(SDK_LNK)
1836
1837   SDK_BIN_DIR=${jvm_root_dir}/bin
1838   AC_SUBST(SDK_BIN_DIR)
1839   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1840
1841   SDK_LIB_DIR=${jvm_root_dir}/lib
1842   AC_SUBST(SDK_LIB_DIR)
1843   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1844
1845   SDK_INCLUDE_DIR=${jvm_root_dir}/include
1846   AC_SUBST(SDK_INCLUDE_DIR)
1847   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1848
1849   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1850   AC_SUBST(JRE_BIN_DIR)
1851   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1852
1853   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1854   AC_SUBST(JRE_LIB_DIR)
1855   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
1856
1857   # Find gcj prefix using gcj found in PATH.
1858   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
1859
1860   # Where do the gcj binaries live?
1861   # For jhbuild based builds, they all live in a sibling of bin called
1862   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
1863   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
1864   AC_SUBST(GCJ_BIN_DIR)
1865   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
1866
1867   AC_MSG_RESULT(host is ${host})
1868   if test "x${host_cpu}" = "x"
1869   then
1870     case ${host} in
1871       *-mingw* | *-cygwin*)
1872         host_cpu=x86;;
1873       i486-* | i586-* | i686-*)
1874         host_cpu=i386;;
1875       x86_64-*)
1876         host_cpu=amd64;;
1877       *)
1878         host_cpu=${host_cpu};;
1879     esac
1880   fi
1881   AC_MSG_RESULT(arch directory: ${host_cpu})
1882   CPU=${host_cpu}
1883   AC_SUBST(CPU)
1884
1885   if test "x${host_os}" = "x"
1886   then
1887     case ${host} in
1888       *-mingw* | *-cygwin*)
1889         host_os=win32;;
1890       *-linux*)
1891         host_os=linux;;
1892       *)
1893         host_os=${host_os};;
1894     esac
1895   fi
1896   echo os directory: ${host_os}
1897   OS=${host_os}
1898   AC_SUBST(OS)
1899
1900   # make an expanded $libdir, for substituting into
1901   # scripts (and other non-Makefile things).
1902   LIBDIR=$libdir
1903   if test "x${exec_prefix}" = "xNONE"
1904   then
1905       lib_exec_prefix=$prefix
1906   else
1907       lib_exec_prefix=$exec_prefix
1908   fi
1909   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
1910   AC_SUBST(LIBDIR)
1911 fi
1912
1913 AC_CONFIG_FILES([
1914 Makefile
1915 libgcj.pc
1916 libgcj.spec
1917 libgcj-test.spec
1918 gcj/Makefile
1919 include/Makefile
1920 testsuite/Makefile
1921 contrib/aotcompile.py
1922 contrib/aot-compile
1923 contrib/aot-compile-rpm
1924 contrib/rebuild-gcj-db
1925 ])
1926
1927 if test ${multilib} = yes; then
1928   multilib_arg="--enable-multilib"
1929 else
1930   multilib_arg=
1931 fi
1932
1933 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1934 AC_OUTPUT