libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  88 GCC_NO_EXECUTABLES
  89
  90 # (1) We use an abnormal CXX (without library references), so we
  91 # must cache it under a different name.
  92 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  93 # the non-multilib-adjusted value will be used in multilibs.
  94 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  95 # (4) As another side effect, automake doesn't automatically include them
  96 # in Makefile.in.
  97 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  98 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  99 # used in later tests.  This may not be necessary in libjava; I don't know.
 100 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103 save_CXXFLAGS="$CXXFLAGS"
 104 CXXFLAGS="$CXXFLAGS -fno-builtin"
 105 AC_PROG_CC
 106 AC_PROG_CXX
 107 CXXFLAGS="$save_CXXFLAGS"
 108 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109 AC_SUBST(CFLAGS)
 110 AC_SUBST(CXXFLAGS)
 111 AC_SUBST(LDFLAGS)
 112
 113 AM_INIT_AUTOMAKE([1.9.0])
 114
 115 AC_CHECK_TOOL(AS, as)
 116 AC_CHECK_TOOL(AR, ar)
 117 AC_CHECK_TOOL(RANLIB, ranlib, :)
 118
 119 AC_PROG_INSTALL
 120
 121 AM_MAINTAINER_MODE
 122
 123 AC_EXEEXT
 124
 125 # configure.host sets the following important variables
 126 #       libgcj_cflags    - host specific C compiler flags
 127 #       libgcj_cxxflags  - host specific C++ compiler flags
 128 #       libgcj_javaflags - host specific Java compiler flags
 129
 130 libgcj_cflags=
 131 libgcj_cxxflags=
 132 libgcj_javaflags=
 133
 134 . ${srcdir}/configure.host
 135
 136 LIBGCJ_CFLAGS="${libgcj_cflags}"
 137 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 138 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 139 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 140 AC_SUBST(LIBGCJ_CFLAGS)
 141 AC_SUBST(LIBGCJ_CXXFLAGS)
 142 AC_SUBST(LIBGCJ_JAVAFLAGS)
 143 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 144
 145 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 146
 147 # Only use libltdl for non-newlib builds.
 148 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 149    AC_LIBLTDL_CONVENIENCE
 150    AC_LIBTOOL_DLOPEN
 151    DIRLTDL=libltdl
 152    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 153    # Sigh.  Libtool's macro doesn't do the right thing.
 154    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 155    # FIXME: this is a hack.
 156    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 157    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 158 fi
 159 AC_SUBST(INCLTDL)
 160 AC_SUBST(LIBLTDL)
 161 AC_SUBST(DIRLTDL)
 162 AC_PROG_LIBTOOL
 163 AM_PROG_GCJ
 164 AM_PROG_CC_C_O
 165 AC_CONFIG_SUBDIRS(libltdl)
 166
 167 # The -no-testsuite modules omit the test subdir.
 168 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 169
 170 # Should the runtime set system properties by examining the
 171 # environment variable GCJ_PROPERTIES?
 172 AC_ARG_ENABLE(getenv-properties,
 173   AS_HELP_STRING([--disable-getenv-properties],
 174                  [don't set system properties from GCJ_PROPERTIES]))
 175
 176 # Whether GCJ_PROPERTIES is used depends on the target.
 177 if test -z "$enable_getenv_properties"; then
 178    enable_getenv_properties=${enable_getenv_properties_default-yes}
 179 fi
 180 if test "$enable_getenv_properties" = no; then
 181    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 182      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 183 fi
 184
 185 # Whether we should use arguments to main()
 186 if test -z "$enable_main_args"; then
 187    enable_main_args=${enable_main_args_default-yes}
 188 fi
 189 if test "$enable_main_args" = no; then
 190    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 191 fi
 192
 193
 194 # Should we use hashtable-based synchronization?
 195 # Currently works only for Linux X86/ia64
 196 # Typically faster and more space-efficient
 197 AC_ARG_ENABLE(hash-synchronization,
 198   AS_HELP_STRING([--enable-hash-synchronization],
 199                  [use global hash table for monitor locks]))
 200
 201 if test -z "$enable_hash_synchronization"; then
 202    enable_hash_synchronization=$enable_hash_synchronization_default
 203 fi
 204
 205 # Do we allow intermodule optimizations (i.e. compiling many files at once)?
 206 AC_ARG_ENABLE(libgcj-multifile,
 207   AS_HELP_STRING([--enable-libgcj-multifile]
 208                  [allow compilation of several files at once]),
 209 [case "${enableval}" in
 210   yes) enable_libgcj_multifile=yes ;;
 211   no)  enable_libgcj_multifile=no ;;
 212   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libgcj-multifile) ;;
 213 esac],[enable_libgcj_multifile=no])
 214 AM_CONDITIONAL(ONESTEP, test "$enable_libgcj_multifile" = yes)
 215
 216 AC_ARG_WITH(java-home,
 217   AS_HELP_STRING([--with-java-home=DIRECTORY],
 218                  [value of java.home system property]),
 219                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 220 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 221 AC_SUBST(JAVA_HOME)
 222
 223 # What is the native OS API for MinGW?
 224 AC_ARG_WITH(win32-nlsapi,
 225   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 226                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 227 [case "${withval}" in
 228   ansi) with_win32_nlsapi=ansi ;;
 229   unicows) with_win32_nlsapi=unicows ;;
 230   unicode) with_win32_nlsapi=unicode ;;
 231   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 232 esac],[with_win32_nlsapi=ansi])
 233
 234 case "${with_win32_nlsapi}" in
 235   unicows | unicode)
 236     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 237       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 238     ;;
 239 esac
 240
 241 # configure.host sets slow_pthread_self if the synchronization code should
 242 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 243 if test "${slow_pthread_self}" = "yes"; then
 244   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 245     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 246 fi
 247
 248
 249 # See if the user has requested runtime debugging.
 250 LIBGCJDEBUG="false"
 251 AC_SUBST(LIBGCJDEBUG)
 252 AC_ARG_ENABLE(libgcj-debug,
 253   AS_HELP_STRING([--enable-libgcj-debug],
 254                  [enable runtime debugging code]),
 255   [if test "$enable_libgcj_debug" = yes; then
 256     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 257     LIBGCJDEBUG="true"
 258   fi])
 259
 260 # Check for gc debugging.  This option is handled both here and in the GC.
 261 AC_ARG_ENABLE(gc-debug,
 262    AS_HELP_STRING([--enable-gc-debug],
 263                   [include full support for pointer backtracing etc.]),
 264 [ if test "$enable_gc_debug" = "yes"; then
 265     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 266               [Define if we want to use debug calls into the garbage collector.])
 267   fi])
 268
 269 # See if the user has the interpreter included.
 270 AC_ARG_ENABLE(interpreter,
 271   AS_HELP_STRING([--enable-interpreter],
 272                  [enable interpreter]),
 273   [if test "$enable_interpreter" = yes; then
 274     # This can also be set in configure.host.
 275     libgcj_interpreter=yes
 276   elif test "$enable_interpreter" = no; then
 277     libgcj_interpreter=no
 278   fi])
 279
 280 if test "$libgcj_interpreter" = yes; then
 281    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 282 fi
 283 INTERPRETER="$libgcj_interpreter"
 284 AC_SUBST(INTERPRETER)
 285
 286 AC_MSG_CHECKING([for exception model to use])
 287 AC_LANG_PUSH(C++)
 288 AC_ARG_ENABLE(sjlj-exceptions,
 289   AS_HELP_STRING([--enable-sjlj-exceptions],
 290                  [force use of builtin_setjmp for exceptions]),
 291 [:],
 292 [dnl Botheration.  Now we've got to detect the exception model.
 293 dnl Link tests against libgcc.a are problematic since -- at least
 294 dnl as of this writing -- we've not been given proper -L bits for
 295 dnl single-tree newlib and libgloss.
 296 dnl
 297 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 298 dnl conftest files before we got a change to grep them first.
 299 cat > conftest.$ac_ext << EOF
 300 [#]line __oline__ "configure"
 301 struct S { ~S(); };
 302 void bar();
 303 void foo()
 304 {
 305   S s;
 306   bar();
 307 }
 308 EOF
 309 old_CXXFLAGS="$CXXFLAGS"
 310 CXXFLAGS=-S
 311 if AC_TRY_EVAL(ac_compile); then
 312   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 313     enable_sjlj_exceptions=yes
 314   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 315     enable_sjlj_exceptions=no
 316   fi
 317 fi
 318 CXXFLAGS="$old_CXXFLAGS"
 319 rm -f conftest*])
 320 if test x$enable_sjlj_exceptions = xyes; then
 321   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 322         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 323   ac_exception_model_name=sjlj
 324 elif test x$enable_sjlj_exceptions = xno; then
 325   ac_exception_model_name="call frame"
 326 else
 327   AC_MSG_ERROR([unable to detect exception model])
 328 fi
 329 AC_LANG_POP(C++)
 330 AC_MSG_RESULT($ac_exception_model_name)
 331
 332 # If we are non using SJLJ exceptions, and this host does not have support
 333 # for unwinding from a signal handler, enable checked dereferences and divides.
 334 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 335   CHECKREFSPEC=-fcheck-references
 336   DIVIDESPEC=-fuse-divide-subroutine
 337   EXCEPTIONSPEC=
 338 fi
 339
 340 # See if the user wants to disable java.net.  This is the mildly
 341 # ugly way that we admit that target-side configuration sucks.
 342 AC_ARG_ENABLE(java-net,
 343   AS_HELP_STRING([--disable-java-net],
 344                  [disable java.net]))
 345
 346 # Whether java.net is built by default can depend on the target.
 347 if test -z "$enable_java_net"; then
 348    enable_java_net=${enable_java_net_default-yes}
 349 fi
 350 if test "$enable_java_net" = no; then
 351    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 352 fi
 353
 354 # See if the user wants to configure without libffi.  Some
 355 # architectures don't support it, and default values are set in
 356 # configure.host.
 357 AC_ARG_WITH(libffi,
 358   AS_HELP_STRING([--without-libffi],
 359                  [don't use libffi]),
 360   [:],
 361   [with_libffi=${with_libffi_default-yes}])
 362
 363 LIBFFI=
 364 LIBFFIINCS=
 365 if test "$with_libffi" != no; then
 366    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 367    LIBFFI=../libffi/libffi_convenience.la
 368    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 369 fi
 370 AC_SUBST(LIBFFI)
 371 AC_SUBST(LIBFFIINCS)
 372
 373 # See if the user wants to disable JVMPI support.
 374 AC_ARG_ENABLE(jvmpi,
 375   AS_HELP_STRING([--disable-jvmpi],
 376                  [disable JVMPI support]))
 377
 378 if test "$enable_jvmpi" != no; then
 379     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 380 fi
 381
 382 # If the target is an eCos system, use the appropriate eCos
 383 # I/O routines.
 384 # FIXME: this should not be a local option but a global target
 385 # system; at present there is no eCos target.
 386 TARGET_ECOS=${PROCESS-"no"}
 387 AC_ARG_WITH(ecos,
 388 [  --with-ecos             enable runtime eCos target support],
 389 TARGET_ECOS="$with_ecos"
 390 )
 391
 392 supply_backtrace=no
 393
 394 PLATFORM_INNER_NAT_HDRS=
 395 case "$TARGET_ECOS" in
 396    no) case "$host" in
 397       *mingw*)
 398             PLATFORM=Win32
 399             PLATFORMNET=Win32
 400             PLATFORMH=win32.h
 401         CHECK_FOR_BROKEN_MINGW_LD
 402       ;;
 403       *)
 404             PLATFORM=Posix
 405             PLATFORMNET=Posix
 406             PLATFORMH=posix.h
 407             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 408       ;;
 409       esac
 410       ;;
 411    *)
 412       PLATFORM=Ecos
 413       PLATFORMNET=NoNet
 414       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 415       PLATFORMH=posix.h
 416       ;;
 417 esac
 418 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 419 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 420
 421 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 422                                       [Define if you have int32_t and uint32_t.]))
 423 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 424                                         [Define if you have int32_t and uint32_t.]))
 425 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 426                                           [Define if you have u_int32_t]))
 427 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 428                                            [Define if you have u_int32_t]))
 429
 430 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 431 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix)
 432 AM_CONDITIONAL(USING_ECOS_PLATFORM, test "$PLATFORM" = Ecos)
 433
 434 case "$host" in
 435   *-darwin*) DARWIN_CRT=true ;;
 436   *) DARWIN_CRT=false ;;
 437 esac
 438 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 439
 440 # These may not be defined in a non-ANS conformant embedded system.
 441 # FIXME: Should these case a runtime exception in that case?
 442 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 443                                   [Define is you have 'mktime' in <time.h>]))
 444 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 445                                   [Define is you have 'localtime' in <time.h>]))
 446
 447 # Create the subdirectory for natFile.cc, or the attempt
 448 # to create the link will fail.
 449 test -d java || mkdir java
 450 test -d java/io || mkdir java/io
 451 test -d gnu || mkdir gnu
 452 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 453
 454 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 455 test -d java/lang || mkdir java/lang
 456 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 457 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 458
 459 # Likewise for natInetAddress.cc and natVMNetworkInterface.cc.
 460 test -d java/net || mkdir java/net
 461 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 462 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 463
 464 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 465 test -d gnu/java || mkdir gnu/java
 466 test -d gnu/java/net || mkdir gnu/java/net
 467 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 468 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 469
 470 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 471 test -d gnu/java/nio || mkdir gnu/java/nio
 472 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 473 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 474 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 475 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 476
 477 case "${host}" in
 478     *mingw*)
 479       SYSTEMSPEC="-lgdi32 -lws2_32"
 480       if test "${with_win32_nlsapi}" = "unicows"; then
 481         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 482       fi
 483     ;;
 484     *)
 485       SYSTEMSPEC=
 486     ;;
 487 esac
 488 AC_SUBST(SYSTEMSPEC)
 489
 490 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 491 AC_SUBST(LIBGCJTESTSPEC)
 492
 493 AC_ARG_WITH(system-zlib,
 494   AS_HELP_STRING([--with-system-zlib],
 495                  [use installed libz]))
 496 ZLIBSPEC=
 497 AC_SUBST(ZLIBSPEC)
 498 ZLIBTESTSPEC=
 499 AC_SUBST(ZLIBTESTSPEC)
 500
 501 AC_PATH_XTRA
 502
 503 # Determine which AWT peer libraries to build
 504 AC_ARG_ENABLE(java-awt,
 505   AS_HELP_STRING([--enable-java-awt],
 506                  [list of AWT peer implementations to be built]))
 507
 508 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 509 use_xlib_awt=""
 510 use_gtk_awt=""
 511 # The default toolkit to use is the first one specified.
 512 TOOLKIT=
 513 AC_SUBST(TOOLKIT)
 514
 515 for peer in $peerlibs ; do
 516   case $peer in
 517     xlib)
 518       if test "$no_x" = yes; then
 519         echo "*** xlib peers requested but no X library available" 1>&2
 520         exit 1
 521       else
 522         use_xlib_awt="yes"
 523         if test -z "$TOOLKIT"; then
 524            TOOLKIT=gnu.awt.xlib.XToolkit
 525         fi
 526       fi
 527       ;;
 528     gtk)
 529       if test "$no_x" = yes; then
 530          echo "*** xlib peers requested but no X library available" 1>&2
 531          exit 1
 532       else
 533          use_gtk_awt=yes
 534          if test -z "$TOOLKIT"; then
 535             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 536          fi
 537          test -d jniinclude || mkdir jniinclude
 538       fi
 539       ;;
 540     no)
 541       use_xlib_awt=
 542       use_gtk_awt=
 543       break
 544       ;;
 545     *)
 546       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 547       exit 1
 548   esac
 549 done
 550
 551 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 552 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 553
 554 # determine whether to enable the cairo GTK Graphics2D backend
 555 AC_ARG_ENABLE(gtk-cairo,
 556   AS_HELP_STRING([--enable-gtk-cairo],
 557                  [build the cairo Graphics2D implementation on GTK]))
 558 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 559 if test "x${enable_gtk_cairo}" = xyes
 560 then
 561         PKG_CHECK_MODULES(CAIRO, cairo)
 562         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 563 fi
 564 AC_SUBST(CAIRO_LIBS)
 565 AC_SUBST(CAIRO_CFLAGS)
 566 AC_SUBST(PANGOFT2_LIBS)
 567 AC_SUBST(PANGOFT2_CFLAGS)
 568
 569 # FIXME: this should be _libs on some hosts.
 570 libsubdir=.libs
 571
 572 # Allow the GC to be disabled.  Can be useful when debugging.
 573 AC_MSG_CHECKING([for garbage collector to use])
 574 AC_ARG_ENABLE(java-gc,
 575   AS_HELP_STRING([--enable-java-gc=TYPE],
 576                  [choose garbage collector (default is boehm)]),
 577   [GC=$enableval],
 578   [GC=boehm])
 579 GCLIBS=
 580 GCINCS=
 581 GCDEPS=
 582 GCSPEC=
 583 JC1GCSPEC=
 584 GCTESTSPEC=
 585 case "$GC" in
 586  boehm)
 587     AC_MSG_RESULT(boehm)
 588     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 589     JC1GCSPEC='-fuse-boehm-gc'
 590     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 591     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 592     GCOBJS=boehm.lo
 593     GCHDR=boehm-gc.h
 594     # The POSIX thread support needs to know this.
 595     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 596     ;;
 597  no)
 598     AC_MSG_RESULT(none)
 599     GCHDR=no-gc.h
 600     ;;
 601  *)
 602     AC_MSG_ERROR([unrecognized collector "$GC"])
 603     ;;
 604 esac
 605 AC_SUBST(GCLIBS)
 606 AC_SUBST(GCINCS)
 607 AC_SUBST(GCDEPS)
 608 AC_SUBST(GCSPEC)
 609 AC_SUBST(JC1GCSPEC)
 610 AC_SUBST(GCTESTSPEC)
 611 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 612 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 613 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 614
 615
 616 AC_MSG_CHECKING([for thread model used by GCC])
 617 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 618 AC_MSG_RESULT([$THREADS])
 619
 620 case "$THREADS" in
 621  no | none | single)
 622     THREADS=none
 623     ;;
 624  posix | posix95 | pthreads)
 625     THREADS=posix
 626     case "$host" in
 627      *-*-linux*)
 628         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 629         ;;
 630     esac
 631     ;;
 632  win32)
 633     ;;
 634  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 635     AC_MSG_ERROR(thread package $THREADS not yet supported)
 636     ;;
 637  *)
 638     AC_MSG_ERROR($THREADS is an unknown thread package)
 639     ;;
 640 esac
 641
 642 THREADCXXFLAGS=
 643 THREADLDFLAGS=
 644 THREADLIBS=
 645 THREADINCS=
 646 THREADDEPS=
 647 THREADH=
 648 THREADSPEC=
 649 case "$THREADS" in
 650  posix)
 651     case "$host" in
 652      *-*-cygwin*)
 653         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 654         ;;
 655      *-*-freebsd[[1234]]*)
 656         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 657         # merely adds pthread_* functions) but it does have a -pthread switch
 658         # which is required at link-time to select -lc_r *instead* of -lc.
 659         THREADLDFLAGS=-pthread
 660         # Don't set THREADSPEC here as might be expected since -pthread is
 661         # not processed when found within a spec file, it must come from
 662         # the command line.  For now, the user must provide the -pthread
 663         # switch to link code compiled with gcj.  In future, consider adding
 664         # support for weak references to pthread_* functions ala gthr.h API.
 665         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 666         ;;
 667      *-*-freebsd*)
 668         # FreeBSD 5 implements a model much closer to other modern UNIX
 669         # which support threads.  However, it still does not support
 670         # -lpthread.
 671         THREADLDFLAGS=-pthread
 672         THREADSPEC=-lc_r
 673         ;;
 674      alpha*-dec-osf*)
 675         THREADCXXFLAGS=-pthread
 676         # boehm-gc needs some functions from librt, so link that too.
 677         THREADLIBS='-lpthread -lrt'
 678         THREADSPEC='-lpthread -lrt'
 679         ;;
 680      *)
 681         THREADLIBS=-lpthread
 682         THREADSPEC=-lpthread
 683         ;;
 684     esac
 685     THREADH=posix-threads.h
 686     # MIT pthreads doesn't seem to have the mutexattr functions.
 687     # But for now we don't check for it.  We just assume you aren't
 688     # using MIT pthreads.
 689     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 690
 691     # If we're using the Boehm GC, then we happen to know that it
 692     # defines _REENTRANT, so we don't bother.  Eww.
 693     if test "$GC" != boehm; then
 694        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 695     fi
 696     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 697     ;;
 698
 699  win32)
 700     THREADH=win32-threads.h
 701     ;;
 702
 703  none)
 704     THREADH=no-threads.h
 705     ;;
 706 esac
 707 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 708 AC_SUBST(THREADLIBS)
 709 AC_SUBST(THREADINCS)
 710 AC_SUBST(THREADDEPS)
 711 AC_SUBST(THREADSPEC)
 712 AC_SUBST(THREADLDFLAGS)
 713 AC_SUBST(THREADCXXFLAGS)
 714 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 715 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 716 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 717
 718 if test -d sysdep; then true; else mkdir sysdep; fi
 719 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 720 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 721
 722 HASH_SYNC_SPEC=
 723 # Hash synchronization is only useful with posix threads right now.
 724 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 725    HASH_SYNC_SPEC=-fhash-synchronization
 726    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 727 fi
 728 AC_SUBST(HASH_SYNC_SPEC)
 729
 730 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 731
 732 # We're in the tree with gcc, and need to include some of its headers.
 733 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 734
 735 if test "x${with_newlib}" = "xyes"; then
 736    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 737    # may not work correctly, because the compiler may not be able to
 738    # link executables.
 739
 740    # We assume newlib.  This lets us hard-code the functions we know
 741    # we'll have.
 742    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 743    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 744    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 745    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 746    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 747    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 748    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 749    # This is only for POSIX threads.
 750    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 751    # We also assume we are using gcc, which provides alloca.
 752    AC_DEFINE(HAVE_ALLOCA)
 753
 754    # Assume we do not have getuid and friends.
 755    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 756    PLATFORMNET=NoNet
 757 else
 758    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 759                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 760                    access stat mkdir rename rmdir unlink realpath utime chmod \
 761                    nl_langinfo setlocale \
 762                    inet_pton uname inet_ntoa \
 763                    fork execvp pipe sigaction ftruncate])
 764    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 765    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 766    AC_CHECK_FUNC(backtrace, [
 767      case "$host" in
 768        ia64-*-linux*)
 769          # Has broken backtrace()
 770          ;;
 771        mips*-*-linux*)
 772          # Has broken backtrace(), but we supply our own.
 773          if test -d sysdep; then true; else mkdir -p sysdep; fi
 774          supply_backtrace=yes
 775          AC_DEFINE(HAVE_BACKTRACE, 1,
 776            [Define if your platform has a working backtrace() function.])
 777          ;;
 778        *)
 779          AC_DEFINE(HAVE_BACKTRACE, 1,
 780            [Define if your platform has a working backtrace() function.])
 781          ;;
 782      esac
 783    ], [
 784      case "$host" in
 785        *mingw*)
 786          # Has backtrace() defined in libgcj itself
 787          AC_DEFINE(HAVE_BACKTRACE, 1,
 788            [Define if your platform has a working backtrace() function.])
 789          ;;
 790      esac
 791    ])
 792
 793    AC_CHECK_LIB(dl, dladdr, [
 794      if test "x${disable_dladdr}" = "xyes"; then
 795        #Broken dladdr().
 796        true
 797      else
 798        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])
 799      fi
 800    ])
 801    if test x"$build" = x"$host"; then
 802      AC_CHECK_FILES(/proc/self/exe, [
 803        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 804    else
 805      case $host in
 806      *-linux*)
 807        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 808        ;;
 809      esac
 810    fi
 811
 812    AM_ICONV
 813    AM_LC_MESSAGES
 814    AC_STRUCT_TIMEZONE
 815
 816    AC_CHECK_FUNCS(gethostbyname_r, [
 817      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 818        [Define if you have the 'gethostbyname_r' function.])
 819      # There are two different kinds of gethostbyname_r.
 820      # We look for the one that returns `int'.
 821      # Hopefully this check is robust enough.
 822      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 823        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 824
 825      case " $GCINCS " in
 826      *" -D_REENTRANT "*) ;;
 827      *)
 828         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 829         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 830         [libjava_cv_gethostbyname_r_needs_reentrant],
 831         [ AC_LANG_PUSH(C++)
 832           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 833             [[gethostbyname_r("", 0, 0);]])],
 834             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 835                 CPPFLAGS_SAVE="$CPPFLAGS"
 836                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 837                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 838                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 839                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 840                 CPPFLAGS="$CPPFLAGS_SAVE"
 841           ])
 842           AC_LANG_POP(C++)
 843         ])
 844         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 845           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 846         fi
 847      ;;
 848      esac
 849
 850      AC_CACHE_CHECK([for struct hostent_data],
 851         [libjava_cv_struct_hostent_data], [dnl
 852         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 853 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 854 # define _REENTRANT 1
 855 #endif
 856 #include <netdb.h>]], [[struct hostent_data data;]])],
 857           [libjava_cv_struct_hostent_data=yes],
 858           [libjava_cv_struct_hostent_data=no])])
 859      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 860        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 861          [Define if struct hostent_data is defined in netdb.h])
 862      fi
 863    ])
 864
 865    # FIXME: libjava source code expects to find a prototype for
 866    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 867    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 868    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 869    # linkage check is enough, yet C++ code requires proper prototypes.)
 870    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 871    AC_CHECK_FUNCS(gethostbyaddr_r, [
 872      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 873        [Define if you have the 'gethostbyaddr_r' function.])
 874      # There are two different kinds of gethostbyaddr_r.
 875      # We look for the one that returns `int'.
 876      # Hopefully this check is robust enough.
 877      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 878        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 879          [Define if gethostbyaddr_r returns 'int'.])])])])
 880
 881    AC_CHECK_FUNCS(gethostname, [
 882      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 883        [Define if you have the 'gethostname' function.])
 884      AC_EGREP_HEADER(gethostname, unistd.h, [
 885        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 886          [Define if gethostname is declared in <unistd.h>.])])])
 887
 888    AC_CHECK_FUNCS(usleep, [
 889      AC_EGREP_HEADER(usleep, unistd.h, [
 890        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 891           [Define if usleep is declared in <unistd.h>.])])])
 892
 893    # Look for these functions in the thread library, but only bother
 894    # if using POSIX threads.
 895    if test "$THREADS" = posix; then
 896       save_LIBS="$LIBS"
 897       LIBS="$LIBS $THREADLIBS"
 898       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 899       # E.g., Solaris.
 900       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 901
 902       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 903       # Solaris 7 the name librt is preferred.
 904       AC_CHECK_FUNCS(sched_yield, , [
 905         AC_CHECK_LIB(rt, sched_yield, [
 906           AC_DEFINE(HAVE_SCHED_YIELD)
 907           THREADLIBS="$THREADLIBS -lrt"
 908           THREADSPEC="$THREADSPEC -lrt"], [
 909           AC_CHECK_LIB(posix4, sched_yield, [
 910             AC_DEFINE(HAVE_SCHED_YIELD)
 911             THREADLIBS="$THREADLIBS -lposix4"
 912             THREADSPEC="$THREADSPEC -lposix4"])])])
 913       LIBS="$save_LIBS"
 914
 915       # We can save a little space at runtime if the mutex has m_count
 916       # or __m_count.  This is a nice hack for Linux.
 917       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
 918           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 919         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
 920              [Define if pthread_mutex_t has m_count member.]), [
 921         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
 922             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 923           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
 924             [Define if pthread_mutex_t has __m_count member.]))])
 925    fi
 926
 927    # We require a way to get the time.
 928    time_found=no
 929    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 930    if test "$time_found" = no; then
 931       AC_MSG_ERROR([no function found to get the time])
 932    fi
 933
 934    AC_CHECK_FUNCS(memmove)
 935
 936    # We require memcpy.
 937    memcpy_found=no
 938    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 939    if test "$memcpy_found" = no; then
 940       AC_MSG_ERROR([memcpy is required])
 941    fi
 942
 943    AC_CHECK_LIB(dl, dlopen, [
 944        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
 945
 946    # Some library-finding code we stole from Tcl.
 947    #--------------------------------------------------------------------
 948    #    Check for the existence of the -lsocket and -lnsl libraries.
 949    #    The order here is important, so that they end up in the right
 950    #    order in the command line generated by make.  Here are some
 951    #    special considerations:
 952    #    1. Use "connect" and "accept" to check for -lsocket, and
 953    #       "gethostbyname" to check for -lnsl.
 954    #    2. Use each function name only once:  can't redo a check because
 955    #       autoconf caches the results of the last check and won't redo it.
 956    #    3. Use -lnsl and -lsocket only if they supply procedures that
 957    #       aren't already present in the normal libraries.  This is because
 958    #       IRIX 5.2 has libraries, but they aren't needed and they're
 959    #       bogus:  they goof up name resolution if used.
 960    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 961    #       To get around this problem, check for both libraries together
 962    #       if -lsocket doesn't work by itself.
 963    #--------------------------------------------------------------------
 964
 965    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 966     [gcj_cv_lib_sockets=
 967      gcj_checkBoth=0
 968      unset ac_cv_func_connect
 969      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 970      if test "$gcj_checkSocket" = 1; then
 971          unset ac_cv_func_connect
 972          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 973                       gcj_checkBoth=1)
 974      fi
 975      if test "$gcj_checkBoth" = 1; then
 976          gcj_oldLibs=$LIBS
 977          LIBS="$LIBS -lsocket -lnsl"
 978          unset ac_cv_func_accept
 979          AC_CHECK_FUNC(accept,
 980                        [gcj_checkNsl=0
 981                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 982          unset ac_cv_func_accept
 983          LIBS=$gcj_oldLibs
 984      fi
 985      unset ac_cv_func_gethostbyname
 986      gcj_oldLibs=$LIBS
 987      LIBS="$LIBS $gcj_cv_lib_sockets"
 988      AC_CHECK_FUNC(gethostbyname, ,
 989                    [AC_CHECK_LIB(nsl, main,
 990                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 991      unset ac_cv_func_gethostbyname
 992      LIBS=$gcj_oldLIBS
 993    ])
 994    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 995
 996    if test "$with_system_zlib" = yes; then
 997       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
 998    fi
 999
1000    # Test for Gtk stuff, if asked for.
1001    if test "$use_gtk_awt" = yes; then
1002       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1003       AC_SUBST(GTK_CFLAGS)
1004       AC_SUBST(GTK_LIBS)
1005
1006       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1007       AC_SUBST(GLIB_CFLAGS)
1008       AC_SUBST(GLIB_LIBS)
1009
1010       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1011       AC_SUBST(LIBART_CFLAGS)
1012       AC_SUBST(LIBART_LIBS)
1013
1014       # We require the XTest Extension to support java.awt.Robot.
1015       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1016                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1017                    [${X_LIBS}])
1018    fi
1019
1020    # On Solaris, and maybe other architectures, the Boehm collector
1021    # requires -ldl.
1022    if test "$GC" = boehm; then
1023       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1024    fi
1025 fi
1026 AM_CONDITIONAL(SUPPLY_BACKTRACE, test "$supply_backtrace" = yes)
1027
1028 if test -z "${with_multisubdir}"; then
1029    builddotdot=.
1030 else
1031    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
1032 fi
1033
1034 NATIVE=yes
1035
1036 # Which gcj do we use?
1037 which_gcj=default
1038 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
1039 if test -n "${with_cross_host}"; then
1040   # We are being configured with a cross compiler. We can't
1041   # use ac_exeext, because that is for the target platform.
1042   NATIVE=no
1043   cross_host_exeext=
1044   case "${with_cross_host}" in
1045      *mingw* | *cygwin*)
1046          cross_host_exeext=.exe
1047      ;;
1048   esac
1049   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
1050      if test x"$build_noncanonical" = x"$with_cross_host"; then
1051         # Ordinary cross (host!=target and host=build)
1052         which_gcj=built
1053      else
1054         # Canadian cross (host!=target and host!=build)
1055         which_gcj=cross
1056      fi
1057   else
1058      which_gcj=cross
1059   fi
1060 else
1061   # We are being configured with a native or crossed-native compiler
1062   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
1063      if test x"$build" = x"$host"; then
1064         # True native build (host=target and host=build)
1065         which_gcj=built
1066      else
1067         # Crossed-native build (host=target and host!=build)
1068         which_gcj=cross
1069      fi
1070   else
1071      which_gcj=path
1072   fi
1073 fi
1074 case "${which_gcj}" in
1075    built)
1076       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
1077       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
1078       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/fastjar/fastjar'
1079    ;;
1080    cross)
1081       if test "x${with_newlib}" = "xyes"; then
1082          # FIXME (comment): Why is this needed?
1083          GCC_UNWIND_INCLUDE=
1084          GCJ="${target_noncanonical}-gcj"
1085       else
1086          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
1087       fi
1088       ZIP='$(target_noncanonical)-fastjar'
1089       GCJH='$(target_noncanonical)-gcjh'
1090    ;;
1091    path)
1092       GCJ="gcj -B`${PWDCMD-pwd}`/"
1093       ## In this case, gcj is found outside the build tree.  However, zip is
1094       ## found in the build tree.
1095       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
1096       GCJH=gcjh
1097    ;;
1098 esac
1099
1100 AC_SUBST(GCJH)
1101 AC_SUBST(ZIP)
1102
1103 # Create it, so that compile/link tests don't fail
1104 test -f libgcj.spec || touch libgcj.spec
1105
1106 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1107 case $build in
1108     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1109     *)         CLASSPATH_SEPARATOR=':' ;;
1110 esac
1111 AC_SUBST(CLASSPATH_SEPARATOR)
1112
1113 # We must search the source tree for java.lang, since we still don't
1114 # have libgcj.jar nor java/lang/*.class
1115 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1116 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1117
1118 # Since some classes depend on this one, we need its source available
1119 # before we can do any GCJ compilation test :-(
1120 if test ! -f gnu/classpath/Configuration.java; then
1121   test -d gnu || mkdir gnu
1122   test -d gnu/classpath || mkdir gnu/classpath
1123   sed -e 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
1124       -e 's,@TOOLKIT@,$TOOLKIT,' \
1125         < $srcdir/gnu/classpath/Configuration.java.in \
1126         > gnu/classpath/Configuration.java
1127   # We do not want to redirect the output of the grep below to /dev/null,
1128   # but we add /dev/null to the input list so that grep will print the
1129   # filename of Configuration.java in case it finds any matches.
1130   if grep @ gnu/classpath/Configuration.java /dev/null; then
1131     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1132   fi
1133 fi
1134
1135 LT_AC_PROG_GCJ
1136
1137 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1138
1139 AC_COMPILE_CHECK_SIZEOF(void *)
1140
1141 AC_C_BIGENDIAN_CROSS
1142
1143 ZLIBS=
1144 SYS_ZLIBS=
1145 ZINCS=
1146
1147 if test -z "$ZLIBSPEC"; then
1148    # Use zlib from the GCC tree.
1149    ZINCS='-I$(top_srcdir)/../zlib'
1150    ZLIBS=../zlib/libzgcj_convenience.la
1151 else
1152    # System's zlib.
1153    SYS_ZLIBS="$ZLIBSPEC"
1154 fi
1155 AC_SUBST(ZLIBS)
1156 AC_SUBST(SYS_ZLIBS)
1157 AC_SUBST(ZINCS)
1158 AC_SUBST(DIVIDESPEC)
1159 AC_SUBST(CHECKREFSPEC)
1160 AC_SUBST(EXCEPTIONSPEC)
1161 AC_SUBST(IEEESPEC)
1162
1163 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1164 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1165 AC_SUBST(GCC_UNWIND_INCLUDE)
1166
1167 # Process the option "--enable-version-specific-runtime-libs"
1168 # Calculate toolexeclibdir
1169 case ${version_specific_libs} in
1170   yes)
1171     # Need the gcc compiler version to know where to install libraries
1172     # and header files if --enable-version-specific-runtime-libs option
1173     # is selected.
1174     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1175     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1176     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1177     toolexeclibdir=$toolexecmainlibdir
1178     ;;
1179   no)
1180     if test -n "$with_cross_host" &&
1181        test x"$with_cross_host" != x"no"; then
1182       # Install a library built with a cross compiler in tooldir, not libdir.
1183       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1184       toolexecmainlibdir='$(toolexecdir)/lib'
1185     else
1186       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1187       toolexecmainlibdir='$(libdir)'
1188     fi
1189     multi_os_directory=`$CC -print-multi-os-directory`
1190     case $multi_os_directory in
1191       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1192       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1193     esac
1194     ;;
1195 esac
1196 AC_SUBST(toolexecdir)
1197 AC_SUBST(toolexecmainlibdir)
1198 AC_SUBST(toolexeclibdir)
1199
1200 # Determine gcj version number.
1201 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1202 GCJVERSION=$gcjversion
1203 AC_SUBST(GCJVERSION)
1204 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1205
1206 AC_DEFINE(JV_VERSION, "1.4.2", [Compatibility version string])
1207 AC_DEFINE(JV_API_VERSION, "1.4", [API compatibility version string])
1208
1209 TL_AC_GXX_INCLUDE_DIR
1210
1211 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1212 # On that system, sys/ioctl.h will not include sys/filio.h unless
1213 # BSD_COMP is defined; just including sys/filio.h is simpler.
1214 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1215 # for now.  If you change this, you also must update natFile.cc.
1216 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1217                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1218                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1219                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1220                   dirent.h])
1221 AC_CHECK_HEADERS(inttypes.h, [
1222     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1223     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1224 ])
1225 AC_HEADER_SYS_WAIT
1226
1227 AC_CHECK_TYPE([ssize_t], [int])
1228
1229 AC_MSG_CHECKING([for in_addr_t])
1230 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1231 #if STDC_HEADERS
1232 #include <stdlib.h>
1233 #include <stddef.h>
1234 #endif
1235 #if HAVE_NETINET_IN_H
1236 #include <netinet/in.h>
1237 #endif]], [[in_addr_t foo;]])],
1238   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1239      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1240    AC_MSG_RESULT(yes)],
1241   [AC_MSG_RESULT(no)])
1242
1243 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1244 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1245   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1246      [Define if struct ip_mreq is defined in netinet/in.h.])
1247    AC_MSG_RESULT(yes)],
1248   [AC_MSG_RESULT(no)])
1249
1250 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1251 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1252   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1253      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1254    AC_MSG_RESULT(yes)],
1255   [AC_MSG_RESULT(no)])
1256
1257 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1258 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1259   [AC_DEFINE(HAVE_INET6, 1,
1260      [Define if inet6 structures are defined in netinet/in.h.])
1261    AC_MSG_RESULT(yes)],
1262   [AC_MSG_RESULT(no)])
1263
1264 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1265 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1266 #include <sys/types.h>
1267 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1268   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1269    AC_MSG_RESULT(yes)],
1270   [AC_MSG_RESULT(no)])
1271
1272 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1273 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1274   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1275    AC_MSG_RESULT(yes)],
1276   [AC_MSG_RESULT(no)
1277    AC_MSG_CHECKING([for global timezone variable])
1278    dnl FIXME: we don't want a link check here because that won't work
1279    dnl when cross-compiling.  So instead we make an assumption that
1280    dnl the header file will mention timezone if it exists.
1281    dnl Don't find the win32 function timezone
1282    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1283      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1284       AC_MSG_RESULT(yes)],
1285      [AC_MSG_RESULT(no)
1286        AC_MSG_CHECKING([for global _timezone variable])
1287        dnl FIXME: As above, don't want link check
1288        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1289          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1290             [Define if your platform has the global _timezone variable.])
1291           AC_MSG_RESULT(yes)],
1292           [AC_MSG_RESULT(no)])])])
1293
1294 AC_FUNC_ALLOCA
1295 AC_FUNC_MMAP
1296
1297 AC_CHECK_PROGS(PERL, perl, false)
1298
1299 SYSDEP_SOURCES=
1300 SIGNAL_HANDLER_AUX=
1301
1302 case "${host}" in
1303  i?86-*-linux*)
1304     SIGNAL_HANDLER=include/i386-signal.h
1305     ;;
1306  sparc*-sun-solaris*)
1307     SIGNAL_HANDLER=include/sparc-signal.h
1308     ;;
1309 # ia64-*)
1310 #    SYSDEP_SOURCES=sysdep/ia64.c
1311 #    test -d sysdep || mkdir sysdep
1312 #    ;;
1313  hppa*-*-linux*)
1314     SIGNAL_HANDLER=include/pa-signal.h
1315     ;;
1316  ia64-*-linux*)
1317     SIGNAL_HANDLER=include/dwarf2-signal.h
1318     ;;
1319  powerpc*-*-linux*)
1320     SIGNAL_HANDLER=include/powerpc-signal.h
1321     ;;
1322  alpha*-*-linux*)
1323     SIGNAL_HANDLER=include/dwarf2-signal.h
1324     ;;
1325  s390*-*-linux*)
1326     SIGNAL_HANDLER=include/s390-signal.h
1327     ;;
1328  x86_64*-*-linux*)
1329     SIGNAL_HANDLER=include/x86_64-signal.h
1330     SIGNAL_HANDLER_AUX=include/i386-signal.h
1331     ;;
1332  sparc*-*-linux*)
1333     SIGNAL_HANDLER=include/dwarf2-signal.h
1334     ;;
1335  sh*-*-linux*)
1336     SIGNAL_HANDLER=include/sh-signal.h
1337     ;;
1338  *mingw*)
1339     SIGNAL_HANDLER=include/win32-signal.h
1340     ;;
1341  mips*-*-linux*)
1342     SIGNAL_HANDLER=include/mips-signal.h
1343     ;;
1344  *-*-darwin*)
1345     SIGNAL_HANDLER=include/darwin-signal.h
1346     ;;
1347  *)
1348     SIGNAL_HANDLER=include/default-signal.h
1349     ;;
1350 esac
1351
1352 # If we're using sjlj exceptions, forget what we just learned.
1353 if test "$enable_sjlj_exceptions" = yes; then
1354    SIGNAL_HANDLER=include/default-signal.h
1355    SIGNAL_HANDLER_AUX=
1356 fi
1357
1358 # Define here any compiler flags that you need in order to make backtrace() work.
1359 BACKTRACESPEC=
1360 case "${host}" in
1361  x86_64*-*-linux*|i?86-*)
1362     BACKTRACESPEC=-fno-omit-frame-pointer
1363     ;;
1364 esac
1365 AC_SUBST(BACKTRACESPEC)
1366
1367 AC_SUBST(SYSDEP_SOURCES)
1368
1369 if test -z "$SIGNAL_HANDLER_AUX"; then
1370   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1371 fi
1372
1373 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1374                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1375
1376 if test "${multilib}" = "yes"; then
1377   multilib_arg="--enable-multilib"
1378 else
1379   multilib_arg=
1380 fi
1381
1382
1383
1384 here=`${PWDCMD-pwd}`
1385 AC_SUBST(here)
1386
1387 # We get this from the environment.
1388 AC_SUBST(GCJFLAGS)
1389
1390 AC_CONFIG_FILES([
1391 Makefile
1392 libgcj.pc
1393 libgcj.spec
1394 libgcj-test.spec
1395 gnu/classpath/Configuration.java
1396 gcj/Makefile
1397 include/Makefile
1398 testsuite/Makefile
1399 external/Makefile
1400 external/sax/Makefile
1401 external/w3c_dom/Makefile
1402 ])
1403
1404 AC_CONFIG_COMMANDS([default],
1405 [# Only add multilib support code if we just rebuilt top-level Makefile.
1406 case " $CONFIG_FILES " in
1407  *" Makefile "*)
1408    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1409    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1410    ;;
1411 esac
1412 for ac_multi_file in $CONFIG_FILES; do
1413   case $ac_multi_file in
1414   */Makefile)
1415     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1416   esac
1417 done
1418 ],
1419 srcdir=${srcdir}
1420 host=${host}
1421 target=${target}
1422 with_multisubdir=${with_multisubdir}
1423 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1424 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1425 libgcj_basedir=${libgcj_basedir}
1426 CC="${CC}"
1427 CXX="${CXX}"
1428 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1429 )
1430
1431 AC_OUTPUT