libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8
   9 dnl We use these options to decide which functions to include.
  10 AC_ARG_WITH(target-subdir,
  11 [  --with-target-subdir=SUBDIR
  12                            configuring in a subdirectory])
  13 AC_ARG_WITH(cross-host,
  14 [  --with-cross-host=HOST  configuring with a cross compiler])
  15
  16 LIBGCJ_CONFIGURE(.)
  17
  18 AM_CONFIG_HEADER(include/config.h)
  19
  20 # Only use libltdl for native builds.
  21 if test -z "${with_cross_host}"; then
  22    AC_LIBLTDL_CONVENIENCE
  23    AC_LIBTOOL_DLOPEN
  24    DIRLTDL=libltdl
  25    AC_DEFINE(USE_LTDL)
  26    # Sigh.  Libtool's macro doesn't do the right thing.
  27    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  28 fi
  29 AC_SUBST(INCLTDL)
  30 AC_SUBST(LIBLTDL)
  31 AC_SUBST(DIRLTDL)
  32 AM_PROG_LIBTOOL
  33 AC_CONFIG_SUBDIRS($DIRLTDL)
  34
  35 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  36    COMPPATH=.
  37 else
  38    COMPPATH=..
  39 fi
  40 AC_SUBST(COMPPATH)
  41
  42 dnl The -no-testsuite modules omit the test subdir.
  43 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  44
  45 dnl See whether the user prefers size or speed for Character.
  46 dnl The default is size.
  47 AC_ARG_ENABLE(fast-character,
  48 [  --enable-fast-character prefer speed over size for Character],
  49 # Nothing
  50 , AC_DEFINE(COMPACT_CHARACTER))
  51
  52 dnl Should the runtime set system properties by examining the
  53 dnl environment variable GCJ_PROPERTIES?
  54 AC_ARG_ENABLE(getenv-properties,
  55 [  --disable-getenv-properties
  56                           don't set system properties from GCJ_PROPERTIES])
  57
  58 dnl Whether GCJ_PROPERTIES is used depends on the target.
  59 if test -n "$enable_getenv_properties"; then
  60    enable_getenv_properties=${enable_getenv_properties_default-yes}
  61 fi
  62 if test "$enable_getenv_properties" = no; then
  63    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  64 fi
  65
  66 dnl See if the user has requested runtime debugging.
  67 AC_ARG_ENABLE(libgcj-debug,
  68 [  --enable-libgcj-debug   enable runtime debugging code],
  69   if test "$enable_libgcj_debug" = yes; then
  70      AC_DEFINE(DEBUG)
  71   fi)
  72
  73 dnl See if the user has the interpreter included.
  74 AC_ARG_ENABLE(interpreter,
  75 [  --enable-interpreter    enable interpreter],
  76   if test "$enable_interpreter" = yes; then
  77     # This can also be set in configure.host.
  78     libgcj_interpreter=yes
  79   elif test "$enable_interpreter" = no; then
  80     libgcj_interpreter=no
  81   fi)
  82
  83 if test "$libgcj_interpreter" = yes; then
  84    AC_DEFINE(INTERPRETER)
  85 fi
  86
  87 EXCEPTIONSPEC=
  88 dnl See if we should use setjmp/longjmp exceptions
  89 AC_ARG_ENABLE(sjlj-exceptions,
  90 [  --enable-sjlj-exceptions    use setjmp/longjmp exceptions],
  91   if test "$enable_sjlj_exceptions" = yes; then
  92      # This can be set in configure.host.
  93      libgcj_sjlj=yes
  94   fi)
  95
  96 if test "$libgcj_sjlj" = yes; then
  97    EXCEPTIONSPEC="-fsjlj-exceptions"
  98    AC_DEFINE(SJLJ_EXCEPTIONS)
  99 fi
 100
 101 FORCELIBGCCSPEC=
 102 dnl Work around libgcc design flaw.
 103 if test "$ac_cv_prog_gnu_ld" = yes; then
 104    FORCELIBGCCSPEC="-u __rethrow -u __frame_state_for -lgcc"
 105 fi
 106
 107 AC_MSG_CHECKING([for data_start])
 108 LIBDATASTARTSPEC=
 109 NEEDS_DATA_START=
 110 AC_TRY_LINK([extern int data_start;], [return ((int) &data_start);],
 111   [AC_MSG_RESULT(found it)],
 112   [LIBDATASTARTSPEC="-u data_start libgcjdata.a%s"
 113    NEEDS_DATA_START=yes
 114    AC_MSG_RESULT(missing)])
 115 AC_SUBST(LIBDATASTARTSPEC)
 116
 117 dnl See if the user wants to disable java.net.  This is the mildly
 118 dnl ugly way that we admit that target-side configuration sucks.
 119 AC_ARG_ENABLE(java-net,
 120 [  --disable-java-net      disable java.net])
 121
 122 dnl Whether java.net is built by default can depend on the target.
 123 if test -n "$enable_java_net"; then
 124    enable_java_net=${enable_java_net_default-yes}
 125 fi
 126 if test "$enable_java_net" = no; then
 127    AC_DEFINE(DISABLE_JAVA_NET)
 128 fi
 129
 130 dnl See if the user wants to disable JVMPI support.
 131 AC_ARG_ENABLE(jvmpi,
 132 [  --disable-jvmpi         disable JVMPI support])
 133
 134 if test "$enable_jvmpi" != no; then
 135     AC_DEFINE(ENABLE_JVMPI)
 136 fi
 137
 138 dnl If the target is an eCos system, use the appropriate eCos
 139 dnl I/O routines.
 140 dnl FIXME: this should not be a local option but a global target
 141 dnl system; at present there is no eCos target.
 142 TARGET_ECOS="no"
 143 AC_ARG_WITH(ecos,
 144 [  --with-ecos             enable runtime eCos target support],
 145 TARGET_ECOS="$with_ecos"
 146 )
 147
 148 case "$TARGET_ECOS" in
 149    no)
 150       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
 151       PROCESS=${PROCESS-Posix}
 152       ;;
 153    *)
 154       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
 155       PROCESS=Ecos
 156       AC_DEFINE(ECOS)
 157       ;;
 158 esac
 159
 160 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 161 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 162 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 163 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 164
 165
 166 dnl These may not be defined in a non-ANS conformant embedded system.
 167 dnl FIXME: Should these case a runtime exception in that case?
 168 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 169 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 170
 171 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 172 dnl to create the link will fail.
 173 test -d java || mkdir java
 174 test -d java/io || mkdir java/io
 175 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 176
 177 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 178 test -d java/lang || mkdir java/lang
 179 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 180 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 181
 182 SYSTEMSPEC=
 183 AC_SUBST(SYSTEMSPEC)
 184
 185 LIBGCJTESTSPEC="-L`pwd`/.libs -rpath `pwd`/.libs"
 186 AC_SUBST(LIBGCJTESTSPEC)
 187
 188 AC_ARG_WITH(system-zlib,
 189 [  --with-system-zlib      use installed libz])
 190 ZLIBSPEC=
 191 AC_SUBST(ZLIBSPEC)
 192 ZLIBTESTSPEC=
 193 AC_SUBST(ZLIBTESTSPEC)
 194
 195 dnl FIXME: this should be _libs on some hosts.
 196 libsubdir=.libs
 197
 198 dnl Allow the GC to be disabled.  Can be useful when debugging.
 199 AC_MSG_CHECKING([for garbage collector to use])
 200 AC_ARG_ENABLE(java-gc,
 201 changequote(<<,>>)dnl
 202 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 203 changequote([,])
 204   GC=$enableval,
 205   GC=boehm)
 206 GCLIBS=
 207 GCINCS=
 208 GCDEPS=
 209 GCOBJS=
 210 GCSPEC=
 211 JC1GCSPEC=
 212 GCTESTSPEC=
 213 case "$GC" in
 214  boehm)
 215     AC_MSG_RESULT(boehm)
 216     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 217     # We include the path to the boehm-gc build directory.
 218     # See Makefile.am to understand why.
 219     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 220     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
 221     GCSPEC='-lgcjgc'
 222     JC1GCSPEC='-fuse-boehm-gc'
 223     GCTESTSPEC="-L`pwd`/../boehm-gc/.libs -rpath `pwd`/../boehm-gc/.libs"
 224     dnl We also want to pick up some cpp flags required when including
 225     dnl boehm-config.h.  Yuck.
 226     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 227     GCOBJS=boehm.lo
 228     GCHDR=boehm-gc.h
 229     dnl The POSIX thread support needs to know this.
 230     AC_DEFINE(HAVE_BOEHM_GC)
 231     ;;
 232  no)
 233     AC_MSG_RESULT(none)
 234     GCOBJS=nogc.lo
 235     GCHDR=no-gc.h
 236     ;;
 237  *)
 238     AC_MSG_ERROR(unrecognized collector \"$GC\")
 239     ;;
 240 esac
 241 AC_SUBST(GCLIBS)
 242 AC_SUBST(GCINCS)
 243 AC_SUBST(GCDEPS)
 244 AC_SUBST(GCOBJS)
 245 AC_SUBST(GCSPEC)
 246 AC_SUBST(JC1GCSPEC)
 247 AC_SUBST(GCTESTSPEC)
 248 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 249
 250
 251 dnl Note that this code is kept in sync with similar code in gcc/configure.in.
 252 dnl In particular both packages must make the same decision about which
 253 dnl thread package to use.
 254 AC_MSG_CHECKING([for threads package to use])
 255 AC_ARG_ENABLE(threads, [  --enable-threads=TYPE   choose threading package],
 256   THREADS=$enableval,
 257   dnl FIXME: figure out native threads to use here.
 258   THREADS=no)
 259
 260 if test "$THREADS" = yes; then
 261    case "$host" in
 262     *-*-vxworks*)
 263        THREADS=vxworks
 264        ;;
 265     *-*-linux*)
 266        # FIXME: this isn't correct in all cases.
 267        THREADS=posix
 268        ;;
 269     *-*-win*)
 270        THREADS=win32
 271        ;;
 272     *-*-irix*)
 273        # FIXME: for now, choose POSIX, because we implement that.
 274        # Later, choose irix threads.
 275        THREADS=posix
 276        ;;
 277     *-*-solaris*)
 278        # FIXME: for now, choose POSIX, because we implement that.
 279        # Later, choose solaris threads.
 280        THREADS=posix
 281        ;;
 282     *)
 283        # For now.
 284        THREADS=none
 285        ;;
 286    esac
 287 fi
 288
 289 case "$THREADS" in
 290  no | none | single)
 291     THREADS=none
 292     ;;
 293  posix | pthreads)
 294     THREADS=posix
 295     case "$host" in
 296      *-*-linux*)
 297         AC_DEFINE(LINUX_THREADS)
 298         ;;
 299     esac
 300     ;;
 301  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 302     AC_MSG_ERROR(thread package $THREADS not yet supported)
 303     ;;
 304  *)
 305     AC_MSG_ERROR($THREADS is an unknown thread package)
 306     ;;
 307 esac
 308 AC_MSG_RESULT($THREADS)
 309
 310 THREADLIBS=
 311 THREADINCS=
 312 THREADDEPS=
 313 THREADOBJS=
 314 THREADH=
 315 THREADSPEC=
 316 case "$THREADS" in
 317  posix)
 318     THREADLIBS=-lpthread
 319     THREADSPEC=-lpthread
 320     THREADOBJS=posix-threads.lo
 321     THREADH=posix-threads.h
 322     # MIT pthreads doesn't seem to have the mutexattr functions.
 323     # But for now we don't check for it.  We just assume you aren't
 324     # using MIT pthreads.
 325     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 326
 327     # If we're using the Boehm GC, then we happen to know that it
 328     # defines _REENTRANT, so we don't bother.  Eww.
 329     if test "$GC" != boehm; then
 330        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 331     fi
 332     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 333     ;;
 334
 335  none)
 336     THREADOBJS=no-threads.lo
 337     THREADH=no-threads.h
 338     ;;
 339 esac
 340 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 341 AC_SUBST(THREADLIBS)
 342 AC_SUBST(THREADINCS)
 343 AC_SUBST(THREADDEPS)
 344 AC_SUBST(THREADOBJS)
 345 AC_SUBST(THREADSPEC)
 346
 347 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 348
 349 CANADIAN=no
 350 NULL_TARGET=no
 351 NATIVE=yes
 352
 353 # Find eh-common.h and support headers.  If we're in the tree with
 354 # gcc, then look there.  Otherwise look in compat-include.  If all else
 355 # fails, just hope the user has set things up somehow.
 356 if test -r $srcdir/../gcc/eh-common.h; then
 357    EH_COMMON_INCLUDE='-I$(top_srcdir)/../gcc -I$(top_srcdir)/../include'
 358 else
 359    if test -d $srcdir/../compat-include; then
 360       EH_COMMON_INCLUDE='-I$(top_srcdir)/../compat-include'
 361    else
 362       EH_COMMON_INCLUDE=
 363    fi
 364 fi
 365
 366 if test -n "${with_cross_host}"; then
 367    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 368    # may not work correctly, because the compiler may not be able to
 369    # link executables.
 370
 371    # We assume newlib.  This lets us hard-code the functions we know
 372    # we'll have.
 373    AC_DEFINE(HAVE_MEMMOVE)
 374    AC_DEFINE(HAVE_MEMCPY)
 375    AC_DEFINE(HAVE_STRERROR)
 376    AC_DEFINE(HAVE_GMTIME_R)
 377    AC_DEFINE(HAVE_LOCALTIME_R)
 378    dnl This is only for POSIX threads.
 379    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 380    dnl We also assume we are using gcc, which provides alloca.
 381    AC_DEFINE(HAVE_ALLOCA)
 382
 383    dnl Assume we do not have getuid and friends.
 384    AC_DEFINE(NO_GETUID)
 385
 386    ZLIBSPEC=-lzgcj
 387    ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 388
 389    # If Canadian cross, then don't pick up tools from the build
 390    # directory.
 391    if test "$build" != "$with_cross_host"; then
 392       CANADIAN=yes
 393       EH_COMMON_INCLUDE=
 394       GCJ="${target_alias}-gcj"
 395    else
 396       GCJ=
 397    fi
 398    NATIVE=no
 399 else
 400    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 401    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 402    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath)
 403    AC_CHECK_FUNCS(iconv nl_langinfo)
 404    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 405    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 406    AC_CHECK_FUNCS(backtrace fork execvp pipe)
 407    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 408    AC_CHECK_LIB(dl, dladdr, [
 409      AC_DEFINE(HAVE_DLADDR)])
 410    AC_CHECK_FILES(/proc/self/exe, [
 411      AC_DEFINE(HAVE_PROC_SELF_EXE)])
 412
 413    AC_CHECK_FUNCS(gethostbyname_r, [
 414      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 415      # There are two different kinds of gethostbyname_r.
 416      # We look for the one that returns `int'.
 417      # Hopefully this check is robust enough.
 418      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 419        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 420
 421      case " $GCINCS " in
 422      *" -D_REENTRANT "*) ;;
 423      *)
 424         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 425         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 426         [libjava_cv_gethostbyname_r_needs_reentrant],
 427         [ AC_LANG_SAVE
 428           AC_LANG_CPLUSPLUS
 429           AC_TRY_COMPILE([#include <netdb.h>],
 430             [gethostbyname_r("", 0, 0);],
 431             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 432                 CPPFLAGS_SAVE="$CPPFLAGS"
 433                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 434                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 435                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 436                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 437                 CPPFLAGS="$CPPFLAGS_SAVE"
 438           ])
 439           AC_LANG_RESTORE
 440         ])
 441         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 442           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 443         fi
 444      ;;
 445      esac
 446
 447      AC_CACHE_CHECK([for struct hostent_data],
 448         [libjava_cv_struct_hostent_data], [dnl
 449         AC_TRY_COMPILE([
 450 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 451 # define _REENTRANT 1
 452 #endif
 453 #include <netdb.h>], [struct hostent_data data;],
 454           [libjava_cv_struct_hostent_data=yes],
 455           [libjava_cv_struct_hostent_data=no])])
 456      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 457        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 458          [Define if struct hostent_data is defined in netdb.h])
 459      fi
 460    ])
 461
 462    AC_CHECK_FUNCS(gethostbyaddr_r, [
 463      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 464      # There are two different kinds of gethostbyaddr_r.
 465      # We look for the one that returns `int'.
 466      # Hopefully this check is robust enough.
 467      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 468        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 469
 470    AC_CHECK_FUNCS(gethostname, [
 471      AC_DEFINE(HAVE_GETHOSTNAME)
 472      AC_EGREP_HEADER(gethostname, unistd.h, [
 473        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 474
 475    # Look for these functions in the thread library, but only bother
 476    # if using POSIX threads.
 477    if test "$THREADS" = posix; then
 478       save_LIBS="$LIBS"
 479       LIBS="$LIBS $THREADLIBS"
 480       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 481       # E.g., Solaris.
 482       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 483
 484       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 485       # Solaris 7 the name librt is preferred.
 486       AC_CHECK_FUNCS(sched_yield, , [
 487         AC_CHECK_LIB(rt, sched_yield, [
 488           AC_DEFINE(HAVE_SCHED_YIELD)
 489           THREADLIBS="$THREADLIBS -lrt"
 490           THREADSPEC="$THREADSPEC -lrt"], [
 491           AC_CHECK_LIB(posix4, sched_yield, [
 492             AC_DEFINE(HAVE_SCHED_YIELD)
 493             THREADLIBS="$THREADLIBS -lposix4"
 494             THREADSPEC="$THREADSPEC -lposix4"])])])
 495       LIBS="$save_LIBS"
 496
 497       # We can save a little space at runtime if the mutex has m_count
 498       # or __m_count.  This is a nice hack for Linux.
 499       AC_TRY_COMPILE([#include <pthread.h>], [
 500           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 501         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 502         AC_TRY_COMPILE([#include <pthread.h>], [
 503             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 504           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 505    fi
 506
 507    # We require a way to get the time.
 508    time_found=no
 509    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 510    if test "$time_found" = no; then
 511       AC_MSG_ERROR([no function found to get the time])
 512    fi
 513
 514    AC_CHECK_FUNCS(memmove)
 515
 516    # We require memcpy.
 517    memcpy_found=no
 518    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 519    if test "$memcpy_found" = no; then
 520       AC_MSG_ERROR([memcpy is required])
 521    fi
 522
 523    # Some library-finding code we stole from Tcl.
 524    #--------------------------------------------------------------------
 525    #    Check for the existence of the -lsocket and -lnsl libraries.
 526    #    The order here is important, so that they end up in the right
 527    #    order in the command line generated by make.  Here are some
 528    #    special considerations:
 529    #    1. Use "connect" and "accept" to check for -lsocket, and
 530    #       "gethostbyname" to check for -lnsl.
 531    #    2. Use each function name only once:  can't redo a check because
 532    #       autoconf caches the results of the last check and won't redo it.
 533    #    3. Use -lnsl and -lsocket only if they supply procedures that
 534    #       aren't already present in the normal libraries.  This is because
 535    #       IRIX 5.2 has libraries, but they aren't needed and they're
 536    #       bogus:  they goof up name resolution if used.
 537    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 538    #       To get around this problem, check for both libraries together
 539    #       if -lsocket doesn't work by itself.
 540    #--------------------------------------------------------------------
 541
 542    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 543     [gcj_cv_lib_sockets=
 544      gcj_checkBoth=0
 545      unset ac_cv_func_connect
 546      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 547      if test "$gcj_checkSocket" = 1; then
 548          unset ac_cv_func_connect
 549          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 550                       gcj_checkBoth=1)
 551      fi
 552      if test "$gcj_checkBoth" = 1; then
 553          gcj_oldLibs=$LIBS
 554          LIBS="$LIBS -lsocket -lnsl"
 555          unset ac_cv_func_accept
 556          AC_CHECK_FUNC(accept,
 557                        [gcj_checkNsl=0
 558                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 559          unset ac_cv_func_accept
 560          LIBS=$gcj_oldLibs
 561      fi
 562      unset ac_cv_func_gethostbyname
 563      gcj_oldLibs=$LIBS
 564      LIBS="$LIBS $gcj_cv_lib_sockets"
 565      AC_CHECK_FUNC(gethostbyname, ,
 566                    [AC_CHECK_LIB(nsl, main,
 567                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 568      unset ac_cv_func_gethostbyname
 569      LIBS=$gcj_oldLIBS
 570    ])
 571    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 572
 573    if test "$with_system_zlib" = yes; then
 574       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 575    else
 576       ZLIBSPEC=-lzgcj
 577       ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 578    fi
 579
 580    # On Solaris, and maybe other architectures, the Boehm collector
 581    # requires -ldl.
 582    if test "$GC" = boehm; then
 583       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 584    fi
 585
 586    if test -z "${with_multisubdir}"; then
 587       builddotdot=.
 588    else
 589 changequote(<<,>>)
 590       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 591 changequote([,])
 592    fi
 593    dir="`cd ${builddotdot}/../../gcc && pwd`"
 594    if test -x "${dir}/gcj"; then
 595       GCJ="$dir/gcj -B`pwd`/ -B$dir/"
 596    else
 597       CANADIAN=yes
 598       NULL_TARGET=yes
 599       GCJ="gcj -B`pwd`/"
 600    fi
 601 fi
 602
 603 # Create it, so that compile/link tests don't fail
 604 test -f libgcj.spec || touch libgcj.spec
 605 GCJ="$GCJ -I$srcdir"
 606
 607 LT_AC_PROG_GCJ
 608
 609 dnl FIXME: cross compilation
 610 AC_CHECK_SIZEOF(void *)
 611
 612 ZLIBS=
 613 ZDEPS=
 614 ZINCS=
 615 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 616    # We include the path to the zlib build directory.
 617    # See Makefile.am to understand why.
 618    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 619    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 620    ZINCS='-I$(top_srcdir)/../zlib'
 621 else
 622    ZLIBS="$ZLIBSPEC"
 623 fi
 624 AC_SUBST(ZLIBS)
 625 AC_SUBST(ZDEPS)
 626 AC_SUBST(ZINCS)
 627 AC_SUBST(DIVIDESPEC)
 628 AC_SUBST(EXCEPTIONSPEC)
 629 AC_SUBST(FORCELIBGCCSPEC)
 630
 631 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 632 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 633 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 634 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 635 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 636 AC_SUBST(EH_COMMON_INCLUDE)
 637
 638 # Determine gcj version number.
 639 changequote(<<,>>)
 640 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 641 changequote([,])
 642 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 643
 644 # See if gcj supports -fuse-divide-subroutine.  gcc 2.95 does not, and
 645 # we want to continue to support that version.
 646 AC_MSG_CHECKING([whether gcj supports -fuse-divide-subroutine])
 647 cat > conftest.java << 'END'
 648 public class conftest { }
 649 END
 650 use_fuse=yes
 651 $GCJ -classpath $srcdir -fuse-divide-subroutine -fsyntax-only \
 652    conftest.java > /dev/null 2>&1 \
 653    || use_fuse=no
 654 rm -f conftest.java
 655 if test "$use_fuse" = no; then
 656    DIVIDESPEC=
 657 fi
 658 AC_MSG_RESULT($use_fuse)
 659
 660 AC_SUBST(AM_RUNTESTFLAGS)
 661
 662 dnl Work around a g++ bug.  Reported to gcc-bugs@gcc.gnu.org on Jan 22, 2000.
 663 AC_MSG_CHECKING([for g++ -ffloat-store bug])
 664 save_CFLAGS="$CFLAGS"
 665 CFLAGS="-x c++ -O2 -ffloat-store"
 666 AC_TRY_COMPILE([#include <math.h>], ,
 667   [AC_MSG_RESULT(no)],
 668   [AC_DEFINE(__NO_MATH_INLINES)
 669    AC_MSG_RESULT(yes)])
 670 CFLAGS="$save_CFLAGS"
 671
 672 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 673 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 674 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 675 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h langinfo.h)
 676 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 677 dnl for now.  If you change this, you also must update natFile.cc.
 678 AC_CHECK_HEADERS(dirent.h)
 679
 680 AC_CHECK_TYPE([ssize_t], [int])
 681
 682 AC_MSG_CHECKING([for in_addr_t])
 683 AC_TRY_COMPILE([#include <sys/types.h>
 684 #if STDC_HEADERS
 685 #include <stdlib.h>
 686 #include <stddef.h>
 687 #endif
 688 #if HAVE_NETINET_IN_H
 689 #include <netinet/in.h>
 690 #endif], [in_addr_t foo;],
 691   [AC_DEFINE([HAVE_IN_ADDR_T])
 692    AC_MSG_RESULT(yes)],
 693   [AC_MSG_RESULT(no)])
 694
 695 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 696 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 697   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 698    AC_MSG_RESULT(yes)],
 699   [AC_MSG_RESULT(no)])
 700
 701 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 702 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 703   [AC_DEFINE(HAVE_INET6)
 704    AC_MSG_RESULT(yes)],
 705   [AC_MSG_RESULT(no)])
 706
 707 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 708 AC_TRY_COMPILE([#include <sys/socket.h>], [socklen_t x = 5;],
 709   [AC_DEFINE(HAVE_SOCKLEN_T)
 710    AC_MSG_RESULT(yes)],
 711   [AC_MSG_RESULT(no)])
 712
 713 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 714 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 715   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 716    AC_MSG_RESULT(yes)],
 717   [AC_MSG_RESULT(no)
 718    AC_MSG_CHECKING([for global timezone variable])
 719    dnl FIXME: we don't want a link check here because that won't work
 720    dnl when cross-compiling.  So instead we make an assumption that
 721    dnl the header file will mention timezone if it exists.
 722    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 723      [AC_DEFINE(HAVE_TIMEZONE)
 724       AC_MSG_RESULT(yes)],
 725      [AC_MSG_RESULT(no)])])
 726
 727 AC_FUNC_ALLOCA
 728
 729 AC_CHECK_PROGS(PERL, perl, false)
 730
 731 SYSDEP_SOURCES=
 732
 733 case "${host}" in
 734  i?86-*-linux*)
 735     SIGNAL_HANDLER=include/i386-signal.h
 736     ;;
 737  sparc-sun-solaris*)
 738     SIGNAL_HANDLER=include/sparc-signal.h
 739     ;;
 740  ia64-*)
 741     SYSDEP_SOURCES=sysdep/ia64.c
 742     test -d sysdep || mkdir sysdep
 743     ;;
 744  *)
 745     SIGNAL_HANDLER=include/default-signal.h
 746     ;;
 747 esac
 748
 749 # If we're using sjlj exceptions, forget what we just learned.
 750 if test "$libgcj_sjlj" = yes; then
 751    SIGNAL_HANDLER=include/default-signal.h
 752 fi
 753
 754 AC_SUBST(SYSDEP_SOURCES)
 755
 756 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 757
 758 if test "${multilib}" = "yes"; then
 759   multilib_arg="--enable-multilib"
 760 else
 761   multilib_arg=
 762 fi
 763
 764 here=`pwd`
 765 AC_SUBST(here)
 766
 767 AC_OUTPUT(Makefile libgcj.spec libgcj-test.spec gcj/Makefile include/Makefile testsuite/Makefile,
 768 [if test -n "$CONFIG_FILES"; then
 769   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 770 fi],
 771 srcdir=${srcdir}
 772 host=${host}
 773 target=${target}
 774 with_multisubdir=${with_multisubdir}
 775 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 776 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 777 libgcj_basedir=${libgcj_basedir}
 778 CC="${CC}"
 779 CXX="${CXX}"
 780 )