projects / gcc.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
pa64-hpux.h (FINI_SECTION_ASM_OP): Define to null string.
[gcc.git] / libstdc++-v3 / acinclude.m4
1 dnl
2 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
3 dnl
4 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
5 dnl end of configure. This lets tested variables be reassigned, and the
6 dnl conditional will depend on the final state of the variable. For a simple
7 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
8 dnl
9 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
10 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
11 m4_divert_text([glibcxx_diversion],dnl
12 AM_CONDITIONAL([$1],[$2])
13 )dnl
14 ])dnl
15 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
16
17
18 dnl
19 dnl Check to see what architecture and operating system we are compiling
20 dnl for. Also, if architecture- or OS-specific flags are required for
21 dnl compilation, pick them up here.
22 dnl
23 AC_DEFUN([GLIBCXX_CHECK_HOST], [
24 . $glibcxx_srcdir/configure.host
25 AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
26 AC_MSG_NOTICE([OS config directory is $os_include_dir])
27 ])
28
29 dnl
30 dnl Initialize the rest of the library configury. At this point we have
31 dnl variables like $host.
32 dnl
33 dnl Sets:
34 dnl SUBDIRS
35 dnl Substs:
36 dnl glibcxx_builddir (absolute path)
37 dnl glibcxx_srcdir (absolute path)
38 dnl toplevel_builddir (absolute path)
39 dnl toplevel_srcdir (absolute path)
40 dnl with_cross_host
41 dnl with_newlib
42 dnl with_target_subdir
43 dnl plus
44 dnl - the variables in GLIBCXX_CHECK_HOST / configure.host
45 dnl - default settings for all AM_CONFITIONAL test variables
46 dnl - lots of tools, like CC and CXX
47 dnl
48 AC_DEFUN([GLIBCXX_CONFIGURE], [
49 # Keep these sync'd with the list in Makefile.am. The first provides an
50 # expandable list at autoconf time; the second provides an expandable list
51 # (i.e., shell variable) at configure time.
52 m4_define([glibcxx_SUBDIRS],[include libsupc++ src src/c++98 src/c++11 src/filesystem doc po testsuite python])
53 SUBDIRS='glibcxx_SUBDIRS'
54
55 # These need to be absolute paths, yet at the same time need to
56 # canonicalize only relative paths, because then amd will not unmount
57 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
58 glibcxx_builddir=`${PWDCMD-pwd}`
59 case $srcdir in
60 [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
61 *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
62 esac
63 toplevel_builddir=${glibcxx_builddir}/..
64 toplevel_srcdir=${glibcxx_srcdir}/..
65 AC_SUBST(glibcxx_builddir)
66 AC_SUBST(glibcxx_srcdir)
67 AC_SUBST(toplevel_builddir)
68 AC_SUBST(toplevel_srcdir)
69
70 # We use these options to decide which functions to include. They are
71 # set from the top level.
72 AC_ARG_WITH([target-subdir],
73 AC_HELP_STRING([--with-target-subdir=SUBDIR],
74 [configuring in a subdirectory]))
75
76 AC_ARG_WITH([cross-host],
77 AC_HELP_STRING([--with-cross-host=HOST],
78 [configuring with a cross compiler]))
79
80 AC_ARG_WITH([newlib],
81 AC_HELP_STRING([--with-newlib],
82 [assume newlib as a system C library]))
83
84 # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
85 # available). Uncomment the next line to force a particular method.
86 AC_PROG_LN_S
87 #LN_S='cp -p'
88
89 AC_CHECK_TOOL(AS, as)
90 AC_CHECK_TOOL(AR, ar)
91 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
92
93 AM_MAINTAINER_MODE
94
95 # Set up safe default values for all subsequent AM_CONDITIONAL tests
96 # which are themselves conditionally expanded.
97 ## (Right now, this only matters for enable_wchar_t, but nothing prevents
98 ## other macros from doing the same. This should be automated.) -pme
99
100 # Check for C library flavor since GNU/Linux platforms use different
101 # configuration directories depending on the C library in use.
102 AC_EGREP_CPP([_using_uclibc], [
103 #include <stdio.h>
104 #if __UCLIBC__
105 _using_uclibc
106 #endif
107 ], uclibc=yes, uclibc=no)
108
109 AC_EGREP_CPP([_using_bionic], [
110 #include <stdio.h>
111 #if __BIONIC__
112 _using_bionic
113 #endif
114 ], bionic=yes, bionic=no)
115
116 # Find platform-specific directories containing configuration info.
117 # Also possibly modify flags used elsewhere, as needed by the platform.
118 GLIBCXX_CHECK_HOST
119 ])
120
121
122 dnl
123 dnl Tests for newer compiler features, or features that are present in newer
124 dnl compiler versions but not older compiler versions still in use, should
125 dnl be placed here.
126 dnl
127 dnl Defines:
128 dnl WERROR='-Werror' if requested and possible; g++'s that lack the
129 dnl new inlining code or the new system_header pragma will die on -Werror.
130 dnl Leave it out by default and use maint-mode to use it.
131 dnl SECTION_FLAGS='-ffunction-sections -fdata-sections' if
132 dnl compiler supports it and the user has not requested debug mode.
133 dnl
134 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
135 # All these tests are for C++; save the language and the compiler flags.
136 # The CXXFLAGS thing is suspicious, but based on similar bits previously
137 # found in GLIBCXX_CONFIGURE.
138 AC_LANG_SAVE
139 AC_LANG_CPLUSPLUS
140 ac_test_CXXFLAGS="${CXXFLAGS+set}"
141 ac_save_CXXFLAGS="$CXXFLAGS"
142
143 # Check for maintainer-mode bits.
144 if test x"$USE_MAINTAINER_MODE" = xno; then
145 WERROR=''
146 else
147 WERROR='-Werror'
148 fi
149
150 # Check for -ffunction-sections -fdata-sections
151 AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
152 CXXFLAGS='-g -Werror -ffunction-sections -fdata-sections'
153 AC_TRY_COMPILE([int foo; void bar() { };],, [ac_fdsections=yes], [ac_fdsections=no])
154 if test "$ac_test_CXXFLAGS" = set; then
155 CXXFLAGS="$ac_save_CXXFLAGS"
156 else
157 # this is the suspicious part
158 CXXFLAGS=''
159 fi
160 if test x"$ac_fdsections" = x"yes"; then
161 SECTION_FLAGS='-ffunction-sections -fdata-sections'
162 fi
163 AC_MSG_RESULT($ac_fdsections)
164
165 AC_LANG_RESTORE
166 AC_SUBST(WERROR)
167 AC_SUBST(SECTION_FLAGS)
168 ])
169
170
171 dnl
172 dnl Check if the assembler used supports disabling generation of hardware
173 dnl capabilities. This is only supported by Sun as at the moment.
174 dnl
175 dnl Defines:
176 dnl HWCAP_FLAGS='-Wa,-nH' if possible.
177 dnl
178 AC_DEFUN([GLIBCXX_CHECK_ASSEMBLER_HWCAP], [
179 test -z "$HWCAP_FLAGS" && HWCAP_FLAGS=''
180
181 # Restrict the test to Solaris, other assemblers (e.g. AIX as) have -nH
182 # with a different meaning.
183 case ${target_os} in
184 solaris2*)
185 ac_save_CFLAGS="$CFLAGS"
186 CFLAGS="$CFLAGS -Wa,-nH"
187
188 AC_MSG_CHECKING([for as that supports -Wa,-nH])
189 AC_TRY_COMPILE([], [return 0;], [ac_hwcap_flags=yes],[ac_hwcap_flags=no])
190 if test "$ac_hwcap_flags" = "yes"; then
191 HWCAP_FLAGS="-Wa,-nH $HWCAP_FLAGS"
192 fi
193 AC_MSG_RESULT($ac_hwcap_flags)
194
195 CFLAGS="$ac_save_CFLAGS"
196 ;;
197 esac
198
199 AC_SUBST(HWCAP_FLAGS)
200 ])
201
202
203 dnl
204 dnl If GNU ld is in use, check to see if tricky linker opts can be used. If
205 dnl the native linker is in use, all variables will be defined to something
206 dnl safe (like an empty string).
207 dnl
208 dnl Defines:
209 dnl SECTION_LDFLAGS='-Wl,--gc-sections' if possible
210 dnl OPT_LDFLAGS='-Wl,-O1' and '-z,relro' if possible
211 dnl LD (as a side effect of testing)
212 dnl Sets:
213 dnl with_gnu_ld
214 dnl glibcxx_ld_is_gold (set to "no" or "yes")
215 dnl glibcxx_gnu_ld_version (possibly)
216 dnl
217 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
218 dnl set glibcxx_gnu_ld_version to 12345. Zeros cause problems.
219 dnl
220 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
221 # If we're not using GNU ld, then there's no point in even trying these
222 # tests. Check for that first. We should have already tested for gld
223 # by now (in libtool), but require it now just to be safe...
224 test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
225 test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
226 AC_REQUIRE([AC_PROG_LD])
227 AC_REQUIRE([AC_PROG_AWK])
228
229 # The name set by libtool depends on the version of libtool. Shame on us
230 # for depending on an impl detail, but c'est la vie. Older versions used
231 # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
232 # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
233 # makes sense). We'll test with_gnu_ld everywhere else, so if that isn't
234 # set (hence we're using an older libtool), then set it.
235 if test x${with_gnu_ld+set} != xset; then
236 if test x${ac_cv_prog_gnu_ld+set} != xset; then
237 # We got through "ac_require(ac_prog_ld)" and still not set? Huh?
238 with_gnu_ld=no
239 else
240 with_gnu_ld=$ac_cv_prog_gnu_ld
241 fi
242 fi
243
244 # Start by getting the version number. I think the libtool test already
245 # does some of this, but throws away the result.
246 glibcxx_ld_is_gold=no
247 if test x"$with_gnu_ld" = x"yes"; then
248 AC_MSG_CHECKING([for ld version])
249 changequote(,)
250 if $LD --version 2>/dev/null | grep 'GNU gold' >/dev/null 2>&1; then
251 glibcxx_ld_is_gold=yes
252 fi
253 ldver=`$LD --version 2>/dev/null |
254 sed -e 's/GNU gold /GNU ld /;s/GNU ld version /GNU ld /;s/GNU ld ([^)]*) /GNU ld /;s/GNU ld \([0-9.][0-9.]*\).*/\1/; q'`
255 changequote([,])
256 glibcxx_gnu_ld_version=`echo $ldver | \
257 $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
258 AC_MSG_RESULT($glibcxx_gnu_ld_version)
259 fi
260
261 # Set --gc-sections.
262 glibcxx_have_gc_sections=no
263 if test "$glibcxx_ld_is_gold" = "yes"; then
264 if $LD --help 2>/dev/null | grep gc-sections >/dev/null 2>&1; then
265 glibcxx_have_gc_sections=yes
266 fi
267 else
268 glibcxx_gcsections_min_ld=21602
269 if test x"$with_gnu_ld" = x"yes" &&
270 test $glibcxx_gnu_ld_version -gt $glibcxx_gcsections_min_ld ; then
271 glibcxx_have_gc_sections=yes
272 fi
273 fi
274 if test "$glibcxx_have_gc_sections" = "yes"; then
275 # Sufficiently young GNU ld it is! Joy and bunny rabbits!
276 # NB: This flag only works reliably after 2.16.1. Configure tests
277 # for this are difficult, so hard wire a value that should work.
278
279 ac_test_CFLAGS="${CFLAGS+set}"
280 ac_save_CFLAGS="$CFLAGS"
281 CFLAGS='-Wl,--gc-sections'
282
283 # Check for -Wl,--gc-sections
284 AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
285 AC_TRY_LINK([ int one(void) { return 1; }
286 int two(void) { return 2; }
287 ], [ two(); ] , [ac_gcsections=yes], [ac_gcsections=no])
288 if test "$ac_gcsections" = "yes"; then
289 rm -f conftest.c
290 touch conftest.c
291 if $CC -c conftest.c; then
292 if $LD --gc-sections -o conftest conftest.o 2>&1 | \
293 grep "Warning: gc-sections option ignored" > /dev/null; then
294 ac_gcsections=no
295 fi
296 fi
297 rm -f conftest.c conftest.o conftest
298 fi
299 if test "$ac_gcsections" = "yes"; then
300 SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
301 fi
302 AC_MSG_RESULT($ac_gcsections)
303
304 if test "$ac_test_CFLAGS" = set; then
305 CFLAGS="$ac_save_CFLAGS"
306 else
307 # this is the suspicious part
308 CFLAGS=''
309 fi
310 fi
311
312 # Set -z,relro.
313 # Note this is only for shared objects.
314 ac_ld_relro=no
315 if test x"$with_gnu_ld" = x"yes"; then
316 AC_MSG_CHECKING([for ld that supports -Wl,-z,relro])
317 cxx_z_relo=`$LD -v --help 2>/dev/null | grep "z relro"`
318 if test -n "$cxx_z_relo"; then
319 OPT_LDFLAGS="-Wl,-z,relro"
320 ac_ld_relro=yes
321 fi
322 AC_MSG_RESULT($ac_ld_relro)
323 fi
324
325 # Set linker optimization flags.
326 if test x"$with_gnu_ld" = x"yes"; then
327 OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
328 fi
329
330 AC_SUBST(SECTION_LDFLAGS)
331 AC_SUBST(OPT_LDFLAGS)
332 ])
333
334
335 dnl
336 dnl Check for headers for, and arguments to, the setrlimit() function.
337 dnl Used only in testsuite_hooks.h. Called from GLIBCXX_CONFIGURE_TESTSUITE.
338 dnl
339 dnl Defines:
340 dnl _GLIBCXX_RES_LIMITS if we can set artificial resource limits
341 dnl various HAVE_LIMIT_* for individual limit names
342 dnl
343 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
344 AC_MSG_CHECKING([for RLIMIT_$1])
345 AC_TRY_COMPILE(
346 [#include <unistd.h>
347 #include <sys/time.h>
348 #include <sys/resource.h>
349 ],
350 [ int f = RLIMIT_$1 ; ],
351 [glibcxx_mresult=1], [glibcxx_mresult=0])
352 AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
353 [Only used in build directory testsuite_hooks.h.])
354 if test $glibcxx_mresult = 1 ; then res=yes ; else res=no ; fi
355 AC_MSG_RESULT($res)
356 ])
357
358 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
359 setrlimit_have_headers=yes
360 AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
361 [],
362 [setrlimit_have_headers=no])
363 # If don't have the headers, then we can't run the tests now, and we
364 # won't be seeing any of these during testsuite compilation.
365 if test $setrlimit_have_headers = yes; then
366 # Can't do these in a loop, else the resulting syntax is wrong.
367 GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
368 GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
369 GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
370 GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
371 GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
372
373 # Check for rlimit, setrlimit.
374 AC_CACHE_VAL(glibcxx_cv_setrlimit, [
375 AC_TRY_COMPILE(
376 [#include <unistd.h>
377 #include <sys/time.h>
378 #include <sys/resource.h>
379 ],
380 [struct rlimit r;
381 setrlimit(0, &r);],
382 [glibcxx_cv_setrlimit=yes], [glibcxx_cv_setrlimit=no])
383 ])
384 fi
385
386 AC_MSG_CHECKING([for testsuite resource limits support])
387 if test $setrlimit_have_headers = yes && test $glibcxx_cv_setrlimit = yes; then
388 ac_res_limits=yes
389 AC_DEFINE(_GLIBCXX_RES_LIMITS, 1,
390 [Define if using setrlimit to set resource limits during
391 "make check"])
392 else
393 ac_res_limits=no
394 fi
395 AC_MSG_RESULT($ac_res_limits)
396 ])
397
398
399 dnl
400 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
401 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
402 dnl
403 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
404
405 AC_LANG_SAVE
406 AC_LANG_CPLUSPLUS
407 ac_save_CXXFLAGS="$CXXFLAGS"
408 CXXFLAGS="$CXXFLAGS -fno-exceptions"
409
410 AC_MSG_CHECKING([for S_ISREG or S_IFREG])
411 AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
412 GCC_TRY_COMPILE_OR_LINK(
413 [#include <sys/stat.h>],
414 [struct stat buffer;
415 fstat(0, &buffer);
416 S_ISREG(buffer.st_mode);],
417 [glibcxx_cv_S_ISREG=yes],
418 [glibcxx_cv_S_ISREG=no])
419 ])
420 AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
421 GCC_TRY_COMPILE_OR_LINK(
422 [#include <sys/stat.h>],
423 [struct stat buffer;
424 fstat(0, &buffer);
425 S_IFREG & buffer.st_mode;],
426 [glibcxx_cv_S_IFREG=yes],
427 [glibcxx_cv_S_IFREG=no])
428 ])
429 res=no
430 if test $glibcxx_cv_S_ISREG = yes; then
431 AC_DEFINE(HAVE_S_ISREG, 1,
432 [Define if S_IFREG is available in <sys/stat.h>.])
433 res=S_ISREG
434 elif test $glibcxx_cv_S_IFREG = yes; then
435 AC_DEFINE(HAVE_S_IFREG, 1,
436 [Define if S_IFREG is available in <sys/stat.h>.])
437 res=S_IFREG
438 fi
439 AC_MSG_RESULT($res)
440
441 CXXFLAGS="$ac_save_CXXFLAGS"
442 AC_LANG_RESTORE
443 ])
444
445
446 dnl
447 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
448 dnl
449 AC_DEFUN([GLIBCXX_CHECK_POLL], [
450
451 AC_LANG_SAVE
452 AC_LANG_CPLUSPLUS
453 ac_save_CXXFLAGS="$CXXFLAGS"
454 CXXFLAGS="$CXXFLAGS -fno-exceptions"
455
456 AC_MSG_CHECKING([for poll])
457 AC_CACHE_VAL(glibcxx_cv_POLL, [
458 GCC_TRY_COMPILE_OR_LINK(
459 [#include <poll.h>],
460 [struct pollfd pfd[1];
461 pfd[0].events = POLLIN;
462 poll(pfd, 1, 0);],
463 [glibcxx_cv_POLL=yes],
464 [glibcxx_cv_POLL=no])
465 ])
466 if test $glibcxx_cv_POLL = yes; then
467 AC_DEFINE(HAVE_POLL, 1, [Define if poll is available in <poll.h>.])
468 fi
469 AC_MSG_RESULT($glibcxx_cv_POLL)
470
471 CXXFLAGS="$ac_save_CXXFLAGS"
472 AC_LANG_RESTORE
473 ])
474
475
476 dnl
477 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
478 dnl
479 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
480
481 AC_LANG_SAVE
482 AC_LANG_CPLUSPLUS
483 ac_save_CXXFLAGS="$CXXFLAGS"
484 CXXFLAGS="$CXXFLAGS -fno-exceptions"
485
486 AC_MSG_CHECKING([for writev])
487 AC_CACHE_VAL(glibcxx_cv_WRITEV, [
488 GCC_TRY_COMPILE_OR_LINK(
489 [#include <sys/uio.h>],
490 [struct iovec iov[2];
491 writev(0, iov, 0);],
492 [glibcxx_cv_WRITEV=yes],
493 [glibcxx_cv_WRITEV=no])
494 ])
495 if test $glibcxx_cv_WRITEV = yes; then
496 AC_DEFINE(HAVE_WRITEV, 1, [Define if writev is available in <sys/uio.h>.])
497 fi
498 AC_MSG_RESULT($glibcxx_cv_WRITEV)
499
500 CXXFLAGS="$ac_save_CXXFLAGS"
501 AC_LANG_RESTORE
502 ])
503
504
505 dnl
506 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
507 dnl Also check whether int64_t is actually a typedef to long or long long.
508 dnl
509 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
510
511 AC_LANG_SAVE
512 AC_LANG_CPLUSPLUS
513
514 AC_MSG_CHECKING([for int64_t])
515 AC_CACHE_VAL(glibcxx_cv_INT64_T, [
516 AC_TRY_COMPILE(
517 [#include <stdint.h>],
518 [int64_t var;],
519 [glibcxx_cv_INT64_T=yes],
520 [glibcxx_cv_INT64_T=no])
521 ])
522
523 if test $glibcxx_cv_INT64_T = yes; then
524 AC_DEFINE(HAVE_INT64_T, 1, [Define if int64_t is available in <stdint.h>.])
525 AC_MSG_RESULT($glibcxx_cv_INT64_T)
526
527 AC_MSG_CHECKING([for int64_t as long])
528 AC_CACHE_VAL(glibcxx_cv_int64_t_long, [
529 AC_TRY_COMPILE(
530 [#include <stdint.h>
531 template<typename, typename> struct same { enum { value = -1 }; };
532 template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
533 int array[same<int64_t, long>::value];], [],
534 [glibcxx_cv_int64_t_long=yes], [glibcxx_cv_int64_t_long=no])
535 ])
536
537 if test $glibcxx_cv_int64_t_long = yes; then
538 AC_DEFINE(HAVE_INT64_T_LONG, 1, [Define if int64_t is a long.])
539 AC_MSG_RESULT($glibcxx_cv_int64_t_long)
540 fi
541
542 AC_MSG_CHECKING([for int64_t as long long])
543 AC_CACHE_VAL(glibcxx_cv_int64_t_long_long, [
544 AC_TRY_COMPILE(
545 [#include <stdint.h>
546 template<typename, typename> struct same { enum { value = -1 }; };
547 template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
548 int array[same<int64_t, long long>::value];], [],
549 [glibcxx_cv_int64_t_long_long=yes], [glibcxx_cv_int64_t_long_long=no])
550 ])
551
552 if test $glibcxx_cv_int64_t_long_long = yes; then
553 AC_DEFINE(HAVE_INT64_T_LONG_LONG, 1, [Define if int64_t is a long long.])
554 AC_MSG_RESULT($glibcxx_cv_int64_t_long_long)
555 fi
556 fi
557
558 AC_LANG_RESTORE
559 ])
560
561
562 dnl
563 dnl Check whether LFS support is available.
564 dnl
565 AC_DEFUN([GLIBCXX_CHECK_LFS], [
566 AC_LANG_SAVE
567 AC_LANG_CPLUSPLUS
568 ac_save_CXXFLAGS="$CXXFLAGS"
569 CXXFLAGS="$CXXFLAGS -fno-exceptions"
570 AC_MSG_CHECKING([for LFS support])
571 AC_CACHE_VAL(glibcxx_cv_LFS, [
572 GCC_TRY_COMPILE_OR_LINK(
573 [#include <unistd.h>
574 #include <stdio.h>
575 #include <sys/stat.h>
576 ],
577 [FILE* fp;
578 fopen64("t", "w");
579 fseeko64(fp, 0, SEEK_CUR);
580 ftello64(fp);
581 lseek64(1, 0, SEEK_CUR);
582 struct stat64 buf;
583 fstat64(1, &buf);],
584 [glibcxx_cv_LFS=yes],
585 [glibcxx_cv_LFS=no])
586 ])
587 if test $glibcxx_cv_LFS = yes; then
588 AC_DEFINE(_GLIBCXX_USE_LFS, 1, [Define if LFS support is available.])
589 fi
590 AC_MSG_RESULT($glibcxx_cv_LFS)
591 CXXFLAGS="$ac_save_CXXFLAGS"
592 AC_LANG_RESTORE
593 ])
594
595
596 dnl
597 dnl Check for whether a fully dynamic basic_string implementation should
598 dnl be turned on, that does not put empty objects in per-process static
599 dnl memory (mostly useful together with shared memory allocators, see PR
600 dnl libstdc++/16612 for details).
601 dnl
602 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING to 1
603 dnl --disable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING to 0
604 dnl otherwise undefined
605 dnl + Usage: GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
606 dnl Where DEFAULT is either `yes' or `no'.
607 dnl
608 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
609 GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
610 if test $enable_fully_dynamic_string = yes; then
611 enable_fully_dynamic_string_def=1
612 else
613 enable_fully_dynamic_string_def=0
614 fi
615 AC_DEFINE_UNQUOTED([_GLIBCXX_FULLY_DYNAMIC_STRING], [${enable_fully_dynamic_string_def}],
616 [Define to 1 if a fully dynamic basic_string is wanted, 0 to disable, undefined for platform defaults])
617 ])
618
619
620 dnl
621 dnl Does any necessary configuration of the testsuite directory. Generates
622 dnl the testsuite_hooks.h header.
623 dnl
624 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
625 dnl
626 dnl Sets:
627 dnl enable_abi_check
628 dnl GLIBCXX_TEST_WCHAR_T
629 dnl GLIBCXX_TEST_THREAD
630 dnl Substs:
631 dnl baseline_dir
632 dnl baseline_subdir_switch
633 dnl
634 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
635 # Do checks for resource limit functions.
636 GLIBCXX_CHECK_SETRLIMIT
637
638 if $GLIBCXX_IS_NATIVE ; then
639 # Look for setenv, so that extended locale tests can be performed.
640 GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
641 fi
642
643 if $GLIBCXX_IS_NATIVE && test $is_hosted = yes &&
644 test $enable_symvers != no; then
645 case "$host" in
646 *-*-cygwin*)
647 enable_abi_check=no ;;
648 *)
649 enable_abi_check=yes ;;
650 esac
651 else
652 # Only build this as native, since automake does not understand
653 # CXX_FOR_BUILD.
654 enable_abi_check=no
655 fi
656
657 # Export file names for ABI checking.
658 baseline_dir="$glibcxx_srcdir/config/abi/post/${abi_baseline_pair}"
659 AC_SUBST(baseline_dir)
660 baseline_subdir_switch="$abi_baseline_subdir_switch"
661 AC_SUBST(baseline_subdir_switch)
662 ])
663
664
665 dnl
666 dnl Does any necessary configuration for docbook in the docs directory.
667 dnl
668 dnl XSLTPROC must be set before this
669 dnl
670 dnl Sets:
671 dnl glibcxx_stylesheets
672 dnl Substs:
673 dnl XSL_STYLE_DIR
674 dnl
675 AC_DEFUN([GLIBCXX_CONFIGURE_DOCBOOK], [
676
677 AC_MSG_CHECKING([for docbook stylesheets for documentation creation])
678 glibcxx_stylesheets=no
679 if test x${XSLTPROC} = xyes && echo '<title/>' | xsltproc --noout --nonet --xinclude http://docbook.sourceforge.net/release/xsl-ns/current/xhtml-1_1/docbook.xsl - 2>/dev/null; then
680 glibcxx_stylesheets=yes
681 fi
682 AC_MSG_RESULT($glibcxx_stylesheets)
683
684 AC_MSG_CHECKING([for local stylesheet directory])
685 glibcxx_local_stylesheets=no
686 if test x"$glibcxx_stylesheets" = x"yes"; then
687 if test -d /usr/share/sgml/docbook/xsl-ns-stylesheets; then
688 glibcxx_local_stylesheets=yes
689 XSL_STYLE_DIR=/usr/share/sgml/docbook/xsl-ns-stylesheets
690 fi
691 if test -d /usr/share/xml/docbook/stylesheet/docbook-xsl-ns; then
692 glibcxx_local_stylesheets=yes
693 XSL_STYLE_DIR=/usr/share/xml/docbook/stylesheet/docbook-xsl-ns
694 fi
695 if test -d /usr/share/xml/docbook/stylesheet/nwalsh5/current; then
696 glibcxx_local_stylesheets=yes
697 XSL_STYLE_DIR=/usr/share/xml/docbook/stylesheet/nwalsh5/current
698 fi
699 fi
700 AC_MSG_RESULT($glibcxx_local_stylesheets)
701
702 if test x"$glibcxx_local_stylesheets" = x"yes"; then
703 AC_SUBST(XSL_STYLE_DIR)
704 AC_MSG_NOTICE($XSL_STYLE_DIR)
705 else
706 glibcxx_stylesheets=no
707 fi
708
709 # Check for epub3 dependencies.
710 AC_MSG_CHECKING([for epub3 stylesheets for documentation creation])
711 glibcxx_epub_stylesheets=no
712 if test x"$glibcxx_local_stylesheets" = x"yes"; then
713 if test -f "$XSL_STYLE_DIR/epub3/chunk.xsl"; then
714 glibcxx_epub_stylesheets=yes
715 fi
716 fi
717 AC_MSG_RESULT($glibcxx_epub_stylesheets)
718 AM_CONDITIONAL(BUILD_EPUB, test x"$glibcxx_epub_stylesheets" = x"yes")
719
720 ])
721
722
723 dnl
724 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
725 dnl
726 dnl Substs:
727 dnl GLIBCXX_INCLUDES
728 dnl TOPLEVEL_INCLUDES
729 dnl
730 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
731 # Used for every C++ compile we perform.
732 GLIBCXX_INCLUDES="\
733 -I$glibcxx_builddir/include/$host_alias \
734 -I$glibcxx_builddir/include \
735 -I$glibcxx_srcdir/libsupc++"
736
737 # For Canadian crosses, pick this up too.
738 if test $CANADIAN = yes; then
739 GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
740 fi
741
742 # Stuff in the actual top level. Currently only used by libsupc++ to
743 # get unwind* headers from the libgcc dir.
744 #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/libgcc -I$(toplevel_srcdir)/include'
745 TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/libgcc'
746
747 # Now, export this to all the little Makefiles....
748 AC_SUBST(GLIBCXX_INCLUDES)
749 AC_SUBST(TOPLEVEL_INCLUDES)
750 ])
751
752
753 dnl
754 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
755 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
756 dnl
757 dnl Substs:
758 dnl OPTIMIZE_CXXFLAGS
759 dnl WARN_FLAGS
760 dnl
761 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
762 # Optimization flags that are probably a good idea for thrill-seekers. Just
763 # uncomment the lines below and make, everything else is ready to go...
764 # Alternatively OPTIMIZE_CXXFLAGS can be set in configure.host.
765 # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
766 AC_SUBST(OPTIMIZE_CXXFLAGS)
767
768 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual -Wabi'
769 AC_SUBST(WARN_FLAGS)
770 ])
771
772
773 dnl
774 dnl All installation directory information is determined here.
775 dnl
776 dnl Substs:
777 dnl gxx_install_dir
778 dnl glibcxx_prefixdir
779 dnl glibcxx_toolexecdir
780 dnl glibcxx_toolexeclibdir
781 dnl
782 dnl Assumes cross_compiling bits already done, and with_cross_host in
783 dnl particular.
784 dnl
785 dnl This logic must match gcc/configure.ac's setting of gcc_gxx_include_dir.
786 dnl config/gxx-include-dir.m4 must be kept consistant with this as well.
787 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
788 glibcxx_toolexecdir=no
789 glibcxx_toolexeclibdir=no
790 glibcxx_prefixdir=$prefix
791
792 AC_MSG_CHECKING([for gxx-include-dir])
793 AC_ARG_WITH([gxx-include-dir],
794 AC_HELP_STRING([--with-gxx-include-dir=DIR],
795 [installation directory for include files]),
796 [case "$withval" in
797 yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
798 no) gxx_include_dir=no ;;
799 *) gxx_include_dir=$withval ;;
800 esac],
801 [gxx_include_dir=no])
802 AC_MSG_RESULT($gxx_include_dir)
803
804 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
805 AC_ARG_ENABLE([version-specific-runtime-libs],
806 AC_HELP_STRING([--enable-version-specific-runtime-libs],
807 [Specify that runtime libraries should be installed in a compiler-specific directory]),
808 [case "$enableval" in
809 yes) version_specific_libs=yes ;;
810 no) version_specific_libs=no ;;
811 *) AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
812 esac],
813 [version_specific_libs=no])
814 AC_MSG_RESULT($version_specific_libs)
815
816 # Default case for install directory for include files.
817 if test $version_specific_libs = no && test $gxx_include_dir = no; then
818 gxx_include_dir='include/c++/${gcc_version}'
819 if test -n "$with_cross_host" &&
820 test x"$with_cross_host" != x"no"; then
821 gxx_include_dir='${prefix}/${target_alias}/'"$gxx_include_dir"
822 else
823 gxx_include_dir='${prefix}/'"$gxx_include_dir"
824 fi
825 fi
826
827 # Version-specific runtime libs processing.
828 if test $version_specific_libs = yes; then
829 # Need the gcc compiler version to know where to install libraries
830 # and header files if --enable-version-specific-runtime-libs option
831 # is selected. FIXME: these variables are misnamed, there are
832 # no executables installed in _toolexecdir or _toolexeclibdir.
833 if test x"$gxx_include_dir" = x"no"; then
834 gxx_include_dir='${libdir}/gcc/${host_alias}/${gcc_version}/include/c++'
835 fi
836 glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
837 glibcxx_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
838 fi
839
840 # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
841 # Install a library built with a cross compiler in tooldir, not libdir.
842 if test x"$glibcxx_toolexecdir" = x"no"; then
843 if test -n "$with_cross_host" &&
844 test x"$with_cross_host" != x"no"; then
845 glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
846 glibcxx_toolexeclibdir='${toolexecdir}/lib'
847 else
848 glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
849 glibcxx_toolexeclibdir='${libdir}'
850 fi
851 multi_os_directory=`$CXX -print-multi-os-directory`
852 case $multi_os_directory in
853 .) ;; # Avoid trailing /.
854 *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
855 esac
856 fi
857
858 AC_MSG_CHECKING([for install location])
859 AC_MSG_RESULT($gxx_include_dir)
860
861 AC_SUBST(glibcxx_prefixdir)
862 AC_SUBST(gxx_include_dir)
863 AC_SUBST(glibcxx_toolexecdir)
864 AC_SUBST(glibcxx_toolexeclibdir)
865 ])
866
867
868 dnl
869 dnl GLIBCXX_ENABLE
870 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
871 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
872 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
873 dnl
874 dnl See manual/appendix_porting.html#appendix.porting.build_hacking for
875 dnl documentation.
876 dnl
877 m4_define([GLIBCXX_ENABLE],[dnl
878 m4_define([_g_switch],[--enable-$1])dnl
879 m4_define([_g_help],[AC_HELP_STRING([_g_switch$3],[$4 @<:@default=$2@:>@])])dnl
880 AC_ARG_ENABLE([$1],m4_dquote(_g_help),
881 m4_bmatch([$5],
882 [^permit ],
883 [[
884 case "$enableval" in
885 m4_bpatsubst([$5],[permit ])) ;;
886 *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
887 dnl Idea for future: generate a URL pointing to
888 dnl "onlinedocs/configopts.html#whatever"
889 esac
890 ]],
891 [^$],
892 [[
893 case "$enableval" in
894 yes|no) ;;
895 *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
896 esac
897 ]],
898 [[$5]]),
899 [enable_]m4_bpatsubst([$1],-,_)[=][$2])
900 m4_undefine([_g_switch])dnl
901 m4_undefine([_g_help])dnl
902 ])
903
904
905 dnl
906 dnl Check for ISO/IEC 9899:1999 "C99" support.
907 dnl
908 dnl --enable-c99 defines _GLIBCXX_USE_C99
909 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
910 dnl + Usage: GLIBCXX_ENABLE_C99[(DEFAULT)]
911 dnl Where DEFAULT is either `yes' or `no'.
912 dnl + If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
913 dnl
914 AC_DEFUN([GLIBCXX_ENABLE_C99], [
915 GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
916
917 if test x"$enable_c99" = x"yes"; then
918 AC_LANG_SAVE
919 AC_LANG_CPLUSPLUS
920
921 # Use -std=c++98 (instead of -std=gnu++98) because leaving __STRICT_ANSI__
922 # undefined may cause fake C99 facilities, like pre-standard snprintf,
923 # to be spuriously enabled.
924 ac_save_CXXFLAGS="$CXXFLAGS"
925 CXXFLAGS="$CXXFLAGS -std=c++98"
926 ac_save_LIBS="$LIBS"
927 ac_save_gcc_no_link="$gcc_no_link"
928
929 if test x$gcc_no_link != xyes; then
930 # Use -fno-exceptions to that the C driver can link these tests without
931 # hitting undefined references to personality routines.
932 CXXFLAGS="$CXXFLAGS -fno-exceptions"
933 AC_CHECK_LIB(m, sin, [LIBS="$LIBS -lm"], [
934 # Use the default compile-only tests in GCC_TRY_COMPILE_OR_LINK
935 gcc_no_link=yes
936 ])
937 fi
938
939 # Check for the existence of <math.h> functions used if C99 is enabled.
940 AC_MSG_CHECKING([for ISO C99 support in <math.h> for C++98])
941 AC_CACHE_VAL(glibcxx_cv_c99_math_cxx98, [
942 GCC_TRY_COMPILE_OR_LINK(
943 [#include <math.h>
944 volatile double d1, d2;
945 volatile int i;],
946 [i = fpclassify(d1);
947 i = isfinite(d1);
948 i = isinf(d1);
949 i = isnan(d1);
950 i = isnormal(d1);
951 i = signbit(d1);
952 i = isgreater(d1, d2);
953 i = isgreaterequal(d1, d2);
954 i = isless(d1, d2);
955 i = islessequal(d1, d2);
956 i = islessgreater(d1, d2);
957 i = islessgreater(d1, d2);
958 i = isunordered(d1, d2);
959 ], [glibcxx_cv_c99_math_cxx98=yes], [glibcxx_cv_c99_math_cxx98=no])
960 ])
961 AC_MSG_RESULT($glibcxx_cv_c99_math_cxx98)
962 if test x"$glibcxx_cv_c99_math_cxx98" = x"yes"; then
963 AC_DEFINE(_GLIBCXX98_USE_C99_MATH, 1,
964 [Define if C99 functions or macros in <math.h> should be imported
965 in <cmath> in namespace std for C++98.])
966 fi
967
968 # Check for the existence of <complex.h> complex math functions.
969 # This is necessary even though libstdc++ uses the builtin versions
970 # of these functions, because if the builtin cannot be used, a reference
971 # to the library function is emitted.
972 AC_CHECK_HEADERS(tgmath.h, ac_has_tgmath_h=yes, ac_has_tgmath_h=no)
973 AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
974 if test x"$ac_has_complex_h" = x"yes"; then
975 AC_MSG_CHECKING([for ISO C99 support in <complex.h> for C++98])
976 AC_CACHE_VAL(glibcxx_cv_c99_complex_cxx98, [
977 GCC_TRY_COMPILE_OR_LINK(
978 [#include <complex.h>
979 typedef __complex__ float float_type;
980 typedef __complex__ double double_type;
981 typedef __complex__ long double ld_type;
982 volatile float_type tmpf;
983 volatile double_type tmpd;
984 volatile ld_type tmpld;
985 volatile float f;
986 volatile double d;
987 volatile long double ld;],
988 [f = cabsf(tmpf);
989 f = cargf(tmpf);
990 tmpf = ccosf(tmpf);
991 tmpf = ccoshf(tmpf);
992 tmpf = cexpf(tmpf);
993 tmpf = clogf(tmpf);
994 tmpf = csinf(tmpf);
995 tmpf = csinhf(tmpf);
996 tmpf = csqrtf(tmpf);
997 tmpf = ctanf(tmpf);
998 tmpf = ctanhf(tmpf);
999 tmpf = cpowf(tmpf, tmpf);
1000 tmpf = cprojf(tmpf);
1001 d = cabs(tmpd);
1002 d = carg(tmpd);
1003 tmpd = ccos(tmpd);
1004 tmpd = ccosh(tmpd);
1005 tmpd = cexp(tmpd);
1006 tmpd = clog(tmpd);
1007 tmpd = csin(tmpd);
1008 tmpd = csinh(tmpd);
1009 tmpd = csqrt(tmpd);
1010 tmpd = ctan(tmpd);
1011 tmpd = ctanh(tmpd);
1012 tmpd = cpow(tmpd, tmpd);
1013 tmpd = cproj(tmpd);
1014 ld = cabsl(tmpld);
1015 ld = cargl(tmpld);
1016 tmpld = ccosl(tmpld);
1017 tmpld = ccoshl(tmpld);
1018 tmpld = cexpl(tmpld);
1019 tmpld = clogl(tmpld);
1020 tmpld = csinl(tmpld);
1021 tmpld = csinhl(tmpld);
1022 tmpld = csqrtl(tmpld);
1023 tmpld = ctanl(tmpld);
1024 tmpld = ctanhl(tmpld);
1025 tmpld = cpowl(tmpld, tmpld);
1026 tmpld = cprojl(tmpld);
1027 ], [glibcxx_cv_c99_complex_cxx98=yes], [glibcxx_cv_c99_complex_cxx98=no])
1028 ])
1029 fi
1030 AC_MSG_RESULT($glibcxx_cv_c99_complex_cxx98)
1031 if test x"$glibcxx_cv_c99_complex_cxx98" = x"yes"; then
1032 AC_DEFINE(_GLIBCXX98_USE_C99_COMPLEX, 1,
1033 [Define if C99 functions in <complex.h> should be used in
1034 <complex> for C++98. Using compiler builtins for these functions
1035 requires corresponding C99 library functions to be present.])
1036 fi
1037
1038 # Check for the existence in <stdio.h> of vscanf, et. al.
1039 AC_MSG_CHECKING([for ISO C99 support in <stdio.h> for C++98])
1040 AC_CACHE_VAL(glibcxx_cv_c99_stdio_cxx98, [
1041 GCC_TRY_COMPILE_OR_LINK(
1042 [#include <stdio.h>
1043 #include <stdarg.h>
1044 void foo(char* fmt, ...)
1045 {
1046 va_list args; va_start(args, fmt);
1047 vfscanf(stderr, "%i", args);
1048 vscanf("%i", args);
1049 vsnprintf(fmt, 0, "%i", args);
1050 vsscanf(fmt, "%i", args);
1051 snprintf(fmt, 0, "%i");
1052 }], [],
1053 [glibcxx_cv_c99_stdio_cxx98=yes], [glibcxx_cv_c99_stdio_cxx98=no])
1054 ])
1055 AC_MSG_RESULT($glibcxx_cv_c99_stdio_cxx98)
1056 if test x"$glibcxx_cv_c99_stdio_cxx98" = x"yes"; then
1057 AC_DEFINE(_GLIBCXX98_USE_C99_STDIO, 1,
1058 [Define if C99 functions or macros in <stdio.h> should be imported
1059 in <cstdio> in namespace std for C++98.])
1060 fi
1061
1062 # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1063 AC_MSG_CHECKING([for ISO C99 support in <stdlib.h> for C++98])
1064 AC_CACHE_VAL(glibcxx_cv_c99_stdlib_cxx98, [
1065 GCC_TRY_COMPILE_OR_LINK(
1066 [#include <stdlib.h>
1067 volatile float f;
1068 volatile long double ld;
1069 volatile unsigned long long ll;
1070 lldiv_t mydivt;],
1071 [char* tmp;
1072 f = strtof("gnu", &tmp);
1073 ld = strtold("gnu", &tmp);
1074 ll = strtoll("gnu", &tmp, 10);
1075 ll = strtoull("gnu", &tmp, 10);
1076 ll = llabs(10);
1077 mydivt = lldiv(10,1);
1078 ll = mydivt.quot;
1079 ll = mydivt.rem;
1080 ll = atoll("10");
1081 _Exit(0);
1082 ], [glibcxx_cv_c99_stdlib_cxx98=yes], [glibcxx_cv_c99_stdlib_cxx98=no])
1083 ])
1084 AC_MSG_RESULT($glibcxx_cv_c99_stdlib_cxx98)
1085 if test x"$glibcxx_cv_c99_stdlib_cxx98" = x"yes"; then
1086 AC_DEFINE(_GLIBCXX98_USE_C99_STDLIB, 1,
1087 [Define if C99 functions or macros in <stdlib.h> should be imported
1088 in <cstdlib> in namespace std for C++98.])
1089 fi
1090
1091 # Check for the existence in <wchar.h> of wcstold, etc.
1092 if test x"$ac_has_wchar_h" = xyes &&
1093 test x"$ac_has_wctype_h" = xyes; then
1094 AC_MSG_CHECKING([for ISO C99 support in <wchar.h> for C++98])
1095 AC_CACHE_VAL(glibcxx_cv_c99_wchar_cxx98, [
1096 AC_TRY_COMPILE([#include <wchar.h>
1097 namespace test
1098 {
1099 using ::wcstold;
1100 using ::wcstoll;
1101 using ::wcstoull;
1102 }
1103 ], [], [glibcxx_cv_c99_wchar_cxx98=yes], [glibcxx_cv_c99_wchar_cxx98=no])
1104 ])
1105
1106 # Checks for wide character functions that may not be present.
1107 # Injection of these is wrapped with guard macros.
1108 # NB: only put functions here, instead of immediately above, if
1109 # absolutely necessary.
1110 AC_TRY_COMPILE([#include <wchar.h>
1111 namespace test { using ::vfwscanf; }], [],
1112 [AC_DEFINE(HAVE_VFWSCANF, 1, [Defined if vfwscanf exists.])], [])
1113
1114 AC_TRY_COMPILE([#include <wchar.h>
1115 namespace test { using ::vswscanf; }], [],
1116 [AC_DEFINE(HAVE_VSWSCANF, 1, [Defined if vswscanf exists.])], [])
1117
1118 AC_TRY_COMPILE([#include <wchar.h>
1119 namespace test { using ::vwscanf; }], [],
1120 [AC_DEFINE(HAVE_VWSCANF, 1, [Defined if vwscanf exists.])], [])
1121
1122 AC_TRY_COMPILE([#include <wchar.h>
1123 namespace test { using ::wcstof; }], [],
1124 [AC_DEFINE(HAVE_WCSTOF, 1, [Defined if wcstof exists.])], [])
1125
1126 AC_TRY_COMPILE([#include <wctype.h>],
1127 [wint_t t; int i = iswblank(t);],
1128 [AC_DEFINE(HAVE_ISWBLANK, 1, [Defined if iswblank exists.])], [])
1129
1130 AC_MSG_RESULT($glibcxx_cv_c99_wchar_cxx98)
1131 if test x"$glibcxx_cv_c99_wchar_cxx98" = x"yes"; then
1132 AC_DEFINE(_GLIBCXX98_USE_C99_WCHAR, 1,
1133 [Define if C99 functions or macros in <wchar.h> should be imported
1134 in <cwchar> in namespace std for C++98.])
1135 fi
1136 fi
1137
1138 # Option parsed, now set things appropriately.
1139 if test x"$glibcxx_cv_c99_math_cxx98" = x"no" ||
1140 test x"$glibcxx_cv_c99_complex_cxx98" = x"no" ||
1141 test x"$glibcxx_cv_c99_stdio_cxx98" = x"no" ||
1142 test x"$glibcxx_cv_c99_stdlib_cxx98" = x"no" ||
1143 test x"$glibcxx_cv_c99_wchar_cxx98" = x"no"; then
1144 enable_c99=no;
1145 else
1146 AC_DEFINE(_GLIBCXX_USE_C99, 1,
1147 [Define if C99 functions or macros from <wchar.h>, <math.h>,
1148 <complex.h>, <stdio.h>, and <stdlib.h> can be used or exposed.])
1149 fi
1150
1151 gcc_no_link="$ac_save_gcc_no_link"
1152 LIBS="$ac_save_LIBS"
1153 CXXFLAGS="$ac_save_CXXFLAGS"
1154 AC_LANG_RESTORE
1155
1156 AC_LANG_SAVE
1157 AC_LANG_CPLUSPLUS
1158
1159 # Use -std=c++11 and test again for C99 library feature in C++11 mode.
1160 # For the reasons given above we use -std=c++11 not -std=gnu++11.
1161 ac_save_CXXFLAGS="$CXXFLAGS"
1162 CXXFLAGS="$CXXFLAGS -std=c++11"
1163 ac_save_LIBS="$LIBS"
1164 ac_save_gcc_no_link="$gcc_no_link"
1165
1166 if test x$gcc_no_link != xyes; then
1167 # Use -fno-exceptions to that the C driver can link these tests without
1168 # hitting undefined references to personality routines.
1169 CXXFLAGS="$CXXFLAGS -fno-exceptions"
1170 AC_CHECK_LIB(m, sin, [LIBS="$LIBS -lm"], [
1171 # Use the default compile-only tests in GCC_TRY_COMPILE_OR_LINK
1172 gcc_no_link=yes
1173 ])
1174 fi
1175
1176 # Check for the existence of <math.h> functions used if C99 is enabled.
1177 AC_MSG_CHECKING([for ISO C99 support in <math.h> for C++11])
1178 AC_CACHE_VAL(glibcxx_cv_c99_math_cxx11, [
1179 GCC_TRY_COMPILE_OR_LINK(
1180 [#include <math.h>
1181 volatile double d1, d2;
1182 volatile int i;],
1183 [i = fpclassify(d1);
1184 i = isfinite(d1);
1185 i = isinf(d1);
1186 i = isnan(d1);
1187 i = isnormal(d1);
1188 i = signbit(d1);
1189 i = isgreater(d1, d2);
1190 i = isgreaterequal(d1, d2);
1191 i = isless(d1, d2);
1192 i = islessequal(d1, d2);
1193 i = islessgreater(d1, d2);
1194 i = islessgreater(d1, d2);
1195 i = isunordered(d1, d2);
1196 ], [glibcxx_cv_c99_math_cxx11=yes], [glibcxx_cv_c99_math_cxx11=no])
1197 ])
1198 AC_MSG_RESULT($glibcxx_cv_c99_math_cxx11)
1199 if test x"$glibcxx_cv_c99_math_cxx11" = x"yes"; then
1200 AC_DEFINE(_GLIBCXX11_USE_C99_MATH, 1,
1201 [Define if C99 functions or macros in <math.h> should be imported
1202 in <cmath> in namespace std for C++11.])
1203 fi
1204
1205 # Check for the existence of <complex.h> complex math functions.
1206 # This is necessary even though libstdc++ uses the builtin versions
1207 # of these functions, because if the builtin cannot be used, a reference
1208 # to the library function is emitted.
1209 AC_CHECK_HEADERS(tgmath.h, ac_has_tgmath_h=yes, ac_has_tgmath_h=no)
1210 AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
1211 if test x"$ac_has_complex_h" = x"yes"; then
1212 AC_MSG_CHECKING([for ISO C99 support in <complex.h> for C++11])
1213 AC_CACHE_VAL(glibcxx_cv_c99_complex_cxx11, [
1214 GCC_TRY_COMPILE_OR_LINK(
1215 [#include <complex.h>
1216 typedef __complex__ float float_type;
1217 typedef __complex__ double double_type;
1218 typedef __complex__ long double ld_type;
1219 volatile float_type tmpf;
1220 volatile double_type tmpd;
1221 volatile ld_type tmpld;
1222 volatile float f;
1223 volatile double d;
1224 volatile long double ld;],
1225 [f = cabsf(tmpf);
1226 f = cargf(tmpf);
1227 tmpf = ccosf(tmpf);
1228 tmpf = ccoshf(tmpf);
1229 tmpf = cexpf(tmpf);
1230 tmpf = clogf(tmpf);
1231 tmpf = csinf(tmpf);
1232 tmpf = csinhf(tmpf);
1233 tmpf = csqrtf(tmpf);
1234 tmpf = ctanf(tmpf);
1235 tmpf = ctanhf(tmpf);
1236 tmpf = cpowf(tmpf, tmpf);
1237 tmpf = cprojf(tmpf);
1238 d = cabs(tmpd);
1239 d = carg(tmpd);
1240 tmpd = ccos(tmpd);
1241 tmpd = ccosh(tmpd);
1242 tmpd = cexp(tmpd);
1243 tmpd = clog(tmpd);
1244 tmpd = csin(tmpd);
1245 tmpd = csinh(tmpd);
1246 tmpd = csqrt(tmpd);
1247 tmpd = ctan(tmpd);
1248 tmpd = ctanh(tmpd);
1249 tmpd = cpow(tmpd, tmpd);
1250 tmpd = cproj(tmpd);
1251 ld = cabsl(tmpld);
1252 ld = cargl(tmpld);
1253 tmpld = ccosl(tmpld);
1254 tmpld = ccoshl(tmpld);
1255 tmpld = cexpl(tmpld);
1256 tmpld = clogl(tmpld);
1257 tmpld = csinl(tmpld);
1258 tmpld = csinhl(tmpld);
1259 tmpld = csqrtl(tmpld);
1260 tmpld = ctanl(tmpld);
1261 tmpld = ctanhl(tmpld);
1262 tmpld = cpowl(tmpld, tmpld);
1263 tmpld = cprojl(tmpld);
1264 ], [glibcxx_cv_c99_complex_cxx11=yes], [glibcxx_cv_c99_complex_cxx11=no])
1265 ])
1266 fi
1267 AC_MSG_RESULT($glibcxx_cv_c99_complex_cxx11)
1268 if test x"$glibcxx_cv_c99_complex_cxx11" = x"yes"; then
1269 AC_DEFINE(_GLIBCXX11_USE_C99_COMPLEX, 1,
1270 [Define if C99 functions in <complex.h> should be used in
1271 <complex> for C++11. Using compiler builtins for these functions
1272 requires corresponding C99 library functions to be present.])
1273 fi
1274
1275 # Check for the existence in <stdio.h> of vscanf, et. al.
1276 AC_MSG_CHECKING([for ISO C99 support in <stdio.h> for C++11])
1277 AC_CACHE_VAL(glibcxx_cv_c99_stdio_cxx11, [
1278 GCC_TRY_COMPILE_OR_LINK(
1279 [#include <stdio.h>
1280 #include <stdarg.h>
1281 void foo(char* fmt, ...)
1282 {
1283 va_list args; va_start(args, fmt);
1284 vfscanf(stderr, "%i", args);
1285 vscanf("%i", args);
1286 vsnprintf(fmt, 0, "%i", args);
1287 vsscanf(fmt, "%i", args);
1288 snprintf(fmt, 0, "%i");
1289 }], [],
1290 [glibcxx_cv_c99_stdio_cxx11=yes], [glibcxx_cv_c99_stdio_cxx11=no])
1291 ])
1292 AC_MSG_RESULT($glibcxx_cv_c99_stdio_cxx11)
1293 if test x"$glibcxx_cv_c99_stdio_cxx11" = x"yes"; then
1294 AC_DEFINE(_GLIBCXX11_USE_C99_STDIO, 1,
1295 [Define if C99 functions or macros in <stdio.h> should be imported
1296 in <cstdio> in namespace std for C++11.])
1297 fi
1298
1299 # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1300 AC_MSG_CHECKING([for ISO C99 support in <stdlib.h> for C++11])
1301 AC_CACHE_VAL(glibcxx_cv_c99_stdlib_cxx11, [
1302 GCC_TRY_COMPILE_OR_LINK(
1303 [#include <stdlib.h>
1304 volatile float f;
1305 volatile long double ld;
1306 volatile unsigned long long ll;
1307 lldiv_t mydivt;],
1308 [char* tmp;
1309 f = strtof("gnu", &tmp);
1310 ld = strtold("gnu", &tmp);
1311 ll = strtoll("gnu", &tmp, 10);
1312 ll = strtoull("gnu", &tmp, 10);
1313 ll = llabs(10);
1314 mydivt = lldiv(10,1);
1315 ll = mydivt.quot;
1316 ll = mydivt.rem;
1317 ll = atoll("10");
1318 _Exit(0);
1319 ], [glibcxx_cv_c99_stdlib_cxx11=yes], [glibcxx_cv_c99_stdlib_cxx11=no])
1320 ])
1321 AC_MSG_RESULT($glibcxx_cv_c99_stdlib_cxx11)
1322 if test x"$glibcxx_cv_c99_stdlib_cxx11" = x"yes"; then
1323 AC_DEFINE(_GLIBCXX11_USE_C99_STDLIB, 1,
1324 [Define if C99 functions or macros in <stdlib.h> should be imported
1325 in <cstdlib> in namespace std for C++11.])
1326 fi
1327
1328 # Check for the existence in <wchar.h> of wcstold, etc.
1329 if test x"$ac_has_wchar_h" = xyes &&
1330 test x"$ac_has_wctype_h" = xyes; then
1331 AC_MSG_CHECKING([for ISO C99 support in <wchar.h> for C++11])
1332 AC_CACHE_VAL(glibcxx_cv_c99_wchar_cxx11, [
1333 AC_TRY_COMPILE([#include <wchar.h>
1334 namespace test
1335 {
1336 using ::wcstold;
1337 using ::wcstoll;
1338 using ::wcstoull;
1339 }
1340 ], [], [glibcxx_cv_c99_wchar_cxx11=yes], [glibcxx_cv_c99_wchar_cxx11=no])
1341 ])
1342
1343 # Checks for wide character functions that may not be present.
1344 # Injection of these is wrapped with guard macros.
1345 # NB: only put functions here, instead of immediately above, if
1346 # absolutely necessary.
1347 AC_TRY_COMPILE([#include <wchar.h>
1348 namespace test { using ::vfwscanf; }], [],
1349 [AC_DEFINE(HAVE_VFWSCANF, 1, [Defined if vfwscanf exists.])], [])
1350
1351 AC_TRY_COMPILE([#include <wchar.h>
1352 namespace test { using ::vswscanf; }], [],
1353 [AC_DEFINE(HAVE_VSWSCANF, 1, [Defined if vswscanf exists.])], [])
1354
1355 AC_TRY_COMPILE([#include <wchar.h>
1356 namespace test { using ::vwscanf; }], [],
1357 [AC_DEFINE(HAVE_VWSCANF, 1, [Defined if vwscanf exists.])], [])
1358
1359 AC_TRY_COMPILE([#include <wchar.h>
1360 namespace test { using ::wcstof; }], [],
1361 [AC_DEFINE(HAVE_WCSTOF, 1, [Defined if wcstof exists.])], [])
1362
1363 AC_TRY_COMPILE([#include <wctype.h>],
1364 [wint_t t; int i = iswblank(t);],
1365 [AC_DEFINE(HAVE_ISWBLANK, 1, [Defined if iswblank exists.])], [])
1366
1367 AC_MSG_RESULT($glibcxx_cv_c99_wchar_cxx11)
1368 if test x"$glibcxx_cv_c99_wchar_cxx11" = x"yes"; then
1369 AC_DEFINE(_GLIBCXX11_USE_C99_WCHAR, 1,
1370 [Define if C99 functions or macros in <wchar.h> should be imported
1371 in <cwchar> in namespace std for C++11.])
1372 fi
1373 fi
1374
1375 gcc_no_link="$ac_save_gcc_no_link"
1376 LIBS="$ac_save_LIBS"
1377 CXXFLAGS="$ac_save_CXXFLAGS"
1378 AC_LANG_RESTORE
1379 fi
1380
1381 AC_MSG_CHECKING([for fully enabled ISO C99 support])
1382 AC_MSG_RESULT($enable_c99)
1383 ])
1384
1385
1386 dnl
1387 dnl Check for clock_gettime, nanosleep and sched_yield, used in the
1388 dnl implementation of 20.11.7 [time.clock], and 30.3.2 [thread.thread.this]
1389 dnl in the C++11 standard.
1390 dnl
1391 dnl --enable-libstdcxx-time
1392 dnl --enable-libstdcxx-time=yes
1393 dnl checks for the availability of monotonic and realtime clocks,
1394 dnl nanosleep and sched_yield in libc and libposix4 and, if needed,
1395 dnl links in the latter.
1396 dnl --enable-libstdcxx-time=rt
1397 dnl also searches (and, if needed, links) librt. Note that this is
1398 dnl not always desirable because, in glibc 2.16 and earlier, for
1399 dnl example, in turn it triggers the linking of libpthread too,
1400 dnl which activates locking,
1401 dnl a large overhead for single-thread programs.
1402 dnl --enable-libstdcxx-time=no
1403 dnl --disable-libstdcxx-time
1404 dnl disables the checks completely
1405 dnl
1406 dnl N.B. Darwin provides nanosleep but doesn't support the whole POSIX
1407 dnl Timers option, so doesn't define _POSIX_TIMERS. Because the test
1408 dnl below fails Darwin unconditionally defines _GLIBCXX_USE_NANOSLEEP in
1409 dnl os_defines.h and also defines _GLIBCXX_USE_SCHED_YIELD.
1410 dnl
1411 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_TIME], [
1412
1413 GLIBCXX_ENABLE(libstdcxx-time,auto,[[[=KIND]]],
1414 [use KIND for check type],
1415 [permit yes|no|rt])
1416
1417 AC_LANG_SAVE
1418 AC_LANG_CPLUSPLUS
1419 ac_save_CXXFLAGS="$CXXFLAGS"
1420 CXXFLAGS="$CXXFLAGS -fno-exceptions"
1421 ac_save_LIBS="$LIBS"
1422
1423 ac_has_clock_monotonic=no
1424 ac_has_clock_realtime=no
1425 ac_has_nanosleep=no
1426 ac_has_sched_yield=no
1427
1428 if test x"$enable_libstdcxx_time" = x"auto"; then
1429
1430 case "${target_os}" in
1431 cygwin*)
1432 ac_has_nanosleep=yes
1433 ;;
1434 darwin*)
1435 ac_has_nanosleep=yes
1436 ac_has_sched_yield=yes
1437 ;;
1438 gnu* | linux* | kfreebsd*-gnu | knetbsd*-gnu)
1439 AC_MSG_CHECKING([for at least GNU libc 2.17])
1440 AC_TRY_COMPILE(
1441 [#include <features.h>],
1442 [
1443 #if ! __GLIBC_PREREQ(2, 17)
1444 #error
1445 #endif
1446 ],
1447 [glibcxx_glibc217=yes], [glibcxx_glibc217=no])
1448 AC_MSG_RESULT($glibcxx_glibc217)
1449
1450 if test x"$glibcxx_glibc217" = x"yes"; then
1451 ac_has_clock_monotonic=yes
1452 ac_has_clock_realtime=yes
1453 fi
1454 ac_has_nanosleep=yes
1455 ac_has_sched_yield=yes
1456 ;;
1457 freebsd*|netbsd*|dragonfly*)
1458 ac_has_clock_monotonic=yes
1459 ac_has_clock_realtime=yes
1460 ac_has_nanosleep=yes
1461 ac_has_sched_yield=yes
1462 ;;
1463 openbsd*)
1464 ac_has_clock_monotonic=yes
1465 ac_has_clock_realtime=yes
1466 ac_has_nanosleep=yes
1467 ;;
1468 solaris*)
1469 GLIBCXX_LIBS="$GLIBCXX_LIBS -lrt"
1470 ac_has_clock_monotonic=yes
1471 ac_has_clock_realtime=yes
1472 ac_has_nanosleep=yes
1473 ac_has_sched_yield=yes
1474 ;;
1475 esac
1476
1477 elif test x"$enable_libstdcxx_time" != x"no"; then
1478
1479 if test x"$enable_libstdcxx_time" = x"rt"; then
1480 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1481 AC_SEARCH_LIBS(nanosleep, [rt posix4])
1482 else
1483 AC_SEARCH_LIBS(clock_gettime, [posix4])
1484 AC_SEARCH_LIBS(nanosleep, [posix4])
1485 fi
1486
1487 case "$ac_cv_search_clock_gettime" in
1488 -l*) GLIBCXX_LIBS=$ac_cv_search_clock_gettime
1489 ;;
1490 esac
1491 case "$ac_cv_search_nanosleep" in
1492 -l*) GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_nanosleep"
1493 ;;
1494 esac
1495
1496 AC_SEARCH_LIBS(sched_yield, [rt posix4])
1497
1498 case "$ac_cv_search_sched_yield" in
1499 -lposix4*)
1500 GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1501 ac_has_sched_yield=yes
1502 ;;
1503 -lrt*)
1504 if test x"$enable_libstdcxx_time" = x"rt"; then
1505 GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1506 ac_has_sched_yield=yes
1507 fi
1508 ;;
1509 *)
1510 ac_has_sched_yield=yes
1511 ;;
1512 esac
1513
1514 AC_CHECK_HEADERS(unistd.h, ac_has_unistd_h=yes, ac_has_unistd_h=no)
1515
1516 if test x"$ac_has_unistd_h" = x"yes"; then
1517 AC_MSG_CHECKING([for monotonic clock])
1518 AC_TRY_LINK(
1519 [#include <unistd.h>
1520 #include <time.h>
1521 ],
1522 [#if _POSIX_TIMERS > 0 && defined(_POSIX_MONOTONIC_CLOCK)
1523 timespec tp;
1524 #endif
1525 clock_gettime(CLOCK_MONOTONIC, &tp);
1526 ], [ac_has_clock_monotonic=yes], [ac_has_clock_monotonic=no])
1527
1528 AC_MSG_RESULT($ac_has_clock_monotonic)
1529
1530 AC_MSG_CHECKING([for realtime clock])
1531 AC_TRY_LINK(
1532 [#include <unistd.h>
1533 #include <time.h>
1534 ],
1535 [#if _POSIX_TIMERS > 0
1536 timespec tp;
1537 #endif
1538 clock_gettime(CLOCK_REALTIME, &tp);
1539 ], [ac_has_clock_realtime=yes], [ac_has_clock_realtime=no])
1540
1541 AC_MSG_RESULT($ac_has_clock_realtime)
1542
1543 AC_MSG_CHECKING([for nanosleep])
1544 AC_TRY_LINK(
1545 [#include <unistd.h>
1546 #include <time.h>
1547 ],
1548 [#if _POSIX_TIMERS > 0
1549 timespec tp;
1550 #endif
1551 nanosleep(&tp, 0);
1552 ], [ac_has_nanosleep=yes], [ac_has_nanosleep=no])
1553
1554 AC_MSG_RESULT($ac_has_nanosleep)
1555 fi
1556 fi
1557
1558 if test x"$ac_has_clock_monotonic" != x"yes"; then
1559 case ${target_os} in
1560 linux*)
1561 AC_MSG_CHECKING([for clock_gettime syscall])
1562 AC_TRY_COMPILE(
1563 [#include <unistd.h>
1564 #include <time.h>
1565 #include <sys/syscall.h>
1566 ],
1567 [#if _POSIX_TIMERS > 0 && defined(_POSIX_MONOTONIC_CLOCK)
1568 timespec tp;
1569 #endif
1570 syscall(SYS_clock_gettime, CLOCK_MONOTONIC, &tp);
1571 syscall(SYS_clock_gettime, CLOCK_REALTIME, &tp);
1572 ], [ac_has_clock_monotonic_syscall=yes], [ac_has_clock_monotonic_syscall=no])
1573 AC_MSG_RESULT($ac_has_clock_monotonic_syscall)
1574 if test x"$ac_has_clock_monotonic_syscall" = x"yes"; then
1575 AC_DEFINE(_GLIBCXX_USE_CLOCK_GETTIME_SYSCALL, 1,
1576 [ Defined if clock_gettime syscall has monotonic and realtime clock support. ])
1577 ac_has_clock_monotonic=yes
1578 ac_has_clock_realtime=yes
1579 fi;;
1580 esac
1581 fi
1582
1583 if test x"$ac_has_clock_monotonic" = x"yes"; then
1584 AC_DEFINE(_GLIBCXX_USE_CLOCK_MONOTONIC, 1,
1585 [ Defined if clock_gettime has monotonic clock support. ])
1586 fi
1587
1588 if test x"$ac_has_clock_realtime" = x"yes"; then
1589 AC_DEFINE(_GLIBCXX_USE_CLOCK_REALTIME, 1,
1590 [ Defined if clock_gettime has realtime clock support. ])
1591 fi
1592
1593 if test x"$ac_has_sched_yield" = x"yes"; then
1594 AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1595 [ Defined if sched_yield is available. ])
1596 fi
1597
1598 if test x"$ac_has_nanosleep" = x"yes"; then
1599 AC_DEFINE(_GLIBCXX_USE_NANOSLEEP, 1,
1600 [ Defined if nanosleep is available. ])
1601 else
1602 AC_MSG_CHECKING([for sleep])
1603 AC_TRY_COMPILE([#include <unistd.h>],
1604 [sleep(1)],
1605 [ac_has_sleep=yes],[ac_has_sleep=no])
1606 if test x"$ac_has_sleep" = x"yes"; then
1607 AC_DEFINE(HAVE_SLEEP,1, [Defined if sleep exists.])
1608 fi
1609 AC_MSG_RESULT($ac_has_sleep)
1610 AC_MSG_CHECKING([for usleep])
1611 AC_TRY_COMPILE([#include <unistd.h>],
1612 [sleep(1);
1613 usleep(100);],
1614 [ac_has_usleep=yes],[ac_has_usleep=no])
1615 if test x"$ac_has_usleep" = x"yes"; then
1616 AC_DEFINE(HAVE_USLEEP,1, [Defined if usleep exists.])
1617 fi
1618 AC_MSG_RESULT($ac_has_usleep)
1619 fi
1620
1621 if test x"$ac_has_nanosleep$ac_has_sleep" = x"nono"; then
1622 AC_MSG_CHECKING([for Sleep])
1623 AC_TRY_COMPILE([#include <windows.h>],
1624 [Sleep(1)],
1625 [ac_has_win32_sleep=yes],[ac_has_win32_sleep=no])
1626 if test x"$ac_has_win32_sleep" = x"yes"; then
1627 AC_DEFINE(HAVE_WIN32_SLEEP,1, [Defined if Sleep exists.])
1628 fi
1629 AC_MSG_RESULT($ac_has_win32_sleep)
1630 fi
1631
1632 AC_SUBST(GLIBCXX_LIBS)
1633
1634 CXXFLAGS="$ac_save_CXXFLAGS"
1635 LIBS="$ac_save_LIBS"
1636 AC_LANG_RESTORE
1637 ])
1638
1639 dnl
1640 dnl Check for gettimeofday, used in the implementation of 20.11.7
1641 dnl [time.clock] in the C++11 standard.
1642 dnl
1643 AC_DEFUN([GLIBCXX_CHECK_GETTIMEOFDAY], [
1644
1645 AC_MSG_CHECKING([for gettimeofday])
1646
1647 AC_LANG_SAVE
1648 AC_LANG_CPLUSPLUS
1649 ac_save_CXXFLAGS="$CXXFLAGS"
1650 CXXFLAGS="$CXXFLAGS -fno-exceptions"
1651
1652 ac_has_gettimeofday=no;
1653 AC_CHECK_HEADERS(sys/time.h, ac_has_sys_time_h=yes, ac_has_sys_time_h=no)
1654 if test x"$ac_has_sys_time_h" = x"yes"; then
1655 AC_MSG_CHECKING([for gettimeofday])
1656 GCC_TRY_COMPILE_OR_LINK([#include <sys/time.h>],
1657 [timeval tv; gettimeofday(&tv, 0);],
1658 [ac_has_gettimeofday=yes], [ac_has_gettimeofday=no])
1659
1660 AC_MSG_RESULT($ac_has_gettimeofday)
1661 fi
1662
1663 if test x"$ac_has_gettimeofday" = x"yes"; then
1664 AC_DEFINE(_GLIBCXX_USE_GETTIMEOFDAY, 1,
1665 [ Defined if gettimeofday is available. ])
1666 fi
1667
1668 CXXFLAGS="$ac_save_CXXFLAGS"
1669 AC_LANG_RESTORE
1670 ])
1671
1672 dnl
1673 dnl Check for ISO/IEC 9899:1999 "C99" support to ISO/IEC DTR 19768 "TR1"
1674 dnl facilities in Chapter 8, "C compatibility".
1675 dnl
1676 AC_DEFUN([GLIBCXX_CHECK_C99_TR1], [
1677
1678 AC_LANG_SAVE
1679 AC_LANG_CPLUSPLUS
1680
1681 # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
1682 # undefined and fake C99 facilities may be spuriously enabled.
1683 ac_save_CXXFLAGS="$CXXFLAGS"
1684 CXXFLAGS="$CXXFLAGS -std=c++98"
1685
1686 # Check for the existence of <complex.h> complex math functions used
1687 # by tr1/complex.
1688 AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
1689 ac_c99_complex_tr1=no;
1690 if test x"$ac_has_complex_h" = x"yes"; then
1691 AC_MSG_CHECKING([for ISO C99 support to TR1 in <complex.h>])
1692 AC_TRY_COMPILE([#include <complex.h>],
1693 [typedef __complex__ float float_type; float_type tmpf;
1694 cacosf(tmpf);
1695 casinf(tmpf);
1696 catanf(tmpf);
1697 cacoshf(tmpf);
1698 casinhf(tmpf);
1699 catanhf(tmpf);
1700 typedef __complex__ double double_type; double_type tmpd;
1701 cacos(tmpd);
1702 casin(tmpd);
1703 catan(tmpd);
1704 cacosh(tmpd);
1705 casinh(tmpd);
1706 catanh(tmpd);
1707 typedef __complex__ long double ld_type; ld_type tmpld;
1708 cacosl(tmpld);
1709 casinl(tmpld);
1710 catanl(tmpld);
1711 cacoshl(tmpld);
1712 casinhl(tmpld);
1713 catanhl(tmpld);
1714 ],[ac_c99_complex_tr1=yes], [ac_c99_complex_tr1=no])
1715 fi
1716 AC_MSG_RESULT($ac_c99_complex_tr1)
1717 if test x"$ac_c99_complex_tr1" = x"yes"; then
1718 AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX_TR1, 1,
1719 [Define if C99 functions in <complex.h> should be used in
1720 <tr1/complex>. Using compiler builtins for these functions
1721 requires corresponding C99 library functions to be present.])
1722 fi
1723
1724 # Check for the existence of <ctype.h> functions.
1725 AC_MSG_CHECKING([for ISO C99 support to TR1 in <ctype.h>])
1726 AC_CACHE_VAL(glibcxx_cv_c99_ctype_tr1, [
1727 AC_TRY_COMPILE([#include <ctype.h>],
1728 [int ch;
1729 int ret;
1730 ret = isblank(ch);
1731 ],[glibcxx_cv_c99_ctype_tr1=yes],
1732 [glibcxx_cv_c99_ctype_tr1=no])
1733 ])
1734 AC_MSG_RESULT($glibcxx_cv_c99_ctype_tr1)
1735 if test x"$glibcxx_cv_c99_ctype_tr1" = x"yes"; then
1736 AC_DEFINE(_GLIBCXX_USE_C99_CTYPE_TR1, 1,
1737 [Define if C99 functions in <ctype.h> should be imported in
1738 <tr1/cctype> in namespace std::tr1.])
1739 fi
1740
1741 # Check for the existence of <fenv.h> functions.
1742 AC_CHECK_HEADERS(fenv.h, ac_has_fenv_h=yes, ac_has_fenv_h=no)
1743 ac_c99_fenv_tr1=no;
1744 if test x"$ac_has_fenv_h" = x"yes"; then
1745 AC_MSG_CHECKING([for ISO C99 support to TR1 in <fenv.h>])
1746 AC_TRY_COMPILE([#include <fenv.h>],
1747 [int except, mode;
1748 fexcept_t* pflag;
1749 fenv_t* penv;
1750 int ret;
1751 ret = feclearexcept(except);
1752 ret = fegetexceptflag(pflag, except);
1753 ret = feraiseexcept(except);
1754 ret = fesetexceptflag(pflag, except);
1755 ret = fetestexcept(except);
1756 ret = fegetround();
1757 ret = fesetround(mode);
1758 ret = fegetenv(penv);
1759 ret = feholdexcept(penv);
1760 ret = fesetenv(penv);
1761 ret = feupdateenv(penv);
1762 ],[ac_c99_fenv_tr1=yes], [ac_c99_fenv_tr1=no])
1763 fi
1764 AC_MSG_RESULT($ac_c99_fenv_tr1)
1765 if test x"$ac_c99_fenv_tr1" = x"yes"; then
1766 AC_DEFINE(_GLIBCXX_USE_C99_FENV_TR1, 1,
1767 [Define if C99 functions in <fenv.h> should be imported in
1768 <tr1/cfenv> in namespace std::tr1.])
1769 fi
1770
1771 # Check for the existence of <stdint.h> types.
1772 AC_MSG_CHECKING([for ISO C99 support to TR1 in <stdint.h>])
1773 AC_CACHE_VAL(glibcxx_cv_c99_stdint_tr1, [
1774 AC_TRY_COMPILE([#define __STDC_LIMIT_MACROS
1775 #define __STDC_CONSTANT_MACROS
1776 #include <stdint.h>],
1777 [typedef int8_t my_int8_t;
1778 my_int8_t i8 = INT8_MIN;
1779 i8 = INT8_MAX;
1780 typedef int16_t my_int16_t;
1781 my_int16_t i16 = INT16_MIN;
1782 i16 = INT16_MAX;
1783 typedef int32_t my_int32_t;
1784 my_int32_t i32 = INT32_MIN;
1785 i32 = INT32_MAX;
1786 typedef int64_t my_int64_t;
1787 my_int64_t i64 = INT64_MIN;
1788 i64 = INT64_MAX;
1789 typedef int_fast8_t my_int_fast8_t;
1790 my_int_fast8_t if8 = INT_FAST8_MIN;
1791 if8 = INT_FAST8_MAX;
1792 typedef int_fast16_t my_int_fast16_t;
1793 my_int_fast16_t if16 = INT_FAST16_MIN;
1794 if16 = INT_FAST16_MAX;
1795 typedef int_fast32_t my_int_fast32_t;
1796 my_int_fast32_t if32 = INT_FAST32_MIN;
1797 if32 = INT_FAST32_MAX;
1798 typedef int_fast64_t my_int_fast64_t;
1799 my_int_fast64_t if64 = INT_FAST64_MIN;
1800 if64 = INT_FAST64_MAX;
1801 typedef int_least8_t my_int_least8_t;
1802 my_int_least8_t il8 = INT_LEAST8_MIN;
1803 il8 = INT_LEAST8_MAX;
1804 typedef int_least16_t my_int_least16_t;
1805 my_int_least16_t il16 = INT_LEAST16_MIN;
1806 il16 = INT_LEAST16_MAX;
1807 typedef int_least32_t my_int_least32_t;
1808 my_int_least32_t il32 = INT_LEAST32_MIN;
1809 il32 = INT_LEAST32_MAX;
1810 typedef int_least64_t my_int_least64_t;
1811 my_int_least64_t il64 = INT_LEAST64_MIN;
1812 il64 = INT_LEAST64_MAX;
1813 typedef intmax_t my_intmax_t;
1814 my_intmax_t im = INTMAX_MAX;
1815 im = INTMAX_MIN;
1816 typedef intptr_t my_intptr_t;
1817 my_intptr_t ip = INTPTR_MAX;
1818 ip = INTPTR_MIN;
1819 typedef uint8_t my_uint8_t;
1820 my_uint8_t ui8 = UINT8_MAX;
1821 ui8 = UINT8_MAX;
1822 typedef uint16_t my_uint16_t;
1823 my_uint16_t ui16 = UINT16_MAX;
1824 ui16 = UINT16_MAX;
1825 typedef uint32_t my_uint32_t;
1826 my_uint32_t ui32 = UINT32_MAX;
1827 ui32 = UINT32_MAX;
1828 typedef uint64_t my_uint64_t;
1829 my_uint64_t ui64 = UINT64_MAX;
1830 ui64 = UINT64_MAX;
1831 typedef uint_fast8_t my_uint_fast8_t;
1832 my_uint_fast8_t uif8 = UINT_FAST8_MAX;
1833 uif8 = UINT_FAST8_MAX;
1834 typedef uint_fast16_t my_uint_fast16_t;
1835 my_uint_fast16_t uif16 = UINT_FAST16_MAX;
1836 uif16 = UINT_FAST16_MAX;
1837 typedef uint_fast32_t my_uint_fast32_t;
1838 my_uint_fast32_t uif32 = UINT_FAST32_MAX;
1839 uif32 = UINT_FAST32_MAX;
1840 typedef uint_fast64_t my_uint_fast64_t;
1841 my_uint_fast64_t uif64 = UINT_FAST64_MAX;
1842 uif64 = UINT_FAST64_MAX;
1843 typedef uint_least8_t my_uint_least8_t;
1844 my_uint_least8_t uil8 = UINT_LEAST8_MAX;
1845 uil8 = UINT_LEAST8_MAX;
1846 typedef uint_least16_t my_uint_least16_t;
1847 my_uint_least16_t uil16 = UINT_LEAST16_MAX;
1848 uil16 = UINT_LEAST16_MAX;
1849 typedef uint_least32_t my_uint_least32_t;
1850 my_uint_least32_t uil32 = UINT_LEAST32_MAX;
1851 uil32 = UINT_LEAST32_MAX;
1852 typedef uint_least64_t my_uint_least64_t;
1853 my_uint_least64_t uil64 = UINT_LEAST64_MAX;
1854 uil64 = UINT_LEAST64_MAX;
1855 typedef uintmax_t my_uintmax_t;
1856 my_uintmax_t uim = UINTMAX_MAX;
1857 uim = UINTMAX_MAX;
1858 typedef uintptr_t my_uintptr_t;
1859 my_uintptr_t uip = UINTPTR_MAX;
1860 uip = UINTPTR_MAX;
1861 ],[glibcxx_cv_c99_stdint_tr1=yes],
1862 [glibcxx_cv_c99_stdint_tr1=no])
1863 ])
1864 AC_MSG_RESULT($glibcxx_cv_c99_stdint_tr1)
1865 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1866 AC_DEFINE(_GLIBCXX_USE_C99_STDINT_TR1, 1,
1867 [Define if C99 types in <stdint.h> should be imported in
1868 <tr1/cstdint> in namespace std::tr1.])
1869 fi
1870
1871 # Check for the existence of <math.h> functions.
1872 AC_MSG_CHECKING([for ISO C99 support to TR1 in <math.h>])
1873 AC_CACHE_VAL(glibcxx_cv_c99_math_tr1, [
1874 AC_TRY_COMPILE([#include <math.h>],
1875 [typedef double_t my_double_t;
1876 typedef float_t my_float_t;
1877 acosh(0.0);
1878 acoshf(0.0f);
1879 acoshl(0.0l);
1880 asinh(0.0);
1881 asinhf(0.0f);
1882 asinhl(0.0l);
1883 atanh(0.0);
1884 atanhf(0.0f);
1885 atanhl(0.0l);
1886 cbrt(0.0);
1887 cbrtf(0.0f);
1888 cbrtl(0.0l);
1889 copysign(0.0, 0.0);
1890 copysignf(0.0f, 0.0f);
1891 copysignl(0.0l, 0.0l);
1892 erf(0.0);
1893 erff(0.0f);
1894 erfl(0.0l);
1895 erfc(0.0);
1896 erfcf(0.0f);
1897 erfcl(0.0l);
1898 exp2(0.0);
1899 exp2f(0.0f);
1900 exp2l(0.0l);
1901 expm1(0.0);
1902 expm1f(0.0f);
1903 expm1l(0.0l);
1904 fdim(0.0, 0.0);
1905 fdimf(0.0f, 0.0f);
1906 fdiml(0.0l, 0.0l);
1907 fma(0.0, 0.0, 0.0);
1908 fmaf(0.0f, 0.0f, 0.0f);
1909 fmal(0.0l, 0.0l, 0.0l);
1910 fmax(0.0, 0.0);
1911 fmaxf(0.0f, 0.0f);
1912 fmaxl(0.0l, 0.0l);
1913 fmin(0.0, 0.0);
1914 fminf(0.0f, 0.0f);
1915 fminl(0.0l, 0.0l);
1916 hypot(0.0, 0.0);
1917 hypotf(0.0f, 0.0f);
1918 hypotl(0.0l, 0.0l);
1919 ilogb(0.0);
1920 ilogbf(0.0f);
1921 ilogbl(0.0l);
1922 lgamma(0.0);
1923 lgammaf(0.0f);
1924 lgammal(0.0l);
1925 llrint(0.0);
1926 llrintf(0.0f);
1927 llrintl(0.0l);
1928 llround(0.0);
1929 llroundf(0.0f);
1930 llroundl(0.0l);
1931 log1p(0.0);
1932 log1pf(0.0f);
1933 log1pl(0.0l);
1934 log2(0.0);
1935 log2f(0.0f);
1936 log2l(0.0l);
1937 logb(0.0);
1938 logbf(0.0f);
1939 logbl(0.0l);
1940 lrint(0.0);
1941 lrintf(0.0f);
1942 lrintl(0.0l);
1943 lround(0.0);
1944 lroundf(0.0f);
1945 lroundl(0.0l);
1946 nan(0);
1947 nanf(0);
1948 nanl(0);
1949 nearbyint(0.0);
1950 nearbyintf(0.0f);
1951 nearbyintl(0.0l);
1952 nextafter(0.0, 0.0);
1953 nextafterf(0.0f, 0.0f);
1954 nextafterl(0.0l, 0.0l);
1955 nexttoward(0.0, 0.0);
1956 nexttowardf(0.0f, 0.0f);
1957 nexttowardl(0.0l, 0.0l);
1958 remainder(0.0, 0.0);
1959 remainderf(0.0f, 0.0f);
1960 remainderl(0.0l, 0.0l);
1961 remquo(0.0, 0.0, 0);
1962 remquof(0.0f, 0.0f, 0);
1963 remquol(0.0l, 0.0l, 0);
1964 rint(0.0);
1965 rintf(0.0f);
1966 rintl(0.0l);
1967 round(0.0);
1968 roundf(0.0f);
1969 roundl(0.0l);
1970 scalbln(0.0, 0l);
1971 scalblnf(0.0f, 0l);
1972 scalblnl(0.0l, 0l);
1973 scalbn(0.0, 0);
1974 scalbnf(0.0f, 0);
1975 scalbnl(0.0l, 0);
1976 tgamma(0.0);
1977 tgammaf(0.0f);
1978 tgammal(0.0l);
1979 trunc(0.0);
1980 truncf(0.0f);
1981 truncl(0.0l);
1982 ],[glibcxx_cv_c99_math_tr1=yes], [glibcxx_cv_c99_math_tr1=no])
1983 ])
1984 AC_MSG_RESULT($glibcxx_cv_c99_math_tr1)
1985 if test x"$glibcxx_cv_c99_math_tr1" = x"yes"; then
1986 AC_DEFINE(_GLIBCXX_USE_C99_MATH_TR1, 1,
1987 [Define if C99 functions or macros in <math.h> should be imported
1988 in <tr1/cmath> in namespace std::tr1.])
1989 fi
1990
1991 # Check for the existence of <inttypes.h> functions (NB: doesn't make
1992 # sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
1993 ac_c99_inttypes_tr1=no;
1994 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1995 AC_MSG_CHECKING([for ISO C99 support to TR1 in <inttypes.h>])
1996 AC_TRY_COMPILE([#include <inttypes.h>],
1997 [intmax_t i, numer, denom, base;
1998 const char* s;
1999 char** endptr;
2000 intmax_t ret = imaxabs(i);
2001 imaxdiv_t dret = imaxdiv(numer, denom);
2002 ret = strtoimax(s, endptr, base);
2003 uintmax_t uret = strtoumax(s, endptr, base);
2004 ],[ac_c99_inttypes_tr1=yes], [ac_c99_inttypes_tr1=no])
2005 fi
2006 AC_MSG_RESULT($ac_c99_inttypes_tr1)
2007 if test x"$ac_c99_inttypes_tr1" = x"yes"; then
2008 AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_TR1, 1,
2009 [Define if C99 functions in <inttypes.h> should be imported in
2010 <tr1/cinttypes> in namespace std::tr1.])
2011 fi
2012
2013 # Check for the existence of wchar_t <inttypes.h> functions (NB: doesn't
2014 # make sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
2015 ac_c99_inttypes_wchar_t_tr1=no;
2016 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
2017 AC_MSG_CHECKING([for wchar_t ISO C99 support to TR1 in <inttypes.h>])
2018 AC_TRY_COMPILE([#include <inttypes.h>],
2019 [intmax_t base;
2020 const wchar_t* s;
2021 wchar_t** endptr;
2022 intmax_t ret = wcstoimax(s, endptr, base);
2023 uintmax_t uret = wcstoumax(s, endptr, base);
2024 ],[ac_c99_inttypes_wchar_t_tr1=yes],
2025 [ac_c99_inttypes_wchar_t_tr1=no])
2026 fi
2027 AC_MSG_RESULT($ac_c99_inttypes_wchar_t_tr1)
2028 if test x"$ac_c99_inttypes_wchar_t_tr1" = x"yes"; then
2029 AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_WCHAR_T_TR1, 1,
2030 [Define if wchar_t C99 functions in <inttypes.h> should be
2031 imported in <tr1/cinttypes> in namespace std::tr1.])
2032 fi
2033
2034 # Check for the existence of the <stdbool.h> header.
2035 AC_CHECK_HEADERS(stdbool.h)
2036
2037 # Check for the existence of the <stdalign.h> header.
2038 AC_CHECK_HEADERS(stdalign.h)
2039
2040 CXXFLAGS="$ac_save_CXXFLAGS"
2041 AC_LANG_RESTORE
2042 ])
2043
2044 dnl
2045 dnl Check for uchar.h and usability.
2046 dnl
2047 AC_DEFUN([GLIBCXX_CHECK_UCHAR_H], [
2048
2049 # Test uchar.h.
2050 AC_CHECK_HEADERS(uchar.h, ac_has_uchar_h=yes, ac_has_uchar_h=no)
2051
2052 AC_LANG_SAVE
2053 AC_LANG_CPLUSPLUS
2054 ac_save_CXXFLAGS="$CXXFLAGS"
2055 CXXFLAGS="$CXXFLAGS -std=c++11"
2056
2057 if test x"$ac_has_uchar_h" = x"yes"; then
2058 AC_MSG_CHECKING([for ISO C11 support for <uchar.h>])
2059 AC_TRY_COMPILE([#include <uchar.h>
2060 #ifdef __STDC_UTF_16__
2061 long i = __STDC_UTF_16__;
2062 #endif
2063 #ifdef __STDC_UTF_32__
2064 long j = __STDC_UTF_32__;
2065 #endif
2066 namespace test
2067 {
2068 using ::c16rtomb;
2069 using ::c32rtomb;
2070 using ::mbrtoc16;
2071 using ::mbrtoc32;
2072 }
2073 ],
2074 [], [ac_c11_uchar_cxx11=yes], [ac_c11_uchar_cxx11=no])
2075 else
2076 ac_c11_uchar_cxx11=no
2077 fi
2078 AC_MSG_RESULT($ac_c11_uchar_cxx11)
2079 if test x"$ac_c11_uchar_cxx11" = x"yes"; then
2080 AC_DEFINE(_GLIBCXX_USE_C11_UCHAR_CXX11, 1,
2081 [Define if C11 functions in <uchar.h> should be imported into
2082 namespace std in <cuchar>.])
2083 fi
2084
2085 CXXFLAGS="$ac_save_CXXFLAGS"
2086 AC_LANG_RESTORE
2087 ])
2088
2089
2090 dnl
2091 dnl Check whether "/dev/random" and "/dev/urandom" are available for the
2092 dnl random_device of "TR1" (Chapter 5.1, "Random number generation").
2093 dnl
2094 AC_DEFUN([GLIBCXX_CHECK_RANDOM_TR1], [
2095
2096 AC_MSG_CHECKING([for "/dev/random" and "/dev/urandom" for TR1 random_device])
2097 AC_CACHE_VAL(glibcxx_cv_random_tr1, [
2098 if test -r /dev/random && test -r /dev/urandom; then
2099 ## For MSys environment the test above is detect as false-positive
2100 ## on mingw-targets. So disable it explicit for them.
2101 case ${target_os} in
2102 *mingw*) glibcxx_cv_random_tr1=no ;;
2103 *) glibcxx_cv_random_tr1=yes ;;
2104 esac
2105 else
2106 glibcxx_cv_random_tr1=no;
2107 fi
2108 ])
2109 AC_MSG_RESULT($glibcxx_cv_random_tr1)
2110
2111 if test x"$glibcxx_cv_random_tr1" = x"yes"; then
2112 AC_DEFINE(_GLIBCXX_USE_RANDOM_TR1, 1,
2113 [Define if /dev/random and /dev/urandom are available for
2114 the random_device of TR1 (Chapter 5.1).])
2115 fi
2116
2117 ])
2118
2119 dnl
2120 dnl Compute the EOF, SEEK_CUR, and SEEK_END integer constants.
2121 dnl
2122 AC_DEFUN([GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS], [
2123
2124 AC_CACHE_CHECK([for the value of EOF], glibcxx_cv_stdio_eof, [
2125 AC_COMPUTE_INT([glibcxx_cv_stdio_eof], [[EOF]],
2126 [#include <stdio.h>],
2127 [AC_MSG_ERROR([computing EOF failed])])
2128 ])
2129 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_EOF, $glibcxx_cv_stdio_eof,
2130 [Define to the value of the EOF integer constant.])
2131
2132 AC_CACHE_CHECK([for the value of SEEK_CUR], glibcxx_cv_stdio_seek_cur, [
2133 AC_COMPUTE_INT([glibcxx_cv_stdio_seek_cur], [[SEEK_CUR]],
2134 [#include <stdio.h>],
2135 [AC_MSG_ERROR([computing SEEK_CUR failed])])
2136 ])
2137 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_CUR, $glibcxx_cv_stdio_seek_cur,
2138 [Define to the value of the SEEK_CUR integer constant.])
2139
2140 AC_CACHE_CHECK([for the value of SEEK_END], glibcxx_cv_stdio_seek_end, [
2141 AC_COMPUTE_INT([glibcxx_cv_stdio_seek_end], [[SEEK_END]],
2142 [#include <stdio.h>],
2143 [AC_MSG_ERROR([computing SEEK_END failed])])
2144 ])
2145 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_END, $glibcxx_cv_stdio_seek_end,
2146 [Define to the value of the SEEK_END integer constant.])
2147 ])
2148
2149 dnl
2150 dnl Check whether required C++ overloads are present in <stdio.h>.
2151 dnl
2152 AC_DEFUN([GLIBCXX_CHECK_STDIO_PROTO], [
2153
2154 AC_LANG_SAVE
2155 AC_LANG_CPLUSPLUS
2156 # Use C++11 because a conforming <stdio.h> won't define gets for C++14,
2157 # and we don't need a declaration for C++14 anyway.
2158 ac_save_CXXFLAGS="$CXXFLAGS"
2159 CXXFLAGS="$CXXFLAGS -std=gnu++11"
2160
2161 AC_MSG_CHECKING([for gets declaration])
2162 AC_CACHE_VAL(glibcxx_cv_gets, [
2163 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
2164 [#include <stdio.h>
2165 namespace test
2166 {
2167 using ::gets;
2168 }
2169 ])],
2170 [glibcxx_cv_gets=yes],
2171 [glibcxx_cv_gets=no]
2172 )])
2173
2174 if test $glibcxx_cv_gets = yes; then
2175 AC_DEFINE(HAVE_GETS, 1, [Define if gets is available in <stdio.h> before C++14.])
2176 fi
2177 AC_MSG_RESULT($glibcxx_cv_gets)
2178
2179 CXXFLAGS="$ac_save_CXXFLAGS"
2180 AC_LANG_RESTORE
2181 ])
2182
2183 dnl
2184 dnl Check whether required C++11 overloads are present in <math.h>.
2185 dnl
2186 AC_DEFUN([GLIBCXX_CHECK_MATH11_PROTO], [
2187
2188 AC_LANG_SAVE
2189 AC_LANG_CPLUSPLUS
2190 ac_save_CXXFLAGS="$CXXFLAGS"
2191 CXXFLAGS="$CXXFLAGS -std=c++11"
2192
2193 case "$host" in
2194 *-*-solaris2.*)
2195 # Solaris 12 introduced the C++11 <math.h> overloads. A backport to
2196 # a Solaris 11.3 SRU is likely, maybe even a Solaris 10 patch.
2197 AC_MSG_CHECKING([for C++11 <math.h> overloads])
2198 AC_CACHE_VAL(glibcxx_cv_math11_overload, [
2199 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
2200 [#include <math.h>
2201 #undef isfinite
2202 namespace std {
2203 inline bool isfinite(float __x)
2204 { return __builtin_isfinite(__x); }
2205 }
2206 ])],
2207 [glibcxx_cv_math11_overload=no],
2208 [glibcxx_cv_math11_overload=yes]
2209 )])
2210
2211 # autoheader cannot handle indented templates.
2212 AH_VERBATIM([__CORRECT_ISO_CPP11_MATH_H_PROTO],
2213 [/* Define if all C++11 overloads are available in <math.h>. */
2214 #if __cplusplus >= 201103L
2215 #undef __CORRECT_ISO_CPP11_MATH_H_PROTO
2216 #endif])
2217
2218 if test $glibcxx_cv_math11_overload = yes; then
2219 AC_DEFINE(__CORRECT_ISO_CPP11_MATH_H_PROTO)
2220 fi
2221 AC_MSG_RESULT([$glibcxx_cv_math11_overload])
2222 ;;
2223 *)
2224 # If <math.h> defines the obsolete isinf(double) and isnan(double)
2225 # functions (instead of or as well as the C99 generic macros) then we
2226 # can't define std::isinf(double) and std::isnan(double) in <cmath>
2227 # and must use the ones from <math.h> instead.
2228 AC_MSG_CHECKING([for obsolete isinf function in <math.h>])
2229 AC_CACHE_VAL(glibcxx_cv_obsolete_isinf, [
2230 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
2231 [#define _GLIBCXX_INCLUDE_NEXT_C_HEADERS
2232 #include <math.h>
2233 #undef isinf
2234 namespace std {
2235 using ::isinf;
2236 bool isinf(float);
2237 bool isinf(long double);
2238 }
2239 using std::isinf;
2240 bool b = isinf(0.0);
2241 ])],
2242 [glibcxx_cv_obsolete_isinf=yes],
2243 [glibcxx_cv_obsolete_isinf=no]
2244 )])
2245 AC_MSG_RESULT([$glibcxx_cv_obsolete_isinf])
2246 if test $glibcxx_cv_obsolete_isinf = yes; then
2247 AC_DEFINE(HAVE_OBSOLETE_ISINF, 1,
2248 [Define if <math.h> defines obsolete isinf function.])
2249 fi
2250
2251 AC_MSG_CHECKING([for obsolete isnan function in <math.h>])
2252 AC_CACHE_VAL(glibcxx_cv_obsolete_isnan, [
2253 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
2254 [#include <math.h>
2255 #undef isnan
2256 namespace std {
2257 using ::isnan;
2258 bool isnan(float);
2259 bool isnan(long double);
2260 }
2261 using std::isnan;
2262 bool b = isnan(0.0);
2263 ])],
2264 [glibcxx_cv_obsolete_isnan=yes],
2265 [glibcxx_cv_obsolete_isnan=no]
2266 )])
2267 AC_MSG_RESULT([$glibcxx_cv_obsolete_isnan])
2268 if test $glibcxx_cv_obsolete_isnan = yes; then
2269 AC_DEFINE(HAVE_OBSOLETE_ISNAN, 1,
2270 [Define if <math.h> defines obsolete isnan function.])
2271 fi
2272 ;;
2273 esac
2274
2275 CXXFLAGS="$ac_save_CXXFLAGS"
2276 AC_LANG_RESTORE
2277 ])
2278
2279 dnl
2280 dnl Check whether macros, etc are present for <system_error>
2281 dnl
2282 AC_DEFUN([GLIBCXX_CHECK_SYSTEM_ERROR], [
2283
2284 m4_pushdef([n_syserr], [1])dnl
2285 m4_foreach([syserr], [EOWNERDEAD, ENOTRECOVERABLE, ENOLINK, EPROTO, ENODATA,
2286 ENOSR, ENOSTR, ETIME, EBADMSG, ECANCELED,
2287 EOVERFLOW, ENOTSUP, EIDRM, ETXTBSY,
2288 ECHILD, ENOSPC, EPERM,
2289 ETIMEDOUT, EWOULDBLOCK],
2290 [m4_pushdef([SYSERR], m4_toupper(syserr))dnl
2291 AC_MSG_CHECKING([for syserr])
2292 AC_CACHE_VAL([glibcxx_cv_system_error[]n_syserr], [
2293 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
2294 [int i = syserr;])],
2295 [glibcxx_cv_system_error[]n_syserr=yes],
2296 [glibcxx_cv_system_error[]n_syserr=no])
2297 ])
2298 AC_MSG_RESULT([$glibcxx_cv_system_error[]n_syserr])
2299 if test x"$glibcxx_cv_system_error[]n_syserr" = x"yes"; then
2300 AC_DEFINE([HAVE_]SYSERR, 1, [Define if ]syserr[ exists.])
2301 fi
2302 m4_define([n_syserr], m4_incr(n_syserr))dnl
2303 m4_popdef([SYSERR])dnl
2304 ])
2305 m4_popdef([n_syserr])dnl
2306 ])
2307
2308 dnl
2309 dnl Check for what type of C headers to use.
2310 dnl
2311 dnl --enable-cheaders= [does stuff].
2312 dnl --disable-cheaders [does not do anything, really].
2313 dnl + Usage: GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
2314 dnl Where DEFAULT is either 'c' or 'c_std' or 'c_global'.
2315 dnl
2316 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
2317 GLIBCXX_ENABLE(cheaders,$1,[[[=KIND]]],
2318 [construct "C" headers for g++], [permit c|c_std|c_global])
2319 AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
2320
2321 C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
2322
2323 # Allow overrides to configure.host here.
2324 if test $enable_cheaders = c_global; then
2325 c_compatibility=yes
2326 fi
2327
2328 AC_SUBST(C_INCLUDE_DIR)
2329 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
2330 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
2331 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_GLOBAL, test $enable_cheaders = c_global)
2332 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
2333 ])
2334
2335
2336 dnl
2337 dnl Check for which locale library to use. The choice is mapped to
2338 dnl a subdirectory of config/locale.
2339 dnl
2340 dnl Default is generic.
2341 dnl
2342 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
2343 GLIBCXX_ENABLE(clocale,auto,[[[=MODEL]]],
2344 [use MODEL for target locale package],
2345 [permit generic|gnu|ieee_1003.1-2001|newlib|yes|no|auto])
2346
2347 # Deal with gettext issues. Default to not using it (=no) until we detect
2348 # support for it later. Let the user turn it off via --e/d, but let that
2349 # default to on for easier handling.
2350 USE_NLS=no
2351 AC_ARG_ENABLE(nls,
2352 AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
2353 [],
2354 [enable_nls=yes])
2355
2356 # Either a known package, or "auto"
2357 if test $enable_clocale = no || test $enable_clocale = yes; then
2358 enable_clocale=auto
2359 fi
2360 enable_clocale_flag=$enable_clocale
2361
2362 # Probe for locale model to use if none specified.
2363 # Default to "generic".
2364 if test $enable_clocale_flag = auto; then
2365 case ${target_os} in
2366 linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
2367 enable_clocale_flag=gnu
2368 ;;
2369 darwin*)
2370 enable_clocale_flag=darwin
2371 ;;
2372 dragonfly* | freebsd*)
2373 enable_clocale_flag=dragonfly
2374 ;;
2375 openbsd*)
2376 enable_clocale_flag=newlib
2377 ;;
2378 *)
2379 if test x"$with_newlib" = x"yes"; then
2380 enable_clocale_flag=newlib
2381 else
2382 enable_clocale_flag=generic
2383 fi
2384 ;;
2385 esac
2386 fi
2387
2388 # Sanity check model, and test for special functionality.
2389 if test $enable_clocale_flag = gnu; then
2390 AC_EGREP_CPP([_GLIBCXX_ok], [
2391 #include <features.h>
2392 #if (__GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 3)) && !defined(__UCLIBC__)
2393 _GLIBCXX_ok
2394 #endif
2395 ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
2396
2397 # Set it to scream when it hurts.
2398 ac_save_CFLAGS="$CFLAGS"
2399 CFLAGS="-Wimplicit-function-declaration -Werror"
2400
2401 # Use strxfrm_l if available.
2402 AC_TRY_COMPILE([#define _GNU_SOURCE 1
2403 #include <string.h>
2404 #include <locale.h>],
2405 [char s[128]; __locale_t loc; strxfrm_l(s, "C", 5, loc);],
2406 AC_DEFINE(HAVE_STRXFRM_L, 1,
2407 [Define if strxfrm_l is available in <string.h>.]),)
2408
2409 # Use strerror_l if available.
2410 AC_TRY_COMPILE([#define _GNU_SOURCE 1
2411 #include <string.h>
2412 #include <locale.h>],
2413 [__locale_t loc; strerror_l(5, loc);],
2414 AC_DEFINE(HAVE_STRERROR_L, 1,
2415 [Define if strerror_l is available in <string.h>.]),)
2416
2417 CFLAGS="$ac_save_CFLAGS"
2418 fi
2419
2420 # Perhaps use strerror_r if available, and strerror_l isn't.
2421 ac_save_CFLAGS="$CFLAGS"
2422 CFLAGS="-Wimplicit-function-declaration -Werror"
2423 AC_TRY_COMPILE([#define _GNU_SOURCE 1
2424 #include <string.h>
2425 #include <locale.h>],
2426 [char s[128]; strerror_r(5, s, 128);],
2427 AC_DEFINE(HAVE_STRERROR_R, 1,
2428 [Define if strerror_r is available in <string.h>.]),)
2429 CFLAGS="$ac_save_CFLAGS"
2430
2431 # Set configure bits for specified locale package
2432 AC_MSG_CHECKING([for C locale to use])
2433 case ${enable_clocale_flag} in
2434 generic)
2435 AC_MSG_RESULT(generic)
2436
2437 CLOCALE_H=config/locale/generic/c_locale.h
2438 CLOCALE_CC=config/locale/generic/c_locale.cc
2439 CCODECVT_CC=config/locale/generic/codecvt_members.cc
2440 CCOLLATE_CC=config/locale/generic/collate_members.cc
2441 CCTYPE_CC=config/locale/generic/ctype_members.cc
2442 CMESSAGES_H=config/locale/generic/messages_members.h
2443 CMESSAGES_CC=config/locale/generic/messages_members.cc
2444 CMONEY_CC=config/locale/generic/monetary_members.cc
2445 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2446 CTIME_H=config/locale/generic/time_members.h
2447 CTIME_CC=config/locale/generic/time_members.cc
2448 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2449 ;;
2450 darwin)
2451 AC_MSG_RESULT(darwin)
2452
2453 CLOCALE_H=config/locale/generic/c_locale.h
2454 CLOCALE_CC=config/locale/generic/c_locale.cc
2455 CCODECVT_CC=config/locale/generic/codecvt_members.cc
2456 CCOLLATE_CC=config/locale/generic/collate_members.cc
2457 CCTYPE_CC=config/locale/darwin/ctype_members.cc
2458 CMESSAGES_H=config/locale/generic/messages_members.h
2459 CMESSAGES_CC=config/locale/generic/messages_members.cc
2460 CMONEY_CC=config/locale/generic/monetary_members.cc
2461 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2462 CTIME_H=config/locale/generic/time_members.h
2463 CTIME_CC=config/locale/generic/time_members.cc
2464 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2465 ;;
2466
2467 dragonfly)
2468 AC_MSG_RESULT(dragonfly or freebsd)
2469
2470 CLOCALE_H=config/locale/dragonfly/c_locale.h
2471 CLOCALE_CC=config/locale/dragonfly/c_locale.cc
2472 CCODECVT_CC=config/locale/dragonfly/codecvt_members.cc
2473 CCOLLATE_CC=config/locale/dragonfly/collate_members.cc
2474 CCTYPE_CC=config/locale/dragonfly/ctype_members.cc
2475 CMESSAGES_H=config/locale/generic/messages_members.h
2476 CMESSAGES_CC=config/locale/generic/messages_members.cc
2477 CMONEY_CC=config/locale/dragonfly/monetary_members.cc
2478 CNUMERIC_CC=config/locale/dragonfly/numeric_members.cc
2479 CTIME_H=config/locale/dragonfly/time_members.h
2480 CTIME_CC=config/locale/dragonfly/time_members.cc
2481 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2482 ;;
2483
2484 gnu)
2485 AC_MSG_RESULT(gnu)
2486
2487 # Declare intention to use gettext, and add support for specific
2488 # languages.
2489 # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
2490 ALL_LINGUAS="de fr"
2491
2492 # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
2493 AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
2494 if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
2495 USE_NLS=yes
2496 fi
2497 # Export the build objects.
2498 for ling in $ALL_LINGUAS; do \
2499 glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
2500 glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
2501 done
2502 AC_SUBST(glibcxx_MOFILES)
2503 AC_SUBST(glibcxx_POFILES)
2504
2505 CLOCALE_H=config/locale/gnu/c_locale.h
2506 CLOCALE_CC=config/locale/gnu/c_locale.cc
2507 CCODECVT_CC=config/locale/gnu/codecvt_members.cc
2508 CCOLLATE_CC=config/locale/gnu/collate_members.cc
2509 CCTYPE_CC=config/locale/gnu/ctype_members.cc
2510 CMESSAGES_H=config/locale/gnu/messages_members.h
2511 CMESSAGES_CC=config/locale/gnu/messages_members.cc
2512 CMONEY_CC=config/locale/gnu/monetary_members.cc
2513 CNUMERIC_CC=config/locale/gnu/numeric_members.cc
2514 CTIME_H=config/locale/gnu/time_members.h
2515 CTIME_CC=config/locale/gnu/time_members.cc
2516 CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
2517 ;;
2518 ieee_1003.1-2001)
2519 AC_MSG_RESULT(IEEE 1003.1)
2520
2521 CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
2522 CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
2523 CCODECVT_CC=config/locale/generic/codecvt_members.cc
2524 CCOLLATE_CC=config/locale/generic/collate_members.cc
2525 CCTYPE_CC=config/locale/generic/ctype_members.cc
2526 CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
2527 CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
2528 CMONEY_CC=config/locale/generic/monetary_members.cc
2529 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2530 CTIME_H=config/locale/generic/time_members.h
2531 CTIME_CC=config/locale/generic/time_members.cc
2532 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2533 ;;
2534 newlib)
2535 AC_MSG_RESULT(newlib)
2536
2537 CLOCALE_H=config/locale/generic/c_locale.h
2538 CLOCALE_CC=config/locale/generic/c_locale.cc
2539 CCODECVT_CC=config/locale/generic/codecvt_members.cc
2540 CCOLLATE_CC=config/locale/generic/collate_members.cc
2541 CCTYPE_CC=config/locale/newlib/ctype_members.cc
2542 CMESSAGES_H=config/locale/generic/messages_members.h
2543 CMESSAGES_CC=config/locale/generic/messages_members.cc
2544 CMONEY_CC=config/locale/generic/monetary_members.cc
2545 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2546 CTIME_H=config/locale/generic/time_members.h
2547 CTIME_CC=config/locale/generic/time_members.cc
2548 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2549 ;;
2550 esac
2551
2552 # This is where the testsuite looks for locale catalogs, using the
2553 # -DLOCALEDIR define during testsuite compilation.
2554 glibcxx_localedir=${glibcxx_builddir}/po/share/locale
2555 AC_SUBST(glibcxx_localedir)
2556
2557 # A standalone libintl (e.g., GNU libintl) may be in use.
2558 if test $USE_NLS = yes; then
2559 AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
2560 AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
2561 fi
2562 if test $USE_NLS = yes; then
2563 AC_DEFINE(_GLIBCXX_USE_NLS, 1,
2564 [Define if NLS translations are to be used.])
2565 fi
2566
2567 AC_SUBST(USE_NLS)
2568 AC_SUBST(CLOCALE_H)
2569 AC_SUBST(CMESSAGES_H)
2570 AC_SUBST(CCODECVT_CC)
2571 AC_SUBST(CCOLLATE_CC)
2572 AC_SUBST(CCTYPE_CC)
2573 AC_SUBST(CMESSAGES_CC)
2574 AC_SUBST(CMONEY_CC)
2575 AC_SUBST(CNUMERIC_CC)
2576 AC_SUBST(CTIME_H)
2577 AC_SUBST(CTIME_CC)
2578 AC_SUBST(CLOCALE_CC)
2579 AC_SUBST(CLOCALE_INTERNAL_H)
2580 ])
2581
2582
2583 dnl
2584 dnl Check for which std::allocator base class to use. The choice is
2585 dnl mapped from a subdirectory of include/ext.
2586 dnl
2587 dnl Default is new.
2588 dnl
2589 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
2590 AC_MSG_CHECKING([for std::allocator base class])
2591 GLIBCXX_ENABLE(libstdcxx-allocator,auto,[[[=KIND]]],
2592 [use KIND for target std::allocator base],
2593 [permit new|malloc|mt|bitmap|pool|yes|no|auto])
2594
2595 # If they didn't use this option switch, or if they specified --enable
2596 # with no specific model, we'll have to look for one. If they
2597 # specified --disable (???), do likewise.
2598 if test $enable_libstdcxx_allocator = no ||
2599 test $enable_libstdcxx_allocator = yes;
2600 then
2601 enable_libstdcxx_allocator=auto
2602 fi
2603
2604 # Either a known package, or "auto". Auto implies the default choice
2605 # for a particular platform.
2606 enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
2607
2608 # Probe for host-specific support if no specific model is specified.
2609 # Default to "new".
2610 if test $enable_libstdcxx_allocator_flag = auto; then
2611 case ${target_os} in
2612 linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
2613 enable_libstdcxx_allocator_flag=new
2614 ;;
2615 *)
2616 enable_libstdcxx_allocator_flag=new
2617 ;;
2618 esac
2619 fi
2620 AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
2621
2622
2623 # Set configure bits for specified locale package
2624 case ${enable_libstdcxx_allocator_flag} in
2625 bitmap)
2626 ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
2627 ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
2628 ;;
2629 malloc)
2630 ALLOCATOR_H=config/allocator/malloc_allocator_base.h
2631 ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
2632 ;;
2633 mt)
2634 ALLOCATOR_H=config/allocator/mt_allocator_base.h
2635 ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
2636 ;;
2637 new)
2638 ALLOCATOR_H=config/allocator/new_allocator_base.h
2639 ALLOCATOR_NAME=__gnu_cxx::new_allocator
2640 ;;
2641 pool)
2642 ALLOCATOR_H=config/allocator/pool_allocator_base.h
2643 ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
2644 ;;
2645 esac
2646
2647 GLIBCXX_CONDITIONAL(ENABLE_ALLOCATOR_NEW,
2648 test $enable_libstdcxx_allocator_flag = new)
2649 AC_SUBST(ALLOCATOR_H)
2650 AC_SUBST(ALLOCATOR_NAME)
2651 ])
2652
2653
2654 dnl
2655 dnl Check for whether the Boost-derived checks should be turned on.
2656 dnl
2657 dnl --enable-concept-checks turns them on.
2658 dnl --disable-concept-checks leaves them off.
2659 dnl + Usage: GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
2660 dnl Where DEFAULT is either `yes' or `no'.
2661 dnl
2662 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
2663 GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
2664 if test $enable_concept_checks = yes; then
2665 AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1,
2666 [Define to use concept checking code from the boost libraries.])
2667 fi
2668 ])
2669
2670 dnl
2671 dnl Use extern templates.
2672 dnl
2673 dnl --enable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 1
2674 dnl --disable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 0
2675
2676 dnl + Usage: GLIBCXX_ENABLE_TEMPLATE[(DEFAULT)]
2677 dnl Where DEFAULT is `yes' or `no'.
2678 dnl
2679 AC_DEFUN([GLIBCXX_ENABLE_EXTERN_TEMPLATE], [
2680
2681 GLIBCXX_ENABLE(extern-template,$1,,[enable extern template])
2682
2683 AC_MSG_CHECKING([for extern template support])
2684 AC_MSG_RESULT([$enable_extern_template])
2685
2686 GLIBCXX_CONDITIONAL(ENABLE_EXTERN_TEMPLATE, test $enable_extern_template = yes)
2687 ])
2688
2689 dnl
2690 dnl Use vtable verification.
2691 dnl
2692 dnl --enable-vtable-verify defines _GLIBCXX_VTABLE_VERIFY to 1
2693 dnl --disable-vtable-verify defines _GLIBCXX_VTABLE_VERIFY to 0
2694
2695 dnl + Usage: GLIBCXX_ENABLE_VTABLE_VERIFY[(DEFAULT)]
2696 dnl Where DEFAULT is `yes' or `no'.
2697 dnl
2698 AC_DEFUN([GLIBCXX_ENABLE_VTABLE_VERIFY], [
2699
2700 GLIBCXX_ENABLE(vtable-verify,$1,,[enable vtable verify])
2701
2702 AC_MSG_CHECKING([for vtable verify support])
2703 AC_MSG_RESULT([$enable_vtable_verify])
2704
2705 vtv_cygmin=no
2706 if test $enable_vtable_verify = yes; then
2707 case ${target_os} in
2708 cygwin*|mingw32*)
2709 VTV_CXXFLAGS="-fvtable-verify=std -Wl,-lvtv,-u_vtable_map_vars_start,-u_vtable_map_vars_end"
2710 VTV_CXXLINKFLAGS="-L${toplevel_builddir}/libvtv/.libs -Wl,--rpath -Wl,${toplevel_builddir}/libvtv/.libs"
2711 vtv_cygmin=yes
2712 ;;
2713 darwin*)
2714 VTV_CXXFLAGS="-fvtable-verify=std -Wl,-u,_vtable_map_vars_start -Wl,-u,_vtable_map_vars_end"
2715 VTV_CXXLINKFLAGS="-L${toplevel_builddir}/libvtv/.libs -Wl,-rpath,${toplevel_builddir}/libvtv/.libs"
2716 ;;
2717 solaris2*)
2718 VTV_CXXFLAGS="-fvtable-verify=std -Wl,-u_vtable_map_vars_start,-u_vtable_map_vars_end"
2719 VTV_CXXLINKFLAGS="-L${toplevel_builddir}/libvtv/.libs -Wl,-R -Wl,${toplevel_builddir}/libvtv/.libs"
2720 ;;
2721 *)
2722 VTV_CXXFLAGS="-fvtable-verify=std -Wl,-u_vtable_map_vars_start,-u_vtable_map_vars_end"
2723 VTV_CXXLINKFLAGS="-L${toplevel_builddir}/libvtv/.libs -Wl,--rpath -Wl,${toplevel_builddir}/libvtv/.libs"
2724 ;;
2725 esac
2726 VTV_PCH_CXXFLAGS="-fvtable-verify=std"
2727 else
2728 VTV_CXXFLAGS=
2729 VTV_PCH_CXXFLAGS=
2730 VTV_CXXLINKFLAGS=
2731 fi
2732
2733 AC_SUBST(VTV_CXXFLAGS)
2734 AC_SUBST(VTV_PCH_CXXFLAGS)
2735 AC_SUBST(VTV_CXXLINKFLAGS)
2736 AM_CONDITIONAL(VTV_CYGMIN, test x$vtv_cygmin = xyes)
2737 GLIBCXX_CONDITIONAL(ENABLE_VTABLE_VERIFY, test $enable_vtable_verify = yes)
2738 ])
2739
2740 dnl
2741 dnl Check for parallel mode pre-requisites, including OpenMP support.
2742 dnl
2743 dnl + Usage: GLIBCXX_ENABLE_PARALLEL
2744 dnl
2745 AC_DEFUN([GLIBCXX_ENABLE_PARALLEL], [
2746
2747 enable_parallel=no;
2748
2749 # See if configured libgomp/omp.h exists. (libgomp may be in
2750 # noconfigdirs but not explicitly disabled.)
2751 if echo " ${TARGET_CONFIGDIRS} " | grep " libgomp " > /dev/null 2>&1 ; then
2752 enable_parallel=yes;
2753 else
2754 AC_MSG_NOTICE([target-libgomp not built])
2755 fi
2756
2757 AC_MSG_CHECKING([for parallel mode support])
2758 AC_MSG_RESULT([$enable_parallel])
2759 ])
2760
2761
2762 dnl
2763 dnl Check for which I/O library to use: stdio, or something specific.
2764 dnl
2765 dnl Default is stdio.
2766 dnl
2767 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
2768 AC_MSG_CHECKING([for underlying I/O to use])
2769 GLIBCXX_ENABLE(cstdio,stdio,[[[=PACKAGE]]],
2770 [use target-specific I/O package], [permit stdio])
2771
2772 # Now that libio has been removed, you can have any color you want as long
2773 # as it's black. This is one big no-op until other packages are added, but
2774 # showing the framework never hurts.
2775 case ${enable_cstdio} in
2776 stdio)
2777 CSTDIO_H=config/io/c_io_stdio.h
2778 BASIC_FILE_H=config/io/basic_file_stdio.h
2779 BASIC_FILE_CC=config/io/basic_file_stdio.cc
2780 AC_MSG_RESULT(stdio)
2781 ;;
2782 esac
2783
2784 AC_SUBST(CSTDIO_H)
2785 AC_SUBST(BASIC_FILE_H)
2786 AC_SUBST(BASIC_FILE_CC)
2787 ])
2788
2789
2790 dnl
2791 dnl Check for "unusual" flags to pass to the compiler while building.
2792 dnl
2793 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
2794 dnl experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
2795 dnl --disable-cxx-flags passes nothing.
2796 dnl + See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
2797 dnl http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
2798 dnl http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
2799 dnl + Usage: GLIBCXX_ENABLE_CXX_FLAGS(default flags)
2800 dnl If "default flags" is an empty string, the effect is the same
2801 dnl as --disable or --enable=no.
2802 dnl
2803 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
2804 AC_MSG_CHECKING([for extra compiler flags for building])
2805 GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
2806 [pass compiler FLAGS when building library],
2807 [case "x$enable_cxx_flags" in
2808 xno | x) enable_cxx_flags= ;;
2809 x-*) ;;
2810 *) AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2811 esac])
2812
2813 # Run through flags (either default or command-line) and set anything
2814 # extra (e.g., #defines) that must accompany particular g++ options.
2815 if test -n "$enable_cxx_flags"; then
2816 for f in $enable_cxx_flags; do
2817 case "$f" in
2818 -fhonor-std) ;;
2819 -*) ;;
2820 *) # and we're trying to pass /what/ exactly?
2821 AC_MSG_ERROR([compiler flags start with a -]) ;;
2822 esac
2823 done
2824 fi
2825
2826 EXTRA_CXX_FLAGS="$enable_cxx_flags"
2827 AC_MSG_RESULT($EXTRA_CXX_FLAGS)
2828 AC_SUBST(EXTRA_CXX_FLAGS)
2829 ])
2830
2831
2832 dnl
2833 dnl Check to see if debugging libraries are to be built.
2834 dnl
2835 dnl --enable-libstdcxx-debug
2836 dnl builds a separate set of debugging libraries in addition to the
2837 dnl normal (shared, static) libstdc++ binaries.
2838 dnl
2839 dnl --disable-libstdcxx-debug
2840 dnl builds only one (non-debug) version of libstdc++.
2841 dnl
2842 dnl --enable-libstdcxx-debug-flags=FLAGS
2843 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
2844 dnl
2845 dnl + Usage: GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
2846 dnl Where DEFAULT is either `yes' or `no'.
2847 dnl
2848 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
2849 AC_MSG_CHECKING([for additional debug build])
2850 GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
2851 AC_MSG_RESULT($enable_libstdcxx_debug)
2852 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
2853 ])
2854
2855
2856 dnl
2857 dnl Check for explicit debug flags.
2858 dnl
2859 dnl --enable-libstdcxx-debug-flags='-O1'
2860 dnl is a general method for passing flags to be used when
2861 dnl building debug libraries with --enable-libstdcxx-debug.
2862 dnl
2863 dnl --disable-libstdcxx-debug-flags does nothing.
2864 dnl + Usage: GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
2865 dnl If "default flags" is an empty string, the effect is the same
2866 dnl as --disable or --enable=no.
2867 dnl
2868 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
2869 GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
2870 [pass compiler FLAGS when building debug library],
2871 [case "x$enable_libstdcxx_debug_flags" in
2872 xno | x) enable_libstdcxx_debug_flags= ;;
2873 x-*) ;;
2874 *) AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2875 esac])
2876
2877 # Option parsed, now set things appropriately
2878 DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
2879 AC_SUBST(DEBUG_FLAGS)
2880
2881 AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
2882 ])
2883
2884
2885 dnl
2886 dnl Check if the user only wants a freestanding library implementation.
2887 dnl
2888 dnl --disable-hosted-libstdcxx will turn off most of the library build,
2889 dnl installing only the headers required by [17.4.1.3] and the language
2890 dnl support library. More than that will be built (to keep the Makefiles
2891 dnl conveniently clean), but not installed.
2892 dnl
2893 dnl Sets:
2894 dnl is_hosted (yes/no)
2895 dnl
2896 dnl Defines:
2897 dnl _GLIBCXX_HOSTED (always defined, either to 1 or 0)
2898 dnl
2899 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
2900 AC_ARG_ENABLE([hosted-libstdcxx],
2901 AC_HELP_STRING([--disable-hosted-libstdcxx],
2902 [only build freestanding C++ runtime support]),,
2903 [case "$host" in
2904 arm*-*-symbianelf*)
2905 enable_hosted_libstdcxx=no
2906 ;;
2907 *)
2908 enable_hosted_libstdcxx=yes
2909 ;;
2910 esac])
2911 if test "$enable_hosted_libstdcxx" = no; then
2912 AC_MSG_NOTICE([Only freestanding libraries will be built])
2913 is_hosted=no
2914 hosted_define=0
2915 enable_abi_check=no
2916 enable_libstdcxx_pch=no
2917 else
2918 is_hosted=yes
2919 hosted_define=1
2920 fi
2921 GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
2922 AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
2923 [Define to 1 if a full hosted library is built, or 0 if freestanding.])
2924 ])
2925
2926
2927 dnl
2928 dnl Check if the user wants a non-verbose library implementation.
2929 dnl
2930 dnl --disable-libstdcxx-verbose will turn off descriptive messages to
2931 dnl standard error on termination.
2932 dnl
2933 dnl Defines:
2934 dnl _GLIBCXX_VERBOSE (always defined, either to 1 or 0)
2935 dnl
2936 AC_DEFUN([GLIBCXX_ENABLE_VERBOSE], [
2937 AC_ARG_ENABLE([libstdcxx-verbose],
2938 AC_HELP_STRING([--disable-libstdcxx-verbose],
2939 [disable termination messages to standard error]),,
2940 [enable_libstdcxx_verbose=yes])
2941 if test x"$enable_libstdcxx_verbose" = xyes; then
2942 verbose_define=1
2943 else
2944 AC_MSG_NOTICE([verbose termination messages are disabled])
2945 verbose_define=0
2946 fi
2947 AC_DEFINE_UNQUOTED(_GLIBCXX_VERBOSE, $verbose_define,
2948 [Define to 1 if a verbose library is built, or 0 otherwise.])
2949 ])
2950
2951
2952 dnl
2953 dnl Check for template specializations for the 'long long' type.
2954 dnl The result determines only whether 'long long' I/O is enabled; things
2955 dnl like numeric_limits<> specializations are always available.
2956 dnl
2957 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
2958 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
2959 dnl + Usage: GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
2960 dnl Where DEFAULT is either `yes' or `no'.
2961 dnl
2962 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
2963 GLIBCXX_ENABLE(long-long,$1,,[enable template specializations for 'long long'])
2964 if test $enable_long_long = yes; then
2965 AC_DEFINE(_GLIBCXX_USE_LONG_LONG, 1,
2966 [Define if code specialized for long long should be used.])
2967 fi
2968 AC_MSG_CHECKING([for enabled long long specializations])
2969 AC_MSG_RESULT([$enable_long_long])
2970 ])
2971
2972
2973 dnl
2974 dnl Check for decimal floating point.
2975 dnl See:
2976 dnl http://gcc.gnu.org/onlinedocs/gcc/Decimal-Float.html#Decimal-Float
2977 dnl
2978 dnl This checks to see if the host supports decimal floating point types.
2979 dnl
2980 dnl Defines:
2981 dnl _GLIBCXX_USE_DECIMAL_FLOAT
2982 dnl
2983 AC_DEFUN([GLIBCXX_ENABLE_DECIMAL_FLOAT], [
2984
2985 # Fake what AC_TRY_COMPILE does, without linking as this is
2986 # unnecessary for this test.
2987
2988 cat > conftest.$ac_ext << EOF
2989 [#]line __oline__ "configure"
2990 int main()
2991 {
2992 _Decimal32 d1;
2993 _Decimal64 d2;
2994 _Decimal128 d3;
2995 return 0;
2996 }
2997 EOF
2998
2999 AC_MSG_CHECKING([for ISO/IEC TR 24733 ])
3000 if AC_TRY_EVAL(ac_compile); then
3001 AC_DEFINE(_GLIBCXX_USE_DECIMAL_FLOAT, 1,
3002 [Define if ISO/IEC TR 24733 decimal floating point types are supported on this host.])
3003 enable_dfp=yes
3004 else
3005 enable_dfp=no
3006 fi
3007 AC_MSG_RESULT($enable_dfp)
3008 rm -f conftest*
3009 ])
3010
3011 dnl
3012 dnl Check for GNU 128-bit integer and floating point types.
3013 dnl
3014 dnl Note: also checks that the types aren't standard types.
3015 dnl
3016 dnl Defines:
3017 dnl _GLIBCXX_USE_INT128
3018 dnl _GLIBCXX_USE_FLOAT128
3019 dnl
3020 AC_DEFUN([GLIBCXX_ENABLE_INT128_FLOAT128], [
3021
3022 AC_LANG_SAVE
3023 AC_LANG_CPLUSPLUS
3024
3025 # Fake what AC_TRY_COMPILE does, without linking as this is
3026 # unnecessary for this test.
3027
3028 cat > conftest.$ac_ext << EOF
3029 [#]line __oline__ "configure"
3030 template<typename T1, typename T2>
3031 struct same
3032 { typedef T2 type; };
3033
3034 template<typename T>
3035 struct same<T, T>;
3036
3037 int main()
3038 {
3039 typename same<long, __int128>::type i1;
3040 typename same<long long, __int128>::type i2;
3041 }
3042 EOF
3043
3044 AC_MSG_CHECKING([for __int128])
3045 if AC_TRY_EVAL(ac_compile); then
3046 AC_DEFINE(_GLIBCXX_USE_INT128, 1,
3047 [Define if __int128 is supported on this host.])
3048 enable_int128=yes
3049 else
3050 enable_int128=no
3051 fi
3052 AC_MSG_RESULT($enable_int128)
3053 rm -f conftest*
3054
3055 cat > conftest.$ac_ext << EOF
3056 [#]line __oline__ "configure"
3057 template<typename T1, typename T2>
3058 struct same
3059 { typedef T2 type; };
3060
3061 template<typename T>
3062 struct same<T, T>;
3063
3064 int main()
3065 {
3066 typename same<double, __float128>::type f1;
3067 typename same<long double, __float128>::type f2;
3068 }
3069 EOF
3070
3071 AC_MSG_CHECKING([for __float128])
3072 if AC_TRY_EVAL(ac_compile); then
3073 AC_DEFINE(_GLIBCXX_USE_FLOAT128, 1,
3074 [Define if __float128 is supported on this host.])
3075 enable_float128=yes
3076 else
3077 enable_float128=no
3078 fi
3079 AC_MSG_RESULT($enable_float128)
3080 rm -f conftest*
3081
3082 AC_LANG_RESTORE
3083 ])
3084
3085 dnl
3086 dnl Check for template specializations for the 'wchar_t' type.
3087 dnl
3088 dnl --enable-wchar_t defines _GLIBCXX_USE_WCHAR_T
3089 dnl --disable-wchar_t leaves _GLIBCXX_USE_WCHAR_T undefined
3090 dnl + Usage: GLIBCXX_ENABLE_WCHAR_T[(DEFAULT)]
3091 dnl Where DEFAULT is either `yes' or `no'.
3092 dnl
3093 dnl Necessary support must also be present.
3094 dnl
3095 AC_DEFUN([GLIBCXX_ENABLE_WCHAR_T], [
3096 GLIBCXX_ENABLE(wchar_t,$1,,[enable template specializations for 'wchar_t'])
3097
3098 # Test wchar.h for mbstate_t, which is needed for char_traits and fpos.
3099 AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
3100 AC_MSG_CHECKING([for mbstate_t])
3101 AC_TRY_COMPILE([#include <wchar.h>],
3102 [mbstate_t teststate;],
3103 have_mbstate_t=yes, have_mbstate_t=no)
3104 AC_MSG_RESULT($have_mbstate_t)
3105 if test x"$have_mbstate_t" = xyes; then
3106 AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
3107 fi
3108
3109 # Test it always, for use in GLIBCXX_ENABLE_C99, together with
3110 # ac_has_wchar_h.
3111 AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
3112
3113 if test x"$enable_wchar_t" = x"yes"; then
3114
3115 AC_LANG_SAVE
3116 AC_LANG_CPLUSPLUS
3117
3118 if test x"$ac_has_wchar_h" = xyes &&
3119 test x"$ac_has_wctype_h" = xyes; then
3120 AC_TRY_COMPILE([#include <wchar.h>
3121 #include <stddef.h>
3122 wint_t i;
3123 long l = WEOF;
3124 long j = WCHAR_MIN;
3125 long k = WCHAR_MAX;
3126 namespace test
3127 {
3128 using ::btowc;
3129 using ::fgetwc;
3130 using ::fgetws;
3131 using ::fputwc;
3132 using ::fputws;
3133 using ::fwide;
3134 using ::fwprintf;
3135 using ::fwscanf;
3136 using ::getwc;
3137 using ::getwchar;
3138 using ::mbrlen;
3139 using ::mbrtowc;
3140 using ::mbsinit;
3141 using ::mbsrtowcs;
3142 using ::putwc;
3143 using ::putwchar;
3144 using ::swprintf;
3145 using ::swscanf;
3146 using ::ungetwc;
3147 using ::vfwprintf;
3148 using ::vswprintf;
3149 using ::vwprintf;
3150 using ::wcrtomb;
3151 using ::wcscat;
3152 using ::wcschr;
3153 using ::wcscmp;
3154 using ::wcscoll;
3155 using ::wcscpy;
3156 using ::wcscspn;
3157 using ::wcsftime;
3158 using ::wcslen;
3159 using ::wcsncat;
3160 using ::wcsncmp;
3161 using ::wcsncpy;
3162 using ::wcspbrk;
3163 using ::wcsrchr;
3164 using ::wcsrtombs;
3165 using ::wcsspn;
3166 using ::wcsstr;
3167 using ::wcstod;
3168 using ::wcstok;
3169 using ::wcstol;
3170 using ::wcstoul;
3171 using ::wcsxfrm;
3172 using ::wctob;
3173 using ::wmemchr;
3174 using ::wmemcmp;
3175 using ::wmemcpy;
3176 using ::wmemmove;
3177 using ::wmemset;
3178 using ::wprintf;
3179 using ::wscanf;
3180 }
3181 ],[],[], [enable_wchar_t=no])
3182 else
3183 enable_wchar_t=no
3184 fi
3185
3186 AC_LANG_RESTORE
3187 fi
3188
3189 if test x"$enable_wchar_t" = x"yes"; then
3190 AC_DEFINE(_GLIBCXX_USE_WCHAR_T, 1,
3191 [Define if code specialized for wchar_t should be used.])
3192 fi
3193
3194 AC_MSG_CHECKING([for enabled wchar_t specializations])
3195 AC_MSG_RESULT([$enable_wchar_t])
3196 ])
3197
3198
3199 dnl
3200 dnl Check to see if building and using a C++ precompiled header can be done.
3201 dnl
3202 dnl --enable-libstdcxx-pch=yes
3203 dnl default, this shows intent to use stdc++.h.gch If it looks like it
3204 dnl may work, after some light-hearted attempts to puzzle out compiler
3205 dnl support, flip bits on in include/Makefile.am
3206 dnl
3207 dnl --disable-libstdcxx-pch
3208 dnl turns off attempts to use or build stdc++.h.gch.
3209 dnl
3210 dnl Substs:
3211 dnl glibcxx_PCHFLAGS
3212 dnl
3213 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
3214 GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
3215 if test $enable_libstdcxx_pch = yes; then
3216 AC_CACHE_CHECK([for compiler with PCH support],
3217 [glibcxx_cv_prog_CXX_pch],
3218 [ac_save_CXXFLAGS="$CXXFLAGS"
3219 CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
3220 AC_LANG_SAVE
3221 AC_LANG_CPLUSPLUS
3222 echo '#include <math.h>' > conftest.h
3223 if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
3224 -o conftest.h.gch 1>&5 2>&1 &&
3225 echo '#error "pch failed"' > conftest.h &&
3226 echo '#include "conftest.h"' > conftest.cc &&
3227 $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
3228 then
3229 glibcxx_cv_prog_CXX_pch=yes
3230 else
3231 glibcxx_cv_prog_CXX_pch=no
3232 fi
3233 rm -f conftest*
3234 CXXFLAGS=$ac_save_CXXFLAGS
3235 AC_LANG_RESTORE
3236 ])
3237 enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
3238 fi
3239
3240 AC_MSG_CHECKING([for enabled PCH])
3241 AC_MSG_RESULT([$enable_libstdcxx_pch])
3242
3243 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
3244 if test $enable_libstdcxx_pch = yes; then
3245 glibcxx_PCHFLAGS="-include bits/stdc++.h"
3246 else
3247 glibcxx_PCHFLAGS=""
3248 fi
3249 AC_SUBST(glibcxx_PCHFLAGS)
3250 ])
3251
3252
3253 dnl
3254 dnl Check for atomic builtins.
3255 dnl See:
3256 dnl http://gcc.gnu.org/onlinedocs/gcc/_005f_005fatomic-Builtins.html
3257 dnl
3258 dnl This checks to see if the host supports the compiler-generated
3259 dnl builtins for atomic operations for various integral sizes. Note, this
3260 dnl is intended to be an all-or-nothing switch, so all the atomic operations
3261 dnl that are used should be checked.
3262 dnl
3263 dnl Note:
3264 dnl libgomp and libgfortran use a link test, see CHECK_SYNC_FETCH_AND_ADD.
3265 dnl
3266 AC_DEFUN([GLIBCXX_ENABLE_ATOMIC_BUILTINS], [
3267 AC_LANG_SAVE
3268 AC_LANG_CPLUSPLUS
3269 old_CXXFLAGS="$CXXFLAGS"
3270
3271 # Do link tests if possible, instead asm tests, limited to some platforms
3272 # see discussion in PR target/40134, PR libstdc++/40133 and the thread
3273 # starting at http://gcc.gnu.org/ml/gcc-patches/2009-07/msg00322.html
3274 atomic_builtins_link_tests=no
3275 if test x$gcc_no_link != xyes; then
3276 # Can do link tests. Limit to some tested platforms
3277 case "$host" in
3278 *-*-linux* | *-*-uclinux* | *-*-kfreebsd*-gnu | *-*-gnu*)
3279 atomic_builtins_link_tests=yes
3280 ;;
3281 esac
3282 fi
3283
3284 if test x$atomic_builtins_link_tests = xyes; then
3285
3286 # Do link tests.
3287
3288 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3289
3290 AC_MSG_CHECKING([for atomic builtins for bool])
3291 AC_CACHE_VAL(glibcxx_cv_atomic_bool, [
3292 AC_TRY_LINK(
3293 [ ],
3294 [typedef bool atomic_type;
3295 atomic_type c1;
3296 atomic_type c2;
3297 atomic_type c3(0);
3298 // N.B. __atomic_fetch_add is not supported for bool.
3299 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
3300 __ATOMIC_RELAXED);
3301 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
3302 __atomic_load_n(&c1, __ATOMIC_RELAXED);
3303 ],
3304 [glibcxx_cv_atomic_bool=yes],
3305 [glibcxx_cv_atomic_bool=no])
3306 ])
3307 AC_MSG_RESULT($glibcxx_cv_atomic_bool)
3308
3309 AC_MSG_CHECKING([for atomic builtins for short])
3310 AC_CACHE_VAL(glibcxx_cv_atomic_short, [
3311 AC_TRY_LINK(
3312 [ ],
3313 [typedef short atomic_type;
3314 atomic_type c1;
3315 atomic_type c2;
3316 atomic_type c3(0);
3317 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
3318 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
3319 __ATOMIC_RELAXED);
3320 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
3321 __atomic_load_n(&c1, __ATOMIC_RELAXED);
3322 ],
3323 [glibcxx_cv_atomic_short=yes],
3324 [glibcxx_cv_atomic_short=no])
3325 ])
3326 AC_MSG_RESULT($glibcxx_cv_atomic_short)
3327
3328 AC_MSG_CHECKING([for atomic builtins for int])
3329 AC_CACHE_VAL(glibcxx_cv_atomic_int, [
3330 AC_TRY_LINK(
3331 [ ],
3332 [typedef int atomic_type;
3333 atomic_type c1;
3334 atomic_type c2;
3335 atomic_type c3(0);
3336 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
3337 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
3338 __ATOMIC_RELAXED);
3339 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
3340 __atomic_load_n(&c1, __ATOMIC_RELAXED);
3341 ],
3342 [glibcxx_cv_atomic_int=yes],
3343 [glibcxx_cv_atomic_int=no])
3344 ])
3345 AC_MSG_RESULT($glibcxx_cv_atomic_int)
3346
3347 AC_MSG_CHECKING([for atomic builtins for long long])
3348 AC_CACHE_VAL(glibcxx_cv_atomic_long_long, [
3349 AC_TRY_LINK(
3350 [ ],
3351 [typedef long long atomic_type;
3352 atomic_type c1;
3353 atomic_type c2;
3354 atomic_type c3(0);
3355 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
3356 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
3357 __ATOMIC_RELAXED);
3358 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
3359 __atomic_load_n(&c1, __ATOMIC_RELAXED);
3360 ],
3361 [glibcxx_cv_atomic_long_long=yes],
3362 [glibcxx_cv_atomic_long_long=no])
3363 ])
3364 AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
3365
3366 else
3367
3368 # Do asm tests.
3369
3370 # Compile unoptimized.
3371 CXXFLAGS='-O0 -S'
3372
3373 # Fake what AC_TRY_COMPILE does.
3374
3375 cat > conftest.$ac_ext << EOF
3376 [#]line __oline__ "configure"
3377 int main()
3378 {
3379 typedef bool atomic_type;
3380 atomic_type c1;
3381 atomic_type c2;
3382 atomic_type c3(0);
3383 // N.B. __atomic_fetch_add is not supported for bool.
3384 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
3385 __ATOMIC_RELAXED);
3386 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
3387 __atomic_load_n(&c1, __ATOMIC_RELAXED);
3388
3389 return 0;
3390 }
3391 EOF
3392
3393 AC_MSG_CHECKING([for atomic builtins for bool])
3394 if AC_TRY_EVAL(ac_compile); then
3395 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
3396 glibcxx_cv_atomic_bool=no
3397 else
3398 glibcxx_cv_atomic_bool=yes
3399 fi
3400 fi
3401 AC_MSG_RESULT($glibcxx_cv_atomic_bool)
3402 rm -f conftest*
3403
3404 cat > conftest.$ac_ext << EOF
3405 [#]line __oline__ "configure"
3406 int main()
3407 {
3408 typedef short atomic_type;
3409 atomic_type c1;
3410 atomic_type c2;
3411 atomic_type c3(0);
3412 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
3413 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
3414 __ATOMIC_RELAXED);
3415 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
3416 __atomic_load_n(&c1, __ATOMIC_RELAXED);
3417
3418 return 0;
3419 }
3420 EOF
3421
3422 AC_MSG_CHECKING([for atomic builtins for short])
3423 if AC_TRY_EVAL(ac_compile); then
3424 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
3425 glibcxx_cv_atomic_short=no
3426 else
3427 glibcxx_cv_atomic_short=yes
3428 fi
3429 fi
3430 AC_MSG_RESULT($glibcxx_cv_atomic_short)
3431 rm -f conftest*
3432
3433 cat > conftest.$ac_ext << EOF
3434 [#]line __oline__ "configure"
3435 int main()
3436 {
3437 // NB: _Atomic_word not necessarily int.
3438 typedef int atomic_type;
3439 atomic_type c1;
3440 atomic_type c2;
3441 atomic_type c3(0);
3442 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
3443 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
3444 __ATOMIC_RELAXED);
3445 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
3446 __atomic_load_n(&c1, __ATOMIC_RELAXED);
3447
3448 return 0;
3449 }
3450 EOF
3451
3452 AC_MSG_CHECKING([for atomic builtins for int])
3453 if AC_TRY_EVAL(ac_compile); then
3454 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
3455 glibcxx_cv_atomic_int=no
3456 else
3457 glibcxx_cv_atomic_int=yes
3458 fi
3459 fi
3460 AC_MSG_RESULT($glibcxx_cv_atomic_int)
3461 rm -f conftest*
3462
3463 cat > conftest.$ac_ext << EOF
3464 [#]line __oline__ "configure"
3465 int main()
3466 {
3467 typedef long long atomic_type;
3468 atomic_type c1;
3469 atomic_type c2;
3470 atomic_type c3(0);
3471 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
3472 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
3473 __ATOMIC_RELAXED);
3474 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
3475 __atomic_load_n(&c1, __ATOMIC_RELAXED);
3476
3477 return 0;
3478 }
3479 EOF
3480
3481 AC_MSG_CHECKING([for atomic builtins for long long])
3482 if AC_TRY_EVAL(ac_compile); then
3483 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
3484 glibcxx_cv_atomic_long_long=no
3485 else
3486 glibcxx_cv_atomic_long_long=yes
3487 fi
3488 fi
3489 AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
3490 rm -f conftest*
3491
3492 fi
3493
3494 CXXFLAGS="$old_CXXFLAGS"
3495 AC_LANG_RESTORE
3496
3497 # Set atomicity_dir to builtins if all but the long long test above passes,
3498 # or if the builtins were already chosen (e.g. by configure.host).
3499 if { test "$glibcxx_cv_atomic_bool" = yes \
3500 && test "$glibcxx_cv_atomic_short" = yes \
3501 && test "$glibcxx_cv_atomic_int" = yes; } \
3502 || test "$atomicity_dir" = "cpu/generic/atomicity_builtins"; then
3503 AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS, 1,
3504 [Define if the compiler supports C++11 atomics.])
3505 atomicity_dir=cpu/generic/atomicity_builtins
3506 fi
3507
3508 # If still generic, set to mutex.
3509 if test $atomicity_dir = "cpu/generic" ; then
3510 atomicity_dir=cpu/generic/atomicity_mutex
3511 AC_MSG_WARN([No native atomic operations are provided for this platform.])
3512 if test "x$target_thread_file" = xsingle; then
3513 AC_MSG_WARN([They cannot be faked when thread support is disabled.])
3514 AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
3515 else
3516 AC_MSG_WARN([They will be faked using a mutex.])
3517 AC_MSG_WARN([Performance of certain classes will degrade as a result.])
3518 fi
3519 fi
3520
3521 ])
3522
3523
3524 dnl
3525 dnl Allow visibility attributes to be used on namespaces, objects, etc.
3526 dnl
3527 dnl --enable-libstdcxx-visibility enables attempt to use visibility attributes.
3528 dnl --disable-libstdcxx-visibility turns off all use of visibility attributes.
3529 dnl + Usage: GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY[(DEFAULT)]
3530 dnl Where DEFAULT is 'yes'.
3531 dnl
3532 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY], [
3533 GLIBCXX_ENABLE(libstdcxx-visibility,$1,,[enables visibility safe usage])
3534
3535 if test x$enable_libstdcxx_visibility = xyes ; then
3536 dnl all hail libgfortran
3537 dnl Check whether the target supports hidden visibility.
3538 AC_CACHE_CHECK([whether the target supports hidden visibility],
3539 glibcxx_cv_have_attribute_visibility, [
3540 save_CFLAGS="$CFLAGS"
3541 CFLAGS="$CFLAGS -Werror"
3542 AC_TRY_COMPILE([void __attribute__((visibility("hidden"))) foo(void) { }],
3543 [], glibcxx_cv_have_attribute_visibility=yes,
3544 glibcxx_cv_have_attribute_visibility=no)
3545 CFLAGS="$save_CFLAGS"])
3546 if test $glibcxx_cv_have_attribute_visibility = no; then
3547 enable_libstdcxx_visibility=no
3548 fi
3549 fi
3550
3551 GLIBCXX_CONDITIONAL(ENABLE_VISIBILITY, test $enable_libstdcxx_visibility = yes)
3552 AC_MSG_NOTICE([visibility supported: $enable_libstdcxx_visibility])
3553 ])
3554
3555
3556 dnl
3557 dnl Add version tags to symbols in shared library (or not), additionally
3558 dnl marking other symbols as private/local (or not).
3559 dnl
3560 dnl Sets libtool_VERSION, and determines shared library SONAME.
3561 dnl
3562 dnl This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
3563 dnl
3564 dnl --enable-symvers=style adds a version script to the linker call when
3565 dnl creating the shared library. The choice of version script is
3566 dnl controlled by 'style'.
3567 dnl --disable-symvers does not.
3568 dnl
3569 dnl + Usage: GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
3570 dnl Where DEFAULT is either 'yes' or 'no'. Passing `yes' tries to
3571 dnl choose a default style based on linker characteristics. Passing
3572 dnl 'no' disables versioning.
3573 dnl
3574 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
3575
3576 GLIBCXX_ENABLE(symvers,$1,[[[=STYLE]]],
3577 [enables symbol versioning of the shared library],
3578 [permit yes|no|gnu|gnu-versioned-namespace|darwin|darwin-export|sun])
3579
3580 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
3581 # don't know enough about $LD to do tricks...
3582 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
3583 # Sun style symbol versions needs GNU c++filt for make_sunver.pl to work
3584 # with extern "C++" in version scripts.
3585 AC_REQUIRE([GCC_PROG_GNU_CXXFILT])
3586
3587 # Turn a 'yes' into a suitable default.
3588 if test x$enable_symvers = xyes ; then
3589 if test $enable_shared = no || test "x$LD" = x || test x$gcc_no_link = xyes; then
3590 enable_symvers=no
3591 else
3592 if test $with_gnu_ld = yes ; then
3593 case ${target_os} in
3594 hpux*)
3595 enable_symvers=no ;;
3596 *)
3597 enable_symvers=gnu ;;
3598 esac
3599 else
3600 case ${target_os} in
3601 darwin*)
3602 enable_symvers=darwin ;;
3603 # Sun symbol versioning exists since Solaris 2.5.
3604 solaris2.[[5-9]]* | solaris2.1[[0-9]]*)
3605 # make_sunver.pl needs GNU c++filt to support extern "C++" in
3606 # version scripts, so disable symbol versioning if none can be
3607 # found.
3608 if test -z "$ac_cv_path_CXXFILT"; then
3609 AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
3610 AC_MSG_WARN([=== no GNU c++filt could be found.])
3611 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3612 enable_symvers=no
3613 else
3614 enable_symvers=sun
3615 fi
3616 ;;
3617 *)
3618 enable_symvers=no ;;
3619 esac
3620 fi
3621 fi
3622 fi
3623
3624 # Check to see if 'darwin' or 'darwin-export' can win.
3625 if test x$enable_symvers = xdarwin-export ; then
3626 enable_symvers=darwin
3627 fi
3628
3629 # Check if 'sun' was requested on non-Solaris 2 platforms.
3630 if test x$enable_symvers = xsun ; then
3631 case ${target_os} in
3632 solaris2*)
3633 # All fine.
3634 ;;
3635 *)
3636 # Unlikely to work.
3637 AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
3638 AC_MSG_WARN([=== you are not targetting Solaris 2.])
3639 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3640 enable_symvers=no
3641 ;;
3642 esac
3643 fi
3644
3645 # Check to see if 'gnu' can win.
3646 if test $enable_symvers = gnu ||
3647 test $enable_symvers = gnu-versioned-namespace ||
3648 test $enable_symvers = sun; then
3649 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
3650 AC_MSG_CHECKING([for shared libgcc])
3651 ac_save_CFLAGS="$CFLAGS"
3652 CFLAGS=' -lgcc_s'
3653 AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
3654 CFLAGS="$ac_save_CFLAGS"
3655 if test $glibcxx_shared_libgcc = no; then
3656 cat > conftest.c <<EOF
3657 int main (void) { return 0; }
3658 EOF
3659 changequote(,)dnl
3660 glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
3661 -shared -shared-libgcc -o conftest.so \
3662 conftest.c -v 2>&1 >/dev/null \
3663 | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
3664 changequote([,])dnl
3665 rm -f conftest.c conftest.so
3666 if test x${glibcxx_libgcc_s_suffix+set} = xset; then
3667 CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
3668 AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
3669 CFLAGS="$ac_save_CFLAGS"
3670 fi
3671 fi
3672 AC_MSG_RESULT($glibcxx_shared_libgcc)
3673
3674 # For GNU ld, we need at least this version. The format is described in
3675 # GLIBCXX_CHECK_LINKER_FEATURES above.
3676 glibcxx_min_gnu_ld_version=21400
3677
3678 # If no shared libgcc, can't win.
3679 if test $glibcxx_shared_libgcc != yes; then
3680 AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3681 AC_MSG_WARN([=== you are not building a shared libgcc_s.])
3682 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3683 enable_symvers=no
3684 elif test $with_gnu_ld != yes && test $enable_symvers = sun; then
3685 : All interesting versions of Sun ld support sun style symbol versioning.
3686 elif test $with_gnu_ld != yes ; then
3687 # just fail for now
3688 AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3689 AC_MSG_WARN([=== you are not using the GNU linker.])
3690 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3691 enable_symvers=no
3692 elif test $glibcxx_ld_is_gold = yes ; then
3693 : All versions of gold support symbol versioning.
3694 elif test $glibcxx_gnu_ld_version -lt $glibcxx_min_gnu_ld_version ; then
3695 # The right tools, the right setup, but too old. Fallbacks?
3696 AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
3697 AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
3698 AC_MSG_WARN(=== You would need to upgrade your binutils to version)
3699 AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
3700 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3701 enable_symvers=no
3702 fi
3703 fi
3704
3705 # For libtool versioning info, format is CURRENT:REVISION:AGE
3706 libtool_VERSION=6:23:0
3707
3708 # Everything parsed; figure out what files and settings to use.
3709 case $enable_symvers in
3710 no)
3711 SYMVER_FILE=config/abi/pre/none.ver
3712 ;;
3713 gnu)
3714 SYMVER_FILE=config/abi/pre/gnu.ver
3715 AC_DEFINE(_GLIBCXX_SYMVER_GNU, 1,
3716 [Define to use GNU versioning in the shared library.])
3717 ;;
3718 gnu-versioned-namespace)
3719 libtool_VERSION=7:0:0
3720 SYMVER_FILE=config/abi/pre/gnu-versioned-namespace.ver
3721 AC_DEFINE(_GLIBCXX_SYMVER_GNU_NAMESPACE, 1,
3722 [Define to use GNU namespace versioning in the shared library.])
3723 ;;
3724 darwin)
3725 SYMVER_FILE=config/abi/pre/gnu.ver
3726 AC_DEFINE(_GLIBCXX_SYMVER_DARWIN, 1,
3727 [Define to use darwin versioning in the shared library.])
3728 ;;
3729 sun)
3730 SYMVER_FILE=config/abi/pre/gnu.ver
3731 AC_DEFINE(_GLIBCXX_SYMVER_SUN, 1,
3732 [Define to use Sun versioning in the shared library.])
3733 ;;
3734 esac
3735
3736 if test x$enable_symvers != xno ; then
3737 AC_DEFINE(_GLIBCXX_SYMVER, 1,
3738 [Define to use symbol versioning in the shared library.])
3739 fi
3740
3741 AC_CACHE_CHECK([whether the target supports .symver directive],
3742 glibcxx_cv_have_as_symver_directive, [
3743 AC_TRY_COMPILE([void foo (void); __asm (".symver foo, bar@SYMVER");],
3744 [], glibcxx_cv_have_as_symver_directive=yes,
3745 glibcxx_cv_have_as_symver_directive=no)])
3746 if test $glibcxx_cv_have_as_symver_directive = yes; then
3747 AC_DEFINE(HAVE_AS_SYMVER_DIRECTIVE, 1,
3748 [Define to 1 if the target assembler supports .symver directive.])
3749 fi
3750
3751 AC_SUBST(SYMVER_FILE)
3752 AC_SUBST(port_specific_symbol_files)
3753 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS, test $enable_symvers != no)
3754 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU, test $enable_symvers = gnu)
3755 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU_NAMESPACE, test $enable_symvers = gnu-versioned-namespace)
3756 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_DARWIN, test $enable_symvers = darwin)
3757 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_SUN, test $enable_symvers = sun)
3758 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
3759
3760 if test $enable_symvers != no ; then
3761 case ${target_os} in
3762 # The Solaris 2 runtime linker doesn't support the GNU extension of
3763 # binding the same symbol to different versions
3764 solaris2*)
3765 ;;
3766 # Other platforms with GNU symbol versioning (GNU/Linux, more?) do.
3767 *)
3768 AC_DEFINE(HAVE_SYMVER_SYMBOL_RENAMING_RUNTIME_SUPPORT, 1,
3769 [Define to 1 if the target runtime linker supports binding the same symbol to different versions.])
3770 ;;
3771 esac
3772 fi
3773
3774 # Now, set up compatibility support, if any.
3775 # In addition, need this to deal with std::size_t mangling in
3776 # src/compatibility.cc. In a perfect world, could use
3777 # typeid(std::size_t).name()[0] to do direct substitution.
3778 AC_MSG_CHECKING([for size_t as unsigned int])
3779 ac_save_CFLAGS="$CFLAGS"
3780 CFLAGS="-Werror"
3781 AC_TRY_COMPILE(, [__SIZE_TYPE__* stp; unsigned int* uip; stp = uip;],
3782 [glibcxx_size_t_is_i=yes], [glibcxx_size_t_is_i=no])
3783 CFLAGS=$ac_save_CFLAGS
3784 if test "$glibcxx_size_t_is_i" = yes; then
3785 AC_DEFINE(_GLIBCXX_SIZE_T_IS_UINT, 1, [Define if size_t is unsigned int.])
3786 fi
3787 AC_MSG_RESULT([$glibcxx_size_t_is_i])
3788
3789 AC_MSG_CHECKING([for ptrdiff_t as int])
3790 ac_save_CFLAGS="$CFLAGS"
3791 CFLAGS="-Werror"
3792 AC_TRY_COMPILE(, [__PTRDIFF_TYPE__* ptp; int* ip; ptp = ip;],
3793 [glibcxx_ptrdiff_t_is_i=yes], [glibcxx_ptrdiff_t_is_i=no])
3794 CFLAGS=$ac_save_CFLAGS
3795 if test "$glibcxx_ptrdiff_t_is_i" = yes; then
3796 AC_DEFINE(_GLIBCXX_PTRDIFF_T_IS_INT, 1, [Define if ptrdiff_t is int.])
3797 fi
3798 AC_MSG_RESULT([$glibcxx_ptrdiff_t_is_i])
3799 ])
3800
3801
3802 dnl
3803 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
3804 dnl We must stage the required headers so that they will be installed
3805 dnl with the library (unlike libgcc, the STL implementation is provided
3806 dnl solely within headers). Since we must not inject random user-space
3807 dnl macro names into user-provided C++ code, we first stage into <file>-in
3808 dnl and process to <file> with an output command. The reason for a two-
3809 dnl stage process here is to correctly handle $srcdir!=$objdir without
3810 dnl having to write complex code (the sed commands to clean the macro
3811 dnl namespace are complex and fragile enough as it is). We must also
3812 dnl add a relative path so that -I- is supported properly.
3813 dnl
3814 dnl Substs:
3815 dnl thread_header
3816 dnl
3817 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
3818 AC_MSG_CHECKING([for thread model used by GCC])
3819 target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3820 AC_MSG_RESULT([$target_thread_file])
3821 GCC_AC_THREAD_HEADER([$target_thread_file])
3822 ])
3823
3824
3825 dnl
3826 dnl Check if gthread implementation defines the types and functions
3827 dnl required by the c++0x thread library. Conforming gthread
3828 dnl implementations can define __GTHREADS_CXX0X to enable use with c++0x.
3829 dnl
3830 dnl GLIBCXX_ENABLE_SYMVERS must be done before this.
3831 dnl
3832 AC_DEFUN([GLIBCXX_CHECK_GTHREADS], [
3833 GLIBCXX_ENABLE(libstdcxx-threads,auto,,[enable C++11 threads support])
3834
3835 if test x$enable_libstdcxx_threads = xauto ||
3836 test x$enable_libstdcxx_threads = xyes; then
3837
3838 AC_LANG_SAVE
3839 AC_LANG_CPLUSPLUS
3840
3841 ac_save_CXXFLAGS="$CXXFLAGS"
3842 CXXFLAGS="$CXXFLAGS -fno-exceptions \
3843 -I${toplevel_srcdir}/libgcc -I${toplevel_builddir}/libgcc"
3844
3845 target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3846 case $target_thread_file in
3847 posix)
3848 CXXFLAGS="$CXXFLAGS -DSUPPORTS_WEAK -DGTHREAD_USE_WEAK -D_PTHREADS"
3849 esac
3850
3851 AC_MSG_CHECKING([whether it can be safely assumed that mutex_timedlock is available])
3852
3853 AC_TRY_COMPILE([#include <unistd.h>],
3854 [
3855 // In case of POSIX threads check _POSIX_TIMEOUTS.
3856 #if (defined(_PTHREADS) \
3857 && (!defined(_POSIX_TIMEOUTS) || _POSIX_TIMEOUTS <= 0))
3858 #error
3859 #endif
3860 ], [ac_gthread_use_mutex_timedlock=1], [ac_gthread_use_mutex_timedlock=0])
3861
3862 AC_DEFINE_UNQUOTED(_GTHREAD_USE_MUTEX_TIMEDLOCK, $ac_gthread_use_mutex_timedlock,
3863 [Define to 1 if mutex_timedlock is available.])
3864
3865 if test $ac_gthread_use_mutex_timedlock = 1 ; then res_mutex_timedlock=yes ;
3866 else res_mutex_timedlock=no ; fi
3867 AC_MSG_RESULT([$res_mutex_timedlock])
3868
3869 AC_MSG_CHECKING([for gthreads library])
3870
3871 AC_TRY_COMPILE([#include "gthr.h"],
3872 [
3873 #ifndef __GTHREADS_CXX0X
3874 #error
3875 #endif
3876 ], [ac_has_gthreads=yes], [ac_has_gthreads=no])
3877 else
3878 ac_has_gthreads=no
3879 fi
3880
3881 AC_MSG_RESULT([$ac_has_gthreads])
3882
3883 if test x"$ac_has_gthreads" = x"yes"; then
3884 AC_DEFINE(_GLIBCXX_HAS_GTHREADS, 1,
3885 [Define if gthreads library is available.])
3886
3887 # Also check for pthread_rwlock_t for std::shared_timed_mutex in C++14
3888 AC_CHECK_TYPE([pthread_rwlock_t],
3889 [AC_DEFINE([_GLIBCXX_USE_PTHREAD_RWLOCK_T], 1,
3890 [Define if POSIX read/write locks are available in <gthr.h>.])],
3891 [],
3892 [#include "gthr.h"])
3893 fi
3894
3895 CXXFLAGS="$ac_save_CXXFLAGS"
3896 AC_LANG_RESTORE
3897 ])
3898
3899
3900 # Check whether LC_MESSAGES is available in <locale.h>.
3901 # Ulrich Drepper <drepper@cygnus.com>, 1995.
3902 #
3903 # This file file be copied and used freely without restrictions. It can
3904 # be used in projects which are not available under the GNU Public License
3905 # but which still want to provide support for the GNU gettext functionality.
3906 # Please note that the actual code is *not* freely available.
3907 AC_DEFUN([AC_LC_MESSAGES], [
3908 AC_CHECK_HEADER(locale.h, [
3909 AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
3910 [AC_TRY_COMPILE([#include <locale.h>], [return LC_MESSAGES],
3911 ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
3912 if test $ac_cv_val_LC_MESSAGES = yes; then
3913 AC_DEFINE(HAVE_LC_MESSAGES, 1,
3914 [Define if LC_MESSAGES is available in <locale.h>.])
3915 fi
3916 ])
3917 ])
3918
3919 dnl
3920 dnl Check whether rdrand is supported in the assembler.
3921 AC_DEFUN([GLIBCXX_CHECK_X86_RDRAND], [
3922 AC_MSG_CHECKING([for rdrand support in assembler])
3923 AC_CACHE_VAL(ac_cv_x86_rdrand, [
3924 ac_cv_x86_rdrand=no
3925 case "$target" in
3926 i?86-*-* | \
3927 x86_64-*-*)
3928 AC_TRY_COMPILE(, [asm("rdrand %eax");],
3929 [ac_cv_x86_rdrand=yes], [ac_cv_x86_rdrand=no])
3930 esac
3931 ])
3932 if test $ac_cv_x86_rdrand = yes; then
3933 AC_DEFINE(_GLIBCXX_X86_RDRAND, 1,
3934 [ Defined if as can handle rdrand. ])
3935 fi
3936 AC_MSG_RESULT($ac_cv_x86_rdrand)
3937 ])
3938
3939 dnl
3940 dnl Check whether get_nprocs is available in <sys/sysinfo.h>, and define _GLIBCXX_USE_GET_NPROCS.
3941 dnl
3942 AC_DEFUN([GLIBCXX_CHECK_GET_NPROCS], [
3943
3944 AC_LANG_SAVE
3945 AC_LANG_CPLUSPLUS
3946 ac_save_CXXFLAGS="$CXXFLAGS"
3947 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3948
3949 AC_MSG_CHECKING([for get_nprocs])
3950 AC_CACHE_VAL(glibcxx_cv_GET_NPROCS, [
3951 GCC_TRY_COMPILE_OR_LINK(
3952 [#include <sys/sysinfo.h>],
3953 [int n = get_nprocs();],
3954 [glibcxx_cv_GET_NPROCS=yes],
3955 [glibcxx_cv_GET_NPROCS=no])
3956 ])
3957 if test $glibcxx_cv_GET_NPROCS = yes; then
3958 AC_DEFINE(_GLIBCXX_USE_GET_NPROCS, 1, [Define if get_nprocs is available in <sys/sysinfo.h>.])
3959 fi
3960 AC_MSG_RESULT($glibcxx_cv_GET_NPROCS)
3961
3962 CXXFLAGS="$ac_save_CXXFLAGS"
3963 AC_LANG_RESTORE
3964 ])
3965
3966 dnl
3967 dnl Check whether sysconf(_SC_NPROCESSORS_ONLN) is available in <unistd.h>, and define _GLIBCXX_USE_SC_NPROCESSORS_ONLN.
3968 dnl
3969 AC_DEFUN([GLIBCXX_CHECK_SC_NPROCESSORS_ONLN], [
3970
3971 AC_LANG_SAVE
3972 AC_LANG_CPLUSPLUS
3973 ac_save_CXXFLAGS="$CXXFLAGS"
3974 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3975
3976 AC_MSG_CHECKING([for _SC_NPROCESSORS_ONLN])
3977 AC_CACHE_VAL(glibcxx_cv_SC_NPROCESSORS_ONLN, [
3978 GCC_TRY_COMPILE_OR_LINK(
3979 [#include <unistd.h>],
3980 [int n = sysconf(_SC_NPROCESSORS_ONLN);],
3981 [glibcxx_cv_SC_NPROCESSORS_ONLN=yes],
3982 [glibcxx_cv_SC_NPROCESSORS_ONLN=no])
3983 ])
3984 if test $glibcxx_cv_SC_NPROCESSORS_ONLN = yes; then
3985 AC_DEFINE(_GLIBCXX_USE_SC_NPROCESSORS_ONLN, 1, [Define if _SC_NPROCESSORS_ONLN is available in <unistd.h>.])
3986 fi
3987 AC_MSG_RESULT($glibcxx_cv_SC_NPROCESSORS_ONLN)
3988
3989 CXXFLAGS="$ac_save_CXXFLAGS"
3990 AC_LANG_RESTORE
3991 ])
3992
3993 dnl
3994 dnl Check whether sysconf(_SC_NPROC_ONLN) is available in <unistd.h>, and define _GLIBCXX_USE_SC_NPROC_ONLN.
3995 dnl
3996 AC_DEFUN([GLIBCXX_CHECK_SC_NPROC_ONLN], [
3997
3998 AC_LANG_SAVE
3999 AC_LANG_CPLUSPLUS
4000 ac_save_CXXFLAGS="$CXXFLAGS"
4001 CXXFLAGS="$CXXFLAGS -fno-exceptions"
4002
4003 AC_MSG_CHECKING([for _SC_NPROC_ONLN])
4004 AC_CACHE_VAL(glibcxx_cv_SC_NPROC_ONLN, [
4005 GCC_TRY_COMPILE_OR_LINK(
4006 [#include <unistd.h>],
4007 [int n = sysconf(_SC_NPROC_ONLN);],
4008 [glibcxx_cv_SC_NPROC_ONLN=yes],
4009 [glibcxx_cv_SC_NPROC_ONLN=no])
4010 ])
4011 if test $glibcxx_cv_SC_NPROC_ONLN = yes; then
4012 AC_DEFINE(_GLIBCXX_USE_SC_NPROC_ONLN, 1, [Define if _SC_NPROC_ONLN is available in <unistd.h>.])
4013 fi
4014 AC_MSG_RESULT($glibcxx_cv_SC_NPROC_ONLN)
4015
4016 CXXFLAGS="$ac_save_CXXFLAGS"
4017 AC_LANG_RESTORE
4018 ])
4019
4020 dnl
4021 dnl Check whether pthread_num_processors_np is available in <pthread.h>, and define _GLIBCXX_USE_PTHREADS_NUM_PROCESSORS_NP.
4022 dnl
4023 AC_DEFUN([GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP], [
4024
4025 AC_LANG_SAVE
4026 AC_LANG_CPLUSPLUS
4027 ac_save_CXXFLAGS="$CXXFLAGS"
4028 CXXFLAGS="$CXXFLAGS -fno-exceptions"
4029
4030 AC_MSG_CHECKING([for pthreads_num_processors_np])
4031 AC_CACHE_VAL(glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP, [
4032 GCC_TRY_COMPILE_OR_LINK(
4033 [#include <pthread.h>],
4034 [int n = pthread_num_processors_np();],
4035 [glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP=yes],
4036 [glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP=no])
4037 ])
4038 if test $glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP = yes; then
4039 AC_DEFINE(_GLIBCXX_USE_PTHREADS_NUM_PROCESSORS_NP, 1, [Define if pthreads_num_processors_np is available in <pthread.h>.])
4040 fi
4041 AC_MSG_RESULT($glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP)
4042
4043 CXXFLAGS="$ac_save_CXXFLAGS"
4044 AC_LANG_RESTORE
4045 ])
4046
4047 dnl
4048 dnl Check whether sysctl is available in <pthread.h>, and define _GLIBCXX_USE_SYSCTL_HW_NCPU.
4049 dnl
4050 AC_DEFUN([GLIBCXX_CHECK_SYSCTL_HW_NCPU], [
4051
4052 AC_LANG_SAVE
4053 AC_LANG_CPLUSPLUS
4054 ac_save_CXXFLAGS="$CXXFLAGS"
4055 CXXFLAGS="$CXXFLAGS -fno-exceptions"
4056
4057 AC_MSG_CHECKING([for hw.ncpu sysctl])
4058 AC_CACHE_VAL(glibcxx_cv_SYSCTL_HW_NCPU, [
4059 GCC_TRY_COMPILE_OR_LINK(
4060 [
4061 #include <stddef.h>
4062 #include <sys/sysctl.h>
4063 ],
4064 [
4065 int count;
4066 size_t size = sizeof(count);
4067 int mib[] = { CTL_HW, HW_NCPU };
4068 sysctl(mib, 2, &count, &size, NULL, 0);
4069 ],
4070 [glibcxx_cv_SYSCTL_HW_NCPU=yes],
4071 [glibcxx_cv_SYSCTL_HW_NCPU=no])
4072 ])
4073 if test $glibcxx_cv_SYSCTL_HW_NCPU = yes; then
4074 AC_DEFINE(_GLIBCXX_USE_SYSCTL_HW_NCPU, 1, [Define if sysctl(), CTL_HW and HW_NCPU are available in <sys/sysctl.h>.])
4075 fi
4076 AC_MSG_RESULT($glibcxx_cv_SYSCTL_HW_NCPU)
4077
4078 CXXFLAGS="$ac_save_CXXFLAGS"
4079 AC_LANG_RESTORE
4080 ])
4081
4082 dnl
4083 dnl Check to see if python pretty printing can be activated.
4084 dnl
4085 dnl --with-python-dir=dir
4086 dnl installs directory into $prefix/dir
4087 AC_DEFUN([GLIBCXX_ENABLE_PYTHON], [
4088
4089 AC_MSG_CHECKING([for custom python install directory])
4090 AC_ARG_WITH([python-dir],
4091 AS_HELP_STRING([--with-python-dir],
4092 [the location to install Python modules. This path is relative starting from the prefix.]),
4093 [with_python_dir=$withval], [with_python_dir="no"])
4094 AC_MSG_RESULT(${with_python_dir})
4095
4096 # Needed for installing Python modules during make install.
4097 python_mod_dir="${with_python_dir}"
4098 AC_SUBST(python_mod_dir)
4099 GLIBCXX_CONDITIONAL(ENABLE_PYTHONDIR, test $python_mod_dir != no)
4100 ])
4101
4102 dnl
4103 dnl Check to see if -Werror is disabled.
4104 dnl
4105 dnl --enable-werror/--disable-werror
4106 AC_DEFUN([GLIBCXX_ENABLE_WERROR], [
4107 AC_MSG_CHECKING([for -Werror])
4108 GLIBCXX_ENABLE(werror,$1,,[turns on -Werror])
4109 AC_MSG_RESULT($enable_werror)
4110 GLIBCXX_CONDITIONAL(ENABLE_WERROR, test $enable_werror = yes)
4111 ])
4112
4113 dnl
4114 dnl Check whether obsolescent tmpnam is available in <stdio.h>,
4115 dnl and define _GLIBCXX_USE_TMPNAM.
4116 dnl
4117 AC_DEFUN([GLIBCXX_CHECK_TMPNAM], [dnl
4118 dnl
4119 AC_LANG_SAVE
4120 AC_LANG_CPLUSPLUS
4121 ac_save_CXXFLAGS="$CXXFLAGS"
4122 CXXFLAGS="$CXXFLAGS -fno-exceptions"
4123 dnl
4124 AC_MSG_CHECKING([for tmpnam])
4125 AC_CACHE_VAL(glibcxx_cv_TMPNAM, [dnl
4126 GCC_TRY_COMPILE_OR_LINK(
4127 [#include <stdio.h>],
4128 [char *tmp = tmpnam(NULL);],
4129 [glibcxx_cv_TMPNAM=yes],
4130 [glibcxx_cv_TMPNAM=no])
4131 ])
4132 if test $glibcxx_cv_TMPNAM = yes; then
4133 AC_DEFINE(_GLIBCXX_USE_TMPNAM, 1, [Define if obsolescent tmpnam is available in <stdio.h>.])
4134 fi
4135 AC_MSG_RESULT($glibcxx_cv_TMPNAM)
4136 dnl
4137 CXXFLAGS="$ac_save_CXXFLAGS"
4138 AC_LANG_RESTORE
4139 ])
4140
4141 dnl
4142 dnl Check to see if sys/sdt.h exists and that it is suitable for use.
4143 dnl Some versions of sdt.h were not compatible with C++11.
4144 dnl
4145 AC_DEFUN([GLIBCXX_CHECK_SDT_H], [
4146 AC_MSG_CHECKING([for suitable sys/sdt.h])
4147 # Note that this test has to be run with the C language.
4148 # Otherwise, sdt.h will try to include some headers from
4149 # libstdc++ itself.
4150 AC_LANG_SAVE
4151 AC_LANG_C
4152 AC_CACHE_VAL(glibcxx_cv_sys_sdt_h, [
4153 # Because we have to run the test in C, we use grep rather
4154 # than the compiler to check for the bug. The bug is that
4155 # were strings without trailing whitespace, causing g++
4156 # to look for operator"". The pattern searches for the fixed
4157 # output.
4158 AC_EGREP_CPP([ \",\" ], [
4159 #include <sys/sdt.h>
4160 int f() { STAP_PROBE(hi, bob); }
4161 ], [glibcxx_cv_sys_sdt_h=yes], [glibcxx_cv_sys_sdt_h=no])
4162 ])
4163 AC_LANG_RESTORE
4164 if test $glibcxx_cv_sys_sdt_h = yes; then
4165 AC_DEFINE(HAVE_SYS_SDT_H, 1,
4166 [Define to 1 if you have a suitable <sys/sdt.h> header file])
4167 fi
4168 AC_MSG_RESULT($glibcxx_cv_sys_sdt_h)
4169 ])
4170
4171 dnl
4172 dnl Control whether the library should define symbols for old and new ABIs.
4173 dnl This affects definitions of strings, stringstreams and locale facets.
4174 dnl
4175 dnl --disable-libstdcxx-dual-abi will use old ABI for all types.
4176 dnl
4177 dnl Defines:
4178 dnl _GLIBCXX_USE_DUAL_ABI (always defined, either to 1 or 0)
4179 dnl
4180 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_DUAL_ABI], [
4181 GLIBCXX_ENABLE(libstdcxx-dual-abi,$1,,[support two versions of std::string])
4182 if test x$enable_symvers = xgnu-versioned-namespace; then
4183 # gnu-versioned-namespace is incompatible with the dual ABI.
4184 enable_libstdcxx_dual_abi="no"
4185 fi
4186 if test x"$enable_libstdcxx_dual_abi" != xyes; then
4187 AC_MSG_NOTICE([dual ABI is disabled])
4188 default_libstdcxx_abi="gcc4-compatible"
4189 fi
4190 GLIBCXX_CONDITIONAL(ENABLE_DUAL_ABI, test $enable_libstdcxx_dual_abi = yes)
4191 ])
4192
4193 dnl
4194 dnl Check to see which ABI should be enabled by default.
4195 dnl
4196 dnl --with-default-libstdcxx-abi={gcc4-compatible,new}
4197 dnl
4198 dnl Defines:
4199 dnl _GLIBCXX_USE_CXX11_ABI (always defined, either to 1 or 0)
4200 dnl
4201 AC_DEFUN([GLIBCXX_DEFAULT_ABI], [
4202 if test x$enable_libstdcxx_dual_abi = xyes; then
4203 AC_MSG_CHECKING([for default std::string ABI to use])
4204 AC_ARG_WITH([default-libstdcxx-abi],
4205 AS_HELP_STRING([--with-default-libstdcxx-abi],
4206 [set the std::string ABI to use by default]),
4207 [case "$withval" in
4208 gcc4-compatible) default_libstdcxx_abi="gcc4-compatible" ;;
4209 new|cxx11) default_libstdcxx_abi="new" ;;
4210 c++*|gnu++*) AC_MSG_ERROR([Supported arguments for --with-default-libstdcxx-abi have changed, use "new" or "gcc4-compatible"]) ;;
4211 *) AC_MSG_ERROR([Invalid argument for --with-default-libstdcxx-abi]) ;;
4212 esac
4213 ],
4214 [default_libstdcxx_abi="new"])
4215 AC_MSG_RESULT(${default_libstdcxx_abi})
4216 fi
4217 if test $default_libstdcxx_abi = "new"; then
4218 glibcxx_cxx11_abi=1
4219 glibcxx_cxx98_abi=0
4220 else
4221 glibcxx_cxx11_abi=0
4222 glibcxx_cxx98_abi=1
4223 fi
4224 AC_SUBST(glibcxx_cxx98_abi)
4225 GLIBCXX_CONDITIONAL(ENABLE_CXX11_ABI, test $glibcxx_cxx11_abi = 1)
4226 ])
4227
4228 dnl
4229 dnl Check to see whether to build libstdc++fs.a
4230 dnl
4231 dnl --enable-libstdcxx-filesystem-ts
4232 dnl
4233 AC_DEFUN([GLIBCXX_ENABLE_FILESYSTEM_TS], [
4234 GLIBCXX_ENABLE(libstdcxx-filesystem-ts,auto,,
4235 [turns on ISO/IEC TS 18822 support],
4236 [permit yes|no|auto])
4237
4238 AC_MSG_CHECKING([whether to build Filesystem TS support])
4239 if test x"$ac_cv_header_dirent_h" != x"yes"; then
4240 enable_libstdcxx_filesystem_ts=no
4241 fi
4242 if test x"$enable_libstdcxx_filesystem_ts" = x"auto"; then
4243 case "${target_os}" in
4244 freebsd*|netbsd*|openbsd*|dragonfly*|darwin*)
4245 enable_libstdcxx_filesystem_ts=yes
4246 ;;
4247 gnu* | linux* | kfreebsd*-gnu | knetbsd*-gnu)
4248 enable_libstdcxx_filesystem_ts=yes
4249 ;;
4250 solaris*)
4251 enable_libstdcxx_filesystem_ts=yes
4252 ;;
4253 *)
4254 enable_libstdcxx_filesystem_ts=no
4255 ;;
4256 esac
4257 fi
4258 AC_MSG_RESULT($enable_libstdcxx_filesystem_ts)
4259 GLIBCXX_CONDITIONAL(ENABLE_FILESYSTEM_TS, test $enable_libstdcxx_filesystem_ts = yes)
4260 ])
4261
4262 dnl
4263 dnl Check whether the library calls required by the Filesystem TS are present
4264 dnl and define _GLIBCXX_USE_REALPATH and _GLIBCXX_USE_UTIMENSAT.
4265 dnl
4266 AC_DEFUN([GLIBCXX_CHECK_FILESYSTEM_DEPS], [dnl
4267 dnl
4268 AC_LANG_SAVE
4269 AC_LANG_CPLUSPLUS
4270 ac_save_CXXFLAGS="$CXXFLAGS"
4271 CXXFLAGS="$CXXFLAGS -fno-exceptions"
4272 dnl
4273 AC_MSG_CHECKING([for struct dirent.d_type])
4274 AC_CACHE_VAL(glibcxx_cv_dirent_d_type, [dnl
4275 GCC_TRY_COMPILE_OR_LINK(
4276 [#include <dirent.h>],
4277 [
4278 struct dirent d;
4279 if (sizeof d.d_type) return 0;
4280 ],
4281 [glibcxx_cv_dirent_d_type=yes],
4282 [glibcxx_cv_dirent_d_type=no])
4283 ])
4284 if test $glibcxx_cv_dirent_d_type = yes; then
4285 AC_DEFINE(HAVE_STRUCT_DIRENT_D_TYPE, 1, [Define to 1 if `d_type' is a member of `struct dirent'.])
4286 fi
4287 AC_MSG_RESULT($glibcxx_cv_dirent_d_type)
4288 dnl
4289 AC_MSG_CHECKING([for realpath])
4290 AC_CACHE_VAL(glibcxx_cv_realpath, [dnl
4291 GCC_TRY_COMPILE_OR_LINK(
4292 [
4293 #include <limits.h>
4294 #include <stdlib.h>
4295 #include <unistd.h>
4296 ],
4297 [
4298 #if _XOPEN_VERSION < 500
4299 #error
4300 #elif _XOPEN_VERSION >= 700 || defined(PATH_MAX)
4301 char *tmp = realpath((const char*)NULL, (char*)NULL);
4302 #else
4303 #error
4304 #endif
4305 ],
4306 [glibcxx_cv_realpath=yes],
4307 [glibcxx_cv_realpath=no])
4308 ])
4309 if test $glibcxx_cv_realpath = yes; then
4310 AC_DEFINE(_GLIBCXX_USE_REALPATH, 1, [Define if usable realpath is available in <stdlib.h>.])
4311 fi
4312 AC_MSG_RESULT($glibcxx_cv_realpath)
4313 dnl
4314 AC_MSG_CHECKING([for utimensat])
4315 AC_CACHE_VAL(glibcxx_cv_utimensat, [dnl
4316 GCC_TRY_COMPILE_OR_LINK(
4317 [
4318 #include <fcntl.h>
4319 #include <sys/stat.h>
4320 ],
4321 [
4322 struct timespec ts[2] = { { 0, UTIME_OMIT }, { 1, 1 } };
4323 int i = utimensat(AT_FDCWD, "path", ts, 0);
4324 ],
4325 [glibcxx_cv_utimensat=yes],
4326 [glibcxx_cv_utimensat=no])
4327 ])
4328 if test $glibcxx_cv_utimensat = yes; then
4329 AC_DEFINE(_GLIBCXX_USE_UTIMENSAT, 1, [Define if utimensat and UTIME_OMIT are available in <sys/stat.h> and AT_FDCWD in <fcntl.h>.])
4330 fi
4331 AC_MSG_RESULT($glibcxx_cv_utimensat)
4332 dnl
4333 AC_MSG_CHECKING([for struct stat.st_mtim.tv_nsec])
4334 AC_CACHE_VAL(glibcxx_cv_st_mtim, [dnl
4335 GCC_TRY_COMPILE_OR_LINK(
4336 [ #include <sys/stat.h> ],
4337 [
4338 struct stat st;
4339 return st.st_mtim.tv_nsec;
4340 ],
4341 [glibcxx_cv_st_mtim=yes],
4342 [glibcxx_cv_st_mtim=no])
4343 ])
4344 if test $glibcxx_cv_st_mtim = yes; then
4345 AC_DEFINE(_GLIBCXX_USE_ST_MTIM, 1, [Define if struct stat has timespec members.])
4346 fi
4347 AC_MSG_RESULT($glibcxx_cv_st_mtim)
4348 dnl
4349 AC_MSG_CHECKING([for fchmod])
4350 AC_CACHE_VAL(glibcxx_cv_fchmod, [dnl
4351 GCC_TRY_COMPILE_OR_LINK(
4352 [#include <sys/stat.h>],
4353 [fchmod(1, S_IWUSR);],
4354 [glibcxx_cv_fchmod=yes],
4355 [glibcxx_cv_fchmod=no])
4356 ])
4357 if test $glibcxx_cv_fchmod = yes; then
4358 AC_DEFINE(_GLIBCXX_USE_FCHMOD, 1, [Define if fchmod is available in <sys/stat.h>.])
4359 fi
4360 AC_MSG_RESULT($glibcxx_cv_fchmod)
4361 dnl
4362 AC_MSG_CHECKING([for fchmodat])
4363 AC_CACHE_VAL(glibcxx_cv_fchmodat, [dnl
4364 GCC_TRY_COMPILE_OR_LINK(
4365 [
4366 #include <fcntl.h>
4367 #include <sys/stat.h>
4368 ],
4369 [fchmodat(AT_FDCWD, "", 0, AT_SYMLINK_NOFOLLOW);],
4370 [glibcxx_cv_fchmodat=yes],
4371 [glibcxx_cv_fchmodat=no])
4372 ])
4373 if test $glibcxx_cv_fchmodat = yes; then
4374 AC_DEFINE(_GLIBCXX_USE_FCHMODAT, 1, [Define if fchmodat is available in <sys/stat.h>.])
4375 fi
4376 AC_MSG_RESULT($glibcxx_cv_fchmodat)
4377 dnl
4378 AC_MSG_CHECKING([for sendfile that can copy files])
4379 AC_CACHE_VAL(glibcxx_cv_sendfile, [dnl
4380 case "${target_os}" in
4381 gnu* | linux* | solaris*)
4382 GCC_TRY_COMPILE_OR_LINK(
4383 [#include <sys/sendfile.h>],
4384 [sendfile(1, 2, (off_t*)0, sizeof 1);],
4385 [glibcxx_cv_sendfile=yes],
4386 [glibcxx_cv_sendfile=no])
4387 ;;
4388 *)
4389 glibcxx_cv_sendfile=no
4390 ;;
4391 esac
4392 ])
4393 if test $glibcxx_cv_sendfile = yes; then
4394 AC_DEFINE(_GLIBCXX_USE_SENDFILE, 1, [Define if sendfile is available in <sys/sendfile.h>.])
4395 fi
4396 AC_MSG_RESULT($glibcxx_cv_sendfile)
4397 dnl
4398 CXXFLAGS="$ac_save_CXXFLAGS"
4399 AC_LANG_RESTORE
4400 ])
4401
4402 dnl
4403 dnl Check how size_t is mangled. Copied from libitm.
4404 dnl
4405 AC_DEFUN([GLIBCXX_CHECK_SIZE_T_MANGLING], [
4406 AC_CACHE_CHECK([how size_t is mangled],
4407 glibcxx_cv_size_t_mangling, [
4408 AC_TRY_COMPILE([], [extern __SIZE_TYPE__ x; extern unsigned long x;],
4409 [glibcxx_cv_size_t_mangling=m], [
4410 AC_TRY_COMPILE([], [extern __SIZE_TYPE__ x; extern unsigned int x;],
4411 [glibcxx_cv_size_t_mangling=j], [
4412 AC_TRY_COMPILE([],
4413 [extern __SIZE_TYPE__ x; extern unsigned long long x;],
4414 [glibcxx_cv_size_t_mangling=y], [
4415 AC_TRY_COMPILE([],
4416 [extern __SIZE_TYPE__ x; extern unsigned short x;],
4417 [glibcxx_cv_size_t_mangling=t],
4418 [glibcxx_cv_size_t_mangling=x])
4419 ])
4420 ])
4421 ])
4422 ])
4423 if test $glibcxx_cv_size_t_mangling = x; then
4424 AC_MSG_ERROR([Unknown underlying type for size_t])
4425 fi
4426 AC_DEFINE_UNQUOTED(_GLIBCXX_MANGLE_SIZE_T, [$glibcxx_cv_size_t_mangling],
4427 [Define to the letter to which size_t is mangled.])
4428 ])
4429
4430 # Macros from the top-level gcc directory.
4431 m4_include([../config/gc++filt.m4])
4432 m4_include([../config/tls.m4])
4433 m4_include([../config/gthr.m4])