libstdc++-v3/acinclude.m4

   1 dnl
   2 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   3 dnl
   4 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   5 dnl end of configure.  This lets tested variables be reassigned, and the
   6 dnl conditional will depend on the final state of the variable.  For a simple
   7 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   8 dnl
   9 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  10 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
  11   m4_divert_text([glibcxx_diversion],dnl
  12    AM_CONDITIONAL([$1],[$2])
  13   )dnl
  14 ])dnl
  15 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
  16
  17
  18 dnl
  19 dnl Check to see what architecture and operating system we are compiling
  20 dnl for.  Also, if architecture- or OS-specific flags are required for
  21 dnl compilation, pick them up here.
  22 dnl
  23 AC_DEFUN([GLIBCXX_CHECK_HOST], [
  24   . $glibcxx_srcdir/configure.host
  25   AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
  26   AC_MSG_NOTICE([OS config directory is $os_include_dir])
  27 ])
  28
  29 dnl
  30 dnl Initialize the rest of the library configury.  At this point we have
  31 dnl variables like $host.
  32 dnl
  33 dnl Sets:
  34 dnl  SUBDIRS
  35 dnl Substs:
  36 dnl  glibcxx_builddir     (absolute path)
  37 dnl  glibcxx_srcdir       (absolute path)
  38 dnl  toplevel_builddir    (absolute path)
  39 dnl  toplevel_srcdir      (absolute path)
  40 dnl  with_cross_host
  41 dnl  with_newlib
  42 dnl  with_target_subdir
  43 dnl plus
  44 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  45 dnl  - default settings for all AM_CONFITIONAL test variables
  46 dnl  - lots of tools, like CC and CXX
  47 dnl
  48 AC_DEFUN([GLIBCXX_CONFIGURE], [
  49   # Keep these sync'd with the list in Makefile.am.  The first provides an
  50   # expandable list at autoconf time; the second provides an expandable list
  51   # (i.e., shell variable) at configure time.
  52   m4_define([glibcxx_SUBDIRS],[include libsupc++ python src doc po testsuite])
  53   SUBDIRS='glibcxx_SUBDIRS'
  54
  55   # These need to be absolute paths, yet at the same time need to
  56   # canonicalize only relative paths, because then amd will not unmount
  57   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  58   glibcxx_builddir=`${PWDCMD-pwd}`
  59   case $srcdir in
  60     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  61     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  62   esac
  63   toplevel_builddir=${glibcxx_builddir}/..
  64   toplevel_srcdir=${glibcxx_srcdir}/..
  65   AC_SUBST(glibcxx_builddir)
  66   AC_SUBST(glibcxx_srcdir)
  67   AC_SUBST(toplevel_builddir)
  68   AC_SUBST(toplevel_srcdir)
  69
  70   # We use these options to decide which functions to include.  They are
  71   # set from the top level.
  72   AC_ARG_WITH([target-subdir],
  73     AC_HELP_STRING([--with-target-subdir=SUBDIR],
  74                    [configuring in a subdirectory]))
  75
  76   AC_ARG_WITH([cross-host],
  77     AC_HELP_STRING([--with-cross-host=HOST],
  78                    [configuring with a cross compiler]))
  79
  80   AC_ARG_WITH([newlib],
  81     AC_HELP_STRING([--with-newlib],
  82                    [assume newlib as a system C library]))
  83
  84   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
  85   # available).  Uncomment the next line to force a particular method.
  86   AC_PROG_LN_S
  87   #LN_S='cp -p'
  88
  89   AC_CHECK_TOOL(AS, as)
  90   AC_CHECK_TOOL(AR, ar)
  91   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
  92
  93   AM_MAINTAINER_MODE
  94
  95   # Set up safe default values for all subsequent AM_CONDITIONAL tests
  96   # which are themselves conditionally expanded.
  97   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
  98   ## other macros from doing the same.  This should be automated.)  -pme
  99
 100   # Check for C library flavor since GNU/Linux platforms use different
 101   # configuration directories depending on the C library in use.
 102   AC_EGREP_CPP([_using_uclibc], [
 103   #include <stdio.h>
 104   #if __UCLIBC__
 105     _using_uclibc
 106   #endif
 107   ], uclibc=yes, uclibc=no)
 108
 109   AC_EGREP_CPP([_using_bionic], [
 110   #include <stdio.h>
 111   #if __BIONIC__
 112     _using_bionic
 113   #endif
 114   ], bionic=yes, bionic=no)
 115
 116   # Find platform-specific directories containing configuration info.
 117   # Also possibly modify flags used elsewhere, as needed by the platform.
 118   GLIBCXX_CHECK_HOST
 119 ])
 120
 121
 122 dnl
 123 dnl Tests for newer compiler features, or features that are present in newer
 124 dnl compiler versions but not older compiler versions still in use, should
 125 dnl be placed here.
 126 dnl
 127 dnl Defines:
 128 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 129 dnl   new inlining code or the new system_header pragma will die on -Werror.
 130 dnl   Leave it out by default and use maint-mode to use it.
 131 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 132 dnl   compiler supports it and the user has not requested debug mode.
 133 dnl
 134 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
 135   # All these tests are for C++; save the language and the compiler flags.
 136   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 137   # found in GLIBCXX_CONFIGURE.
 138   AC_LANG_SAVE
 139   AC_LANG_CPLUSPLUS
 140   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 141   ac_save_CXXFLAGS="$CXXFLAGS"
 142
 143   # Check for maintainer-mode bits.
 144   if test x"$USE_MAINTAINER_MODE" = xno; then
 145     WERROR=''
 146   else
 147     WERROR='-Werror'
 148   fi
 149
 150   # Check for -ffunction-sections -fdata-sections
 151   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 152   CXXFLAGS='-g -Werror -ffunction-sections -fdata-sections'
 153   AC_TRY_COMPILE([int foo; void bar() { };],, [ac_fdsections=yes], [ac_fdsections=no])
 154   if test "$ac_test_CXXFLAGS" = set; then
 155     CXXFLAGS="$ac_save_CXXFLAGS"
 156   else
 157     # this is the suspicious part
 158     CXXFLAGS=''
 159   fi
 160   if test x"$ac_fdsections" = x"yes"; then
 161     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 162   fi
 163   AC_MSG_RESULT($ac_fdsections)
 164
 165   AC_LANG_RESTORE
 166   AC_SUBST(WERROR)
 167   AC_SUBST(SECTION_FLAGS)
 168 ])
 169
 170
 171 dnl
 172 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 173 dnl the native linker is in use, all variables will be defined to something
 174 dnl safe (like an empty string).
 175 dnl
 176 dnl Defines:
 177 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 178 dnl  OPT_LDFLAGS='-Wl,-O1' and '-z,relro' if possible
 179 dnl  LD (as a side effect of testing)
 180 dnl Sets:
 181 dnl  with_gnu_ld
 182 dnl  glibcxx_ld_is_gold (set to "no" or "yes")
 183 dnl  glibcxx_gnu_ld_version (possibly)
 184 dnl
 185 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 186 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 187 dnl
 188 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
 189   # If we're not using GNU ld, then there's no point in even trying these
 190   # tests.  Check for that first.  We should have already tested for gld
 191   # by now (in libtool), but require it now just to be safe...
 192   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 193   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 194   AC_REQUIRE([AC_PROG_LD])
 195   AC_REQUIRE([AC_PROG_AWK])
 196
 197   # The name set by libtool depends on the version of libtool.  Shame on us
 198   # for depending on an impl detail, but c'est la vie.  Older versions used
 199   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 200   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 201   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 202   # set (hence we're using an older libtool), then set it.
 203   if test x${with_gnu_ld+set} != xset; then
 204     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 205       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 206       with_gnu_ld=no
 207     else
 208       with_gnu_ld=$ac_cv_prog_gnu_ld
 209     fi
 210   fi
 211
 212   # Start by getting the version number.  I think the libtool test already
 213   # does some of this, but throws away the result.
 214   glibcxx_ld_is_gold=no
 215   if test x"$with_gnu_ld" = x"yes"; then
 216     AC_MSG_CHECKING([for ld version])
 217     changequote(,)
 218     if $LD --version 2>/dev/null | grep 'GNU gold' >/dev/null 2>&1; then
 219       glibcxx_ld_is_gold=yes
 220     fi
 221     ldver=`$LD --version 2>/dev/null |
 222            sed -e 's/GNU gold /GNU ld /;s/GNU ld version /GNU ld /;s/GNU ld ([^)]*) /GNU ld /;s/GNU ld \([0-9.][0-9.]*\).*/\1/; q'`
 223     changequote([,])
 224     glibcxx_gnu_ld_version=`echo $ldver | \
 225            $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 226     AC_MSG_RESULT($glibcxx_gnu_ld_version)
 227   fi
 228
 229   # Set --gc-sections.
 230   glibcxx_have_gc_sections=no
 231   if test "$glibcxx_ld_is_gold" = "yes"; then
 232     if $LD --help 2>/dev/null | grep gc-sections >/dev/null 2>&1; then
 233       glibcxx_have_gc_sections=yes
 234     fi
 235   else
 236     glibcxx_gcsections_min_ld=21602
 237     if test x"$with_gnu_ld" = x"yes" &&
 238         test $glibcxx_gnu_ld_version -gt $glibcxx_gcsections_min_ld ; then
 239       glibcxx_have_gc_sections=yes
 240     fi
 241   fi
 242   if test "$glibcxx_have_gc_sections" = "yes"; then
 243     # Sufficiently young GNU ld it is!  Joy and bunny rabbits!
 244     # NB: This flag only works reliably after 2.16.1. Configure tests
 245     # for this are difficult, so hard wire a value that should work.
 246
 247     ac_test_CFLAGS="${CFLAGS+set}"
 248     ac_save_CFLAGS="$CFLAGS"
 249     CFLAGS='-Wl,--gc-sections'
 250
 251     # Check for -Wl,--gc-sections
 252     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 253     AC_TRY_LINK([ int one(void) { return 1; }
 254      int two(void) { return 2; }
 255         ], [ two(); ] , [ac_gcsections=yes], [ac_gcsections=no])
 256     if test "$ac_gcsections" = "yes"; then
 257       rm -f conftest.c
 258       touch conftest.c
 259       if $CC -c conftest.c; then
 260         if $LD --gc-sections -o conftest conftest.o 2>&1 | \
 261            grep "Warning: gc-sections option ignored" > /dev/null; then
 262           ac_gcsections=no
 263         fi
 264       fi
 265       rm -f conftest.c conftest.o conftest
 266     fi
 267     if test "$ac_gcsections" = "yes"; then
 268       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 269     fi
 270     AC_MSG_RESULT($ac_gcsections)
 271
 272     if test "$ac_test_CFLAGS" = set; then
 273       CFLAGS="$ac_save_CFLAGS"
 274     else
 275       # this is the suspicious part
 276       CFLAGS=''
 277     fi
 278   fi
 279
 280   # Set -z,relro.
 281   # Note this is only for shared objects.
 282   ac_ld_relro=no
 283   if test x"$with_gnu_ld" = x"yes"; then
 284     AC_MSG_CHECKING([for ld that supports -Wl,-z,relro])
 285     cxx_z_relo=`$LD -v --help 2>/dev/null | grep "z relro"`
 286     if test -n "$cxx_z_relo"; then
 287       OPT_LDFLAGS="-Wl,-z,relro"
 288       ac_ld_relro=yes
 289     fi
 290     AC_MSG_RESULT($ac_ld_relro)
 291   fi
 292
 293   # Set linker optimization flags.
 294   if test x"$with_gnu_ld" = x"yes"; then
 295     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 296   fi
 297
 298   AC_SUBST(SECTION_LDFLAGS)
 299   AC_SUBST(OPT_LDFLAGS)
 300 ])
 301
 302
 303 dnl
 304 dnl Check for headers for, and arguments to, the setrlimit() function.
 305 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 306 dnl
 307 dnl Defines:
 308 dnl  _GLIBCXX_RES_LIMITS if we can set artificial resource limits
 309 dnl  various HAVE_LIMIT_* for individual limit names
 310 dnl
 311 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
 312   AC_MSG_CHECKING([for RLIMIT_$1])
 313   AC_TRY_COMPILE(
 314     [#include <unistd.h>
 315      #include <sys/time.h>
 316      #include <sys/resource.h>
 317     ],
 318     [ int f = RLIMIT_$1 ; ],
 319     [glibcxx_mresult=1], [glibcxx_mresult=0])
 320   AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
 321                      [Only used in build directory testsuite_hooks.h.])
 322   if test $glibcxx_mresult = 1 ; then res=yes ; else res=no ; fi
 323   AC_MSG_RESULT($res)
 324 ])
 325
 326 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
 327   setrlimit_have_headers=yes
 328   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 329                    [],
 330                    [setrlimit_have_headers=no])
 331   # If don't have the headers, then we can't run the tests now, and we
 332   # won't be seeing any of these during testsuite compilation.
 333   if test $setrlimit_have_headers = yes; then
 334     # Can't do these in a loop, else the resulting syntax is wrong.
 335     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 336     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 337     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 338     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 339     GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
 340
 341     # Check for rlimit, setrlimit.
 342     AC_CACHE_VAL(glibcxx_cv_setrlimit, [
 343       AC_TRY_COMPILE(
 344         [#include <unistd.h>
 345          #include <sys/time.h>
 346          #include <sys/resource.h>
 347         ],
 348         [struct rlimit r;
 349          setrlimit(0, &r);],
 350         [glibcxx_cv_setrlimit=yes], [glibcxx_cv_setrlimit=no])
 351     ])
 352   fi
 353
 354   AC_MSG_CHECKING([for testsuite resource limits support])
 355   if test $setrlimit_have_headers = yes && test $glibcxx_cv_setrlimit = yes; then
 356     ac_res_limits=yes
 357     AC_DEFINE(_GLIBCXX_RES_LIMITS, 1,
 358               [Define if using setrlimit to set resource limits during
 359               "make check"])
 360   else
 361     ac_res_limits=no
 362   fi
 363   AC_MSG_RESULT($ac_res_limits)
 364 ])
 365
 366
 367 dnl
 368 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 369 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 370 dnl
 371 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
 372
 373   AC_LANG_SAVE
 374   AC_LANG_CPLUSPLUS
 375   ac_save_CXXFLAGS="$CXXFLAGS"
 376   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 377
 378   AC_MSG_CHECKING([for S_ISREG or S_IFREG])
 379   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 380     GCC_TRY_COMPILE_OR_LINK(
 381       [#include <sys/stat.h>],
 382       [struct stat buffer;
 383        fstat(0, &buffer);
 384        S_ISREG(buffer.st_mode);],
 385       [glibcxx_cv_S_ISREG=yes],
 386       [glibcxx_cv_S_ISREG=no])
 387   ])
 388   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 389     GCC_TRY_COMPILE_OR_LINK(
 390       [#include <sys/stat.h>],
 391       [struct stat buffer;
 392        fstat(0, &buffer);
 393        S_IFREG & buffer.st_mode;],
 394       [glibcxx_cv_S_IFREG=yes],
 395       [glibcxx_cv_S_IFREG=no])
 396   ])
 397   res=no
 398   if test $glibcxx_cv_S_ISREG = yes; then
 399     AC_DEFINE(HAVE_S_ISREG, 1,
 400               [Define if S_IFREG is available in <sys/stat.h>.])
 401     res=S_ISREG
 402   elif test $glibcxx_cv_S_IFREG = yes; then
 403     AC_DEFINE(HAVE_S_IFREG, 1,
 404               [Define if S_IFREG is available in <sys/stat.h>.])
 405     res=S_IFREG
 406   fi
 407   AC_MSG_RESULT($res)
 408
 409   CXXFLAGS="$ac_save_CXXFLAGS"
 410   AC_LANG_RESTORE
 411 ])
 412
 413
 414 dnl
 415 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 416 dnl
 417 AC_DEFUN([GLIBCXX_CHECK_POLL], [
 418
 419   AC_LANG_SAVE
 420   AC_LANG_CPLUSPLUS
 421   ac_save_CXXFLAGS="$CXXFLAGS"
 422   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 423
 424   AC_MSG_CHECKING([for poll])
 425   AC_CACHE_VAL(glibcxx_cv_POLL, [
 426     GCC_TRY_COMPILE_OR_LINK(
 427       [#include <poll.h>],
 428       [struct pollfd pfd[1];
 429        pfd[0].events = POLLIN;
 430        poll(pfd, 1, 0);],
 431       [glibcxx_cv_POLL=yes],
 432       [glibcxx_cv_POLL=no])
 433   ])
 434   if test $glibcxx_cv_POLL = yes; then
 435     AC_DEFINE(HAVE_POLL, 1, [Define if poll is available in <poll.h>.])
 436   fi
 437   AC_MSG_RESULT($glibcxx_cv_POLL)
 438
 439   CXXFLAGS="$ac_save_CXXFLAGS"
 440   AC_LANG_RESTORE
 441 ])
 442
 443
 444 dnl
 445 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 446 dnl
 447 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
 448
 449   AC_LANG_SAVE
 450   AC_LANG_CPLUSPLUS
 451   ac_save_CXXFLAGS="$CXXFLAGS"
 452   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 453
 454   AC_MSG_CHECKING([for writev])
 455   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 456     GCC_TRY_COMPILE_OR_LINK(
 457       [#include <sys/uio.h>],
 458       [struct iovec iov[2];
 459        writev(0, iov, 0);],
 460       [glibcxx_cv_WRITEV=yes],
 461       [glibcxx_cv_WRITEV=no])
 462   ])
 463   if test $glibcxx_cv_WRITEV = yes; then
 464     AC_DEFINE(HAVE_WRITEV, 1, [Define if writev is available in <sys/uio.h>.])
 465   fi
 466   AC_MSG_RESULT($glibcxx_cv_WRITEV)
 467
 468   CXXFLAGS="$ac_save_CXXFLAGS"
 469   AC_LANG_RESTORE
 470 ])
 471
 472
 473 dnl
 474 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 475 dnl Also check whether int64_t is actually a typedef to long or long long.
 476 dnl
 477 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
 478
 479   AC_LANG_SAVE
 480   AC_LANG_CPLUSPLUS
 481
 482   AC_MSG_CHECKING([for int64_t])
 483   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 484     AC_TRY_COMPILE(
 485       [#include <stdint.h>],
 486       [int64_t var;],
 487       [glibcxx_cv_INT64_T=yes],
 488       [glibcxx_cv_INT64_T=no])
 489   ])
 490
 491   if test $glibcxx_cv_INT64_T = yes; then
 492     AC_DEFINE(HAVE_INT64_T, 1, [Define if int64_t is available in <stdint.h>.])
 493     AC_MSG_RESULT($glibcxx_cv_INT64_T)
 494
 495     AC_MSG_CHECKING([for int64_t as long])
 496     AC_CACHE_VAL(glibcxx_cv_int64_t_long, [
 497       AC_TRY_COMPILE(
 498         [#include <stdint.h>
 499         template<typename, typename> struct same { enum { value = -1 }; };
 500         template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
 501         int array[same<int64_t, long>::value];], [],
 502         [glibcxx_cv_int64_t_long=yes], [glibcxx_cv_int64_t_long=no])
 503     ])
 504
 505     if test $glibcxx_cv_int64_t_long = yes; then
 506       AC_DEFINE(HAVE_INT64_T_LONG, 1, [Define if int64_t is a long.])
 507       AC_MSG_RESULT($glibcxx_cv_int64_t_long)
 508     fi
 509
 510     AC_MSG_CHECKING([for int64_t as long long])
 511     AC_CACHE_VAL(glibcxx_cv_int64_t_long_long, [
 512       AC_TRY_COMPILE(
 513         [#include <stdint.h>
 514         template<typename, typename> struct same { enum { value = -1 }; };
 515         template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
 516         int array[same<int64_t, long long>::value];], [],
 517         [glibcxx_cv_int64_t_long_long=yes], [glibcxx_cv_int64_t_long_long=no])
 518     ])
 519
 520     if test $glibcxx_cv_int64_t_long_long = yes; then
 521       AC_DEFINE(HAVE_INT64_T_LONG_LONG, 1, [Define if int64_t is a long long.])
 522       AC_MSG_RESULT($glibcxx_cv_int64_t_long_long)
 523     fi
 524   fi
 525
 526   AC_LANG_RESTORE
 527 ])
 528
 529
 530 dnl
 531 dnl Check whether LFS support is available.
 532 dnl
 533 AC_DEFUN([GLIBCXX_CHECK_LFS], [
 534   AC_LANG_SAVE
 535   AC_LANG_CPLUSPLUS
 536   ac_save_CXXFLAGS="$CXXFLAGS"
 537   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 538   AC_MSG_CHECKING([for LFS support])
 539   AC_CACHE_VAL(glibcxx_cv_LFS, [
 540     GCC_TRY_COMPILE_OR_LINK(
 541       [#include <unistd.h>
 542        #include <stdio.h>
 543        #include <sys/stat.h>
 544       ],
 545       [FILE* fp;
 546        fopen64("t", "w");
 547        fseeko64(fp, 0, SEEK_CUR);
 548        ftello64(fp);
 549        lseek64(1, 0, SEEK_CUR);
 550        struct stat64 buf;
 551        fstat64(1, &buf);],
 552       [glibcxx_cv_LFS=yes],
 553       [glibcxx_cv_LFS=no])
 554   ])
 555   if test $glibcxx_cv_LFS = yes; then
 556     AC_DEFINE(_GLIBCXX_USE_LFS, 1, [Define if LFS support is available.])
 557   fi
 558   AC_MSG_RESULT($glibcxx_cv_LFS)
 559   CXXFLAGS="$ac_save_CXXFLAGS"
 560   AC_LANG_RESTORE
 561 ])
 562
 563
 564 dnl
 565 dnl Check for whether a fully dynamic basic_string implementation should
 566 dnl be turned on, that does not put empty objects in per-process static
 567 dnl memory (mostly useful together with shared memory allocators, see PR
 568 dnl libstdc++/16612 for details).
 569 dnl
 570 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING to 1
 571 dnl --disable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING to 0
 572 dnl otherwise undefined
 573 dnl  +  Usage:  GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
 574 dnl       Where DEFAULT is either `yes' or `no'.
 575 dnl
 576 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
 577   GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
 578   if test $enable_fully_dynamic_string = yes; then
 579     enable_fully_dynamic_string_def=1
 580   else
 581     enable_fully_dynamic_string_def=0
 582   fi
 583   AC_DEFINE_UNQUOTED([_GLIBCXX_FULLY_DYNAMIC_STRING], [${enable_fully_dynamic_string_def}],
 584               [Define to 1 if a fully dynamic basic_string is wanted, 0 to disable, undefined for platform defaults])
 585 ])
 586
 587
 588 dnl
 589 dnl Does any necessary configuration of the testsuite directory.  Generates
 590 dnl the testsuite_hooks.h header.
 591 dnl
 592 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 593 dnl
 594 dnl Sets:
 595 dnl  enable_abi_check
 596 dnl  GLIBCXX_TEST_WCHAR_T
 597 dnl  GLIBCXX_TEST_THREAD
 598 dnl Substs:
 599 dnl  baseline_dir
 600 dnl  baseline_subdir_switch
 601 dnl
 602 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
 603   if $GLIBCXX_IS_NATIVE ; then
 604     # Do checks for resource limit functions.
 605     GLIBCXX_CHECK_SETRLIMIT
 606
 607     # Look for setenv, so that extended locale tests can be performed.
 608     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 609   fi
 610
 611   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes &&
 612      test $enable_symvers != no; then
 613     case "$host" in
 614       *-*-cygwin*)
 615         enable_abi_check=no ;;
 616       *)
 617         enable_abi_check=yes ;;
 618     esac
 619   else
 620     # Only build this as native, since automake does not understand
 621     # CXX_FOR_BUILD.
 622     enable_abi_check=no
 623   fi
 624
 625   # Export file names for ABI checking.
 626   baseline_dir="$glibcxx_srcdir/config/abi/post/${abi_baseline_pair}"
 627   AC_SUBST(baseline_dir)
 628   baseline_subdir_switch="$abi_baseline_subdir_switch"
 629   AC_SUBST(baseline_subdir_switch)
 630 ])
 631
 632
 633 dnl
 634 dnl Does any necessary configuration of the documentation directory.
 635 dnl
 636 dnl XSLTPROC must be set before this
 637 dnl
 638 dnl Sets:
 639 dnl  glibcxx_stylesheets
 640 dnl Substs:
 641 dnl  XSL_STYLE_DIR
 642 dnl
 643 AC_DEFUN([GLIBCXX_CONFIGURE_DOCBOOK], [
 644
 645 AC_MSG_CHECKING([for stylesheets used in generation of documentation])
 646 glibcxx_stylesheets=no
 647 if test x${XSLTPROC} = xyes && echo '<title/>' | xsltproc --noout --nonet --xinclude http://docbook.sourceforge.net/release/xsl-ns/current/xhtml-1_1/docbook.xsl - 2>/dev/null; then
 648   glibcxx_stylesheets=yes
 649 fi
 650 AC_MSG_RESULT($glibcxx_stylesheets)
 651
 652 AC_MSG_CHECKING([for local stylesheet directory])
 653 glibcxx_local_stylesheets=no
 654 if test x"$glibcxx_stylesheets" = x"yes"; then
 655   if test -d /usr/share/sgml/docbook/xsl-ns-stylesheets; then
 656     glibcxx_local_stylesheets=yes
 657     XSL_STYLE_DIR=/usr/share/sgml/docbook/xsl-ns-stylesheets
 658   fi
 659   if test -d /usr/share/xml/docbook/stylesheet/docbook-xsl-ns; then
 660     glibcxx_local_stylesheets=yes
 661     XSL_STYLE_DIR=/usr/share/xml/docbook/stylesheet/docbook-xsl-ns
 662   fi
 663 fi
 664 AC_MSG_RESULT($glibcxx_local_stylesheets)
 665
 666 if test x"$glibcxx_local_stylesheets" = x"yes"; then
 667   AC_SUBST(XSL_STYLE_DIR)
 668   AC_MSG_NOTICE($XSL_STYLE_DIR)
 669 else
 670   glibcxx_stylesheets=no
 671 fi
 672 ])
 673
 674
 675 dnl
 676 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 677 dnl
 678 dnl Substs:
 679 dnl  GLIBCXX_INCLUDES
 680 dnl  TOPLEVEL_INCLUDES
 681 dnl
 682 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
 683   # Used for every C++ compile we perform.
 684   GLIBCXX_INCLUDES="\
 685 -I$glibcxx_builddir/include/$host_alias \
 686 -I$glibcxx_builddir/include \
 687 -I$glibcxx_srcdir/libsupc++"
 688
 689   # For Canadian crosses, pick this up too.
 690   if test $CANADIAN = yes; then
 691     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 692   fi
 693
 694   # Stuff in the actual top level.  Currently only used by libsupc++ to
 695   # get unwind* headers from the libgcc dir.
 696   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/libgcc -I$(toplevel_srcdir)/include'
 697   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/libgcc'
 698
 699   # Now, export this to all the little Makefiles....
 700   AC_SUBST(GLIBCXX_INCLUDES)
 701   AC_SUBST(TOPLEVEL_INCLUDES)
 702 ])
 703
 704
 705 dnl
 706 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 707 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 708 dnl
 709 dnl Substs:
 710 dnl  OPTIMIZE_CXXFLAGS
 711 dnl  WARN_FLAGS
 712 dnl
 713 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
 714   # Optimization flags that are probably a good idea for thrill-seekers. Just
 715   # uncomment the lines below and make, everything else is ready to go...
 716   # Alternatively OPTIMIZE_CXXFLAGS can be set in configure.host.
 717   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 718   AC_SUBST(OPTIMIZE_CXXFLAGS)
 719
 720   WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
 721   AC_SUBST(WARN_FLAGS)
 722 ])
 723
 724
 725 dnl
 726 dnl All installation directory information is determined here.
 727 dnl
 728 dnl Substs:
 729 dnl  gxx_install_dir
 730 dnl  glibcxx_prefixdir
 731 dnl  glibcxx_toolexecdir
 732 dnl  glibcxx_toolexeclibdir
 733 dnl
 734 dnl Assumes cross_compiling bits already done, and with_cross_host in
 735 dnl particular.
 736 dnl
 737 dnl This logic must match gcc/configure.ac's setting of gcc_gxx_include_dir.
 738 dnl config/gxx-include-dir.m4 must be kept consistant with this as well.
 739 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
 740   glibcxx_toolexecdir=no
 741   glibcxx_toolexeclibdir=no
 742   glibcxx_prefixdir=$prefix
 743
 744   AC_MSG_CHECKING([for gxx-include-dir])
 745   AC_ARG_WITH([gxx-include-dir],
 746     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 747                    [installation directory for include files]),
 748     [case "$withval" in
 749       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 750       no)  gxx_include_dir=no ;;
 751       *)   gxx_include_dir=$withval ;;
 752      esac],
 753     [gxx_include_dir=no])
 754   AC_MSG_RESULT($gxx_include_dir)
 755
 756   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 757   AC_ARG_ENABLE([version-specific-runtime-libs],
 758     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 759                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 760     [case "$enableval" in
 761       yes) version_specific_libs=yes ;;
 762       no)  version_specific_libs=no ;;
 763       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 764      esac],
 765     [version_specific_libs=no])
 766   AC_MSG_RESULT($version_specific_libs)
 767
 768   # Default case for install directory for include files.
 769   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 770     gxx_include_dir='include/c++/${gcc_version}'
 771     if test -n "$with_cross_host" &&
 772        test x"$with_cross_host" != x"no"; then
 773       gxx_include_dir='${prefix}/${target_alias}/'"$gxx_include_dir"
 774     else
 775       gxx_include_dir='${prefix}/'"$gxx_include_dir"
 776     fi
 777   fi
 778
 779   # Version-specific runtime libs processing.
 780   if test $version_specific_libs = yes; then
 781     # Need the gcc compiler version to know where to install libraries
 782     # and header files if --enable-version-specific-runtime-libs option
 783     # is selected.  FIXME: these variables are misnamed, there are
 784     # no executables installed in _toolexecdir or _toolexeclibdir.
 785     if test x"$gxx_include_dir" = x"no"; then
 786       gxx_include_dir='${libdir}/gcc/${host_alias}/${gcc_version}/include/c++'
 787     fi
 788     glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 789     glibcxx_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
 790   fi
 791
 792   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 793   # Install a library built with a cross compiler in tooldir, not libdir.
 794   if test x"$glibcxx_toolexecdir" = x"no"; then
 795     if test -n "$with_cross_host" &&
 796        test x"$with_cross_host" != x"no"; then
 797       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 798       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 799     else
 800       glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 801       glibcxx_toolexeclibdir='${libdir}'
 802     fi
 803     multi_os_directory=`$CXX -print-multi-os-directory`
 804     case $multi_os_directory in
 805       .) ;; # Avoid trailing /.
 806       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 807     esac
 808   fi
 809
 810   AC_MSG_CHECKING([for install location])
 811   AC_MSG_RESULT($gxx_include_dir)
 812
 813   AC_SUBST(glibcxx_prefixdir)
 814   AC_SUBST(gxx_include_dir)
 815   AC_SUBST(glibcxx_toolexecdir)
 816   AC_SUBST(glibcxx_toolexeclibdir)
 817 ])
 818
 819
 820 dnl
 821 dnl GLIBCXX_ENABLE
 822 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 823 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 824 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 825 dnl
 826 dnl See docs/html/17_intro/configury.html#enable for documentation.
 827 dnl
 828 m4_define([GLIBCXX_ENABLE],[dnl
 829 m4_define([_g_switch],[--enable-$1])dnl
 830 m4_define([_g_help],[AC_HELP_STRING([_g_switch$3],[$4 @<:@default=$2@:>@])])dnl
 831  AC_ARG_ENABLE([$1],m4_dquote(_g_help),
 832   m4_bmatch([$5],
 833    [^permit ],
 834      [[
 835       case "$enableval" in
 836        m4_bpatsubst([$5],[permit ])) ;;
 837        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 838           dnl Idea for future:  generate a URL pointing to
 839           dnl "onlinedocs/configopts.html#whatever"
 840       esac
 841      ]],
 842    [^$],
 843      [[
 844       case "$enableval" in
 845        yes|no) ;;
 846        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 847       esac
 848      ]],
 849    [[$5]]),
 850   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 851 m4_undefine([_g_switch])dnl
 852 m4_undefine([_g_help])dnl
 853 ])
 854
 855
 856 dnl
 857 dnl Check for ISO/IEC 9899:1999 "C99" support.
 858 dnl
 859 dnl --enable-c99 defines _GLIBCXX_USE_C99
 860 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 861 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 862 dnl       Where DEFAULT is either `yes' or `no'.
 863 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 864 dnl
 865 AC_DEFUN([GLIBCXX_ENABLE_C99], [
 866   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 867
 868   if test x"$enable_c99" = x"yes"; then
 869
 870   AC_LANG_SAVE
 871   AC_LANG_CPLUSPLUS
 872
 873   # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
 874   # undefined and fake C99 facilities - like pre-standard snprintf - may be
 875   # spuriously enabled.
 876   # Long term, -std=c++0x could be even better, could manage to explicitely
 877   # request C99 facilities to the underlying C headers.
 878   ac_save_CXXFLAGS="$CXXFLAGS"
 879   CXXFLAGS="$CXXFLAGS -std=c++98"
 880   ac_save_LIBS="$LIBS"
 881   ac_save_gcc_no_link="$gcc_no_link"
 882
 883   if test x$gcc_no_link != xyes; then
 884     # Use -fno-exceptions to that the C driver can link these tests without
 885     # hitting undefined references to personality routines.
 886     CXXFLAGS="$CXXFLAGS -fno-exceptions"
 887     AC_CHECK_LIB(m, sin, [
 888       LIBS="$LIBS -lm"
 889     ], [
 890       # Use the default compile-only tests in GCC_TRY_COMPILE_OR_LINK
 891       gcc_no_link=yes
 892     ])
 893   fi
 894
 895   # Check for the existence of <math.h> functions used if C99 is enabled.
 896   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 897   AC_CACHE_VAL(glibcxx_cv_c99_math, [
 898   GCC_TRY_COMPILE_OR_LINK(
 899      [#include <math.h>
 900       volatile double d1, d2;
 901       volatile int i;],
 902      [i = fpclassify(d1);
 903       i = isfinite(d1);
 904       i = isinf(d1);
 905       i = isnan(d1);
 906       i = isnormal(d1);
 907       i = signbit(d1);
 908       i = isgreater(d1, d2);
 909       i = isgreaterequal(d1, d2);
 910       i = isless(d1, d2);
 911       i = islessequal(d1, d2);
 912       i = islessgreater(d1, d2);
 913       i = islessgreater(d1, d2);
 914       i = isunordered(d1, d2);
 915      ],[glibcxx_cv_c99_math=yes], [glibcxx_cv_c99_math=no])
 916   ])
 917   AC_MSG_RESULT($glibcxx_cv_c99_math)
 918   if test x"$glibcxx_cv_c99_math" = x"yes"; then
 919     AC_DEFINE(_GLIBCXX_USE_C99_MATH, 1,
 920               [Define if C99 functions or macros in <math.h> should be imported
 921               in <cmath> in namespace std.])
 922   fi
 923
 924   # Check for the existence of <complex.h> complex math functions.
 925   # This is necessary even though libstdc++ uses the builtin versions
 926   # of these functions, because if the builtin cannot be used, a reference
 927   # to the library function is emitted.
 928   AC_CHECK_HEADERS(tgmath.h, ac_has_tgmath_h=yes, ac_has_tgmath_h=no)
 929   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
 930   glibcxx_cv_c99_complex=no;
 931   if test x"$ac_has_complex_h" = x"yes"; then
 932     AC_MSG_CHECKING([for ISO C99 support in <complex.h>])
 933     GCC_TRY_COMPILE_OR_LINK(
 934        [#include <complex.h>
 935         typedef __complex__ float float_type;
 936         typedef __complex__ double double_type;
 937         typedef __complex__ long double ld_type;
 938         volatile float_type tmpf;
 939         volatile double_type tmpd;
 940         volatile ld_type tmpld;
 941         volatile float f;
 942         volatile double d;
 943         volatile long double ld;],
 944        [f = cabsf(tmpf);
 945         f = cargf(tmpf);
 946         tmpf = ccosf(tmpf);
 947         tmpf = ccoshf(tmpf);
 948         tmpf = cexpf(tmpf);
 949         tmpf = clogf(tmpf);
 950         tmpf = csinf(tmpf);
 951         tmpf = csinhf(tmpf);
 952         tmpf = csqrtf(tmpf);
 953         tmpf = ctanf(tmpf);
 954         tmpf = ctanhf(tmpf);
 955         tmpf = cpowf(tmpf, tmpf);
 956         tmpf = cprojf(tmpf);
 957         d = cabs(tmpd);
 958         d = carg(tmpd);
 959         tmpd = ccos(tmpd);
 960         tmpd = ccosh(tmpd);
 961         tmpd = cexp(tmpd);
 962         tmpd = clog(tmpd);
 963         tmpd = csin(tmpd);
 964         tmpd = csinh(tmpd);
 965         tmpd = csqrt(tmpd);
 966         tmpd = ctan(tmpd);
 967         tmpd = ctanh(tmpd);
 968         tmpd = cpow(tmpd, tmpd);
 969         tmpd = cproj(tmpd);
 970         ld = cabsl(tmpld);
 971         ld = cargl(tmpld);
 972         tmpld = ccosl(tmpld);
 973         tmpld = ccoshl(tmpld);
 974         tmpld = cexpl(tmpld);
 975         tmpld = clogl(tmpld);
 976         tmpld = csinl(tmpld);
 977         tmpld = csinhl(tmpld);
 978         tmpld = csqrtl(tmpld);
 979         tmpld = ctanl(tmpld);
 980         tmpld = ctanhl(tmpld);
 981         tmpld = cpowl(tmpld, tmpld);
 982         tmpld = cprojl(tmpld);
 983        ],[glibcxx_cv_c99_complex=yes], [glibcxx_cv_c99_complex=no])
 984   fi
 985   AC_MSG_RESULT($glibcxx_cv_c99_complex)
 986   if test x"$glibcxx_cv_c99_complex" = x"yes"; then
 987     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX, 1,
 988               [Define if C99 functions in <complex.h> should be used in
 989               <complex>. Using compiler builtins for these functions requires
 990               corresponding C99 library functions to be present.])
 991   fi
 992
 993   # Check for the existence in <stdio.h> of vscanf, et. al.
 994   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 995   AC_CACHE_VAL(glibcxx_cv_c99_stdio, [
 996   GCC_TRY_COMPILE_OR_LINK(
 997      [#include <stdio.h>
 998       #include <stdarg.h>
 999       void foo(char* fmt, ...)
1000       {
1001         va_list args; va_start(args, fmt);
1002         vfscanf(stderr, "%i", args);
1003         vscanf("%i", args);
1004         vsnprintf(fmt, 0, "%i", args);
1005         vsscanf(fmt, "%i", args);
1006       }],
1007      [snprintf("12", 0, "%i");],
1008      [glibcxx_cv_c99_stdio=yes], [glibcxx_cv_c99_stdio=no])
1009   ])
1010   AC_MSG_RESULT($glibcxx_cv_c99_stdio)
1011
1012   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1013   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1014   AC_CACHE_VAL(glibcxx_cv_c99_stdlib, [
1015   GCC_TRY_COMPILE_OR_LINK(
1016      [#include <stdlib.h>
1017       volatile float f;
1018       volatile long double ld;
1019       volatile unsigned long long ll;
1020       lldiv_t mydivt;],
1021      [char* tmp;
1022       f = strtof("gnu", &tmp);
1023       ld = strtold("gnu", &tmp);
1024       ll = strtoll("gnu", &tmp, 10);
1025       ll = strtoull("gnu", &tmp, 10);
1026       ll = llabs(10);
1027       mydivt = lldiv(10,1);
1028       ll = mydivt.quot;
1029       ll = mydivt.rem;
1030       ll = atoll("10");
1031       _Exit(0);
1032       ],[glibcxx_cv_c99_stdlib=yes], [glibcxx_cv_c99_stdlib=no])
1033   ])
1034   AC_MSG_RESULT($glibcxx_cv_c99_stdlib)
1035
1036   # Check for the existence in <wchar.h> of wcstold, etc.
1037   glibcxx_cv_c99_wchar=no;
1038   if test x"$ac_has_wchar_h" = xyes &&
1039      test x"$ac_has_wctype_h" = xyes; then
1040     AC_MSG_CHECKING([for ISO C99 support in <wchar.h>])
1041     AC_TRY_COMPILE([#include <wchar.h>
1042                     namespace test
1043                     {
1044                       using ::wcstold;
1045                       using ::wcstoll;
1046                       using ::wcstoull;
1047                     }
1048                    ],[],[glibcxx_cv_c99_wchar=yes], [glibcxx_cv_c99_wchar=no])
1049
1050     # Checks for wide character functions that may not be present.
1051     # Injection of these is wrapped with guard macros.
1052     # NB: only put functions here, instead of immediately above, if
1053     # absolutely necessary.
1054     AC_TRY_COMPILE([#include <wchar.h>
1055                     namespace test { using ::vfwscanf; } ], [],
1056                    [AC_DEFINE(HAVE_VFWSCANF,1,
1057                         [Defined if vfwscanf exists.])],[])
1058
1059     AC_TRY_COMPILE([#include <wchar.h>
1060                     namespace test { using ::vswscanf; } ], [],
1061                    [AC_DEFINE(HAVE_VSWSCANF,1,
1062                         [Defined if vswscanf exists.])],[])
1063
1064     AC_TRY_COMPILE([#include <wchar.h>
1065                     namespace test { using ::vwscanf; } ], [],
1066                    [AC_DEFINE(HAVE_VWSCANF,1,[Defined if vwscanf exists.])],[])
1067
1068     AC_TRY_COMPILE([#include <wchar.h>
1069                     namespace test { using ::wcstof; } ], [],
1070                    [AC_DEFINE(HAVE_WCSTOF,1,[Defined if wcstof exists.])],[])
1071
1072     AC_TRY_COMPILE([#include <wctype.h>],
1073                    [ wint_t t; int i = iswblank(t);],
1074                    [AC_DEFINE(HAVE_ISWBLANK,1,
1075                         [Defined if iswblank exists.])],[])
1076
1077     AC_MSG_RESULT($glibcxx_cv_c99_wchar)
1078   fi
1079
1080   # Option parsed, now set things appropriately.
1081   if test x"$glibcxx_cv_c99_math" = x"no" ||
1082      test x"$glibcxx_cv_c99_complex" = x"no" ||
1083      test x"$glibcxx_cv_c99_stdio" = x"no" ||
1084      test x"$glibcxx_cv_c99_stdlib" = x"no" ||
1085      test x"$glibcxx_cv_c99_wchar" = x"no"; then
1086     enable_c99=no;
1087   else
1088     AC_DEFINE(_GLIBCXX_USE_C99, 1,
1089     [Define if C99 functions or macros from <wchar.h>, <math.h>,
1090     <complex.h>, <stdio.h>, and <stdlib.h> can be used or exposed.])
1091   fi
1092
1093   gcc_no_link="$ac_save_gcc_no_link"
1094   LIBS="$ac_save_LIBS"
1095   CXXFLAGS="$ac_save_CXXFLAGS"
1096   AC_LANG_RESTORE
1097   fi
1098
1099   AC_MSG_CHECKING([for fully enabled ISO C99 support])
1100   AC_MSG_RESULT($enable_c99)
1101 ])
1102
1103
1104 dnl
1105 dnl Check for clock_gettime, nanosleep and sched_yield, used in the
1106 dnl implementation of 20.8.5 [time.clock], and 30.2.2 [thread.thread.this]
1107 dnl in the current C++0x working draft.
1108 dnl
1109 dnl --enable-libstdcxx-time
1110 dnl --enable-libstdcxx-time=yes
1111 dnl        checks for the availability of monotonic and realtime clocks,
1112 dnl        nanosleep and sched_yield in libc and libposix4 and, in case, links
1113 dnl       the latter
1114 dnl --enable-libstdcxx-time=rt
1115 dnl        also searches (and, in case, links) librt.  Note that this is
1116 dnl        not always desirable because, in glibc, for example, in turn it
1117 dnl        triggers the linking of libpthread too, which activates locking,
1118 dnl        a large overhead for single-thread programs.
1119 dnl --enable-libstdcxx-time=no
1120 dnl --disable-libstdcxx-time
1121 dnl        disables the checks completely
1122 dnl
1123 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_TIME], [
1124
1125   AC_MSG_CHECKING([for clock_gettime, nanosleep and sched_yield])
1126   GLIBCXX_ENABLE(libstdcxx-time,$1,[[[=KIND]]],
1127     [use KIND for check type],
1128     [permit yes|no|rt])
1129
1130   AC_LANG_SAVE
1131   AC_LANG_CPLUSPLUS
1132   ac_save_CXXFLAGS="$CXXFLAGS"
1133   CXXFLAGS="$CXXFLAGS -fno-exceptions"
1134   ac_save_LIBS="$LIBS"
1135
1136   ac_has_clock_monotonic=no
1137   ac_has_clock_realtime=no
1138   AC_MSG_RESULT($enable_libstdcxx_time)
1139
1140   if test x"$enable_libstdcxx_time" != x"no"; then
1141
1142     if test x"$enable_libstdcxx_time" = x"rt"; then
1143       AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1144       AC_SEARCH_LIBS(nanosleep, [rt posix4])
1145     else
1146       AC_SEARCH_LIBS(clock_gettime, [posix4])
1147       AC_SEARCH_LIBS(nanosleep, [posix4])
1148     fi
1149
1150     case "$ac_cv_search_clock_gettime" in
1151       -l*) GLIBCXX_LIBS=$ac_cv_search_clock_gettime
1152       ;;
1153     esac
1154     case "$ac_cv_search_nanosleep" in
1155       -l*) GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_nanosleep"
1156       ;;
1157     esac
1158
1159     AC_SEARCH_LIBS(sched_yield, [rt posix4])
1160
1161     case "$ac_cv_search_sched_yield" in
1162       -lposix4*)
1163       GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1164       AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1165                 [ Defined if sched_yield is available. ])
1166       ;;
1167       -lrt*)
1168       if test x"$enable_libstdcxx_time" = x"rt"; then
1169         GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1170         AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1171                   [ Defined if sched_yield is available. ])
1172       fi
1173       ;;
1174       *)
1175       AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1176                 [ Defined if sched_yield is available. ])
1177       ;;
1178     esac
1179
1180     AC_CHECK_HEADERS(unistd.h, ac_has_unistd_h=yes, ac_has_unistd_h=no)
1181
1182     if test x"$ac_has_unistd_h" = x"yes"; then
1183       AC_MSG_CHECKING([for monotonic clock])
1184       AC_TRY_LINK(
1185         [#include <unistd.h>
1186          #include <time.h>
1187         ],
1188         [#if _POSIX_TIMERS > 0 && defined(_POSIX_MONOTONIC_CLOCK)
1189           timespec tp;
1190          #endif
1191           clock_gettime(CLOCK_MONOTONIC, &tp);
1192         ], [ac_has_clock_monotonic=yes], [ac_has_clock_monotonic=no])
1193
1194       AC_MSG_RESULT($ac_has_clock_monotonic)
1195
1196       AC_MSG_CHECKING([for realtime clock])
1197       AC_TRY_LINK(
1198         [#include <unistd.h>
1199          #include <time.h>
1200         ],
1201         [#if _POSIX_TIMERS > 0
1202           timespec tp;
1203          #endif
1204           clock_gettime(CLOCK_REALTIME, &tp);
1205         ], [ac_has_clock_realtime=yes], [ac_has_clock_realtime=no])
1206
1207       AC_MSG_RESULT($ac_has_clock_realtime)
1208
1209       AC_MSG_CHECKING([for nanosleep])
1210       AC_TRY_LINK(
1211         [#include <unistd.h>
1212          #include <time.h>
1213         ],
1214         [#if _POSIX_TIMERS > 0
1215           timespec tp;
1216          #endif
1217           nanosleep(&tp, 0);
1218         ], [ac_has_nanosleep=yes], [ac_has_nanosleep=no])
1219
1220       AC_MSG_RESULT($ac_has_nanosleep)
1221     fi
1222   fi
1223
1224   if test x"$ac_has_clock_monotonic" = x"yes"; then
1225     AC_DEFINE(_GLIBCXX_USE_CLOCK_MONOTONIC, 1,
1226       [ Defined if clock_gettime has monotonic clock support. ])
1227   fi
1228
1229   if test x"$ac_has_clock_realtime" = x"yes"; then
1230     AC_DEFINE(_GLIBCXX_USE_CLOCK_REALTIME, 1,
1231       [ Defined if clock_gettime has realtime clock support. ])
1232   fi
1233
1234   if test x"$ac_has_nanosleep" = x"yes"; then
1235     AC_DEFINE(_GLIBCXX_USE_NANOSLEEP, 1,
1236       [ Defined if nanosleep is available. ])
1237   fi
1238
1239   AC_SUBST(GLIBCXX_LIBS)
1240
1241   CXXFLAGS="$ac_save_CXXFLAGS"
1242   LIBS="$ac_save_LIBS"
1243   AC_LANG_RESTORE
1244 ])
1245
1246 dnl
1247 dnl Check for gettimeofday, used in the implementation of 20.8.5
1248 dnl [time.clock] in the current C++0x working draft.
1249 dnl
1250 AC_DEFUN([GLIBCXX_CHECK_GETTIMEOFDAY], [
1251
1252   AC_MSG_CHECKING([for gettimeofday])
1253
1254   AC_LANG_SAVE
1255   AC_LANG_CPLUSPLUS
1256   ac_save_CXXFLAGS="$CXXFLAGS"
1257   CXXFLAGS="$CXXFLAGS -fno-exceptions"
1258
1259   ac_has_gettimeofday=no;
1260   AC_CHECK_HEADERS(sys/time.h, ac_has_sys_time_h=yes, ac_has_sys_time_h=no)
1261   if test x"$ac_has_sys_time_h" = x"yes"; then
1262     AC_MSG_CHECKING([for gettimeofday])
1263     GCC_TRY_COMPILE_OR_LINK([#include <sys/time.h>],
1264       [timeval tv; gettimeofday(&tv, 0);],
1265       [ac_has_gettimeofday=yes], [ac_has_gettimeofday=no])
1266
1267     AC_MSG_RESULT($ac_has_gettimeofday)
1268   fi
1269
1270   if test x"$ac_has_gettimeofday" = x"yes"; then
1271     AC_DEFINE(_GLIBCXX_USE_GETTIMEOFDAY, 1,
1272       [ Defined if gettimeofday is available. ])
1273   fi
1274
1275   CXXFLAGS="$ac_save_CXXFLAGS"
1276   AC_LANG_RESTORE
1277 ])
1278
1279 dnl
1280 dnl Check for ISO/IEC 9899:1999 "C99" support to ISO/IEC DTR 19768 "TR1"
1281 dnl facilities in Chapter 8, "C compatibility".
1282 dnl
1283 AC_DEFUN([GLIBCXX_CHECK_C99_TR1], [
1284
1285   AC_LANG_SAVE
1286   AC_LANG_CPLUSPLUS
1287
1288   # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
1289   # undefined and fake C99 facilities may be spuriously enabled.
1290   ac_save_CXXFLAGS="$CXXFLAGS"
1291   CXXFLAGS="$CXXFLAGS -std=c++98"
1292
1293   # Check for the existence of <complex.h> complex math functions used
1294   # by tr1/complex.
1295   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
1296   ac_c99_complex_tr1=no;
1297   if test x"$ac_has_complex_h" = x"yes"; then
1298     AC_MSG_CHECKING([for ISO C99 support to TR1 in <complex.h>])
1299     AC_TRY_COMPILE([#include <complex.h>],
1300                    [typedef __complex__ float float_type; float_type tmpf;
1301                     cacosf(tmpf);
1302                     casinf(tmpf);
1303                     catanf(tmpf);
1304                     cacoshf(tmpf);
1305                     casinhf(tmpf);
1306                     catanhf(tmpf);
1307                     typedef __complex__ double double_type; double_type tmpd;
1308                     cacos(tmpd);
1309                     casin(tmpd);
1310                     catan(tmpd);
1311                     cacosh(tmpd);
1312                     casinh(tmpd);
1313                     catanh(tmpd);
1314                     typedef __complex__ long double ld_type; ld_type tmpld;
1315                     cacosl(tmpld);
1316                     casinl(tmpld);
1317                     catanl(tmpld);
1318                     cacoshl(tmpld);
1319                     casinhl(tmpld);
1320                     catanhl(tmpld);
1321                    ],[ac_c99_complex_tr1=yes], [ac_c99_complex_tr1=no])
1322   fi
1323   AC_MSG_RESULT($ac_c99_complex_tr1)
1324   if test x"$ac_c99_complex_tr1" = x"yes"; then
1325     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX_TR1, 1,
1326               [Define if C99 functions in <complex.h> should be used in
1327               <tr1/complex>. Using compiler builtins for these functions
1328               requires corresponding C99 library functions to be present.])
1329   fi
1330
1331   # Check for the existence of <ctype.h> functions.
1332   AC_MSG_CHECKING([for ISO C99 support to TR1 in <ctype.h>])
1333   AC_CACHE_VAL(glibcxx_cv_c99_ctype_tr1, [
1334   AC_TRY_COMPILE([#include <ctype.h>],
1335                  [int ch;
1336                   int ret;
1337                   ret = isblank(ch);
1338                  ],[glibcxx_cv_c99_ctype_tr1=yes],
1339                    [glibcxx_cv_c99_ctype_tr1=no])
1340   ])
1341   AC_MSG_RESULT($glibcxx_cv_c99_ctype_tr1)
1342   if test x"$glibcxx_cv_c99_ctype_tr1" = x"yes"; then
1343     AC_DEFINE(_GLIBCXX_USE_C99_CTYPE_TR1, 1,
1344               [Define if C99 functions in <ctype.h> should be imported in
1345               <tr1/cctype> in namespace std::tr1.])
1346   fi
1347
1348   # Check for the existence of <fenv.h> functions.
1349   AC_CHECK_HEADERS(fenv.h, ac_has_fenv_h=yes, ac_has_fenv_h=no)
1350   ac_c99_fenv_tr1=no;
1351   if test x"$ac_has_fenv_h" = x"yes"; then
1352     AC_MSG_CHECKING([for ISO C99 support to TR1 in <fenv.h>])
1353     AC_TRY_COMPILE([#include <fenv.h>],
1354                    [int except, mode;
1355                     fexcept_t* pflag;
1356                     fenv_t* penv;
1357                     int ret;
1358                     ret = feclearexcept(except);
1359                     ret = fegetexceptflag(pflag, except);
1360                     ret = feraiseexcept(except);
1361                     ret = fesetexceptflag(pflag, except);
1362                     ret = fetestexcept(except);
1363                     ret = fegetround();
1364                     ret = fesetround(mode);
1365                     ret = fegetenv(penv);
1366                     ret = feholdexcept(penv);
1367                     ret = fesetenv(penv);
1368                     ret = feupdateenv(penv);
1369                    ],[ac_c99_fenv_tr1=yes], [ac_c99_fenv_tr1=no])
1370   fi
1371   AC_MSG_RESULT($ac_c99_fenv_tr1)
1372   if test x"$ac_c99_fenv_tr1" = x"yes"; then
1373     AC_DEFINE(_GLIBCXX_USE_C99_FENV_TR1, 1,
1374               [Define if C99 functions in <fenv.h> should be imported in
1375               <tr1/cfenv> in namespace std::tr1.])
1376   fi
1377
1378   # Check for the existence of <stdint.h> types.
1379   AC_MSG_CHECKING([for ISO C99 support to TR1 in <stdint.h>])
1380   AC_CACHE_VAL(glibcxx_cv_c99_stdint_tr1, [
1381   AC_TRY_COMPILE([#define __STDC_LIMIT_MACROS
1382                   #define __STDC_CONSTANT_MACROS
1383                   #include <stdint.h>],
1384                  [typedef int8_t          my_int8_t;
1385                   my_int8_t               i8 = INT8_MIN;
1386                   i8 = INT8_MAX;
1387                   typedef int16_t         my_int16_t;
1388                   my_int16_t              i16 = INT16_MIN;
1389                   i16 = INT16_MAX;
1390                   typedef int32_t         my_int32_t;
1391                   my_int32_t              i32 = INT32_MIN;
1392                   i32 = INT32_MAX;
1393                   typedef int64_t         my_int64_t;
1394                   my_int64_t              i64 = INT64_MIN;
1395                   i64 = INT64_MAX;
1396                   typedef int_fast8_t     my_int_fast8_t;
1397                   my_int_fast8_t          if8 = INT_FAST8_MIN;
1398                   if8 = INT_FAST8_MAX;
1399                   typedef int_fast16_t    my_int_fast16_t;
1400                   my_int_fast16_t         if16 = INT_FAST16_MIN;
1401                   if16 = INT_FAST16_MAX;
1402                   typedef int_fast32_t    my_int_fast32_t;
1403                   my_int_fast32_t         if32 = INT_FAST32_MIN;
1404                   if32 = INT_FAST32_MAX;
1405                   typedef int_fast64_t    my_int_fast64_t;
1406                   my_int_fast64_t         if64 = INT_FAST64_MIN;
1407                   if64 = INT_FAST64_MAX;
1408                   typedef int_least8_t    my_int_least8_t;
1409                   my_int_least8_t         il8 = INT_LEAST8_MIN;
1410                   il8 = INT_LEAST8_MAX;
1411                   typedef int_least16_t   my_int_least16_t;
1412                   my_int_least16_t        il16 = INT_LEAST16_MIN;
1413                   il16 = INT_LEAST16_MAX;
1414                   typedef int_least32_t   my_int_least32_t;
1415                   my_int_least32_t        il32 = INT_LEAST32_MIN;
1416                   il32 = INT_LEAST32_MAX;
1417                   typedef int_least64_t   my_int_least64_t;
1418                   my_int_least64_t        il64 = INT_LEAST64_MIN;
1419                   il64 = INT_LEAST64_MAX;
1420                   typedef intmax_t        my_intmax_t;
1421                   my_intmax_t             im = INTMAX_MAX;
1422                   im = INTMAX_MIN;
1423                   typedef intptr_t        my_intptr_t;
1424                   my_intptr_t             ip = INTPTR_MAX;
1425                   ip = INTPTR_MIN;
1426                   typedef uint8_t         my_uint8_t;
1427                   my_uint8_t              ui8 = UINT8_MAX;
1428                   ui8 = UINT8_MAX;
1429                   typedef uint16_t        my_uint16_t;
1430                   my_uint16_t             ui16 = UINT16_MAX;
1431                   ui16 = UINT16_MAX;
1432                   typedef uint32_t        my_uint32_t;
1433                   my_uint32_t             ui32 = UINT32_MAX;
1434                   ui32 = UINT32_MAX;
1435                   typedef uint64_t        my_uint64_t;
1436                   my_uint64_t             ui64 = UINT64_MAX;
1437                   ui64 = UINT64_MAX;
1438                   typedef uint_fast8_t    my_uint_fast8_t;
1439                   my_uint_fast8_t         uif8 = UINT_FAST8_MAX;
1440                   uif8 = UINT_FAST8_MAX;
1441                   typedef uint_fast16_t   my_uint_fast16_t;
1442                   my_uint_fast16_t        uif16 = UINT_FAST16_MAX;
1443                   uif16 = UINT_FAST16_MAX;
1444                   typedef uint_fast32_t   my_uint_fast32_t;
1445                   my_uint_fast32_t        uif32 = UINT_FAST32_MAX;
1446                   uif32 = UINT_FAST32_MAX;
1447                   typedef uint_fast64_t   my_uint_fast64_t;
1448                   my_uint_fast64_t        uif64 = UINT_FAST64_MAX;
1449                   uif64 = UINT_FAST64_MAX;
1450                   typedef uint_least8_t   my_uint_least8_t;
1451                   my_uint_least8_t        uil8 = UINT_LEAST8_MAX;
1452                   uil8 = UINT_LEAST8_MAX;
1453                   typedef uint_least16_t  my_uint_least16_t;
1454                   my_uint_least16_t       uil16 = UINT_LEAST16_MAX;
1455                   uil16 = UINT_LEAST16_MAX;
1456                   typedef uint_least32_t  my_uint_least32_t;
1457                   my_uint_least32_t       uil32 = UINT_LEAST32_MAX;
1458                   uil32 = UINT_LEAST32_MAX;
1459                   typedef uint_least64_t  my_uint_least64_t;
1460                   my_uint_least64_t       uil64 = UINT_LEAST64_MAX;
1461                   uil64 = UINT_LEAST64_MAX;
1462                   typedef uintmax_t       my_uintmax_t;
1463                   my_uintmax_t            uim = UINTMAX_MAX;
1464                   uim = UINTMAX_MAX;
1465                   typedef uintptr_t       my_uintptr_t;
1466                   my_uintptr_t            uip = UINTPTR_MAX;
1467                   uip = UINTPTR_MAX;
1468                  ],[glibcxx_cv_c99_stdint_tr1=yes],
1469                    [glibcxx_cv_c99_stdint_tr1=no])
1470   ])
1471   AC_MSG_RESULT($glibcxx_cv_c99_stdint_tr1)
1472   if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1473     AC_DEFINE(_GLIBCXX_USE_C99_STDINT_TR1, 1,
1474               [Define if C99 types in <stdint.h> should be imported in
1475               <tr1/cstdint> in namespace std::tr1.])
1476   fi
1477
1478   # Check for the existence of <math.h> functions.
1479   AC_MSG_CHECKING([for ISO C99 support to TR1 in <math.h>])
1480   AC_CACHE_VAL(glibcxx_cv_c99_math_tr1, [
1481   AC_TRY_COMPILE([#include <math.h>],
1482                  [typedef double_t  my_double_t;
1483                   typedef float_t   my_float_t;
1484                   acosh(0.0);
1485                   acoshf(0.0f);
1486                   acoshl(0.0l);
1487                   asinh(0.0);
1488                   asinhf(0.0f);
1489                   asinhl(0.0l);
1490                   atanh(0.0);
1491                   atanhf(0.0f);
1492                   atanhl(0.0l);
1493                   cbrt(0.0);
1494                   cbrtf(0.0f);
1495                   cbrtl(0.0l);
1496                   copysign(0.0, 0.0);
1497                   copysignf(0.0f, 0.0f);
1498                   copysignl(0.0l, 0.0l);
1499                   erf(0.0);
1500                   erff(0.0f);
1501                   erfl(0.0l);
1502                   erfc(0.0);
1503                   erfcf(0.0f);
1504                   erfcl(0.0l);
1505                   exp2(0.0);
1506                   exp2f(0.0f);
1507                   exp2l(0.0l);
1508                   expm1(0.0);
1509                   expm1f(0.0f);
1510                   expm1l(0.0l);
1511                   fdim(0.0, 0.0);
1512                   fdimf(0.0f, 0.0f);
1513                   fdiml(0.0l, 0.0l);
1514                   fma(0.0, 0.0, 0.0);
1515                   fmaf(0.0f, 0.0f, 0.0f);
1516                   fmal(0.0l, 0.0l, 0.0l);
1517                   fmax(0.0, 0.0);
1518                   fmaxf(0.0f, 0.0f);
1519                   fmaxl(0.0l, 0.0l);
1520                   fmin(0.0, 0.0);
1521                   fminf(0.0f, 0.0f);
1522                   fminl(0.0l, 0.0l);
1523                   hypot(0.0, 0.0);
1524                   hypotf(0.0f, 0.0f);
1525                   hypotl(0.0l, 0.0l);
1526                   ilogb(0.0);
1527                   ilogbf(0.0f);
1528                   ilogbl(0.0l);
1529                   lgamma(0.0);
1530                   lgammaf(0.0f);
1531                   lgammal(0.0l);
1532                   llrint(0.0);
1533                   llrintf(0.0f);
1534                   llrintl(0.0l);
1535                   llround(0.0);
1536                   llroundf(0.0f);
1537                   llroundl(0.0l);
1538                   log1p(0.0);
1539                   log1pf(0.0f);
1540                   log1pl(0.0l);
1541                   log2(0.0);
1542                   log2f(0.0f);
1543                   log2l(0.0l);
1544                   logb(0.0);
1545                   logbf(0.0f);
1546                   logbl(0.0l);
1547                   lrint(0.0);
1548                   lrintf(0.0f);
1549                   lrintl(0.0l);
1550                   lround(0.0);
1551                   lroundf(0.0f);
1552                   lroundl(0.0l);
1553                   nan(0);
1554                   nanf(0);
1555                   nanl(0);
1556                   nearbyint(0.0);
1557                   nearbyintf(0.0f);
1558                   nearbyintl(0.0l);
1559                   nextafter(0.0, 0.0);
1560                   nextafterf(0.0f, 0.0f);
1561                   nextafterl(0.0l, 0.0l);
1562                   nexttoward(0.0, 0.0);
1563                   nexttowardf(0.0f, 0.0f);
1564                   nexttowardl(0.0l, 0.0l);
1565                   remainder(0.0, 0.0);
1566                   remainderf(0.0f, 0.0f);
1567                   remainderl(0.0l, 0.0l);
1568                   remquo(0.0, 0.0, 0);
1569                   remquof(0.0f, 0.0f, 0);
1570                   remquol(0.0l, 0.0l, 0);
1571                   rint(0.0);
1572                   rintf(0.0f);
1573                   rintl(0.0l);
1574                   round(0.0);
1575                   roundf(0.0f);
1576                   roundl(0.0l);
1577                   scalbln(0.0, 0l);
1578                   scalblnf(0.0f, 0l);
1579                   scalblnl(0.0l, 0l);
1580                   scalbn(0.0, 0);
1581                   scalbnf(0.0f, 0);
1582                   scalbnl(0.0l, 0);
1583                   tgamma(0.0);
1584                   tgammaf(0.0f);
1585                   tgammal(0.0l);
1586                   trunc(0.0);
1587                   truncf(0.0f);
1588                   truncl(0.0l);
1589                  ],[glibcxx_cv_c99_math_tr1=yes], [glibcxx_cv_c99_math_tr1=no])
1590   ])
1591   AC_MSG_RESULT($glibcxx_cv_c99_math_tr1)
1592   if test x"$glibcxx_cv_c99_math_tr1" = x"yes"; then
1593     AC_DEFINE(_GLIBCXX_USE_C99_MATH_TR1, 1,
1594               [Define if C99 functions or macros in <math.h> should be imported
1595               in <tr1/cmath> in namespace std::tr1.])
1596   fi
1597
1598   # Check for the existence of <inttypes.h> functions (NB: doesn't make
1599   # sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
1600   ac_c99_inttypes_tr1=no;
1601   if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1602     AC_MSG_CHECKING([for ISO C99 support to TR1 in <inttypes.h>])
1603     AC_TRY_COMPILE([#include <inttypes.h>],
1604                    [intmax_t i, numer, denom, base;
1605                     const char* s;
1606                     char** endptr;
1607                     intmax_t ret = imaxabs(i);
1608                     imaxdiv_t dret = imaxdiv(numer, denom);
1609                     ret = strtoimax(s, endptr, base);
1610                     uintmax_t uret = strtoumax(s, endptr, base);
1611                    ],[ac_c99_inttypes_tr1=yes], [ac_c99_inttypes_tr1=no])
1612   fi
1613   AC_MSG_RESULT($ac_c99_inttypes_tr1)
1614   if test x"$ac_c99_inttypes_tr1" = x"yes"; then
1615     AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_TR1, 1,
1616               [Define if C99 functions in <inttypes.h> should be imported in
1617               <tr1/cinttypes> in namespace std::tr1.])
1618   fi
1619
1620   # Check for the existence of whcar_t <inttypes.h> functions (NB: doesn't
1621   # make sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
1622   ac_c99_inttypes_wchar_t_tr1=no;
1623   if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1624     AC_MSG_CHECKING([for wchar_t ISO C99 support to TR1 in <inttypes.h>])
1625     AC_TRY_COMPILE([#include <inttypes.h>],
1626                    [intmax_t base;
1627                     const wchar_t* s;
1628                     wchar_t** endptr;
1629                     intmax_t ret = wcstoimax(s, endptr, base);
1630                     uintmax_t uret = wcstoumax(s, endptr, base);
1631                    ],[ac_c99_inttypes_wchar_t_tr1=yes],
1632                      [ac_c99_inttypes_wchar_t_tr1=no])
1633   fi
1634   AC_MSG_RESULT($ac_c99_inttypes_wchar_t_tr1)
1635   if test x"$ac_c99_inttypes_wchar_t_tr1" = x"yes"; then
1636     AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_WCHAR_T_TR1, 1,
1637               [Define if wchar_t C99 functions in <inttypes.h> should be
1638               imported in <tr1/cinttypes> in namespace std::tr1.])
1639   fi
1640
1641   # Check for the existence of the <stdbool.h> header.
1642   AC_CHECK_HEADERS(stdbool.h)
1643
1644   CXXFLAGS="$ac_save_CXXFLAGS"
1645   AC_LANG_RESTORE
1646 ])
1647
1648 dnl
1649 dnl Check whether "/dev/random" and "/dev/urandom" are available for the
1650 dnl random_device of "TR1" (Chapter 5.1, "Random number generation").
1651 dnl
1652 AC_DEFUN([GLIBCXX_CHECK_RANDOM_TR1], [
1653
1654   AC_MSG_CHECKING([for "/dev/random" and "/dev/urandom" for TR1 random_device])
1655   AC_CACHE_VAL(glibcxx_cv_random_tr1, [
1656     if test -r /dev/random && test -r /dev/urandom; then
1657       glibcxx_cv_random_tr1=yes;
1658     else
1659       glibcxx_cv_random_tr1=no;
1660     fi
1661   ])
1662   AC_MSG_RESULT($glibcxx_cv_random_tr1)
1663
1664   if test x"$glibcxx_cv_random_tr1" = x"yes"; then
1665     AC_DEFINE(_GLIBCXX_USE_RANDOM_TR1, 1,
1666               [Define if /dev/random and /dev/urandom are available for
1667                the random_device of TR1 (Chapter 5.1).])
1668   fi
1669
1670 ])
1671
1672 dnl
1673 dnl Compute the EOF, SEEK_CUR, and SEEK_END integer constants.
1674 dnl
1675 AC_DEFUN([GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS], [
1676
1677   AC_CACHE_CHECK([for the value of EOF], glibcxx_cv_stdio_eof, [
1678   AC_COMPUTE_INT([glibcxx_cv_stdio_eof], [[EOF]],
1679                  [#include <stdio.h>],
1680                  [AC_MSG_ERROR([computing EOF failed])])
1681   ])
1682   AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_EOF, $glibcxx_cv_stdio_eof,
1683                      [Define to the value of the EOF integer constant.])
1684
1685   AC_CACHE_CHECK([for the value of SEEK_CUR], glibcxx_cv_stdio_seek_cur, [
1686   AC_COMPUTE_INT([glibcxx_cv_stdio_seek_cur], [[SEEK_CUR]],
1687                  [#include <stdio.h>],
1688                  [AC_MSG_ERROR([computing SEEK_CUR failed])])
1689   ])
1690   AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_CUR, $glibcxx_cv_stdio_seek_cur,
1691                      [Define to the value of the SEEK_CUR integer constant.])
1692
1693   AC_CACHE_CHECK([for the value of SEEK_END], glibcxx_cv_stdio_seek_end, [
1694   AC_COMPUTE_INT([glibcxx_cv_stdio_seek_end], [[SEEK_END]],
1695                  [#include <stdio.h>],
1696                  [AC_MSG_ERROR([computing SEEK_END failed])])
1697   ])
1698   AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_END, $glibcxx_cv_stdio_seek_end,
1699                      [Define to the value of the SEEK_END integer constant.])
1700 ])
1701
1702 dnl
1703 dnl Check whether required C++ overloads are present in <math.h>.
1704 dnl
1705
1706 AC_DEFUN([GLIBCXX_CHECK_MATH_PROTO], [
1707
1708   AC_LANG_SAVE
1709   AC_LANG_CPLUSPLUS
1710
1711   case "$host" in
1712     *-*-solaris2.*)
1713       # Solaris 8 FCS only had an overload for double std::abs(double) in
1714       # <iso/math_iso.h>.  Patches 111721-04 (SPARC) and 112757-01 (x86)
1715       # introduced the full set also found from Solaris 9 onwards.
1716       AC_MSG_CHECKING([for float std::abs(float) overload])
1717       AC_CACHE_VAL(glibcxx_cv_abs_float, [
1718         AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1719           [#include <math.h>
1720            namespace std {
1721              inline float abs(float __x)
1722              {  return __builtin_fabsf(__x); }
1723            }
1724         ])],
1725         [glibcxx_cv_abs_float=no],
1726         [glibcxx_cv_abs_float=yes]
1727       )])
1728
1729       # autoheader cannot handle indented templates.
1730       AH_VERBATIM([__CORRECT_ISO_CPP_MATH_H_PROTO1],
1731         [/* Define if all C++ overloads are available in <math.h>.  */
1732 #if __cplusplus >= 199711L
1733 #undef __CORRECT_ISO_CPP_MATH_H_PROTO1
1734 #endif])
1735       AH_VERBATIM([__CORRECT_ISO_CPP_MATH_H_PROTO2],
1736         [/* Define if only double std::abs(double) is available in <math.h>.  */
1737 #if __cplusplus >= 199711L
1738 #undef __CORRECT_ISO_CPP_MATH_H_PROTO2
1739 #endif])
1740
1741       if test $glibcxx_cv_abs_float = yes; then
1742         AC_DEFINE(__CORRECT_ISO_CPP_MATH_H_PROTO1)
1743       else
1744         AC_DEFINE(__CORRECT_ISO_CPP_MATH_H_PROTO2)
1745       fi
1746       AC_MSG_RESULT($glibcxx_cv_abs_float)
1747       ;;
1748   esac
1749
1750   AC_LANG_RESTORE
1751 ])
1752
1753 dnl
1754 dnl Check whether required C++ overloads are present in <stdlib.h>.
1755 dnl
1756
1757 AC_DEFUN([GLIBCXX_CHECK_STDLIB_PROTO], [
1758
1759   AC_LANG_SAVE
1760   AC_LANG_CPLUSPLUS
1761
1762   case "$host" in
1763     *-*-solaris2.*)
1764       # Solaris 8 FCS lacked the overloads for long std::abs(long) and
1765       # ldiv_t std::div(long, long) in <iso/stdlib_iso.h>.  Patches 109607-02
1766       # (SPARC) and 109608-02 (x86) introduced them.
1767       AC_MSG_CHECKING([for long std::abs(long) overload])
1768       AC_CACHE_VAL(glibcxx_cv_abs_long, [
1769         AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1770           [#include <stdlib.h>
1771            namespace std {
1772              inline long
1773              abs(long __i) { return labs(__i); }
1774            }
1775         ])],
1776         [glibcxx_cv_abs_long=no],
1777         [glibcxx_cv_abs_long=yes]
1778       )])
1779
1780       # autoheader cannot handle indented templates.
1781       AH_VERBATIM([__CORRECT_ISO_CPP_STDLIB_H_PROTO],
1782         [/* Define if all C++ overloads are available in <stdlib.h>.  */
1783 #if __cplusplus >= 199711L
1784 #undef __CORRECT_ISO_CPP_STDLIB_H_PROTO
1785 #endif])
1786       if test $glibcxx_cv_abs_long = yes; then
1787         AC_DEFINE(__CORRECT_ISO_CPP_STDLIB_H_PROTO, 1)
1788       fi
1789       AC_MSG_RESULT($glibcxx_cv_abs_long)
1790       ;;
1791   esac
1792
1793   AC_LANG_RESTORE
1794 ])
1795
1796 dnl
1797 dnl Check whether macros, etc are present for <system_error>
1798 dnl
1799 AC_DEFUN([GLIBCXX_CHECK_SYSTEM_ERROR], [
1800
1801 m4_pushdef([n_syserr], [1])dnl
1802 m4_foreach([syserr], [EOWNERDEAD, ENOTRECOVERABLE, ENOLINK, EPROTO, ENODATA,
1803                       ENOSR, ENOSTR, ETIME, EBADMSG, ECANCELED,
1804                       EOVERFLOW, ENOTSUP, EIDRM, ETXTBSY,
1805                       ECHILD, ENOSPC, EPERM,
1806                       ETIMEDOUT, EWOULDBLOCK],
1807 [m4_pushdef([SYSERR], m4_toupper(syserr))dnl
1808 AC_MSG_CHECKING([for syserr])
1809 AC_CACHE_VAL([glibcxx_cv_system_error[]n_syserr], [
1810 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
1811                                    [int i = syserr;])],
1812                   [glibcxx_cv_system_error[]n_syserr=yes],
1813                   [glibcxx_cv_system_error[]n_syserr=no])
1814 ])
1815 AC_MSG_RESULT([$glibcxx_cv_system_error[]n_syserr])
1816 if test x"$glibcxx_cv_system_error[]n_syserr" = x"yes"; then
1817   AC_DEFINE([HAVE_]SYSERR, 1, [Define if ]syserr[ exists.])
1818 fi
1819 m4_define([n_syserr], m4_incr(n_syserr))dnl
1820 m4_popdef([SYSERR])dnl
1821 ])
1822 m4_popdef([n_syserr])dnl
1823 ])
1824
1825 dnl
1826 dnl Check for what type of C headers to use.
1827 dnl
1828 dnl --enable-cheaders= [does stuff].
1829 dnl --disable-cheaders [does not do anything, really].
1830 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
1831 dnl       Where DEFAULT is either 'c' or 'c_std' or 'c_global'.
1832 dnl
1833 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
1834   GLIBCXX_ENABLE(cheaders,$1,[[[=KIND]]],
1835     [construct "C" headers for g++], [permit c|c_std|c_global])
1836   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
1837
1838   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
1839
1840   # Allow overrides to configure.host here.
1841   if test $enable_cheaders = c_global; then
1842      c_compatibility=yes
1843   fi
1844
1845   AC_SUBST(C_INCLUDE_DIR)
1846   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
1847   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
1848   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_GLOBAL, test $enable_cheaders = c_global)
1849   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
1850 ])
1851
1852
1853 dnl
1854 dnl Check for which locale library to use.  The choice is mapped to
1855 dnl a subdirectory of config/locale.
1856 dnl
1857 dnl Default is generic.
1858 dnl
1859 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
1860   GLIBCXX_ENABLE(clocale,auto,[[[=MODEL]]],
1861     [use MODEL for target locale package],
1862     [permit generic|gnu|ieee_1003.1-2001|newlib|yes|no|auto])
1863
1864   # Deal with gettext issues.  Default to not using it (=no) until we detect
1865   # support for it later.  Let the user turn it off via --e/d, but let that
1866   # default to on for easier handling.
1867   USE_NLS=no
1868   AC_ARG_ENABLE(nls,
1869     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1870     [],
1871     [enable_nls=yes])
1872
1873   # Either a known package, or "auto"
1874   if test $enable_clocale = no || test $enable_clocale = yes; then
1875      enable_clocale=auto
1876   fi
1877   enable_clocale_flag=$enable_clocale
1878
1879   # Probe for locale model to use if none specified.
1880   # Default to "generic".
1881   if test $enable_clocale_flag = auto; then
1882     case ${target_os} in
1883       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1884         enable_clocale_flag=gnu
1885         ;;
1886       darwin* | freebsd*)
1887         enable_clocale_flag=darwin
1888         ;;
1889       *)
1890         if test x"$with_newlib" = x"yes"; then
1891           enable_clocale_flag=newlib
1892         else
1893           enable_clocale_flag=generic
1894         fi
1895         ;;
1896     esac
1897   fi
1898
1899   # Sanity check model, and test for special functionality.
1900   if test $enable_clocale_flag = gnu; then
1901     AC_EGREP_CPP([_GLIBCXX_ok], [
1902     #include <features.h>
1903     #if (__GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 3)) && !defined(__UCLIBC__)
1904       _GLIBCXX_ok
1905     #endif
1906     ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1907
1908     # Set it to scream when it hurts.
1909     ac_save_CFLAGS="$CFLAGS"
1910     CFLAGS="-Wimplicit-function-declaration -Werror"
1911
1912     # Use strxfrm_l if available.
1913     AC_TRY_COMPILE([#define _GNU_SOURCE 1
1914                     #include <string.h>
1915                     #include <locale.h>],
1916                     [char s[128]; __locale_t loc; strxfrm_l(s, "C", 5, loc);],
1917                     AC_DEFINE(HAVE_STRXFRM_L, 1,
1918                     [Define if strxfrm_l is available in <string.h>.]),)
1919
1920     # Use strerror_l if available.
1921     AC_TRY_COMPILE([#define _GNU_SOURCE 1
1922                     #include <string.h>
1923                     #include <locale.h>],
1924                     [__locale_t loc; strerror_l(5, loc);],
1925                     AC_DEFINE(HAVE_STRERROR_L, 1,
1926                     [Define if strerror_l is available in <string.h>.]),)
1927
1928     CFLAGS="$ac_save_CFLAGS"
1929   fi
1930
1931   # Perhaps use strerror_r if available, and strerror_l isn't.
1932   ac_save_CFLAGS="$CFLAGS"
1933   CFLAGS="-Wimplicit-function-declaration -Werror"
1934   AC_TRY_COMPILE([#define _GNU_SOURCE 1
1935                   #include <string.h>
1936                   #include <locale.h>],
1937                   [char s[128]; strerror_r(5, s, 128);],
1938                   AC_DEFINE(HAVE_STRERROR_R, 1,
1939                   [Define if strerror_r is available in <string.h>.]),)
1940   CFLAGS="$ac_save_CFLAGS"
1941
1942   # Set configure bits for specified locale package
1943   AC_MSG_CHECKING([for C locale to use])
1944   case ${enable_clocale_flag} in
1945     generic)
1946       AC_MSG_RESULT(generic)
1947
1948       CLOCALE_H=config/locale/generic/c_locale.h
1949       CLOCALE_CC=config/locale/generic/c_locale.cc
1950       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1951       CCOLLATE_CC=config/locale/generic/collate_members.cc
1952       CCTYPE_CC=config/locale/generic/ctype_members.cc
1953       CMESSAGES_H=config/locale/generic/messages_members.h
1954       CMESSAGES_CC=config/locale/generic/messages_members.cc
1955       CMONEY_CC=config/locale/generic/monetary_members.cc
1956       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1957       CTIME_H=config/locale/generic/time_members.h
1958       CTIME_CC=config/locale/generic/time_members.cc
1959       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1960       ;;
1961     darwin)
1962       AC_MSG_RESULT(darwin or freebsd)
1963
1964       CLOCALE_H=config/locale/generic/c_locale.h
1965       CLOCALE_CC=config/locale/generic/c_locale.cc
1966       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1967       CCOLLATE_CC=config/locale/generic/collate_members.cc
1968       CCTYPE_CC=config/locale/darwin/ctype_members.cc
1969       CMESSAGES_H=config/locale/generic/messages_members.h
1970       CMESSAGES_CC=config/locale/generic/messages_members.cc
1971       CMONEY_CC=config/locale/generic/monetary_members.cc
1972       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1973       CTIME_H=config/locale/generic/time_members.h
1974       CTIME_CC=config/locale/generic/time_members.cc
1975       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1976       ;;
1977
1978     gnu)
1979       AC_MSG_RESULT(gnu)
1980
1981       # Declare intention to use gettext, and add support for specific
1982       # languages.
1983       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1984       ALL_LINGUAS="de fr"
1985
1986       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1987       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1988       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1989         USE_NLS=yes
1990       fi
1991       # Export the build objects.
1992       for ling in $ALL_LINGUAS; do \
1993         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1994         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1995       done
1996       AC_SUBST(glibcxx_MOFILES)
1997       AC_SUBST(glibcxx_POFILES)
1998
1999       CLOCALE_H=config/locale/gnu/c_locale.h
2000       CLOCALE_CC=config/locale/gnu/c_locale.cc
2001       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
2002       CCOLLATE_CC=config/locale/gnu/collate_members.cc
2003       CCTYPE_CC=config/locale/gnu/ctype_members.cc
2004       CMESSAGES_H=config/locale/gnu/messages_members.h
2005       CMESSAGES_CC=config/locale/gnu/messages_members.cc
2006       CMONEY_CC=config/locale/gnu/monetary_members.cc
2007       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
2008       CTIME_H=config/locale/gnu/time_members.h
2009       CTIME_CC=config/locale/gnu/time_members.cc
2010       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
2011       ;;
2012     ieee_1003.1-2001)
2013       AC_MSG_RESULT(IEEE 1003.1)
2014
2015       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
2016       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
2017       CCODECVT_CC=config/locale/generic/codecvt_members.cc
2018       CCOLLATE_CC=config/locale/generic/collate_members.cc
2019       CCTYPE_CC=config/locale/generic/ctype_members.cc
2020       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
2021       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
2022       CMONEY_CC=config/locale/generic/monetary_members.cc
2023       CNUMERIC_CC=config/locale/generic/numeric_members.cc
2024       CTIME_H=config/locale/generic/time_members.h
2025       CTIME_CC=config/locale/generic/time_members.cc
2026       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2027       ;;
2028     newlib)
2029       AC_MSG_RESULT(newlib)
2030
2031       CLOCALE_H=config/locale/generic/c_locale.h
2032       CLOCALE_CC=config/locale/generic/c_locale.cc
2033       CCODECVT_CC=config/locale/generic/codecvt_members.cc
2034       CCOLLATE_CC=config/locale/generic/collate_members.cc
2035       CCTYPE_CC=config/locale/newlib/ctype_members.cc
2036       CMESSAGES_H=config/locale/generic/messages_members.h
2037       CMESSAGES_CC=config/locale/generic/messages_members.cc
2038       CMONEY_CC=config/locale/generic/monetary_members.cc
2039       CNUMERIC_CC=config/locale/generic/numeric_members.cc
2040       CTIME_H=config/locale/generic/time_members.h
2041       CTIME_CC=config/locale/generic/time_members.cc
2042       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2043       ;;
2044   esac
2045
2046   # This is where the testsuite looks for locale catalogs, using the
2047   # -DLOCALEDIR define during testsuite compilation.
2048   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
2049   AC_SUBST(glibcxx_localedir)
2050
2051   # A standalone libintl (e.g., GNU libintl) may be in use.
2052   if test $USE_NLS = yes; then
2053     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
2054     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
2055   fi
2056   if test $USE_NLS = yes; then
2057     AC_DEFINE(_GLIBCXX_USE_NLS, 1,
2058               [Define if NLS translations are to be used.])
2059   fi
2060
2061   AC_SUBST(USE_NLS)
2062   AC_SUBST(CLOCALE_H)
2063   AC_SUBST(CMESSAGES_H)
2064   AC_SUBST(CCODECVT_CC)
2065   AC_SUBST(CCOLLATE_CC)
2066   AC_SUBST(CCTYPE_CC)
2067   AC_SUBST(CMESSAGES_CC)
2068   AC_SUBST(CMONEY_CC)
2069   AC_SUBST(CNUMERIC_CC)
2070   AC_SUBST(CTIME_H)
2071   AC_SUBST(CTIME_CC)
2072   AC_SUBST(CLOCALE_CC)
2073   AC_SUBST(CLOCALE_INTERNAL_H)
2074 ])
2075
2076
2077 dnl
2078 dnl Check for which std::allocator base class to use.  The choice is
2079 dnl mapped from a subdirectory of include/ext.
2080 dnl
2081 dnl Default is new.
2082 dnl
2083 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
2084   AC_MSG_CHECKING([for std::allocator base class])
2085   GLIBCXX_ENABLE(libstdcxx-allocator,auto,[[[=KIND]]],
2086     [use KIND for target std::allocator base],
2087     [permit new|malloc|mt|bitmap|pool|yes|no|auto])
2088
2089   # If they didn't use this option switch, or if they specified --enable
2090   # with no specific model, we'll have to look for one.  If they
2091   # specified --disable (???), do likewise.
2092   if test $enable_libstdcxx_allocator = no ||
2093      test $enable_libstdcxx_allocator = yes;
2094   then
2095      enable_libstdcxx_allocator=auto
2096   fi
2097
2098   # Either a known package, or "auto". Auto implies the default choice
2099   # for a particular platform.
2100   enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
2101
2102   # Probe for host-specific support if no specific model is specified.
2103   # Default to "new".
2104   if test $enable_libstdcxx_allocator_flag = auto; then
2105     case ${target_os} in
2106       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
2107         enable_libstdcxx_allocator_flag=new
2108         ;;
2109       *)
2110         enable_libstdcxx_allocator_flag=new
2111         ;;
2112     esac
2113   fi
2114   AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
2115
2116
2117   # Set configure bits for specified locale package
2118   case ${enable_libstdcxx_allocator_flag} in
2119     bitmap)
2120       ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
2121       ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
2122       ;;
2123     malloc)
2124       ALLOCATOR_H=config/allocator/malloc_allocator_base.h
2125       ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
2126       ;;
2127     mt)
2128       ALLOCATOR_H=config/allocator/mt_allocator_base.h
2129       ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
2130       ;;
2131     new)
2132       ALLOCATOR_H=config/allocator/new_allocator_base.h
2133       ALLOCATOR_NAME=__gnu_cxx::new_allocator
2134       ;;
2135     pool)
2136       ALLOCATOR_H=config/allocator/pool_allocator_base.h
2137       ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
2138       ;;
2139   esac
2140
2141   AC_SUBST(ALLOCATOR_H)
2142   AC_SUBST(ALLOCATOR_NAME)
2143 ])
2144
2145
2146 dnl
2147 dnl Check for whether the Boost-derived checks should be turned on.
2148 dnl
2149 dnl --enable-concept-checks turns them on.
2150 dnl --disable-concept-checks leaves them off.
2151 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
2152 dnl       Where DEFAULT is either `yes' or `no'.
2153 dnl
2154 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
2155   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
2156   if test $enable_concept_checks = yes; then
2157     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1,
2158               [Define to use concept checking code from the boost libraries.])
2159   fi
2160 ])
2161
2162 dnl
2163 dnl Use extern templates.
2164 dnl
2165 dnl --enable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 1
2166 dnl --disable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 0
2167
2168 dnl  +  Usage:  GLIBCXX_ENABLE_TEMPLATE[(DEFAULT)]
2169 dnl       Where DEFAULT is `yes' or `no'.
2170 dnl
2171 AC_DEFUN([GLIBCXX_ENABLE_EXTERN_TEMPLATE], [
2172
2173   GLIBCXX_ENABLE(extern-template,$1,,[enable extern template])
2174
2175   AC_MSG_CHECKING([for extern template support])
2176   AC_MSG_RESULT([$enable_extern_template])
2177
2178   GLIBCXX_CONDITIONAL(ENABLE_EXTERN_TEMPLATE, test $enable_extern_template = yes)
2179 ])
2180
2181 dnl
2182 dnl Check for parallel mode pre-requisites, including OpenMP support.
2183 dnl
2184 dnl  +  Usage:  GLIBCXX_ENABLE_PARALLEL
2185 dnl
2186 AC_DEFUN([GLIBCXX_ENABLE_PARALLEL], [
2187
2188   enable_parallel=no;
2189
2190   # See if configured libgomp/omp.h exists. (libgomp may be in
2191   # noconfigdirs but not explicitly disabled.)
2192   if echo " ${TARGET_CONFIGDIRS} " | grep " libgomp " > /dev/null 2>&1 ; then
2193     enable_parallel=yes;
2194   else
2195     AC_MSG_NOTICE([target-libgomp not built])
2196   fi
2197
2198   AC_MSG_CHECKING([for parallel mode support])
2199   AC_MSG_RESULT([$enable_parallel])
2200   GLIBCXX_CONDITIONAL(ENABLE_PARALLEL, test $enable_parallel = yes)
2201 ])
2202
2203
2204 dnl
2205 dnl Check for which I/O library to use:  stdio, or something specific.
2206 dnl
2207 dnl Default is stdio.
2208 dnl
2209 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
2210   AC_MSG_CHECKING([for underlying I/O to use])
2211   GLIBCXX_ENABLE(cstdio,stdio,[[[=PACKAGE]]],
2212     [use target-specific I/O package], [permit stdio])
2213
2214   # Now that libio has been removed, you can have any color you want as long
2215   # as it's black.  This is one big no-op until other packages are added, but
2216   # showing the framework never hurts.
2217   case ${enable_cstdio} in
2218     stdio)
2219       CSTDIO_H=config/io/c_io_stdio.h
2220       BASIC_FILE_H=config/io/basic_file_stdio.h
2221       BASIC_FILE_CC=config/io/basic_file_stdio.cc
2222       AC_MSG_RESULT(stdio)
2223       ;;
2224   esac
2225
2226   AC_SUBST(CSTDIO_H)
2227   AC_SUBST(BASIC_FILE_H)
2228   AC_SUBST(BASIC_FILE_CC)
2229 ])
2230
2231
2232 dnl
2233 dnl Check for "unusual" flags to pass to the compiler while building.
2234 dnl
2235 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
2236 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
2237 dnl --disable-cxx-flags passes nothing.
2238 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
2239 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
2240 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
2241 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
2242 dnl       If "default flags" is an empty string, the effect is the same
2243 dnl       as --disable or --enable=no.
2244 dnl
2245 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
2246   AC_MSG_CHECKING([for extra compiler flags for building])
2247   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
2248     [pass compiler FLAGS when building library],
2249     [case "x$enable_cxx_flags" in
2250       xno | x)   enable_cxx_flags= ;;
2251       x-*)       ;;
2252       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2253      esac])
2254
2255   # Run through flags (either default or command-line) and set anything
2256   # extra (e.g., #defines) that must accompany particular g++ options.
2257   if test -n "$enable_cxx_flags"; then
2258     for f in $enable_cxx_flags; do
2259       case "$f" in
2260         -fhonor-std)  ;;
2261         -*)  ;;
2262         *)   # and we're trying to pass /what/ exactly?
2263              AC_MSG_ERROR([compiler flags start with a -]) ;;
2264       esac
2265     done
2266   fi
2267
2268   EXTRA_CXX_FLAGS="$enable_cxx_flags"
2269   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
2270   AC_SUBST(EXTRA_CXX_FLAGS)
2271 ])
2272
2273
2274 dnl
2275 dnl Check to see if debugging libraries are to be built.
2276 dnl
2277 dnl --enable-libstdcxx-debug
2278 dnl builds a separate set of debugging libraries in addition to the
2279 dnl normal (shared, static) libstdc++ binaries.
2280 dnl
2281 dnl --disable-libstdcxx-debug
2282 dnl builds only one (non-debug) version of libstdc++.
2283 dnl
2284 dnl --enable-libstdcxx-debug-flags=FLAGS
2285 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
2286 dnl
2287 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
2288 dnl       Where DEFAULT is either `yes' or `no'.
2289 dnl
2290 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
2291   AC_MSG_CHECKING([for additional debug build])
2292   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
2293   AC_MSG_RESULT($enable_libstdcxx_debug)
2294   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
2295 ])
2296
2297
2298 dnl
2299 dnl Check for explicit debug flags.
2300 dnl
2301 dnl --enable-libstdcxx-debug-flags='-O1'
2302 dnl is a general method for passing flags to be used when
2303 dnl building debug libraries with --enable-debug.
2304 dnl
2305 dnl --disable-libstdcxx-debug-flags does nothing.
2306 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
2307 dnl       If "default flags" is an empty string, the effect is the same
2308 dnl       as --disable or --enable=no.
2309 dnl
2310 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
2311   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
2312     [pass compiler FLAGS when building debug library],
2313     [case "x$enable_libstdcxx_debug_flags" in
2314       xno | x)    enable_libstdcxx_debug_flags= ;;
2315       x-*)        ;;
2316       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2317      esac])
2318
2319   # Option parsed, now set things appropriately
2320   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
2321   AC_SUBST(DEBUG_FLAGS)
2322
2323   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
2324 ])
2325
2326
2327 dnl
2328 dnl Check if the user only wants a freestanding library implementation.
2329 dnl
2330 dnl --disable-hosted-libstdcxx will turn off most of the library build,
2331 dnl installing only the headers required by [17.4.1.3] and the language
2332 dnl support library.  More than that will be built (to keep the Makefiles
2333 dnl conveniently clean), but not installed.
2334 dnl
2335 dnl Sets:
2336 dnl  is_hosted  (yes/no)
2337 dnl
2338 dnl Defines:
2339 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
2340 dnl
2341 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
2342   AC_ARG_ENABLE([hosted-libstdcxx],
2343     AC_HELP_STRING([--disable-hosted-libstdcxx],
2344                    [only build freestanding C++ runtime support]),,
2345     [case "$host" in
2346         arm*-*-symbianelf*)
2347             enable_hosted_libstdcxx=no
2348             ;;
2349         *)
2350             enable_hosted_libstdcxx=yes
2351             ;;
2352      esac])
2353   if test "$enable_hosted_libstdcxx" = no; then
2354     AC_MSG_NOTICE([Only freestanding libraries will be built])
2355     is_hosted=no
2356     hosted_define=0
2357     enable_abi_check=no
2358     enable_libstdcxx_pch=no
2359   else
2360     is_hosted=yes
2361     hosted_define=1
2362   fi
2363   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
2364   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
2365     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
2366 ])
2367
2368
2369 dnl
2370 dnl Check for template specializations for the 'long long' type.
2371 dnl The result determines only whether 'long long' I/O is enabled; things
2372 dnl like numeric_limits<> specializations are always available.
2373 dnl
2374 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
2375 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
2376 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
2377 dnl       Where DEFAULT is either `yes' or `no'.
2378 dnl
2379 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
2380   GLIBCXX_ENABLE(long-long,$1,,[enable template specializations for 'long long'])
2381   if test $enable_long_long = yes; then
2382     AC_DEFINE(_GLIBCXX_USE_LONG_LONG, 1,
2383               [Define if code specialized for long long should be used.])
2384   fi
2385   AC_MSG_CHECKING([for enabled long long specializations])
2386   AC_MSG_RESULT([$enable_long_long])
2387 ])
2388
2389
2390 dnl
2391 dnl Check for decimal floating point.
2392 dnl See:
2393 dnl http://gcc.gnu.org/onlinedocs/gcc/Decimal-Float.html#Decimal-Float
2394 dnl
2395 dnl This checks to see if the host supports decimal floating point types.
2396 dnl
2397 dnl Defines:
2398 dnl  _GLIBCXX_USE_DECIMAL_FLOAT
2399 dnl
2400 AC_DEFUN([GLIBCXX_ENABLE_DECIMAL_FLOAT], [
2401
2402   # Fake what AC_TRY_COMPILE does, without linking as this is
2403   # unnecessary for this test.
2404
2405     cat > conftest.$ac_ext << EOF
2406 [#]line __oline__ "configure"
2407 int main()
2408 {
2409   _Decimal32 d1;
2410   _Decimal64 d2;
2411   _Decimal128 d3;
2412   return 0;
2413 }
2414 EOF
2415
2416     AC_MSG_CHECKING([for ISO/IEC TR 24733 ])
2417     if AC_TRY_EVAL(ac_compile); then
2418       AC_DEFINE(_GLIBCXX_USE_DECIMAL_FLOAT, 1,
2419       [Define if ISO/IEC TR 24733 decimal floating point types are supported on this host.])
2420       enable_dfp=yes
2421     else
2422       enable_dfp=no
2423     fi
2424     AC_MSG_RESULT($enable_dfp)
2425     rm -f conftest*
2426 ])
2427
2428 dnl
2429 dnl Check for GNU 128-bit integer and floating point types.
2430 dnl
2431 dnl Note: also checks that the types aren't standard types.
2432 dnl
2433 dnl Defines:
2434 dnl  _GLIBCXX_USE_INT128
2435 dnl  _GLIBCXX_USE_FLOAT128
2436 dnl
2437 AC_DEFUN([GLIBCXX_ENABLE_INT128_FLOAT128], [
2438
2439   AC_LANG_SAVE
2440   AC_LANG_CPLUSPLUS
2441
2442   # Fake what AC_TRY_COMPILE does, without linking as this is
2443   # unnecessary for this test.
2444
2445     cat > conftest.$ac_ext << EOF
2446 [#]line __oline__ "configure"
2447 template<typename T1, typename T2>
2448   struct same
2449   { typedef T2 type; };
2450
2451 template<typename T>
2452   struct same<T, T>;
2453
2454 int main()
2455 {
2456   typename same<long, __int128>::type                i1;
2457   typename same<long long, __int128>::type           i2;
2458 }
2459 EOF
2460
2461     AC_MSG_CHECKING([for __int128])
2462     if AC_TRY_EVAL(ac_compile); then
2463       AC_DEFINE(_GLIBCXX_USE_INT128, 1,
2464       [Define if __int128 is supported on this host.])
2465       enable_int128=yes
2466     else
2467       enable_int128=no
2468     fi
2469     AC_MSG_RESULT($enable_int128)
2470     rm -f conftest*
2471
2472     cat > conftest.$ac_ext << EOF
2473 [#]line __oline__ "configure"
2474 template<typename T1, typename T2>
2475   struct same
2476   { typedef T2 type; };
2477
2478 template<typename T>
2479   struct same<T, T>;
2480
2481 int main()
2482 {
2483   typename same<double, __float128>::type      f1;
2484   typename same<long double, __float128>::type f2;
2485 }
2486 EOF
2487
2488     AC_MSG_CHECKING([for __float128])
2489     if AC_TRY_EVAL(ac_compile); then
2490       AC_DEFINE(_GLIBCXX_USE_FLOAT128, 1,
2491       [Define if __float128 is supported on this host.])
2492       enable_float128=yes
2493     else
2494       enable_float128=no
2495     fi
2496     AC_MSG_RESULT($enable_float128)
2497     rm -f conftest*
2498
2499   AC_LANG_RESTORE
2500 ])
2501
2502 dnl
2503 dnl Check for template specializations for the 'wchar_t' type.
2504 dnl
2505 dnl --enable-wchar_t defines _GLIBCXX_USE_WCHAR_T
2506 dnl --disable-wchar_t leaves _GLIBCXX_USE_WCHAR_T undefined
2507 dnl  +  Usage:  GLIBCXX_ENABLE_WCHAR_T[(DEFAULT)]
2508 dnl       Where DEFAULT is either `yes' or `no'.
2509 dnl
2510 dnl Necessary support must also be present.
2511 dnl
2512 AC_DEFUN([GLIBCXX_ENABLE_WCHAR_T], [
2513   GLIBCXX_ENABLE(wchar_t,$1,,[enable template specializations for 'wchar_t'])
2514
2515   # Test wchar.h for mbstate_t, which is needed for char_traits and fpos.
2516   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
2517   AC_MSG_CHECKING([for mbstate_t])
2518   AC_TRY_COMPILE([#include <wchar.h>],
2519   [mbstate_t teststate;],
2520   have_mbstate_t=yes, have_mbstate_t=no)
2521   AC_MSG_RESULT($have_mbstate_t)
2522   if test x"$have_mbstate_t" = xyes; then
2523     AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
2524   fi
2525
2526   # Test it always, for use in GLIBCXX_ENABLE_C99, together with
2527   # ac_has_wchar_h.
2528   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
2529
2530   if test x"$enable_wchar_t" = x"yes"; then
2531
2532     AC_LANG_SAVE
2533     AC_LANG_CPLUSPLUS
2534
2535     if test x"$ac_has_wchar_h" = xyes &&
2536        test x"$ac_has_wctype_h" = xyes; then
2537       AC_TRY_COMPILE([#include <wchar.h>
2538                       #include <stddef.h>
2539                       wint_t i;
2540                       long l = WEOF;
2541                       long j = WCHAR_MIN;
2542                       long k = WCHAR_MAX;
2543                       namespace test
2544                       {
2545                         using ::btowc;
2546                         using ::fgetwc;
2547                         using ::fgetws;
2548                         using ::fputwc;
2549                         using ::fputws;
2550                         using ::fwide;
2551                         using ::fwprintf;
2552                         using ::fwscanf;
2553                         using ::getwc;
2554                         using ::getwchar;
2555                         using ::mbrlen;
2556                         using ::mbrtowc;
2557                         using ::mbsinit;
2558                         using ::mbsrtowcs;
2559                         using ::putwc;
2560                         using ::putwchar;
2561                         using ::swprintf;
2562                         using ::swscanf;
2563                         using ::ungetwc;
2564                         using ::vfwprintf;
2565                         using ::vswprintf;
2566                         using ::vwprintf;
2567                         using ::wcrtomb;
2568                         using ::wcscat;
2569                         using ::wcschr;
2570                         using ::wcscmp;
2571                         using ::wcscoll;
2572                         using ::wcscpy;
2573                         using ::wcscspn;
2574                         using ::wcsftime;
2575                         using ::wcslen;
2576                         using ::wcsncat;
2577                         using ::wcsncmp;
2578                         using ::wcsncpy;
2579                         using ::wcspbrk;
2580                         using ::wcsrchr;
2581                         using ::wcsrtombs;
2582                         using ::wcsspn;
2583                         using ::wcsstr;
2584                         using ::wcstod;
2585                         using ::wcstok;
2586                         using ::wcstol;
2587                         using ::wcstoul;
2588                         using ::wcsxfrm;
2589                         using ::wctob;
2590                         using ::wmemchr;
2591                         using ::wmemcmp;
2592                         using ::wmemcpy;
2593                         using ::wmemmove;
2594                         using ::wmemset;
2595                         using ::wprintf;
2596                         using ::wscanf;
2597                       }
2598                      ],[],[], [enable_wchar_t=no])
2599     else
2600       enable_wchar_t=no
2601     fi
2602
2603     AC_LANG_RESTORE
2604   fi
2605
2606   if test x"$enable_wchar_t" = x"yes"; then
2607     AC_DEFINE(_GLIBCXX_USE_WCHAR_T, 1,
2608               [Define if code specialized for wchar_t should be used.])
2609   fi
2610
2611   AC_MSG_CHECKING([for enabled wchar_t specializations])
2612   AC_MSG_RESULT([$enable_wchar_t])
2613 ])
2614
2615
2616 dnl
2617 dnl Check to see if building and using a C++ precompiled header can be done.
2618 dnl
2619 dnl --enable-libstdcxx-pch=yes
2620 dnl default, this shows intent to use stdc++.h.gch If it looks like it
2621 dnl may work, after some light-hearted attempts to puzzle out compiler
2622 dnl support, flip bits on in include/Makefile.am
2623 dnl
2624 dnl --disable-libstdcxx-pch
2625 dnl turns off attempts to use or build stdc++.h.gch.
2626 dnl
2627 dnl Substs:
2628 dnl  glibcxx_PCHFLAGS
2629 dnl
2630 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
2631   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
2632   if test $enable_libstdcxx_pch = yes; then
2633     AC_CACHE_CHECK([for compiler with PCH support],
2634       [glibcxx_cv_prog_CXX_pch],
2635       [ac_save_CXXFLAGS="$CXXFLAGS"
2636        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
2637        AC_LANG_SAVE
2638        AC_LANG_CPLUSPLUS
2639        echo '#include <math.h>' > conftest.h
2640        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
2641                           -o conftest.h.gch 1>&5 2>&1 &&
2642                 echo '#error "pch failed"' > conftest.h &&
2643           echo '#include "conftest.h"' > conftest.cc &&
2644                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
2645        then
2646          glibcxx_cv_prog_CXX_pch=yes
2647        else
2648          glibcxx_cv_prog_CXX_pch=no
2649        fi
2650        rm -f conftest*
2651        CXXFLAGS=$ac_save_CXXFLAGS
2652        AC_LANG_RESTORE
2653       ])
2654     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
2655   fi
2656
2657   AC_MSG_CHECKING([for enabled PCH])
2658   AC_MSG_RESULT([$enable_libstdcxx_pch])
2659
2660   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
2661   if test $enable_libstdcxx_pch = yes; then
2662     glibcxx_PCHFLAGS="-include bits/stdc++.h"
2663   else
2664     glibcxx_PCHFLAGS=""
2665   fi
2666   AC_SUBST(glibcxx_PCHFLAGS)
2667 ])
2668
2669
2670 dnl
2671 dnl Check for atomic builtins.
2672 dnl See:
2673 dnl http://gcc.gnu.org/onlinedocs/gcc/Atomic-Builtins.html#Atomic-Builtins
2674 dnl
2675 dnl This checks to see if the host supports the compiler-generated
2676 dnl builtins for atomic operations for various integral sizes. Note, this
2677 dnl is intended to be an all-or-nothing switch, so all the atomic operations
2678 dnl that are used should be checked.
2679 dnl
2680 dnl Note:
2681 dnl libgomp and libgfortran use a link test, see CHECK_SYNC_FETCH_AND_ADD.
2682 dnl
2683 dnl Defines:
2684 dnl  _GLIBCXX_ATOMIC_BUILTINS_1
2685 dnl  _GLIBCXX_ATOMIC_BUILTINS_2
2686 dnl  _GLIBCXX_ATOMIC_BUILTINS_4
2687 dnl  _GLIBCXX_ATOMIC_BUILTINS_8
2688 dnl
2689 AC_DEFUN([GLIBCXX_ENABLE_ATOMIC_BUILTINS], [
2690   AC_LANG_SAVE
2691   AC_LANG_CPLUSPLUS
2692   old_CXXFLAGS="$CXXFLAGS"
2693
2694   # Do link tests if possible, instead asm tests, limited to some platforms
2695   # see discussion in PR target/40134, PR libstdc++/40133 and the thread
2696   # starting at http://gcc.gnu.org/ml/gcc-patches/2009-07/msg00322.html
2697   atomic_builtins_link_tests=no
2698   if test x$gcc_no_link != xyes; then
2699     # Can do link tests. Limit to some tested platforms
2700     case "$host" in
2701       *-*-linux* | *-*-uclinux* | *-*-kfreebsd*-gnu | *-*-gnu*)
2702         atomic_builtins_link_tests=yes
2703         ;;
2704     esac
2705   fi
2706
2707   if test x$atomic_builtins_link_tests = xyes; then
2708
2709   # Do link tests.
2710
2711   CXXFLAGS="$CXXFLAGS -fno-exceptions"
2712
2713   AC_MSG_CHECKING([for atomic builtins for bool])
2714   AC_CACHE_VAL(glibcxx_cv_atomic_bool, [
2715     AC_TRY_LINK(
2716       [ ],
2717       [typedef bool atomic_type;
2718        atomic_type c1;
2719        atomic_type c2;
2720        const atomic_type c3(0);
2721        __sync_fetch_and_add(&c1, c2);
2722        __sync_val_compare_and_swap(&c1, c3, c2);
2723        __sync_lock_test_and_set(&c1, c3);
2724        __sync_lock_release(&c1);
2725        __sync_synchronize();],
2726       [glibcxx_cv_atomic_bool=yes],
2727       [glibcxx_cv_atomic_bool=no])
2728   ])
2729   if test $glibcxx_cv_atomic_bool = yes; then
2730     AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS_1, 1,
2731       [Define if builtin atomic operations for bool are supported on this host.])
2732   fi
2733   AC_MSG_RESULT($glibcxx_cv_atomic_bool)
2734
2735   AC_MSG_CHECKING([for atomic builtins for short])
2736   AC_CACHE_VAL(glibcxx_cv_atomic_short, [
2737     AC_TRY_LINK(
2738       [ ],
2739       [typedef short atomic_type;
2740        atomic_type c1;
2741        atomic_type c2;
2742        const atomic_type c3(0);
2743        __sync_fetch_and_add(&c1, c2);
2744        __sync_val_compare_and_swap(&c1, c3, c2);
2745        __sync_lock_test_and_set(&c1, c3);
2746        __sync_lock_release(&c1);
2747        __sync_synchronize();],
2748       [glibcxx_cv_atomic_short=yes],
2749       [glibcxx_cv_atomic_short=no])
2750   ])
2751   if test $glibcxx_cv_atomic_short = yes; then
2752     AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS_2, 1,
2753       [Define if builtin atomic operations for short are supported on this host.])
2754   fi
2755   AC_MSG_RESULT($glibcxx_cv_atomic_short)
2756
2757   AC_MSG_CHECKING([for atomic builtins for int])
2758   AC_CACHE_VAL(glibcxx_cv_atomic_int, [
2759     AC_TRY_LINK(
2760       [ ],
2761       [typedef int atomic_type;
2762        atomic_type c1;
2763        atomic_type c2;
2764        const atomic_type c3(0);
2765        __sync_fetch_and_add(&c1, c2);
2766        __sync_val_compare_and_swap(&c1, c3, c2);
2767        __sync_lock_test_and_set(&c1, c3);
2768        __sync_lock_release(&c1);
2769        __sync_synchronize();],
2770       [glibcxx_cv_atomic_int=yes],
2771       [glibcxx_cv_atomic_int=no])
2772   ])
2773   if test $glibcxx_cv_atomic_int = yes; then
2774     AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS_4, 1,
2775       [Define if builtin atomic operations for int are supported on this host.])
2776   fi
2777   AC_MSG_RESULT($glibcxx_cv_atomic_int)
2778
2779   AC_MSG_CHECKING([for atomic builtins for long long])
2780   AC_CACHE_VAL(glibcxx_cv_atomic_long_long, [
2781     AC_TRY_LINK(
2782       [ ],
2783       [typedef long long atomic_type;
2784        atomic_type c1;
2785        atomic_type c2;
2786        const atomic_type c3(0);
2787        __sync_fetch_and_add(&c1, c2);
2788        __sync_val_compare_and_swap(&c1, c3, c2);
2789        __sync_lock_test_and_set(&c1, c3);
2790        __sync_lock_release(&c1);
2791        __sync_synchronize();],
2792       [glibcxx_cv_atomic_long_long=yes],
2793       [glibcxx_cv_atomic_long_long=no])
2794   ])
2795   if test $glibcxx_cv_atomic_long_long = yes; then
2796     AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS_8, 1,
2797       [Define if builtin atomic operations for long long are supported on this host.])
2798   fi
2799   AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
2800
2801   else
2802
2803   # Do asm tests.
2804
2805   # Compile unoptimized.
2806   CXXFLAGS='-O0 -S'
2807
2808   # Fake what AC_TRY_COMPILE does.
2809
2810     cat > conftest.$ac_ext << EOF
2811 [#]line __oline__ "configure"
2812 int main()
2813 {
2814   typedef bool atomic_type;
2815   atomic_type c1;
2816   atomic_type c2;
2817   const atomic_type c3(0);
2818   __sync_fetch_and_add(&c1, c2);
2819   __sync_val_compare_and_swap(&c1, c3, c2);
2820   __sync_lock_test_and_set(&c1, c3);
2821   __sync_lock_release(&c1);
2822   __sync_synchronize();
2823   return 0;
2824 }
2825 EOF
2826
2827     AC_MSG_CHECKING([for atomic builtins for bool])
2828     if AC_TRY_EVAL(ac_compile); then
2829       if grep __sync_ conftest.s >/dev/null 2>&1 ; then
2830         glibcxx_cv_atomic_bool=no
2831       else
2832       AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS_1, 1,
2833       [Define if builtin atomic operations for bool are supported on this host.])
2834         glibcxx_cv_atomic_bool=yes
2835       fi
2836     fi
2837     AC_MSG_RESULT($glibcxx_cv_atomic_bool)
2838     rm -f conftest*
2839
2840     cat > conftest.$ac_ext << EOF
2841 [#]line __oline__ "configure"
2842 int main()
2843 {
2844   typedef short atomic_type;
2845   atomic_type c1;
2846   atomic_type c2;
2847   const atomic_type c3(0);
2848   __sync_fetch_and_add(&c1, c2);
2849   __sync_val_compare_and_swap(&c1, c3, c2);
2850   __sync_lock_test_and_set(&c1, c3);
2851   __sync_lock_release(&c1);
2852   __sync_synchronize();
2853   return 0;
2854 }
2855 EOF
2856
2857     AC_MSG_CHECKING([for atomic builtins for short])
2858     if AC_TRY_EVAL(ac_compile); then
2859       if grep __sync_ conftest.s >/dev/null 2>&1 ; then
2860         glibcxx_cv_atomic_short=no
2861       else
2862       AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS_2, 1,
2863       [Define if builtin atomic operations for short are supported on this host.])
2864         glibcxx_cv_atomic_short=yes
2865       fi
2866     fi
2867     AC_MSG_RESULT($glibcxx_cv_atomic_short)
2868     rm -f conftest*
2869
2870     cat > conftest.$ac_ext << EOF
2871 [#]line __oline__ "configure"
2872 int main()
2873 {
2874   // NB: _Atomic_word not necessarily int.
2875   typedef int atomic_type;
2876   atomic_type c1;
2877   atomic_type c2;
2878   const atomic_type c3(0);
2879   __sync_fetch_and_add(&c1, c2);
2880   __sync_val_compare_and_swap(&c1, c3, c2);
2881   __sync_lock_test_and_set(&c1, c3);
2882   __sync_lock_release(&c1);
2883   __sync_synchronize();
2884   return 0;
2885 }
2886 EOF
2887
2888     AC_MSG_CHECKING([for atomic builtins for int])
2889     if AC_TRY_EVAL(ac_compile); then
2890       if grep __sync_ conftest.s >/dev/null 2>&1 ; then
2891         glibcxx_cv_atomic_int=no
2892       else
2893       AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS_4, 1,
2894         [Define if builtin atomic operations for int are supported on this host.])
2895         glibcxx_cv_atomic_int=yes
2896       fi
2897     fi
2898     AC_MSG_RESULT($glibcxx_cv_atomic_int)
2899     rm -f conftest*
2900
2901     cat > conftest.$ac_ext << EOF
2902 [#]line __oline__ "configure"
2903 int main()
2904 {
2905   typedef long long atomic_type;
2906   atomic_type c1;
2907   atomic_type c2;
2908   const atomic_type c3(0);
2909   __sync_fetch_and_add(&c1, c2);
2910   __sync_val_compare_and_swap(&c1, c3, c2);
2911   __sync_lock_test_and_set(&c1, c3);
2912   __sync_lock_release(&c1);
2913   __sync_synchronize();
2914   return 0;
2915 }
2916 EOF
2917
2918     AC_MSG_CHECKING([for atomic builtins for long long])
2919     if AC_TRY_EVAL(ac_compile); then
2920       if grep __sync_ conftest.s >/dev/null 2>&1 ; then
2921         glibcxx_cv_atomic_long_long=no
2922       else
2923       AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS_8, 1,
2924       [Define if builtin atomic operations for long long are supported on this host.])
2925         glibcxx_cv_atomic_long_long=yes
2926       fi
2927     fi
2928     AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
2929     rm -f conftest*
2930
2931   fi
2932
2933   CXXFLAGS="$old_CXXFLAGS"
2934   AC_LANG_RESTORE
2935
2936   # Set atomicity_dir to builtins if either of above tests pass.
2937   if test $glibcxx_cv_atomic_int = yes || test $glibcxx_cv_atomic_bool = yes ; then
2938     atomicity_dir=cpu/generic/atomicity_builtins
2939   fi
2940
2941   # If still generic, set to mutex.
2942   if test $atomicity_dir = "cpu/generic" ; then
2943     atomicity_dir=cpu/generic/atomicity_mutex
2944     AC_MSG_WARN([No native atomic operations are provided for this platform.])
2945       if test "x$target_thread_file" = xsingle; then
2946         AC_MSG_WARN([They cannot be faked when thread support is disabled.])
2947         AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
2948       else
2949         AC_MSG_WARN([They will be faked using a mutex.])
2950         AC_MSG_WARN([Performance of certain classes will degrade as a result.])
2951       fi
2952   fi
2953
2954 ])
2955
2956
2957 dnl
2958 dnl Check for exception handling support.  If an explicit enable/disable
2959 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
2960 dnl target may or may not support call frame exceptions.
2961 dnl
2962 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
2963 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
2964 dnl Neither one forces an attempt at detection.
2965 dnl
2966 dnl Defines:
2967 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
2968 dnl
2969 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
2970   AC_MSG_CHECKING([for exception model to use])
2971   AC_LANG_SAVE
2972   AC_LANG_CPLUSPLUS
2973   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
2974     [force use of builtin_setjmp for exceptions],
2975     [permit yes|no|auto])
2976
2977   if test $enable_sjlj_exceptions = auto; then
2978     # Botheration.  Now we've got to detect the exception model.  Link tests
2979     # against libgcc.a are problematic since we've not been given proper -L
2980     # bits for single-tree newlib and libgloss.
2981     #
2982     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
2983     cat > conftest.$ac_ext << EOF
2984 [#]line __oline__ "configure"
2985 struct S { ~S(); };
2986 void bar();
2987 void foo()
2988 {
2989   S s;
2990   bar();
2991 }
2992 EOF
2993     old_CXXFLAGS="$CXXFLAGS"
2994     CXXFLAGS=-S
2995     if AC_TRY_EVAL(ac_compile); then
2996       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
2997         enable_sjlj_exceptions=yes
2998       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
2999         enable_sjlj_exceptions=no
3000       elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
3001         enable_sjlj_exceptions=no
3002       fi
3003     fi
3004     CXXFLAGS="$old_CXXFLAGS"
3005     rm -f conftest*
3006   fi
3007
3008   # This is a tad weird, for hysterical raisins.  We have to map
3009   # enable/disable to two different models.
3010   case $enable_sjlj_exceptions in
3011     yes)
3012       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
3013         [Define if the compiler is configured for setjmp/longjmp exceptions.])
3014       ac_exception_model_name=sjlj
3015       ;;
3016     no)
3017       ac_exception_model_name="call frame"
3018       ;;
3019     *)
3020       AC_MSG_ERROR([unable to detect exception model])
3021       ;;
3022   esac
3023  AC_LANG_RESTORE
3024  AC_MSG_RESULT($ac_exception_model_name)
3025 ])
3026
3027
3028 dnl
3029 dnl Allow visibility attributes to be used on namespaces, objects, etc.
3030 dnl
3031 dnl --enable-visibility enables attempt to use visibility attributes.
3032 dnl --disable-visibility turns off all use of visibility attributes.
3033 dnl  +  Usage:  GLIBCXX_ENABLE_VISIBILITY[(DEFAULT)]
3034 dnl       Where DEFAULT is 'yes'.
3035 dnl
3036 AC_DEFUN([GLIBCXX_ENABLE_VISIBILITY], [
3037 GLIBCXX_ENABLE(visibility,$1,,[enables visibility safe usage])
3038
3039 if test x$enable_visibility = xyes ; then
3040   dnl all hail libgfortran
3041   dnl Check whether the target supports hidden visibility.
3042   AC_CACHE_CHECK([whether the target supports hidden visibility],
3043                  glibcxx_cv_have_attribute_visibility, [
3044   save_CFLAGS="$CFLAGS"
3045   CFLAGS="$CFLAGS -Werror"
3046   AC_TRY_COMPILE([void __attribute__((visibility("hidden"))) foo(void) { }],
3047                  [], glibcxx_cv_have_attribute_visibility=yes,
3048                  glibcxx_cv_have_attribute_visibility=no)
3049   CFLAGS="$save_CFLAGS"])
3050   if test $glibcxx_cv_have_attribute_visibility = no; then
3051     enable_visibility=no
3052   fi
3053 fi
3054
3055 GLIBCXX_CONDITIONAL(ENABLE_VISIBILITY, test $enable_visibility = yes)
3056 AC_MSG_NOTICE([visibility supported: $enable_visibility])
3057 ])
3058
3059
3060 dnl
3061 dnl Add version tags to symbols in shared library (or not), additionally
3062 dnl marking other symbols as private/local (or not).
3063 dnl
3064 dnl Sets libtool_VERSION, and determines shared library SONAME.
3065 dnl
3066 dnl  This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
3067 dnl
3068 dnl --enable-symvers=style adds a version script to the linker call when
3069 dnl       creating the shared library.  The choice of version script is
3070 dnl       controlled by 'style'.
3071 dnl --disable-symvers does not.
3072 dnl
3073 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
3074 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
3075 dnl       choose a default style based on linker characteristics.  Passing
3076 dnl       'no' disables versioning.
3077 dnl
3078 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
3079
3080 GLIBCXX_ENABLE(symvers,$1,[[[=STYLE]]],
3081   [enables symbol versioning of the shared library],
3082   [permit yes|no|gnu|gnu-versioned-namespace|darwin|darwin-export|sun])
3083
3084 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
3085 # don't know enough about $LD to do tricks...
3086 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
3087 # Sun style symbol versions needs GNU c++filt for make_sunver.pl to work
3088 # with extern "C++" in version scripts.
3089 AC_REQUIRE([GCC_PROG_GNU_CXXFILT])
3090
3091 # Turn a 'yes' into a suitable default.
3092 if test x$enable_symvers = xyes ; then
3093   if test $enable_shared = no || test "x$LD" = x || test x$gcc_no_link = xyes; then
3094     enable_symvers=no
3095   else
3096     if test $with_gnu_ld = yes ; then
3097       case ${target_os} in
3098         hpux*)
3099           enable_symvers=no ;;
3100         *)
3101           enable_symvers=gnu ;;
3102       esac
3103     else
3104       case ${target_os} in
3105         darwin*)
3106           enable_symvers=darwin ;;
3107         # Sun symbol versioning exists since Solaris 2.5.
3108         solaris2.[[5-9]]* | solaris2.1[[0-9]]*)
3109           # make_sunver.pl needs GNU c++filt to support extern "C++" in
3110           # version scripts, so disable symbol versioning if none can be
3111           # found.
3112           if test -z "$ac_cv_path_CXXFILT"; then
3113             AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
3114             AC_MSG_WARN([=== no GNU c++filt could  be found.])
3115             AC_MSG_WARN([=== Symbol versioning will be disabled.])
3116             enable_symvers=no
3117           else
3118             enable_symvers=sun
3119           fi
3120           ;;
3121         *)
3122           enable_symvers=no ;;
3123       esac
3124     fi
3125   fi
3126 fi
3127
3128 # Check to see if 'darwin' or 'darwin-export' can win.
3129 if test x$enable_symvers = xdarwin-export ; then
3130     enable_symvers=darwin
3131 fi
3132
3133 # Check if 'sun' was requested on non-Solaris 2 platforms.
3134 if test x$enable_symvers = xsun ; then
3135   case ${target_os} in
3136     solaris2*)
3137       # All fine.
3138       ;;
3139     *)
3140       # Unlikely to work.
3141       AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
3142       AC_MSG_WARN([=== you are not targetting Solaris 2.])
3143       AC_MSG_WARN([=== Symbol versioning will be disabled.])
3144       enable_symvers=no
3145       ;;
3146   esac
3147 fi
3148
3149 # Check to see if 'gnu' can win.
3150 if test $enable_symvers = gnu ||
3151   test $enable_symvers = gnu-versioned-namespace ||
3152   test $enable_symvers = sun; then
3153   # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
3154   AC_MSG_CHECKING([for shared libgcc])
3155   ac_save_CFLAGS="$CFLAGS"
3156   CFLAGS=' -lgcc_s'
3157   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
3158   CFLAGS="$ac_save_CFLAGS"
3159   if test $glibcxx_shared_libgcc = no; then
3160     cat > conftest.c <<EOF
3161 int main (void) { return 0; }
3162 EOF
3163 changequote(,)dnl
3164     glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
3165                              -shared -shared-libgcc -o conftest.so \
3166                              conftest.c -v 2>&1 >/dev/null \
3167                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
3168 changequote([,])dnl
3169     rm -f conftest.c conftest.so
3170     if test x${glibcxx_libgcc_s_suffix+set} = xset; then
3171       CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
3172       AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
3173       CFLAGS="$ac_save_CFLAGS"
3174     fi
3175   fi
3176   AC_MSG_RESULT($glibcxx_shared_libgcc)
3177
3178   # For GNU ld, we need at least this version.  The format is described in
3179   # GLIBCXX_CHECK_LINKER_FEATURES above.
3180   glibcxx_min_gnu_ld_version=21400
3181
3182   # If no shared libgcc, can't win.
3183   if test $glibcxx_shared_libgcc != yes; then
3184       AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3185       AC_MSG_WARN([=== you are not building a shared libgcc_s.])
3186       AC_MSG_WARN([=== Symbol versioning will be disabled.])
3187       enable_symvers=no
3188   elif test $with_gnu_ld != yes && test $enable_symvers = sun; then
3189     : All interesting versions of Sun ld support sun style symbol versioning.
3190   elif test $with_gnu_ld != yes ; then
3191     # just fail for now
3192     AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3193     AC_MSG_WARN([=== you are not using the GNU linker.])
3194     AC_MSG_WARN([=== Symbol versioning will be disabled.])
3195     enable_symvers=no
3196   elif test $glibcxx_ld_is_gold = yes ; then
3197     : All versions of gold support symbol versioning.
3198   elif test $glibcxx_gnu_ld_version -lt $glibcxx_min_gnu_ld_version ; then
3199     # The right tools, the right setup, but too old.  Fallbacks?
3200     AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
3201     AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
3202     AC_MSG_WARN(=== You would need to upgrade your binutils to version)
3203     AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
3204     AC_MSG_WARN([=== Symbol versioning will be disabled.])
3205     enable_symvers=no
3206   fi
3207 fi
3208
3209 # For libtool versioning info, format is CURRENT:REVISION:AGE
3210 libtool_VERSION=6:17:0
3211
3212 # Everything parsed; figure out what files and settings to use.
3213 case $enable_symvers in
3214   no)
3215     SYMVER_FILE=config/abi/pre/none.ver
3216     ;;
3217   gnu)
3218     SYMVER_FILE=config/abi/pre/gnu.ver
3219     AC_DEFINE(_GLIBCXX_SYMVER_GNU, 1,
3220               [Define to use GNU versioning in the shared library.])
3221     ;;
3222   gnu-versioned-namespace)
3223     libtool_VERSION=7:0:0
3224     SYMVER_FILE=config/abi/pre/gnu-versioned-namespace.ver
3225     AC_DEFINE(_GLIBCXX_SYMVER_GNU_NAMESPACE, 1,
3226               [Define to use GNU namespace versioning in the shared library.])
3227     ;;
3228   darwin)
3229     SYMVER_FILE=config/abi/pre/gnu.ver
3230     AC_DEFINE(_GLIBCXX_SYMVER_DARWIN, 1,
3231               [Define to use darwin versioning in the shared library.])
3232     ;;
3233   sun)
3234     SYMVER_FILE=config/abi/pre/gnu.ver
3235     AC_DEFINE(_GLIBCXX_SYMVER_SUN, 1,
3236               [Define to use Sun versioning in the shared library.])
3237     ;;
3238 esac
3239
3240 if test x$enable_symvers != xno ; then
3241   AC_DEFINE(_GLIBCXX_SYMVER, 1,
3242          [Define to use symbol versioning in the shared library.])
3243 fi
3244
3245 AC_CACHE_CHECK([whether the target supports .symver directive],
3246                glibcxx_cv_have_as_symver_directive, [
3247   AC_TRY_COMPILE([void foo (void); __asm (".symver foo, bar@SYMVER");],
3248                  [], glibcxx_cv_have_as_symver_directive=yes,
3249                  glibcxx_cv_have_as_symver_directive=no)])
3250 if test $glibcxx_cv_have_as_symver_directive = yes; then
3251   AC_DEFINE(HAVE_AS_SYMVER_DIRECTIVE, 1,
3252     [Define to 1 if the target assembler supports .symver directive.])
3253 fi
3254
3255 AC_SUBST(SYMVER_FILE)
3256 AC_SUBST(port_specific_symbol_files)
3257 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS, test $enable_symvers != no)
3258 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU, test $enable_symvers = gnu)
3259 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU_NAMESPACE, test $enable_symvers = gnu-versioned-namespace)
3260 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_DARWIN, test $enable_symvers = darwin)
3261 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_SUN, test $enable_symvers = sun)
3262 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
3263
3264 if test $enable_symvers != no ; then
3265    case ${target_os} in
3266      # The Solaris 2 runtime linker doesn't support the GNU extension of
3267      # binding the same symbol to different versions
3268      solaris2*)
3269        symvers_renaming=no  ;;
3270      # Other platforms with GNU symbol versioning (GNU/Linux, more?) do.
3271      *)
3272        AC_DEFINE(HAVE_SYMVER_SYMBOL_RENAMING_RUNTIME_SUPPORT, 1,
3273          [Define to 1 if the target runtime linker supports binding the same symbol to different versions.])
3274        symvers_renaming=yes  ;;
3275     esac
3276 else
3277     symvers_renaming=no
3278 fi
3279 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_SOL2, test $symvers_renaming = no)
3280
3281 # Now, set up compatibility support, if any.
3282 # In addition, need this to deal with std::size_t mangling in
3283 # src/compatibility.cc.  In a perfect world, could use
3284 # typeid(std::size_t).name()[0] to do direct substitution.
3285 AC_MSG_CHECKING([for size_t as unsigned int])
3286 ac_save_CFLAGS="$CFLAGS"
3287 CFLAGS="-Werror"
3288 AC_TRY_COMPILE(, [__SIZE_TYPE__* stp; unsigned int* uip; stp = uip;],
3289                  [glibcxx_size_t_is_i=yes], [glibcxx_size_t_is_i=no])
3290 CFLAGS=$ac_save_CFLAGS
3291 if test "$glibcxx_size_t_is_i" = yes; then
3292   AC_DEFINE(_GLIBCXX_SIZE_T_IS_UINT, 1, [Define if size_t is unsigned int.])
3293 fi
3294 AC_MSG_RESULT([$glibcxx_size_t_is_i])
3295
3296 AC_MSG_CHECKING([for ptrdiff_t as int])
3297 ac_save_CFLAGS="$CFLAGS"
3298 CFLAGS="-Werror"
3299 AC_TRY_COMPILE(, [__PTRDIFF_TYPE__* ptp; int* ip; ptp = ip;],
3300                  [glibcxx_ptrdiff_t_is_i=yes], [glibcxx_ptrdiff_t_is_i=no])
3301 CFLAGS=$ac_save_CFLAGS
3302 if test "$glibcxx_ptrdiff_t_is_i" = yes; then
3303   AC_DEFINE(_GLIBCXX_PTRDIFF_T_IS_INT, 1, [Define if ptrdiff_t is int.])
3304 fi
3305 AC_MSG_RESULT([$glibcxx_ptrdiff_t_is_i])
3306 ])
3307
3308
3309 dnl
3310 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
3311 dnl We must stage the required headers so that they will be installed
3312 dnl with the library (unlike libgcc, the STL implementation is provided
3313 dnl solely within headers).  Since we must not inject random user-space
3314 dnl macro names into user-provided C++ code, we first stage into <file>-in
3315 dnl and process to <file> with an output command.  The reason for a two-
3316 dnl stage process here is to correctly handle $srcdir!=$objdir without
3317 dnl having to write complex code (the sed commands to clean the macro
3318 dnl namespace are complex and fragile enough as it is).  We must also
3319 dnl add a relative path so that -I- is supported properly.
3320 dnl
3321 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
3322   AC_MSG_CHECKING([for thread model used by GCC])
3323   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3324   AC_MSG_RESULT([$target_thread_file])
3325 ])
3326
3327
3328 dnl
3329 dnl Check if gthread implementation defines the types and functions
3330 dnl required by the c++0x thread library.  Conforming gthread
3331 dnl implementations can define __GTHREADS_CXX0X to enable use with c++0x.
3332 dnl
3333 AC_DEFUN([GLIBCXX_CHECK_GTHREADS], [
3334   AC_LANG_SAVE
3335   AC_LANG_CPLUSPLUS
3336
3337   ac_save_CXXFLAGS="$CXXFLAGS"
3338   CXXFLAGS="$CXXFLAGS -fno-exceptions \
3339         -I${toplevel_srcdir}/libgcc -I${toplevel_builddir}/libgcc"
3340
3341   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3342   case $target_thread_file in
3343     posix)
3344       CXXFLAGS="$CXXFLAGS -DSUPPORTS_WEAK -DGTHREAD_USE_WEAK -D_PTHREADS"
3345   esac
3346
3347   AC_MSG_CHECKING([whether it can be safely assumed that mutex_timedlock is available])
3348
3349   AC_TRY_COMPILE([#include <unistd.h>],
3350     [
3351       // In case of POSIX threads check _POSIX_TIMEOUTS.
3352       #if (defined(_PTHREADS) \
3353           && (!defined(_POSIX_TIMEOUTS) || _POSIX_TIMEOUTS <= 0))
3354       #error
3355       #endif
3356     ], [ac_gthread_use_mutex_timedlock=1], [ac_gthread_use_mutex_timedlock=0])
3357
3358   AC_DEFINE_UNQUOTED(_GTHREAD_USE_MUTEX_TIMEDLOCK, $ac_gthread_use_mutex_timedlock,
3359                      [Define to 1 if mutex_timedlock is available.])
3360
3361   if test $ac_gthread_use_mutex_timedlock = 1 ; then res_mutex_timedlock=yes ;
3362   else res_mutex_timedlock=no ; fi
3363   AC_MSG_RESULT([$res_mutex_timedlock])
3364
3365   AC_MSG_CHECKING([for gthreads library])
3366
3367   AC_TRY_COMPILE([#include "gthr.h"],
3368     [
3369       #ifndef __GTHREADS_CXX0X
3370       #error
3371       #endif
3372     ], [ac_has_gthreads=yes], [ac_has_gthreads=no])
3373
3374   AC_MSG_RESULT([$ac_has_gthreads])
3375
3376   if test x"$ac_has_gthreads" = x"yes"; then
3377     AC_DEFINE(_GLIBCXX_HAS_GTHREADS, 1,
3378               [Define if gthreads library is available.])
3379   fi
3380
3381   CXXFLAGS="$ac_save_CXXFLAGS"
3382   AC_LANG_RESTORE
3383 ])
3384
3385
3386 # Check whether LC_MESSAGES is available in <locale.h>.
3387 # Ulrich Drepper <drepper@cygnus.com>, 1995.
3388 #
3389 # This file file be copied and used freely without restrictions.  It can
3390 # be used in projects which are not available under the GNU Public License
3391 # but which still want to provide support for the GNU gettext functionality.
3392 # Please note that the actual code is *not* freely available.
3393 AC_DEFUN([AC_LC_MESSAGES], [
3394   AC_CHECK_HEADER(locale.h, [
3395     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
3396       [AC_TRY_COMPILE([#include <locale.h>], [return LC_MESSAGES],
3397        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
3398     if test $ac_cv_val_LC_MESSAGES = yes; then
3399       AC_DEFINE(HAVE_LC_MESSAGES, 1,
3400                 [Define if LC_MESSAGES is available in <locale.h>.])
3401     fi
3402   ])
3403 ])
3404
3405 dnl
3406 dnl Check whether get_nprocs is available in <sys/sysinfo.h>, and define _GLIBCXX_USE_GET_NPROCS.
3407 dnl
3408 AC_DEFUN([GLIBCXX_CHECK_GET_NPROCS], [
3409
3410   AC_LANG_SAVE
3411   AC_LANG_CPLUSPLUS
3412   ac_save_CXXFLAGS="$CXXFLAGS"
3413   CXXFLAGS="$CXXFLAGS -fno-exceptions"
3414
3415   AC_MSG_CHECKING([for get_nprocs])
3416   AC_CACHE_VAL(glibcxx_cv_GET_NPROCS, [
3417     GCC_TRY_COMPILE_OR_LINK(
3418       [#include <sys/sysinfo.h>],
3419       [int n = get_nprocs();],
3420       [glibcxx_cv_GET_NPROCS=yes],
3421       [glibcxx_cv_GET_NPROCS=no])
3422   ])
3423   if test $glibcxx_cv_GET_NPROCS = yes; then
3424     AC_DEFINE(_GLIBCXX_USE_GET_NPROCS, 1, [Define if get_nprocs is available in <sys/sysinfo.h>.])
3425   fi
3426   AC_MSG_RESULT($glibcxx_cv_GET_NPROCS)
3427
3428   CXXFLAGS="$ac_save_CXXFLAGS"
3429   AC_LANG_RESTORE
3430 ])
3431
3432 dnl
3433 dnl Check whether sysconf(_SC_NPROCESSORS_ONLN) is available in <unistd.h>, and define _GLIBCXX_USE_SC_NPROCESSORS_ONLN.
3434 dnl
3435 AC_DEFUN([GLIBCXX_CHECK_SC_NPROCESSORS_ONLN], [
3436
3437   AC_LANG_SAVE
3438   AC_LANG_CPLUSPLUS
3439   ac_save_CXXFLAGS="$CXXFLAGS"
3440   CXXFLAGS="$CXXFLAGS -fno-exceptions"
3441
3442   AC_MSG_CHECKING([for _SC_NPROCESSORS_ONLN])
3443   AC_CACHE_VAL(glibcxx_cv_SC_NPROCESSORS_ONLN, [
3444     GCC_TRY_COMPILE_OR_LINK(
3445       [#include <unistd.h>],
3446       [int n = sysconf(_SC_NPROCESSORS_ONLN);],
3447       [glibcxx_cv_SC_NPROCESSORS_ONLN=yes],
3448       [glibcxx_cv_SC_NPROCESSORS_ONLN=no])
3449   ])
3450   if test $glibcxx_cv_SC_NPROCESSORS_ONLN = yes; then
3451     AC_DEFINE(_GLIBCXX_USE_SC_NPROCESSORS_ONLN, 1, [Define if _SC_NPROCESSORS_ONLN  is available in <unistd.h>.])
3452   fi
3453   AC_MSG_RESULT($glibcxx_cv_SC_NPROCESSORS_ONLN)
3454
3455   CXXFLAGS="$ac_save_CXXFLAGS"
3456   AC_LANG_RESTORE
3457 ])
3458
3459
3460 # Macros from the top-level gcc directory.
3461 m4_include([../config/gc++filt.m4])
3462 m4_include([../config/tls.m4])