libquadmath/acinclude.m4

   1 dnl ----------------------------------------------------------------------
   2 dnl This whole bit snagged from libgfortran.
   3
   4 sinclude(../libtool.m4)
   5 dnl The lines below arrange for aclocal not to bring an installed
   6 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
   7 dnl add a definition of LIBTOOL to Makefile.in.
   8 ifelse(,,,[AC_SUBST(LIBTOOL)
   9 AC_DEFUN([AM_PROG_LIBTOOL])
  10 AC_DEFUN([AC_LIBTOOL_DLOPEN])
  11 AC_DEFUN([AC_PROG_LD])
  12 ])
  13
  14 dnl Check whether POSIX's signgam is defined in math.h.
  15 AC_DEFUN([LIBQUAD_CHECK_MATH_H_SIGNGAM], [
  16   AC_CACHE_CHECK([whether the math.h includes POSIX's signgam],
  17                  libgfor_cv_have_math_h_signgam, [
  18   save_CFLAGS="$CFLAGS"
  19   CFLAGS="$CFLAGS -Werror"
  20   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  21 #include <math.h>
  22 void foo(void) { signgam = 1; }]], [])],
  23                     libgfor_cv_have_math_h_signgam=yes,
  24                     libgfor_cv_have_math_h_signgam=no)
  25   CFLAGS="$save_CFLAGS"])
  26   if test $libgfor_cv_have_math_h_signgam = yes; then
  27     AC_DEFINE(HAVE_MATH_H_SIGNGAM, 1,
  28       [Define to 1 if the math.h includes POSIX's signgam.])
  29   fi])