libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN([GLIBCXX_CHECK_HOST], [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
  27   AC_MSG_NOTICE([OS config directory is $os_include_dir])
  28 ])
  29
  30 dnl
  31 dnl Initialize the rest of the library configury.  At this point we have
  32 dnl variables like $host.
  33 dnl
  34 dnl Sets:
  35 dnl  gcc_version          (x.y.z format)
  36 dnl  SUBDIRS
  37 dnl Substs:
  38 dnl  glibcxx_builddir     (absolute path)
  39 dnl  glibcxx_srcdir       (absolute path)
  40 dnl  toplevel_srcdir      (absolute path)
  41 dnl  with_cross_host
  42 dnl  with_newlib
  43 dnl  with_target_subdir
  44 dnl plus
  45 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  46 dnl  - default settings for all AM_CONFITIONAL test variables
  47 dnl  - lots of tools, like CC and CXX
  48 dnl
  49 AC_DEFUN([GLIBCXX_CONFIGURE], [
  50   # Keep these sync'd with the list in Makefile.am.  The first provides an
  51   # expandable list at autoconf time; the second provides an expandable list
  52   # (i.e., shell variable) at configure time.
  53   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  54   SUBDIRS='glibcxx_SUBDIRS'
  55
  56   # These need to be absolute paths, yet at the same time need to
  57   # canonicalize only relative paths, because then amd will not unmount
  58   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  59   glibcxx_builddir=`${PWDCMD-pwd}`
  60   case $srcdir in
  61     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  62     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  63   esac
  64   toplevel_srcdir=${glibcxx_srcdir}/..
  65   AC_SUBST(glibcxx_builddir)
  66   AC_SUBST(glibcxx_srcdir)
  67   AC_SUBST(toplevel_srcdir)
  68
  69   # We use these options to decide which functions to include.  They are
  70   # set from the top level.
  71   AC_ARG_WITH([target-subdir],
  72     AC_HELP_STRING([--with-target-subdir=SUBDIR],
  73                    [configuring in a subdirectory]))
  74
  75   AC_ARG_WITH([cross-host],
  76     AC_HELP_STRING([--with-cross-host=HOST],
  77                    [configuring with a cross compiler]))
  78
  79   AC_ARG_WITH([newlib],
  80     AC_HELP_STRING([--with-newlib],
  81                    [assume newlib as a system C library]))
  82
  83   # We're almost certainly being configured before anything else which uses
  84   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
  85   # we not cache the value of CXX that we "discover" here, because it's set
  86   # to something unique for us and libjava.  Other target libraries need to
  87   # find CXX for themselves.  We yank the rug out from under the normal AC_*
  88   # process by sneakily renaming the cache variable.  This also lets us debug
  89   # the value of "our" CXX in postmortems.
  90   #
  91   # We must also force CXX to /not/ be a precious variable, otherwise the
  92   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
  93   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
  94   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
  95   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
  96   #
  97   # -fno-builtin must be present here so that a non-conflicting form of
  98   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  99
 100   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103   save_CXXFLAGS="$CXXFLAGS"
 104   CXXFLAGS="$CXXFLAGS -fno-builtin"
 105   AC_PROG_CC
 106   AC_PROG_CXX
 107   CXXFLAGS="$save_CXXFLAGS"
 108   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109   AC_SUBST(CFLAGS)
 110   AC_SUBST(CXXFLAGS)
 111
 112   # For directory versioning (e.g., headers) and other variables.
 113   AC_MSG_CHECKING([for GCC version number])
 114   gcc_version=`$CXX -dumpversion`
 115   AC_MSG_RESULT($gcc_version)
 116
 117   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 118   # available).  Uncomment the next line to force a particular method.
 119   AC_PROG_LN_S
 120   #LN_S='cp -p'
 121
 122   AC_CHECK_TOOL(AS, as)
 123   AC_CHECK_TOOL(AR, ar)
 124   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 125
 126   AM_MAINTAINER_MODE
 127
 128   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 129   # which are themselves conditionally expanded.
 130   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 131   ## other macros from doing the same.  This should be automated.)  -pme
 132   need_libmath=no
 133   enable_wchar_t=no
 134   #enable_libstdcxx_debug=no
 135   #enable_libstdcxx_pch=no
 136   #enable_cheaders=c
 137   #c_compatibility=no
 138   #enable_abi_check=no
 139   #enable_symvers=no
 140   #enable_hosted_libstdcxx=yes
 141
 142   # Find platform-specific directories containing configuration info.
 143   # Also possibly modify flags used elsewhere, as needed by the platform.
 144   GLIBCXX_CHECK_HOST
 145 ])
 146
 147
 148 m4_include([linkage.m4])
 149 m4_include([../config/no-executables.m4])
 150
 151
 152 dnl
 153 dnl Tests for newer compiler features, or features that are present in newer
 154 dnl compiler versions but not older compiler versions still in use, should
 155 dnl be placed here.
 156 dnl
 157 dnl Defines:
 158 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 159 dnl   new inlining code or the new system_header pragma will die on -Werror.
 160 dnl   Leave it out by default and use maint-mode to use it.
 161 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 162 dnl   compiler supports it and the user has not requested debug mode.
 163 dnl
 164 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
 165   # All these tests are for C++; save the language and the compiler flags.
 166   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 167   # found in GLIBCXX_CONFIGURE.
 168   AC_LANG_SAVE
 169   AC_LANG_CPLUSPLUS
 170   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 171   ac_save_CXXFLAGS="$CXXFLAGS"
 172
 173   # Check for maintainer-mode bits.
 174   if test x"$USE_MAINTAINER_MODE" = xno; then
 175     WERROR=''
 176   else
 177     WERROR='-Werror'
 178   fi
 179
 180   # Check for -ffunction-sections -fdata-sections
 181   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 182   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 183   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 184   if test "$ac_test_CXXFLAGS" = set; then
 185     CXXFLAGS="$ac_save_CXXFLAGS"
 186   else
 187     # this is the suspicious part
 188     CXXFLAGS=''
 189   fi
 190   if test x"$ac_fdsections" = x"yes"; then
 191     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 192   fi
 193   AC_MSG_RESULT($ac_fdsections)
 194
 195   AC_LANG_RESTORE
 196   AC_SUBST(WERROR)
 197   AC_SUBST(SECTION_FLAGS)
 198 ])
 199
 200
 201 dnl
 202 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 203 dnl the native linker is in use, all variables will be defined to something
 204 dnl safe (like an empty string).
 205 dnl
 206 dnl Defines:
 207 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 208 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 209 dnl  LD (as a side effect of testing)
 210 dnl Sets:
 211 dnl  with_gnu_ld
 212 dnl  glibcxx_gnu_ld_version (possibly)
 213 dnl
 214 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 215 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 216 dnl
 217 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
 218   # If we're not using GNU ld, then there's no point in even trying these
 219   # tests.  Check for that first.  We should have already tested for gld
 220   # by now (in libtool), but require it now just to be safe...
 221   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 222   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 223   AC_REQUIRE([AC_PROG_LD])
 224   AC_REQUIRE([AC_PROG_AWK])
 225
 226   # The name set by libtool depends on the version of libtool.  Shame on us
 227   # for depending on an impl detail, but c'est la vie.  Older versions used
 228   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 229   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 230   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 231   # set (hence we're using an older libtool), then set it.
 232   if test x${with_gnu_ld+set} != xset; then
 233     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 234       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 235       with_gnu_ld=no
 236     else
 237       with_gnu_ld=$ac_cv_prog_gnu_ld
 238     fi
 239   fi
 240
 241   # Start by getting the version number.  I think the libtool test already
 242   # does some of this, but throws away the result.
 243   changequote(,)
 244   ldver=`$LD --version 2>/dev/null | head -1 | \
 245          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 246   changequote([,])
 247   glibcxx_gnu_ld_version=`echo $ldver | \
 248          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 249
 250   # Set --gc-sections.
 251   if test "$with_gnu_ld" = "notbroken"; then
 252     # GNU ld it is!  Joy and bunny rabbits!
 253
 254     # All these tests are for C++; save the language and the compiler flags.
 255     # Need to do this so that g++ won't try to link in libstdc++
 256     ac_test_CFLAGS="${CFLAGS+set}"
 257     ac_save_CFLAGS="$CFLAGS"
 258     CFLAGS='-x c++  -Wl,--gc-sections'
 259
 260     # Check for -Wl,--gc-sections
 261     # XXX This test is broken at the moment, as symbols required for linking
 262     # are now in libsupc++ (not built yet).  In addition, this test has
 263     # cored on solaris in the past.  In addition, --gc-sections doesn't
 264     # really work at the moment (keeps on discarding used sections, first
 265     # .eh_frame and now some of the glibc sections for iconv).
 266     # Bzzzzt.  Thanks for playing, maybe next time.
 267     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 268     AC_TRY_RUN([
 269      int main(void)
 270      {
 271        try { throw 1; }
 272        catch (...) { };
 273        return 0;
 274      }
 275     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 276     if test "$ac_test_CFLAGS" = set; then
 277       CFLAGS="$ac_save_CFLAGS"
 278     else
 279       # this is the suspicious part
 280       CFLAGS=''
 281     fi
 282     if test "$ac_sectionLDflags" = "yes"; then
 283       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 284     fi
 285     AC_MSG_RESULT($ac_sectionLDflags)
 286   fi
 287
 288   # Set linker optimization flags.
 289   if test x"$with_gnu_ld" = x"yes"; then
 290     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 291   fi
 292
 293   AC_SUBST(SECTION_LDFLAGS)
 294   AC_SUBST(OPT_LDFLAGS)
 295 ])
 296
 297
 298 dnl
 299 dnl Check to see if this target can enable the wchar_t parts.
 300 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 301 dnl must have been previously checked.)  By default, wide characters are
 302 dnl disabled.
 303 dnl
 304 dnl Defines:
 305 dnl  HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 306 dnl  _GLIBCXX_USE_WCHAR_T if all the bits are found.
 307 dnl Substs:
 308 dnl  LIBICONV to a -l string containing the iconv library, if needed.
 309 dnl
 310 AC_DEFUN([GLIBCXX_CHECK_WCHAR_T_SUPPORT], [
 311   # Test wchar.h for mbstate_t, which is needed for char_traits and
 312   # others even if wchar_t support is not on.
 313   AC_MSG_CHECKING([for mbstate_t])
 314   AC_TRY_COMPILE([#include <wchar.h>],
 315   [mbstate_t teststate;],
 316   have_mbstate_t=yes, have_mbstate_t=no)
 317   AC_MSG_RESULT($have_mbstate_t)
 318   if test x"$have_mbstate_t" = xyes; then
 319     AC_DEFINE(HAVE_MBSTATE_T)
 320   fi
 321
 322   # Sanity check for existence of ISO C99 headers for extended encoding.
 323   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 324   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 325
 326   # Only continue checking if the ISO C99 headers exist and support is on.
 327   if test x"$ac_has_wchar_h" = xyes &&
 328      test x"$ac_has_wctype_h" = xyes &&
 329      test x"$enable_c_mbchar" != xno; then
 330
 331     # Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 332     # numeric_limits can instantiate type_traits<wchar_t>
 333     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 334     AC_TRY_COMPILE([#include <wchar.h>],
 335     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 336     has_wchar_minmax=yes, has_wchar_minmax=no)
 337     AC_MSG_RESULT($has_wchar_minmax)
 338
 339     # Test wchar.h for WEOF, which is what we use to determine whether
 340     # to specialize for char_traits<wchar_t> or not.
 341     AC_MSG_CHECKING([for WEOF])
 342     AC_TRY_COMPILE([
 343       #include <wchar.h>
 344       #include <stddef.h>],
 345     [wint_t i = WEOF;],
 346     has_weof=yes, has_weof=no)
 347     AC_MSG_RESULT($has_weof)
 348
 349     # Tests for wide character functions used in char_traits<wchar_t>.
 350     ac_wfuncs=yes
 351     AC_CHECK_FUNCS([wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset],
 352     [],[ac_wfuncs=no])
 353
 354     # Checks for names injected into std:: by the c_std headers.
 355     AC_CHECK_FUNCS([btowc wctob fgetwc fgetws fputwc fputws fwide \
 356     fwprintf fwscanf swprintf swscanf vfwprintf vswprintf \
 357     vwprintf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 358     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstol \
 359     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 360     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr],
 361     [],[ac_wfuncs=no])
 362
 363     # Checks for wide character functions that are not required
 364     # for basic wchar_t support.  Don't disable support if they are missing.
 365     # Injection of these is wrapped with guard macros.
 366     AC_CHECK_FUNCS([vfwscanf vswscanf vwscanf wcstof iswblank],[],[])
 367
 368     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 369     if test x"$has_weof" = xyes &&
 370        test x"$has_wchar_minmax" = xyes &&
 371        test x"$ac_wfuncs" = xyes;
 372     then
 373       ac_isoC99_wchar_t=yes
 374     else
 375       ac_isoC99_wchar_t=no
 376     fi
 377     AC_MSG_RESULT($ac_isoC99_wchar_t)
 378
 379     # Use iconv for wchar_t to char conversions. As such, check for
 380     # X/Open Portability Guide, version 2 features (XPG2).
 381     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 382     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 383
 384     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 385     AC_CHECK_LIB(iconv, iconv, LIBICONV="-liconv")
 386     ac_save_LIBS="$LIBS"
 387     LIBS="$LIBS $LIBICONV"
 388     AC_SUBST(LIBICONV)
 389
 390     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 391     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 392
 393     LIBS="$ac_save_LIBS"
 394
 395     AC_MSG_CHECKING([for XPG2 wchar_t support])
 396     if test x"$ac_has_iconv_h" = xyes &&
 397        test x"$ac_has_langinfo_h" = xyes &&
 398        test x"$ac_XPG2funcs" = xyes;
 399     then
 400       ac_XPG2_wchar_t=yes
 401     else
 402       ac_XPG2_wchar_t=no
 403     fi
 404     AC_MSG_RESULT($ac_XPG2_wchar_t)
 405
 406     # At the moment, only enable wchar_t specializations if all the
 407     # above support is present.
 408     if test x"$ac_isoC99_wchar_t" = xyes &&
 409        test x"$ac_XPG2_wchar_t" = xyes;
 410     then
 411       AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
 412       enable_wchar_t=yes
 413     fi
 414   fi
 415   AC_MSG_CHECKING([for enabled wchar_t specializations])
 416   AC_MSG_RESULT($enable_wchar_t)
 417 ])
 418
 419
 420 dnl
 421 dnl Check for headers for, and arguments to, the setrlimit() function.
 422 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 423 dnl
 424 dnl Defines:
 425 dnl  _GLIBCXX_RES_LIMITS if we can set artificial resource limits
 426 dnl  various HAVE_LIMIT_* for individual limit names
 427 dnl
 428 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
 429   AC_TRY_COMPILE(
 430     [#include <unistd.h>
 431      #include <sys/time.h>
 432      #include <sys/resource.h>
 433     ],
 434     [ int f = RLIMIT_$1 ; ],
 435     [glibcxx_mresult=1], [glibcxx_mresult=0])
 436   AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
 437                      [Only used in build directory testsuite_hooks.h.])
 438 ])
 439
 440 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
 441   setrlimit_have_headers=yes
 442   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 443                    [],
 444                    [setrlimit_have_headers=no])
 445   # If don't have the headers, then we can't run the tests now, and we
 446   # won't be seeing any of these during testsuite compilation.
 447   if test $setrlimit_have_headers = yes; then
 448     # Can't do these in a loop, else the resulting syntax is wrong.
 449     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 450     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 451     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 452     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 453     GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
 454
 455     # Check for rlimit, setrlimit.
 456     AC_CACHE_VAL(ac_setrlimit, [
 457       AC_TRY_COMPILE(
 458         [#include <unistd.h>
 459          #include <sys/time.h>
 460          #include <sys/resource.h>
 461         ],
 462         [struct rlimit r;
 463          setrlimit(0, &r);],
 464         [ac_setrlimit=yes], [ac_setrlimit=no])
 465     ])
 466   fi
 467
 468   AC_MSG_CHECKING([for testsuite resource limits support])
 469   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 470     ac_res_limits=yes
 471     AC_DEFINE(_GLIBCXX_RES_LIMITS)
 472   else
 473     ac_res_limits=no
 474   fi
 475   AC_MSG_RESULT($ac_res_limits)
 476 ])
 477
 478
 479 dnl
 480 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 481 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 482 dnl
 483 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
 484   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 485     AC_TRY_LINK(
 486       [#include <sys/stat.h>],
 487       [struct stat buffer;
 488        fstat(0, &buffer);
 489        S_ISREG(buffer.st_mode);],
 490       [glibcxx_cv_S_ISREG=yes],
 491       [glibcxx_cv_S_ISREG=no])
 492   ])
 493   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 494     AC_TRY_LINK(
 495       [#include <sys/stat.h>],
 496       [struct stat buffer;
 497        fstat(0, &buffer);
 498        S_IFREG & buffer.st_mode;],
 499       [glibcxx_cv_S_IFREG=yes],
 500       [glibcxx_cv_S_IFREG=no])
 501   ])
 502   if test $glibcxx_cv_S_ISREG = yes; then
 503     AC_DEFINE(HAVE_S_ISREG)
 504   elif test $glibcxx_cv_S_IFREG = yes; then
 505     AC_DEFINE(HAVE_S_IFREG)
 506   fi
 507 ])
 508
 509
 510 dnl
 511 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 512 dnl
 513 AC_DEFUN([GLIBCXX_CHECK_POLL], [
 514   AC_CACHE_VAL(glibcxx_cv_POLL, [
 515     AC_TRY_LINK(
 516       [#include <poll.h>],
 517       [struct pollfd pfd[1];
 518        pfd[0].events = POLLIN;
 519        poll(pfd, 1, 0);],
 520       [glibcxx_cv_POLL=yes],
 521       [glibcxx_cv_POLL=no])
 522   ])
 523   if test $glibcxx_cv_POLL = yes; then
 524     AC_DEFINE(HAVE_POLL)
 525   fi
 526 ])
 527
 528
 529 dnl
 530 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 531 dnl
 532 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
 533   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 534     AC_TRY_LINK(
 535       [#include <sys/uio.h>],
 536       [struct iovec iov[2];
 537        writev(0, iov, 0);],
 538       [glibcxx_cv_WRITEV=yes],
 539       [glibcxx_cv_WRITEV=no])
 540   ])
 541   if test $glibcxx_cv_WRITEV = yes; then
 542     AC_DEFINE(HAVE_WRITEV)
 543   fi
 544 ])
 545
 546
 547 dnl
 548 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 549 dnl
 550 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
 551   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 552     AC_TRY_COMPILE(
 553       [#include <stdint.h>],
 554       [int64_t var;],
 555       [glibcxx_cv_INT64_T=yes],
 556       [glibcxx_cv_INT64_T=no])
 557   ])
 558   if test $glibcxx_cv_INT64_T = yes; then
 559     AC_DEFINE(HAVE_INT64_T)
 560   fi
 561 ])
 562
 563
 564 dnl
 565 dnl Check whether LFS support is available.
 566 dnl
 567 AC_DEFUN([GLIBCXX_CHECK_LFS], [
 568   AC_LANG_SAVE
 569   AC_LANG_CPLUSPLUS
 570   ac_save_CXXFLAGS="$CXXFLAGS"
 571   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 572   AC_CACHE_VAL(glibcxx_cv_LFS, [
 573     AC_TRY_LINK(
 574       [#include <unistd.h>
 575        #include <stdio.h>
 576       ],
 577       [FILE* fp;
 578        fopen64("t", "w");
 579        fseeko64(fp, 0, SEEK_CUR);
 580        ftello64(fp);
 581        lseek64(1, 0, SEEK_CUR);],
 582       [glibcxx_cv_LFS=yes],
 583       [glibcxx_cv_LFS=no])
 584   ])
 585   if test $glibcxx_cv_LFS = yes; then
 586     AC_DEFINE(_GLIBCXX_USE_LFS)
 587   fi
 588   CXXFLAGS="$ac_save_CXXFLAGS"
 589   AC_LANG_RESTORE
 590 ])
 591
 592
 593 dnl
 594 dnl Does any necessary configuration of the testsuite directory.  Generates
 595 dnl the testsuite_hooks.h header.
 596 dnl
 597 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 598 dnl
 599 dnl Sets:
 600 dnl  enable_abi_check / GLIBCXX_TEST_ABI
 601 dnl Substs:
 602 dnl  baseline_dir
 603 dnl
 604 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
 605   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes; then
 606     # Do checks for resource limit functions.
 607     GLIBCXX_CHECK_SETRLIMIT
 608
 609     # Look for setenv, so that extended locale tests can be performed.
 610     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 611
 612     if test $enable_symvers = no; then
 613       enable_abi_check=no
 614     else
 615       case "$host" in
 616         *-*-cygwin*)
 617           enable_abi_check=no ;;
 618         *)
 619           enable_abi_check=yes ;;
 620       esac
 621     fi
 622   else
 623     # Only build this as native, since automake does not understand
 624     # CXX_FOR_BUILD.
 625     enable_abi_check=no
 626   fi
 627
 628   # Export file names for ABI checking.
 629   baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
 630   AC_SUBST(baseline_dir)
 631
 632   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
 633   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
 634 ])
 635
 636
 637 dnl
 638 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 639 dnl
 640 dnl Substs:
 641 dnl  GLIBCXX_INCLUDES
 642 dnl  TOPLEVEL_INCLUDES
 643 dnl
 644 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
 645   # Used for every C++ compile we perform.
 646   GLIBCXX_INCLUDES="\
 647 -I$glibcxx_builddir/include/$host_alias \
 648 -I$glibcxx_builddir/include \
 649 -I$glibcxx_srcdir/libsupc++"
 650
 651   # For Canadian crosses, pick this up too.
 652   if test $CANADIAN = yes; then
 653     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 654   fi
 655
 656   # Stuff in the actual top level.  Currently only used by libsupc++ to
 657   # get unwind* headers from the gcc dir.
 658   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 659   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 660
 661   # Now, export this to all the little Makefiles....
 662   AC_SUBST(GLIBCXX_INCLUDES)
 663   AC_SUBST(TOPLEVEL_INCLUDES)
 664 ])
 665
 666
 667 dnl
 668 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 669 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 670 dnl
 671 dnl Substs:
 672 dnl  OPTIMIZE_CXXFLAGS
 673 dnl  WARN_FLAGS
 674 dnl
 675 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
 676   # Optimization flags that are probably a good idea for thrill-seekers. Just
 677   # uncomment the lines below and make, everything else is ready to go...
 678   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 679   OPTIMIZE_CXXFLAGS=
 680   AC_SUBST(OPTIMIZE_CXXFLAGS)
 681
 682   WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
 683   AC_SUBST(WARN_FLAGS)
 684 ])
 685
 686
 687 dnl
 688 dnl All installation directory information is determined here.
 689 dnl
 690 dnl Substs:
 691 dnl  gxx_install_dir
 692 dnl  glibcxx_prefixdir
 693 dnl  glibcxx_toolexecdir
 694 dnl  glibcxx_toolexeclibdir
 695 dnl
 696 dnl Assumes cross_compiling bits already done, and with_cross_host in
 697 dnl particular.
 698 dnl
 699 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
 700   glibcxx_toolexecdir=no
 701   glibcxx_toolexeclibdir=no
 702   glibcxx_prefixdir=$prefix
 703
 704   AC_MSG_CHECKING([for gxx-include-dir])
 705   AC_ARG_WITH([gxx-include-dir],
 706     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 707                    [installation directory for include files]),
 708     [case "$withval" in
 709       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 710       no)  gxx_include_dir=no ;;
 711       *)   gxx_include_dir=$withval ;;
 712      esac],
 713     [gxx_include_dir=no])
 714   AC_MSG_RESULT($gxx_include_dir)
 715
 716   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 717   AC_ARG_ENABLE([version-specific-runtime-libs],
 718     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 719                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 720     [case "$enableval" in
 721       yes) version_specific_libs=yes ;;
 722       no)  version_specific_libs=no ;;
 723       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 724      esac],
 725     [version_specific_libs=no])
 726   AC_MSG_RESULT($version_specific_libs)
 727
 728   # Default case for install directory for include files.
 729   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 730     gxx_include_dir='${prefix}'/include/c++/${gcc_version}
 731   fi
 732
 733   # Version-specific runtime libs processing.
 734   if test $version_specific_libs = yes; then
 735     # Need the gcc compiler version to know where to install libraries
 736     # and header files if --enable-version-specific-runtime-libs option
 737     # is selected.  FIXME: these variables are misnamed, there are
 738     # no executables installed in _toolexecdir or _toolexeclibdir.
 739     if test x"$gxx_include_dir" = x"no"; then
 740       gxx_include_dir='${libdir}/gcc/${host_alias}/'$gcc_version/include/c++
 741     fi
 742     glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 743     glibcxx_toolexeclibdir='${toolexecdir}/'$gcc_version'$(MULTISUBDIR)'
 744   fi
 745
 746   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 747   # Install a library built with a cross compiler in tooldir, not libdir.
 748   if test x"$glibcxx_toolexecdir" = x"no"; then
 749     if test -n "$with_cross_host" &&
 750        test x"$with_cross_host" != x"no"; then
 751       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 752       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 753     else
 754       glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 755       glibcxx_toolexeclibdir='${libdir}'
 756     fi
 757     multi_os_directory=`$CXX -print-multi-os-directory`
 758     case $multi_os_directory in
 759       .) ;; # Avoid trailing /.
 760       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 761     esac
 762   fi
 763
 764   AC_MSG_CHECKING([for install location])
 765   AC_MSG_RESULT($gxx_include_dir)
 766
 767   AC_SUBST(glibcxx_prefixdir)
 768   AC_SUBST(gxx_include_dir)
 769   AC_SUBST(glibcxx_toolexecdir)
 770   AC_SUBST(glibcxx_toolexeclibdir)
 771 ])
 772
 773
 774 dnl
 775 dnl GLIBCXX_ENABLE
 776 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 777 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 778 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 779 dnl
 780 dnl See docs/html/17_intro/configury.html#enable for documentation.
 781 dnl
 782 m4_define([GLIBCXX_ENABLE],[dnl
 783 m4_define([_g_switch],[--enable-$1])dnl
 784 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 785  AC_ARG_ENABLE($1,_g_help,
 786   m4_bmatch([$5],
 787    [^permit ],
 788      [[
 789       case "$enableval" in
 790        m4_bpatsubst([$5],[permit ])) ;;
 791        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 792           dnl Idea for future:  generate a URL pointing to
 793           dnl "onlinedocs/configopts.html#whatever"
 794       esac
 795      ]],
 796    [^$],
 797      [[
 798       case "$enableval" in
 799        yes|no) ;;
 800        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 801       esac
 802      ]],
 803    [[$5]]),
 804   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 805 m4_undefine([_g_switch])dnl
 806 m4_undefine([_g_help])dnl
 807 ])
 808
 809
 810 dnl
 811 dnl Check for ISO/IEC 9899:1999 "C99" support.
 812 dnl
 813 dnl --enable-c99 defines _GLIBCXX_USE_C99
 814 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 815 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 816 dnl       Where DEFAULT is either `yes' or `no'.
 817 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 818 dnl
 819 AC_DEFUN([GLIBCXX_ENABLE_C99], [
 820   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 821
 822   AC_LANG_SAVE
 823   AC_LANG_CPLUSPLUS
 824
 825   # Check for the existence of <math.h> functions used if C99 is enabled.
 826   ac_c99_math=yes;
 827   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 828   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
 829   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
 830   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
 831   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
 832   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
 833   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
 834   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
 835   AC_TRY_COMPILE([#include <math.h>],
 836                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
 837   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
 838   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
 839   AC_TRY_COMPILE([#include <math.h>],
 840                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
 841   AC_TRY_COMPILE([#include <math.h>],
 842                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
 843   AC_MSG_RESULT($ac_c99_math)
 844
 845   if test x"$ac_c99_math" = x"yes"; then
 846     AC_DEFINE(_GLIBCXX_USE_C99_MATH)
 847   fi
 848
 849   # Check for the existence in <stdio.h> of vscanf, et. al.
 850   ac_c99_stdio=yes;
 851   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 852   AC_TRY_COMPILE([#include <stdio.h>],
 853                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
 854   AC_TRY_COMPILE([#include <stdio.h>
 855                   #include <stdarg.h>
 856                   void foo(char* fmt, ...)
 857                   {va_list args; va_start(args, fmt);
 858                   vfscanf(stderr, "%i", args);}],
 859                   [],, [ac_c99_stdio=no])
 860   AC_TRY_COMPILE([#include <stdio.h>
 861                   #include <stdarg.h>
 862                   void foo(char* fmt, ...)
 863                   {va_list args; va_start(args, fmt);
 864                   vscanf("%i", args);}],
 865                   [],, [ac_c99_stdio=no])
 866   AC_TRY_COMPILE([#include <stdio.h>
 867                   #include <stdarg.h>
 868                   void foo(char* fmt, ...)
 869                   {va_list args; va_start(args, fmt);
 870                   vsnprintf(fmt, 0, "%i", args);}],
 871                   [],, [ac_c99_stdio=no])
 872   AC_TRY_COMPILE([#include <stdio.h>
 873                   #include <stdarg.h>
 874                   void foo(char* fmt, ...)
 875                   {va_list args; va_start(args, fmt);
 876                   vsscanf(fmt, "%i", args);}],
 877                   [],, [ac_c99_stdio=no])
 878   AC_MSG_RESULT($ac_c99_stdio)
 879
 880   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 881   ac_c99_stdlib=yes;
 882   AC_MSG_CHECKING([for lldiv_t declaration])
 883   AC_CACHE_VAL(ac_c99_lldiv_t, [
 884   AC_TRY_COMPILE([#include <stdlib.h>],
 885                    [ lldiv_t mydivt;],
 886                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
 887   ])
 888   AC_MSG_RESULT($ac_c99_lldiv_t)
 889
 890   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 891   AC_TRY_COMPILE([#include <stdlib.h>],
 892                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
 893   AC_TRY_COMPILE([#include <stdlib.h>],
 894                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
 895   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
 896   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
 897   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
 898   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
 899   if test x"$ac_c99_lldiv_t" = x"no"; then
 900     ac_c99_stdlib=no;
 901   fi;
 902   AC_MSG_RESULT($ac_c99_stdlib)
 903
 904   # Check for the existence of <wchar.h> functions used if C99 is enabled.
 905   # XXX the wchar.h checks should be rolled into the general C99 bits.
 906   ac_c99_wchar=yes;
 907   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
 908   AC_TRY_COMPILE([#include <wchar.h>],
 909                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
 910   AC_TRY_COMPILE([#include <wchar.h>],
 911                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
 912   AC_TRY_COMPILE([#include <wchar.h>],
 913                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
 914   AC_MSG_RESULT($ac_c99_wchar)
 915
 916   AC_MSG_CHECKING([for enabled ISO C99 support])
 917   if test x"$ac_c99_math" = x"no" ||
 918      test x"$ac_c99_stdio" = x"no" ||
 919      test x"$ac_c99_stdlib" = x"no" ||
 920      test x"$ac_c99_wchar" = x"no"; then
 921     enable_c99=no;
 922   fi;
 923   AC_MSG_RESULT($enable_c99)
 924
 925   if test x"$ac_99_math" = x"yes"; then
 926     AC_DEFINE(_GLIBCXX_USE_C99_MATH)
 927   fi
 928
 929   # Option parsed, now set things appropriately
 930   if test x"$enable_c99" = x"yes"; then
 931     AC_DEFINE(_GLIBCXX_USE_C99)
 932   fi
 933
 934   AC_LANG_RESTORE
 935 ])
 936
 937
 938 dnl
 939 dnl Check for what type of C headers to use.
 940 dnl
 941 dnl --enable-cheaders= [does stuff].
 942 dnl --disable-cheaders [does not do anything, really].
 943 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
 944 dnl       Where DEFAULT is either `c' or `c_std'.
 945 dnl
 946 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
 947   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
 948     [construct "C" headers for g++], [permit c|c_std])
 949   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
 950
 951   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
 952
 953   AC_SUBST(C_INCLUDE_DIR)
 954   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
 955   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
 956   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
 957 ])
 958
 959
 960 dnl
 961 dnl Check for which locale library to use.  The choice is mapped to
 962 dnl a subdirectory of config/locale.
 963 dnl
 964 dnl Default is generic.
 965 dnl
 966 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
 967   AC_MSG_CHECKING([for C locale to use])
 968   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
 969     [use MODEL for target locale package],
 970     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
 971
 972   # If they didn't use this option switch, or if they specified --enable
 973   # with no specific model, we'll have to look for one.  If they
 974   # specified --disable (???), do likewise.
 975   if test $enable_clocale = no || test $enable_clocale = yes; then
 976      enable_clocale=auto
 977   fi
 978
 979   # Either a known package, or "auto"
 980   enable_clocale_flag=$enable_clocale
 981
 982   # Probe for locale support if no specific model is specified.
 983   # Default to "generic".
 984   if test $enable_clocale_flag = auto; then
 985     case ${target_os} in
 986       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
 987         AC_EGREP_CPP([_GLIBCXX_ok], [
 988         #include <features.h>
 989         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
 990           _GLIBCXX_ok
 991         #endif
 992         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
 993
 994         # Test for bugs early in glibc-2.2.x series
 995           if test $enable_clocale_flag = gnu; then
 996           AC_TRY_RUN([
 997           #define _GNU_SOURCE 1
 998           #include <locale.h>
 999           #include <string.h>
1000           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1001           extern __typeof(newlocale) __newlocale;
1002           extern __typeof(duplocale) __duplocale;
1003           extern __typeof(strcoll_l) __strcoll_l;
1004           #endif
1005           int main()
1006           {
1007               const char __one[] = "Äuglein Augmen";
1008               const char __two[] = "Äuglein";
1009               int i;
1010               int j;
1011               __locale_t        loc;
1012                __locale_t        loc_dup;
1013               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1014               loc_dup = __duplocale(loc);
1015               i = __strcoll_l(__one, __two, loc);
1016               j = __strcoll_l(__one, __two, loc_dup);
1017               return 0;
1018           }
1019           ],
1020           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1021           [enable_clocale_flag=generic])
1022           fi
1023
1024         # ... at some point put __strxfrm_l tests in as well.
1025         ;;
1026       *)
1027         enable_clocale_flag=generic
1028         ;;
1029     esac
1030   fi
1031
1032   # Deal with gettext issues.  Default to not using it (=no) until we detect
1033   # support for it later.  Let the user turn it off via --e/d, but let that
1034   # default to on for easier handling.
1035   USE_NLS=no
1036   AC_ARG_ENABLE(nls,
1037     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1038     [],
1039     [enable_nls=yes])
1040
1041   # Set configure bits for specified locale package
1042   case ${enable_clocale_flag} in
1043     generic)
1044       AC_MSG_RESULT(generic)
1045
1046       CLOCALE_H=config/locale/generic/c_locale.h
1047       CLOCALE_CC=config/locale/generic/c_locale.cc
1048       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1049       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1050       CCOLLATE_CC=config/locale/generic/collate_members.cc
1051       CCTYPE_CC=config/locale/generic/ctype_members.cc
1052       CMESSAGES_H=config/locale/generic/messages_members.h
1053       CMESSAGES_CC=config/locale/generic/messages_members.cc
1054       CMONEY_CC=config/locale/generic/monetary_members.cc
1055       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1056       CTIME_H=config/locale/generic/time_members.h
1057       CTIME_CC=config/locale/generic/time_members.cc
1058       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1059       ;;
1060     gnu)
1061       AC_MSG_RESULT(gnu)
1062
1063       # Declare intention to use gettext, and add support for specific
1064       # languages.
1065       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1066       ALL_LINGUAS="de fr"
1067
1068       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1069       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1070       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1071         USE_NLS=yes
1072       fi
1073       # Export the build objects.
1074       for ling in $ALL_LINGUAS; do \
1075         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1076         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1077       done
1078       AC_SUBST(glibcxx_MOFILES)
1079       AC_SUBST(glibcxx_POFILES)
1080
1081       CLOCALE_H=config/locale/gnu/c_locale.h
1082       CLOCALE_CC=config/locale/gnu/c_locale.cc
1083       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1084       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1085       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1086       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1087       CMESSAGES_H=config/locale/gnu/messages_members.h
1088       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1089       CMONEY_CC=config/locale/gnu/monetary_members.cc
1090       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1091       CTIME_H=config/locale/gnu/time_members.h
1092       CTIME_CC=config/locale/gnu/time_members.cc
1093       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1094       ;;
1095     ieee_1003.1-2001)
1096       AC_MSG_RESULT(IEEE 1003.1)
1097
1098       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1099       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1100       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1101       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1102       CCOLLATE_CC=config/locale/generic/collate_members.cc
1103       CCTYPE_CC=config/locale/generic/ctype_members.cc
1104       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1105       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1106       CMONEY_CC=config/locale/generic/monetary_members.cc
1107       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1108       CTIME_H=config/locale/generic/time_members.h
1109       CTIME_CC=config/locale/generic/time_members.cc
1110       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1111       ;;
1112   esac
1113
1114   # This is where the testsuite looks for locale catalogs, using the
1115   # -DLOCALEDIR define during testsuite compilation.
1116   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1117   AC_SUBST(glibcxx_localedir)
1118
1119   # A standalone libintl (e.g., GNU libintl) may be in use.
1120   if test $USE_NLS = yes; then
1121     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1122     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1123   fi
1124   if test $USE_NLS = yes; then
1125     AC_DEFINE(_GLIBCXX_USE_NLS)
1126   fi
1127
1128   AC_SUBST(USE_NLS)
1129   AC_SUBST(CLOCALE_H)
1130   AC_SUBST(CCODECVT_H)
1131   AC_SUBST(CMESSAGES_H)
1132   AC_SUBST(CCODECVT_CC)
1133   AC_SUBST(CCOLLATE_CC)
1134   AC_SUBST(CCTYPE_CC)
1135   AC_SUBST(CMESSAGES_CC)
1136   AC_SUBST(CMONEY_CC)
1137   AC_SUBST(CNUMERIC_CC)
1138   AC_SUBST(CTIME_H)
1139   AC_SUBST(CTIME_CC)
1140   AC_SUBST(CLOCALE_CC)
1141   AC_SUBST(CLOCALE_INTERNAL_H)
1142 ])
1143
1144
1145 dnl
1146 dnl Check for which std::allocator base class to use.  The choice is
1147 dnl mapped from a subdirectory of include/ext.
1148 dnl
1149 dnl Default is new.
1150 dnl
1151 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
1152   AC_MSG_CHECKING([for std::allocator base class to use])
1153   GLIBCXX_ENABLE(libstdcxx-allocator,auto,[=KIND],
1154     [use KIND for target std::allocator base],
1155     [permit new|malloc|mt|bitmap|pool|yes|no|auto])
1156
1157   # If they didn't use this option switch, or if they specified --enable
1158   # with no specific model, we'll have to look for one.  If they
1159   # specified --disable (???), do likewise.
1160   if test $enable_libstdcxx_allocator = no ||
1161      test $enable_libstdcxx_allocator = yes;
1162   then
1163      enable_libstdcxx_allocator=auto
1164   fi
1165
1166   # Either a known package, or "auto". Auto implies the default choice
1167   # for a particular platform.
1168   enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
1169
1170   # Probe for host-specific support if no specific model is specified.
1171   # Default to "new".
1172   if test $enable_libstdcxx_allocator_flag = auto; then
1173     case ${target_os} in
1174       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1175         enable_libstdcxx_allocator_flag=mt
1176         ;;
1177       *)
1178         enable_libstdcxx_allocator_flag=new
1179         ;;
1180     esac
1181   fi
1182   AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
1183
1184
1185   # Set configure bits for specified locale package
1186   case ${enable_libstdcxx_allocator_flag} in
1187     bitmap)
1188       ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
1189       ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
1190       ;;
1191     malloc)
1192       ALLOCATOR_H=config/allocator/malloc_allocator_base.h
1193       ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
1194       ;;
1195     mt)
1196       ALLOCATOR_H=config/allocator/mt_allocator_base.h
1197       ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
1198       ;;
1199     new)
1200       ALLOCATOR_H=config/allocator/new_allocator_base.h
1201       ALLOCATOR_NAME=__gnu_cxx::new_allocator
1202       ;;
1203     pool)
1204       ALLOCATOR_H=config/allocator/pool_allocator_base.h
1205       ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
1206       ;;
1207   esac
1208
1209   AC_SUBST(ALLOCATOR_H)
1210   AC_SUBST(ALLOCATOR_NAME)
1211 ])
1212
1213
1214 dnl
1215 dnl Check for whether the Boost-derived checks should be turned on.
1216 dnl
1217 dnl --enable-concept-checks turns them on.
1218 dnl --disable-concept-checks leaves them off.
1219 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1220 dnl       Where DEFAULT is either `yes' or `no'.
1221 dnl
1222 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
1223   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1224   if test $enable_concept_checks = yes; then
1225     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1226   fi
1227 ])
1228
1229
1230 dnl
1231 dnl Check for which I/O library to use:  stdio, or something specific.
1232 dnl
1233 dnl Default is stdio.
1234 dnl
1235 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
1236   AC_MSG_CHECKING([for underlying I/O to use])
1237   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1238     [use target-specific I/O package], [permit stdio])
1239
1240   # Now that libio has been removed, you can have any color you want as long
1241   # as it's black.  This is one big no-op until other packages are added, but
1242   # showing the framework never hurts.
1243   case ${enable_cstdio} in
1244     stdio)
1245       CSTDIO_H=config/io/c_io_stdio.h
1246       BASIC_FILE_H=config/io/basic_file_stdio.h
1247       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1248       AC_MSG_RESULT(stdio)
1249       ;;
1250   esac
1251
1252   AC_SUBST(CSTDIO_H)
1253   AC_SUBST(BASIC_FILE_H)
1254   AC_SUBST(BASIC_FILE_CC)
1255 ])
1256
1257
1258 dnl
1259 dnl Check for "unusual" flags to pass to the compiler while building.
1260 dnl
1261 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1262 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1263 dnl --disable-cxx-flags passes nothing.
1264 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1265 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1266 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1267 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1268 dnl       If "default flags" is an empty string, the effect is the same
1269 dnl       as --disable or --enable=no.
1270 dnl
1271 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
1272   AC_MSG_CHECKING([for extra compiler flags for building])
1273   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1274     [pass compiler FLAGS when building library],
1275     [case "x$enable_cxx_flags" in
1276       xno | x)   enable_cxx_flags= ;;
1277       x-*)       ;;
1278       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1279      esac])
1280
1281   # Run through flags (either default or command-line) and set anything
1282   # extra (e.g., #defines) that must accompany particular g++ options.
1283   if test -n "$enable_cxx_flags"; then
1284     for f in $enable_cxx_flags; do
1285       case "$f" in
1286         -fhonor-std)  ;;
1287         -*)  ;;
1288         *)   # and we're trying to pass /what/ exactly?
1289              AC_MSG_ERROR([compiler flags start with a -]) ;;
1290       esac
1291     done
1292   fi
1293
1294   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1295   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1296   AC_SUBST(EXTRA_CXX_FLAGS)
1297 ])
1298
1299
1300 dnl
1301 dnl Check for wide character support.  Has the same effect as the option
1302 dnl in gcc's configure, but in a form that autoconf can mess with.
1303 dnl
1304 dnl --enable-c-mbchar requests all the wchar_t stuff.
1305 dnl --disable-c-mbchar doesn't.
1306 dnl  +  Usage:  GLIBCXX_ENABLE_C_MBCHAR[(DEFAULT)]
1307 dnl       Where DEFAULT is either `yes' or `no'.
1308 dnl
1309 AC_DEFUN([GLIBCXX_ENABLE_C_MBCHAR], [
1310   GLIBCXX_ENABLE(c-mbchar,$1,,[enable multibyte (wide) characters])
1311   # Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1312 ])
1313
1314
1315 dnl
1316 dnl Check to see if debugging libraries are to be built.
1317 dnl
1318 dnl --enable-libstdcxx-debug
1319 dnl builds a separate set of debugging libraries in addition to the
1320 dnl normal (shared, static) libstdc++ binaries.
1321 dnl
1322 dnl --disable-libstdcxx-debug
1323 dnl builds only one (non-debug) version of libstdc++.
1324 dnl
1325 dnl --enable-libstdcxx-debug-flags=FLAGS
1326 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1327 dnl
1328 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1329 dnl       Where DEFAULT is either `yes' or `no'.
1330 dnl
1331 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
1332   AC_MSG_CHECKING([for additional debug build])
1333   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1334   AC_MSG_RESULT($enable_libstdcxx_debug)
1335   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1336 ])
1337
1338
1339 dnl
1340 dnl Check for explicit debug flags.
1341 dnl
1342 dnl --enable-libstdcxx-debug-flags='-O1'
1343 dnl is a general method for passing flags to be used when
1344 dnl building debug libraries with --enable-debug.
1345 dnl
1346 dnl --disable-libstdcxx-debug-flags does nothing.
1347 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1348 dnl       If "default flags" is an empty string, the effect is the same
1349 dnl       as --disable or --enable=no.
1350 dnl
1351 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
1352   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1353     [pass compiler FLAGS when building debug library],
1354     [case "x$enable_libstdcxx_debug_flags" in
1355       xno | x)    enable_libstdcxx_debug_flags= ;;
1356       x-*)        ;;
1357       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1358      esac])
1359
1360   # Option parsed, now set things appropriately
1361   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1362   AC_SUBST(DEBUG_FLAGS)
1363
1364   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1365 ])
1366
1367
1368 dnl
1369 dnl Check if the user only wants a freestanding library implementation.
1370 dnl
1371 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1372 dnl installing only the headers required by [17.4.1.3] and the language
1373 dnl support library.  More than that will be built (to keep the Makefiles
1374 dnl conveniently clean), but not installed.
1375 dnl
1376 dnl Sets:
1377 dnl  is_hosted  (yes/no)
1378 dnl
1379 dnl Defines:
1380 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1381 dnl
1382 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
1383   AC_ARG_ENABLE([hosted-libstdcxx],
1384     AC_HELP_STRING([--disable-hosted-libstdcxx],
1385                    [only build freestanding C++ runtime support]),,
1386     [case "$host" in
1387         arm*-*-symbianelf*)
1388             enable_hosted_libstdcxx=no
1389             ;;
1390         *)
1391             enable_hosted_libstdcxx=yes
1392             ;;
1393      esac])
1394   if test "$enable_hosted_libstdcxx" = no; then
1395     AC_MSG_NOTICE([Only freestanding libraries will be built])
1396     is_hosted=no
1397     hosted_define=0
1398     enable_abi_check=no
1399     enable_libstdcxx_pch=no
1400   else
1401     is_hosted=yes
1402     hosted_define=1
1403   fi
1404   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1405   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1406     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1407 ])
1408
1409
1410 dnl
1411 dnl Check for template specializations for the 'long long' type extension.
1412 dnl The result determines only whether 'long long' I/O is enabled; things
1413 dnl like numeric_limits<> specializations are always available.
1414 dnl
1415 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1416 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1417 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1418 dnl       Where DEFAULT is either `yes' or `no'.
1419 dnl
1420 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
1421   GLIBCXX_ENABLE(long-long,$1,,[enables I/O support for 'long long'])
1422   if test $enable_long_long = yes; then
1423     AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1424   fi
1425 ])
1426
1427
1428 dnl
1429 dnl Check to see if building and using a C++ precompiled header can be done.
1430 dnl
1431 dnl --enable-libstdcxx-pch=yes
1432 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1433 dnl may work, after some light-hearted attempts to puzzle out compiler
1434 dnl support, flip bits on in include/Makefile.am
1435 dnl
1436 dnl --disable-libstdcxx-pch
1437 dnl turns off attempts to use or build stdc++.h.gch.
1438 dnl
1439 dnl Substs:
1440 dnl  glibcxx_PCHFLAGS
1441 dnl
1442 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
1443   AC_MSG_CHECKING([for enabled PCH])
1444   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1445   AC_MSG_RESULT([$enable_libstdcxx_pch])
1446
1447   if test $enable_libstdcxx_pch = yes; then
1448     AC_CACHE_CHECK([for compiler with PCH support],
1449       [glibcxx_cv_prog_CXX_pch],
1450       [ac_save_CXXFLAGS="$CXXFLAGS"
1451        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1452        AC_LANG_SAVE
1453        AC_LANG_CPLUSPLUS
1454        echo '#include <math.h>' > conftest.h
1455        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1456                           -o conftest.h.gch 1>&5 2>&1 &&
1457                 echo '#error "pch failed"' > conftest.h &&
1458           echo '#include "conftest.h"' > conftest.cc &&
1459                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1460        then
1461          glibcxx_cv_prog_CXX_pch=yes
1462        else
1463          glibcxx_cv_prog_CXX_pch=no
1464        fi
1465        rm -f conftest*
1466        CXXFLAGS=$ac_save_CXXFLAGS
1467        AC_LANG_RESTORE
1468       ])
1469     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1470   fi
1471
1472   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1473   if test $enable_libstdcxx_pch = yes; then
1474     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1475   else
1476     glibcxx_PCHFLAGS=""
1477   fi
1478   AC_SUBST(glibcxx_PCHFLAGS)
1479 ])
1480
1481
1482 dnl
1483 dnl Check for exception handling support.  If an explicit enable/disable
1484 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1485 dnl target may or may not support call frame exceptions.
1486 dnl
1487 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1488 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1489 dnl Neither one forces an attempt at detection.
1490 dnl
1491 dnl Defines:
1492 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1493 dnl
1494 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
1495   AC_MSG_CHECKING([for exception model to use])
1496   AC_LANG_SAVE
1497   AC_LANG_CPLUSPLUS
1498   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1499     [force use of builtin_setjmp for exceptions],
1500     [permit yes|no|auto])
1501
1502   if test $enable_sjlj_exceptions = auto; then
1503     # Botheration.  Now we've got to detect the exception model.  Link tests
1504     # against libgcc.a are problematic since we've not been given proper -L
1505     # bits for single-tree newlib and libgloss.
1506     #
1507     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1508     cat > conftest.$ac_ext << EOF
1509 [#]line __oline__ "configure"
1510 struct S { ~S(); };
1511 void bar();
1512 void foo()
1513 {
1514   S s;
1515   bar();
1516 }
1517 EOF
1518     old_CXXFLAGS="$CXXFLAGS"
1519     CXXFLAGS=-S
1520     if AC_TRY_EVAL(ac_compile); then
1521       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1522         enable_sjlj_exceptions=yes
1523       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1524         enable_sjlj_exceptions=no
1525       fi
1526     fi
1527     CXXFLAGS="$old_CXXFLAGS"
1528     rm -f conftest*
1529   fi
1530
1531   # This is a tad weird, for hysterical raisins.  We have to map enable/disable
1532   # to two different models.
1533   case $enable_sjlj_exceptions in
1534     yes)
1535       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1536         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1537       ac_exception_model_name=sjlj
1538       ;;
1539     no)
1540       ac_exception_model_name="call frame"
1541       ;;
1542     *)
1543       AC_MSG_ERROR([unable to detect exception model])
1544       ;;
1545   esac
1546  AC_LANG_RESTORE
1547  AC_MSG_RESULT($ac_exception_model_name)
1548 ])
1549
1550
1551 dnl
1552 dnl Add version tags to symbols in shared library (or not), additionally
1553 dnl marking other symbols as private/local (or not).
1554 dnl
1555 dnl --enable-symvers=style adds a version script to the linker call when
1556 dnl       creating the shared library.  The choice of version script is
1557 dnl       controlled by 'style'.
1558 dnl --disable-symvers does not.
1559 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1560 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1561 dnl       choose a default style based on linker characteristics.  Passing
1562 dnl       'no' disables versioning.
1563 dnl
1564 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
1565
1566 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1567   [enables symbol versioning of the shared library],
1568   [permit yes|no|gnu])
1569
1570 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1571 # don't know enough about $LD to do tricks...
1572 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1573 # FIXME  The following test is too strict, in theory.
1574 if test $enable_shared = no ||
1575         test "x$LD" = x ||
1576         test x$glibcxx_gnu_ld_version = x; then
1577   enable_symvers=no
1578 fi
1579
1580 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1581 if test $enable_symvers != no; then
1582   AC_MSG_CHECKING([for shared libgcc])
1583   ac_save_CFLAGS="$CFLAGS"
1584   CFLAGS=' -lgcc_s'
1585   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1586   CFLAGS="$ac_save_CFLAGS"
1587   if test $glibcxx_shared_libgcc = no; then
1588     cat > conftest.c <<EOF
1589 int main (void) { return 0; }
1590 EOF
1591 changequote(,)dnl
1592     glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1593                              -shared -shared-libgcc -o conftest.so \
1594                              conftest.c -v 2>&1 >/dev/null \
1595                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
1596 changequote([,])dnl
1597     rm -f conftest.c conftest.so
1598     if test x${glibcxx_libgcc_s_suffix+set} = xset; then
1599       CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
1600       AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
1601       CFLAGS="$ac_save_CFLAGS"
1602     fi
1603   fi
1604   AC_MSG_RESULT($glibcxx_shared_libgcc)
1605 fi
1606
1607 # For GNU ld, we need at least this version.  The format is described in
1608 # GLIBCXX_CHECK_LINKER_FEATURES above.
1609 glibcxx_min_gnu_ld_version=21400
1610 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1611
1612 # Check to see if unspecified "yes" value can win, given results above.
1613 # Change "yes" into either "no" or a style name.
1614 if test $enable_symvers = yes; then
1615   if test $with_gnu_ld = yes &&
1616      test $glibcxx_shared_libgcc = yes;
1617   then
1618     if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1619       enable_symvers=gnu
1620     else
1621       # The right tools, the right setup, but too old.  Fallbacks?
1622       AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1623       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1624       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1625       AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1626       if test $glibcxx_gnu_ld_version -ge 21200 ; then
1627         # Globbing fix is present, proper block support is not.
1628         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
1629         dnl enable_symvers=???
1630         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1631         enable_symvers=no
1632       else
1633         # 2.11 or older.
1634         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1635         enable_symvers=no
1636       fi
1637     fi
1638   else
1639     # just fail for now
1640     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1641     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1642     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1643     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1644     enable_symvers=no
1645   fi
1646 fi
1647
1648 # Everything parsed; figure out what file to use.
1649 case $enable_symvers in
1650   no)
1651     SYMVER_MAP=config/linker-map.dummy
1652     ;;
1653   gnu)
1654     SYMVER_MAP=config/linker-map.gnu
1655     AC_DEFINE(_GLIBCXX_SYMVER)
1656     ;;
1657 esac
1658
1659 AC_SUBST(SYMVER_MAP)
1660 AC_SUBST(port_specific_symbol_files)
1661 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1662 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1663 ])
1664
1665
1666 dnl
1667 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1668 dnl We must stage the required headers so that they will be installed
1669 dnl with the library (unlike libgcc, the STL implementation is provided
1670 dnl solely within headers).  Since we must not inject random user-space
1671 dnl macro names into user-provided C++ code, we first stage into <file>-in
1672 dnl and process to <file> with an output command.  The reason for a two-
1673 dnl stage process here is to correctly handle $srcdir!=$objdir without
1674 dnl having to write complex code (the sed commands to clean the macro
1675 dnl namespace are complex and fragile enough as it is).  We must also
1676 dnl add a relative path so that -I- is supported properly.
1677 dnl
1678 dnl Substs:
1679 dnl  glibcxx_thread_h
1680 dnl
1681 dnl Defines:
1682 dnl  HAVE_GTHR_DEFAULT
1683 dnl
1684 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
1685   AC_MSG_CHECKING([for thread model used by GCC])
1686   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1687   AC_MSG_RESULT([$target_thread_file])
1688
1689   if test $target_thread_file != single; then
1690     AC_DEFINE(HAVE_GTHR_DEFAULT)
1691   fi
1692
1693   glibcxx_thread_h=gthr-$target_thread_file.h
1694   AC_SUBST(glibcxx_thread_h)
1695 ])
1696
1697
1698 # Check whether LC_MESSAGES is available in <locale.h>.
1699 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1700 #
1701 # This file file be copied and used freely without restrictions.  It can
1702 # be used in projects which are not available under the GNU Public License
1703 # but which still want to provide support for the GNU gettext functionality.
1704 # Please note that the actual code is *not* freely available.
1705
1706 # serial 1
1707 AC_DEFUN([AC_LC_MESSAGES], [
1708   AC_CHECK_HEADER(locale.h, [
1709     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1710       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1711        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1712     if test $ac_cv_val_LC_MESSAGES = yes; then
1713       AC_DEFINE(HAVE_LC_MESSAGES)
1714     fi
1715   ])
1716 ])
1717
1718
1719 sinclude([../libtool.m4])
1720 dnl The lines below arrange for aclocal not to bring an installed
1721 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1722 dnl add a definition of LIBTOOL to Makefile.in.
1723 ifelse(,,,[AC_SUBST(LIBTOOL)
1724 AC_DEFUN([AM_PROG_LIBTOOL])
1725 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1726 AC_DEFUN([AC_PROG_LD])
1727 ])
1728
1729 dnl vim:et:ts=2:sw=2