libsanitizer/configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.64])
   5 AC_INIT(package-unused, version-unused, libsanitizer)
   6 AC_CONFIG_SRCDIR([include/sanitizer/common_interface_defs.h])
   7
   8 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
   9 AC_ARG_ENABLE(version-specific-runtime-libs,
  10 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  11 [case "$enableval" in
  12  yes) version_specific_libs=yes ;;
  13  no)  version_specific_libs=no ;;
  14  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  15  esac],
  16 [version_specific_libs=no])
  17 AC_MSG_RESULT($version_specific_libs)
  18
  19 # Do not delete or change the following two lines.  For why, see
  20 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  21 AC_CANONICAL_SYSTEM
  22 target_alias=${target_alias-$host_alias}
  23 AC_SUBST(target_alias)
  24
  25 AM_INIT_AUTOMAKE(foreign)
  26 AM_ENABLE_MULTILIB(, ..)
  27
  28 # Calculate toolexeclibdir
  29 # Also toolexecdir, though it's only used in toolexeclibdir
  30 case ${version_specific_libs} in
  31   yes)
  32     # Need the gcc compiler version to know where to install libraries
  33     # and header files if --enable-version-specific-runtime-libs option
  34     # is selected.
  35     toolexecdir='$(libdir)/gcc/$(target_alias)'
  36     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  37     ;;
  38   no)
  39     if test -n "$with_cross_host" &&
  40        test x"$with_cross_host" != x"no"; then
  41       # Install a library built with a cross compiler in tooldir, not libdir.
  42       toolexecdir='$(exec_prefix)/$(target_alias)'
  43       toolexeclibdir='$(toolexecdir)/lib'
  44     else
  45       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  46       toolexeclibdir='$(libdir)'
  47     fi
  48     multi_os_directory=`$CC -print-multi-os-directory`
  49     case $multi_os_directory in
  50       .) ;; # Avoid trailing /.
  51       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  52     esac
  53     ;;
  54 esac
  55 AC_SUBST(toolexecdir)
  56 AC_SUBST(toolexeclibdir)
  57
  58 # Checks for programs.
  59 AC_PROG_CC
  60 AC_PROG_CXX
  61 AM_PROG_AS
  62
  63 AC_LIBTOOL_DLOPEN
  64 AM_PROG_LIBTOOL
  65
  66 AC_SUBST(enable_shared)
  67 AC_SUBST(enable_static)
  68
  69 if test "${multilib}" = "yes"; then
  70   multilib_arg="--enable-multilib"
  71 else
  72   multilib_arg=
  73 fi
  74
  75 AC_CONFIG_FILES([Makefile])
  76
  77 AC_CONFIG_FILES(AC_FOREACH([DIR], [interception sanitizer_common asan], [DIR/Makefile ]),
  78   [cat > vpsed$$ << \_EOF
  79 s!`test -f '$<' || echo '$(srcdir)/'`!!
  80 _EOF
  81    sed -f vpsed$$ $ac_file > tmp$$
  82    mv tmp$$ $ac_file
  83    rm vpsed$$
  84    echo 'MULTISUBDIR =' >> $ac_file
  85 ])
  86
  87 AC_OUTPUT