libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8
   9 dnl We use these options to decide which functions to include.
  10 AC_ARG_WITH(target-subdir,
  11 [  --with-target-subdir=SUBDIR
  12                            configuring in a subdirectory])
  13 AC_ARG_WITH(cross-host,
  14 [  --with-cross-host=HOST  configuring with a cross compiler])
  15
  16 LIBGCJ_CONFIGURE(.)
  17
  18 AM_CONFIG_HEADER(include/config.h)
  19
  20 # Only use libltdl for native builds.
  21 if test -z "${with_cross_host}"; then
  22    AC_LIBLTDL_CONVENIENCE
  23    AC_LIBTOOL_DLOPEN
  24    DIRLTDL=libltdl
  25    AC_DEFINE(USE_LTDL)
  26    # Sigh.  Libtool's macro doesn't do the right thing.
  27    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  28 fi
  29 AC_SUBST(INCLTDL)
  30 AC_SUBST(LIBLTDL)
  31 AC_SUBST(DIRLTDL)
  32 AM_PROG_LIBTOOL
  33 AC_CONFIG_SUBDIRS($DIRLTDL)
  34
  35 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  36    COMPPATH=.
  37 else
  38    COMPPATH=..
  39 fi
  40 AC_SUBST(COMPPATH)
  41
  42 dnl The -no-testsuite modules omit the test subdir.
  43 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  44
  45 dnl See whether the user prefers size or speed for Character.
  46 dnl The default is size.
  47 AC_ARG_ENABLE(fast-character,
  48 [  --enable-fast-character prefer speed over size for Character],
  49 # Nothing
  50 , AC_DEFINE(COMPACT_CHARACTER))
  51
  52 AC_ARG_ENABLE(java-awt,
  53 [  --enable-java-awt       enable AWT implementation],
  54   awt=$enable_java_awt
  55 , [# Default to enabled on native systems.
  56 if test -z "${with_cross_host}"; then
  57    awt=yes
  58 else
  59    awt=no
  60 fi])
  61
  62 AM_CONDITIONAL(AWT, test "$awt" = yes)
  63
  64 dnl Should the runtime set system properties by examining the
  65 dnl environment variable GCJ_PROPERTIES?
  66 AC_ARG_ENABLE(getenv-properties,
  67 [  --disable-getenv-properties
  68                           don't set system properties from GCJ_PROPERTIES])
  69
  70 dnl Whether GCJ_PROPERTIES is used depends on the target.
  71 if test -n "$enable_getenv_properties"; then
  72    enable_getenv_properties=${enable_getenv_properties_default-yes}
  73 fi
  74 if test "$enable_getenv_properties" = no; then
  75    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  76 fi
  77
  78 dnl See if the user has requested runtime debugging.
  79 AC_ARG_ENABLE(libgcj-debug,
  80 [  --enable-libgcj-debug   enable runtime debugging code],
  81   if test "$enable_libgcj_debug" = yes; then
  82      AC_DEFINE(DEBUG)
  83   fi)
  84
  85 dnl See if the user has the interpreter included.
  86 AC_ARG_ENABLE(interpreter,
  87 [  --enable-interpreter    enable interpreter],
  88   if test "$enable_interpreter" = yes; then
  89     # This can also be set in configure.host.
  90     libgcj_interpreter=yes
  91   elif test "$enable_interpreter" = no; then
  92     libgcj_interpreter=no
  93   fi)
  94
  95 if test "$libgcj_interpreter" = yes; then
  96    AC_DEFINE(INTERPRETER)
  97 fi
  98
  99 EXCEPTIONSPEC=
 100 dnl See if we should use setjmp/longjmp exceptions
 101 AC_ARG_ENABLE(sjlj-exceptions,
 102 [  --enable-sjlj-exceptions    use setjmp/longjmp exceptions],
 103   if test "$enable_sjlj_exceptions" = yes; then
 104      # This can be set in configure.host.
 105      libgcj_sjlj=yes
 106   fi)
 107
 108 if test "$libgcj_sjlj" = yes; then
 109    EXCEPTIONSPEC="-fsjlj-exceptions"
 110    AC_DEFINE(SJLJ_EXCEPTIONS)
 111 fi
 112
 113 FORCELIBGCCSPEC=
 114 dnl Work around libgcc design flaw.
 115 if test "$ac_cv_prog_gnu_ld" = yes; then
 116    FORCELIBGCCSPEC="-u __rethrow -u __frame_state_for -lgcc"
 117 fi
 118
 119 AC_MSG_CHECKING([for data_start])
 120 LIBDATASTARTSPEC=
 121 NEEDS_DATA_START=
 122 AC_TRY_LINK([extern int data_start;], [return ((int) &data_start);],
 123   [AC_MSG_RESULT(found it)],
 124   [LIBDATASTARTSPEC="-u data_start -lgcjdata"
 125    NEEDS_DATA_START=yes
 126    AC_MSG_RESULT(missing)])
 127 AC_SUBST(LIBDATASTARTSPEC)
 128
 129 dnl See if the user wants to disable java.net.  This is the mildly
 130 dnl ugly way that we admit that target-side configuration sucks.
 131 AC_ARG_ENABLE(java-net,
 132 [  --disable-java-net      disable java.net])
 133
 134 dnl Whether java.net is built by default can depend on the target.
 135 if test -n "$enable_java_net"; then
 136    enable_java_net=${enable_java_net_default-yes}
 137 fi
 138 if test "$enable_java_net" = no; then
 139    AC_DEFINE(DISABLE_JAVA_NET)
 140 fi
 141
 142 dnl See if the user wants to disable JVMPI support.
 143 AC_ARG_ENABLE(jvmpi,
 144 [  --disable-jvmpi         disable JVMPI support])
 145
 146 if test "$enable_jvmpi" != no; then
 147     AC_DEFINE(ENABLE_JVMPI)
 148 fi
 149
 150 dnl If the target is an eCos system, use the appropriate eCos
 151 dnl I/O routines.
 152 dnl FIXME: this should not be a local option but a global target
 153 dnl system; at present there is no eCos target.
 154 TARGET_ECOS="no"
 155 AC_ARG_WITH(ecos,
 156 [  --with-ecos             enable runtime eCos target support],
 157 TARGET_ECOS="$with_ecos"
 158 )
 159
 160 case "$TARGET_ECOS" in
 161    no)
 162       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
 163       PROCESS=${PROCESS-Posix}
 164       ;;
 165    *)
 166       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
 167       PROCESS=Ecos
 168       AC_DEFINE(ECOS)
 169       ;;
 170 esac
 171
 172 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 173 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 174 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 175 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 176
 177
 178 dnl These may not be defined in a non-ANS conformant embedded system.
 179 dnl FIXME: Should these case a runtime exception in that case?
 180 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 181 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 182
 183 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 184 dnl to create the link will fail.
 185 test -d java || mkdir java
 186 test -d java/io || mkdir java/io
 187 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 188
 189 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 190 test -d java/lang || mkdir java/lang
 191 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 192 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 193
 194 SYSTEMSPEC=
 195 AC_SUBST(SYSTEMSPEC)
 196
 197 LIBGCJTESTSPEC="-L`pwd`/.libs -rpath `pwd`/.libs"
 198 AC_SUBST(LIBGCJTESTSPEC)
 199
 200 AC_ARG_WITH(system-zlib,
 201 [  --with-system-zlib      use installed libz])
 202 ZLIBSPEC=
 203 AC_SUBST(ZLIBSPEC)
 204 ZLIBTESTSPEC=
 205 AC_SUBST(ZLIBTESTSPEC)
 206
 207 dnl FIXME: this should be _libs on some hosts.
 208 libsubdir=.libs
 209
 210 dnl Allow the GC to be disabled.  Can be useful when debugging.
 211 AC_MSG_CHECKING([for garbage collector to use])
 212 AC_ARG_ENABLE(java-gc,
 213 changequote(<<,>>)dnl
 214 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 215 changequote([,])
 216   GC=$enableval,
 217   GC=boehm)
 218 GCLIBS=
 219 GCINCS=
 220 GCDEPS=
 221 GCOBJS=
 222 GCSPEC=
 223 GCTESTSPEC=
 224 case "$GC" in
 225  boehm)
 226     AC_MSG_RESULT(boehm)
 227     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 228     # We include the path to the boehm-gc build directory.
 229     # See Makefile.am to understand why.
 230     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 231     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
 232     GCSPEC='-lgcjgc'
 233     GCTESTSPEC="-L`pwd`/../boehm-gc/.libs -rpath `pwd`/../boehm-gc/.libs"
 234     dnl We also want to pick up some cpp flags required when including
 235     dnl boehm-config.h.  Yuck.
 236     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 237     GCOBJS=boehm.lo
 238     GCHDR=boehm-gc.h
 239     dnl The POSIX thread support needs to know this.
 240     AC_DEFINE(HAVE_BOEHM_GC)
 241     ;;
 242  no)
 243     AC_MSG_RESULT(none)
 244     GCOBJS=nogc.lo
 245     GCHDR=no-gc.h
 246     ;;
 247  *)
 248     AC_MSG_ERROR(unrecognized collector \"$GC\")
 249     ;;
 250 esac
 251 AC_SUBST(GCLIBS)
 252 AC_SUBST(GCINCS)
 253 AC_SUBST(GCDEPS)
 254 AC_SUBST(GCOBJS)
 255 AC_SUBST(GCSPEC)
 256 AC_SUBST(GCTESTSPEC)
 257 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 258
 259
 260 dnl Note that this code is kept in sync with similar code in gcc/configure.in.
 261 dnl In particular both packages must make the same decision about which
 262 dnl thread package to use.
 263 AC_MSG_CHECKING([for threads package to use])
 264 AC_ARG_ENABLE(threads, [  --enable-threads=TYPE   choose threading package],
 265   THREADS=$enableval,
 266   dnl FIXME: figure out native threads to use here.
 267   THREADS=no)
 268
 269 if test "$THREADS" = yes; then
 270    case "$host" in
 271     *-*-vxworks*)
 272        THREADS=vxworks
 273        ;;
 274     *-*-linux*)
 275        # FIXME: this isn't correct in all cases.
 276        THREADS=posix
 277        ;;
 278     *-*-win*)
 279        THREADS=win32
 280        ;;
 281     *-*-irix*)
 282        # FIXME: for now, choose POSIX, because we implement that.
 283        # Later, choose irix threads.
 284        THREADS=posix
 285        ;;
 286     *-*-solaris*)
 287        # FIXME: for now, choose POSIX, because we implement that.
 288        # Later, choose solaris threads.
 289        THREADS=posix
 290        ;;
 291     *)
 292        # For now.
 293        THREADS=none
 294        ;;
 295    esac
 296 fi
 297
 298 case "$THREADS" in
 299  no | none | single)
 300     THREADS=none
 301     ;;
 302  posix | pthreads)
 303     THREADS=posix
 304     case "$host" in
 305      *-*-linux*)
 306         AC_DEFINE(LINUX_THREADS)
 307         ;;
 308     esac
 309     ;;
 310  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 311     AC_MSG_ERROR(thread package $THREADS not yet supported)
 312     ;;
 313  *)
 314     AC_MSG_ERROR($THREADS is an unknown thread package)
 315     ;;
 316 esac
 317 AC_MSG_RESULT($THREADS)
 318
 319 THREADLIBS=
 320 THREADINCS=
 321 THREADDEPS=
 322 THREADOBJS=
 323 THREADH=
 324 THREADSPEC=
 325 case "$THREADS" in
 326  posix)
 327     THREADLIBS=-lpthread
 328     THREADSPEC=-lpthread
 329     THREADOBJS=posix-threads.lo
 330     THREADH=posix-threads.h
 331     # MIT pthreads doesn't seem to have the mutexattr functions.
 332     # But for now we don't check for it.  We just assume you aren't
 333     # using MIT pthreads.
 334     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 335     ;;
 336
 337  none)
 338     THREADOBJS=no-threads.lo
 339     THREADH=no-threads.h
 340     ;;
 341 esac
 342 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 343 AC_SUBST(THREADLIBS)
 344 AC_SUBST(THREADINCS)
 345 AC_SUBST(THREADDEPS)
 346 AC_SUBST(THREADOBJS)
 347 AC_SUBST(THREADSPEC)
 348
 349 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 350
 351 CANADIAN=no
 352 NULL_TARGET=no
 353 NATIVE=yes
 354
 355 # Find eh-common.h and support headers.  If we're in the tree with
 356 # gcc, then look there.  Otherwise look in compat-include.  If all else
 357 # fails, just hope the user has set things up somehow.
 358 if test -r $srcdir/../gcc/eh-common.h; then
 359    EH_COMMON_INCLUDE='-I$(top_srcdir)/../gcc -I$(top_srcdir)/../include'
 360 else
 361    if test -d $srcdir/../compat-include; then
 362       EH_COMMON_INCLUDE='-I$(top_srcdir)/../compat-include'
 363    else
 364       EH_COMMON_INCLUDE=
 365    fi
 366 fi
 367
 368 if test -n "${with_cross_host}"; then
 369    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 370    # may not work correctly, because the compiler may not be able to
 371    # link executables.
 372
 373    # We assume newlib.  This lets us hard-code the functions we know
 374    # we'll have.
 375    AC_DEFINE(HAVE_MEMMOVE)
 376    AC_DEFINE(HAVE_MEMCPY)
 377    AC_DEFINE(HAVE_STRERROR)
 378    AC_DEFINE(HAVE_GMTIME_R)
 379    AC_DEFINE(HAVE_LOCALTIME_R)
 380    dnl This is only for POSIX threads.
 381    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 382    dnl We also assume we are using gcc, which provides alloca.
 383    AC_DEFINE(HAVE_ALLOCA)
 384
 385    dnl Assume we do not have getuid and friends.
 386    AC_DEFINE(NO_GETUID)
 387
 388    ZLIBSPEC=-lzgcj
 389    ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 390
 391    # If Canadian cross, then don't pick up tools from the build
 392    # directory.
 393    if test "$build" != "$with_cross_host"; then
 394       CANADIAN=yes
 395       EH_COMMON_INCLUDE=
 396       GCJ="${target_alias}-gcj"
 397    else
 398       GCJ=
 399    fi
 400    NATIVE=no
 401 else
 402    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 403    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 404    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath iconv)
 405    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 406    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 407    AC_CHECK_FUNCS(backtrace fork execvp pipe)
 408    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 409    AC_CHECK_LIB(dl, dladdr, [
 410      AC_DEFINE(HAVE_DLADDR)])
 411    AC_CHECK_FILES(/proc/self/exe, [
 412      AC_DEFINE(HAVE_PROC_SELF_EXE)])
 413
 414    AC_CHECK_FUNCS(gethostbyname_r, [
 415      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 416      # There are two different kinds of gethostbyname_r.
 417      # We look for the one that returns `int'.
 418      # Hopefully this check is robust enough.
 419      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 420        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 421
 422      case " $GCINCS " in
 423      *" -D_REENTRANT "*) ;;
 424      *)
 425         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 426         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 427         [libjava_cv_gethostbyname_r_needs_reentrant],
 428         [ AC_LANG_SAVE
 429           AC_LANG_CPLUSPLUS
 430           AC_TRY_COMPILE([#include <netdb.h>],
 431             [gethostbyname_r("", 0, 0);],
 432             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 433                 CPPFLAGS_SAVE="$CPPFLAGS"
 434                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 435                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 436                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 437                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 438                 CPPFLAGS="$CPPFLAGS_SAVE"
 439           ])
 440           AC_LANG_RESTORE
 441         ])
 442         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 443           AC_DEFINE(GETHOSTBYNAME_R_NEEDS_REENTRANT, 1, [Define if gethostbyname_r is only declared if _REENTRANT is defined])
 444         fi
 445      ;;
 446      esac
 447
 448      AC_CACHE_CHECK([for struct hostent_data],
 449         [libjava_cv_struct_hostent_data], [dnl
 450         AC_TRY_COMPILE([
 451 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 452 # define _REENTRANT 1
 453 #endif
 454 #include <netdb.h>], [struct hostent_data data;],
 455           [libjava_cv_struct_hostent_data=yes],
 456           [libjava_cv_struct_hostent_data=no])])
 457      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 458        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 459          [Define if struct hostent_data is defined in netdb.h])
 460      fi
 461    ])
 462
 463    AC_CHECK_FUNCS(gethostbyaddr_r, [
 464      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 465      # There are two different kinds of gethostbyaddr_r.
 466      # We look for the one that returns `int'.
 467      # Hopefully this check is robust enough.
 468      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 469        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 470
 471    AC_CHECK_FUNCS(gethostname, [
 472      AC_DEFINE(HAVE_GETHOSTNAME)
 473      AC_EGREP_HEADER(gethostname, unistd.h, [
 474        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 475
 476    # Look for these functions in the thread library, but only bother
 477    # if using POSIX threads.
 478    if test "$THREADS" = posix; then
 479       save_LIBS="$LIBS"
 480       LIBS="$LIBS $THREADLIBS"
 481       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 482       # E.g., Solaris.
 483       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 484
 485       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 486       # Solaris 7 the name librt is preferred.
 487       AC_CHECK_FUNCS(sched_yield, , [
 488         AC_CHECK_LIB(rt, sched_yield, [
 489           AC_DEFINE(HAVE_SCHED_YIELD)
 490           THREADLIBS="$THREADLIBS -lrt"
 491           THREADSPEC="$THREADSPEC -lrt"], [
 492           AC_CHECK_LIB(posix4, sched_yield, [
 493             AC_DEFINE(HAVE_SCHED_YIELD)
 494             THREADLIBS="$THREADLIBS -lposix4"
 495             THREADSPEC="$THREADSPEC -lposix4"])])])
 496       LIBS="$save_LIBS"
 497
 498       # We can save a little space at runtime if the mutex has m_count
 499       # or __m_count.  This is a nice hack for Linux.
 500       AC_TRY_COMPILE([#include <pthread.h>], [
 501           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 502         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 503         AC_TRY_COMPILE([#include <pthread.h>], [
 504             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 505           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 506    fi
 507
 508    # We require a way to get the time.
 509    time_found=no
 510    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 511    if test "$time_found" = no; then
 512       AC_MSG_ERROR([no function found to get the time])
 513    fi
 514
 515    AC_CHECK_FUNCS(memmove)
 516
 517    # We require memcpy.
 518    memcpy_found=no
 519    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 520    if test "$memcpy_found" = no; then
 521       AC_MSG_ERROR([memcpy is required])
 522    fi
 523
 524    # Some library-finding code we stole from Tcl.
 525    #--------------------------------------------------------------------
 526    #    Check for the existence of the -lsocket and -lnsl libraries.
 527    #    The order here is important, so that they end up in the right
 528    #    order in the command line generated by make.  Here are some
 529    #    special considerations:
 530    #    1. Use "connect" and "accept" to check for -lsocket, and
 531    #       "gethostbyname" to check for -lnsl.
 532    #    2. Use each function name only once:  can't redo a check because
 533    #       autoconf caches the results of the last check and won't redo it.
 534    #    3. Use -lnsl and -lsocket only if they supply procedures that
 535    #       aren't already present in the normal libraries.  This is because
 536    #       IRIX 5.2 has libraries, but they aren't needed and they're
 537    #       bogus:  they goof up name resolution if used.
 538    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 539    #       To get around this problem, check for both libraries together
 540    #       if -lsocket doesn't work by itself.
 541    #--------------------------------------------------------------------
 542
 543    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 544     [gcj_cv_lib_sockets=
 545      gcj_checkBoth=0
 546      unset ac_cv_func_connect
 547      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 548      if test "$gcj_checkSocket" = 1; then
 549          unset ac_cv_func_connect
 550          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 551                       gcj_checkBoth=1)
 552      fi
 553      if test "$gcj_checkBoth" = 1; then
 554          gcj_oldLibs=$LIBS
 555          LIBS="$LIBS -lsocket -lnsl"
 556          unset ac_cv_func_accept
 557          AC_CHECK_FUNC(accept,
 558                        [gcj_checkNsl=0
 559                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 560          unset ac_cv_func_accept
 561          LIBS=$gcj_oldLibs
 562      fi
 563      unset ac_cv_func_gethostbyname
 564      gcj_oldLibs=$LIBS
 565      LIBS="$LIBS $gcj_cv_lib_sockets"
 566      AC_CHECK_FUNC(gethostbyname, ,
 567                    [AC_CHECK_LIB(nsl, main,
 568                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 569      unset ac_cv_func_gethostbyname
 570      LIBS=$gcj_oldLIBS
 571    ])
 572    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 573
 574    if test "$with_system_zlib" = yes; then
 575       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 576    else
 577       ZLIBSPEC=-lzgcj
 578       ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 579    fi
 580
 581    # On Solaris, and maybe other architectures, the Boehm collector
 582    # requires -ldl.
 583    if test "$GC" = boehm; then
 584       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 585    fi
 586
 587    if test -d "$libgcj_basedir/../gcc/java"; then
 588       GCJ=
 589    else
 590       CANADIAN=yes
 591       NULL_TARGET=yes
 592       GCJ=gcj
 593    fi
 594 fi
 595
 596 dnl FIXME: cross compilation
 597 AC_CHECK_SIZEOF(void *)
 598
 599 ZLIBS=
 600 ZDEPS=
 601 ZINCS=
 602 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 603    # We include the path to the zlib build directory.
 604    # See Makefile.am to understand why.
 605    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 606    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 607    ZINCS='-I$(top_srcdir)/../zlib'
 608 else
 609    ZLIBS="$ZLIBSPEC"
 610 fi
 611 AC_SUBST(ZLIBS)
 612 AC_SUBST(ZDEPS)
 613 AC_SUBST(ZINCS)
 614 AC_SUBST(DIVIDESPEC)
 615 AC_SUBST(EXCEPTIONSPEC)
 616 AC_SUBST(FORCELIBGCCSPEC)
 617
 618 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 619 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 620 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 621 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 622 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 623 AC_SUBST(EH_COMMON_INCLUDE)
 624
 625 # Determine gcj version number.
 626 if test "$GCJ" = ""; then
 627    if test -z "${with_multisubdir}"; then
 628       builddotdot=.
 629    else
 630 changequote(<<,>>)
 631       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 632 changequote([,])
 633    fi
 634    dir="`cd ${builddotdot}/../../gcc && pwd`"
 635    GCJ="$dir/gcj -B$dir/"
 636 fi
 637 changequote(<<,>>)
 638 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 639 changequote([,])
 640 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 641
 642 # See if gcj supports -fuse-divide-subroutine.  gcc 2.95 does not, and
 643 # we want to continue to support that version.
 644 AC_MSG_CHECKING([whether gcj supports -fuse-divide-subroutine])
 645 cat > conftest.java << 'END'
 646 public class conftest { }
 647 END
 648 use_fuse=yes
 649 $GCJ -classpath $srcdir -fuse-divide-subroutine -fsyntax-only \
 650    conftest.java > /dev/null 2>&1 \
 651    || use_fuse=no
 652 rm -f conftest.java
 653 if test "$use_fuse" = no; then
 654    DIVIDESPEC=
 655 fi
 656 AC_MSG_RESULT($use_fuse)
 657
 658 AC_SUBST(AM_RUNTESTFLAGS)
 659
 660 dnl Work around a g++ bug.  Reported to gcc-bugs@gcc.gnu.org on Jan 22, 2000.
 661 AC_MSG_CHECKING([for g++ -ffloat-store bug])
 662 save_CFLAGS="$CFLAGS"
 663 CFLAGS="-x c++ -O2 -ffloat-store"
 664 AC_TRY_COMPILE([#include <math.h>], ,
 665   [AC_MSG_RESULT(no)],
 666   [AC_DEFINE(__NO_MATH_INLINES)
 667    AC_MSG_RESULT(yes)])
 668 CFLAGS="$save_CFLAGS"
 669
 670 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 671 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 672 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 673 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h)
 674 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 675 dnl for now.  If you change this, you also must update natFile.cc.
 676 AC_CHECK_HEADERS(dirent.h)
 677
 678 AC_CHECK_TYPE([ssize_t], [int])
 679
 680 AC_MSG_CHECKING([for in_addr_t])
 681 AC_TRY_COMPILE([#include <sys/types.h>
 682 #if STDC_HEADERS
 683 #include <stdlib.h>
 684 #include <stddef.h>
 685 #endif
 686 #if HAVE_NETINET_IN_H
 687 #include <netinet/in.h>
 688 #endif], [in_addr_t foo;],
 689   [AC_DEFINE([HAVE_IN_ADDR_T])
 690    AC_MSG_RESULT(yes)],
 691   [AC_MSG_RESULT(no)])
 692
 693 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 694 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 695   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 696    AC_MSG_RESULT(yes)],
 697   [AC_MSG_RESULT(no)])
 698
 699 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 700 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 701   [AC_DEFINE(HAVE_INET6)
 702    AC_MSG_RESULT(yes)],
 703   [AC_MSG_RESULT(no)])
 704
 705 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 706 AC_TRY_COMPILE([#include <sys/socket.h>], [socklen_t x = 5;],
 707   [AC_DEFINE(HAVE_SOCKLEN_T)
 708    AC_MSG_RESULT(yes)],
 709   [AC_MSG_RESULT(no)])
 710
 711 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 712 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 713   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 714    AC_MSG_RESULT(yes)],
 715   [AC_MSG_RESULT(no)
 716    AC_MSG_CHECKING([for global timezone variable])
 717    dnl FIXME: we don't want a link check here because that won't work
 718    dnl when cross-compiling.  So instead we make an assumption that
 719    dnl the header file will mention timezone if it exists.
 720    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 721      [AC_DEFINE(HAVE_TIMEZONE)
 722       AC_MSG_RESULT(yes)],
 723      [AC_MSG_RESULT(no)])])
 724
 725 AC_FUNC_ALLOCA
 726
 727 AC_CHECK_PROGS(PERL, perl, false)
 728
 729 if test "$enable_sjlj_exceptions" = yes; then
 730    SIGNAL_HANDLER=include/default-signal.h
 731 else
 732    case "${host}" in
 733     i?86-*-linux*)
 734        SIGNAL_HANDLER=include/i386-signal.h
 735        ;;
 736     sparc-sun-solaris*)
 737        SIGNAL_HANDLER=include/sparc-signal.h
 738        ;;
 739     *)
 740        SIGNAL_HANDLER=include/default-signal.h
 741        ;;
 742    esac
 743 fi
 744
 745 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 746
 747 if test "${multilib}" = "yes"; then
 748   multilib_arg="--enable-multilib"
 749 else
 750   multilib_arg=
 751 fi
 752
 753 here=`pwd`
 754 AC_SUBST(here)
 755
 756 AC_OUTPUT(Makefile libgcj.spec libgcj-test.spec gcj/Makefile include/Makefile testsuite/Makefile,
 757 [if test -n "$CONFIG_FILES"; then
 758   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 759 fi],
 760 srcdir=${srcdir}
 761 host=${host}
 762 target=${target}
 763 with_multisubdir=${with_multisubdir}
 764 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 765 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 766 libgcj_basedir=${libgcj_basedir}
 767 CC="${CC}"
 768 CXX="${CXX}"
 769 )