libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_PROG_LN_S
   9
  10 dnl We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12 [  --with-target-subdir=SUBDIR
  13                            configuring in a subdirectory])
  14 AC_ARG_WITH(cross-host,
  15 [  --with-cross-host=HOST  configuring with a cross compiler])
  16
  17 LIBGCJ_CONFIGURE(.)
  18
  19 AM_CONFIG_HEADER(include/config.h gcj/libgcj-config.h)
  20
  21 # Only use libltdl for native builds.
  22 if test -z "${with_cross_host}"; then
  23    AC_LIBLTDL_CONVENIENCE
  24    AC_LIBTOOL_DLOPEN
  25    DIRLTDL=libltdl
  26    AC_DEFINE(USE_LTDL)
  27    # Sigh.  Libtool's macro doesn't do the right thing.
  28    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  29 fi
  30 AC_SUBST(INCLTDL)
  31 AC_SUBST(LIBLTDL)
  32 AC_SUBST(DIRLTDL)
  33 AM_PROG_LIBTOOL
  34 AC_CONFIG_SUBDIRS($DIRLTDL)
  35
  36 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  37    COMPPATH=.
  38 else
  39    COMPPATH=..
  40 fi
  41 AC_SUBST(COMPPATH)
  42
  43 dnl The -no-testsuite modules omit the test subdir.
  44 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  45
  46 dnl See whether the user prefers size or speed for Character.
  47 dnl The default is size.
  48 AC_ARG_ENABLE(fast-character,
  49 [  --enable-fast-character prefer speed over size for Character],
  50 # Nothing
  51 , AC_DEFINE(COMPACT_CHARACTER))
  52
  53 dnl Should the runtime set system properties by examining the
  54 dnl environment variable GCJ_PROPERTIES?
  55 AC_ARG_ENABLE(getenv-properties,
  56 [  --disable-getenv-properties
  57                           don't set system properties from GCJ_PROPERTIES])
  58
  59 dnl Whether GCJ_PROPERTIES is used depends on the target.
  60 if test -z "$enable_getenv_properties"; then
  61    enable_getenv_properties=${enable_getenv_properties_default-yes}
  62 fi
  63 if test "$enable_getenv_properties" = no; then
  64    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  65 fi
  66
  67
  68 dnl Should we use hashtable-based synchronization?
  69 dnl Currently works only for Linux X86/ia64
  70 dnl Typically faster and more space-efficient
  71 AC_ARG_ENABLE(hash-synchronization,
  72 [  --enable-hash-synchronization
  73                           Use global hash table for monitor locks])
  74
  75 if test -z "$enable_hash_synchronization"; then
  76    enable_hash_synchronization=$enable_hash_synchronization_default
  77 fi
  78
  79
  80 dnl See if the user has requested runtime debugging.
  81 LIBGCJDEBUG="false"
  82 AC_SUBST(LIBGCJDEBUG)
  83 AC_ARG_ENABLE(libgcj-debug,
  84 [  --enable-libgcj-debug   enable runtime debugging code],
  85   if test "$enable_libgcj_debug" = yes; then
  86     AC_DEFINE(DEBUG)
  87     LIBGCJDEBUG="true"
  88   fi)
  89
  90 dnl See if the user has the interpreter included.
  91 AC_ARG_ENABLE(interpreter,
  92 [  --enable-interpreter    enable interpreter],
  93   if test "$enable_interpreter" = yes; then
  94     # This can also be set in configure.host.
  95     libgcj_interpreter=yes
  96   elif test "$enable_interpreter" = no; then
  97     libgcj_interpreter=no
  98   fi)
  99
 100 if test "$libgcj_interpreter" = yes; then
 101    AC_DEFINE(INTERPRETER)
 102 fi
 103
 104 AC_MSG_CHECKING([for exception model to use])
 105 AC_LANG_SAVE
 106 AC_LANG_CPLUSPLUS
 107 AC_ARG_ENABLE(sjlj-exceptions,
 108 [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
 109 [:],
 110 [dnl Botheration.  Now we've got to detect the exception model.
 111 dnl Link tests against libgcc.a are problematic since -- at least
 112 dnl as of this writing -- we've not been given proper -L bits for
 113 dnl single-tree newlib and libgloss.
 114 dnl
 115 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 116 dnl conftest files before we got a change to grep them first.
 117 cat > conftest.$ac_ext << EOF
 118 [#]line __oline__ "configure"
 119 struct S { ~S(); };
 120 void bar();
 121 void foo()
 122 {
 123   S s;
 124   bar();
 125 }
 126 EOF
 127 old_CXXFLAGS="$CXXFLAGS"
 128 CXXFLAGS=-S
 129 if AC_TRY_EVAL(ac_compile); then
 130   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 131     enable_sjlj_exceptions=yes
 132   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 133     enable_sjlj_exceptions=no
 134   fi
 135 fi
 136 CXXFLAGS="$old_CXXFLAGS"
 137 rm -f conftest*])
 138 if test x$enable_sjlj_exceptions = xyes; then
 139   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 140         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 141   ac_exception_model_name=sjlj
 142 elif test x$enable_sjlj_exceptions = xno; then
 143   ac_exception_model_name="call frame"
 144 else
 145   AC_MSG_ERROR([unable to detect exception model])
 146 fi
 147 AC_LANG_RESTORE
 148 AC_MSG_RESULT($ac_exception_model_name)
 149
 150 AC_MSG_CHECKING([for data_start])
 151 LIBDATASTARTSPEC=
 152 NEEDS_DATA_START=
 153 AC_TRY_LINK([extern int data_start;], [return ((int) &data_start);],
 154   [AC_MSG_RESULT(found it)],
 155   [LIBDATASTARTSPEC="-u data_start libgcjdata.a%s"
 156    NEEDS_DATA_START=yes
 157    AC_MSG_RESULT(missing)])
 158 AC_SUBST(LIBDATASTARTSPEC)
 159
 160 dnl See if the user wants to disable java.net.  This is the mildly
 161 dnl ugly way that we admit that target-side configuration sucks.
 162 AC_ARG_ENABLE(java-net,
 163 [  --disable-java-net      disable java.net])
 164
 165 dnl Whether java.net is built by default can depend on the target.
 166 if test -z "$enable_java_net"; then
 167    enable_java_net=${enable_java_net_default-yes}
 168 fi
 169 if test "$enable_java_net" = no; then
 170    AC_DEFINE(DISABLE_JAVA_NET)
 171 fi
 172
 173 dnl See if the user wants to disable JVMPI support.
 174 AC_ARG_ENABLE(jvmpi,
 175 [  --disable-jvmpi         disable JVMPI support])
 176
 177 if test "$enable_jvmpi" != no; then
 178     AC_DEFINE(ENABLE_JVMPI)
 179 fi
 180
 181 dnl If the target is an eCos system, use the appropriate eCos
 182 dnl I/O routines.
 183 dnl FIXME: this should not be a local option but a global target
 184 dnl system; at present there is no eCos target.
 185 TARGET_ECOS="no"
 186 AC_ARG_WITH(ecos,
 187 [  --with-ecos             enable runtime eCos target support],
 188 TARGET_ECOS="$with_ecos"
 189 )
 190
 191 case "$TARGET_ECOS" in
 192    no)
 193       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
 194       PROCESS=${PROCESS-Posix}
 195       ;;
 196    *)
 197       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
 198       PROCESS=Ecos
 199       AC_DEFINE(ECOS)
 200       ;;
 201 esac
 202
 203 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 204 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 205 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 206 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 207
 208
 209 dnl These may not be defined in a non-ANS conformant embedded system.
 210 dnl FIXME: Should these case a runtime exception in that case?
 211 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 212 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 213
 214 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 215 dnl to create the link will fail.
 216 test -d java || mkdir java
 217 test -d java/io || mkdir java/io
 218 test -d gnu || mkdir gnu
 219 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 220
 221 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 222 test -d java/lang || mkdir java/lang
 223 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 224 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 225
 226 SYSTEMSPEC=
 227 AC_SUBST(SYSTEMSPEC)
 228
 229 LIBGCJTESTSPEC="-L`pwd`/.libs -rpath `pwd`/.libs"
 230 AC_SUBST(LIBGCJTESTSPEC)
 231
 232 AC_ARG_WITH(system-zlib,
 233 [  --with-system-zlib      use installed libz])
 234 ZLIBSPEC=
 235 AC_SUBST(ZLIBSPEC)
 236 ZLIBTESTSPEC=
 237 AC_SUBST(ZLIBTESTSPEC)
 238
 239 dnl FIXME: this should be _libs on some hosts.
 240 libsubdir=.libs
 241
 242 dnl Allow the GC to be disabled.  Can be useful when debugging.
 243 AC_MSG_CHECKING([for garbage collector to use])
 244 AC_ARG_ENABLE(java-gc,
 245 changequote(<<,>>)dnl
 246 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 247 changequote([,])
 248   GC=$enableval,
 249   GC=boehm)
 250 GCLIBS=
 251 GCINCS=
 252 GCDEPS=
 253 GCOBJS=
 254 GCSPEC=
 255 JC1GCSPEC=
 256 GCTESTSPEC=
 257 case "$GC" in
 258  boehm)
 259     AC_MSG_RESULT(boehm)
 260     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 261     # We include the path to the boehm-gc build directory.
 262     # See Makefile.am to understand why.
 263     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 264     GCINCS='-I$(top_srcdir)/../boehm-gc/include'
 265     GCSPEC='-lgcjgc'
 266     JC1GCSPEC='-fuse-boehm-gc'
 267     GCTESTSPEC="-L`pwd`/../boehm-gc/.libs -rpath `pwd`/../boehm-gc/.libs"
 268     dnl We also want to pick up some cpp flags required when including
 269     dnl boehm-config.h.  Yuck.
 270     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 271     GCOBJS=boehm.lo
 272     GCHDR=boehm-gc.h
 273     dnl The POSIX thread support needs to know this.
 274     AC_DEFINE(HAVE_BOEHM_GC)
 275     ;;
 276  no)
 277     AC_MSG_RESULT(none)
 278     GCOBJS=nogc.lo
 279     GCHDR=no-gc.h
 280     ;;
 281  *)
 282     AC_MSG_ERROR(unrecognized collector \"$GC\")
 283     ;;
 284 esac
 285 AC_SUBST(GCLIBS)
 286 AC_SUBST(GCINCS)
 287 AC_SUBST(GCDEPS)
 288 AC_SUBST(GCOBJS)
 289 AC_SUBST(GCSPEC)
 290 AC_SUBST(JC1GCSPEC)
 291 AC_SUBST(GCTESTSPEC)
 292 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 293
 294
 295 AC_MSG_CHECKING([for thread model used by GCC])
 296 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 297 AC_MSG_RESULT([$THREADS])
 298
 299 case "$THREADS" in
 300  no | none | single)
 301     THREADS=none
 302     ;;
 303  posix | pthreads)
 304     THREADS=posix
 305     case "$host" in
 306      *-*-linux*)
 307         AC_DEFINE(LINUX_THREADS)
 308         ;;
 309     esac
 310     ;;
 311  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 312     AC_MSG_ERROR(thread package $THREADS not yet supported)
 313     ;;
 314  *)
 315     AC_MSG_ERROR($THREADS is an unknown thread package)
 316     ;;
 317 esac
 318
 319 THREADLIBS=
 320 THREADINCS=
 321 THREADDEPS=
 322 THREADOBJS=
 323 THREADH=
 324 THREADSPEC=
 325 case "$THREADS" in
 326  posix)
 327     THREADLIBS=-lpthread
 328     THREADSPEC=-lpthread
 329     THREADOBJS=posix-threads.lo
 330     THREADH=posix-threads.h
 331     # MIT pthreads doesn't seem to have the mutexattr functions.
 332     # But for now we don't check for it.  We just assume you aren't
 333     # using MIT pthreads.
 334     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 335
 336     # If we're using the Boehm GC, then we happen to know that it
 337     # defines _REENTRANT, so we don't bother.  Eww.
 338     if test "$GC" != boehm; then
 339        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 340     fi
 341     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 342     ;;
 343
 344  none)
 345     THREADOBJS=no-threads.lo
 346     THREADH=no-threads.h
 347     ;;
 348 esac
 349 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 350 AC_SUBST(THREADLIBS)
 351 AC_SUBST(THREADINCS)
 352 AC_SUBST(THREADDEPS)
 353 AC_SUBST(THREADOBJS)
 354 AC_SUBST(THREADSPEC)
 355
 356 HASH_SYNC_SPEC=
 357 # Hash synchronization is only useful with posix threads right now.
 358 if test "$enable_hash_synchronization" = yes && test "$THREADS" = "posix"; then
 359    HASH_SYNC_SPEC=-fhash-synchronization
 360    AC_DEFINE(JV_HASH_SYNCHRONIZATION)
 361 fi
 362 AC_SUBST(HASH_SYNC_SPEC)
 363
 364
 365 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 366
 367 CANADIAN=no
 368 NULL_TARGET=no
 369 NATIVE=yes
 370
 371 # We're in the tree with gcc, and need to include some of its headers.
 372 GCC_UNWIND_INCLUDE='-I$(top_srcdir)/../gcc'
 373
 374 if test -n "${with_cross_host}"; then
 375    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 376    # may not work correctly, because the compiler may not be able to
 377    # link executables.
 378
 379    # We assume newlib.  This lets us hard-code the functions we know
 380    # we'll have.
 381    AC_DEFINE(HAVE_MEMMOVE)
 382    AC_DEFINE(HAVE_MEMCPY)
 383    AC_DEFINE(HAVE_STRERROR)
 384    AC_DEFINE(HAVE_GMTIME_R)
 385    AC_DEFINE(HAVE_LOCALTIME_R)
 386    dnl This is only for POSIX threads.
 387    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 388    dnl We also assume we are using gcc, which provides alloca.
 389    AC_DEFINE(HAVE_ALLOCA)
 390
 391    dnl Assume we do not have getuid and friends.
 392    AC_DEFINE(NO_GETUID)
 393
 394    ZLIBSPEC=-lzgcj
 395    ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 396
 397    # If Canadian cross, then don't pick up tools from the build
 398    # directory.
 399    if test x"$build" != x"$with_cross_host" && x"$build" != x"$target"; then
 400       CANADIAN=yes
 401       GCC_UNWIND_INCLUDE=
 402       GCJ="${target_alias}-gcj"
 403    fi
 404    NATIVE=no
 405 else
 406    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 407    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 408    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath utime chmod)
 409    AC_CHECK_FUNCS(iconv nl_langinfo setlocale)
 410    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 411    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 412    AC_CHECK_FUNCS(backtrace fork execvp pipe)
 413    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 414    AC_CHECK_LIB(dl, dladdr, [
 415      AC_DEFINE(HAVE_DLADDR)])
 416    AC_CHECK_FILES(/proc/self/exe, [
 417      AC_DEFINE(HAVE_PROC_SELF_EXE)])
 418
 419    AC_CHECK_FUNCS(gethostbyname_r, [
 420      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 421      # There are two different kinds of gethostbyname_r.
 422      # We look for the one that returns `int'.
 423      # Hopefully this check is robust enough.
 424      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 425        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 426
 427      case " $GCINCS " in
 428      *" -D_REENTRANT "*) ;;
 429      *)
 430         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 431         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 432         [libjava_cv_gethostbyname_r_needs_reentrant],
 433         [ AC_LANG_SAVE
 434           AC_LANG_CPLUSPLUS
 435           AC_TRY_COMPILE([#include <netdb.h>],
 436             [gethostbyname_r("", 0, 0);],
 437             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 438                 CPPFLAGS_SAVE="$CPPFLAGS"
 439                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 440                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 441                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 442                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 443                 CPPFLAGS="$CPPFLAGS_SAVE"
 444           ])
 445           AC_LANG_RESTORE
 446         ])
 447         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 448           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 449         fi
 450      ;;
 451      esac
 452
 453      AC_CACHE_CHECK([for struct hostent_data],
 454         [libjava_cv_struct_hostent_data], [dnl
 455         AC_TRY_COMPILE([
 456 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 457 # define _REENTRANT 1
 458 #endif
 459 #include <netdb.h>], [struct hostent_data data;],
 460           [libjava_cv_struct_hostent_data=yes],
 461           [libjava_cv_struct_hostent_data=no])])
 462      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 463        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 464          [Define if struct hostent_data is defined in netdb.h])
 465      fi
 466    ])
 467
 468    AC_CHECK_FUNCS(gethostbyaddr_r, [
 469      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 470      # There are two different kinds of gethostbyaddr_r.
 471      # We look for the one that returns `int'.
 472      # Hopefully this check is robust enough.
 473      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 474        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 475
 476    AC_CHECK_FUNCS(gethostname, [
 477      AC_DEFINE(HAVE_GETHOSTNAME)
 478      AC_EGREP_HEADER(gethostname, unistd.h, [
 479        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 480
 481    # Look for these functions in the thread library, but only bother
 482    # if using POSIX threads.
 483    if test "$THREADS" = posix; then
 484       save_LIBS="$LIBS"
 485       LIBS="$LIBS $THREADLIBS"
 486       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 487       # E.g., Solaris.
 488       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 489
 490       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 491       # Solaris 7 the name librt is preferred.
 492       AC_CHECK_FUNCS(sched_yield, , [
 493         AC_CHECK_LIB(rt, sched_yield, [
 494           AC_DEFINE(HAVE_SCHED_YIELD)
 495           THREADLIBS="$THREADLIBS -lrt"
 496           THREADSPEC="$THREADSPEC -lrt"], [
 497           AC_CHECK_LIB(posix4, sched_yield, [
 498             AC_DEFINE(HAVE_SCHED_YIELD)
 499             THREADLIBS="$THREADLIBS -lposix4"
 500             THREADSPEC="$THREADSPEC -lposix4"])])])
 501       LIBS="$save_LIBS"
 502
 503       # We can save a little space at runtime if the mutex has m_count
 504       # or __m_count.  This is a nice hack for Linux.
 505       AC_TRY_COMPILE([#include <pthread.h>], [
 506           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 507         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 508         AC_TRY_COMPILE([#include <pthread.h>], [
 509             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 510           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 511    fi
 512
 513    # We require a way to get the time.
 514    time_found=no
 515    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 516    if test "$time_found" = no; then
 517       AC_MSG_ERROR([no function found to get the time])
 518    fi
 519
 520    AC_CHECK_FUNCS(memmove)
 521
 522    # We require memcpy.
 523    memcpy_found=no
 524    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 525    if test "$memcpy_found" = no; then
 526       AC_MSG_ERROR([memcpy is required])
 527    fi
 528
 529    # Some library-finding code we stole from Tcl.
 530    #--------------------------------------------------------------------
 531    #    Check for the existence of the -lsocket and -lnsl libraries.
 532    #    The order here is important, so that they end up in the right
 533    #    order in the command line generated by make.  Here are some
 534    #    special considerations:
 535    #    1. Use "connect" and "accept" to check for -lsocket, and
 536    #       "gethostbyname" to check for -lnsl.
 537    #    2. Use each function name only once:  can't redo a check because
 538    #       autoconf caches the results of the last check and won't redo it.
 539    #    3. Use -lnsl and -lsocket only if they supply procedures that
 540    #       aren't already present in the normal libraries.  This is because
 541    #       IRIX 5.2 has libraries, but they aren't needed and they're
 542    #       bogus:  they goof up name resolution if used.
 543    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 544    #       To get around this problem, check for both libraries together
 545    #       if -lsocket doesn't work by itself.
 546    #--------------------------------------------------------------------
 547
 548    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 549     [gcj_cv_lib_sockets=
 550      gcj_checkBoth=0
 551      unset ac_cv_func_connect
 552      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 553      if test "$gcj_checkSocket" = 1; then
 554          unset ac_cv_func_connect
 555          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 556                       gcj_checkBoth=1)
 557      fi
 558      if test "$gcj_checkBoth" = 1; then
 559          gcj_oldLibs=$LIBS
 560          LIBS="$LIBS -lsocket -lnsl"
 561          unset ac_cv_func_accept
 562          AC_CHECK_FUNC(accept,
 563                        [gcj_checkNsl=0
 564                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 565          unset ac_cv_func_accept
 566          LIBS=$gcj_oldLibs
 567      fi
 568      unset ac_cv_func_gethostbyname
 569      gcj_oldLibs=$LIBS
 570      LIBS="$LIBS $gcj_cv_lib_sockets"
 571      AC_CHECK_FUNC(gethostbyname, ,
 572                    [AC_CHECK_LIB(nsl, main,
 573                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 574      unset ac_cv_func_gethostbyname
 575      LIBS=$gcj_oldLIBS
 576    ])
 577    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 578
 579    if test "$with_system_zlib" = yes; then
 580       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 581    else
 582       ZLIBSPEC=-lzgcj
 583       ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 584    fi
 585
 586    # On Solaris, and maybe other architectures, the Boehm collector
 587    # requires -ldl.
 588    if test "$GC" = boehm; then
 589       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 590    fi
 591
 592    if test -z "${with_multisubdir}"; then
 593       builddotdot=.
 594    else
 595 changequote(<<,>>)
 596       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 597 changequote([,])
 598    fi
 599    if test -x "${builddotdot}/../../gcc/gcj"; then
 600       dir="`cd ${builddotdot}/../../gcc && pwd`"
 601       GCJ="$dir/gcj -B`pwd`/ -B$dir/"
 602    else
 603       CANADIAN=yes
 604       NULL_TARGET=yes
 605       GCJ="gcj -B`pwd`/"
 606    fi
 607 fi
 608
 609 # Create it, so that compile/link tests don't fail
 610 test -f libgcj.spec || touch libgcj.spec
 611
 612 # We must search the source tree for java.lang, since we still don't
 613 # have libgcj.jar nor java/lang/*.class
 614 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
 615 CPPFLAGS="$CPPFLAGS -I`pwd` -I`cd $srcdir && pwd`"
 616
 617 # Since some classes depend on this one, we need its source available
 618 # before we can do any GCJ compilation test :-(
 619 if test ! -f gnu/classpath/Configuration.java; then
 620   test -d gnu || mkdir gnu
 621   test -d gnu/classpath || mkdir gnu/classpath
 622   sed 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
 623         < $srcdir/gnu/classpath/Configuration.java.in \
 624         > gnu/classpath/Configuration.java
 625   # We do not want to redirect the output of the grep below to /dev/null,
 626   # but we add /dev/null to the input list so that grep will print the
 627   # filename of Configuration.java in case it finds any matches.
 628   if grep @ gnu/classpath/Configuration.java /dev/null; then
 629     AC_MSG_ERROR([configure.in is missing the substitutions above])
 630   fi
 631 fi
 632
 633 LT_AC_PROG_GCJ
 634
 635 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
 636
 637 dnl FIXME: cross compilation
 638 AC_CHECK_SIZEOF(void *)
 639
 640 ZLIBS=
 641 ZDEPS=
 642 ZINCS=
 643 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 644    # We include the path to the zlib build directory.
 645    # See Makefile.am to understand why.
 646    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 647    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 648    ZINCS='-I$(top_srcdir)/../zlib'
 649 else
 650    ZLIBS="$ZLIBSPEC"
 651 fi
 652 AC_SUBST(ZLIBS)
 653 AC_SUBST(ZDEPS)
 654 AC_SUBST(ZINCS)
 655 AC_SUBST(DIVIDESPEC)
 656 AC_SUBST(EXCEPTIONSPEC)
 657
 658 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 659 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 660 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 661 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 662 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 663 AC_SUBST(GCC_UNWIND_INCLUDE)
 664
 665 # Determine gcj version number.
 666 changequote(<<,>>)
 667 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 668 changequote([,])
 669 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 670 AC_SUBST(GCJVERSION)
 671
 672 AC_SUBST(AM_RUNTESTFLAGS)
 673
 674 dnl Work around a g++ bug.  Reported to gcc-bugs@gcc.gnu.org on Jan 22, 2000.
 675 AC_MSG_CHECKING([for g++ -ffloat-store bug])
 676 save_CFLAGS="$CFLAGS"
 677 CFLAGS="-x c++ -O2 -ffloat-store"
 678 AC_TRY_COMPILE([#include <math.h>], ,
 679   [AC_MSG_RESULT(no)],
 680   [AC_DEFINE(__NO_MATH_INLINES)
 681    AC_MSG_RESULT(yes)])
 682 CFLAGS="$save_CFLAGS"
 683
 684 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 685 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 686 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 687 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h langinfo.h locale.h)
 688 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 689 dnl for now.  If you change this, you also must update natFile.cc.
 690 AC_CHECK_HEADERS(dirent.h)
 691
 692 AC_CHECK_TYPE([ssize_t], [int])
 693
 694 AC_MSG_CHECKING([for in_addr_t])
 695 AC_TRY_COMPILE([#include <sys/types.h>
 696 #if STDC_HEADERS
 697 #include <stdlib.h>
 698 #include <stddef.h>
 699 #endif
 700 #if HAVE_NETINET_IN_H
 701 #include <netinet/in.h>
 702 #endif], [in_addr_t foo;],
 703   [AC_DEFINE([HAVE_IN_ADDR_T])
 704    AC_MSG_RESULT(yes)],
 705   [AC_MSG_RESULT(no)])
 706
 707 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 708 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 709   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 710    AC_MSG_RESULT(yes)],
 711   [AC_MSG_RESULT(no)])
 712
 713 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 714 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 715   [AC_DEFINE(HAVE_INET6)
 716    AC_MSG_RESULT(yes)],
 717   [AC_MSG_RESULT(no)])
 718
 719 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 720 AC_TRY_COMPILE([#include <sys/types.h>
 721 #include <sys/socket.h>], [socklen_t x = 5;],
 722   [AC_DEFINE(HAVE_SOCKLEN_T)
 723    AC_MSG_RESULT(yes)],
 724   [AC_MSG_RESULT(no)])
 725
 726 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 727 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 728   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 729    AC_MSG_RESULT(yes)],
 730   [AC_MSG_RESULT(no)
 731    AC_MSG_CHECKING([for global timezone variable])
 732    dnl FIXME: we don't want a link check here because that won't work
 733    dnl when cross-compiling.  So instead we make an assumption that
 734    dnl the header file will mention timezone if it exists.
 735    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 736      [AC_DEFINE(HAVE_TIMEZONE)
 737       AC_MSG_RESULT(yes)],
 738      [AC_MSG_RESULT(no)])])
 739
 740 AC_FUNC_ALLOCA
 741
 742 AC_CHECK_PROGS(PERL, perl, false)
 743
 744 SYSDEP_SOURCES=
 745
 746 case "${host}" in
 747  i?86-*-linux*)
 748     SIGNAL_HANDLER=include/i386-signal.h
 749     ;;
 750  sparc-sun-solaris*)
 751     SIGNAL_HANDLER=include/sparc-signal.h
 752     ;;
 753 # ia64-*)
 754 #    SYSDEP_SOURCES=sysdep/ia64.c
 755 #    test -d sysdep || mkdir sysdep
 756 #    ;;
 757  powerpc-*-linux*)
 758     SIGNAL_HANDLER=include/dwarf2-signal.h
 759     ;;
 760  alpha*-*-linux*)
 761     SIGNAL_HANDLER=include/dwarf2-signal.h
 762     ;;
 763  *)
 764     SIGNAL_HANDLER=include/default-signal.h
 765     ;;
 766 esac
 767
 768 # If we're using sjlj exceptions, forget what we just learned.
 769 if test "$enable_sjlj_exceptions" = yes; then
 770    SIGNAL_HANDLER=include/default-signal.h
 771 fi
 772
 773 AC_SUBST(SYSDEP_SOURCES)
 774
 775 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 776
 777 if test "${multilib}" = "yes"; then
 778   multilib_arg="--enable-multilib"
 779 else
 780   multilib_arg=
 781 fi
 782
 783 AC_PATH_XTRA
 784
 785 dnl Determine which AWT peer libraries to build
 786 AC_ARG_ENABLE(java-awt,
 787 [  --enable-java-awt       list of AWT peer implementations to be built])
 788
 789 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 790 use_xlib_awt=""
 791 use_gtk_awt=""
 792
 793 for peer in $peerlibs ; do
 794   case $peer in
 795     xlib)
 796       if [test "$no_x" = yes]; then
 797         echo "*** xlib peers requested but no X library available" 1>&2
 798         exit 1
 799       else
 800         use_xlib_awt="yes"
 801       fi
 802       ;;
 803     gtk)
 804       # Nothing, yet...
 805       ;;
 806     *)
 807       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 808       exit 1
 809   esac
 810 done
 811
 812 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 813 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 814
 815
 816 here=`pwd`
 817 AC_SUBST(here)
 818
 819 # We get this from the environment.
 820 AC_SUBST(GCJFLAGS)
 821
 822 AC_OUTPUT(Makefile libgcj.spec libgcj-test.spec gnu/classpath/Configuration.java gcj/Makefile include/Makefile testsuite/Makefile,
 823 [if test -n "$CONFIG_FILES"; then
 824   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 825 fi
 826
 827 # Make subdirectories and `.d' files.  Look in both srcdir and
 828 # builddir for the .java files.
 829 h=`pwd`
 830 : > deps.mk
 831 ( (cd $srcdir && find . -name '*.java' -print) ;
 832   find . -name '*.java' -print) | \
 833    fgrep -v testsuite | \
 834    sed -e 's/\.java/.d/' | \
 835    while read f; do
 836       echo "include $f" >> deps.mk
 837       test -f $f || {
 838 changequote(<<,>>)
 839          d=`echo $f | sed -e 's,/[^/]*$,,'`
 840 changequote([,])
 841          $srcdir/../mkinstalldirs $d
 842          echo > $f
 843       }
 844    done
 845 ],
 846 srcdir=${srcdir}
 847 host=${host}
 848 target=${target}
 849 with_multisubdir=${with_multisubdir}
 850 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 851 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 852 libgcj_basedir=${libgcj_basedir}
 853 CC="${CC}"
 854 CXX="${CXX}"
 855 )