libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8
   9 dnl We use these options to decide which functions to include.
  10 AC_ARG_WITH(target-subdir,
  11 [  --with-target-subdir=SUBDIR
  12                            configuring in a subdirectory])
  13 AC_ARG_WITH(cross-host,
  14 [  --with-cross-host=HOST  configuring with a cross compiler])
  15
  16 LIBGCJ_CONFIGURE(.)
  17
  18 AM_CONFIG_HEADER(include/config.h)
  19
  20 AM_PROG_LIBTOOL
  21
  22 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  23    COMPPATH=.
  24 else
  25    COMPPATH=..
  26 fi
  27 AC_SUBST(COMPPATH)
  28
  29 dnl The -no-testsuite modules omit the test subdir.
  30 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  31
  32 dnl See whether the user prefers size or speed for Character.
  33 dnl The default is size.
  34 AC_ARG_ENABLE(fast-character,
  35 [  --enable-fast-character prefer speed over size for Character],
  36 # Nothing
  37 , AC_DEFINE(COMPACT_CHARACTER))
  38
  39 dnl Should the runtime set system properties by examining the
  40 dnl environment variable GCJ_PROPERTIES?
  41 AC_ARG_ENABLE(getenv-properties,
  42 [  --disable-getenv-properties
  43                           don't set system properties from GCJ_PROPERTIES])
  44
  45 dnl Whether GCJ_PROPERTIES is used depends on the target.
  46 if test -n "$enable_getenv_properties"; then
  47    enable_getenv_properties=${enable_getenv_properties_default-yes}
  48 fi
  49 if test "$enable_getenv_properties" = no; then
  50    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  51 fi
  52
  53 dnl See if the user has requested runtime debugging.
  54 AC_ARG_ENABLE(libgcj-debug,
  55 [  --enable-libgcj-debug   enable runtime debugging code],
  56   if test "$enable_libgcj_debug" = yes; then
  57      AC_DEFINE(DEBUG)
  58   fi)
  59
  60 dnl See if the user has the interpreter included.
  61 AC_ARG_ENABLE(interpreter,
  62 [  --enable-interpreter    enable interpreter],
  63   if test "$enable_interpreter" = yes; then
  64      AC_DEFINE(INTERPRETER)
  65   fi)
  66
  67 EXCEPTIONSPEC=
  68 dnl See if we should use setjmp/longjmp exceptions
  69 AC_ARG_ENABLE(sjlj-exceptions,
  70 [  --enable-sjlj-exceptions    use setjmp/longjmp exceptions],
  71   if test "$enable_sjlj_exceptions" = yes; then
  72      # This can be set in configure.host.
  73      libgcj_sjlj=yes
  74   fi)
  75
  76 if test "$libgcj_sjlj" = yes; then
  77    EXCEPTIONSPEC="-fsjlj-exceptions"
  78    AC_DEFINE(SJLJ_EXCEPTIONS)
  79 fi
  80
  81 FORCELIBGCCSPEC=
  82 dnl Work around libgcc design flaw.
  83 if test "$ac_cv_prog_gnu_ld" = yes; then
  84    FORCELIBGCCSPEC="-u __rethrow -lgcc"
  85 fi
  86
  87 AC_MSG_CHECKING([for data_start])
  88 LIBDATASTARTSPEC=
  89 NEEDS_DATA_START=
  90 AC_TRY_LINK([extern int data_start;], [return ((int) &data_start);],
  91   [AC_MSG_RESULT(found it)],
  92   [LIBDATASTARTSPEC="-lgcjdata"
  93    NEEDS_DATA_START=yes
  94    AC_MSG_RESULT(missing)])
  95 AC_SUBST(LIBDATASTARTSPEC)
  96
  97 dnl See if the user wants to disable java.net.  This is the mildly
  98 dnl ugly way that we admit that target-side configuration sucks.
  99 AC_ARG_ENABLE(java-net,
 100 [  --disable-java-net      disable java.net])
 101
 102 dnl Whether java.net is built by default can depend on the target.
 103 if test -n "$enable_java_net"; then
 104    enable_java_net=${enable_java_net_default-yes}
 105 fi
 106 if test "$enable_java_net" = no; then
 107    AC_DEFINE(DISABLE_JAVA_NET)
 108 fi
 109
 110 dnl If the target is an eCos system, use the appropriate eCos
 111 dnl I/O routines.
 112 dnl FIXME: this should not be a local option but a global target
 113 dnl system; at present there is no eCos target.
 114 TARGET_ECOS="no"
 115 AC_ARG_WITH(ecos,
 116 [  --with-ecos             enable runtime eCos target support],
 117 TARGET_ECOS="$with_ecos"
 118 )
 119
 120 case "$TARGET_ECOS" in
 121    no)
 122       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
 123       PROCESS=${PROCESS-Posix}
 124       ;;
 125    *)
 126       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
 127       PROCESS=Ecos
 128       AC_DEFINE(ECOS)
 129       ;;
 130 esac
 131
 132 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 133 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 134 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 135 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 136
 137
 138 dnl These may not be defined in a non-ANS conformant embedded system.
 139 dnl FIXME: Should these case a runtime exception in that case?
 140 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 141 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 142
 143 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 144 dnl to create the link will fail.
 145 test -d java || mkdir java
 146 test -d java/io || mkdir java/io
 147 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 148
 149 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 150 test -d java/lang || mkdir java/lang
 151 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 152 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 153
 154 SYSTEMSPEC=
 155 AC_SUBST(SYSTEMSPEC)
 156
 157 AC_ARG_WITH(system-zlib,
 158 [  --with-system-zlib      use installed libz])
 159 ZLIBSPEC=
 160 AC_SUBST(ZLIBSPEC)
 161
 162 dnl FIXME: this should be _libs on some hosts.
 163 libsubdir=.libs
 164
 165 dnl Allow the GC to be disabled.  Can be useful when debugging.
 166 AC_MSG_CHECKING([for garbage collector to use])
 167 AC_ARG_ENABLE(java-gc,
 168 changequote(<<,>>)dnl
 169 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 170 changequote([,])
 171   GC=$enableval,
 172   GC=boehm)
 173 GCLIBS=
 174 GCINCS=
 175 GCDEPS=
 176 GCOBJS=
 177 GCSPEC=
 178 case "$GC" in
 179  boehm)
 180     AC_MSG_RESULT(boehm)
 181     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 182     # We include the path to the boehm-gc build directory.
 183     # See Makefile.am to understand why.
 184     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 185     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
 186     GCSPEC='-lgcjgc'
 187     dnl We also want to pick up some cpp flags required when including
 188     dnl boehm-config.h.  Yuck.
 189     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 190     GCOBJS=boehm.lo
 191     GCHDR=boehm-gc.h
 192     dnl The POSIX thread support needs to know this.
 193     AC_DEFINE(HAVE_BOEHM_GC)
 194     ;;
 195  no)
 196     AC_MSG_RESULT(none)
 197     GCOBJS=nogc.lo
 198     GCHDR=no-gc.h
 199     ;;
 200  *)
 201     AC_MSG_ERROR(unrecognized collector \"$GC\")
 202     ;;
 203 esac
 204 AC_SUBST(GCLIBS)
 205 AC_SUBST(GCINCS)
 206 AC_SUBST(GCDEPS)
 207 AC_SUBST(GCOBJS)
 208 AC_SUBST(GCSPEC)
 209 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 210
 211
 212 dnl Note that this code is kept in sync with similar code in gcc/configure.in.
 213 dnl In particular both packages must make the same decision about which
 214 dnl thread package to use.
 215 AC_MSG_CHECKING([for threads package to use])
 216 AC_ARG_ENABLE(threads, [  --enable-threads=TYPE   choose threading package],
 217   THREADS=$enableval,
 218   dnl FIXME: figure out native threads to use here.
 219   THREADS=no)
 220
 221 if test "$THREADS" = yes; then
 222    case "$host" in
 223     *-*-vxworks*)
 224        THREADS=vxworks
 225        ;;
 226     *-*-linux*)
 227        # FIXME: this isn't correct in all cases.
 228        THREADS=posix
 229        ;;
 230     *-*-win*)
 231        THREADS=win32
 232        ;;
 233     *-*-irix*)
 234        # FIXME: for now, choose POSIX, because we implement that.
 235        # Later, choose irix threads.
 236        THREADS=posix
 237        ;;
 238     *-*-solaris*)
 239        # FIXME: for now, choose POSIX, because we implement that.
 240        # Later, choose solaris threads.
 241        THREADS=posix
 242        ;;
 243     *)
 244        # For now.
 245        THREADS=none
 246        ;;
 247    esac
 248 fi
 249
 250 case "$THREADS" in
 251  no | none | single)
 252     THREADS=none
 253     ;;
 254  posix | pthreads)
 255     THREADS=posix
 256     case "$host" in
 257      *-*-linux*)
 258         AC_DEFINE(LINUX_THREADS)
 259         ;;
 260     esac
 261     ;;
 262  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 263     AC_MSG_ERROR(thread package $THREADS not yet supported)
 264     ;;
 265  *)
 266     AC_MSG_ERROR($THREADS is an unknown thread package)
 267     ;;
 268 esac
 269 AC_MSG_RESULT($THREADS)
 270
 271 THREADLIBS=
 272 THREADINCS=
 273 THREADDEPS=
 274 THREADOBJS=
 275 THREADH=
 276 THREADSPEC=
 277 case "$THREADS" in
 278  posix)
 279     THREADLIBS=-lpthread
 280     THREADSPEC=-lpthread
 281     THREADOBJS=posix-threads.lo
 282     THREADH=posix-threads.h
 283     # MIT pthreads doesn't seem to have the mutexattr functions.
 284     # But for now we don't check for it.  We just assume you aren't
 285     # using MIT pthreads.
 286     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 287     ;;
 288
 289  none)
 290     THREADOBJS=no-threads.lo
 291     THREADH=no-threads.h
 292     ;;
 293 esac
 294 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 295 AC_SUBST(THREADLIBS)
 296 AC_SUBST(THREADINCS)
 297 AC_SUBST(THREADDEPS)
 298 AC_SUBST(THREADOBJS)
 299 AC_SUBST(THREADSPEC)
 300
 301 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 302
 303 CANADIAN=no
 304 NULL_TARGET=no
 305 NATIVE=yes
 306
 307 # Find eh-common.h and support headers.  If we're in the tree with
 308 # gcc, then look there.  Otherwise look in compat-include.  If all else
 309 # fails, just hope the user has set things up somehow.
 310 if test -r $srcdir/../gcc/eh-common.h; then
 311    EH_COMMON_INCLUDE='-I$(top_srcdir)/../gcc -I$(top_srcdir)/../include'
 312 else
 313    if test -d $srcdir/../compat-include; then
 314       EH_COMMON_INCLUDE='-I$(top_srcdir)/../compat-include'
 315    else
 316       EH_COMMON_INCLUDE=
 317    fi
 318 fi
 319
 320 if test -n "${with_cross_host}"; then
 321    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 322    # may not work correctly, because the compiler may not be able to
 323    # link executables.
 324
 325    # We assume newlib.  This lets us hard-code the functions we know
 326    # we'll have.
 327    AC_DEFINE(HAVE_MEMMOVE)
 328    AC_DEFINE(HAVE_MEMCPY)
 329    AC_DEFINE(HAVE_STRERROR)
 330    AC_DEFINE(HAVE_GMTIME_R)
 331    AC_DEFINE(HAVE_LOCALTIME_R)
 332    dnl This is only for POSIX threads.
 333    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 334    dnl We also assume we are using gcc, which provides alloca.
 335    AC_DEFINE(HAVE_ALLOCA)
 336
 337    dnl Assume we do not have getuid and friends.
 338    AC_DEFINE(NO_GETUID)
 339
 340    ZLIBSPEC=-lzgcj
 341
 342    # If Canadian cross, then don't pick up tools from the build
 343    # directory.
 344    if test "$build" != "$with_cross_host"; then
 345       CANADIAN=yes
 346       EH_COMMON_INCLUDE=
 347       GCJ="${target_alias}-gcj"
 348    else
 349       GCJ=
 350    fi
 351    NATIVE=no
 352 else
 353    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 354    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 355    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath)
 356    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 357    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 358
 359    AC_CHECK_FUNCS(gethostbyname_r, [
 360      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 361      # There are two different kinds of gethostbyname_r.
 362      # We look for the one that returns `int'.
 363      # Hopefully this check is robust enough.
 364      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 365        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 366
 367      case " $GCINCS " in
 368      *" -D_REENTRANT "*) ;;
 369      *)
 370         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 371         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 372         [libjava_cv_gethostbyname_r_needs_reentrant],
 373         [ AC_LANG_SAVE
 374           AC_LANG_CPLUSPLUS
 375           AC_TRY_COMPILE([#include <netdb.h>],
 376             [gethostbyname_r("", 0, 0);],
 377             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 378                 CPPFLAGS_SAVE="$CPPFLAGS"
 379                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 380                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 381                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 382                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 383                 CPPFLAGS="$CPPFLAGS_SAVE"
 384           ])
 385           AC_LANG_RESTORE
 386         ])
 387         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 388           AC_DEFINE(GETHOSTBYNAME_R_NEEDS_REENTRANT, 1, [Define if gethostbyname_r is only declared if _REENTRANT is defined])
 389         fi
 390      ;;
 391      esac
 392
 393      AC_CACHE_CHECK([for struct hostent_data],
 394         [libjava_cv_struct_hostent_data], [dnl
 395         AC_TRY_COMPILE([
 396 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 397 # define _REENTRANT 1
 398 #endif
 399 #include <netdb.h>], [struct hostent_data data;],
 400           [libjava_cv_struct_hostent_data=yes],
 401           [libjava_cv_struct_hostent_data=no])])
 402      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 403        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 404          [Define if struct hostent_data is defined in netdb.h])
 405      fi
 406    ])
 407
 408    AC_CHECK_FUNCS(gethostbyaddr_r, [
 409      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 410      # There are two different kinds of gethostbyaddr_r.
 411      # We look for the one that returns `int'.
 412      # Hopefully this check is robust enough.
 413      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 414        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 415
 416    AC_CHECK_FUNCS(gethostname, [
 417      AC_DEFINE(HAVE_GETHOSTNAME)
 418      AC_EGREP_HEADER(gethostname, unistd.h, [
 419        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 420
 421    # Look for these functions in the thread library, but only bother
 422    # if using POSIX threads.
 423    if test "$THREADS" = posix; then
 424       save_LIBS="$LIBS"
 425       LIBS="$LIBS $THREADLIBS"
 426       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 427       # E.g., Solaris.
 428       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 429
 430       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 431       # Solaris 7 the name librt is preferred.
 432       AC_CHECK_FUNCS(sched_yield, , [
 433         AC_CHECK_LIB(rt, sched_yield, [
 434           AC_DEFINE(HAVE_SCHED_YIELD)
 435           THREADLIBS="$THREADLIBS -lrt"
 436           THREADSPEC="$THREADSPEC -lrt"], [
 437           AC_CHECK_LIB(posix4, sched_yield, [
 438             AC_DEFINE(HAVE_SCHED_YIELD)
 439             THREADLIBS="$THREADLIBS -lposix4"
 440             THREADSPEC="$THREADSPEC -lposix4"])])])
 441       LIBS="$save_LIBS"
 442
 443       # We can save a little space at runtime if the mutex has m_count
 444       # or __m_count.  This is a nice hack for Linux.
 445       AC_TRY_COMPILE([#include <pthread.h>], [
 446           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 447         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 448         AC_TRY_COMPILE([#include <pthread.h>], [
 449             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 450           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 451    fi
 452
 453    # We require a way to get the time.
 454    time_found=no
 455    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 456    if test "$time_found" = no; then
 457       AC_MSG_ERROR([no function found to get the time])
 458    fi
 459
 460    AC_CHECK_FUNCS(memmove)
 461
 462    # We require memcpy.
 463    memcpy_found=no
 464    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 465    if test "$memcpy_found" = no; then
 466       AC_MSG_ERROR([memcpy is required])
 467    fi
 468
 469    # Some library-finding code we stole from Tcl.
 470    #--------------------------------------------------------------------
 471    #    Check for the existence of the -lsocket and -lnsl libraries.
 472    #    The order here is important, so that they end up in the right
 473    #    order in the command line generated by make.  Here are some
 474    #    special considerations:
 475    #    1. Use "connect" and "accept" to check for -lsocket, and
 476    #       "gethostbyname" to check for -lnsl.
 477    #    2. Use each function name only once:  can't redo a check because
 478    #       autoconf caches the results of the last check and won't redo it.
 479    #    3. Use -lnsl and -lsocket only if they supply procedures that
 480    #       aren't already present in the normal libraries.  This is because
 481    #       IRIX 5.2 has libraries, but they aren't needed and they're
 482    #       bogus:  they goof up name resolution if used.
 483    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 484    #       To get around this problem, check for both libraries together
 485    #       if -lsocket doesn't work by itself.
 486    #--------------------------------------------------------------------
 487
 488    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 489     [gcj_cv_lib_sockets=
 490      gcj_checkBoth=0
 491      unset ac_cv_func_connect
 492      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 493      if test "$gcj_checkSocket" = 1; then
 494          unset ac_cv_func_connect
 495          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 496                       gcj_checkBoth=1)
 497      fi
 498      if test "$gcj_checkBoth" = 1; then
 499          gcj_oldLibs=$LIBS
 500          LIBS="$LIBS -lsocket -lnsl"
 501          unset ac_cv_func_accept
 502          AC_CHECK_FUNC(accept,
 503                        [gcj_checkNsl=0
 504                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 505          unset ac_cv_func_accept
 506          LIBS=$gcj_oldLibs
 507      fi
 508      unset ac_cv_func_gethostbyname
 509      gcj_oldLibs=$LIBS
 510      LIBS="$LIBS $gcj_cv_lib_sockets"
 511      AC_CHECK_FUNC(gethostbyname, ,
 512                    [AC_CHECK_LIB(nsl, main,
 513                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 514      unset ac_cv_func_gethostbyname
 515      LIBS=$gcj_oldLIBS
 516    ])
 517    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 518
 519    if test "$with_system_zlib" = yes; then
 520       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 521    else
 522       ZLIBSPEC=-lzgcj
 523    fi
 524
 525    # On Solaris, and maybe other architectures, the Boehm collector
 526    # requires -ldl.
 527    if test "$GC" = boehm; then
 528       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 529    fi
 530
 531    if test -d "$libgcj_basedir/../gcc/java"; then
 532       GCJ=
 533    else
 534       CANADIAN=yes
 535       NULL_TARGET=yes
 536       GCJ=gcj
 537    fi
 538 fi
 539
 540 ZLIBS=
 541 ZDEPS=
 542 ZINCS=
 543 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 544    # We include the path to the zlib build directory.
 545    # See Makefile.am to understand why.
 546    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 547    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 548    ZINCS='-I$(top_srcdir)/../zlib'
 549 else
 550    ZLIBS="$ZLIBSPEC"
 551 fi
 552 AC_SUBST(ZLIBS)
 553 AC_SUBST(ZDEPS)
 554 AC_SUBST(ZINCS)
 555 AC_SUBST(DIVIDESPEC)
 556 AC_SUBST(EXCEPTIONSPEC)
 557 AC_SUBST(FORCELIBGCCSPEC)
 558
 559 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 560 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 561 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 562 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 563 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 564 AC_SUBST(EH_COMMON_INCLUDE)
 565
 566 # Determine gcj version number.
 567 if test "$GCJ" = ""; then
 568    if test -z "${with_multisubdir}"; then
 569       builddotdot=.
 570    else
 571 changequote(<<,>>)
 572       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 573 changequote([,])
 574    fi
 575    dir="`cd ${builddotdot}/../../gcc && pwd`"
 576    GCJ="$dir/gcj -B$dir/"
 577 fi
 578 changequote(<<,>>)
 579 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 580 changequote([,])
 581 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 582
 583 # See if gcj supports -fuse-divide-subroutine.  gcc 2.95 does not, and
 584 # we want to continue to support that version.
 585 AC_MSG_CHECKING([whether gcj supports -fuse-divide-subroutine])
 586 cat > conftest.java << 'END'
 587 public class conftest { }
 588 END
 589 use_fuse=yes
 590 $GCJ -classpath $srcdir -fuse-divide-subroutine -fsyntax-only \
 591    conftest.java > /dev/null 2>&1 \
 592    || use_fuse=no
 593 rm -f conftest.java
 594 if test "$use_fuse" = no; then
 595    DIVIDESPEC=
 596 fi
 597 AC_MSG_RESULT($use_fuse)
 598
 599 AC_SUBST(AM_RUNTESTFLAGS)
 600
 601 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 602 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 603 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 604 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h)
 605 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 606 dnl for now.  If you change this, you also must update natFile.cc.
 607 AC_CHECK_HEADERS(dirent.h)
 608
 609 AC_CHECK_TYPE([ssize_t], [int])
 610
 611 AC_MSG_CHECKING([for in_addr_t])
 612 AC_TRY_COMPILE([#include <sys/types.h>
 613 #if STDC_HEADERS
 614 #include <stdlib.h>
 615 #include <stddef.h>
 616 #endif
 617 #if HAVE_NETINET_IN_H
 618 #include <netinet/in.h>
 619 #endif], [in_addr_t foo;],
 620   [AC_DEFINE([HAVE_IN_ADDR_T])
 621    AC_MSG_RESULT(yes)],
 622   [AC_MSG_RESULT(no)])
 623
 624 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 625 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 626   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 627    AC_MSG_RESULT(yes)],
 628   [AC_MSG_RESULT(no)])
 629
 630 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 631 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 632   [AC_DEFINE(HAVE_INET6)
 633    AC_MSG_RESULT(yes)],
 634   [AC_MSG_RESULT(no)])
 635
 636 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 637 AC_TRY_COMPILE([#include <sys/socket.h>], [socklen_t x = 5;],
 638   [AC_DEFINE(HAVE_SOCKLEN_T)
 639    AC_MSG_RESULT(yes)],
 640   [AC_MSG_RESULT(no)])
 641
 642 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 643 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 644   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 645    AC_MSG_RESULT(yes)],
 646   [AC_MSG_RESULT(no)
 647    AC_MSG_CHECKING([for global timezone variable])
 648    dnl FIXME: we don't want a link check here because that won't work
 649    dnl when cross-compiling.  So instead we make an assumption that
 650    dnl the header file will mention timezone if it exists.
 651    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 652      [AC_DEFINE(HAVE_TIMEZONE)
 653       AC_MSG_RESULT(yes)],
 654      [AC_MSG_RESULT(no)])])
 655
 656 AC_FUNC_ALLOCA
 657
 658 AC_CHECK_PROGS(PERL, perl, false)
 659
 660 if test "$enable_sjlj_exceptions" = yes; then
 661    SIGNAL_HANDLER=include/default-signal.h
 662 else
 663    case "${host}" in
 664     i?86-*-linux*)
 665        SIGNAL_HANDLER=include/i386-signal.h
 666        ;;
 667     sparc-sun-solaris*)
 668        SIGNAL_HANDLER=include/sparc-signal.h
 669        ;;
 670     *)
 671        SIGNAL_HANDLER=include/default-signal.h
 672        ;;
 673    esac
 674 fi
 675
 676 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 677
 678 if test "${multilib}" = "yes"; then
 679   multilib_arg="--enable-multilib"
 680 else
 681   multilib_arg=
 682 fi
 683
 684 here=`pwd`
 685 AC_SUBST(here)
 686
 687 AC_OUTPUT(Makefile libgcj.spec gcj/Makefile include/Makefile testsuite/Makefile,
 688 [if test -n "$CONFIG_FILES"; then
 689   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 690 fi],
 691 srcdir=${srcdir}
 692 host=${host}
 693 target=${target}
 694 with_multisubdir=${with_multisubdir}
 695 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 696 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 697 libgcj_basedir=${libgcj_basedir}
 698 CC="${CC}"
 699 CXX="${CXX}"
 700 )