libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8
   9 dnl We use these options to decide which functions to include.
  10 AC_ARG_WITH(target-subdir,
  11 [  --with-target-subdir=SUBDIR
  12                            configuring in a subdirectory])
  13 AC_ARG_WITH(cross-host,
  14 [  --with-cross-host=HOST  configuring with a cross compiler])
  15
  16 LIBGCJ_CONFIGURE(.)
  17
  18 AM_CONFIG_HEADER(include/config.h)
  19
  20 # Only use libltdl for native builds.
  21 if test -z "${with_cross_host}"; then
  22    AC_LIBLTDL_CONVENIENCE
  23    AC_LIBTOOL_DLOPEN
  24    DIRLTDL=libltdl
  25    AC_DEFINE(USE_LTDL)
  26    # Sigh.  Libtool's macro doesn't do the right thing.
  27    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  28 fi
  29 AC_SUBST(INCLTDL)
  30 AC_SUBST(LIBLTDL)
  31 AC_SUBST(DIRLTDL)
  32 AM_PROG_LIBTOOL
  33 AC_CONFIG_SUBDIRS($DIRLTDL)
  34
  35 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  36    COMPPATH=.
  37 else
  38    COMPPATH=..
  39 fi
  40 AC_SUBST(COMPPATH)
  41
  42 dnl The -no-testsuite modules omit the test subdir.
  43 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  44
  45 dnl See whether the user prefers size or speed for Character.
  46 dnl The default is size.
  47 AC_ARG_ENABLE(fast-character,
  48 [  --enable-fast-character prefer speed over size for Character],
  49 # Nothing
  50 , AC_DEFINE(COMPACT_CHARACTER))
  51
  52 dnl Should the runtime set system properties by examining the
  53 dnl environment variable GCJ_PROPERTIES?
  54 AC_ARG_ENABLE(getenv-properties,
  55 [  --disable-getenv-properties
  56                           don't set system properties from GCJ_PROPERTIES])
  57
  58 dnl Whether GCJ_PROPERTIES is used depends on the target.
  59 if test -n "$enable_getenv_properties"; then
  60    enable_getenv_properties=${enable_getenv_properties_default-yes}
  61 fi
  62 if test "$enable_getenv_properties" = no; then
  63    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  64 fi
  65
  66 dnl See if the user has requested runtime debugging.
  67 AC_ARG_ENABLE(libgcj-debug,
  68 [  --enable-libgcj-debug   enable runtime debugging code],
  69   if test "$enable_libgcj_debug" = yes; then
  70      AC_DEFINE(DEBUG)
  71   fi)
  72
  73 dnl See if the user has the interpreter included.
  74 AC_ARG_ENABLE(interpreter,
  75 [  --enable-interpreter    enable interpreter],
  76   if test "$enable_interpreter" = yes; then
  77     # This can also be set in configure.host.
  78     libgcj_interpreter=yes
  79   elif test "$enable_interpreter" = no; then
  80     libgcj_interpreter=no
  81   fi)
  82
  83 if test "$libgcj_interpreter" = yes; then
  84    AC_DEFINE(INTERPRETER)
  85 fi
  86
  87 EXCEPTIONSPEC=
  88 dnl See if we should use setjmp/longjmp exceptions
  89 AC_ARG_ENABLE(sjlj-exceptions,
  90 [  --enable-sjlj-exceptions    use setjmp/longjmp exceptions],
  91   if test "$enable_sjlj_exceptions" = yes; then
  92      # This can be set in configure.host.
  93      libgcj_sjlj=yes
  94   fi)
  95
  96 if test "$libgcj_sjlj" = yes; then
  97    EXCEPTIONSPEC="-fsjlj-exceptions"
  98    AC_DEFINE(SJLJ_EXCEPTIONS)
  99 fi
 100
 101 FORCELIBGCCSPEC=
 102 dnl Work around libgcc design flaw.
 103 if test "$ac_cv_prog_gnu_ld" = yes; then
 104    FORCELIBGCCSPEC="-u __rethrow -u __frame_state_for -lgcc"
 105 fi
 106
 107 AC_MSG_CHECKING([for data_start])
 108 LIBDATASTARTSPEC=
 109 NEEDS_DATA_START=
 110 AC_TRY_LINK([extern int data_start;], [return ((int) &data_start);],
 111   [AC_MSG_RESULT(found it)],
 112   [LIBDATASTARTSPEC="-u data_start -lgcjdata"
 113    NEEDS_DATA_START=yes
 114    AC_MSG_RESULT(missing)])
 115 AC_SUBST(LIBDATASTARTSPEC)
 116
 117 dnl See if the user wants to disable java.net.  This is the mildly
 118 dnl ugly way that we admit that target-side configuration sucks.
 119 AC_ARG_ENABLE(java-net,
 120 [  --disable-java-net      disable java.net])
 121
 122 dnl Whether java.net is built by default can depend on the target.
 123 if test -n "$enable_java_net"; then
 124    enable_java_net=${enable_java_net_default-yes}
 125 fi
 126 if test "$enable_java_net" = no; then
 127    AC_DEFINE(DISABLE_JAVA_NET)
 128 fi
 129
 130 dnl If the target is an eCos system, use the appropriate eCos
 131 dnl I/O routines.
 132 dnl FIXME: this should not be a local option but a global target
 133 dnl system; at present there is no eCos target.
 134 TARGET_ECOS="no"
 135 AC_ARG_WITH(ecos,
 136 [  --with-ecos             enable runtime eCos target support],
 137 TARGET_ECOS="$with_ecos"
 138 )
 139
 140 case "$TARGET_ECOS" in
 141    no)
 142       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
 143       PROCESS=${PROCESS-Posix}
 144       ;;
 145    *)
 146       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
 147       PROCESS=Ecos
 148       AC_DEFINE(ECOS)
 149       ;;
 150 esac
 151
 152 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 153 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 154 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 155 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 156
 157
 158 dnl These may not be defined in a non-ANS conformant embedded system.
 159 dnl FIXME: Should these case a runtime exception in that case?
 160 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 161 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 162
 163 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 164 dnl to create the link will fail.
 165 test -d java || mkdir java
 166 test -d java/io || mkdir java/io
 167 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 168
 169 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 170 test -d java/lang || mkdir java/lang
 171 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 172 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 173
 174 SYSTEMSPEC=
 175 AC_SUBST(SYSTEMSPEC)
 176
 177 AC_ARG_WITH(system-zlib,
 178 [  --with-system-zlib      use installed libz])
 179 ZLIBSPEC=
 180 AC_SUBST(ZLIBSPEC)
 181
 182 dnl FIXME: this should be _libs on some hosts.
 183 libsubdir=.libs
 184
 185 dnl Allow the GC to be disabled.  Can be useful when debugging.
 186 AC_MSG_CHECKING([for garbage collector to use])
 187 AC_ARG_ENABLE(java-gc,
 188 changequote(<<,>>)dnl
 189 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 190 changequote([,])
 191   GC=$enableval,
 192   GC=boehm)
 193 GCLIBS=
 194 GCINCS=
 195 GCDEPS=
 196 GCOBJS=
 197 GCSPEC=
 198 case "$GC" in
 199  boehm)
 200     AC_MSG_RESULT(boehm)
 201     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 202     # We include the path to the boehm-gc build directory.
 203     # See Makefile.am to understand why.
 204     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 205     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
 206     GCSPEC='-lgcjgc'
 207     dnl We also want to pick up some cpp flags required when including
 208     dnl boehm-config.h.  Yuck.
 209     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 210     GCOBJS=boehm.lo
 211     GCHDR=boehm-gc.h
 212     dnl The POSIX thread support needs to know this.
 213     AC_DEFINE(HAVE_BOEHM_GC)
 214     ;;
 215  no)
 216     AC_MSG_RESULT(none)
 217     GCOBJS=nogc.lo
 218     GCHDR=no-gc.h
 219     ;;
 220  *)
 221     AC_MSG_ERROR(unrecognized collector \"$GC\")
 222     ;;
 223 esac
 224 AC_SUBST(GCLIBS)
 225 AC_SUBST(GCINCS)
 226 AC_SUBST(GCDEPS)
 227 AC_SUBST(GCOBJS)
 228 AC_SUBST(GCSPEC)
 229 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 230
 231
 232 dnl Note that this code is kept in sync with similar code in gcc/configure.in.
 233 dnl In particular both packages must make the same decision about which
 234 dnl thread package to use.
 235 AC_MSG_CHECKING([for threads package to use])
 236 AC_ARG_ENABLE(threads, [  --enable-threads=TYPE   choose threading package],
 237   THREADS=$enableval,
 238   dnl FIXME: figure out native threads to use here.
 239   THREADS=no)
 240
 241 if test "$THREADS" = yes; then
 242    case "$host" in
 243     *-*-vxworks*)
 244        THREADS=vxworks
 245        ;;
 246     *-*-linux*)
 247        # FIXME: this isn't correct in all cases.
 248        THREADS=posix
 249        ;;
 250     *-*-win*)
 251        THREADS=win32
 252        ;;
 253     *-*-irix*)
 254        # FIXME: for now, choose POSIX, because we implement that.
 255        # Later, choose irix threads.
 256        THREADS=posix
 257        ;;
 258     *-*-solaris*)
 259        # FIXME: for now, choose POSIX, because we implement that.
 260        # Later, choose solaris threads.
 261        THREADS=posix
 262        ;;
 263     *)
 264        # For now.
 265        THREADS=none
 266        ;;
 267    esac
 268 fi
 269
 270 case "$THREADS" in
 271  no | none | single)
 272     THREADS=none
 273     ;;
 274  posix | pthreads)
 275     THREADS=posix
 276     case "$host" in
 277      *-*-linux*)
 278         AC_DEFINE(LINUX_THREADS)
 279         ;;
 280     esac
 281     ;;
 282  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 283     AC_MSG_ERROR(thread package $THREADS not yet supported)
 284     ;;
 285  *)
 286     AC_MSG_ERROR($THREADS is an unknown thread package)
 287     ;;
 288 esac
 289 AC_MSG_RESULT($THREADS)
 290
 291 THREADLIBS=
 292 THREADINCS=
 293 THREADDEPS=
 294 THREADOBJS=
 295 THREADH=
 296 THREADSPEC=
 297 case "$THREADS" in
 298  posix)
 299     THREADLIBS=-lpthread
 300     THREADSPEC=-lpthread
 301     THREADOBJS=posix-threads.lo
 302     THREADH=posix-threads.h
 303     # MIT pthreads doesn't seem to have the mutexattr functions.
 304     # But for now we don't check for it.  We just assume you aren't
 305     # using MIT pthreads.
 306     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 307     ;;
 308
 309  none)
 310     THREADOBJS=no-threads.lo
 311     THREADH=no-threads.h
 312     ;;
 313 esac
 314 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 315 AC_SUBST(THREADLIBS)
 316 AC_SUBST(THREADINCS)
 317 AC_SUBST(THREADDEPS)
 318 AC_SUBST(THREADOBJS)
 319 AC_SUBST(THREADSPEC)
 320
 321 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 322
 323 CANADIAN=no
 324 NULL_TARGET=no
 325 NATIVE=yes
 326
 327 # Find eh-common.h and support headers.  If we're in the tree with
 328 # gcc, then look there.  Otherwise look in compat-include.  If all else
 329 # fails, just hope the user has set things up somehow.
 330 if test -r $srcdir/../gcc/eh-common.h; then
 331    EH_COMMON_INCLUDE='-I$(top_srcdir)/../gcc -I$(top_srcdir)/../include'
 332 else
 333    if test -d $srcdir/../compat-include; then
 334       EH_COMMON_INCLUDE='-I$(top_srcdir)/../compat-include'
 335    else
 336       EH_COMMON_INCLUDE=
 337    fi
 338 fi
 339
 340 if test -n "${with_cross_host}"; then
 341    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 342    # may not work correctly, because the compiler may not be able to
 343    # link executables.
 344
 345    # We assume newlib.  This lets us hard-code the functions we know
 346    # we'll have.
 347    AC_DEFINE(HAVE_MEMMOVE)
 348    AC_DEFINE(HAVE_MEMCPY)
 349    AC_DEFINE(HAVE_STRERROR)
 350    AC_DEFINE(HAVE_GMTIME_R)
 351    AC_DEFINE(HAVE_LOCALTIME_R)
 352    dnl This is only for POSIX threads.
 353    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 354    dnl We also assume we are using gcc, which provides alloca.
 355    AC_DEFINE(HAVE_ALLOCA)
 356
 357    dnl Assume we do not have getuid and friends.
 358    AC_DEFINE(NO_GETUID)
 359
 360    ZLIBSPEC=-lzgcj
 361
 362    # If Canadian cross, then don't pick up tools from the build
 363    # directory.
 364    if test "$build" != "$with_cross_host"; then
 365       CANADIAN=yes
 366       EH_COMMON_INCLUDE=
 367       GCJ="${target_alias}-gcj"
 368    else
 369       GCJ=
 370    fi
 371    NATIVE=no
 372 else
 373    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 374    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 375    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath iconv)
 376    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 377    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 378    AC_CHECK_FUNCS(backtrace fork execvp pipe)
 379    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 380    AC_CHECK_LIB(dl, dladdr, [
 381      AC_DEFINE(HAVE_DLADDR)])
 382    AC_CHECK_FILES(/proc/self/exe, [
 383      AC_DEFINE(HAVE_PROC_SELF_EXE)])
 384
 385    AC_CHECK_FUNCS(gethostbyname_r, [
 386      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 387      # There are two different kinds of gethostbyname_r.
 388      # We look for the one that returns `int'.
 389      # Hopefully this check is robust enough.
 390      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 391        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 392
 393      case " $GCINCS " in
 394      *" -D_REENTRANT "*) ;;
 395      *)
 396         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 397         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 398         [libjava_cv_gethostbyname_r_needs_reentrant],
 399         [ AC_LANG_SAVE
 400           AC_LANG_CPLUSPLUS
 401           AC_TRY_COMPILE([#include <netdb.h>],
 402             [gethostbyname_r("", 0, 0);],
 403             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 404                 CPPFLAGS_SAVE="$CPPFLAGS"
 405                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 406                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 407                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 408                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 409                 CPPFLAGS="$CPPFLAGS_SAVE"
 410           ])
 411           AC_LANG_RESTORE
 412         ])
 413         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 414           AC_DEFINE(GETHOSTBYNAME_R_NEEDS_REENTRANT, 1, [Define if gethostbyname_r is only declared if _REENTRANT is defined])
 415         fi
 416      ;;
 417      esac
 418
 419      AC_CACHE_CHECK([for struct hostent_data],
 420         [libjava_cv_struct_hostent_data], [dnl
 421         AC_TRY_COMPILE([
 422 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 423 # define _REENTRANT 1
 424 #endif
 425 #include <netdb.h>], [struct hostent_data data;],
 426           [libjava_cv_struct_hostent_data=yes],
 427           [libjava_cv_struct_hostent_data=no])])
 428      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 429        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 430          [Define if struct hostent_data is defined in netdb.h])
 431      fi
 432    ])
 433
 434    AC_CHECK_FUNCS(gethostbyaddr_r, [
 435      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 436      # There are two different kinds of gethostbyaddr_r.
 437      # We look for the one that returns `int'.
 438      # Hopefully this check is robust enough.
 439      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 440        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 441
 442    AC_CHECK_FUNCS(gethostname, [
 443      AC_DEFINE(HAVE_GETHOSTNAME)
 444      AC_EGREP_HEADER(gethostname, unistd.h, [
 445        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 446
 447    # Look for these functions in the thread library, but only bother
 448    # if using POSIX threads.
 449    if test "$THREADS" = posix; then
 450       save_LIBS="$LIBS"
 451       LIBS="$LIBS $THREADLIBS"
 452       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 453       # E.g., Solaris.
 454       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 455
 456       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 457       # Solaris 7 the name librt is preferred.
 458       AC_CHECK_FUNCS(sched_yield, , [
 459         AC_CHECK_LIB(rt, sched_yield, [
 460           AC_DEFINE(HAVE_SCHED_YIELD)
 461           THREADLIBS="$THREADLIBS -lrt"
 462           THREADSPEC="$THREADSPEC -lrt"], [
 463           AC_CHECK_LIB(posix4, sched_yield, [
 464             AC_DEFINE(HAVE_SCHED_YIELD)
 465             THREADLIBS="$THREADLIBS -lposix4"
 466             THREADSPEC="$THREADSPEC -lposix4"])])])
 467       LIBS="$save_LIBS"
 468
 469       # We can save a little space at runtime if the mutex has m_count
 470       # or __m_count.  This is a nice hack for Linux.
 471       AC_TRY_COMPILE([#include <pthread.h>], [
 472           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 473         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 474         AC_TRY_COMPILE([#include <pthread.h>], [
 475             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 476           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 477    fi
 478
 479    # We require a way to get the time.
 480    time_found=no
 481    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 482    if test "$time_found" = no; then
 483       AC_MSG_ERROR([no function found to get the time])
 484    fi
 485
 486    AC_CHECK_FUNCS(memmove)
 487
 488    # We require memcpy.
 489    memcpy_found=no
 490    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 491    if test "$memcpy_found" = no; then
 492       AC_MSG_ERROR([memcpy is required])
 493    fi
 494
 495    # Some library-finding code we stole from Tcl.
 496    #--------------------------------------------------------------------
 497    #    Check for the existence of the -lsocket and -lnsl libraries.
 498    #    The order here is important, so that they end up in the right
 499    #    order in the command line generated by make.  Here are some
 500    #    special considerations:
 501    #    1. Use "connect" and "accept" to check for -lsocket, and
 502    #       "gethostbyname" to check for -lnsl.
 503    #    2. Use each function name only once:  can't redo a check because
 504    #       autoconf caches the results of the last check and won't redo it.
 505    #    3. Use -lnsl and -lsocket only if they supply procedures that
 506    #       aren't already present in the normal libraries.  This is because
 507    #       IRIX 5.2 has libraries, but they aren't needed and they're
 508    #       bogus:  they goof up name resolution if used.
 509    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 510    #       To get around this problem, check for both libraries together
 511    #       if -lsocket doesn't work by itself.
 512    #--------------------------------------------------------------------
 513
 514    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 515     [gcj_cv_lib_sockets=
 516      gcj_checkBoth=0
 517      unset ac_cv_func_connect
 518      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 519      if test "$gcj_checkSocket" = 1; then
 520          unset ac_cv_func_connect
 521          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 522                       gcj_checkBoth=1)
 523      fi
 524      if test "$gcj_checkBoth" = 1; then
 525          gcj_oldLibs=$LIBS
 526          LIBS="$LIBS -lsocket -lnsl"
 527          unset ac_cv_func_accept
 528          AC_CHECK_FUNC(accept,
 529                        [gcj_checkNsl=0
 530                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 531          unset ac_cv_func_accept
 532          LIBS=$gcj_oldLibs
 533      fi
 534      unset ac_cv_func_gethostbyname
 535      gcj_oldLibs=$LIBS
 536      LIBS="$LIBS $gcj_cv_lib_sockets"
 537      AC_CHECK_FUNC(gethostbyname, ,
 538                    [AC_CHECK_LIB(nsl, main,
 539                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 540      unset ac_cv_func_gethostbyname
 541      LIBS=$gcj_oldLIBS
 542    ])
 543    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 544
 545    if test "$with_system_zlib" = yes; then
 546       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 547    else
 548       ZLIBSPEC=-lzgcj
 549    fi
 550
 551    # On Solaris, and maybe other architectures, the Boehm collector
 552    # requires -ldl.
 553    if test "$GC" = boehm; then
 554       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 555    fi
 556
 557    if test -d "$libgcj_basedir/../gcc/java"; then
 558       GCJ=
 559    else
 560       CANADIAN=yes
 561       NULL_TARGET=yes
 562       GCJ=gcj
 563    fi
 564 fi
 565
 566 ZLIBS=
 567 ZDEPS=
 568 ZINCS=
 569 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 570    # We include the path to the zlib build directory.
 571    # See Makefile.am to understand why.
 572    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 573    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 574    ZINCS='-I$(top_srcdir)/../zlib'
 575 else
 576    ZLIBS="$ZLIBSPEC"
 577 fi
 578 AC_SUBST(ZLIBS)
 579 AC_SUBST(ZDEPS)
 580 AC_SUBST(ZINCS)
 581 AC_SUBST(DIVIDESPEC)
 582 AC_SUBST(EXCEPTIONSPEC)
 583 AC_SUBST(FORCELIBGCCSPEC)
 584
 585 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 586 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 587 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 588 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 589 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 590 AC_SUBST(EH_COMMON_INCLUDE)
 591
 592 # Determine gcj version number.
 593 if test "$GCJ" = ""; then
 594    if test -z "${with_multisubdir}"; then
 595       builddotdot=.
 596    else
 597 changequote(<<,>>)
 598       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 599 changequote([,])
 600    fi
 601    dir="`cd ${builddotdot}/../../gcc && pwd`"
 602    GCJ="$dir/gcj -B$dir/"
 603 fi
 604 changequote(<<,>>)
 605 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 606 changequote([,])
 607 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 608
 609 # See if gcj supports -fuse-divide-subroutine.  gcc 2.95 does not, and
 610 # we want to continue to support that version.
 611 AC_MSG_CHECKING([whether gcj supports -fuse-divide-subroutine])
 612 cat > conftest.java << 'END'
 613 public class conftest { }
 614 END
 615 use_fuse=yes
 616 $GCJ -classpath $srcdir -fuse-divide-subroutine -fsyntax-only \
 617    conftest.java > /dev/null 2>&1 \
 618    || use_fuse=no
 619 rm -f conftest.java
 620 if test "$use_fuse" = no; then
 621    DIVIDESPEC=
 622 fi
 623 AC_MSG_RESULT($use_fuse)
 624
 625 AC_SUBST(AM_RUNTESTFLAGS)
 626
 627 dnl Work around a g++ bug.  Reported to gcc-bugs@gcc.gnu.org on Jan 22, 2000.
 628 AC_MSG_CHECKING([for g++ -ffloat-store bug])
 629 save_CFLAGS="$CFLAGS"
 630 CFLAGS="-x c++ -O2 -ffloat-store"
 631 AC_TRY_COMPILE([#include <math.h>], ,
 632   [AC_MSG_RESULT(no)],
 633   [AC_DEFINE(__NO_MATH_INLINES)
 634    AC_MSG_RESULT(yes)])
 635 CFLAGS="$save_CFLAGS"
 636
 637 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 638 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 639 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 640 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h)
 641 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 642 dnl for now.  If you change this, you also must update natFile.cc.
 643 AC_CHECK_HEADERS(dirent.h)
 644
 645 AC_CHECK_TYPE([ssize_t], [int])
 646
 647 AC_MSG_CHECKING([for in_addr_t])
 648 AC_TRY_COMPILE([#include <sys/types.h>
 649 #if STDC_HEADERS
 650 #include <stdlib.h>
 651 #include <stddef.h>
 652 #endif
 653 #if HAVE_NETINET_IN_H
 654 #include <netinet/in.h>
 655 #endif], [in_addr_t foo;],
 656   [AC_DEFINE([HAVE_IN_ADDR_T])
 657    AC_MSG_RESULT(yes)],
 658   [AC_MSG_RESULT(no)])
 659
 660 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 661 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 662   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 663    AC_MSG_RESULT(yes)],
 664   [AC_MSG_RESULT(no)])
 665
 666 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 667 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 668   [AC_DEFINE(HAVE_INET6)
 669    AC_MSG_RESULT(yes)],
 670   [AC_MSG_RESULT(no)])
 671
 672 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 673 AC_TRY_COMPILE([#include <sys/socket.h>], [socklen_t x = 5;],
 674   [AC_DEFINE(HAVE_SOCKLEN_T)
 675    AC_MSG_RESULT(yes)],
 676   [AC_MSG_RESULT(no)])
 677
 678 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 679 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 680   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 681    AC_MSG_RESULT(yes)],
 682   [AC_MSG_RESULT(no)
 683    AC_MSG_CHECKING([for global timezone variable])
 684    dnl FIXME: we don't want a link check here because that won't work
 685    dnl when cross-compiling.  So instead we make an assumption that
 686    dnl the header file will mention timezone if it exists.
 687    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 688      [AC_DEFINE(HAVE_TIMEZONE)
 689       AC_MSG_RESULT(yes)],
 690      [AC_MSG_RESULT(no)])])
 691
 692 AC_FUNC_ALLOCA
 693
 694 AC_CHECK_PROGS(PERL, perl, false)
 695
 696 if test "$enable_sjlj_exceptions" = yes; then
 697    SIGNAL_HANDLER=include/default-signal.h
 698 else
 699    case "${host}" in
 700     i?86-*-linux*)
 701        SIGNAL_HANDLER=include/i386-signal.h
 702        ;;
 703     sparc-sun-solaris*)
 704        SIGNAL_HANDLER=include/sparc-signal.h
 705        ;;
 706     *)
 707        SIGNAL_HANDLER=include/default-signal.h
 708        ;;
 709    esac
 710 fi
 711
 712 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 713
 714 if test "${multilib}" = "yes"; then
 715   multilib_arg="--enable-multilib"
 716 else
 717   multilib_arg=
 718 fi
 719
 720 here=`pwd`
 721 AC_SUBST(here)
 722
 723 AC_OUTPUT(Makefile libgcj.spec gcj/Makefile include/Makefile testsuite/Makefile,
 724 [if test -n "$CONFIG_FILES"; then
 725   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 726 fi],
 727 srcdir=${srcdir}
 728 host=${host}
 729 target=${target}
 730 with_multisubdir=${with_multisubdir}
 731 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 732 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 733 libgcj_basedir=${libgcj_basedir}
 734 CC="${CC}"
 735 CXX="${CXX}"
 736 )