libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.64)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 GCC_LIBSTDCXX_RAW_CXX_FLAGS
  28
  29 # This works around the fact that libtool configuration may change LD
  30 # for this particular configuration, but some shells, instead of
  31 # keeping the changes in LD private, export them just because LD is
  32 # exported.
  33 ORIGINAL_LD_FOR_MULTILIBS=$LD
  34
  35 AC_PROG_LN_S
  36
  37 # This works around an automake problem.
  38 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  39 AC_SUBST(mkinstalldirs)
  40
  41 AC_ARG_WITH(cross-host,
  42   AS_HELP_STRING([--with-cross-host=HOST],
  43                  [configure with a cross compiler from HOST]))
  44
  45 AC_ARG_WITH(newlib,
  46   AS_HELP_STRING([--with-newlib],
  47                  [configure with newlib]))
  48
  49 AC_ARG_ENABLE(version-specific-runtime-libs,
  50   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  51                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  52     [case "$enableval" in
  53       yes) version_specific_libs=yes ;;
  54       no)  version_specific_libs=no ;;
  55       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  56      esac],
  57     [version_specific_libs=no]
  58 )
  59
  60 AC_ARG_ENABLE(browser-plugin,
  61   AS_HELP_STRING([--enable-browser-plugin],
  62                  [build gcjwebplugin web browser plugin]),
  63     [case "$enableval" in
  64       yes) browser_plugin_enabled=yes ;;
  65       no)  browser_plugin_enabled=no ;;
  66       *)   AC_MSG_ERROR([Unknown argument to enable/disable browser plugin]);;
  67      esac],
  68     [browser_plugin_enabled=no]
  69 )
  70
  71 AC_ARG_ENABLE(gconf-peer,
  72   AS_HELP_STRING([--enable-gconf-peer],
  73                  [compile GConf native peers for util.preferences]),
  74     [case "$enableval" in
  75       yes) gconf_enabled=yes ;;
  76       no)  gconf_enabled=no ;;
  77       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  78      esac],
  79     [gconf_enabled=no]
  80 )
  81
  82 AC_ARG_WITH([antlr-jar],
  83             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  84             [
  85              ANTLR_JAR=$withval
  86             ],
  87             [
  88              ANTLR_JAR=
  89             ])
  90
  91 AC_MSG_CHECKING([for antlr.jar])
  92 if test "x$ANTLR_JAR" = x; then
  93     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  94         /usr/share/antlr/lib /usr/share/java /usr/lib;
  95     do
  96         if test -f "$antlr_lib_home/antlr.jar"; then
  97             # FIXME: version check for antlr needed without using a VM
  98             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  99             break
 100         fi
 101     done
 102     if test "x$ANTLR_JAR" = x; then
 103         AC_MSG_RESULT([not found])
 104     else
 105         AC_MSG_RESULT($ANTLR_JAR)
 106     fi
 107 else
 108     if test -f "${ANTLR_JAR}"; then
 109         AC_MSG_RESULT($ANTLR_JAR)
 110     else
 111         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 112     fi
 113 fi
 114 AC_SUBST(ANTLR_JAR)
 115
 116 AC_ARG_ENABLE([gjdoc],
 117               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 118               [case "${enableval}" in
 119                 yes) BUILD_GJDOC=yes ;;
 120                 no) BUILD_GJDOC=no ;;
 121                 *) BUILD_GJDOC=yes ;;
 122               esac],
 123               [BUILD_GJDOC=maybe])
 124
 125 AC_MSG_CHECKING([whether to build gjdoc])
 126 if test "x$BUILD_GJDOC" = xmaybe; then
 127     if test -f "${ANTLR_JAR}"; then
 128         BUILD_GJDOC=yes
 129         AC_MSG_RESULT(yes)
 130     else
 131         BUILD_GJDOC=no
 132         AC_MSG_RESULT([no, antlr.jar not found])
 133     fi
 134 else
 135     AC_MSG_RESULT($BUILD_GJDOC)
 136 fi
 137 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 138
 139 AC_ARG_ENABLE(java-maintainer-mode,
 140         AS_HELP_STRING([--enable-java-maintainer-mode],
 141         [allow rebuilding of .class and .h files]))
 142 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 143
 144 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 145 GCC_NO_EXECUTABLES
 146
 147 # For libstdc++-v3, -fno-builtin must be present here so that a
 148 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 149 # used in later tests.  This may not be necessary in libjava; I don't know.
 150 save_CXXFLAGS="$CXXFLAGS"
 151 CXXFLAGS="$CXXFLAGS -fno-builtin"
 152 AC_PROG_CC
 153 AC_PROG_CXX
 154 CXXFLAGS="$save_CXXFLAGS"
 155
 156 AM_INIT_AUTOMAKE([no-dist 1.9.0])
 157
 158 AC_CHECK_TOOL(AS, as)
 159 AC_CHECK_TOOL(LD, ld)
 160 AC_CHECK_TOOL(AR, ar)
 161 AC_CHECK_TOOL(RANLIB, ranlib, :)
 162 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 163 AC_PROG_AWK
 164 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 165 AC_PATH_PROG([ZIP], [zip], no)
 166 AC_PATH_PROG([UNZIP], [unzip], unzip)
 167
 168 # We need a jar that supports -@.  This is a GNU extension.
 169 if test "$JAR" != no; then
 170    rm -f config-test.jar
 171    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar >/dev/null 2>&1
 172    if test -f config-test.jar; then
 173      rm -f config-test.jar
 174    else
 175      JAR=no
 176    fi
 177 fi
 178
 179 # Prefer the jar we found, but fall back to our jar script.
 180 if test "$JAR" = no; then
 181   if test "$ZIP" = no; then
 182     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 183   else
 184     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 185     JAR=`pwd`/scripts/jar
 186   fi
 187 fi
 188
 189 AC_PROG_INSTALL
 190
 191 AM_MAINTAINER_MODE
 192
 193 AC_EXEEXT
 194
 195 # configure.host sets the following important variables
 196 #       libgcj_cflags    - host specific C compiler flags
 197 #       libgcj_cxxflags  - host specific C++ compiler flags
 198 #       libgcj_javaflags - host specific Java compiler flags
 199 #       libgcj_sublib_ltflags - host specific Libtool flags
 200 #       libgcj_sublib_core_extra_deps - host specific extra
 201 #                          dependencies for core sublib
 202 #       (these last two only used when building sublibs)
 203 # and a number of others; see the list at the start of the file.
 204
 205 libgcj_cflags=
 206 libgcj_cxxflags=
 207 libgcj_javaflags=
 208 libgcj_sublib_ltflags=
 209 libgcj_sublib_core_extra_deps=
 210
 211 . ${srcdir}/configure.host
 212
 213 ACX_PROG_LD_GNU_SYMBOLIC
 214 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 215 if test -z "$libgcj_ld_symbolic"; then
 216   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 217 fi
 218
 219 # for windows native targets enforce export of all symbols for shared libgcj.
 220 libgcj_ld_export_all=
 221 case "$host" in
 222       *mingw*)
 223         libgcj_ld_export_all=-Wl,--export-all-symbols
 224         ;;
 225       *)
 226         ;;
 227 esac
 228
 229 LIBGCJ_CFLAGS="${libgcj_cflags}"
 230 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 231 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 232 LIBGCJ_SUBLIB_LTFLAGS="${libgcj_sublib_ltflags}"
 233 LIBGCJ_SUBLIB_CORE_EXTRA_DEPS="${libgcj_sublib_core_extra_deps}"
 234 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 235 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 236 LIBGCJ_LD_EXPORT_ALL="${libgcj_ld_export_all}"
 237 AC_SUBST(LIBGCJ_CFLAGS)
 238 AC_SUBST(LIBGCJ_CXXFLAGS)
 239 AC_SUBST(LIBGCJ_JAVAFLAGS)
 240 AC_SUBST(LIBGCJ_SUBLIB_LTFLAGS)
 241 AC_SUBST(LIBGCJ_SUBLIB_CORE_EXTRA_DEPS)
 242 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 243 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 244 AC_SUBST(LIBGCJ_LD_EXPORT_ALL)
 245
 246 # Only use libltdl for non-newlib builds.
 247 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 248    AC_LTDL_SHLIBPATH
 249 fi
 250
 251 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 252
 253 # Possibly build libgcj as many sub-libraries.
 254 AC_ARG_ENABLE(libgcj-sublibs,
 255   AS_HELP_STRING([--enable-libgcj-sublibs],
 256                  [build libgcj as many sub-libraries]))
 257
 258 if test -z "$enable_libgcj_sublibs"; then
 259    enable_libgcj_sublibs=$enable_libgcj_sublibs_default
 260 fi
 261 AM_CONDITIONAL(BUILD_SUBLIBS, test "$enable_libgcj_sublibs" = yes)
 262 if test "$enable_libgcj_sublibs" = yes ; then
 263   # In theory we could make do with only one override and simply
 264   # tag "_bc" onto the end of it when we use it to generate the
 265   # spec, but that's an ugly thing to do when there are multiple
 266   # words in the string and you're relying on the ordering to
 267   # append the correct one.
 268   libgcj_spec_lgcj_override="-lgcj-noncore -lgcj"
 269   libgcj_spec_lgcj_bc_override="-lgcj-noncore -lgcj_bc"
 270 fi
 271
 272
 273 # See if the user has requested runtime debugging.
 274 LIBGCJDEBUG="disable"
 275 AC_SUBST(LIBGCJDEBUG)
 276 AC_ARG_ENABLE(libgcj-debug,
 277   AS_HELP_STRING([--enable-libgcj-debug],
 278                  [enable runtime debugging code]),
 279   [if test "$enable_libgcj_debug" = yes; then
 280     AC_DEFINE(__GCJ_DEBUG, 1, [Define this if you want runtime debugging enabled.])
 281     LIBGCJDEBUG="enable"
 282   fi])
 283
 284 AC_ARG_WITH([escher],
 285          AS_HELP_STRING([--with-escher=ABS.PATH],
 286                         [specify path to escher dir or JAR for X peers]))
 287 case "$with_escher" in
 288 "")
 289         use_escher=false
 290         ;;
 291 "no")
 292         use_escher=false
 293         ;;
 294 "yes")
 295         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 296         ;;
 297 *)
 298         use_escher=true
 299         ;;
 300 esac
 301
 302 # Determine which AWT peer libraries to build
 303 AC_ARG_ENABLE(java-awt,
 304   AS_HELP_STRING([--enable-java-awt],
 305                  [list of AWT peer implementations to be built]))
 306
 307 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 308 use_xlib_awt=""
 309 use_gtk_awt=""
 310 use_qt_awt=""
 311 use_x_awt=""
 312 # The default toolkit to use is the first one specified.
 313 TOOLKIT=
 314 AC_SUBST(TOOLKIT)
 315
 316 for peer in $peerlibs ; do
 317   case $peer in
 318     xlib)
 319       if test "$no_x" = yes; then
 320         echo "*** xlib peers requested but no X library available" 1>&2
 321         exit 1
 322       else
 323         use_xlib_awt="yes"
 324         if test -z "$TOOLKIT"; then
 325            TOOLKIT=gnu.awt.xlib.XToolkit
 326         fi
 327       fi
 328       ;;
 329     gtk)
 330       if test "$no_x" = yes; then
 331          echo "*** gtk peers requested but no X library available" 1>&2
 332          exit 1
 333       else
 334          use_gtk_awt=yes
 335          if test -z "$TOOLKIT"; then
 336             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 337          fi
 338       fi
 339       ;;
 340     qt)
 341       if test "$no_x" = yes; then
 342          # Perhaps we should admit the possibility of embedded Qt.
 343          echo "*** Qt peers requested but no X library available" 1>&2
 344          exit 1
 345       else
 346          use_qt_awt=yes
 347          if test -z "$TOOLKIT"; then
 348             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 349          fi
 350       fi
 351       ;;
 352     x)
 353       use_x_awt=yes
 354       if test -z "$TOOLKIT"; then
 355          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 356       fi
 357       ;;
 358     no)
 359       use_xlib_awt=
 360       use_gtk_awt=
 361       use_qt_awt=
 362       use_x_awt=
 363       break
 364       ;;
 365     *)
 366       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 367       exit 1
 368   esac
 369 done
 370
 371 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 372 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 373
 374 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 375
 376 expanded_prefix=$prefix
 377 if test "X$prefix" = XNONE; then
 378   expanded_prefix=${ac_default_prefix}
 379 fi
 380
 381 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$expanded_prefix", [Installation prefix])
 382
 383 # Create standard.omit based on decisions we just made.
 384 cp $srcdir/standard.omit.in standard.omit
 385 if test "$use_xlib_awt" != yes; then
 386    echo gnu/awt/xlib >> standard.omit
 387    echo gnu/gcj/xlib >> standard.omit
 388 fi
 389 if test "$use_x_awt" != yes; then
 390    echo gnu/java/awt/peer/x >> standard.omit
 391 fi
 392
 393 # Tools that need to be compiled against classpath's tools classes
 394 : > vm-tools-packages
 395 for package in gnu/gcj/tools/gc_analyze ; do
 396     echo $package >> standard.omit
 397     echo $package >> vm-tools-packages
 398 done
 399
 400 if test -z "${with_multisubdir}"; then
 401    builddotdot=.
 402 else
 403    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 404 fi
 405
 406 NATIVE=yes
 407
 408 # Which gcj and host gcj (for ecjx) do we use?
 409 which_gcj=default
 410 host_exeext=${ac_exeext}
 411 GCJ_FOR_ECJX='$(GCJ)'
 412 GCC_FOR_ECJX='$(CXX)'
 413 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 414 if test -n "${with_cross_host}"; then
 415   # We are being configured with a cross compiler. We can't
 416   # use ac_exeext, because that is for the target platform.
 417   NATIVE=no
 418   cross_host_exeext=
 419   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 420   GCC_FOR_ECJX="${with_cross_host}-gcc"
 421   case "${with_cross_host}" in
 422      *mingw* | *cygwin*)
 423          cross_host_exeext=.exe
 424      ;;
 425   esac
 426   host_exeext=${cross_host_exeext}
 427   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 428      if test x"$build_noncanonical" = x"$with_cross_host"; then
 429         # Ordinary cross (host!=target and host=build)
 430         which_gcj=built
 431      else
 432         # Canadian cross (host!=target and host!=build)
 433         which_gcj=cross
 434      fi
 435   else
 436      which_gcj=cross
 437   fi
 438 else
 439   # We are being configured with a native or crossed-native compiler
 440   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 441      if test x"$build" = x"$host"; then
 442         # True native build (host=target and host=build)
 443         which_gcj=built
 444      else
 445         # Crossed-native build (host=target and host!=build)
 446         which_gcj=cross
 447      fi
 448   else
 449      which_gcj=path
 450   fi
 451 fi
 452 libgcjdir=`${PWDCMD-pwd}`
 453 case $GCJ in
 454 *" -B"*)
 455   # Just in case there is a comma in the build dir, quote it for the
 456   # sed command below.
 457   case $libgcjdir in
 458   *[[,\\]]*) qlibgcjdir=`echo "$libgcjdir" | sed 's:[[,\\]]:\\&:g'`;;
 459   *) qlibgcjdir=$libgcjdir;;
 460   esac
 461   GCJ=`echo "$GCJ" | sed "s, -B, -B$qlibgcjdir/&,"`
 462   ;;
 463 *)
 464   GCJ=$GCJ" -B$libgcjdir/"
 465   ;;
 466 esac
 467 case "${which_gcj}" in
 468    built)
 469       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 470    ;;
 471    cross)
 472       if test "x${with_newlib}" = "xyes"; then
 473          # FIXME (comment): Why is this needed?
 474          LIBGCC_UNWIND_INCLUDE=
 475       fi
 476       GCJH='$(target_noncanonical)-gcjh'
 477    ;;
 478    path)
 479       GCJH=gcjh
 480    ;;
 481 esac
 482 JAVAC="$GCJ -C"
 483 export JAVAC
 484
 485 AC_SUBST(GCJ_FOR_ECJX)
 486 AC_SUBST(GCC_FOR_ECJX)
 487 AC_SUBST(GCJH)
 488 AC_SUBST(host_exeext)
 489
 490 # Create it, so that compile/link tests don't fail
 491 test -f libgcj.spec || touch libgcj.spec
 492
 493
 494
 495 # Set up to configure Classpath.
 496 # FIXME: no supported way to pass args in autoconf.
 497 # Disable tool wrappers to avoid ltdl.h configure check.
 498 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 499 ac_configure_args="$ac_configure_args --disable-load-library"
 500 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 501 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 502 dir1=`cd $srcdir && pwd`
 503 dir2=`pwd`
 504 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 505 ac_configure_args="$ac_configure_args --disable-core-jni"
 506 dnl FIXME?
 507 ac_configure_args="$ac_configure_args --disable-examples"
 508 ac_configure_args="$ac_configure_args --with-glibj=build"
 509 if test "$browser_plugin_enabled" != yes; then
 510   ac_configure_args="$ac_configure_args --disable-plugin"
 511 else
 512   ac_configure_args="$ac_configure_args --enable-plugin"
 513 fi
 514 if test "$gconf_enabled" != yes; then
 515   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 516   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 517 fi
 518 if test "$use_gtk_awt" != yes; then
 519   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 520 fi
 521 if test "$use_qt_awt" != yes; then
 522   ac_configure_args="$ac_configure_args --disable-qt-peer"
 523 else
 524   # We need this as qt is disabled by default in classpath.
 525   ac_configure_args="$ac_configure_args --enable-qt-peer"
 526 fi
 527 if test "$use_x_awt" != yes; then
 528   ac_configure_args="$ac_configure_args --without-escher"
 529 else
 530   # We need this as escher is disabled by default in classpath.
 531   if test "$use_escher" != true; then
 532     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 533   else
 534     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 535   fi
 536 fi
 537 if test "x$BUILD_GJDOC" = xno; then
 538   ac_configure_args="$ac_configure_args --disable-gjdoc"
 539 fi
 540 # -Werror causes unavoidable problems in code using alsa.
 541 ac_configure_args="$ac_configure_args --disable-regen-headers"
 542 ac_configure_args="$ac_configure_args --disable-Werror"
 543 dnl --with-gcj=$GCJ
 544 dnl --with-javah=$GCJH
 545 dnl gtk-cairo -- just export here...
 546 dnl --enable-regen-headers?
 547
 548 # Only use libltdl for non-newlib builds.
 549 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 550    AC_LIBLTDL_CONVENIENCE
 551    AC_LIBTOOL_DLOPEN
 552    DIRLTDL=libltdl
 553    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 554    # Sigh.  Libtool's macro doesn't do the right thing.
 555    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 556    # FIXME: this is a hack.
 557    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 558    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 559 fi
 560 AC_SUBST(INCLTDL)
 561 AC_SUBST(LIBLTDL)
 562 AC_SUBST(DIRLTDL)
 563 AC_PROG_LIBTOOL
 564 ACX_LT_HOST_FLAGS
 565 AM_PROG_GCJ
 566 AM_PROG_CC_C_O
 567
 568 AC_CONFIG_SUBDIRS(classpath libltdl)
 569
 570 # The -no-testsuite modules omit the test subdir.
 571 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 572
 573 # Should the runtime set system properties by examining the
 574 # environment variable GCJ_PROPERTIES?
 575 AC_ARG_ENABLE(getenv-properties,
 576   AS_HELP_STRING([--disable-getenv-properties],
 577                  [don't set system properties from GCJ_PROPERTIES]))
 578
 579 # Whether GCJ_PROPERTIES is used depends on the target.
 580 if test -z "$enable_getenv_properties"; then
 581    enable_getenv_properties=${enable_getenv_properties_default-yes}
 582 fi
 583 if test "$enable_getenv_properties" = no; then
 584    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 585      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 586 fi
 587
 588 # Whether we should use arguments to main()
 589 if test -z "$enable_main_args"; then
 590    enable_main_args=${enable_main_args_default-yes}
 591 fi
 592 if test "$enable_main_args" = no; then
 593    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 594 fi
 595
 596
 597 # Should we use hashtable-based synchronization?
 598 # Currently works only for Linux X86/ia64
 599 # Typically faster and more space-efficient
 600 AC_ARG_ENABLE(hash-synchronization,
 601   AS_HELP_STRING([--enable-hash-synchronization],
 602                  [use global hash table for monitor locks]))
 603
 604 if test -z "$enable_hash_synchronization"; then
 605    enable_hash_synchronization=$enable_hash_synchronization_default
 606 fi
 607
 608
 609 install_ecj_jar=no
 610 ECJ_BUILD_JAR=
 611 ECJ_JAR=
 612 AC_ARG_WITH(ecj-jar,
 613         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 614         [ECJ_JAR=$withval],
 615         [if test -f $multi_basedir/ecj.jar; then
 616            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 617            ECJ_JAR='$(jardir)/ecj.jar'
 618            install_ecj_jar=yes
 619          fi])
 620 AC_SUBST(ECJ_BUILD_JAR)
 621 AC_SUBST(ECJ_JAR)
 622 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 623 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 624
 625 AC_ARG_WITH(java-home,
 626   AS_HELP_STRING([--with-java-home=DIRECTORY],
 627                  [value of java.home system property]),
 628                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 629 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 630 AC_SUBST(JAVA_HOME)
 631
 632 suppress_libgcj_bc=no
 633 AC_ARG_ENABLE(libgcj-bc,
 634   AS_HELP_STRING([--enable-libgcj-bc],
 635                  [enable(default) or disable BC ABI for portions of libgcj]),
 636   [if test "$enable_libgcj_bc" = "no"; then
 637      suppress_libgcj_bc=yes
 638    fi])
 639 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 640
 641 build_libgcj_reduced_reflection=no
 642 AC_ARG_ENABLE(reduced-reflection,
 643   AS_HELP_STRING([--enable-reduced-reflection],
 644                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 645   [if test "$enable_reduced_reflection" = "yes"; then
 646      build_libgcj_reduced_reflection=yes
 647    fi])
 648 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 649
 650 # What is the native OS API for MinGW?
 651 AC_ARG_WITH(win32-nlsapi,
 652   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 653                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 654 [case "${withval}" in
 655   ansi) with_win32_nlsapi=ansi ;;
 656   unicows) with_win32_nlsapi=unicows ;;
 657   unicode) with_win32_nlsapi=unicode ;;
 658   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 659 esac],[with_win32_nlsapi=ansi])
 660
 661 case "${with_win32_nlsapi}" in
 662   unicows | unicode)
 663     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 664       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 665     ;;
 666 esac
 667
 668 # configure.host sets slow_pthread_self if the synchronization code should
 669 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 670 if test "${slow_pthread_self}" = "yes"; then
 671   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 672     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 673 fi
 674
 675 # Check for gc debugging.  This option is handled both here and in the GC.
 676 AC_ARG_ENABLE(gc-debug,
 677    AS_HELP_STRING([--enable-gc-debug],
 678                   [include full support for pointer backtracing etc.]),
 679 [ if test "$enable_gc_debug" = "yes"; then
 680     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 681               [Define if we want to use debug calls into the garbage collector.])
 682   fi])
 683
 684 # See if the user has the interpreter included.
 685 AC_ARG_ENABLE(interpreter,
 686   AS_HELP_STRING([--enable-interpreter],
 687                  [enable interpreter]),
 688   [if test "$enable_interpreter" = yes; then
 689     # This can also be set in configure.host.
 690     libgcj_interpreter=yes
 691   elif test "$enable_interpreter" = no; then
 692     libgcj_interpreter=no
 693   fi])
 694
 695 if test "$libgcj_interpreter" = yes; then
 696    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 697 fi
 698 INTERPRETER="$libgcj_interpreter"
 699 AC_SUBST(INTERPRETER)
 700 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 701
 702 AC_MSG_CHECKING([for exception model to use])
 703 AC_LANG_PUSH(C++)
 704 AC_ARG_ENABLE(sjlj-exceptions,
 705   AS_HELP_STRING([--enable-sjlj-exceptions],
 706                  [force use of builtin_setjmp for exceptions]),
 707 [:],
 708 [dnl Botheration.  Now we've got to detect the exception model.
 709 dnl Link tests against libgcc.a are problematic since -- at least
 710 dnl as of this writing -- we've not been given proper -L bits for
 711 dnl single-tree newlib and libgloss.
 712 dnl
 713 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 714 dnl conftest files before we got a change to grep them first.
 715 cat > conftest.$ac_ext << EOF
 716 [#]line __oline__ "configure"
 717 struct S { ~S(); };
 718 void bar();
 719 void foo()
 720 {
 721   S s;
 722   bar();
 723 }
 724 EOF
 725 old_CXXFLAGS="$CXXFLAGS"
 726 CXXFLAGS=-S
 727 if AC_TRY_EVAL(ac_compile); then
 728   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 729     enable_sjlj_exceptions=yes
 730   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 731     enable_sjlj_exceptions=no
 732   elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
 733     # ARM EH ABI.
 734     enable_sjlj_exceptions=no
 735   fi
 736 fi
 737 CXXFLAGS="$old_CXXFLAGS"
 738 rm -f conftest*])
 739 if test x$enable_sjlj_exceptions = xyes; then
 740   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 741         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 742   ac_exception_model_name=sjlj
 743 elif test x$enable_sjlj_exceptions = xno; then
 744   ac_exception_model_name="call frame"
 745 else
 746   AC_MSG_ERROR([unable to detect exception model])
 747 fi
 748 AC_LANG_POP(C++)
 749 AC_MSG_RESULT($ac_exception_model_name)
 750
 751 # If we are non using SJLJ exceptions, and this host does not have support
 752 # for unwinding from a signal handler, enable checked dereferences and divides.
 753 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 754   CHECKREFSPEC=-fcheck-references
 755   DIVIDESPEC=-fuse-divide-subroutine
 756   EXCEPTIONSPEC=
 757 fi
 758
 759 # See if the user wants to disable java.net.  This is the mildly
 760 # ugly way that we admit that target-side configuration sucks.
 761 AC_ARG_ENABLE(java-net,
 762   AS_HELP_STRING([--disable-java-net],
 763                  [disable java.net]))
 764
 765 # Whether java.net is built by default can depend on the target.
 766 if test -z "$enable_java_net"; then
 767    enable_java_net=${enable_java_net_default-yes}
 768 fi
 769 if test "$enable_java_net" = no; then
 770    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 771 fi
 772
 773 # See if the user wants to configure without libffi.  Some
 774 # architectures don't support it, and default values are set in
 775 # configure.host.
 776 AC_ARG_WITH(libffi,
 777   AS_HELP_STRING([--without-libffi],
 778                  [don't use libffi]),
 779   [:],
 780   [with_libffi=${with_libffi_default-yes}])
 781
 782 LIBFFI=
 783 LIBFFIINCS=
 784 if test "$with_libffi" != no; then
 785    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 786    LIBFFI=../libffi/libffi_convenience.la
 787    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 788 fi
 789 AC_SUBST(LIBFFI)
 790 AC_SUBST(LIBFFIINCS)
 791
 792 # See if the user wants to disable JVMPI support.
 793 AC_ARG_ENABLE(jvmpi,
 794   AS_HELP_STRING([--disable-jvmpi],
 795                  [disable JVMPI support]))
 796
 797 if test "$enable_jvmpi" != no; then
 798     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 799 fi
 800
 801 # If the target is an eCos system, use the appropriate eCos
 802 # I/O routines.
 803 # FIXME: this should not be a local option but a global target
 804 # system; at present there is no eCos target.
 805 TARGET_ECOS=${PROCESS-"no"}
 806 AC_ARG_WITH(ecos,
 807 [  --with-ecos             enable runtime eCos target support],
 808 TARGET_ECOS="$with_ecos"
 809 )
 810
 811 case "$TARGET_ECOS" in
 812    no) case "$host" in
 813       *mingw*)
 814             PLATFORM=Win32
 815             PLATFORMNET=Win32
 816             PLATFORMH=win32.h
 817         CHECK_FOR_BROKEN_MINGW_LD
 818       ;;
 819       *)
 820             PLATFORM=Posix
 821             PLATFORMNET=Posix
 822             PLATFORMH=posix.h
 823       ;;
 824       esac
 825       ;;
 826    *)
 827       PLATFORM=Ecos
 828       PLATFORMNET=NoNet
 829       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 830       PLATFORMH=posix.h
 831       ;;
 832 esac
 833 AC_SUBST(PLATFORM)
 834 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 835
 836 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 837                                       [Define if you have int32_t and uint32_t.]))
 838 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 839                                         [Define if you have int32_t and uint32_t.]))
 840 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 841                                           [Define if you have u_int32_t]))
 842 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 843                                            [Define if you have u_int32_t]))
 844
 845 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 846 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 847
 848 case "$host" in
 849   *-darwin*) DARWIN_CRT=true ;;
 850   *) DARWIN_CRT=false ;;
 851 esac
 852 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 853
 854 # This may not be defined in a non-ANS conformant embedded system.
 855 # FIXME: Should these case a runtime exception in that case?
 856 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 857                                   [Define is you have 'localtime' in <time.h>]))
 858
 859 # Create the subdirectory for natFile.cc, or the attempt
 860 # to create the link will fail.
 861 test -d java || mkdir java
 862 test -d java/io || mkdir java/io
 863 test -d gnu || mkdir gnu
 864 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 865
 866 # Likewise for natConcreteProcess.cc.
 867 test -d java/lang || mkdir java/lang
 868 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 869
 870 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 871 test -d java/net || mkdir java/net
 872 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 873 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 874
 875 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 876 test -d gnu/java || mkdir gnu/java
 877 test -d gnu/java/net || mkdir gnu/java/net
 878 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 879 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 880
 881 # Likewise for natVMPipe.cc and natVMSelector.cc.
 882 test -d gnu/java/nio || mkdir gnu/java/nio
 883 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 884 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 885
 886 # Likewise for natFileChannelImpl.cc
 887 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 888 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 889
 890 # Likewise for natVMSecureRandom.cc
 891 test -d gnu/java/security || mkdir gnu/java/security
 892 test -d gnu/java/security/jce || mkdir gnu/java/security/jce
 893 test -d gnu/java/security/jce/prng || mkdir gnu/java/security/jce/prng
 894 AC_CONFIG_LINKS(gnu/java/security/jce/prng/natVMSecureRandom.cc:gnu/java/security/jce/prng/natVMSecureRandom${FILE-${PLATFORM}}.cc)
 895
 896 case "${host}" in
 897     *mingw*)
 898       SYSTEMSPEC="-lgdi32 -lws2_32"
 899       if test "${with_win32_nlsapi}" = "unicows"; then
 900         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 901       fi
 902     ;;
 903     *-*-darwin[[912]]*)
 904       SYSTEMSPEC="%{!Zdynamiclib:%{!Zbundle:-allow_stack_execute}}"
 905     ;;
 906     *)
 907       SYSTEMSPEC=
 908     ;;
 909 esac
 910 AC_SUBST(SYSTEMSPEC)
 911
 912 AC_ARG_WITH(system-zlib,
 913   AS_HELP_STRING([--with-system-zlib],
 914                  [use installed libz]))
 915 ZLIBSPEC=
 916 AC_SUBST(ZLIBSPEC)
 917 ZLIBTESTSPEC=
 918 AC_SUBST(ZLIBTESTSPEC)
 919
 920 AC_PATH_XTRA
 921
 922 # FIXME: this should be _libs on some hosts.
 923 libsubdir=.libs
 924
 925 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 926
 927 LIBSTDCXXSPEC=
 928 # extra LD Flags which are required for targets
 929 case "${host}" in
 930 *-*-darwin[[0-7]].*)
 931     # For now we have to disable it on darwin[8-9] because it slows down
 932     # the linking phase. A possible bug in ld?
 933     # on Darwin -single_module speeds up loading of the dynamic libraries.
 934     extra_ldflags_libjava=-Wl,-single_module
 935     ;;
 936 arm*-*-linux-*)
 937     # Some of the ARM unwinder code is actually in libstdc++.  We
 938     # could in principle replicate it in libgcj, but it's better to
 939     # have a dependency on libstdc++.
 940     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 941     LIBSTDCXXSPEC=-lstdc++
 942     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 943     ;;
 944 *-*-cygwin)
 945     extra_ldflags_libjava=-liconv
 946     ;;
 947 *-*-mingw*)
 948     extra_ldflags_libjava=-lws2_32
 949     ;;
 950 esac
 951
 952 LIBMATHSPEC=
 953 # extra LD Flags which are required for targets
 954 case "${host}" in
 955 *-*-darwin*)
 956      ;;
 957 *)
 958      LIBMATHSPEC=-lm
 959      ;;
 960 esac
 961
 962 # Check for --no-merge-exidx-entries, an ARM-specific linker option.
 963 AC_CACHE_CHECK([for --no-merge-exidx-entries], [libgcj_cv_exidx],
 964   [saved_ldflags="$LDFLAGS"
 965    LDFLAGS="${LDFLAGS} -Wl,--no-merge-exidx-entries"
 966    AC_LINK_IFELSE([int main(void){ return 0;} ],
 967                       [eval "libgcj_cv_exidx=yes"],
 968                       [eval "libgcj_cv_exidx=no"])
 969    LDFLAGS="${saved_ldflags}"]
 970 )
 971 if test "${libgcj_cv_exidx}" = "yes"; then
 972   SYSTEMSPEC="${SYSTEMSPEC} --no-merge-exidx-entries"
 973   extra_ldflags="${extra_ldflags} -Wl,--no-merge-exidx-entries"
 974 fi
 975
 976 AC_SUBST(extra_ldflags_libjava)
 977 AC_SUBST(extra_ldflags)
 978 AC_SUBST(LIBSTDCXXSPEC)
 979 AC_SUBST(LIBMATHSPEC)
 980
 981 AC_SUBST(LIBGCJTESTSPEC)
 982
 983 # Allow the GC to be disabled.  Can be useful when debugging.
 984 AC_MSG_CHECKING([for garbage collector to use])
 985 AC_ARG_ENABLE(java-gc,
 986   AS_HELP_STRING([--enable-java-gc=TYPE],
 987                  [choose garbage collector (default is boehm)]),
 988   [GC=$enableval],
 989   [GC=boehm])
 990 GCLIBS=
 991 GCINCS=
 992 GCDEPS=
 993 GCSPEC=
 994 JC1GCSPEC=
 995 GCTESTSPEC=
 996 case "$GC" in
 997  boehm)
 998     AC_MSG_RESULT(boehm)
 999     GCLIBS=../boehm-gc/libgcjgc_convenience.la
