libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_PROG_LN_S
   9
  10 dnl We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12 [  --with-target-subdir=SUBDIR
  13                            configuring in a subdirectory])
  14 AC_ARG_WITH(cross-host,
  15 [  --with-cross-host=HOST  configuring with a cross compiler])
  16
  17 LIBGCJ_CONFIGURE(.)
  18
  19 AM_CONFIG_HEADER(include/config.h)
  20
  21 # Only use libltdl for native builds.
  22 if test -z "${with_cross_host}"; then
  23    AC_LIBLTDL_CONVENIENCE
  24    AC_LIBTOOL_DLOPEN
  25    DIRLTDL=libltdl
  26    AC_DEFINE(USE_LTDL)
  27    # Sigh.  Libtool's macro doesn't do the right thing.
  28    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  29 fi
  30 AC_SUBST(INCLTDL)
  31 AC_SUBST(LIBLTDL)
  32 AC_SUBST(DIRLTDL)
  33 AM_PROG_LIBTOOL
  34 AC_CONFIG_SUBDIRS($DIRLTDL)
  35
  36 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  37    COMPPATH=.
  38 else
  39    COMPPATH=..
  40 fi
  41 AC_SUBST(COMPPATH)
  42
  43 dnl The -no-testsuite modules omit the test subdir.
  44 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  45
  46 dnl See whether the user prefers size or speed for Character.
  47 dnl The default is size.
  48 AC_ARG_ENABLE(fast-character,
  49 [  --enable-fast-character prefer speed over size for Character],
  50 # Nothing
  51 , AC_DEFINE(COMPACT_CHARACTER))
  52
  53 dnl Should the runtime set system properties by examining the
  54 dnl environment variable GCJ_PROPERTIES?
  55 AC_ARG_ENABLE(getenv-properties,
  56 [  --disable-getenv-properties
  57                           don't set system properties from GCJ_PROPERTIES])
  58
  59 dnl Whether GCJ_PROPERTIES is used depends on the target.
  60 if test -n "$enable_getenv_properties"; then
  61    enable_getenv_properties=${enable_getenv_properties_default-yes}
  62 fi
  63 if test "$enable_getenv_properties" = no; then
  64    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  65 fi
  66
  67 dnl See if the user has requested runtime debugging.
  68 LIBGCJDEBUG="false"
  69 AC_SUBST(LIBGCJDEBUG)
  70 AC_ARG_ENABLE(libgcj-debug,
  71 [  --enable-libgcj-debug   enable runtime debugging code],
  72   if test "$enable_libgcj_debug" = yes; then
  73     AC_DEFINE(DEBUG)
  74     LIBGCJDEBUG="true"
  75   fi)
  76
  77 dnl See if the user has the interpreter included.
  78 AC_ARG_ENABLE(interpreter,
  79 [  --enable-interpreter    enable interpreter],
  80   if test "$enable_interpreter" = yes; then
  81     # This can also be set in configure.host.
  82     libgcj_interpreter=yes
  83   elif test "$enable_interpreter" = no; then
  84     libgcj_interpreter=no
  85   fi)
  86
  87 if test "$libgcj_interpreter" = yes; then
  88    AC_DEFINE(INTERPRETER)
  89 fi
  90
  91 AC_MSG_CHECKING([for exception model to use])
  92 AC_LANG_SAVE
  93 AC_LANG_CPLUSPLUS
  94 AC_ARG_ENABLE(sjlj-exceptions,
  95 [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
  96 [:],
  97 [dnl Botheration.  Now we've got to detect the exception model.
  98 dnl Link tests against libgcc.a are problematic since -- at least
  99 dnl as of this writing -- we've not been given proper -L bits for
 100 dnl single-tree newlib and libgloss.
 101 dnl
 102 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 103 dnl conftest files before we got a change to grep them first.
 104 cat > conftest.$ac_ext << EOF
 105 [#]line __oline__ "configure"
 106 struct S { ~S(); };
 107 void bar();
 108 void foo()
 109 {
 110   S s;
 111   bar();
 112 }
 113 EOF
 114 old_CXXFLAGS="$CXXFLAGS"
 115 CXXFLAGS=-S
 116 if AC_TRY_EVAL(ac_compile); then
 117   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 118     enable_sjlj_exceptions=yes
 119   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 120     enable_sjlj_exceptions=no
 121   fi
 122 fi
 123 CXXFLAGS="$old_CXXFLAGS"
 124 rm -f conftest*])
 125 if test x$enable_sjlj_exceptions = xyes; then
 126   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 127         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 128   ac_exception_model_name=sjlj
 129 elif test x$enable_sjlj_exceptions = xno; then
 130   ac_exception_model_name="call frame"
 131 else
 132   AC_MSG_ERROR([unable to detect exception model])
 133 fi
 134 AC_LANG_RESTORE
 135 AC_MSG_RESULT($ac_exception_model_name)
 136
 137 AC_MSG_CHECKING([for data_start])
 138 LIBDATASTARTSPEC=
 139 NEEDS_DATA_START=
 140 AC_TRY_LINK([extern int data_start;], [return ((int) &data_start);],
 141   [AC_MSG_RESULT(found it)],
 142   [LIBDATASTARTSPEC="-u data_start libgcjdata.a%s"
 143    NEEDS_DATA_START=yes
 144    AC_MSG_RESULT(missing)])
 145 AC_SUBST(LIBDATASTARTSPEC)
 146
 147 dnl See if the user wants to disable java.net.  This is the mildly
 148 dnl ugly way that we admit that target-side configuration sucks.
 149 AC_ARG_ENABLE(java-net,
 150 [  --disable-java-net      disable java.net])
 151
 152 dnl Whether java.net is built by default can depend on the target.
 153 if test -n "$enable_java_net"; then
 154    enable_java_net=${enable_java_net_default-yes}
 155 fi
 156 if test "$enable_java_net" = no; then
 157    AC_DEFINE(DISABLE_JAVA_NET)
 158 fi
 159
 160 dnl See if the user wants to disable JVMPI support.
 161 AC_ARG_ENABLE(jvmpi,
 162 [  --disable-jvmpi         disable JVMPI support])
 163
 164 if test "$enable_jvmpi" != no; then
 165     AC_DEFINE(ENABLE_JVMPI)
 166 fi
 167
 168 dnl If the target is an eCos system, use the appropriate eCos
 169 dnl I/O routines.
 170 dnl FIXME: this should not be a local option but a global target
 171 dnl system; at present there is no eCos target.
 172 TARGET_ECOS="no"
 173 AC_ARG_WITH(ecos,
 174 [  --with-ecos             enable runtime eCos target support],
 175 TARGET_ECOS="$with_ecos"
 176 )
 177
 178 case "$TARGET_ECOS" in
 179    no)
 180       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
 181       PROCESS=${PROCESS-Posix}
 182       ;;
 183    *)
 184       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
 185       PROCESS=Ecos
 186       AC_DEFINE(ECOS)
 187       ;;
 188 esac
 189
 190 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 191 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 192 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 193 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 194
 195
 196 dnl These may not be defined in a non-ANS conformant embedded system.
 197 dnl FIXME: Should these case a runtime exception in that case?
 198 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 199 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 200
 201 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 202 dnl to create the link will fail.
 203 test -d java || mkdir java
 204 test -d java/io || mkdir java/io
 205 test -d gnu || mkdir gnu
 206 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 207
 208 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 209 test -d java/lang || mkdir java/lang
 210 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 211 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 212
 213 SYSTEMSPEC=
 214 AC_SUBST(SYSTEMSPEC)
 215
 216 LIBGCJTESTSPEC="-L`pwd`/.libs -rpath `pwd`/.libs"
 217 AC_SUBST(LIBGCJTESTSPEC)
 218
 219 AC_ARG_WITH(system-zlib,
 220 [  --with-system-zlib      use installed libz])
 221 ZLIBSPEC=
 222 AC_SUBST(ZLIBSPEC)
 223 ZLIBTESTSPEC=
 224 AC_SUBST(ZLIBTESTSPEC)
 225
 226 dnl FIXME: this should be _libs on some hosts.
 227 libsubdir=.libs
 228
 229 dnl Allow the GC to be disabled.  Can be useful when debugging.
 230 AC_MSG_CHECKING([for garbage collector to use])
 231 AC_ARG_ENABLE(java-gc,
 232 changequote(<<,>>)dnl
 233 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 234 changequote([,])
 235   GC=$enableval,
 236   GC=boehm)
 237 GCLIBS=
 238 GCINCS=
 239 GCDEPS=
 240 GCOBJS=
 241 GCSPEC=
 242 JC1GCSPEC=
 243 GCTESTSPEC=
 244 case "$GC" in
 245  boehm)
 246     AC_MSG_RESULT(boehm)
 247     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 248     # We include the path to the boehm-gc build directory.
 249     # See Makefile.am to understand why.
 250     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 251     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
 252     GCSPEC='-lgcjgc'
 253     JC1GCSPEC='-fuse-boehm-gc'
 254     GCTESTSPEC="-L`pwd`/../boehm-gc/.libs -rpath `pwd`/../boehm-gc/.libs"
 255     dnl We also want to pick up some cpp flags required when including
 256     dnl boehm-config.h.  Yuck.
 257     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 258     GCOBJS=boehm.lo
 259     GCHDR=boehm-gc.h
 260     dnl The POSIX thread support needs to know this.
 261     AC_DEFINE(HAVE_BOEHM_GC)
 262     ;;
 263  no)
 264     AC_MSG_RESULT(none)
 265     GCOBJS=nogc.lo
 266     GCHDR=no-gc.h
 267     ;;
 268  *)
 269     AC_MSG_ERROR(unrecognized collector \"$GC\")
 270     ;;
 271 esac
 272 AC_SUBST(GCLIBS)
 273 AC_SUBST(GCINCS)
 274 AC_SUBST(GCDEPS)
 275 AC_SUBST(GCOBJS)
 276 AC_SUBST(GCSPEC)
 277 AC_SUBST(JC1GCSPEC)
 278 AC_SUBST(GCTESTSPEC)
 279 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 280
 281
 282 AC_MSG_CHECKING([for thread model used by GCC])
 283 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 284 AC_MSG_RESULT([$THREADS])
 285
 286 case "$THREADS" in
 287  no | none | single)
 288     THREADS=none
 289     ;;
 290  posix | pthreads)
 291     THREADS=posix
 292     case "$host" in
 293      *-*-linux*)
 294         AC_DEFINE(LINUX_THREADS)
 295         ;;
 296     esac
 297     ;;
 298  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 299     AC_MSG_ERROR(thread package $THREADS not yet supported)
 300     ;;
 301  *)
 302     AC_MSG_ERROR($THREADS is an unknown thread package)
 303     ;;
 304 esac
 305
 306 THREADLIBS=
 307 THREADINCS=
 308 THREADDEPS=
 309 THREADOBJS=
 310 THREADH=
 311 THREADSPEC=
 312 case "$THREADS" in
 313  posix)
 314     THREADLIBS=-lpthread
 315     THREADSPEC=-lpthread
 316     THREADOBJS=posix-threads.lo
 317     THREADH=posix-threads.h
 318     # MIT pthreads doesn't seem to have the mutexattr functions.
 319     # But for now we don't check for it.  We just assume you aren't
 320     # using MIT pthreads.
 321     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 322
 323     # If we're using the Boehm GC, then we happen to know that it
 324     # defines _REENTRANT, so we don't bother.  Eww.
 325     if test "$GC" != boehm; then
 326        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 327     fi
 328     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 329     ;;
 330
 331  none)
 332     THREADOBJS=no-threads.lo
 333     THREADH=no-threads.h
 334     ;;
 335 esac
 336 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 337 AC_SUBST(THREADLIBS)
 338 AC_SUBST(THREADINCS)
 339 AC_SUBST(THREADDEPS)
 340 AC_SUBST(THREADOBJS)
 341 AC_SUBST(THREADSPEC)
 342
 343 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 344
 345 CANADIAN=no
 346 NULL_TARGET=no
 347 NATIVE=yes
 348
 349 # We're in the tree with gcc, and need to include some of its headers.
 350 GCC_UNWIND_INCLUDE='-I$(top_srcdir)/../gcc'
 351
 352 if test -n "${with_cross_host}"; then
 353    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 354    # may not work correctly, because the compiler may not be able to
 355    # link executables.
 356
 357    # We assume newlib.  This lets us hard-code the functions we know
 358    # we'll have.
 359    AC_DEFINE(HAVE_MEMMOVE)
 360    AC_DEFINE(HAVE_MEMCPY)
 361    AC_DEFINE(HAVE_STRERROR)
 362    AC_DEFINE(HAVE_GMTIME_R)
 363    AC_DEFINE(HAVE_LOCALTIME_R)
 364    dnl This is only for POSIX threads.
 365    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 366    dnl We also assume we are using gcc, which provides alloca.
 367    AC_DEFINE(HAVE_ALLOCA)
 368
 369    dnl Assume we do not have getuid and friends.
 370    AC_DEFINE(NO_GETUID)
 371
 372    ZLIBSPEC=-lzgcj
 373    ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 374
 375    # If Canadian cross, then don't pick up tools from the build
 376    # directory.
 377    if test "$build" != "$with_cross_host"; then
 378       CANADIAN=yes
 379       GCC_UNWIND_INCLUDE=
 380       GCJ="${target_alias}-gcj"
 381    else
 382       GCJ=
 383    fi
 384    NATIVE=no
 385 else
 386    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 387    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 388    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath utime chmod)
 389    AC_CHECK_FUNCS(iconv nl_langinfo setlocale)
 390    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 391    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 392    AC_CHECK_FUNCS(backtrace fork execvp pipe)
 393    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 394    AC_CHECK_LIB(dl, dladdr, [
 395      AC_DEFINE(HAVE_DLADDR)])
 396    AC_CHECK_FILES(/proc/self/exe, [
 397      AC_DEFINE(HAVE_PROC_SELF_EXE)])
 398
 399    AC_CHECK_FUNCS(gethostbyname_r, [
 400      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 401      # There are two different kinds of gethostbyname_r.
 402      # We look for the one that returns `int'.
 403      # Hopefully this check is robust enough.
 404      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 405        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 406
 407      case " $GCINCS " in
 408      *" -D_REENTRANT "*) ;;
 409      *)
 410         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 411         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 412         [libjava_cv_gethostbyname_r_needs_reentrant],
 413         [ AC_LANG_SAVE
 414           AC_LANG_CPLUSPLUS
 415           AC_TRY_COMPILE([#include <netdb.h>],
 416             [gethostbyname_r("", 0, 0);],
 417             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 418                 CPPFLAGS_SAVE="$CPPFLAGS"
 419                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 420                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 421                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 422                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 423                 CPPFLAGS="$CPPFLAGS_SAVE"
 424           ])
 425           AC_LANG_RESTORE
 426         ])
 427         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 428           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 429         fi
 430      ;;
 431      esac
 432
 433      AC_CACHE_CHECK([for struct hostent_data],
 434         [libjava_cv_struct_hostent_data], [dnl
 435         AC_TRY_COMPILE([
 436 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 437 # define _REENTRANT 1
 438 #endif
 439 #include <netdb.h>], [struct hostent_data data;],
 440           [libjava_cv_struct_hostent_data=yes],
 441           [libjava_cv_struct_hostent_data=no])])
 442      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 443        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 444          [Define if struct hostent_data is defined in netdb.h])
 445      fi
 446    ])
 447
 448    AC_CHECK_FUNCS(gethostbyaddr_r, [
 449      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 450      # There are two different kinds of gethostbyaddr_r.
 451      # We look for the one that returns `int'.
 452      # Hopefully this check is robust enough.
 453      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 454        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 455
 456    AC_CHECK_FUNCS(gethostname, [
 457      AC_DEFINE(HAVE_GETHOSTNAME)
 458      AC_EGREP_HEADER(gethostname, unistd.h, [
 459        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 460
 461    # Look for these functions in the thread library, but only bother
 462    # if using POSIX threads.
 463    if test "$THREADS" = posix; then
 464       save_LIBS="$LIBS"
 465       LIBS="$LIBS $THREADLIBS"
 466       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 467       # E.g., Solaris.
 468       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 469
 470       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 471       # Solaris 7 the name librt is preferred.
 472       AC_CHECK_FUNCS(sched_yield, , [
 473         AC_CHECK_LIB(rt, sched_yield, [
 474           AC_DEFINE(HAVE_SCHED_YIELD)
 475           THREADLIBS="$THREADLIBS -lrt"
 476           THREADSPEC="$THREADSPEC -lrt"], [
 477           AC_CHECK_LIB(posix4, sched_yield, [
 478             AC_DEFINE(HAVE_SCHED_YIELD)
 479             THREADLIBS="$THREADLIBS -lposix4"
 480             THREADSPEC="$THREADSPEC -lposix4"])])])
 481       LIBS="$save_LIBS"
 482
 483       # We can save a little space at runtime if the mutex has m_count
 484       # or __m_count.  This is a nice hack for Linux.
 485       AC_TRY_COMPILE([#include <pthread.h>], [
 486           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 487         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 488         AC_TRY_COMPILE([#include <pthread.h>], [
 489             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 490           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 491    fi
 492
 493    # We require a way to get the time.
 494    time_found=no
 495    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 496    if test "$time_found" = no; then
 497       AC_MSG_ERROR([no function found to get the time])
 498    fi
 499
 500    AC_CHECK_FUNCS(memmove)
 501
 502    # We require memcpy.
 503    memcpy_found=no
 504    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 505    if test "$memcpy_found" = no; then
 506       AC_MSG_ERROR([memcpy is required])
 507    fi
 508
 509    # Some library-finding code we stole from Tcl.
 510    #--------------------------------------------------------------------
 511    #    Check for the existence of the -lsocket and -lnsl libraries.
 512    #    The order here is important, so that they end up in the right
 513    #    order in the command line generated by make.  Here are some
 514    #    special considerations:
 515    #    1. Use "connect" and "accept" to check for -lsocket, and
 516    #       "gethostbyname" to check for -lnsl.
 517    #    2. Use each function name only once:  can't redo a check because
 518    #       autoconf caches the results of the last check and won't redo it.
 519    #    3. Use -lnsl and -lsocket only if they supply procedures that
 520    #       aren't already present in the normal libraries.  This is because
 521    #       IRIX 5.2 has libraries, but they aren't needed and they're
 522    #       bogus:  they goof up name resolution if used.
 523    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 524    #       To get around this problem, check for both libraries together
 525    #       if -lsocket doesn't work by itself.
 526    #--------------------------------------------------------------------
 527
 528    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 529     [gcj_cv_lib_sockets=
 530      gcj_checkBoth=0
 531      unset ac_cv_func_connect
 532      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 533      if test "$gcj_checkSocket" = 1; then
 534          unset ac_cv_func_connect
 535          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 536                       gcj_checkBoth=1)
 537      fi
 538      if test "$gcj_checkBoth" = 1; then
 539          gcj_oldLibs=$LIBS
 540          LIBS="$LIBS -lsocket -lnsl"
 541          unset ac_cv_func_accept
 542          AC_CHECK_FUNC(accept,
 543                        [gcj_checkNsl=0
 544                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 545          unset ac_cv_func_accept
 546          LIBS=$gcj_oldLibs
 547      fi
 548      unset ac_cv_func_gethostbyname
 549      gcj_oldLibs=$LIBS
 550      LIBS="$LIBS $gcj_cv_lib_sockets"
 551      AC_CHECK_FUNC(gethostbyname, ,
 552                    [AC_CHECK_LIB(nsl, main,
 553                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 554      unset ac_cv_func_gethostbyname
 555      LIBS=$gcj_oldLIBS
 556    ])
 557    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 558
 559    if test "$with_system_zlib" = yes; then
 560       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 561    else
 562       ZLIBSPEC=-lzgcj
 563       ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 564    fi
 565
 566    # On Solaris, and maybe other architectures, the Boehm collector
 567    # requires -ldl.
 568    if test "$GC" = boehm; then
 569       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 570    fi
 571
 572    if test -z "${with_multisubdir}"; then
 573       builddotdot=.
 574    else
 575 changequote(<<,>>)
 576       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 577 changequote([,])
 578    fi
 579    if test -x "${builddotdot}/../../gcc/gcj"; then
 580       dir="`cd ${builddotdot}/../../gcc && pwd`"
 581       GCJ="$dir/gcj -B`pwd`/ -B$dir/"
 582    else
 583       CANADIAN=yes
 584       NULL_TARGET=yes
 585       GCJ="gcj -B`pwd`/"
 586    fi
 587 fi
 588
 589 # Create it, so that compile/link tests don't fail
 590 test -f libgcj.spec || touch libgcj.spec
 591
 592 # We must search the source tree for java.lang, since we still don't
 593 # have libgcj.jar nor java/lang/*.class
 594 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
 595 CPPFLAGS="$CPPFLAGS -I`pwd` -I`cd $srcdir && pwd`"
 596
 597 # Since some classes depend on this one, we need its source available
 598 # before we can do any GCJ compilation test :-(
 599 if test ! -f gnu/classpath/Configuration.java; then
 600   test -d gnu || mkdir gnu
 601   test -d gnu/classpath || mkdir gnu/classpath
 602   sed 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
 603         < $srcdir/gnu/classpath/Configuration.java.in \
 604         > gnu/classpath/Configuration.java
 605   # We do not want to redirect the output of the grep below to /dev/null,
 606   # but we add /dev/null to the input list so that grep will print the
 607   # filename of Configuration.java in case it finds any matches.
 608   if grep @ gnu/classpath/Configuration.java /dev/null; then
 609     AC_MSG_ERROR([configure.in is missing the substitutions above])
 610   fi
 611 fi
 612
 613 LT_AC_PROG_GCJ
 614
 615 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
 616
 617 dnl FIXME: cross compilation
 618 AC_CHECK_SIZEOF(void *)
 619
 620 ZLIBS=
 621 ZDEPS=
 622 ZINCS=
 623 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 624    # We include the path to the zlib build directory.
 625    # See Makefile.am to understand why.
 626    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 627    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 628    ZINCS='-I$(top_srcdir)/../zlib'
 629 else
 630    ZLIBS="$ZLIBSPEC"
 631 fi
 632 AC_SUBST(ZLIBS)
 633 AC_SUBST(ZDEPS)
 634 AC_SUBST(ZINCS)
 635 AC_SUBST(DIVIDESPEC)
 636 AC_SUBST(EXCEPTIONSPEC)
 637
 638 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 639 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 640 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 641 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 642 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 643 AC_SUBST(GCC_UNWIND_INCLUDE)
 644
 645 # Determine gcj version number.
 646 changequote(<<,>>)
 647 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 648 changequote([,])
 649 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 650 AC_SUBST(GCJVERSION)
 651
 652 AC_SUBST(AM_RUNTESTFLAGS)
 653
 654 dnl Work around a g++ bug.  Reported to gcc-bugs@gcc.gnu.org on Jan 22, 2000.
 655 AC_MSG_CHECKING([for g++ -ffloat-store bug])
 656 save_CFLAGS="$CFLAGS"
 657 CFLAGS="-x c++ -O2 -ffloat-store"
 658 AC_TRY_COMPILE([#include <math.h>], ,
 659   [AC_MSG_RESULT(no)],
 660   [AC_DEFINE(__NO_MATH_INLINES)
 661    AC_MSG_RESULT(yes)])
 662 CFLAGS="$save_CFLAGS"
 663
 664 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 665 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 666 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 667 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h langinfo.h locale.h)
 668 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 669 dnl for now.  If you change this, you also must update natFile.cc.
 670 AC_CHECK_HEADERS(dirent.h)
 671
 672 AC_CHECK_TYPE([ssize_t], [int])
 673
 674 AC_MSG_CHECKING([for in_addr_t])
 675 AC_TRY_COMPILE([#include <sys/types.h>
 676 #if STDC_HEADERS
 677 #include <stdlib.h>
 678 #include <stddef.h>
 679 #endif
 680 #if HAVE_NETINET_IN_H
 681 #include <netinet/in.h>
 682 #endif], [in_addr_t foo;],
 683   [AC_DEFINE([HAVE_IN_ADDR_T])
 684    AC_MSG_RESULT(yes)],
 685   [AC_MSG_RESULT(no)])
 686
 687 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 688 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 689   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 690    AC_MSG_RESULT(yes)],
 691   [AC_MSG_RESULT(no)])
 692
 693 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 694 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 695   [AC_DEFINE(HAVE_INET6)
 696    AC_MSG_RESULT(yes)],
 697   [AC_MSG_RESULT(no)])
 698
 699 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 700 AC_TRY_COMPILE([#include <sys/types.h>
 701 #include <sys/socket.h>], [socklen_t x = 5;],
 702   [AC_DEFINE(HAVE_SOCKLEN_T)
 703    AC_MSG_RESULT(yes)],
 704   [AC_MSG_RESULT(no)])
 705
 706 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 707 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 708   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 709    AC_MSG_RESULT(yes)],
 710   [AC_MSG_RESULT(no)
 711    AC_MSG_CHECKING([for global timezone variable])
 712    dnl FIXME: we don't want a link check here because that won't work
 713    dnl when cross-compiling.  So instead we make an assumption that
 714    dnl the header file will mention timezone if it exists.
 715    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 716      [AC_DEFINE(HAVE_TIMEZONE)
 717       AC_MSG_RESULT(yes)],
 718      [AC_MSG_RESULT(no)])])
 719
 720 AC_FUNC_ALLOCA
 721
 722 AC_CHECK_PROGS(PERL, perl, false)
 723
 724 SYSDEP_SOURCES=
 725
 726 case "${host}" in
 727  i?86-*-linux*)
 728     SIGNAL_HANDLER=include/i386-signal.h
 729     ;;
 730  sparc-sun-solaris*)
 731     SIGNAL_HANDLER=include/sparc-signal.h
 732     ;;
 733 # ia64-*)
 734 #    SYSDEP_SOURCES=sysdep/ia64.c
 735 #    test -d sysdep || mkdir sysdep
 736 #    ;;
 737  *)
 738     SIGNAL_HANDLER=include/default-signal.h
 739     ;;
 740 esac
 741
 742 # If we're using sjlj exceptions, forget what we just learned.
 743 if test "$libgcj_sjlj" = yes; then
 744    SIGNAL_HANDLER=include/default-signal.h
 745 fi
 746
 747 AC_SUBST(SYSDEP_SOURCES)
 748
 749 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 750
 751 if test "${multilib}" = "yes"; then
 752   multilib_arg="--enable-multilib"
 753 else
 754   multilib_arg=
 755 fi
 756
 757 AC_PATH_XTRA
 758
 759 dnl Determine which AWT peer libraries to build
 760 AC_ARG_ENABLE(java-awt,
 761 [  --enable-java-awt       list of AWT peer implementations to be built])
 762
 763 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 764 use_xlib_awt=""
 765 use_gtk_awt=""
 766
 767 for peer in $peerlibs ; do
 768   case $peer in
 769     xlib)
 770       if [test "$no_x" = yes]; then
 771         echo "*** xlib peers requested but no X library available" 1>&2
 772         exit 1
 773       else
 774         use_xlib_awt="yes"
 775       fi
 776       ;;
 777     gtk)
 778       # Nothing, yet...
 779       ;;
 780     *)
 781       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 782       exit 1
 783   esac
 784 done
 785
 786 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 787 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 788
 789
 790 here=`pwd`
 791 AC_SUBST(here)
 792
 793 # We get this from the environment.
 794 AC_SUBST(GCJFLAGS)
 795
 796 AC_OUTPUT(Makefile libgcj.spec libgcj-test.spec gnu/classpath/Configuration.java gcj/Makefile include/Makefile testsuite/Makefile,
 797 [if test -n "$CONFIG_FILES"; then
 798   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 799 fi
 800
 801 # Make subdirectories and `.d' files.  Look in both srcdir and
 802 # builddir for the .java files.
 803 h=`pwd`
 804 : > deps.mk
 805 ( (cd $srcdir && find . -name '*.java' -print) ;
 806   find . -name '*.java' -print) | \
 807    fgrep -v testsuite | \
 808    sed -e 's/\.java/.d/' | \
 809    while read f; do
 810       echo "include $f" >> deps.mk
 811       test -f $f || {
 812 changequote(<<,>>)
 813          d=`echo $f | sed -e 's,/[^/]*$,,'`
 814 changequote([,])
 815          $srcdir/../mkinstalldirs $d
 816          echo > $f
 817       }
 818    done
 819 ],
 820 srcdir=${srcdir}
 821 host=${host}
 822 target=${target}
 823 with_multisubdir=${with_multisubdir}
 824 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 825 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 826 libgcj_basedir=${libgcj_basedir}
 827 CC="${CC}"
 828 CXX="${CXX}"
 829 )