libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8
   9 dnl We use these options to decide which functions to include.
  10 AC_ARG_WITH(target-subdir,
  11 [  --with-target-subdir=SUBDIR
  12                           configuring in a subdirectory])
  13 AC_ARG_WITH(cross-host,
  14 [  --with-cross-host=HOST  configuring with a cross compiler])
  15
  16 LIBGCJ_CONFIGURE(.)
  17
  18 AM_CONFIG_HEADER(include/config.h)
  19
  20 AM_PROG_LIBTOOL
  21
  22 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  23    COMPPATH=.
  24 else
  25    COMPPATH=..
  26 fi
  27 AC_SUBST(COMPPATH)
  28
  29 dnl The -no-testsuite modules omit the test subdir.
  30 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  31
  32 dnl See whether the user prefers size or speed for Character.
  33 dnl The default is size.
  34 AC_ARG_ENABLE(fast-character,
  35 [  --enable-fast-character prefer speed over size for Character],
  36 # Nothing
  37 , AC_DEFINE(COMPACT_CHARACTER))
  38
  39 dnl See if the user has requested runtime debugging.
  40 AC_ARG_ENABLE(libgcj-debug,
  41 [  --enable-libgcj-debug   enable runtime debugging code],
  42   if test "$enable_libgcj_debug" = yes; then
  43      AC_DEFINE(DEBUG)
  44   fi)
  45
  46 dnl See if the user has the enterpreter included.
  47 AC_ARG_ENABLE(interpreter,
  48 [  --enable-interpreter    enable interpreter],
  49   if test "$enable_interpreter" = yes; then
  50      AC_DEFINE(INTERPRETER)
  51   fi)
  52
  53 dnl See if the user wants to disable java.net.  This is the mildly
  54 dnl ugly way that we admit that target-side configuration sucks.
  55 AC_ARG_ENABLE(java-net,
  56 [  --disable-java-net      disable java.net])
  57
  58 dnl Whether java.net is built by default can depend on the target.
  59 if test -n "$enable_java_net"; then
  60    enable_java_net=${enable_java_net_default-yes}
  61 fi
  62 if test "$enable_java_net" != yes; then
  63    AC_DEFINE(DISABLE_JAVA_NET)
  64 fi
  65
  66 dnl If the target is an eCos system, use the appropriate eCos
  67 dnl I/O routines.
  68 dnl FIXME: this should not be a local option but a global target
  69 dnl system; at present there is no eCos target.
  70 TARGET_ECOS="no"
  71 AC_ARG_WITH(ecos,
  72 [  --with-ecos             enable runtime eCos target support],
  73 TARGET_ECOS="$with_ecos"
  74 )
  75
  76 case "$TARGET_ECOS" in
  77    no)
  78       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
  79       PROCESS=${PROCESS-Posix}
  80       ;;
  81    *)
  82       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
  83       PROCESS=Ecos
  84       AC_DEFINE(ECOS)
  85       ;;
  86 esac
  87
  88 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
  89 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
  90 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
  91 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
  92
  93
  94 dnl These may not be defined in a non-ANS conformant embedded system.
  95 dnl FIXME: Should these case a runtime exception in that case?
  96 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
  97 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
  98
  99 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 100 dnl to create the link will fail.
 101 test -d java || mkdir java
 102 test -d java/io || mkdir java/io
 103 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 104
 105 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 106 test -d java/lang || mkdir java/lang
 107 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 108 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 109
 110 SYSTEMSPEC=
 111 AC_SUBST(SYSTEMSPEC)
 112
 113 AC_ARG_WITH(system-zlib,
 114 [  --with-system-zlib      use installed libz])
 115 ZLIBSPEC=
 116 AC_SUBST(ZLIBSPEC)
 117
 118 dnl FIXME: this should be _libs on some hosts.
 119 libsubdir=.libs
 120
 121 dnl Allow the GC to be disabled.  Can be useful when debugging.
 122 AC_MSG_CHECKING([for garbage collector to use])
 123 AC_ARG_ENABLE(java-gc,
 124 changequote(<<,>>)dnl
 125 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 126 changequote([,])
 127   GC=$enableval,
 128   GC=boehm)
 129 GCLIBS=
 130 GCINCS=
 131 GCDEPS=
 132 GCOBJS=
 133 GCSPEC=
 134 case "$GC" in
 135  boehm)
 136     AC_MSG_RESULT(boehm)
 137     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 138     # We include the path to the boehm-gc build directory.
 139     # See Makefile.am to understand why.
 140     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 141     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
 142     GCSPEC='-lgcjgc'
 143     dnl We also want to pick up some cpp flags required when including
 144     dnl boehm-config.h.  Yuck.
 145     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 146     GCOBJS=boehm.lo
 147     GCHDR=boehm-gc.h
 148     dnl The POSIX thread support needs to know this.
 149     AC_DEFINE(HAVE_BOEHM_GC)
 150     ;;
 151  no)
 152     AC_MSG_RESULT(none)
 153     GCOBJS=nogc.lo
 154     GCHDR=no-gc.h
 155     ;;
 156  *)
 157     AC_MSG_ERROR(unrecognized collector \"$GC\")
 158     ;;
 159 esac
 160 AC_SUBST(GCLIBS)
 161 AC_SUBST(GCINCS)
 162 AC_SUBST(GCDEPS)
 163 AC_SUBST(GCOBJS)
 164 AC_SUBST(GCSPEC)
 165 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 166
 167
 168 dnl Note that this code is kept in sync with similar code in gcc/configure.in.
 169 dnl In particular both packages must make the same decision about which
 170 dnl thread package to use.
 171 AC_MSG_CHECKING([for threads package to use])
 172 AC_ARG_ENABLE(threads, [  --enable-threads=TYPE   choose threading package],
 173   THREADS=$enableval,
 174   dnl FIXME: figure out native threads to use here.
 175   THREADS=no)
 176
 177 if test "$THREADS" = yes; then
 178    case "$host" in
 179     *-*-vxworks*)
 180        THREADS=vxworks
 181        ;;
 182     *-*-linux*)
 183        # FIXME: this isn't correct in all cases.
 184        THREADS=posix
 185        ;;
 186     *-*-win*)
 187        THREADS=win32
 188        ;;
 189     *-*-irix*)
 190        # FIXME: for now, choose POSIX, because we implement that.
 191        # Later, choose irix threads.
 192        THREADS=posix
 193        ;;
 194     *-*-solaris*)
 195        # FIXME: for now, choose POSIX, because we implement that.
 196        # Later, choose solaris threads.
 197        THREADS=posix
 198        ;;
 199     *)
 200        # For now.
 201        THREADS=none
 202        ;;
 203    esac
 204 fi
 205
 206 case "$THREADS" in
 207  no | none | single)
 208     THREADS=none
 209     ;;
 210  posix | pthreads)
 211     THREADS=posix
 212     case "$host" in
 213      *-*-linux*)
 214         AC_DEFINE(LINUX_THREADS)
 215         ;;
 216     esac
 217     ;;
 218  qt)
 219     ;;
 220  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 221     AC_MSG_ERROR(thread package $THREADS not yet supported)
 222     ;;
 223  *)
 224     AC_MSG_ERROR($THREADS is an unknown thread package)
 225     ;;
 226 esac
 227 AC_MSG_RESULT($THREADS)
 228
 229 THREADLIBS=
 230 THREADINCS=
 231 THREADDEPS=
 232 THREADOBJS=
 233 THREADH=
 234 THREADSPEC=
 235 case "$THREADS" in
 236  posix)
 237     THREADLIBS=-lpthread
 238     THREADSPEC=-lpthread
 239     THREADOBJS=posix-threads.lo
 240     THREADH=posix-threads.h
 241     # MIT pthreads doesn't seem to have the mutexattr functions.
 242     # But for now we don't check for it.  We just assume you aren't
 243     # using MIT pthreads.
 244     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 245     ;;
 246
 247  qt)
 248     THREADDEPS='$(top_builddir)/../qthreads/libgcjcoop.la'
 249     # We include the path to the qthreads build directory.
 250     # See Makefile.am to understand why.
 251     THREADLIBS="$THREADDEPS -L\$(here)/../qthreads/$libsubdir"
 252     THREADSPEC='-lgcjcoop'
 253     THREADOBJS=quick-threads.lo
 254     THREADINCS='-I$(top_srcdir)/../qthreads'
 255     THREADH=quick-threads.h
 256     ;;
 257
 258  none)
 259     THREADOBJS=no-threads.lo
 260     THREADH=no-threads.h
 261     ;;
 262 esac
 263 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 264 AC_SUBST(THREADLIBS)
 265 AC_SUBST(THREADINCS)
 266 AC_SUBST(THREADDEPS)
 267 AC_SUBST(THREADOBJS)
 268 AC_SUBST(THREADSPEC)
 269
 270 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 271
 272 CANADIAN=no
 273 NULL_TARGET=no
 274
 275 # Find eh-common.h and support headers.  If we're in the tree with
 276 # gcc, then look there.  Otherwise look in compat-include.  If all else
 277 # fails, just hope the user has set things up somehow.
 278 if test -r $srcdir/../gcc/eh-common.h; then
 279    EH_COMMON_INCLUDE='-I$(top_srcdir)/../gcc -I$(top_srcdir)/../include'
 280 else
 281    if test -d $srcdir/../compat-include; then
 282       EH_COMMON_INCLUDE='-I$(top_srcdir)/../compat-include'
 283    else
 284       EH_COMMON_INCLUDE=
 285    fi
 286 fi
 287
 288 if test -n "${with_cross_host}"; then
 289    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 290    # may not work correctly, because the compiler may not be able to
 291    # link executables.
 292
 293    # We assume newlib.  This lets us hard-code the functions we know
 294    # we'll have.
 295    AC_DEFINE(HAVE_MEMMOVE)
 296    AC_DEFINE(HAVE_MEMCPY)
 297    AC_DEFINE(HAVE_STRERROR)
 298    AC_DEFINE(HAVE_GMTIME_R)
 299    AC_DEFINE(HAVE_LOCALTIME_R)
 300    dnl This is only for POSIX threads.
 301    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 302    dnl We also assume we are using gcc, which provides alloca.
 303    AC_DEFINE(HAVE_ALLOCA)
 304
 305    ZLIBSPEC=-lzgcj
 306
 307    # If Canadian cross, then don't pick up tools from the build
 308    # directory.
 309    if test "$build" != "$with_cross_host"; then
 310       CANADIAN=yes
 311       EH_COMMON_INCLUDE=
 312       GCJ="${target_alias}/gcj"
 313    else
 314       GCJ=
 315    fi
 316 else
 317    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 318    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r)
 319    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath)
 320    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 321    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 322
 323    AC_CHECK_FUNCS(gethostbyname_r, [
 324      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 325      # There are two different kinds of gethostbyname_r.
 326      # We look for the one that returns `int'.
 327      # Hopefully this check is robust enough.
 328      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 329        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 330
 331      case " $GCINCS " in
 332      *" -D_REENTRANT "*) ;;
 333      *)
 334         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 335         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 336         [libjava_cv_gethostbyname_r_needs_reentrant],
 337         [ AC_LANG_SAVE
 338           AC_LANG_CPLUSPLUS
 339           AC_TRY_COMPILE([#include <netdb.h>],
 340             [gethostbyname_r("", 0, 0);],
 341             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 342                 CPPFLAGS_SAVE="$CPPFLAGS"
 343                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 344                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 345                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 346                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 347                 CPPFLAGS="$CPPFLAGS_SAVE"
 348           ])
 349           AC_LANG_RESTORE
 350         ])
 351         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 352           AC_DEFINE(GETHOSTBYNAME_R_NEEDS_REENTRANT, 1, [Define if gethostbyname_r is only declared if _REENTRANT is defined])
 353         fi
 354      ;;
 355      esac
 356
 357      AC_CACHE_CHECK([for struct hostent_data],
 358         [libjava_cv_struct_hostent_data], [dnl
 359         AC_TRY_COMPILE([
 360 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 361 # define _REENTRANT 1
 362 #endif
 363 #include <netdb.h>], [struct hostent_data data;],
 364           [libjava_cv_struct_hostent_data=yes],
 365           [libjava_cv_struct_hostent_data=no])])
 366      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 367        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 368          [Define if struct hostent_data is defined in netdb.h])
 369      fi
 370    ])
 371
 372    AC_CHECK_FUNCS(gethostbyaddr_r, [
 373      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 374      # There are two different kinds of gethostbyaddr_r.
 375      # We look for the one that returns `int'.
 376      # Hopefully this check is robust enough.
 377      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 378        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 379
 380    AC_CHECK_FUNCS(gethostname, [
 381      AC_DEFINE(HAVE_GETHOSTNAME)
 382      AC_EGREP_HEADER(gethostname, unistd.h, [
 383        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 384
 385    # Look for these functions in the thread library, but only bother
 386    # if using POSIX threads.
 387    if test "$THREADS" = posix; then
 388       save_LIBS="$LIBS"
 389       LIBS="$LIBS $THREADLIBS"
 390       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 391       # E.g., Solaris.
 392       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 393
 394       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 395       # Solaris 7 the name librt is preferred.
 396       AC_CHECK_FUNCS(sched_yield, , [
 397         AC_CHECK_LIB(rt, sched_yield, [
 398           AC_DEFINE(HAVE_SCHED_YIELD)
 399           THREADLIBS="$THREADLIBS -lrt"
 400           THREADSPEC="$THREADSPEC -lrt"], [
 401           AC_CHECK_LIB(posix4, sched_yield, [
 402             AC_DEFINE(HAVE_SCHED_YIELD)
 403             THREADLIBS="$THREADLIBS -lposix4"
 404             THREADSPEC="$THREADSPEC -lposix4"])])])
 405       LIBS="$save_LIBS"
 406
 407       # We can save a little space at runtime if the mutex has m_count
 408       # or __m_count.  This is a nice hack for Linux.
 409       AC_TRY_COMPILE([#include <pthread.h>], [
 410           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 411         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 412         AC_TRY_COMPILE([#include <pthread.h>], [
 413             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 414           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 415    fi
 416
 417    # We require a way to get the time.
 418    time_found=no
 419    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 420    if test "$time_found" = no; then
 421       AC_MSG_ERROR([no function found to get the time])
 422    fi
 423
 424    AC_CHECK_FUNCS(memmove)
 425
 426    # We require memcpy.
 427    memcpy_found=no
 428    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 429    if test "$memcpy_found" = no; then
 430       AC_MSG_ERROR([memcpy is required])
 431    fi
 432
 433    # Some library-finding code we stole from Tcl.
 434    #--------------------------------------------------------------------
 435    #    Check for the existence of the -lsocket and -lnsl libraries.
 436    #    The order here is important, so that they end up in the right
 437    #    order in the command line generated by make.  Here are some
 438    #    special considerations:
 439    #    1. Use "connect" and "accept" to check for -lsocket, and
 440    #       "gethostbyname" to check for -lnsl.
 441    #    2. Use each function name only once:  can't redo a check because
 442    #       autoconf caches the results of the last check and won't redo it.
 443    #    3. Use -lnsl and -lsocket only if they supply procedures that
 444    #       aren't already present in the normal libraries.  This is because
 445    #       IRIX 5.2 has libraries, but they aren't needed and they're
 446    #       bogus:  they goof up name resolution if used.
 447    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 448    #       To get around this problem, check for both libraries together
 449    #       if -lsocket doesn't work by itself.
 450    #--------------------------------------------------------------------
 451
 452    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 453     [gcj_cv_lib_sockets=
 454      gcj_checkBoth=0
 455      unset ac_cv_func_connect
 456      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 457      if test "$gcj_checkSocket" = 1; then
 458          unset ac_cv_func_connect
 459          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 460                       gcj_checkBoth=1)
 461      fi
 462      if test "$gcj_checkBoth" = 1; then
 463          gcj_oldLibs=$LIBS
 464          LIBS="$LIBS -lsocket -lnsl"
 465          unset ac_cv_func_accept
 466          AC_CHECK_FUNC(accept,
 467                        [gcj_checkNsl=0
 468                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 469          unset ac_cv_func_accept
 470          LIBS=$gcj_oldLibs
 471      fi
 472      unset ac_cv_func_gethostbyname
 473      gcj_oldLibs=$LIBS
 474      LIBS="$LIBS $gcj_cv_lib_sockets"
 475      AC_CHECK_FUNC(gethostbyname, ,
 476                    [AC_CHECK_LIB(nsl, main,
 477                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 478      unset ac_cv_func_gethostbyname
 479      LIBS=$gcj_oldLIBS
 480    ])
 481    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 482
 483    if test "$with_system_zlib" = yes; then
 484       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 485    else
 486       ZLIBSPEC=-lzgcj
 487    fi
 488
 489    # On Solaris, and maybe other architectures, the Boehm collector
 490    # requires -ldl.
 491    if test "$GC" = boehm; then
 492       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 493    fi
 494
 495    if test -d "$libgcj_basedir/../gcc/java"; then
 496       GCJ=
 497    else
 498       CANADIAN=yes
 499       NULL_TARGET=yes
 500       GCJ=gcj
 501    fi
 502 fi
 503
 504 ZLIBS=
 505 ZDEPS=
 506 ZINCS=
 507 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 508    # We include the path to the zlib build directory.
 509    # See Makefile.am to understand why.
 510    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 511    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 512    ZINCS='-I$(top_srcdir)/../zlib'
 513 else
 514    ZLIBS="$ZLIBSPEC"
 515 fi
 516 AC_SUBST(ZLIBS)
 517 AC_SUBST(ZDEPS)
 518 AC_SUBST(ZINCS)
 519 AC_SUBST(DIVIDESPEC)
 520
 521 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 522 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 523 AM_CONDITIONAL(NATIVE, test "$CANADIAN" = no || test "$NULL_TARGET" = yes)
 524 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 525 AC_SUBST(EH_COMMON_INCLUDE)
 526
 527 # Determine gcj version number.
 528 if test "$GCJ" = ""; then
 529    if test -z "${with_multisubdir}"; then
 530       builddotdot=.
 531    else
 532 changequote(<<,>>)
 533       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 534 changequote([,])
 535    fi
 536    dir="`cd ${builddotdot}/../../gcc && pwd`"
 537    GCJ="$dir/gcj -B$dir/"
 538 fi
 539 changequote(<<,>>)
 540 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 541 changequote([,])
 542 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 543
 544 # See if gcj supports -fuse-divide-subroutine.  gcc 2.95 does not, and
 545 # we want to continue to support that version.
 546 AC_MSG_CHECKING([whether gcj supports -fuse-divide-subroutine])
 547 cat > conftest.java << 'END'
 548 public class conftest { }
 549 END
 550 use_fuse=yes
 551 $GCJ -classpath $srcdir -fuse-divide-subroutine -fsyntax-only \
 552    conftest.java > /dev/null 2>&1 \
 553    || use_fuse=no
 554 rm -f conftest.java
 555 if test "$use_fuse" = no; then
 556    DIVIDESPEC=
 557 fi
 558 AC_MSG_RESULT($use_fuse)
 559
 560 AC_SUBST(AM_RUNTESTFLAGS)
 561
 562 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 563 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 564 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 565 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h)
 566 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 567 dnl for now.  If you change this, you also must update natFile.cc.
 568 AC_CHECK_HEADERS(dirent.h)
 569
 570 AC_CHECK_TYPE([ssize_t], [int])
 571
 572 AC_MSG_CHECKING([for in_addr_t])
 573 AC_TRY_COMPILE([#include <sys/types.h>
 574 #if STDC_HEADERS
 575 #include <stdlib.h>
 576 #include <stddef.h>
 577 #endif
 578 #if HAVE_NETINET_IN_H
 579 #include <netinet/in.h>
 580 #endif], [in_addr_t foo;],
 581   [AC_DEFINE([HAVE_IN_ADDR_T])
 582    AC_MSG_RESULT(yes)],
 583   [AC_MSG_RESULT(no)])
 584
 585 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 586 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 587   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 588    AC_MSG_RESULT(yes)],
 589   [AC_MSG_RESULT(no)])
 590
 591 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 592 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 593   [AC_DEFINE(HAVE_INET6)
 594    AC_MSG_RESULT(yes)],
 595   [AC_MSG_RESULT(no)])
 596
 597 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 598 AC_TRY_COMPILE([#include <sys/socket.h>], [socklen_t x = 5;],
 599   [AC_DEFINE(HAVE_SOCKLEN_T)
 600    AC_MSG_RESULT(yes)],
 601   [AC_MSG_RESULT(no)])
 602
 603 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 604 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 605   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 606    AC_MSG_RESULT(yes)],
 607   [AC_MSG_RESULT(no)
 608    AC_MSG_CHECKING([for global timezone variable])
 609    dnl FIXME: we don't want a link check here because that won't work
 610    dnl when cross-compiling.  So instead we make an assumption that
 611    dnl the header file will mention timezone if it exists.
 612    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 613      [AC_DEFINE(HAVE_TIMEZONE)
 614       AC_MSG_RESULT(yes)],
 615      [AC_MSG_RESULT(no)])])
 616
 617 AC_FUNC_ALLOCA
 618
 619 AC_CHECK_PROGS(PERL, perl, false)
 620
 621 case "${host}" in
 622   i?86-*-linux*)
 623     SIGNAL_HANDLER=include/i386-signal.h
 624         ;;
 625   sparc-sun-solaris*)
 626     SIGNAL_HANDLER=include/sparc-signal.h
 627         ;;
 628   *)
 629     SIGNAL_HANDLER=include/default-signal.h
 630         ;;
 631 esac
 632
 633 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 634
 635 if test "${multilib}" = "yes"; then
 636   multilib_arg="--enable-multilib"
 637 else
 638   multilib_arg=
 639 fi
 640
 641 here=`pwd`
 642 AC_SUBST(here)
 643
 644 AC_OUTPUT(Makefile libgcj.spec gcj/Makefile include/Makefile testsuite/Makefile,
 645 [if test -n "$CONFIG_FILES"; then
 646   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 647 fi],
 648 srcdir=${srcdir}
 649 host=${host}
 650 target=${target}
 651 with_multisubdir=${with_multisubdir}
 652 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 653 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 654 libgcj_basedir=${libgcj_basedir}
 655 CC="${CC}"
 656 CXX="${CXX}"
 657 )