1000     JC1GCSPEC='-fuse-boehm-gc'
1001     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
1002     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
1003     GCOBJS=boehm.lo
1004     GCHDR=boehm-gc.h
1005     # The POSIX thread support needs to know this.
1006     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
1007     ;;
1008  no)
1009     AC_MSG_RESULT(none)
1010     GCHDR=no-gc.h
1011     ;;
1012  *)
1013     AC_MSG_ERROR([unrecognized collector "$GC"])
1014     ;;
1015 esac
1016 AC_SUBST(GCLIBS)
1017 AC_SUBST(GCINCS)
1018 AC_SUBST(GCDEPS)
1019 AC_SUBST(GCSPEC)
1020 AC_SUBST(JC1GCSPEC)
1021 AC_SUBST(GCTESTSPEC)
1022 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
1023 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
1024 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
1025
1026
1027 AC_MSG_CHECKING([for thread model used by GCC])
1028 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
1029 AC_MSG_RESULT([$THREADS])
1030
1031 case "$THREADS" in
1032  no | none | single)
1033     THREADS=none
1034     ;;
1035  aix | posix | pthreads)
1036     THREADS=posix
1037     case "$host" in
1038      *-*-linux*)
1039         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
1040         ;;
1041     esac
1042     ;;
1043  win32)
1044     ;;
1045  dce | vxworks)
1046     AC_MSG_ERROR(thread package $THREADS not yet supported)
1047     ;;
1048  *)
1049     AC_MSG_ERROR($THREADS is an unknown thread package)
1050     ;;
1051 esac
1052
1053 THREADCXXFLAGS=
1054 THREADLDFLAGS=
1055 THREADLIBS=
1056 THREADINCS=
1057 THREADDEPS=
1058 THREADH=
1059 THREADSPEC=
1060 THREADSTARTFILESPEC=
1061 case "$THREADS" in
1062  posix)
1063     case "$host" in
1064      *-*-cygwin*)
1065         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
1066         ;;
1067      *-*-freebsd[[34]].*)
1068         # Before FreeBSD 5, it didn't have -lpthread (or any library which
1069         # merely adds pthread_* functions) but it does have a -pthread switch
1070         # which is required at link-time to select -lc_r *instead* of -lc.
1071         THREADLDFLAGS=-pthread
1072         # Don't set THREADSPEC here as might be expected since -pthread is
1073         # not processed when found within a spec file, it must come from
1074         # the command line.  For now, the user must provide the -pthread
1075         # switch to link code compiled with gcj.  In future, consider adding
1076         # support for weak references to pthread_* functions ala gthr.h API.
1077         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
1078         ;;
1079      *-*-freebsd*)
1080         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
1081         # systems which support threads and -lpthread.
1082         THREADLDFLAGS=-pthread
1083         THREADSPEC=-lpthread
1084         ;;
1085      hppa*-hp-hpux*)
1086         THREADCXXFLAGS=-pthread
1087         # boehm-gc needs some functions from librt, so link that too.
1088         THREADLIBS='-lpthread -lrt'
1089         THREADSPEC='-lpthread -lrt'
1090         ;;
1091      *-*-darwin*)
1092         # Don't set THREADLIBS or THREADSPEC as Darwin already
1093         # provides pthread via libSystem.
1094         ;;
1095      *)
1096         THREADLIBS=-lpthread
1097         THREADSPEC=-lpthread
1098         ;;
1099     esac
1100     THREADH=posix-threads.h
1101     # MIT pthreads doesn't seem to have the mutexattr functions.
1102     # But for now we don't check for it.  We just assume you aren't
1103     # using MIT pthreads.
1104     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1105
1106     # If we're using the Boehm GC, then we happen to know that it
1107     # defines _REENTRANT, so we don't bother.  Eww.
1108     if test "$GC" != boehm; then
1109        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1110     fi
1111     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1112     ;;
1113
1114  win32)
1115     THREADH=win32-threads.h
1116     THREADCXXFLAGS=-mthreads
1117     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1118     # But we do not want the executables created to be dependent on
1119     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1120     # exception handling contexts.  The following kludge achieves this effect
1121     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1122     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1123     # A workaround is to explicitly use -mthreads while linking Java programs.
1124     # See PR libgcj/28263.
1125     #
1126     # FIXME: In Java we are able to detect thread death at the end of
1127     # Thread.run() so we should be able to clean up the exception handling
1128     # contexts ourselves.
1129     case "$host" in
1130     *-w64-mingw*)
1131       ;;
1132     *)
1133       THREADSTARTFILESPEC='crtmt%O%s'
1134       ;;
1135     esac
1136     ;;
1137  none)
1138     THREADH=no-threads.h
1139     ;;
1140 esac
1141 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1142 AC_SUBST(THREADLIBS)
1143 AC_SUBST(THREADINCS)
1144 AC_SUBST(THREADDEPS)
1145 AC_SUBST(THREADSPEC)
1146 AC_SUBST(THREADSTARTFILESPEC)
1147 AC_SUBST(THREADLDFLAGS)
1148 AC_SUBST(THREADCXXFLAGS)
1149 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1150 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1151 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1152 if test "$enable_shared" != yes; then
1153   use_libgcj_bc=no
1154 fi
1155 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1156
1157 if test -d sysdep; then true; else mkdir sysdep; fi
1158 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1159 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1160 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1161
1162 LIBGCJ_SPEC_LGCJ=-lgcj
1163 LIBGCJ_SPEC_LGCJ_BC=-lgcj_bc
1164 if test x"$libgcj_spec_lgcj_override" != x ; then
1165   LIBGCJ_SPEC_LGCJ=$libgcj_spec_lgcj_override
1166 fi
1167 if test x"$libgcj_spec_lgcj_bc_override" != x ; then
1168   LIBGCJ_SPEC_LGCJ_BC=$libgcj_spec_lgcj_bc_override
1169 fi
1170 LIBGCJ_SPEC="%{s-bc-abi:} $LIBGCJ_SPEC_LGCJ"
1171 if test "$use_libgcj_bc" = yes; then
1172   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:$LIBGCJ_SPEC_LGCJ;:$LIBGCJ_SPEC_LGCJ_BC}"
1173   LIBGCJ_BC_SPEC="%{findirect-dispatch:-fPIC}"
1174 fi
1175 AC_SUBST(LIBGCJ_SPEC)
1176 AC_SUBST(LIBGCJ_BC_SPEC)
1177
1178 HASH_SYNC_SPEC=
1179 # Hash synchronization is only useful with posix threads right now.
1180 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1181    HASH_SYNC_SPEC=-fhash-synchronization
1182    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1183 fi
1184 AC_SUBST(HASH_SYNC_SPEC)
1185
1186 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1187
1188 # We're in the tree with libgcc, and need to include some of its headers.
1189 LIBGCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../libgcc'
1190
1191 if test "x${with_newlib}" = "xyes"; then
1192    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1193    # may not work correctly, because the compiler may not be able to
1194    # link executables.
1195
1196    # We assume newlib.  This lets us hard-code the functions we know
1197    # we'll have.
1198    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1199    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1200    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1201    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1202    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1203    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1204    # This is only for POSIX threads.
1205    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1206
1207    # Assume we do not have getuid and friends.
1208    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1209    PLATFORMNET=NoNet
1210 else
1211    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1212                    localtime_r getpwuid_r getcwd \
1213                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1214                    nl_langinfo setlocale \
1215                    inet_pton uname inet_ntoa \
1216                    getrlimit sigaction ftruncate mmap \
1217                    getifaddrs])
1218    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1219    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1220    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1221    AC_CHECK_LIB(dl, dladdr, [
1222        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1223        AC_CHECK_LIB(dld, dladdr, [
1224        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1225
1226    if test x"$cross_compiling" = x"no"; then
1227      AC_CHECK_FILES(/proc/self/exe, [
1228        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1229      AC_CHECK_FILES(/proc/self/maps, [
1230        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1231          [Define if you have /proc/self/maps])])
1232    else
1233      case $host in
1234      *-linux*)
1235        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1236        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1237        ;;
1238      esac
1239    fi
1240
1241    AM_ICONV
1242    AM_LC_MESSAGES
1243    AC_STRUCT_TIMEZONE
1244    LDLIBICONV=`echo " $LIBICONV " | sed "s/${acl_cv_wl--Wl,}/ /g; s/,/ /g"`
1245    AC_SUBST([LDLIBICONV])
1246
1247    AC_CHECK_FUNCS(gethostbyname_r, [
1248      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1249        [Define if you have the 'gethostbyname_r' function.])
1250      # There are two different kinds of gethostbyname_r.
1251      # We look for the one that returns `int'.
1252      # Hopefully this check is robust enough.
1253      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1254        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1255
1256      case " $GCINCS " in
1257      *" -D_REENTRANT "*) ;;
1258      *)
1259         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1260         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1261         [libjava_cv_gethostbyname_r_needs_reentrant],
1262         [ AC_LANG_PUSH(C++)
1263           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1264             [[gethostbyname_r("", 0, 0);]])],
1265             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1266                 CPPFLAGS_SAVE="$CPPFLAGS"
1267                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1268                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1269                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1270                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1271                 CPPFLAGS="$CPPFLAGS_SAVE"
1272           ])
1273           AC_LANG_POP(C++)
1274         ])
1275         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1276           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1277         fi
1278      ;;
1279      esac
1280
1281      AC_CACHE_CHECK([for struct hostent_data],
1282         [libjava_cv_struct_hostent_data], [dnl
1283         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1284 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1285 # define _REENTRANT 1
1286 #endif
1287 #include <netdb.h>]], [[struct hostent_data data;]])],
1288           [libjava_cv_struct_hostent_data=yes],
1289           [libjava_cv_struct_hostent_data=no])])
1290      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1291        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1292          [Define if struct hostent_data is defined in netdb.h])
1293      fi
1294    ])
1295
1296    # FIXME: libjava source code expects to find a prototype for
1297    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1298    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1299    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1300    # linkage check is enough, yet C++ code requires proper prototypes.)
1301    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1302    AC_CHECK_FUNCS(gethostbyaddr_r, [
1303      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1304        [Define if you have the 'gethostbyaddr_r' function.])
1305      # There are two different kinds of gethostbyaddr_r.
1306      # We look for the one that returns `int'.
1307      # Hopefully this check is robust enough.
1308      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1309        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1310          [Define if gethostbyaddr_r returns 'int'.])])])])
1311
1312    AC_CHECK_FUNCS(gethostname, [
1313      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1314        [Define if you have the 'gethostname' function.])
1315      AC_EGREP_HEADER(gethostname, unistd.h, [
1316        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1317          [Define if gethostname is declared in <unistd.h>.])])])
1318
1319    AC_CHECK_FUNCS(usleep, [
1320      AC_EGREP_HEADER(usleep, unistd.h, [
1321        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1322           [Define if usleep is declared in <unistd.h>.])])])
1323
1324    # Look for these functions in the thread library, but only bother
1325    # if using POSIX threads.
1326    if test "$THREADS" = posix; then
1327       save_LIBS="$LIBS"
1328       LIBS="$LIBS $THREADLIBS"
1329
1330       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1331       # Solaris 7 the name librt is preferred.
1332       AC_CHECK_FUNCS(sched_yield, , [
1333         AC_CHECK_LIB(rt, sched_yield, [
1334           AC_DEFINE(HAVE_SCHED_YIELD)
1335           THREADLIBS="$THREADLIBS -lrt"
1336           THREADSPEC="$THREADSPEC -lrt"], [
1337           AC_CHECK_LIB(posix4, sched_yield, [
1338             AC_DEFINE(HAVE_SCHED_YIELD)
1339             THREADLIBS="$THREADLIBS -lposix4"
1340             THREADSPEC="$THREADSPEC -lposix4"])])])
1341
1342       AC_CHECK_LIB(rt, clock_gettime, [
1343          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1344          case "$THREADSPEC" in
1345            *-lrt*) ;;
1346            *)
1347              THREADSPEC="$THREADSPEC -lrt"
1348              THREADLIBS="$THREADLIBS -lrt"
1349              ;;
1350          esac])
1351
1352       LIBS="$save_LIBS"
1353
1354       # We can save a little space at runtime if the mutex has m_count
1355       # or __m_count.  This is a nice hack for Linux.
1356       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1357           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1358         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1359              [Define if pthread_mutex_t has m_count member.]), [
1360         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1361             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1362           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1363             [Define if pthread_mutex_t has __m_count member.]))])
1364    fi
1365
1366    # We require a way to get the time.
1367    time_found=no
1368    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1369    if test "$time_found" = no; then
1370       AC_MSG_ERROR([no function found to get the time])
1371    fi
1372
1373    AC_CHECK_FUNCS(memmove)
1374
1375    # We require memcpy.
1376    memcpy_found=no
1377    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1378    if test "$memcpy_found" = no; then
1379       AC_MSG_ERROR([memcpy is required])
1380    fi
1381    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1382    AC_CHECK_LIB(dl, dlopen, [
1383        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1384        AC_CHECK_LIB(dld, dlopen, [
1385        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1386
1387    # Some library-finding code we stole from Tcl.
1388    #--------------------------------------------------------------------
1389    #    Check for the existence of the -lsocket and -lnsl libraries.
1390    #    The order here is important, so that they end up in the right
1391    #    order in the command line generated by make.  Here are some
1392    #    special considerations:
1393    #    1. Use "connect" and "accept" to check for -lsocket, and
1394    #       "gethostbyname" to check for -lnsl.
1395    #    2. Use each function name only once:  can't redo a check because
1396    #       autoconf caches the results of the last check and won't redo it.
1397    #    3. Use -lnsl and -lsocket only if they supply procedures that
1398    #       aren't already present in the normal libraries.  This is because
1399    #       IRIX 5.2 has libraries, but they aren't needed and they're
1400    #       bogus:  they goof up name resolution if used.
1401    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1402    #       To get around this problem, check for both libraries together
1403    #       if -lsocket doesn't work by itself.
1404    #--------------------------------------------------------------------
1405
1406    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1407     [gcj_cv_lib_sockets=
1408      gcj_checkBoth=0
1409      unset ac_cv_func_connect
1410      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1411      if test "$gcj_checkSocket" = 1; then
1412          unset ac_cv_func_connect
1413          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1414                       gcj_checkBoth=1)
1415      fi
1416      if test "$gcj_checkBoth" = 1; then
1417          gcj_oldLibs=$LIBS
1418          LIBS="$LIBS -lsocket -lnsl"
1419          unset ac_cv_func_accept
1420          AC_CHECK_FUNC(accept,
1421                        [gcj_checkNsl=0
1422                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1423          unset ac_cv_func_accept
1424          LIBS=$gcj_oldLibs
1425      fi
1426      unset ac_cv_func_gethostbyname
1427      gcj_oldLibs=$LIBS
1428      LIBS="$LIBS $gcj_cv_lib_sockets"
1429      AC_CHECK_FUNC(gethostbyname, ,
1430                    [AC_CHECK_LIB(nsl, main,
1431                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1432      unset ac_cv_func_gethostbyname
1433      LIBS=$gcj_oldLIBS
1434    ])
1435    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1436
1437    if test "$with_system_zlib" = yes; then
1438       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1439    fi
1440
1441    # Test for Gtk stuff, if asked for.
1442    if test "$use_gtk_awt" = yes; then
1443       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1444       AC_SUBST(GTK_CFLAGS)
1445       AC_SUBST(GTK_LIBS)
1446
1447       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1448       AC_SUBST(GLIB_CFLAGS)
1449       AC_SUBST(GLIB_LIBS)
1450
1451       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1452       AC_SUBST(LIBART_CFLAGS)
1453       AC_SUBST(LIBART_LIBS)
1454
1455       # We require the XTest Extension to support java.awt.Robot.
1456       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1457                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1458                    [${X_LIBS}])
1459    fi
1460
1461    # On Solaris, and maybe other architectures, the Boehm collector
1462    # requires -ldl.
1463    if test "$GC" = boehm; then
1464       case "${host}" in
1465           *-*-darwin*)
1466             ;;
1467           *)
1468             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1469             ;;
1470       esac
1471    fi
1472 fi
1473
1474 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1475 case $build in
1476     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1477     *)         CLASSPATH_SEPARATOR=':' ;;
1478 esac
1479 AC_SUBST(CLASSPATH_SEPARATOR)
1480
1481 # We must search the source tree for java.lang, since we still don't
1482 # have libgcj.jar nor java/lang/*.class
1483 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1484 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1485
1486 # Since some classes depend on this one, we need its source available
1487 # before we can do any GCJ compilation test :-(
1488 if test ! -f gnu/classpath/Configuration.java; then
1489   test -d gnu || mkdir gnu
1490   test -d gnu/classpath || mkdir gnu/classpath
1491   # Note that it is not crucial that all the values here be correct.
1492   sed -e "s,@prefix@,$expanded_prefix," \
1493       -e "s,@VERSION@,$VERSION," \
1494       -e "s,@LIBDEBUG@,false," \
1495       -e "s,@INIT_LOAD_LIBRARY@,false," \
1496       -e "s,@@,$LIBGCJDEBUG," \
1497       -e "s,@default_toolkit@,$TOOLKIT," \
1498       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1499       -e "s,@GTK_CAIRO_ENABLED@,false," \
1500       -e "s,@ECJ_JAR@,," \
1501       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1502         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1503         > gnu/classpath/Configuration.java
1504   # We do not want to redirect the output of the grep below to /dev/null,
1505   # but we add /dev/null to the input list so that grep will print the
1506   # filename of Configuration.java in case it finds any matches.
1507   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1508     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1509   fi
1510 fi
1511
1512 LT_AC_PROG_GCJ
1513
1514 # Now remove it.
1515 rm -f gnu/classpath/Configuration.java
1516
1517 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1518
1519 AC_CHECK_SIZEOF(void *)
1520
1521 AC_C_BIGENDIAN
1522
1523 ZLIBS=
1524 SYS_ZLIBS=
1525 ZINCS=
1526
1527 if test -z "$ZLIBSPEC"; then
1528    # Use zlib from the GCC tree.
1529    ZINCS='-I$(top_srcdir)/../zlib'
1530    ZLIBS=../zlib/libzgcj_convenience.la
1531 else
1532    # System's zlib.
1533    SYS_ZLIBS="$ZLIBSPEC"
1534 fi
1535 AC_SUBST(ZLIBS)
1536 AC_SUBST(SYS_ZLIBS)
1537 AC_SUBST(ZINCS)
1538 AC_SUBST(DIVIDESPEC)
1539 AC_SUBST(CHECKREFSPEC)
1540 AC_SUBST(EXCEPTIONSPEC)
1541 AC_SUBST(BACKTRACESPEC)
1542 AC_SUBST(IEEESPEC)
1543 AC_SUBST(ATOMICSPEC)
1544
1545 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1546 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1547 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1548 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1549 AC_SUBST(LIBGCC_UNWIND_INCLUDE)
1550
1551 # Process the option "--enable-version-specific-runtime-libs"
1552 # Calculate toolexeclibdir
1553 case ${version_specific_libs} in
1554   yes)
1555     # Need the gcc compiler version to know where to install libraries
1556     # and header files if --enable-version-specific-runtime-libs option
1557     # is selected.
1558     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1559     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1560     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1561     toolexeclibdir=$toolexecmainlibdir
1562     ;;
1563   no)
1564     if test -n "$with_cross_host" &&
1565        test x"$with_cross_host" != x"no"; then
1566       # Install a library built with a cross compiler in tooldir, not libdir.
1567       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1568       toolexecmainlibdir='$(toolexecdir)/lib'
1569     else
1570       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1571       toolexecmainlibdir='$(libdir)'
1572     fi
1573     multi_os_directory=`$CC -print-multi-os-directory`
1574     case $multi_os_directory in
1575       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1576       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1577     esac
1578     ;;
1579 esac
1580 AC_SUBST(toolexecdir)
1581 AC_SUBST(toolexecmainlibdir)
1582 AC_SUBST(toolexeclibdir)
1583
1584 # Determine gcj and libgcj version number.
1585 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1586 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1587 GCJVERSION=$gcjversion
1588 AC_SUBST(GCJVERSION)
1589 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1590
1591 # Determine where the standard .db file and GNU Classpath JNI
1592 # libraries are found.
1593 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1594 dbexecdir='$(toolexeclibdir)/'$gcjsubdir
1595 AC_SUBST(dbexecdir)
1596 AC_SUBST(gcjsubdir)
1597
1598 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1599 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1600
1601 TL_AC_GXX_INCLUDE_DIR
1602
1603 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1604 # On that system, sys/ioctl.h will not include sys/filio.h unless
1605 # BSD_COMP is defined; just including sys/filio.h is simpler.
1606 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1607 # for now.  If you change this, you also must update natFile.cc.
1608 AC_CHECK_HEADERS([unistd.h sys/time.h sys/types.h fcntl.h \
1609                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1610                   sys/socket.h netinet/in.h arpa/inet.h netdb.h \
1611                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1612                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1613
1614 # sys/socket.h is a prerequisite for net/if.h on Solaris.
1615 AC_CHECK_HEADERS(net/if.h, [], [], [
1616 #ifdef HAVE_SYS_SOCKET_H
1617 #include <sys/socket.h>
1618 #endif
1619 ])
1620
1621 AC_CHECK_HEADERS(inttypes.h, [
1622     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1623     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1624 ])
1625
1626 AC_CHECK_TYPE([ssize_t], [int])
1627 AC_CHECK_TYPE([magic_t], [
1628     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1629 #ifdef HAVE_MAGIC_H
1630 #include <magic.h>
1631 #endif])
1632
1633 AC_MSG_CHECKING([for in_addr_t])
1634 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1635 #if STDC_HEADERS
1636 #include <stdlib.h>
1637 #include <stddef.h>
1638 #endif
1639 #if HAVE_NETINET_IN_H
1640 #include <netinet/in.h>
1641 #endif]], [[in_addr_t foo;]])],
1642   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1643      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1644    AC_MSG_RESULT(yes)],
1645   [AC_MSG_RESULT(no)])
1646
1647 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1648 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1649   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1650      [Define if struct ip_mreq is defined in netinet/in.h.])
1651    AC_MSG_RESULT(yes)],
1652   [AC_MSG_RESULT(no)])
1653
1654 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1655 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1656   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1657      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1658    AC_MSG_RESULT(yes)],
1659   [AC_MSG_RESULT(no)])
1660
1661 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1662 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1663   [AC_DEFINE(HAVE_INET6, 1,
1664      [Define if inet6 structures are defined in netinet/in.h.])
1665    AC_MSG_RESULT(yes)],
1666   [AC_MSG_RESULT(no)])
1667
1668 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1669 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1670 #include <sys/types.h>
1671 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1672   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1673    AC_MSG_RESULT(yes)],
1674   [AC_MSG_RESULT(no)])
1675
1676 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1677 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1678   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1679    AC_MSG_RESULT(yes)],
1680   [AC_MSG_RESULT(no)
1681    AC_MSG_CHECKING([for global timezone variable])
1682    dnl FIXME: we don't want a link check here because that won't work
1683    dnl when cross-compiling.  So instead we make an assumption that
1684    dnl the header file will mention timezone if it exists.
1685    dnl Don't find the win32 function timezone
1686    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1687      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1688       AC_MSG_RESULT(yes)],
1689      [AC_MSG_RESULT(no)
1690        AC_MSG_CHECKING([for global _timezone variable])
1691        dnl FIXME: As above, don't want link check
1692        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1693          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1694             [Define if your platform has the global _timezone variable.])
1695           AC_MSG_RESULT(yes)],
1696           [AC_MSG_RESULT(no)])])])
1697
1698 AC_CHECK_PROGS(PERL, perl, false)
1699
1700 SYSDEP_SOURCES=
1701 SIGNAL_HANDLER_AUX=
1702
1703 case "${host}" in
1704  *-*-solaris2*)
1705     SIGNAL_HANDLER=include/posix-signal.h
1706     ;;
1707  i?86-*-linux*)
1708     SIGNAL_HANDLER=include/i386-signal.h
1709     SIGNAL_HANDLER_AUX=include/x86_64-signal.h
1710     ;;
1711 # ia64-*)
1712 #    SYSDEP_SOURCES=sysdep/ia64.c
1713 #    test -d sysdep || mkdir sysdep
1714 #    ;;
1715  hppa*-*-linux*)
1716     SIGNAL_HANDLER=include/pa-signal.h
1717     ;;
1718  hppa*-hp-hpux*)
1719     SIGNAL_HANDLER=include/hppa-signal.h
1720     ;;
1721  ia64-*-linux*)
1722     SIGNAL_HANDLER=include/dwarf2-signal.h
1723     ;;
1724  powerpc*-*-linux*)
1725     SIGNAL_HANDLER=include/powerpc-signal.h
1726     ;;
1727  alpha*-*-linux*)
1728     SIGNAL_HANDLER=include/dwarf2-signal.h
1729     ;;
1730  s390*-*-linux*)
1731     SIGNAL_HANDLER=include/s390-signal.h
1732     ;;
1733  x86_64*-*-linux*)
1734     SIGNAL_HANDLER=include/x86_64-signal.h
1735     SIGNAL_HANDLER_AUX=include/i386-signal.h
1736     ;;
1737  sparc*-*-linux*)
1738     SIGNAL_HANDLER=include/dwarf2-signal.h
1739     ;;
1740  sh*-*-linux*)
1741     SIGNAL_HANDLER=include/sh-signal.h
1742     ;;
1743  *mingw*)
1744     SIGNAL_HANDLER=include/win32-signal.h
1745     ;;
1746  mips*-*-linux*)
1747     SIGNAL_HANDLER=include/mips-signal.h
1748     ;;
1749  m68*-*-linux*)
1750     SIGNAL_HANDLER=include/dwarf2-signal.h
1751     ;;
1752  powerpc*-*-darwin* | i?86-*-darwin[[912]]* | x86_64-*-darwin[[912]]*)
1753     SIGNAL_HANDLER=include/darwin-signal.h
1754     ;;
1755  powerpc*-*-aix*)
1756     SIGNAL_HANDLER=include/aix-signal.h
1757     ;;
1758  *)
1759     SIGNAL_HANDLER=include/default-signal.h
1760     ;;
1761 esac
1762
1763 # If we're using sjlj exceptions, forget what we just learned.
1764 if test "$enable_sjlj_exceptions" = yes; then
1765    SIGNAL_HANDLER=include/default-signal.h
1766    SIGNAL_HANDLER_AUX=
1767 fi
1768
1769 AC_SUBST(SYSDEP_SOURCES)
1770
1771 if test -z "$SIGNAL_HANDLER_AUX"; then
1772   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1773 fi
1774
1775 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1776                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1777
1778 if test "${multilib}" = "yes"; then
1779   multilib_arg="--enable-multilib"
1780 else
1781   multilib_arg=
1782 fi
1783
1784 # See if we support thread-local storage.
1785 GCC_CHECK_TLS
1786
1787 # For _Unwind_GetIPInfo.
1788 GCC_CHECK_UNWIND_GETIPINFO
1789
1790 # See if linker supports anonymous version scripts.
1791 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1792   [libjava_cv_anon_version_script],
1793   [AC_ARG_ENABLE(symvers,
1794      AS_HELP_STRING([--disable-symvers],
1795                     [disable symbol versioning for libjava]),
1796        [case "$enableval" in
1797          yes|gnu*) libjava_cv_anon_version_script=yes ;;
1798          no)  libjava_cv_anon_version_script=no ;;
1799          *)   AC_MSG_ERROR([Unknown argument to enable/disable symvers]);;
1800         esac],
1801        [libjava_cv_anon_version_script=yes]
1802    )
1803    if test x$libjava_cv_anon_version_script = xyes; then
1804      save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1805      CFLAGS="$CFLAGS -fPIC";
1806      LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1807      echo '{ global: globalsymb*; local: *; };' > conftest.map
1808      AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1809                  [libjava_cv_anon_version_script=gnu],
1810                  [libjava_cv_anon_version_script=no])
1811      if test x$libjava_cv_anon_version_script = xno; then
1812        case "$target_os" in
1813          solaris2*)
1814            LDFLAGS="$save_LDFLAGS"
1815            LDFLAGS="$LDFLAGS -shared -Wl,-M,conftest.map"
1816            # Sun ld doesn't understand wildcards here.
1817            echo '{ global: globalsymbol; local: *; };' > conftest.map
1818            AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1819                        [libjava_cv_anon_version_script=sun], [])
1820            ;;
1821        esac
1822      fi
1823      CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1824    fi
1825   ])
1826 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" != no)
1827 AM_CONDITIONAL(ANONVERSCRIPT_GNU, test "$libjava_cv_anon_version_script" = gnu)
1828 AM_CONDITIONAL(ANONVERSCRIPT_SUN, test "$libjava_cv_anon_version_script" = sun)
1829
1830 # Check if linker supports static linking on a per library basis
1831 LD_START_STATIC_SPEC=
1832 LD_FINISH_STATIC_SPEC=
1833 if $LD --help 2>&1 | grep -- -call_shared >/dev/null 2>&1; then
1834   if $LD --help 2>&1 | grep -- -non_shared >/dev/null 2>&1; then
1835     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1836     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1837   fi
1838 fi
1839 AC_SUBST(LD_START_STATIC_SPEC)
1840 AC_SUBST(LD_FINISH_STATIC_SPEC)
1841
1842 here=`${PWDCMD-pwd}`
1843 AC_SUBST(here)
1844
1845 # We get this from the environment.
1846 AC_SUBST(GCJFLAGS)
1847
1848 default_python_dir="/share/gcc-`cat ${srcdir}/../gcc/BASE-VER`/python/libjava"
1849 AC_ARG_WITH([python-dir],
1850             AS_HELP_STRING([--with-python-dir],
1851                            [the location to install Python modules. This path should NOT include the prefix.]),
1852             [with_python_dir=$withval], [with_python_dir="${default_python_dir}"])
1853
1854 # Needed for installing Python modules during make install.
1855 python_mod_dir="\${prefix}${with_python_dir}"
1856
1857 # Needed for substituting into aot-compile*
1858 python_mod_dir_expanded="${expanded_prefix}${with_python_dir}"
1859
1860 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1861 AC_SUBST(python_mod_dir)
1862 AC_SUBST(python_mod_dir_expanded)
1863
1864 # needed for aot-compile-rpm
1865 MAKE=`which make`
1866 AC_SUBST(MAKE)
1867
1868 AC_ARG_ENABLE([aot-compile-rpm],
1869   [AS_HELP_STRING([--enable-aot-compile-rpm],
1870                  [enable installation of aot-compile-rpm [default=no]])],
1871   [case "${enableval}" in
1872     yes) AOT_RPM_ENABLED=yes ;;
1873     no)  AOT_RPM_ENABLED=no ;;
1874     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1875   esac],
1876   [AOT_RPM_ENABLED=no]
1877 )
1878 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1879
1880 AC_ARG_ENABLE([java-home],
1881   [AS_HELP_STRING([--enable-java-home],
1882                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1883   [case "${enableval}" in
1884     yes) JAVA_HOME_ENABLED=yes ;;
1885     no)  JAVA_HOME_ENABLED=no ;;
1886     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1887   esac],
1888   [JAVA_HOME_ENABLED=no]
1889 )
1890 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1891
1892 # Only do these checks if java-home above is enabled.
1893 if test "x${JAVA_HOME_ENABLED}" = xyes
1894 then
1895
1896   AC_ARG_WITH([gcc-suffix],
1897               AS_HELP_STRING([--with-gcc-suffix],
1898                              [the GCC tool suffix (defaults to empty string)]),
1899               [gcc_suffix=$withval], [gcc_suffix=""])
1900   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1901   AC_SUBST(gcc_suffix)
1902
1903   AC_ARG_WITH([arch-directory],
1904               AS_HELP_STRING([--with-arch-directory],
1905                              [the arch directory under jre/lib (defaults to auto-detect)]),
1906               [host_cpu=$withval], [host_cpu=""])
1907
1908   AC_ARG_WITH([os-directory],
1909               AS_HELP_STRING([--with-os-directory],
1910                              [the os directory under include (defaults to auto-detect)]),
1911               [host_os=$withval], [host_os=""])
1912
1913   AC_ARG_WITH([origin-name],
1914               AS_HELP_STRING([--with-origin-name],
1915                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1916               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1917   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1918
1919   AC_ARG_WITH([arch-suffix],
1920               AS_HELP_STRING([--with-arch-suffix],
1921                              [the arch directory suffix (default is the empty string]),
1922               [arch_suffix=$withval], [arch_suffix=""])
1923   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1924
1925   AC_ARG_WITH([jvm-root-dir],
1926               AS_HELP_STRING([--with-jvm-root-dir],
1927                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1928               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1929   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1930
1931   AC_ARG_WITH([jvm-jar-dir],
1932               AS_HELP_STRING([--with-jvm-jar-dir],
1933                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1934               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1935   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1936
1937   JAVA_VERSION=1.5.0
1938   BUILD_VERSION=0
1939   AC_SUBST(JAVA_VERSION)
1940   AC_SUBST(BUILD_VERSION)
1941   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1942
1943   jre_dir=jre
1944   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1945   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1946
1947   JVM_ROOT_DIR=${jvm_root_dir}
1948   AC_SUBST(JVM_ROOT_DIR)
1949   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1950
1951   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1952   AC_SUBST(JVM_JAR_ROOT_DIR)
1953   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1954
1955   JVM_JAR_DIR=${jvm_jar_dir}
1956   AC_SUBST(JVM_JAR_DIR)
1957   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1958
1959   JRE_DIR=${jre_dir}
1960   AC_SUBST(JRE_DIR)
1961
1962   JRE_LNK=${jre_lnk}
1963   AC_SUBST(JRE_LNK)
1964
1965   SDK_LNK=${sdk_lnk}
1966   AC_SUBST(SDK_LNK)
1967
1968   SDK_BIN_DIR=${jvm_root_dir}/bin
1969   AC_SUBST(SDK_BIN_DIR)
1970   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1971
1972   SDK_LIB_DIR=${jvm_root_dir}/lib
1973   AC_SUBST(SDK_LIB_DIR)
1974   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1975
1976   SDK_INCLUDE_DIR=${jvm_root_dir}/include
1977   AC_SUBST(SDK_INCLUDE_DIR)
1978   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1979
1980   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1981   AC_SUBST(JRE_BIN_DIR)
1982   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1983
1984   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1985   AC_SUBST(JRE_LIB_DIR)
1986   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
1987
1988   # Find gcj prefix using gcj found in PATH.
1989   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
1990
1991   # Where do the gcj binaries live?
1992   # For jhbuild based builds, they all live in a sibling of bin called
1993   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
1994   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
1995   AC_SUBST(GCJ_BIN_DIR)
1996   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
1997
1998   AC_MSG_RESULT(host is ${host})
1999   if test "x${host_cpu}" = "x"
2000   then
2001     case ${host} in
2002       *-mingw* | *-cygwin*)
2003         host_cpu=x86;;
2004       i486-* | i586-* | i686-*)
2005         host_cpu=i386;;
2006       x86_64-*)
2007         host_cpu=amd64;;
2008       *)
2009         host_cpu=${host_cpu};;
2010     esac
2011   fi
2012   AC_MSG_RESULT(arch directory: ${host_cpu})
2013   CPU=${host_cpu}
2014   AC_SUBST(CPU)
2015
2016   if test "x${host_os}" = "x"
2017   then
2018     case ${host} in
2019       *-mingw* | *-cygwin*)
2020         host_os=win32;;
2021       *-linux*)
2022         host_os=linux;;
2023       *)
2024         host_os=${host_os};;
2025     esac
2026   fi
2027   echo os directory: ${host_os}
2028   OS=${host_os}
2029   AC_SUBST(OS)
2030
2031   # make an expanded $libdir, for substituting into
2032   # scripts (and other non-Makefile things).
2033   LIBDIR=$libdir
2034   if test "x${exec_prefix}" = "xNONE"
2035   then
2036       lib_exec_prefix=$expanded_prefix
2037   else
2038       lib_exec_prefix=$exec_prefix
2039   fi
2040   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
2041   AC_SUBST(LIBDIR)
2042 fi
2043
2044 AC_CONFIG_FILES([
2045 Makefile
2046 libgcj.pc
2047 libgcj.spec
2048 libgcj-test.spec
2049 gcj/Makefile
2050 include/Makefile
2051 testsuite/Makefile
2052 contrib/aotcompile.py
2053 contrib/aot-compile
2054 contrib/aot-compile-rpm
2055 contrib/generate-cacerts.pl
2056 contrib/rebuild-gcj-db
2057 ])
2058
2059 if test ${multilib} = yes; then
2060   multilib_arg="--enable-multilib"
2061 else
2062   multilib_arg=
2063 fi
2064
2065 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
2066 AC_OUTPUT