libobjc/configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright 1994, 1995, 1996, 1997, 1998, 1999, 2001, 2002, 2003, 2004
   3 #   2005, 2006, 2009, 2011, 2012 Free Software Foundation, Inc.
   4 #   Originally contributed by Dave Love (d.love@dl.ac.uk).
   5 #
   6 #This file is part of GCC.
   7 #
   8 #GCC is free software; you can redistribute it and/or modify
   9 #it under the terms of the GNU General Public License as published by
  10 #the Free Software Foundation; either version 3, or (at your option)
  11 #any later version.
  12 #
  13 #GCC is distributed in the hope that it will be useful,
  14 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #GNU General Public License for more details.
  17 #
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING3.  If not see
  20 #<http://www.gnu.org/licenses/>.
  21
  22 AC_PREREQ(2.64)
  23 AC_INIT(package-unused, version-unused,, libobjc)
  24 AC_CONFIG_SRCDIR([objc/objc.h])
  25 GCC_TOPLEV_SUBDIRS
  26
  27 # We need the following definitions because AC_PROG_LIBTOOL relies on them
  28 PACKAGE=libobjc
  29 # Version is pulled out to make it a bit easier to change using sed.
  30 VERSION=4:0:0
  31 AC_SUBST(VERSION)
  32
  33 # This works around the fact that libtool configuration may change LD
  34 # for this particular configuration, but some shells, instead of
  35 # keeping the changes in LD private, export them just because LD is
  36 # exported.
  37 ORIGINAL_LD_FOR_MULTILIBS=$LD
  38
  39 # -------
  40 # Options
  41 # -------
  42
  43 # We use these options to decide which functions to include.
  44 AC_ARG_WITH(target-subdir,
  45 [  --with-target-subdir=SUBDIR
  46                            configuring in a subdirectory])
  47 AC_ARG_WITH(cross-host,
  48 [  --with-cross-host=HOST  configuring with a cross compiler])
  49
  50 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  51 AC_ARG_ENABLE(version-specific-runtime-libs,
  52 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  53 [case "$enableval" in
  54  yes) version_specific_libs=yes ;;
  55  no)  version_specific_libs=no ;;
  56  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  57  esac],
  58 [version_specific_libs=no])
  59 AC_MSG_RESULT($version_specific_libs)
  60
  61 AC_ARG_ENABLE(objc-gc,
  62 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
  63                           the GNU Objective-C runtime.],
  64 [case $enable_objc_gc in
  65   no)
  66     OBJC_GCFLAGS=''
  67     OBJC_BOEHM_GC=''
  68     OBJC_BOEHM_GC_INCLUDES=''
  69     ;;
  70   *)
  71     OBJC_GCFLAGS='-DOBJC_WITH_GC=1'
  72     OBJC_BOEHM_GC='libobjc_gc$(libsuffix).la'
  73     OBJC_BOEHM_GC_INCLUDES='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
  74     ;;
  75 esac],
  76 [OBJC_GCFLAGS=''; OBJC_BOEHM_GC=''; OBJC_BOEHM_GC_INCLUDES=''])
  77 AC_SUBST(OBJC_GCFLAGS)
  78 AC_SUBST(OBJC_BOEHM_GC)
  79 AC_SUBST(OBJC_BOEHM_GC_INCLUDES)
  80
  81 # -----------
  82 # Directories
  83 # -----------
  84
  85 # Find the rest of the source tree framework.
  86 AM_ENABLE_MULTILIB(, ..)
  87
  88 AC_CANONICAL_SYSTEM
  89 ACX_NONCANONICAL_TARGET
  90
  91 # Export source directory.
  92 # These need to be absolute paths, yet at the same time need to
  93 # canonicalize only relative paths, because then amd will not unmount
  94 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  95 case $srcdir in
  96   [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
  97   *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  98 esac
  99 AC_SUBST(glibcpp_srcdir)
 100
 101 # Calculate toolexeclibdir
 102 # Also toolexecdir, though it's only used in toolexeclibdir
 103 case ${version_specific_libs} in
 104   yes)
 105     # Need the gcc compiler version to know where to install libraries
 106     # and header files if --enable-version-specific-runtime-libs option
 107     # is selected.
 108     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 109     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 110     ;;
 111   no)
 112     if test -n "$with_cross_host" &&
 113        test x"$with_cross_host" != x"no"; then
 114       # Install a library built with a cross compiler in tooldir, not libdir.
 115       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 116       toolexeclibdir='$(toolexecdir)/lib'
 117     else
 118       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 119       toolexeclibdir='$(libdir)'
 120     fi
 121     multi_os_directory=`$CC -print-multi-os-directory`
 122     case $multi_os_directory in
 123       .) ;; # Avoid trailing /.
 124       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 125     esac
 126     ;;
 127 esac
 128 AC_SUBST(toolexecdir)
 129 AC_SUBST(toolexeclibdir)
 130
 131 # Figure out if we want to name the include directory and the
 132 #  library name changes differently.
 133 includedirname=include
 134 libsuffix=
 135 case "${host}" in
 136   *-darwin*)
 137     # Darwin is the only target so far that needs a different include directory.
 138     includedirname=include-gnu-runtime
 139     libsuffix=-gnu
 140     ;;
 141 esac
 142 AC_SUBST(includedirname)
 143 AC_SUBST(libsuffix)
 144
 145 AC_CONFIG_HEADERS(config.h)
 146
 147 # --------
 148 # Programs
 149 # --------
 150
 151 GCC_NO_EXECUTABLES
 152
 153 # We must force CC to /not/ be a precious variable; otherwise
 154 # the wrong, non-multilib-adjusted value will be used in multilibs.
 155 # As a side effect, we have to subst CFLAGS ourselves.
 156 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 157 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 158 AC_PROG_CC
 159 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 160
 161 # extra LD Flags which are required for targets
 162 ACX_LT_HOST_FLAGS
 163 case "${host}" in
 164   *-darwin*)
 165     # Darwin needs -single_module when linking libobjc
 166     extra_ldflags_libobjc='$(lt_host_flags) -Wl,-single_module'
 167     ;;
 168   *-cygwin*|*-mingw*)
 169     # Tell libtool to build DLLs on Windows
 170     extra_ldflags_libobjc='$(lt_host_flags)'
 171     ;;
 172 esac
 173 AC_SUBST(extra_ldflags_libobjc)
 174
 175 AC_SUBST(CFLAGS)
 176
 177 AC_CHECK_TOOL(AS, as)
 178 AC_CHECK_TOOL(AR, ar)
 179 AC_CHECK_TOOL(RANLIB, ranlib, :)
 180 AC_PROG_INSTALL
 181
 182 AM_MAINTAINER_MODE
 183
 184 # Enable Win32 DLL on MS Windows - FIXME
 185 AC_LIBTOOL_WIN32_DLL
 186
 187 AC_PROG_LIBTOOL
 188
 189 AM_PROG_CC_C_O
 190
 191 AC_PROG_MAKE_SET
 192
 193 # -------
 194 # Headers
 195 # -------
 196
 197 # Sanity check for the cross-compilation case:
 198 AC_CHECK_HEADER(stdio.h,:,
 199   [AC_MSG_ERROR([Can't find stdio.h.
 200 You must have a usable C system for the target already installed, at least
 201 including headers and, preferably, the library, before you can configure
 202 the Objective C runtime system.  If necessary, install gcc now with
 203 \`LANGUAGES=c', then the target library, then build with \`LANGUAGES=objc'.])])
 204
 205 AC_HEADER_STDC
 206
 207 AC_CHECK_HEADERS(sched.h)
 208
 209 # -----------
 210 # Miscellanea
 211 # -----------
 212
 213 # Check if we have thread-local storage
 214 GCC_CHECK_TLS
 215
 216 AC_MSG_CHECKING([for exception model to use])
 217 AC_LANG_PUSH(C)
 218 AC_ARG_ENABLE(sjlj-exceptions,
 219   AS_HELP_STRING([--enable-sjlj-exceptions],
 220                  [force use of builtin_setjmp for exceptions]),
 221 [:],
 222 [dnl Botheration.  Now we've got to detect the exception model.
 223 dnl Link tests against libgcc.a are problematic since -- at least
 224 dnl as of this writing -- we've not been given proper -L bits for
 225 dnl single-tree newlib and libgloss.
 226 dnl
 227 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 228 dnl conftest files before we got a change to grep them first.
 229 cat > conftest.$ac_ext << EOF
 230 [#]line __oline__ "configure"
 231 @interface Frob
 232 @end
 233 @implementation Frob
 234 @end
 235 int proc();
 236 int foo()
 237 {
 238   @try {
 239    return proc();
 240   }
 241   @catch (Frob* ex) {
 242     return 0;
 243   }
 244 }
 245 EOF
 246 old_CFLAGS="$CFLAGS"
 247 dnl work around that we don't have Objective-C support in autoconf
 248 CFLAGS="-x objective-c -fgnu-runtime -fobjc-exceptions -S"
 249 if AC_TRY_EVAL(ac_compile); then
 250   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 251     enable_sjlj_exceptions=yes
 252   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 253     enable_sjlj_exceptions=no
 254   fi
 255 fi
 256 CFLAGS="$old_CFLAGS"
 257 rm -f conftest*])
 258 if test x$enable_sjlj_exceptions = xyes; then
 259   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 260         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 261   ac_exception_model_name=sjlj
 262 elif test x$enable_sjlj_exceptions = xno; then
 263   ac_exception_model_name="call frame"
 264 else
 265   AC_MSG_ERROR([unable to detect exception model])
 266 fi
 267 AC_LANG_POP(C)
 268 AC_MSG_RESULT($ac_exception_model_name)
 269
 270 # ------
 271 # Output
 272 # ------
 273
 274 if test ${multilib} = yes; then
 275   multilib_arg="--enable-multilib"
 276 else
 277   multilib_arg=
 278 fi
 279
 280 AC_CONFIG_FILES([Makefile])
 281 AC_OUTPUT