libmudflap/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I .. -I ../config && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.64)
   5 AC_INIT(libmudflap, 1.0)
   6 AC_CONFIG_SRCDIR(mf-runtime.c)
   7 AC_CANONICAL_SYSTEM
   8 ACX_NONCANONICAL_TARGET
   9
  10 AM_INIT_AUTOMAKE([no-dist])
  11
  12 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  13 AC_ARG_ENABLE(version-specific-runtime-libs,
  14 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  15 [case "$enableval" in
  16  yes) version_specific_libs=yes ;;
  17  no)  version_specific_libs=no ;;
  18  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  19  esac],
  20 [version_specific_libs=no])
  21 AC_MSG_RESULT($version_specific_libs)
  22
  23 AM_MAINTAINER_MODE
  24 AC_EXEEXT
  25
  26 AM_ENABLE_MULTILIB(, ..)
  27
  28 target_alias=${target_alias-$host_alias}
  29 AC_SUBST(target_alias)
  30
  31 AC_CONFIG_HEADERS(config.h)
  32
  33 AC_LANG_C
  34 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  35 # We must force CC to /not/ be precious variables; otherwise
  36 # the wrong, non-multilib-adjusted value will be used in multilibs.
  37 # As a side effect, we have to subst CFLAGS ourselves.
  38
  39 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  40 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  41 AC_PROG_CC
  42 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  43
  44 AC_SUBST(CFLAGS)
  45
  46 if test "x$GCC" != "xyes"; then
  47   AC_MSG_ERROR([libmudflap must be built with GCC])
  48 fi
  49 AC_PROG_CPP
  50
  51 # Some hosts don't have dlsym(RTLD_NEXT, "symbol") for use in
  52 # symbol interposition.  We disable shared libraries for these.
  53 AC_MSG_CHECKING([whether dlsym(RTLD_NEXT,...) is available])
  54 AC_TRY_COMPILE([
  55 #define _GNU_SOURCE
  56 #include <dlfcn.h>
  57 ],
  58 [void *foo = dlsym (RTLD_NEXT, "exit");],
  59 [AC_MSG_RESULT(yes)],
  60 [AC_MSG_RESULT(no)
  61 enable_shared=no])
  62
  63 AC_CHECK_HEADERS(stdint.h execinfo.h signal.h dlfcn.h dirent.h pwd.h grp.h \
  64   netdb.h sys/ipc.h sys/sem.h sys/shm.h sys/wait.h ctype.h mntent.h \
  65   sys/mnttab.h sys/socket.h netinet/in.h arpa/inet.h dlfcn.h sys/mman.h)
  66
  67 AC_CHECK_FUNCS(backtrace backtrace_symbols gettimeofday signal)
  68 AC_CHECK_FUNCS(fopen64 fseeko64 ftello64 stat64 freopen64)
  69 AC_CHECK_FUNCS(setbuf setbuffer setlinebuf setvbuf)
  70 AC_CHECK_FUNCS(strnlen memrchr strncpy memmem sethostname)
  71 AC_CHECK_FUNCS(__ctype_b_loc __ctype_tolower_loc __ctype_toupper_loc)
  72 AC_CHECK_FUNCS(getlogin cuserid getpwnam getpwuid getpwent getgrnam getgrgid getgrent)
  73 AC_CHECK_FUNCS(getlogin_r getpwnam_r getpwuid_r getgrnam_r getgrgid_r)
  74 AC_CHECK_FUNCS(getservent getservbyname getservbyport getaddrinfo gai_strerror)
  75 AC_CHECK_FUNCS(getprotoent getprotobyname getprotobynumber)
  76 AC_CHECK_FUNCS(getmntent setmntent addmntent)
  77 AC_CHECK_FUNCS(inet_ntoa mmap munmap)
  78 AC_CHECK_FUNCS(mmap64)
  79 AC_CHECK_FUNCS(__libc_freeres)
  80 AC_CHECK_FUNCS(rawmemchr stpcpy mempcpy)
  81
  82 AC_TRY_COMPILE([#include <sys/types.h>
  83 #include <sys/ipc.h>
  84 #include <sys/sem.h>],[union semun foo;], [mf_have_semun=1], [mf_have_semun=0])
  85 if test $mf_have_semun = 1
  86 then
  87   AC_DEFINE(HAVE_UNION_SEMUN, 1, [union semun defined in sys/ipc.h or sys/sem.h])
  88 fi
  89
  90
  91 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
  92 AC_TRY_COMPILE([#define _POSIX_PII_SOCKET
  93 #include <sys/types.h>
  94 #include <sys/socket.h>], [socklen_t x = 5;],
  95   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
  96    AC_MSG_RESULT(yes)],
  97   [AC_MSG_RESULT(no)])
  98
  99 AC_LIBTOOL_DLOPEN
 100 AM_PROG_LIBTOOL
 101 AC_SUBST(enable_shared)
 102 AC_SUBST(enable_static)
 103
 104 AC_CHECK_HEADER(stdint.h, [MF_HAVE_STDINT_H=1], [MF_HAVE_STDINT_H=0])
 105 AC_SUBST(MF_HAVE_STDINT_H)
 106 if test $MF_HAVE_STDINT_H = 1
 107 then
 108    MF_HAVE_UINTPTR_T=1
 109 else
 110    AC_TRY_COMPILE([#include <sys/types.h>], [uintptr_t k = 0;],
 111         [MF_HAVE_UINTPTR_T=1], [MF_HAVE_UINTPTR_T=0])
 112 fi
 113 AC_SUBST(MF_HAVE_UINTPTR_T)
 114
 115 if test ! -d pth
 116 then
 117   # libmudflapth objects are built in this subdirectory
 118   mkdir pth
 119 fi
 120
 121 AC_CHECK_HEADERS(pthread.h)
 122
 123 AC_MSG_CHECKING([for thread model used by GCC])
 124 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 125 AC_MSG_RESULT([$target_thread_file])
 126
 127 # We only support posix threads, or no threads at all.
 128 posix_threads=
 129 case ${target_thread_file} in
 130   posix)
 131     posix_threads=yes
 132     ;;
 133   single)
 134     ;;
 135   *)
 136     echo "${target_thread_file} is an unsupported thread package" 1>&2
 137     exit 1
 138     ;;
 139 esac
 140
 141 AM_CONDITIONAL(LIBMUDFLAPTH, [test "x$posix_threads" != "x"])
 142 if test "x$posix_threads" != "x"
 143 then
 144         build_libmudflapth=1
 145 else
 146         build_libmudflapth=0
 147 fi
 148 AC_SUBST(build_libmudflapth)
 149
 150 AC_CHECK_LIB(dl, dlsym)
 151
 152 AC_CHECK_FUNC(connect,, AC_CHECK_LIB(socket, connect))
 153
 154 # Calculate toolexeclibdir
 155 # Also toolexecdir, though it's only used in toolexeclibdir
 156 case ${version_specific_libs} in
 157   yes)
 158     # Need the gcc compiler version to know where to install libraries
 159     # and header files if --enable-version-specific-runtime-libs option
 160     # is selected.
 161     toolexecdir='$(libdir)/gcc/$(target_alias)'
 162     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 163     ;;
 164   no)
 165     if test -n "$with_cross_host" &&
 166        test x"$with_cross_host" != x"no"; then
 167       # Install a library built with a cross compiler in tooldir, not libdir.
 168       toolexecdir='$(exec_prefix)/$(target_alias)'
 169       toolexeclibdir='$(toolexecdir)/lib'
 170     else
 171       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 172       toolexeclibdir='$(libdir)'
 173     fi
 174     multi_os_directory=`$CC -print-multi-os-directory`
 175     case $multi_os_directory in
 176       .) ;; # Avoid trailing /.
 177       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 178     esac
 179     ;;
 180 esac
 181 AC_SUBST(toolexecdir)
 182 AC_SUBST(toolexeclibdir)
 183
 184 includedir=${toolexecdir}/include
 185 AC_SUBST(includedir)
 186
 187 pthread_create_version='""'
 188 if test "x$enable_shared" = "xyes" && test "x$posix_threads" != "x"; then
 189   # NB: don't check for -lpthread here, because then it would be
 190   # added to LIBS.  For the thread-unaware libmudflap.la, we don't
 191   # want it there.
 192
 193   # glibc-related hacks.  dlsym() may pick the wrong version of
 194   # interposed functions like pthread_create on modern glibc.
 195   # We need to find the proper symbol version string, and use
 196   # the nonstandard dlvsym().
 197   AC_CHECK_FUNCS(dlvsym)
 198   AC_CHECK_TOOL(NM, nm)
 199   if test "x$ac_cv_have_dlvsym" != "x"; then
 200     # Try compiling a simple pthreads program.  Find the shared libraries it
 201     # ends up with.  Then use "nm" on those libraries to extract the
 202     # default symbol versioning suffix ("@@"), if any.  But that's tricky.
 203     # Rather, run nm on the resulting executable.  Unfortunately, autoconf
 204     # doesn't appear to have a macro that builds a test executable for
 205     # subsequent analysis ... so we do it by hand here.
 206     cat >> conftest.c << EOF
 207 #include <pthread.h>
 208 int main () { void *p = (void *) & pthread_create; return (int) p; }
 209 EOF
 210     oldLIBS="$LIBS"
 211     LIBS="$LIBS -lpthread"
 212     pthread_create_version="\"\""
 213     AC_MSG_CHECKING(pthread_create symbol version)
 214     if eval $ac_link 2>&5 && test -s conftest${ac_exeext}; then
 215       version=`$NM conftest${ac_exeect} | grep 'pthread_create@@' | sed -e 's/^.*@@//'`
 216       if test "x$version" != "x"; then
 217         pthread_create_version="\"$version\""
 218       fi
 219     fi
 220     AC_MSG_RESULT($pthread_create_version)
 221     LIBS="$oldLIBS"
 222   fi
 223 fi
 224 AC_DEFINE_UNQUOTED(PTHREAD_CREATE_VERSION, $pthread_create_version, [pthread_create symbol version])
 225
 226
 227 # Figure out whether the compiler supports "-ffunction-sections -fdata-sections",
 228 # similarly to how libstdc++ does it
 229 ac_test_CFLAGS="${CFLAGS+set}"
 230 ac_save_CFLAGS="$CFLAGS"
 231
 232 # Check for -ffunction-sections -fdata-sections
 233 AC_MSG_CHECKING([for gcc that supports -ffunction-sections -fdata-sections])
 234 CFLAGS='-Werror -ffunction-sections -fdata-sections'
 235 AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 236 if test "$ac_test_CFLAGS" = set; then
 237   CFLAGS="$ac_save_CFLAGS"
 238 else
 239   # this is the suspicious part
 240   CFLAGS=""
 241 fi
 242 if test x"$ac_fdsections" = x"yes"; then
 243   SECTION_FLAGS='-ffunction-sections -fdata-sections'
 244 fi
 245 AC_MSG_RESULT($ac_fdsections)
 246 AC_SUBST(SECTION_FLAGS)
 247
 248
 249 # Check for the name of the symbol used for the entry point.
 250 AC_CACHE_CHECK([for the name of the symbol used for the entry point],
 251   [mudflap_cv_entry_point], [
 252 for name in _start __start unknown; do
 253   AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char $name@<:@@:>@;], [$name@<:@0@:>@ = 0;])],
 254                  [break])
 255 done
 256 mudflap_cv_entry_point="$name"])
 257 if test "$mudflap_cv_entry_point" = unknown; then
 258   AC_MSG_ERROR([none of the known symbol names works])
 259 fi
 260 AC_DEFINE_UNQUOTED([ENTRY_POINT], [$mudflap_cv_entry_point],
 261   [Define to the name of the symbol used for the entry point.])
 262
 263
 264 if test ${multilib} = yes; then
 265   multilib_arg="--enable-multilib"
 266 else
 267   multilib_arg=
 268 fi
 269
 270 # See if we support thread-local storage.
 271 GCC_CHECK_TLS
 272 GCC_CHECK_EMUTLS
 273
 274 AC_CONFIG_FILES([Makefile testsuite/Makefile testsuite/mfconfig.exp])
 275 AC_OUTPUT