libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8
   9 dnl We use these options to decide which functions to include.
  10 AC_ARG_WITH(target-subdir,
  11 [  --with-target-subdir=SUBDIR
  12                            configuring in a subdirectory])
  13 AC_ARG_WITH(cross-host,
  14 [  --with-cross-host=HOST  configuring with a cross compiler])
  15
  16 LIBGCJ_CONFIGURE(.)
  17
  18 AM_CONFIG_HEADER(include/config.h)
  19
  20 # Only use libltdl for native builds.
  21 if test -z "${with_cross_host}"; then
  22    AC_LIBLTDL_CONVENIENCE
  23    AC_LIBTOOL_DLOPEN
  24    DIRLTDL=libltdl
  25    AC_DEFINE(USE_LTDL)
  26    # Sigh.  Libtool's macro doesn't do the right thing.
  27    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  28 fi
  29 AC_SUBST(INCLTDL)
  30 AC_SUBST(LIBLTDL)
  31 AC_SUBST(DIRLTDL)
  32 AM_PROG_LIBTOOL
  33 AC_CONFIG_SUBDIRS($DIRLTDL)
  34
  35 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  36    COMPPATH=.
  37 else
  38    COMPPATH=..
  39 fi
  40 AC_SUBST(COMPPATH)
  41
  42 dnl The -no-testsuite modules omit the test subdir.
  43 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  44
  45 dnl See whether the user prefers size or speed for Character.
  46 dnl The default is size.
  47 AC_ARG_ENABLE(fast-character,
  48 [  --enable-fast-character prefer speed over size for Character],
  49 # Nothing
  50 , AC_DEFINE(COMPACT_CHARACTER))
  51
  52 dnl Should the runtime set system properties by examining the
  53 dnl environment variable GCJ_PROPERTIES?
  54 AC_ARG_ENABLE(getenv-properties,
  55 [  --disable-getenv-properties
  56                           don't set system properties from GCJ_PROPERTIES])
  57
  58 dnl Whether GCJ_PROPERTIES is used depends on the target.
  59 if test -n "$enable_getenv_properties"; then
  60    enable_getenv_properties=${enable_getenv_properties_default-yes}
  61 fi
  62 if test "$enable_getenv_properties" = no; then
  63    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  64 fi
  65
  66 dnl See if the user has requested runtime debugging.
  67 AC_ARG_ENABLE(libgcj-debug,
  68 [  --enable-libgcj-debug   enable runtime debugging code],
  69   if test "$enable_libgcj_debug" = yes; then
  70      AC_DEFINE(DEBUG)
  71   fi)
  72
  73 dnl See if the user has the interpreter included.
  74 AC_ARG_ENABLE(interpreter,
  75 [  --enable-interpreter    enable interpreter],
  76   if test "$enable_interpreter" = yes; then
  77     # This can also be set in configure.host.
  78     libgcj_interpreter=yes
  79   fi)
  80
  81 if test "$libgcj_interpreter" = yes; then
  82    AC_DEFINE(INTERPRETER)
  83 fi
  84
  85 EXCEPTIONSPEC=
  86 dnl See if we should use setjmp/longjmp exceptions
  87 AC_ARG_ENABLE(sjlj-exceptions,
  88 [  --enable-sjlj-exceptions    use setjmp/longjmp exceptions],
  89   if test "$enable_sjlj_exceptions" = yes; then
  90      # This can be set in configure.host.
  91      libgcj_sjlj=yes
  92   fi)
  93
  94 if test "$libgcj_sjlj" = yes; then
  95    EXCEPTIONSPEC="-fsjlj-exceptions"
  96    AC_DEFINE(SJLJ_EXCEPTIONS)
  97 fi
  98
  99 FORCELIBGCCSPEC=
 100 dnl Work around libgcc design flaw.
 101 if test "$ac_cv_prog_gnu_ld" = yes; then
 102    FORCELIBGCCSPEC="-u __rethrow -u __frame_state_for -lgcc"
 103 fi
 104
 105 AC_MSG_CHECKING([for data_start])
 106 LIBDATASTARTSPEC=
 107 NEEDS_DATA_START=
 108 AC_TRY_LINK([extern int data_start;], [return ((int) &data_start);],
 109   [AC_MSG_RESULT(found it)],
 110   [LIBDATASTARTSPEC="-u data_start -lgcjdata"
 111    NEEDS_DATA_START=yes
 112    AC_MSG_RESULT(missing)])
 113 AC_SUBST(LIBDATASTARTSPEC)
 114
 115 dnl See if the user wants to disable java.net.  This is the mildly
 116 dnl ugly way that we admit that target-side configuration sucks.
 117 AC_ARG_ENABLE(java-net,
 118 [  --disable-java-net      disable java.net])
 119
 120 dnl Whether java.net is built by default can depend on the target.
 121 if test -n "$enable_java_net"; then
 122    enable_java_net=${enable_java_net_default-yes}
 123 fi
 124 if test "$enable_java_net" = no; then
 125    AC_DEFINE(DISABLE_JAVA_NET)
 126 fi
 127
 128 dnl If the target is an eCos system, use the appropriate eCos
 129 dnl I/O routines.
 130 dnl FIXME: this should not be a local option but a global target
 131 dnl system; at present there is no eCos target.
 132 TARGET_ECOS="no"
 133 AC_ARG_WITH(ecos,
 134 [  --with-ecos             enable runtime eCos target support],
 135 TARGET_ECOS="$with_ecos"
 136 )
 137
 138 case "$TARGET_ECOS" in
 139    no)
 140       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
 141       PROCESS=${PROCESS-Posix}
 142       ;;
 143    *)
 144       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
 145       PROCESS=Ecos
 146       AC_DEFINE(ECOS)
 147       ;;
 148 esac
 149
 150 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 151 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 152 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 153 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 154
 155
 156 dnl These may not be defined in a non-ANS conformant embedded system.
 157 dnl FIXME: Should these case a runtime exception in that case?
 158 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 159 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 160
 161 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 162 dnl to create the link will fail.
 163 test -d java || mkdir java
 164 test -d java/io || mkdir java/io
 165 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 166
 167 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 168 test -d java/lang || mkdir java/lang
 169 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 170 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 171
 172 SYSTEMSPEC=
 173 AC_SUBST(SYSTEMSPEC)
 174
 175 AC_ARG_WITH(system-zlib,
 176 [  --with-system-zlib      use installed libz])
 177 ZLIBSPEC=
 178 AC_SUBST(ZLIBSPEC)
 179
 180 dnl FIXME: this should be _libs on some hosts.
 181 libsubdir=.libs
 182
 183 dnl Allow the GC to be disabled.  Can be useful when debugging.
 184 AC_MSG_CHECKING([for garbage collector to use])
 185 AC_ARG_ENABLE(java-gc,
 186 changequote(<<,>>)dnl
 187 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 188 changequote([,])
 189   GC=$enableval,
 190   GC=boehm)
 191 GCLIBS=
 192 GCINCS=
 193 GCDEPS=
 194 GCOBJS=
 195 GCSPEC=
 196 case "$GC" in
 197  boehm)
 198     AC_MSG_RESULT(boehm)
 199     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 200     # We include the path to the boehm-gc build directory.
 201     # See Makefile.am to understand why.
 202     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 203     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
 204     GCSPEC='-lgcjgc'
 205     dnl We also want to pick up some cpp flags required when including
 206     dnl boehm-config.h.  Yuck.
 207     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 208     GCOBJS=boehm.lo
 209     GCHDR=boehm-gc.h
 210     dnl The POSIX thread support needs to know this.
 211     AC_DEFINE(HAVE_BOEHM_GC)
 212     ;;
 213  no)
 214     AC_MSG_RESULT(none)
 215     GCOBJS=nogc.lo
 216     GCHDR=no-gc.h
 217     ;;
 218  *)
 219     AC_MSG_ERROR(unrecognized collector \"$GC\")
 220     ;;
 221 esac
 222 AC_SUBST(GCLIBS)
 223 AC_SUBST(GCINCS)
 224 AC_SUBST(GCDEPS)
 225 AC_SUBST(GCOBJS)
 226 AC_SUBST(GCSPEC)
 227 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 228
 229
 230 dnl Note that this code is kept in sync with similar code in gcc/configure.in.
 231 dnl In particular both packages must make the same decision about which
 232 dnl thread package to use.
 233 AC_MSG_CHECKING([for threads package to use])
 234 AC_ARG_ENABLE(threads, [  --enable-threads=TYPE   choose threading package],
 235   THREADS=$enableval,
 236   dnl FIXME: figure out native threads to use here.
 237   THREADS=no)
 238
 239 if test "$THREADS" = yes; then
 240    case "$host" in
 241     *-*-vxworks*)
 242        THREADS=vxworks
 243        ;;
 244     *-*-linux*)
 245        # FIXME: this isn't correct in all cases.
 246        THREADS=posix
 247        ;;
 248     *-*-win*)
 249        THREADS=win32
 250        ;;
 251     *-*-irix*)
 252        # FIXME: for now, choose POSIX, because we implement that.
 253        # Later, choose irix threads.
 254        THREADS=posix
 255        ;;
 256     *-*-solaris*)
 257        # FIXME: for now, choose POSIX, because we implement that.
 258        # Later, choose solaris threads.
 259        THREADS=posix
 260        ;;
 261     *)
 262        # For now.
 263        THREADS=none
 264        ;;
 265    esac
 266 fi
 267
 268 case "$THREADS" in
 269  no | none | single)
 270     THREADS=none
 271     ;;
 272  posix | pthreads)
 273     THREADS=posix
 274     case "$host" in
 275      *-*-linux*)
 276         AC_DEFINE(LINUX_THREADS)
 277         ;;
 278     esac
 279     ;;
 280  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 281     AC_MSG_ERROR(thread package $THREADS not yet supported)
 282     ;;
 283  *)
 284     AC_MSG_ERROR($THREADS is an unknown thread package)
 285     ;;
 286 esac
 287 AC_MSG_RESULT($THREADS)
 288
 289 THREADLIBS=
 290 THREADINCS=
 291 THREADDEPS=
 292 THREADOBJS=
 293 THREADH=
 294 THREADSPEC=
 295 case "$THREADS" in
 296  posix)
 297     THREADLIBS=-lpthread
 298     THREADSPEC=-lpthread
 299     THREADOBJS=posix-threads.lo
 300     THREADH=posix-threads.h
 301     # MIT pthreads doesn't seem to have the mutexattr functions.
 302     # But for now we don't check for it.  We just assume you aren't
 303     # using MIT pthreads.
 304     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 305     ;;
 306
 307  none)
 308     THREADOBJS=no-threads.lo
 309     THREADH=no-threads.h
 310     ;;
 311 esac
 312 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 313 AC_SUBST(THREADLIBS)
 314 AC_SUBST(THREADINCS)
 315 AC_SUBST(THREADDEPS)
 316 AC_SUBST(THREADOBJS)
 317 AC_SUBST(THREADSPEC)
 318
 319 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 320
 321 CANADIAN=no
 322 NULL_TARGET=no
 323 NATIVE=yes
 324
 325 # Find eh-common.h and support headers.  If we're in the tree with
 326 # gcc, then look there.  Otherwise look in compat-include.  If all else
 327 # fails, just hope the user has set things up somehow.
 328 if test -r $srcdir/../gcc/eh-common.h; then
 329    EH_COMMON_INCLUDE='-I$(top_srcdir)/../gcc -I$(top_srcdir)/../include'
 330 else
 331    if test -d $srcdir/../compat-include; then
 332       EH_COMMON_INCLUDE='-I$(top_srcdir)/../compat-include'
 333    else
 334       EH_COMMON_INCLUDE=
 335    fi
 336 fi
 337
 338 if test -n "${with_cross_host}"; then
 339    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 340    # may not work correctly, because the compiler may not be able to
 341    # link executables.
 342
 343    # We assume newlib.  This lets us hard-code the functions we know
 344    # we'll have.
 345    AC_DEFINE(HAVE_MEMMOVE)
 346    AC_DEFINE(HAVE_MEMCPY)
 347    AC_DEFINE(HAVE_STRERROR)
 348    AC_DEFINE(HAVE_GMTIME_R)
 349    AC_DEFINE(HAVE_LOCALTIME_R)
 350    dnl This is only for POSIX threads.
 351    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 352    dnl We also assume we are using gcc, which provides alloca.
 353    AC_DEFINE(HAVE_ALLOCA)
 354
 355    dnl Assume we do not have getuid and friends.
 356    AC_DEFINE(NO_GETUID)
 357
 358    ZLIBSPEC=-lzgcj
 359
 360    # If Canadian cross, then don't pick up tools from the build
 361    # directory.
 362    if test "$build" != "$with_cross_host"; then
 363       CANADIAN=yes
 364       EH_COMMON_INCLUDE=
 365       GCJ="${target_alias}-gcj"
 366    else
 367       GCJ=
 368    fi
 369    NATIVE=no
 370 else
 371    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 372    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 373    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath)
 374    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 375    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 376    AC_CHECK_FUNCS(backtrace fork execvp pipe)
 377    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 378    AC_CHECK_LIB(dl, dladdr, [
 379      AC_DEFINE(HAVE_DLADDR)])
 380    AC_CHECK_FILES(/proc/self/exe, [
 381      AC_DEFINE(HAVE_PROC_SELF_EXE)])
 382
 383    AC_CHECK_FUNCS(gethostbyname_r, [
 384      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 385      # There are two different kinds of gethostbyname_r.
 386      # We look for the one that returns `int'.
 387      # Hopefully this check is robust enough.
 388      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 389        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 390
 391      case " $GCINCS " in
 392      *" -D_REENTRANT "*) ;;
 393      *)
 394         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 395         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 396         [libjava_cv_gethostbyname_r_needs_reentrant],
 397         [ AC_LANG_SAVE
 398           AC_LANG_CPLUSPLUS
 399           AC_TRY_COMPILE([#include <netdb.h>],
 400             [gethostbyname_r("", 0, 0);],
 401             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 402                 CPPFLAGS_SAVE="$CPPFLAGS"
 403                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 404                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 405                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 406                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 407                 CPPFLAGS="$CPPFLAGS_SAVE"
 408           ])
 409           AC_LANG_RESTORE
 410         ])
 411         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 412           AC_DEFINE(GETHOSTBYNAME_R_NEEDS_REENTRANT, 1, [Define if gethostbyname_r is only declared if _REENTRANT is defined])
 413         fi
 414      ;;
 415      esac
 416
 417      AC_CACHE_CHECK([for struct hostent_data],
 418         [libjava_cv_struct_hostent_data], [dnl
 419         AC_TRY_COMPILE([
 420 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 421 # define _REENTRANT 1
 422 #endif
 423 #include <netdb.h>], [struct hostent_data data;],
 424           [libjava_cv_struct_hostent_data=yes],
 425           [libjava_cv_struct_hostent_data=no])])
 426      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 427        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 428          [Define if struct hostent_data is defined in netdb.h])
 429      fi
 430    ])
 431
 432    AC_CHECK_FUNCS(gethostbyaddr_r, [
 433      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 434      # There are two different kinds of gethostbyaddr_r.
 435      # We look for the one that returns `int'.
 436      # Hopefully this check is robust enough.
 437      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 438        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 439
 440    AC_CHECK_FUNCS(gethostname, [
 441      AC_DEFINE(HAVE_GETHOSTNAME)
 442      AC_EGREP_HEADER(gethostname, unistd.h, [
 443        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 444
 445    # Look for these functions in the thread library, but only bother
 446    # if using POSIX threads.
 447    if test "$THREADS" = posix; then
 448       save_LIBS="$LIBS"
 449       LIBS="$LIBS $THREADLIBS"
 450       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 451       # E.g., Solaris.
 452       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 453
 454       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 455       # Solaris 7 the name librt is preferred.
 456       AC_CHECK_FUNCS(sched_yield, , [
 457         AC_CHECK_LIB(rt, sched_yield, [
 458           AC_DEFINE(HAVE_SCHED_YIELD)
 459           THREADLIBS="$THREADLIBS -lrt"
 460           THREADSPEC="$THREADSPEC -lrt"], [
 461           AC_CHECK_LIB(posix4, sched_yield, [
 462             AC_DEFINE(HAVE_SCHED_YIELD)
 463             THREADLIBS="$THREADLIBS -lposix4"
 464             THREADSPEC="$THREADSPEC -lposix4"])])])
 465       LIBS="$save_LIBS"
 466
 467       # We can save a little space at runtime if the mutex has m_count
 468       # or __m_count.  This is a nice hack for Linux.
 469       AC_TRY_COMPILE([#include <pthread.h>], [
 470           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 471         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 472         AC_TRY_COMPILE([#include <pthread.h>], [
 473             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 474           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 475    fi
 476
 477    # We require a way to get the time.
 478    time_found=no
 479    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 480    if test "$time_found" = no; then
 481       AC_MSG_ERROR([no function found to get the time])
 482    fi
 483
 484    AC_CHECK_FUNCS(memmove)
 485
 486    # We require memcpy.
 487    memcpy_found=no
 488    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 489    if test "$memcpy_found" = no; then
 490       AC_MSG_ERROR([memcpy is required])
 491    fi
 492
 493    # Some library-finding code we stole from Tcl.
 494    #--------------------------------------------------------------------
 495    #    Check for the existence of the -lsocket and -lnsl libraries.
 496    #    The order here is important, so that they end up in the right
 497    #    order in the command line generated by make.  Here are some
 498    #    special considerations:
 499    #    1. Use "connect" and "accept" to check for -lsocket, and
 500    #       "gethostbyname" to check for -lnsl.
 501    #    2. Use each function name only once:  can't redo a check because
 502    #       autoconf caches the results of the last check and won't redo it.
 503    #    3. Use -lnsl and -lsocket only if they supply procedures that
 504    #       aren't already present in the normal libraries.  This is because
 505    #       IRIX 5.2 has libraries, but they aren't needed and they're
 506    #       bogus:  they goof up name resolution if used.
 507    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 508    #       To get around this problem, check for both libraries together
 509    #       if -lsocket doesn't work by itself.
 510    #--------------------------------------------------------------------
 511
 512    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 513     [gcj_cv_lib_sockets=
 514      gcj_checkBoth=0
 515      unset ac_cv_func_connect
 516      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 517      if test "$gcj_checkSocket" = 1; then
 518          unset ac_cv_func_connect
 519          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 520                       gcj_checkBoth=1)
 521      fi
 522      if test "$gcj_checkBoth" = 1; then
 523          gcj_oldLibs=$LIBS
 524          LIBS="$LIBS -lsocket -lnsl"
 525          unset ac_cv_func_accept
 526          AC_CHECK_FUNC(accept,
 527                        [gcj_checkNsl=0
 528                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 529          unset ac_cv_func_accept
 530          LIBS=$gcj_oldLibs
 531      fi
 532      unset ac_cv_func_gethostbyname
 533      gcj_oldLibs=$LIBS
 534      LIBS="$LIBS $gcj_cv_lib_sockets"
 535      AC_CHECK_FUNC(gethostbyname, ,
 536                    [AC_CHECK_LIB(nsl, main,
 537                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 538      unset ac_cv_func_gethostbyname
 539      LIBS=$gcj_oldLIBS
 540    ])
 541    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 542
 543    if test "$with_system_zlib" = yes; then
 544       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 545    else
 546       ZLIBSPEC=-lzgcj
 547    fi
 548
 549    # On Solaris, and maybe other architectures, the Boehm collector
 550    # requires -ldl.
 551    if test "$GC" = boehm; then
 552       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 553    fi
 554
 555    if test -d "$libgcj_basedir/../gcc/java"; then
 556       GCJ=
 557    else
 558       CANADIAN=yes
 559       NULL_TARGET=yes
 560       GCJ=gcj
 561    fi
 562 fi
 563
 564 ZLIBS=
 565 ZDEPS=
 566 ZINCS=
 567 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 568    # We include the path to the zlib build directory.
 569    # See Makefile.am to understand why.
 570    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 571    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 572    ZINCS='-I$(top_srcdir)/../zlib'
 573 else
 574    ZLIBS="$ZLIBSPEC"
 575 fi
 576 AC_SUBST(ZLIBS)
 577 AC_SUBST(ZDEPS)
 578 AC_SUBST(ZINCS)
 579 AC_SUBST(DIVIDESPEC)
 580 AC_SUBST(EXCEPTIONSPEC)
 581 AC_SUBST(FORCELIBGCCSPEC)
 582
 583 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 584 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 585 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 586 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 587 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 588 AC_SUBST(EH_COMMON_INCLUDE)
 589
 590 # Determine gcj version number.
 591 if test "$GCJ" = ""; then
 592    if test -z "${with_multisubdir}"; then
 593       builddotdot=.
 594    else
 595 changequote(<<,>>)
 596       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 597 changequote([,])
 598    fi
 599    dir="`cd ${builddotdot}/../../gcc && pwd`"
 600    GCJ="$dir/gcj -B$dir/"
 601 fi
 602 changequote(<<,>>)
 603 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 604 changequote([,])
 605 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 606
 607 # See if gcj supports -fuse-divide-subroutine.  gcc 2.95 does not, and
 608 # we want to continue to support that version.
 609 AC_MSG_CHECKING([whether gcj supports -fuse-divide-subroutine])
 610 cat > conftest.java << 'END'
 611 public class conftest { }
 612 END
 613 use_fuse=yes
 614 $GCJ -classpath $srcdir -fuse-divide-subroutine -fsyntax-only \
 615    conftest.java > /dev/null 2>&1 \
 616    || use_fuse=no
 617 rm -f conftest.java
 618 if test "$use_fuse" = no; then
 619    DIVIDESPEC=
 620 fi
 621 AC_MSG_RESULT($use_fuse)
 622
 623 AC_SUBST(AM_RUNTESTFLAGS)
 624
 625 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 626 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 627 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 628 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h)
 629 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 630 dnl for now.  If you change this, you also must update natFile.cc.
 631 AC_CHECK_HEADERS(dirent.h)
 632
 633 AC_CHECK_TYPE([ssize_t], [int])
 634
 635 AC_MSG_CHECKING([for in_addr_t])
 636 AC_TRY_COMPILE([#include <sys/types.h>
 637 #if STDC_HEADERS
 638 #include <stdlib.h>
 639 #include <stddef.h>
 640 #endif
 641 #if HAVE_NETINET_IN_H
 642 #include <netinet/in.h>
 643 #endif], [in_addr_t foo;],
 644   [AC_DEFINE([HAVE_IN_ADDR_T])
 645    AC_MSG_RESULT(yes)],
 646   [AC_MSG_RESULT(no)])
 647
 648 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 649 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 650   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 651    AC_MSG_RESULT(yes)],
 652   [AC_MSG_RESULT(no)])
 653
 654 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 655 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 656   [AC_DEFINE(HAVE_INET6)
 657    AC_MSG_RESULT(yes)],
 658   [AC_MSG_RESULT(no)])
 659
 660 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 661 AC_TRY_COMPILE([#include <sys/socket.h>], [socklen_t x = 5;],
 662   [AC_DEFINE(HAVE_SOCKLEN_T)
 663    AC_MSG_RESULT(yes)],
 664   [AC_MSG_RESULT(no)])
 665
 666 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 667 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 668   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 669    AC_MSG_RESULT(yes)],
 670   [AC_MSG_RESULT(no)
 671    AC_MSG_CHECKING([for global timezone variable])
 672    dnl FIXME: we don't want a link check here because that won't work
 673    dnl when cross-compiling.  So instead we make an assumption that
 674    dnl the header file will mention timezone if it exists.
 675    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 676      [AC_DEFINE(HAVE_TIMEZONE)
 677       AC_MSG_RESULT(yes)],
 678      [AC_MSG_RESULT(no)])])
 679
 680 AC_FUNC_ALLOCA
 681
 682 AC_CHECK_PROGS(PERL, perl, false)
 683
 684 if test "$enable_sjlj_exceptions" = yes; then
 685    SIGNAL_HANDLER=include/default-signal.h
 686 else
 687    case "${host}" in
 688     i?86-*-linux*)
 689        SIGNAL_HANDLER=include/i386-signal.h
 690        ;;
 691     sparc-sun-solaris*)
 692        SIGNAL_HANDLER=include/sparc-signal.h
 693        ;;
 694     *)
 695        SIGNAL_HANDLER=include/default-signal.h
 696        ;;
 697    esac
 698 fi
 699
 700 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 701
 702 if test "${multilib}" = "yes"; then
 703   multilib_arg="--enable-multilib"
 704 else
 705   multilib_arg=
 706 fi
 707
 708 here=`pwd`
 709 AC_SUBST(here)
 710
 711 AC_OUTPUT(Makefile libgcj.spec gcj/Makefile include/Makefile testsuite/Makefile,
 712 [if test -n "$CONFIG_FILES"; then
 713   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 714 fi],
 715 srcdir=${srcdir}
 716 host=${host}
 717 target=${target}
 718 with_multisubdir=${with_multisubdir}
 719 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 720 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 721 libgcj_basedir=${libgcj_basedir}
 722 CC="${CC}"
 723 CXX="${CXX}"
 724 )