libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN([GLIBCXX_CHECK_HOST], [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
  27   AC_MSG_NOTICE([OS config directory is $os_include_dir])
  28 ])
  29
  30 dnl
  31 dnl Initialize the rest of the library configury.  At this point we have
  32 dnl variables like $host.
  33 dnl
  34 dnl Sets:
  35 dnl  SUBDIRS
  36 dnl Substs:
  37 dnl  glibcxx_builddir     (absolute path)
  38 dnl  glibcxx_srcdir       (absolute path)
  39 dnl  toplevel_srcdir      (absolute path)
  40 dnl  with_cross_host
  41 dnl  with_newlib
  42 dnl  with_target_subdir
  43 dnl plus
  44 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  45 dnl  - default settings for all AM_CONFITIONAL test variables
  46 dnl  - lots of tools, like CC and CXX
  47 dnl
  48 AC_DEFUN([GLIBCXX_CONFIGURE], [
  49   # Keep these sync'd with the list in Makefile.am.  The first provides an
  50   # expandable list at autoconf time; the second provides an expandable list
  51   # (i.e., shell variable) at configure time.
  52   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  53   SUBDIRS='glibcxx_SUBDIRS'
  54
  55   # These need to be absolute paths, yet at the same time need to
  56   # canonicalize only relative paths, because then amd will not unmount
  57   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  58   glibcxx_builddir=`${PWDCMD-pwd}`
  59   case $srcdir in
  60     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  61     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  62   esac
  63   toplevel_srcdir=${glibcxx_srcdir}/..
  64   AC_SUBST(glibcxx_builddir)
  65   AC_SUBST(glibcxx_srcdir)
  66   AC_SUBST(toplevel_srcdir)
  67
  68   # We use these options to decide which functions to include.  They are
  69   # set from the top level.
  70   AC_ARG_WITH([target-subdir],
  71     AC_HELP_STRING([--with-target-subdir=SUBDIR],
  72                    [configuring in a subdirectory]))
  73
  74   AC_ARG_WITH([cross-host],
  75     AC_HELP_STRING([--with-cross-host=HOST],
  76                    [configuring with a cross compiler]))
  77
  78   AC_ARG_WITH([newlib],
  79     AC_HELP_STRING([--with-newlib],
  80                    [assume newlib as a system C library]))
  81
  82   # We're almost certainly being configured before anything else which uses
  83   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
  84   # we not cache the value of CXX that we "discover" here, because it's set
  85   # to something unique for us and libjava.  Other target libraries need to
  86   # find CXX for themselves.  We yank the rug out from under the normal AC_*
  87   # process by sneakily renaming the cache variable.  This also lets us debug
  88   # the value of "our" CXX in postmortems.
  89   #
  90   # We must also force CXX to /not/ be a precious variable, otherwise the
  91   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
  92   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
  93   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
  94   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
  95   #
  96   # -fno-builtin must be present here so that a non-conflicting form of
  97   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  98
  99   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 100   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 101   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 102   save_CXXFLAGS="$CXXFLAGS"
 103   CXXFLAGS="$CXXFLAGS -fno-builtin"
 104   AC_PROG_CC
 105   AC_PROG_CXX
 106   CXXFLAGS="$save_CXXFLAGS"
 107   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 108   AC_SUBST(CFLAGS)
 109   AC_SUBST(CXXFLAGS)
 110
 111   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 112   # available).  Uncomment the next line to force a particular method.
 113   AC_PROG_LN_S
 114   #LN_S='cp -p'
 115
 116   AC_CHECK_TOOL(AS, as)
 117   AC_CHECK_TOOL(AR, ar)
 118   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 119
 120   AM_MAINTAINER_MODE
 121
 122   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 123   # which are themselves conditionally expanded.
 124   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 125   ## other macros from doing the same.  This should be automated.)  -pme
 126   need_libmath=no
 127
 128   # Check for uClibc since Linux platforms use different configuration
 129   # directories depending on the C library in use.
 130   AC_EGREP_CPP([_using_uclibc], [
 131   #include <stdio.h>
 132   #if __UCLIBC__
 133     _using_uclibc
 134   #endif
 135   ], uclibc=yes, uclibc=no)
 136
 137   # Find platform-specific directories containing configuration info.
 138   # Also possibly modify flags used elsewhere, as needed by the platform.
 139   GLIBCXX_CHECK_HOST
 140 ])
 141
 142
 143 dnl
 144 dnl Tests for newer compiler features, or features that are present in newer
 145 dnl compiler versions but not older compiler versions still in use, should
 146 dnl be placed here.
 147 dnl
 148 dnl Defines:
 149 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 150 dnl   new inlining code or the new system_header pragma will die on -Werror.
 151 dnl   Leave it out by default and use maint-mode to use it.
 152 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 153 dnl   compiler supports it and the user has not requested debug mode.
 154 dnl
 155 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
 156   # All these tests are for C++; save the language and the compiler flags.
 157   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 158   # found in GLIBCXX_CONFIGURE.
 159   AC_LANG_SAVE
 160   AC_LANG_CPLUSPLUS
 161   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 162   ac_save_CXXFLAGS="$CXXFLAGS"
 163
 164   # Check for maintainer-mode bits.
 165   if test x"$USE_MAINTAINER_MODE" = xno; then
 166     WERROR=''
 167   else
 168     WERROR='-Werror'
 169   fi
 170
 171   # Check for -ffunction-sections -fdata-sections
 172   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 173   CXXFLAGS='-g -Werror -ffunction-sections -fdata-sections'
 174   AC_TRY_COMPILE([int foo; void bar() { };],, [ac_fdsections=yes], [ac_fdsections=no])
 175   if test "$ac_test_CXXFLAGS" = set; then
 176     CXXFLAGS="$ac_save_CXXFLAGS"
 177   else
 178     # this is the suspicious part
 179     CXXFLAGS=''
 180   fi
 181   if test x"$ac_fdsections" = x"yes"; then
 182     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 183   fi
 184   AC_MSG_RESULT($ac_fdsections)
 185
 186   AC_LANG_RESTORE
 187   AC_SUBST(WERROR)
 188   AC_SUBST(SECTION_FLAGS)
 189 ])
 190
 191
 192 dnl
 193 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 194 dnl the native linker is in use, all variables will be defined to something
 195 dnl safe (like an empty string).
 196 dnl
 197 dnl Defines:
 198 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 199 dnl  OPT_LDFLAGS='-Wl,-O1' and '-z,relro' if possible
 200 dnl  LD (as a side effect of testing)
 201 dnl Sets:
 202 dnl  with_gnu_ld
 203 dnl  glibcxx_gnu_ld_version (possibly)
 204 dnl
 205 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 206 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 207 dnl
 208 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
 209   # If we're not using GNU ld, then there's no point in even trying these
 210   # tests.  Check for that first.  We should have already tested for gld
 211   # by now (in libtool), but require it now just to be safe...
 212   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 213   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 214   AC_REQUIRE([AC_PROG_LD])
 215   AC_REQUIRE([AC_PROG_AWK])
 216
 217   # The name set by libtool depends on the version of libtool.  Shame on us
 218   # for depending on an impl detail, but c'est la vie.  Older versions used
 219   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 220   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 221   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 222   # set (hence we're using an older libtool), then set it.
 223   if test x${with_gnu_ld+set} != xset; then
 224     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 225       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 226       with_gnu_ld=no
 227     else
 228       with_gnu_ld=$ac_cv_prog_gnu_ld
 229     fi
 230   fi
 231
 232   # Start by getting the version number.  I think the libtool test already
 233   # does some of this, but throws away the result.
 234   if test x"$with_gnu_ld" = x"yes"; then
 235     AC_MSG_CHECKING([for ld version])
 236     changequote(,)
 237     ldver=`$LD --version 2>/dev/null | head -1 | \
 238            sed -e 's/GNU ld \(version \)\{0,1\}\(([^)]*) \)\{0,1\}\([0-9.][0-9.]*\).*/\3/'`
 239     changequote([,])
 240     glibcxx_gnu_ld_version=`echo $ldver | \
 241            $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 242     AC_MSG_RESULT($glibcxx_gnu_ld_version)
 243   fi
 244
 245   # Set --gc-sections.
 246   glibcxx_gcsections_min_ld=21602
 247   if test x"$with_gnu_ld" = x"yes" &&
 248         test $glibcxx_gnu_ld_version -gt $glibcxx_gcsections_min_ld ; then
 249
 250     # Sufficiently young GNU ld it is!  Joy and bunny rabbits!
 251     # NB: This flag only works reliably after 2.16.1. Configure tests
 252     # for this are difficult, so hard wire a value that should work.
 253
 254     ac_test_CFLAGS="${CFLAGS+set}"
 255     ac_save_CFLAGS="$CFLAGS"
 256     CFLAGS='-Wl,--gc-sections'
 257
 258     # Check for -Wl,--gc-sections
 259     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 260     AC_TRY_LINK([ int one(void) { return 1; }
 261      int two(void) { return 2; }
 262         ], [ two(); ] , [ac_gcsections=yes], [ac_gcsections=no])
 263     if test "$ac_gcsections" = "yes"; then
 264       rm -f conftest.c
 265       touch conftest.c
 266       if $CC -c conftest.c; then
 267         if $LD --gc-sections -o conftest conftest.o 2>&1 | \
 268            grep "Warning: gc-sections option ignored" > /dev/null; then
 269           ac_gcsections=no
 270         fi
 271       fi
 272       rm -f conftest.c conftest.o conftest
 273     fi
 274     if test "$ac_gcsections" = "yes"; then
 275       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 276     fi
 277     AC_MSG_RESULT($ac_gcsections)
 278
 279     if test "$ac_test_CFLAGS" = set; then
 280       CFLAGS="$ac_save_CFLAGS"
 281     else
 282       # this is the suspicious part
 283       CFLAGS=''
 284     fi
 285   fi
 286
 287   # Set -z,relro.
 288   # Note this is only for shared objects.
 289   ac_ld_relro=no
 290   if test x"$with_gnu_ld" = x"yes"; then
 291     AC_MSG_CHECKING([for ld that supports -Wl,-z,relro])
 292     cxx_z_relo=`$LD -v --help 2>/dev/null | grep "z relro"`
 293     if test -n "$cxx_z_relo"; then
 294       OPT_LDFLAGS="-Wl,-z,relro"
 295       ac_ld_relro=yes
 296     fi
 297     AC_MSG_RESULT($ac_ld_relro)
 298   fi
 299
 300   # Set linker optimization flags.
 301   if test x"$with_gnu_ld" = x"yes"; then
 302     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 303   fi
 304
 305   AC_SUBST(SECTION_LDFLAGS)
 306   AC_SUBST(OPT_LDFLAGS)
 307 ])
 308
 309
 310 dnl
 311 dnl Check for headers for, and arguments to, the setrlimit() function.
 312 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 313 dnl
 314 dnl Defines:
 315 dnl  _GLIBCXX_RES_LIMITS if we can set artificial resource limits
 316 dnl  various HAVE_LIMIT_* for individual limit names
 317 dnl
 318 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
 319   AC_MSG_CHECKING([for RLIMIT_$1])
 320   AC_TRY_COMPILE(
 321     [#include <unistd.h>
 322      #include <sys/time.h>
 323      #include <sys/resource.h>
 324     ],
 325     [ int f = RLIMIT_$1 ; ],
 326     [glibcxx_mresult=1], [glibcxx_mresult=0])
 327   AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
 328                      [Only used in build directory testsuite_hooks.h.])
 329   if test $glibcxx_mresult = 1 ; then res=yes ; else res=no ; fi
 330   AC_MSG_RESULT($res)
 331 ])
 332
 333 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
 334   setrlimit_have_headers=yes
 335   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 336                    [],
 337                    [setrlimit_have_headers=no])
 338   # If don't have the headers, then we can't run the tests now, and we
 339   # won't be seeing any of these during testsuite compilation.
 340   if test $setrlimit_have_headers = yes; then
 341     # Can't do these in a loop, else the resulting syntax is wrong.
 342     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 343     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 344     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 345     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 346     GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
 347
 348     # Check for rlimit, setrlimit.
 349     AC_CACHE_VAL(ac_setrlimit, [
 350       AC_TRY_COMPILE(
 351         [#include <unistd.h>
 352          #include <sys/time.h>
 353          #include <sys/resource.h>
 354         ],
 355         [struct rlimit r;
 356          setrlimit(0, &r);],
 357         [ac_setrlimit=yes], [ac_setrlimit=no])
 358     ])
 359   fi
 360
 361   AC_MSG_CHECKING([for testsuite resource limits support])
 362   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 363     ac_res_limits=yes
 364     AC_DEFINE(_GLIBCXX_RES_LIMITS, 1,
 365               [Define if using setrlimit to set resource limits during
 366               "make check"])
 367   else
 368     ac_res_limits=no
 369   fi
 370   AC_MSG_RESULT($ac_res_limits)
 371 ])
 372
 373
 374 dnl
 375 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 376 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 377 dnl
 378 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
 379   AC_MSG_CHECKING([for S_ISREG or S_IFREG])
 380   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 381     AC_TRY_LINK(
 382       [#include <sys/stat.h>],
 383       [struct stat buffer;
 384        fstat(0, &buffer);
 385        S_ISREG(buffer.st_mode);],
 386       [glibcxx_cv_S_ISREG=yes],
 387       [glibcxx_cv_S_ISREG=no])
 388   ])
 389   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 390     AC_TRY_LINK(
 391       [#include <sys/stat.h>],
 392       [struct stat buffer;
 393        fstat(0, &buffer);
 394        S_IFREG & buffer.st_mode;],
 395       [glibcxx_cv_S_IFREG=yes],
 396       [glibcxx_cv_S_IFREG=no])
 397   ])
 398   res=no
 399   if test $glibcxx_cv_S_ISREG = yes; then
 400     AC_DEFINE(HAVE_S_ISREG, 1,
 401               [Define if S_IFREG is available in <sys/stat.h>.])
 402     res=S_ISREG
 403   elif test $glibcxx_cv_S_IFREG = yes; then
 404     AC_DEFINE(HAVE_S_IFREG, 1,
 405               [Define if S_IFREG is available in <sys/stat.h>.])
 406     res=S_IFREG
 407   fi
 408   AC_MSG_RESULT($res)
 409 ])
 410
 411
 412 dnl
 413 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 414 dnl
 415 AC_DEFUN([GLIBCXX_CHECK_POLL], [
 416   AC_MSG_CHECKING([for poll])
 417   AC_CACHE_VAL(glibcxx_cv_POLL, [
 418     AC_TRY_LINK(
 419       [#include <poll.h>],
 420       [struct pollfd pfd[1];
 421        pfd[0].events = POLLIN;
 422        poll(pfd, 1, 0);],
 423       [glibcxx_cv_POLL=yes],
 424       [glibcxx_cv_POLL=no])
 425   ])
 426   if test $glibcxx_cv_POLL = yes; then
 427     AC_DEFINE(HAVE_POLL, 1, [Define if poll is available in <poll.h>.])
 428   fi
 429   AC_MSG_RESULT($glibcxx_cv_POLL)
 430 ])
 431
 432
 433 dnl
 434 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 435 dnl
 436 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
 437   AC_MSG_CHECKING([for writev])
 438   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 439     AC_TRY_LINK(
 440       [#include <sys/uio.h>],
 441       [struct iovec iov[2];
 442        writev(0, iov, 0);],
 443       [glibcxx_cv_WRITEV=yes],
 444       [glibcxx_cv_WRITEV=no])
 445   ])
 446   if test $glibcxx_cv_WRITEV = yes; then
 447     AC_DEFINE(HAVE_WRITEV, 1, [Define if writev is available in <sys/uio.h>.])
 448   fi
 449   AC_MSG_RESULT($glibcxx_cv_WRITEV)
 450 ])
 451
 452
 453 dnl
 454 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 455 dnl
 456 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
 457   AC_MSG_CHECKING([for int64_t])
 458   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 459     AC_TRY_COMPILE(
 460       [#include <stdint.h>],
 461       [int64_t var;],
 462       [glibcxx_cv_INT64_T=yes],
 463       [glibcxx_cv_INT64_T=no])
 464   ])
 465   if test $glibcxx_cv_INT64_T = yes; then
 466     AC_DEFINE(HAVE_INT64_T, 1, [Define if int64_t is available in <stdint.h>.])
 467   fi
 468   AC_MSG_RESULT($glibcxx_cv_INT64_T)
 469 ])
 470
 471
 472 dnl
 473 dnl Check whether LFS support is available.
 474 dnl
 475 AC_DEFUN([GLIBCXX_CHECK_LFS], [
 476   AC_LANG_SAVE
 477   AC_LANG_CPLUSPLUS
 478   ac_save_CXXFLAGS="$CXXFLAGS"
 479   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 480   AC_MSG_CHECKING([for LFS support])
 481   AC_CACHE_VAL(glibcxx_cv_LFS, [
 482     AC_TRY_LINK(
 483       [#include <unistd.h>
 484        #include <stdio.h>
 485        #include <sys/stat.h>
 486       ],
 487       [FILE* fp;
 488        fopen64("t", "w");
 489        fseeko64(fp, 0, SEEK_CUR);
 490        ftello64(fp);
 491        lseek64(1, 0, SEEK_CUR);
 492        struct stat64 buf;
 493        fstat64(1, &buf);],
 494       [glibcxx_cv_LFS=yes],
 495       [glibcxx_cv_LFS=no])
 496   ])
 497   if test $glibcxx_cv_LFS = yes; then
 498     AC_DEFINE(_GLIBCXX_USE_LFS, 1, [Define if LFS support is available.])
 499   fi
 500   AC_MSG_RESULT($glibcxx_cv_LFS)
 501   CXXFLAGS="$ac_save_CXXFLAGS"
 502   AC_LANG_RESTORE
 503 ])
 504
 505
 506 dnl
 507 dnl Check for whether a fully dynamic basic_string implementation should
 508 dnl be turned on, that does not put empty objects in per-process static
 509 dnl memory (mostly useful together with shared memory allocators, see PR
 510 dnl libstdc++/16612 for details).
 511 dnl
 512 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING
 513 dnl --disable-fully-dynamic-string leaves _GLIBCXX_FULLY_DYNAMIC_STRING undefined
 514 dnl  +  Usage:  GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
 515 dnl       Where DEFAULT is either `yes' or `no'.
 516 dnl
 517 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
 518   GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
 519   if test $enable_fully_dynamic_string = yes; then
 520     AC_DEFINE(_GLIBCXX_FULLY_DYNAMIC_STRING, 1,
 521               [Define if a fully dynamic basic_string is wanted.])
 522   fi
 523 ])
 524
 525
 526 dnl
 527 dnl Does any necessary configuration of the testsuite directory.  Generates
 528 dnl the testsuite_hooks.h header.
 529 dnl
 530 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 531 dnl
 532 dnl Sets:
 533 dnl  enable_abi_check
 534 dnl  GLIBCXX_TEST_WCHAR_T
 535 dnl  GLIBCXX_TEST_THREAD
 536 dnl Substs:
 537 dnl  baseline_dir
 538 dnl
 539 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
 540   if $GLIBCXX_IS_NATIVE ; then
 541     # Do checks for resource limit functions.
 542     GLIBCXX_CHECK_SETRLIMIT
 543
 544     # Look for setenv, so that extended locale tests can be performed.
 545     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 546   fi
 547
 548   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes &&
 549      test $enable_symvers != no; then
 550     case "$host" in
 551       *-*-cygwin*)
 552         enable_abi_check=no ;;
 553       *)
 554         enable_abi_check=yes ;;
 555     esac
 556   else
 557     # Only build this as native, since automake does not understand
 558     # CXX_FOR_BUILD.
 559     enable_abi_check=no
 560   fi
 561
 562   # Export file names for ABI checking.
 563   baseline_dir="$glibcxx_srcdir/config/abi/post/${abi_baseline_pair}\$(MULTISUBDIR)"
 564   AC_SUBST(baseline_dir)
 565 ])
 566
 567
 568 dnl
 569 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 570 dnl
 571 dnl Substs:
 572 dnl  GLIBCXX_INCLUDES
 573 dnl  TOPLEVEL_INCLUDES
 574 dnl
 575 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
 576   # Used for every C++ compile we perform.
 577   GLIBCXX_INCLUDES="\
 578 -I$glibcxx_builddir/include/$host_alias \
 579 -I$glibcxx_builddir/include \
 580 -I$glibcxx_srcdir/libsupc++"
 581
 582   # For Canadian crosses, pick this up too.
 583   if test $CANADIAN = yes; then
 584     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 585   fi
 586
 587   # Stuff in the actual top level.  Currently only used by libsupc++ to
 588   # get unwind* headers from the gcc dir.
 589   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 590   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 591
 592   # Now, export this to all the little Makefiles....
 593   AC_SUBST(GLIBCXX_INCLUDES)
 594   AC_SUBST(TOPLEVEL_INCLUDES)
 595 ])
 596
 597
 598 dnl
 599 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 600 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 601 dnl
 602 dnl Substs:
 603 dnl  OPTIMIZE_CXXFLAGS
 604 dnl  WARN_FLAGS
 605 dnl
 606 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
 607   # Optimization flags that are probably a good idea for thrill-seekers. Just
 608   # uncomment the lines below and make, everything else is ready to go...
 609   # Alternatively OPTIMIZE_CXXFLAGS can be set in configure.host.
 610   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 611   AC_SUBST(OPTIMIZE_CXXFLAGS)
 612
 613   WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
 614   AC_SUBST(WARN_FLAGS)
 615 ])
 616
 617
 618 dnl
 619 dnl All installation directory information is determined here.
 620 dnl
 621 dnl Substs:
 622 dnl  gxx_install_dir
 623 dnl  glibcxx_prefixdir
 624 dnl  glibcxx_toolexecdir
 625 dnl  glibcxx_toolexeclibdir
 626 dnl
 627 dnl Assumes cross_compiling bits already done, and with_cross_host in
 628 dnl particular.
 629 dnl
 630 dnl This logic must match gcc/configure.ac's setting of gcc_gxx_include_dir.
 631 dnl config/gxx-include-dir.m4 must be kept consistant with this as well.
 632 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
 633   glibcxx_toolexecdir=no
 634   glibcxx_toolexeclibdir=no
 635   glibcxx_prefixdir=$prefix
 636
 637   AC_MSG_CHECKING([for gxx-include-dir])
 638   AC_ARG_WITH([gxx-include-dir],
 639     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 640                    [installation directory for include files]),
 641     [case "$withval" in
 642       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 643       no)  gxx_include_dir=no ;;
 644       *)   gxx_include_dir=$withval ;;
 645      esac],
 646     [gxx_include_dir=no])
 647   AC_MSG_RESULT($gxx_include_dir)
 648
 649   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 650   AC_ARG_ENABLE([version-specific-runtime-libs],
 651     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 652                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 653     [case "$enableval" in
 654       yes) version_specific_libs=yes ;;
 655       no)  version_specific_libs=no ;;
 656       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 657      esac],
 658     [version_specific_libs=no])
 659   AC_MSG_RESULT($version_specific_libs)
 660
 661   # Default case for install directory for include files.
 662   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 663     gxx_include_dir='include/c++/${gcc_version}'
 664     if test -n "$with_cross_host" &&
 665        test x"$with_cross_host" != x"no"; then
 666       gxx_include_dir='${prefix}/${target_alias}/'"$gxx_include_dir"
 667     else
 668       gxx_include_dir='${prefix}/'"$gxx_include_dir"
 669     fi
 670   fi
 671
 672   # Version-specific runtime libs processing.
 673   if test $version_specific_libs = yes; then
 674     # Need the gcc compiler version to know where to install libraries
 675     # and header files if --enable-version-specific-runtime-libs option
 676     # is selected.  FIXME: these variables are misnamed, there are
 677     # no executables installed in _toolexecdir or _toolexeclibdir.
 678     if test x"$gxx_include_dir" = x"no"; then
 679       gxx_include_dir='${libdir}/gcc/${host_alias}/${gcc_version}/include/c++'
 680     fi
 681     glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 682     glibcxx_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
 683   fi
 684
 685   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 686   # Install a library built with a cross compiler in tooldir, not libdir.
 687   if test x"$glibcxx_toolexecdir" = x"no"; then
 688     if test -n "$with_cross_host" &&
 689        test x"$with_cross_host" != x"no"; then
 690       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 691       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 692     else
 693       glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 694       glibcxx_toolexeclibdir='${libdir}'
 695     fi
 696     multi_os_directory=`$CXX -print-multi-os-directory`
 697     case $multi_os_directory in
 698       .) ;; # Avoid trailing /.
 699       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 700     esac
 701   fi
 702
 703   AC_MSG_CHECKING([for install location])
 704   AC_MSG_RESULT($gxx_include_dir)
 705
 706   AC_SUBST(glibcxx_prefixdir)
 707   AC_SUBST(gxx_include_dir)
 708   AC_SUBST(glibcxx_toolexecdir)
 709   AC_SUBST(glibcxx_toolexeclibdir)
 710 ])
 711
 712
 713 dnl
 714 dnl GLIBCXX_ENABLE
 715 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 716 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 717 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 718 dnl
 719 dnl See docs/html/17_intro/configury.html#enable for documentation.
 720 dnl
 721 m4_define([GLIBCXX_ENABLE],[dnl
 722 m4_define([_g_switch],[--enable-$1])dnl
 723 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 724  AC_ARG_ENABLE($1,_g_help,
 725   m4_bmatch([$5],
 726    [^permit ],
 727      [[
 728       case "$enableval" in
 729        m4_bpatsubst([$5],[permit ])) ;;
 730        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 731           dnl Idea for future:  generate a URL pointing to
 732           dnl "onlinedocs/configopts.html#whatever"
 733       esac
 734      ]],
 735    [^$],
 736      [[
 737       case "$enableval" in
 738        yes|no) ;;
 739        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 740       esac
 741      ]],
 742    [[$5]]),
 743   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 744 m4_undefine([_g_switch])dnl
 745 m4_undefine([_g_help])dnl
 746 ])
 747
 748
 749 dnl
 750 dnl Check for ISO/IEC 9899:1999 "C99" support.
 751 dnl
 752 dnl --enable-c99 defines _GLIBCXX_USE_C99
 753 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 754 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 755 dnl       Where DEFAULT is either `yes' or `no'.
 756 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 757 dnl
 758 AC_DEFUN([GLIBCXX_ENABLE_C99], [
 759   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 760
 761   if test x"$enable_c99" = x"yes"; then
 762
 763   AC_LANG_SAVE
 764   AC_LANG_CPLUSPLUS
 765
 766   # Check for the existence of <math.h> functions used if C99 is enabled.
 767   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 768   AC_CACHE_VAL(ac_c99_math, [
 769   AC_TRY_COMPILE([#include <math.h>],
 770                  [fpclassify(0.0);
 771                   isfinite(0.0);
 772                   isinf(0.0);
 773                   isnan(0.0);
 774                   isnormal(0.0);
 775                   signbit(0.0);
 776                   isgreater(0.0,0.0);
 777                   isgreaterequal(0.0,0.0);
 778                   isless(0.0,0.0);
 779                   islessequal(0.0,0.0);
 780                   islessgreater(0.0,0.0);
 781                   islessgreater(0.0,0.0);
 782                   isunordered(0.0,0.0);
 783                  ],[ac_c99_math=yes], [ac_c99_math=no])
 784   ])
 785   AC_MSG_RESULT($ac_c99_math)
 786   if test x"$ac_c99_math" = x"yes"; then
 787     AC_DEFINE(_GLIBCXX_USE_C99_MATH, 1,
 788               [Define if C99 functions or macros in <math.h> should be imported
 789               in <cmath> in namespace std.])
 790   fi
 791
 792   # Check for the existence of <complex.h> complex math functions.
 793   # This is necessary even though libstdc++ uses the builtin versions
 794   # of these functions, because if the builtin cannot be used, a reference
 795   # to the library function is emitted.
 796   AC_CHECK_HEADERS(tgmath.h, ac_has_tgmath_h=yes, ac_has_tgmath_h=no)
 797   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
 798   ac_c99_complex=no;
 799   if test x"$ac_has_complex_h" = x"yes"; then
 800     AC_MSG_CHECKING([for ISO C99 support in <complex.h>])
 801     AC_TRY_COMPILE([#include <complex.h>],
 802                    [typedef __complex__ float float_type; float_type tmpf;
 803                     cabsf(tmpf);
 804                     cargf(tmpf);
 805                     ccosf(tmpf);
 806                     ccoshf(tmpf);
 807                     cexpf(tmpf);
 808                     clogf(tmpf);
 809                     csinf(tmpf);
 810                     csinhf(tmpf);
 811                     csqrtf(tmpf);
 812                     ctanf(tmpf);
 813                     ctanhf(tmpf);
 814                     cpowf(tmpf, tmpf);
 815                     typedef __complex__ double double_type; double_type tmpd;
 816                     cabs(tmpd);
 817                     carg(tmpd);
 818                     ccos(tmpd);
 819                     ccosh(tmpd);
 820                     cexp(tmpd);
 821                     clog(tmpd);
 822                     csin(tmpd);
 823                     csinh(tmpd);
 824                     csqrt(tmpd);
 825                     ctan(tmpd);
 826                     ctanh(tmpd);
 827                     cpow(tmpd, tmpd);
 828                     typedef __complex__ long double ld_type; ld_type tmpld;
 829                     cabsl(tmpld);
 830                     cargl(tmpld);
 831                     ccosl(tmpld);
 832                     ccoshl(tmpld);
 833                     cexpl(tmpld);
 834                     clogl(tmpld);
 835                     csinl(tmpld);
 836                     csinhl(tmpld);
 837                     csqrtl(tmpld);
 838                     ctanl(tmpld);
 839                     ctanhl(tmpld);
 840                     cpowl(tmpld, tmpld);
 841                    ],[ac_c99_complex=yes], [ac_c99_complex=no])
 842   fi
 843   AC_MSG_RESULT($ac_c99_complex)
 844   if test x"$ac_c99_complex" = x"yes"; then
 845     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX, 1,
 846               [Define if C99 functions in <complex.h> should be used in
 847               <complex>. Using compiler builtins for these functions requires
 848               corresponding C99 library functions to be present.])
 849   fi
 850
 851   # Check for the existence in <stdio.h> of vscanf, et. al.
 852   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 853   AC_CACHE_VAL(ac_c99_stdio, [
 854   AC_TRY_COMPILE([#include <stdio.h>
 855                   #include <stdarg.h>
 856                   void foo(char* fmt, ...)
 857                   {
 858                     va_list args; va_start(args, fmt);
 859                     vfscanf(stderr, "%i", args);
 860                     vscanf("%i", args);
 861                     vsnprintf(fmt, 0, "%i", args);
 862                     vsscanf(fmt, "%i", args);
 863                   }],
 864                  [snprintf("12", 0, "%i");],
 865                  [ac_c99_stdio=yes], [ac_c99_stdio=no])
 866   ])
 867   AC_MSG_RESULT($ac_c99_stdio)
 868
 869   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 870   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 871   AC_CACHE_VAL(ac_c99_stdlib, [
 872   AC_TRY_COMPILE([#include <stdlib.h>],
 873                  [char* tmp;
 874                   strtof("gnu", &tmp);
 875                   strtold("gnu", &tmp);
 876                   strtoll("gnu", &tmp, 10);
 877                   strtoull("gnu", &tmp, 10);
 878                   llabs(10);
 879                   lldiv(10,1);
 880                   atoll("10");
 881                   _Exit(0);
 882                   lldiv_t mydivt;],[ac_c99_stdlib=yes], [ac_c99_stdlib=no])
 883   ])
 884   AC_MSG_RESULT($ac_c99_stdlib)
 885
 886   # Check for the existence in <wchar.h> of wcstold, etc.
 887   ac_c99_wchar=no;
 888   if test x"$ac_has_wchar_h" = xyes &&
 889      test x"$ac_has_wctype_h" = xyes; then
 890     AC_MSG_CHECKING([for ISO C99 support in <wchar.h>])
 891     AC_TRY_COMPILE([#include <wchar.h>
 892                     namespace test
 893                     {
 894                       using ::wcstold;
 895                       using ::wcstoll;
 896                       using ::wcstoull;
 897                     }
 898                    ],[],[ac_c99_wchar=yes], [ac_c99_wchar=no])
 899
 900     # Checks for wide character functions that may not be present.
 901     # Injection of these is wrapped with guard macros.
 902     # NB: only put functions here, instead of immediately above, if
 903     # absolutely necessary.
 904     AC_TRY_COMPILE([#include <wchar.h>
 905                     namespace test { using ::vfwscanf; } ], [],
 906                    [AC_DEFINE(HAVE_VFWSCANF,1,
 907                         [Defined if vfwscanf exists.])],[])
 908
 909     AC_TRY_COMPILE([#include <wchar.h>
 910                     namespace test { using ::vswscanf; } ], [],
 911                    [AC_DEFINE(HAVE_VSWSCANF,1,
 912                         [Defined if vswscanf exists.])],[])
 913
 914     AC_TRY_COMPILE([#include <wchar.h>
 915                     namespace test { using ::vwscanf; } ], [],
 916                    [AC_DEFINE(HAVE_VWSCANF,1,[Defined if vwscanf exists.])],[])
 917
 918     AC_TRY_COMPILE([#include <wchar.h>
 919                     namespace test { using ::wcstof; } ], [],
 920                    [AC_DEFINE(HAVE_WCSTOF,1,[Defined if wcstof exists.])],[])
 921
 922     AC_TRY_COMPILE([#include <wctype.h>],
 923                    [ wint_t t; int i = iswblank(t);],
 924                    [AC_DEFINE(HAVE_ISWBLANK,1,
 925                         [Defined if iswblank exists.])],[])
 926
 927     AC_MSG_RESULT($ac_c99_wchar)
 928   fi
 929
 930   # Option parsed, now set things appropriately.
 931   if test x"$ac_c99_math" = x"no" ||
 932      test x"$ac_c99_complex" = x"no" ||
 933      test x"$ac_c99_stdio" = x"no" ||
 934      test x"$ac_c99_stdlib" = x"no" ||
 935      test x"$ac_c99_wchar" = x"no"; then
 936     enable_c99=no;
 937   else
 938     AC_DEFINE(_GLIBCXX_USE_C99, 1,
 939     [Define if C99 functions or macros from <wchar.h>, <math.h>,
 940     <complex.h>, <stdio.h>, and <stdlib.h> can be used or exposed.])
 941   fi
 942
 943   AC_LANG_RESTORE
 944   fi
 945
 946   AC_MSG_CHECKING([for fully enabled ISO C99 support])
 947   AC_MSG_RESULT($enable_c99)
 948 ])
 949
 950
 951 dnl
 952 dnl Check for ISO/IEC 9899:1999 "C99" support to ISO/IEC DTR 19768 "TR1"
 953 dnl facilities in Chapter 8, "C compatibility".
 954 dnl
 955 AC_DEFUN([GLIBCXX_CHECK_C99_TR1], [
 956
 957   AC_LANG_SAVE
 958   AC_LANG_CPLUSPLUS
 959
 960   # Check for the existence of <complex.h> complex math functions used
 961   # by tr1/complex.
 962   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
 963   ac_c99_complex_tr1=no;
 964   if test x"$ac_has_complex_h" = x"yes"; then
 965     AC_MSG_CHECKING([for ISO C99 support to TR1 in <complex.h>])
 966     AC_TRY_COMPILE([#include <complex.h>],
 967                    [typedef __complex__ float float_type; float_type tmpf;
 968                     cacosf(tmpf);
 969                     casinf(tmpf);
 970                     catanf(tmpf);
 971                     cacoshf(tmpf);
 972                     casinhf(tmpf);
 973                     catanhf(tmpf);
 974                     typedef __complex__ double double_type; double_type tmpd;
 975                     cacos(tmpd);
 976                     casin(tmpd);
 977                     catan(tmpd);
 978                     cacosh(tmpd);
 979                     casinh(tmpd);
 980                     catanh(tmpd);
 981                     typedef __complex__ long double ld_type; ld_type tmpld;
 982                     cacosl(tmpld);
 983                     casinl(tmpld);
 984                     catanl(tmpld);
 985                     cacoshl(tmpld);
 986                     casinhl(tmpld);
 987                     catanhl(tmpld);
 988                    ],[ac_c99_complex_tr1=yes], [ac_c99_complex_tr1=no])
 989   fi
 990   AC_MSG_RESULT($ac_c99_complex_tr1)
 991   if test x"$ac_c99_complex_tr1" = x"yes"; then
 992     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX_TR1, 1,
 993               [Define if C99 functions in <complex.h> should be used in
 994               <tr1/complex>. Using compiler builtins for these functions
 995               requires corresponding C99 library functions to be present.])
 996   fi
 997
 998   # Check for the existence of <ctype.h> functions.
 999   AC_MSG_CHECKING([for ISO C99 support to TR1 in <ctype.h>])
1000   AC_CACHE_VAL(ac_c99_ctype_tr1, [
1001   AC_TRY_COMPILE([#include <ctype.h>],
1002                  [int ch;
1003                   int ret;
1004                   ret = isblank(ch);
1005                  ],[ac_c99_ctype_tr1=yes], [ac_c99_ctype_tr1=no])
1006   ])
1007   AC_MSG_RESULT($ac_c99_ctype_tr1)
1008   if test x"$ac_c99_ctype_tr1" = x"yes"; then
1009     AC_DEFINE(_GLIBCXX_USE_C99_CTYPE_TR1, 1,
1010               [Define if C99 functions in <ctype.h> should be imported in
1011               <tr1/cctype> in namespace std::tr1.])
1012   fi
1013
1014   # Check for the existence of <fenv.h> functions.
1015   AC_CHECK_HEADERS(fenv.h, ac_has_fenv_h=yes, ac_has_fenv_h=no)
1016   ac_c99_fenv_tr1=no;
1017   if test x"$ac_has_fenv_h" = x"yes"; then
1018     AC_MSG_CHECKING([for ISO C99 support to TR1 in <fenv.h>])
1019     AC_TRY_COMPILE([#include <fenv.h>],
1020                    [int except, mode;
1021                     fexcept_t* pflag;
1022                     fenv_t* penv;
1023                     int ret;
1024                     ret = feclearexcept(except);
1025                     ret = fegetexceptflag(pflag, except);
1026                     ret = feraiseexcept(except);
1027                     ret = fesetexceptflag(pflag, except);
1028                     ret = fetestexcept(except);
1029                     ret = fegetround();
1030                     ret = fesetround(mode);
1031                     ret = fegetenv(penv);
1032                     ret = feholdexcept(penv);
1033                     ret = fesetenv(penv);
1034                     ret = feupdateenv(penv);
1035                    ],[ac_c99_fenv_tr1=yes], [ac_c99_fenv_tr1=no])
1036   fi
1037   AC_MSG_RESULT($ac_c99_fenv_tr1)
1038   if test x"$ac_c99_fenv_tr1" = x"yes"; then
1039     AC_DEFINE(_GLIBCXX_USE_C99_FENV_TR1, 1,
1040               [Define if C99 functions in <fenv.h> should be imported in
1041               <tr1/cfenv> in namespace std::tr1.])
1042   fi
1043
1044   # Check for the existence of <stdint.h> types.
1045   AC_MSG_CHECKING([for ISO C99 support to TR1 in <stdint.h>])
1046   AC_CACHE_VAL(ac_c99_stdint_tr1, [
1047   AC_TRY_COMPILE([#include <stdint.h>],
1048                  [typedef int8_t          my_int8_t;
1049                   typedef int16_t         my_int16_t;
1050                   typedef int32_t         my_int32_t;
1051                   typedef int64_t         my_int64_t;
1052                   typedef int_fast8_t     my_int_fast8_t;
1053                   typedef int_fast16_t    my_int_fast16_t;
1054                   typedef int_fast32_t    my_int_fast32_t;
1055                   typedef int_fast64_t    my_int_fast64_t;
1056                   typedef int_least8_t    my_int_least8_t;
1057                   typedef int_least16_t   my_int_least16_t;
1058                   typedef int_least32_t   my_int_least32_t;
1059                   typedef int_least64_t   my_int_least64_t;
1060                   typedef intmax_t        my_intmax_t;
1061                   typedef intptr_t        my_intptr_t;
1062                   typedef uint8_t         my_uint8_t;
1063                   typedef uint16_t        my_uint16_t;
1064                   typedef uint32_t        my_uint32_t;
1065                   typedef uint64_t        my_uint64_t;
1066                   typedef uint_fast8_t    my_uint_fast8_t;
1067                   typedef uint_fast16_t   my_uint_fast16_t;
1068                   typedef uint_fast32_t   my_uint_fast32_t;
1069                   typedef uint_fast64_t   my_uint_fast64_t;
1070                   typedef uint_least8_t   my_uint_least8_t;
1071                   typedef uint_least16_t  my_uint_least16_t;
1072                   typedef uint_least32_t  my_uint_least32_t;
1073                   typedef uint_least64_t  my_uint_least64_t;
1074                   typedef uintmax_t       my_uintmax_t;
1075                   typedef uintptr_t       my_uintptr_t;
1076                  ],[ac_c99_stdint_tr1=yes], [ac_c99_stdint_tr1=no])
1077   ])
1078   AC_MSG_RESULT($ac_c99_stdint_tr1)
1079   if test x"$ac_c99_stdint_tr1" = x"yes"; then
1080     AC_DEFINE(_GLIBCXX_USE_C99_STDINT_TR1, 1,
1081               [Define if C99 types in <stdint.h> should be imported in
1082               <tr1/cstdint> in namespace std::tr1.])
1083   fi
1084
1085   # Check for the existence of <math.h> functions.
1086   AC_MSG_CHECKING([for ISO C99 support to TR1 in <math.h>])
1087   AC_CACHE_VAL(ac_c99_math_tr1, [
1088   AC_TRY_COMPILE([#include <math.h>],
1089                  [typedef double_t  my_double_t;
1090                   typedef float_t   my_float_t;
1091                   acosh(0.0);
1092                   acoshf(0.0f);
1093                   acoshl(0.0l);
1094                   asinh(0.0);
1095                   asinhf(0.0f);
1096                   asinhl(0.0l);
1097                   atanh(0.0);
1098                   atanhf(0.0f);
1099                   atanhl(0.0l);
1100                   cbrt(0.0);
1101                   cbrtf(0.0f);
1102                   cbrtl(0.0l);
1103                   copysign(0.0, 0.0);
1104                   copysignf(0.0f, 0.0f);
1105                   copysignl(0.0l, 0.0l);
1106                   erf(0.0);
1107                   erff(0.0f);
1108                   erfl(0.0l);
1109                   erfc(0.0);
1110                   erfcf(0.0f);
1111                   erfcl(0.0l);
1112                   exp2(0.0);
1113                   exp2f(0.0f);
1114                   exp2l(0.0l);
1115                   expm1(0.0);
1116                   expm1f(0.0f);
1117                   expm1l(0.0l);
1118                   fdim(0.0, 0.0);
1119                   fdimf(0.0f, 0.0f);
1120                   fdiml(0.0l, 0.0l);
1121                   fma(0.0, 0.0, 0.0);
1122                   fmaf(0.0f, 0.0f, 0.0f);
1123                   fmal(0.0l, 0.0l, 0.0l);
1124                   fmax(0.0, 0.0);
1125                   fmaxf(0.0f, 0.0f);
1126                   fmaxl(0.0l, 0.0l);
1127                   fmin(0.0, 0.0);
1128                   fminf(0.0f, 0.0f);
1129                   fminl(0.0l, 0.0l);
1130                   hypot(0.0, 0.0);
1131                   hypotf(0.0f, 0.0f);
1132                   hypotl(0.0l, 0.0l);
1133                   ilogb(0.0);
1134                   ilogbf(0.0f);
1135                   ilogbl(0.0l);
1136                   lgamma(0.0);
1137                   lgammaf(0.0f);
1138                   lgammal(0.0l);
1139                   llrint(0.0);
1140                   llrintf(0.0f);
1141                   llrintl(0.0l);
1142                   llround(0.0);
1143                   llroundf(0.0f);
1144                   llroundl(0.0l);
1145                   log1p(0.0);
1146                   log1pf(0.0f);
1147                   log1pl(0.0l);
1148                   log2(0.0);
1149                   log2f(0.0f);
1150                   log2l(0.0l);
1151                   logb(0.0);
1152                   logbf(0.0f);
1153                   logbl(0.0l);
1154                   lrint(0.0);
1155                   lrintf(0.0f);
1156                   lrintl(0.0l);
1157                   lround(0.0);
1158                   lroundf(0.0f);
1159                   lroundl(0.0l);
1160                   nan(0);
1161                   nanf(0);
1162                   nanl(0);
1163                   nearbyint(0.0);
1164                   nearbyintf(0.0f);
1165                   nearbyintl(0.0l);
1166                   nextafter(0.0, 0.0);
1167                   nextafterf(0.0f, 0.0f);
1168                   nextafterl(0.0l, 0.0l);
1169                   nexttoward(0.0, 0.0);
1170                   nexttowardf(0.0f, 0.0f);
1171                   nexttowardl(0.0l, 0.0l);
1172                   remainder(0.0, 0.0);
1173                   remainderf(0.0f, 0.0f);
1174                   remainderl(0.0l, 0.0l);
1175                   remquo(0.0, 0.0, 0);
1176                   remquo(0.0f, 0.0f, 0);
1177                   remquo(0.0l, 0.0l, 0);
1178                   rint(0.0);
1179                   rintf(0.0f);
1180                   rintl(0.0l);
1181                   round(0.0);
1182                   roundf(0.0f);
1183                   roundl(0.0l);
1184                   scalbln(0.0, 0l);
1185                   scalblnf(0.0f, 0l);
1186                   scalblnl(0.0l, 0l);
1187                   scalbn(0.0, 0);
1188                   scalbnf(0.0f, 0);
1189                   scalbnl(0.0l, 0);
1190                   tgamma(0.0);
1191                   tgammaf(0.0f);
1192                   tgammal(0.0l);
1193                   trunc(0.0);
1194                   truncf(0.0f);
1195                   truncl(0.0l);
1196                  ],[ac_c99_math_tr1=yes], [ac_c99_math_tr1=no])
1197   ])
1198   AC_MSG_RESULT($ac_c99_math_tr1)
1199   if test x"$ac_c99_math_tr1" = x"yes"; then
1200     AC_DEFINE(_GLIBCXX_USE_C99_MATH_TR1, 1,
1201               [Define if C99 functions or macros in <math.h> should be imported
1202               in <tr1/cmath> in namespace std::tr1.])
1203   fi
1204
1205   # Check for the existence of <inttypes.h> functions (NB: doesn't make
1206   # sense if the previous check fails, per C99, 7.8/1).
1207   ac_c99_inttypes_tr1=no;
1208   if test x"$ac_c99_stdint_tr1" = x"yes"; then
1209     AC_MSG_CHECKING([for ISO C99 support to TR1 in <inttypes.h>])
1210     AC_TRY_COMPILE([#include <inttypes.h>],
1211                    [intmax_t i, numer, denom, base;
1212                     const char* s;
1213                     char** endptr;
1214                     intmax_t ret = imaxabs(i);
1215                     imaxdiv_t dret = imaxdiv(numer, denom);
1216                     ret = strtoimax(s, endptr, base);
1217                     uintmax_t uret = strtoumax(s, endptr, base);
1218                    ],[ac_c99_inttypes_tr1=yes], [ac_c99_inttypes_tr1=no])
1219   fi
1220   AC_MSG_RESULT($ac_c99_inttypes_tr1)
1221   if test x"$ac_c99_inttypes_tr1" = x"yes"; then
1222     AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_TR1, 1,
1223               [Define if C99 functions in <inttypes.h> should be imported in
1224               <tr1/cinttypes> in namespace std::tr1.])
1225   fi
1226
1227   # Check for the existence of the <stdbool.h> header.
1228   AC_CHECK_HEADERS(stdbool.h)
1229
1230   AC_LANG_RESTORE
1231 ])
1232
1233 dnl
1234 dnl Check whether "dev/random" and "dev/urandom" are available for the
1235 dnl random_device of "TR1" (Chapter 5.1, "Random number generation").
1236 dnl
1237 AC_DEFUN([GLIBCXX_CHECK_RANDOM_TR1], [
1238
1239   AC_MSG_CHECKING([for "dev/random" and "dev/urandom" for TR1 random_device])
1240   AC_CACHE_VAL(ac_random_tr1, [
1241   AC_TRY_RUN([#include <stdio.h>
1242               int main()
1243               {
1244                 return !(fopen("/dev/random", "r")
1245                          && fopen("/dev/urandom", "r"));
1246               }
1247              ],
1248              [ac_random_tr1=yes], [ac_random_tr1=no],
1249              [ac_random_tr1=no])
1250   ])
1251   AC_MSG_RESULT($ac_random_tr1)
1252   if test x"$ac_random_tr1" = x"yes"; then
1253     AC_DEFINE(_GLIBCXX_USE_RANDOM_TR1, 1,
1254               [Define if dev/random and dev/urandom are available for
1255                the random_device of TR1 (Chapter 5.1).])
1256   fi
1257
1258 ])
1259
1260 dnl
1261 dnl Check for what type of C headers to use.
1262 dnl
1263 dnl --enable-cheaders= [does stuff].
1264 dnl --disable-cheaders [does not do anything, really].
1265 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
1266 dnl       Where DEFAULT is either 'c' or 'c_std' or 'c_global'.
1267 dnl
1268 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
1269   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
1270     [construct "C" headers for g++], [permit c|c_std|c_global])
1271   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
1272
1273   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
1274
1275   # Allow overrides to configure.host here.
1276   if test $enable_cheaders = c_global; then
1277      c_compatibility=yes
1278   fi
1279
1280   if test $enable_cheaders = c_global || test $enable_cheaders = c_std; then
1281      c_extra=yes
1282   fi
1283
1284   AC_SUBST(C_INCLUDE_DIR)
1285   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
1286   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
1287   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_GLOBAL, test $enable_cheaders = c_global)
1288   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
1289   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_EXTRA, test $c_extra = yes)
1290 ])
1291
1292
1293 dnl
1294 dnl Check for which locale library to use.  The choice is mapped to
1295 dnl a subdirectory of config/locale.
1296 dnl
1297 dnl Default is generic.
1298 dnl
1299 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
1300   AC_MSG_CHECKING([for C locale to use])
1301   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
1302     [use MODEL for target locale package],
1303     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
1304
1305   # If they didn't use this option switch, or if they specified --enable
1306   # with no specific model, we'll have to look for one.  If they
1307   # specified --disable (???), do likewise.
1308   if test $enable_clocale = no || test $enable_clocale = yes; then
1309      enable_clocale=auto
1310   fi
1311
1312   # Either a known package, or "auto"
1313   enable_clocale_flag=$enable_clocale
1314
1315   # Probe for locale support if no specific model is specified.
1316   # Default to "generic".
1317   if test $enable_clocale_flag = auto; then
1318     case ${target_os} in
1319       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1320         AC_EGREP_CPP([_GLIBCXX_ok], [
1321         #include <features.h>
1322         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1323           _GLIBCXX_ok
1324         #endif
1325         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1326
1327         # Test for bugs early in glibc-2.2.x series
1328           if test $enable_clocale_flag = gnu; then
1329           AC_TRY_RUN([
1330           #define _GNU_SOURCE 1
1331           #include <locale.h>
1332           #include <string.h>
1333           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1334           extern __typeof(newlocale) __newlocale;
1335           extern __typeof(duplocale) __duplocale;
1336           extern __typeof(strcoll_l) __strcoll_l;
1337           #endif
1338           int main()
1339           {
1340               const char __one[] = "Äuglein Augmen";
1341               const char __two[] = "Äuglein";
1342               int i;
1343               int j;
1344               __locale_t        loc;
1345                __locale_t        loc_dup;
1346               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1347               loc_dup = __duplocale(loc);
1348               i = __strcoll_l(__one, __two, loc);
1349               j = __strcoll_l(__one, __two, loc_dup);
1350               return 0;
1351           }
1352           ],
1353           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1354           [enable_clocale_flag=generic])
1355           fi
1356
1357         # ... at some point put __strxfrm_l tests in as well.
1358         ;;
1359       darwin* | freebsd*)
1360         enable_clocale_flag=darwin
1361         ;;
1362       *)
1363         enable_clocale_flag=generic
1364         ;;
1365     esac
1366   fi
1367
1368   # Deal with gettext issues.  Default to not using it (=no) until we detect
1369   # support for it later.  Let the user turn it off via --e/d, but let that
1370   # default to on for easier handling.
1371   USE_NLS=no
1372   AC_ARG_ENABLE(nls,
1373     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1374     [],
1375     [enable_nls=yes])
1376
1377   # Set configure bits for specified locale package
1378   case ${enable_clocale_flag} in
1379     generic)
1380       AC_MSG_RESULT(generic)
1381
1382       CLOCALE_H=config/locale/generic/c_locale.h
1383       CLOCALE_CC=config/locale/generic/c_locale.cc
1384       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1385       CCOLLATE_CC=config/locale/generic/collate_members.cc
1386       CCTYPE_CC=config/locale/generic/ctype_members.cc
1387       CMESSAGES_H=config/locale/generic/messages_members.h
1388       CMESSAGES_CC=config/locale/generic/messages_members.cc
1389       CMONEY_CC=config/locale/generic/monetary_members.cc
1390       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1391       CTIME_H=config/locale/generic/time_members.h
1392       CTIME_CC=config/locale/generic/time_members.cc
1393       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1394       ;;
1395     darwin)
1396       AC_MSG_RESULT(darwin or freebsd)
1397
1398       CLOCALE_H=config/locale/generic/c_locale.h
1399       CLOCALE_CC=config/locale/generic/c_locale.cc
1400       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1401       CCOLLATE_CC=config/locale/generic/collate_members.cc
1402       CCTYPE_CC=config/locale/darwin/ctype_members.cc
1403       CMESSAGES_H=config/locale/generic/messages_members.h
1404       CMESSAGES_CC=config/locale/generic/messages_members.cc
1405       CMONEY_CC=config/locale/generic/monetary_members.cc
1406       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1407       CTIME_H=config/locale/generic/time_members.h
1408       CTIME_CC=config/locale/generic/time_members.cc
1409       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1410       ;;
1411
1412     gnu)
1413       AC_MSG_RESULT(gnu)
1414
1415       # Declare intention to use gettext, and add support for specific
1416       # languages.
1417       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1418       ALL_LINGUAS="de fr"
1419
1420       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1421       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1422       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1423         USE_NLS=yes
1424       fi
1425       # Export the build objects.
1426       for ling in $ALL_LINGUAS; do \
1427         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1428         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1429       done
1430       AC_SUBST(glibcxx_MOFILES)
1431       AC_SUBST(glibcxx_POFILES)
1432
1433       CLOCALE_H=config/locale/gnu/c_locale.h
1434       CLOCALE_CC=config/locale/gnu/c_locale.cc
1435       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1436       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1437       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1438       CMESSAGES_H=config/locale/gnu/messages_members.h
1439       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1440       CMONEY_CC=config/locale/gnu/monetary_members.cc
1441       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1442       CTIME_H=config/locale/gnu/time_members.h
1443       CTIME_CC=config/locale/gnu/time_members.cc
1444       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1445       ;;
1446     ieee_1003.1-2001)
1447       AC_MSG_RESULT(IEEE 1003.1)
1448
1449       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1450       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1451       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1452       CCOLLATE_CC=config/locale/generic/collate_members.cc
1453       CCTYPE_CC=config/locale/generic/ctype_members.cc
1454       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1455       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1456       CMONEY_CC=config/locale/generic/monetary_members.cc
1457       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1458       CTIME_H=config/locale/generic/time_members.h
1459       CTIME_CC=config/locale/generic/time_members.cc
1460       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1461       ;;
1462   esac
1463
1464   # This is where the testsuite looks for locale catalogs, using the
1465   # -DLOCALEDIR define during testsuite compilation.
1466   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1467   AC_SUBST(glibcxx_localedir)
1468
1469   # A standalone libintl (e.g., GNU libintl) may be in use.
1470   if test $USE_NLS = yes; then
1471     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1472     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1473   fi
1474   if test $USE_NLS = yes; then
1475     AC_DEFINE(_GLIBCXX_USE_NLS, 1,
1476               [Define if NLS translations are to be used.])
1477   fi
1478
1479   AC_SUBST(USE_NLS)
1480   AC_SUBST(CLOCALE_H)
1481   AC_SUBST(CMESSAGES_H)
1482   AC_SUBST(CCODECVT_CC)
1483   AC_SUBST(CCOLLATE_CC)
1484   AC_SUBST(CCTYPE_CC)
1485   AC_SUBST(CMESSAGES_CC)
1486   AC_SUBST(CMONEY_CC)
1487   AC_SUBST(CNUMERIC_CC)
1488   AC_SUBST(CTIME_H)
1489   AC_SUBST(CTIME_CC)
1490   AC_SUBST(CLOCALE_CC)
1491   AC_SUBST(CLOCALE_INTERNAL_H)
1492 ])
1493
1494
1495 dnl
1496 dnl Check for which std::allocator base class to use.  The choice is
1497 dnl mapped from a subdirectory of include/ext.
1498 dnl
1499 dnl Default is new.
1500 dnl
1501 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
1502   AC_MSG_CHECKING([for std::allocator base class])
1503   GLIBCXX_ENABLE(libstdcxx-allocator,auto,[=KIND],
1504     [use KIND for target std::allocator base],
1505     [permit new|malloc|mt|bitmap|pool|yes|no|auto])
1506
1507   # If they didn't use this option switch, or if they specified --enable
1508   # with no specific model, we'll have to look for one.  If they
1509   # specified --disable (???), do likewise.
1510   if test $enable_libstdcxx_allocator = no ||
1511      test $enable_libstdcxx_allocator = yes;
1512   then
1513      enable_libstdcxx_allocator=auto
1514   fi
1515
1516   # Either a known package, or "auto". Auto implies the default choice
1517   # for a particular platform.
1518   enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
1519
1520   # Probe for host-specific support if no specific model is specified.
1521   # Default to "new".
1522   if test $enable_libstdcxx_allocator_flag = auto; then
1523     case ${target_os} in
1524       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1525         enable_libstdcxx_allocator_flag=new
1526         ;;
1527       *)
1528         enable_libstdcxx_allocator_flag=new
1529         ;;
1530     esac
1531   fi
1532   AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
1533
1534
1535   # Set configure bits for specified locale package
1536   case ${enable_libstdcxx_allocator_flag} in
1537     bitmap)
1538       ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
1539       ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
1540       ;;
1541     malloc)
1542       ALLOCATOR_H=config/allocator/malloc_allocator_base.h
1543       ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
1544       ;;
1545     mt)
1546       ALLOCATOR_H=config/allocator/mt_allocator_base.h
1547       ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
1548       ;;
1549     new)
1550       ALLOCATOR_H=config/allocator/new_allocator_base.h
1551       ALLOCATOR_NAME=__gnu_cxx::new_allocator
1552       ;;
1553     pool)
1554       ALLOCATOR_H=config/allocator/pool_allocator_base.h
1555       ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
1556       ;;
1557   esac
1558
1559   AC_SUBST(ALLOCATOR_H)
1560   AC_SUBST(ALLOCATOR_NAME)
1561 ])
1562
1563
1564 dnl
1565 dnl Check for whether the Boost-derived checks should be turned on.
1566 dnl
1567 dnl --enable-concept-checks turns them on.
1568 dnl --disable-concept-checks leaves them off.
1569 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1570 dnl       Where DEFAULT is either `yes' or `no'.
1571 dnl
1572 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
1573   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1574   if test $enable_concept_checks = yes; then
1575     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1,
1576               [Define to use concept checking code from the boost libraries.])
1577   fi
1578 ])
1579
1580
1581 dnl
1582 dnl Check for which I/O library to use:  stdio, or something specific.
1583 dnl
1584 dnl Default is stdio.
1585 dnl
1586 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
1587   AC_MSG_CHECKING([for underlying I/O to use])
1588   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1589     [use target-specific I/O package], [permit stdio])
1590
1591   # Now that libio has been removed, you can have any color you want as long
1592   # as it's black.  This is one big no-op until other packages are added, but
1593   # showing the framework never hurts.
1594   case ${enable_cstdio} in
1595     stdio)
1596       CSTDIO_H=config/io/c_io_stdio.h
1597       BASIC_FILE_H=config/io/basic_file_stdio.h
1598       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1599       AC_MSG_RESULT(stdio)
1600       ;;
1601   esac
1602
1603   AC_SUBST(CSTDIO_H)
1604   AC_SUBST(BASIC_FILE_H)
1605   AC_SUBST(BASIC_FILE_CC)
1606 ])
1607
1608
1609 dnl
1610 dnl Check for "unusual" flags to pass to the compiler while building.
1611 dnl
1612 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1613 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1614 dnl --disable-cxx-flags passes nothing.
1615 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1616 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1617 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1618 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1619 dnl       If "default flags" is an empty string, the effect is the same
1620 dnl       as --disable or --enable=no.
1621 dnl
1622 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
1623   AC_MSG_CHECKING([for extra compiler flags for building])
1624   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1625     [pass compiler FLAGS when building library],
1626     [case "x$enable_cxx_flags" in
1627       xno | x)   enable_cxx_flags= ;;
1628       x-*)       ;;
1629       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1630      esac])
1631
1632   # Run through flags (either default or command-line) and set anything
1633   # extra (e.g., #defines) that must accompany particular g++ options.
1634   if test -n "$enable_cxx_flags"; then
1635     for f in $enable_cxx_flags; do
1636       case "$f" in
1637         -fhonor-std)  ;;
1638         -*)  ;;
1639         *)   # and we're trying to pass /what/ exactly?
1640              AC_MSG_ERROR([compiler flags start with a -]) ;;
1641       esac
1642     done
1643   fi
1644
1645   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1646   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1647   AC_SUBST(EXTRA_CXX_FLAGS)
1648 ])
1649
1650
1651 dnl
1652 dnl Check to see if debugging libraries are to be built.
1653 dnl
1654 dnl --enable-libstdcxx-debug
1655 dnl builds a separate set of debugging libraries in addition to the
1656 dnl normal (shared, static) libstdc++ binaries.
1657 dnl
1658 dnl --disable-libstdcxx-debug
1659 dnl builds only one (non-debug) version of libstdc++.
1660 dnl
1661 dnl --enable-libstdcxx-debug-flags=FLAGS
1662 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1663 dnl
1664 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1665 dnl       Where DEFAULT is either `yes' or `no'.
1666 dnl
1667 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
1668   AC_MSG_CHECKING([for additional debug build])
1669   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1670   AC_MSG_RESULT($enable_libstdcxx_debug)
1671   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1672 ])
1673
1674
1675 dnl
1676 dnl Check for explicit debug flags.
1677 dnl
1678 dnl --enable-libstdcxx-debug-flags='-O1'
1679 dnl is a general method for passing flags to be used when
1680 dnl building debug libraries with --enable-debug.
1681 dnl
1682 dnl --disable-libstdcxx-debug-flags does nothing.
1683 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1684 dnl       If "default flags" is an empty string, the effect is the same
1685 dnl       as --disable or --enable=no.
1686 dnl
1687 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
1688   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1689     [pass compiler FLAGS when building debug library],
1690     [case "x$enable_libstdcxx_debug_flags" in
1691       xno | x)    enable_libstdcxx_debug_flags= ;;
1692       x-*)        ;;
1693       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1694      esac])
1695
1696   # Option parsed, now set things appropriately
1697   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1698   AC_SUBST(DEBUG_FLAGS)
1699
1700   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1701 ])
1702
1703
1704 dnl
1705 dnl Check if the user only wants a freestanding library implementation.
1706 dnl
1707 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1708 dnl installing only the headers required by [17.4.1.3] and the language
1709 dnl support library.  More than that will be built (to keep the Makefiles
1710 dnl conveniently clean), but not installed.
1711 dnl
1712 dnl Sets:
1713 dnl  is_hosted  (yes/no)
1714 dnl
1715 dnl Defines:
1716 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1717 dnl
1718 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
1719   AC_ARG_ENABLE([hosted-libstdcxx],
1720     AC_HELP_STRING([--disable-hosted-libstdcxx],
1721                    [only build freestanding C++ runtime support]),,
1722     [case "$host" in
1723         arm*-*-symbianelf*)
1724             enable_hosted_libstdcxx=no
1725             ;;
1726         *)
1727             enable_hosted_libstdcxx=yes
1728             ;;
1729      esac])
1730   if test "$enable_hosted_libstdcxx" = no; then
1731     AC_MSG_NOTICE([Only freestanding libraries will be built])
1732     is_hosted=no
1733     hosted_define=0
1734     enable_abi_check=no
1735     enable_libstdcxx_pch=no
1736   else
1737     is_hosted=yes
1738     hosted_define=1
1739   fi
1740   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1741   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1742     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1743 ])
1744
1745
1746 dnl
1747 dnl Check for template specializations for the 'long long' type.
1748 dnl The result determines only whether 'long long' I/O is enabled; things
1749 dnl like numeric_limits<> specializations are always available.
1750 dnl
1751 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1752 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1753 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1754 dnl       Where DEFAULT is either `yes' or `no'.
1755 dnl
1756 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
1757   GLIBCXX_ENABLE(long-long,$1,,[enable template specializations for 'long long'])
1758   if test $enable_long_long = yes; then
1759     AC_DEFINE(_GLIBCXX_USE_LONG_LONG, 1,
1760               [Define if code specialized for long long should be used.])
1761   fi
1762   AC_MSG_CHECKING([for enabled long long specializations])
1763   AC_MSG_RESULT([$enable_long_long])
1764 ])
1765
1766
1767 dnl
1768 dnl Check for template specializations for the 'wchar_t' type.
1769 dnl
1770 dnl --enable-wchar_t defines _GLIBCXX_USE_WCHAR_T
1771 dnl --disable-wchar_t leaves _GLIBCXX_USE_WCHAR_T undefined
1772 dnl  +  Usage:  GLIBCXX_ENABLE_WCHAR_T[(DEFAULT)]
1773 dnl       Where DEFAULT is either `yes' or `no'.
1774 dnl
1775 dnl Necessary support must also be present.
1776 dnl
1777 AC_DEFUN([GLIBCXX_ENABLE_WCHAR_T], [
1778   GLIBCXX_ENABLE(wchar_t,$1,,[enable template specializations for 'wchar_t'])
1779
1780   # Test wchar.h for mbstate_t, which is needed for char_traits and fpos.
1781   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
1782   AC_MSG_CHECKING([for mbstate_t])
1783   AC_TRY_COMPILE([#include <wchar.h>],
1784   [mbstate_t teststate;],
1785   have_mbstate_t=yes, have_mbstate_t=no)
1786   AC_MSG_RESULT($have_mbstate_t)
1787   if test x"$have_mbstate_t" = xyes; then
1788     AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
1789   fi
1790
1791   # Test it always, for use in GLIBCXX_ENABLE_C99, together with
1792   # ac_has_wchar_h.
1793   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
1794
1795   if test x"$enable_wchar_t" = x"yes"; then
1796
1797     AC_LANG_SAVE
1798     AC_LANG_CPLUSPLUS
1799
1800     if test x"$ac_has_wchar_h" = xyes &&
1801        test x"$ac_has_wctype_h" = xyes; then
1802       AC_TRY_COMPILE([#include <wchar.h>
1803                       #include <stddef.h>
1804                       wint_t i;
1805                       long l = WEOF;
1806                       long j = WCHAR_MIN;
1807                       long k = WCHAR_MAX;
1808                       namespace test
1809                       {
1810                         using ::btowc;
1811                         using ::fgetwc;
1812                         using ::fgetws;
1813                         using ::fputwc;
1814                         using ::fputws;
1815                         using ::fwide;
1816                         using ::fwprintf;
1817                         using ::fwscanf;
1818                         using ::getwc;
1819                         using ::getwchar;
1820                         using ::mbrlen;
1821                         using ::mbrtowc;
1822                         using ::mbsinit;
1823                         using ::mbsrtowcs;
1824                         using ::putwc;
1825                         using ::putwchar;
1826                         using ::swprintf;
1827                         using ::swscanf;
1828                         using ::ungetwc;
1829                         using ::vfwprintf;
1830                         using ::vswprintf;
1831                         using ::vwprintf;
1832                         using ::wcrtomb;
1833                         using ::wcscat;
1834                         using ::wcschr;
1835                         using ::wcscmp;
1836                         using ::wcscoll;
1837                         using ::wcscpy;
1838                         using ::wcscspn;
1839                         using ::wcsftime;
1840                         using ::wcslen;
1841                         using ::wcsncat;
1842                         using ::wcsncmp;
1843                         using ::wcsncpy;
1844                         using ::wcspbrk;
1845                         using ::wcsrchr;
1846                         using ::wcsrtombs;
1847                         using ::wcsspn;
1848                         using ::wcsstr;
1849                         using ::wcstod;
1850                         using ::wcstok;
1851                         using ::wcstol;
1852                         using ::wcstoul;
1853                         using ::wcsxfrm;
1854                         using ::wctob;
1855                         using ::wmemchr;
1856                         using ::wmemcmp;
1857                         using ::wmemcpy;
1858                         using ::wmemmove;
1859                         using ::wmemset;
1860                         using ::wprintf;
1861                         using ::wscanf;
1862                       }
1863                      ],[],[], [enable_wchar_t=no])
1864     else
1865       enable_wchar_t=no
1866     fi
1867
1868     AC_LANG_RESTORE
1869   fi
1870
1871   if test x"$enable_wchar_t" = x"yes"; then
1872     AC_DEFINE(_GLIBCXX_USE_WCHAR_T, 1,
1873               [Define if code specialized for wchar_t should be used.])
1874   fi
1875
1876   AC_MSG_CHECKING([for enabled wchar_t specializations])
1877   AC_MSG_RESULT([$enable_wchar_t])
1878 ])
1879
1880
1881 dnl
1882 dnl Check to see if building and using a C++ precompiled header can be done.
1883 dnl
1884 dnl --enable-libstdcxx-pch=yes
1885 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1886 dnl may work, after some light-hearted attempts to puzzle out compiler
1887 dnl support, flip bits on in include/Makefile.am
1888 dnl
1889 dnl --disable-libstdcxx-pch
1890 dnl turns off attempts to use or build stdc++.h.gch.
1891 dnl
1892 dnl Substs:
1893 dnl  glibcxx_PCHFLAGS
1894 dnl
1895 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
1896   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1897   if test $enable_libstdcxx_pch = yes; then
1898     AC_CACHE_CHECK([for compiler with PCH support],
1899       [glibcxx_cv_prog_CXX_pch],
1900       [ac_save_CXXFLAGS="$CXXFLAGS"
1901        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1902        AC_LANG_SAVE
1903        AC_LANG_CPLUSPLUS
1904        echo '#include <math.h>' > conftest.h
1905        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1906                           -o conftest.h.gch 1>&5 2>&1 &&
1907                 echo '#error "pch failed"' > conftest.h &&
1908           echo '#include "conftest.h"' > conftest.cc &&
1909                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1910        then
1911          glibcxx_cv_prog_CXX_pch=yes
1912        else
1913          glibcxx_cv_prog_CXX_pch=no
1914        fi
1915        rm -f conftest*
1916        CXXFLAGS=$ac_save_CXXFLAGS
1917        AC_LANG_RESTORE
1918       ])
1919     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1920   fi
1921
1922   AC_MSG_CHECKING([for enabled PCH])
1923   AC_MSG_RESULT([$enable_libstdcxx_pch])
1924
1925   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1926   if test $enable_libstdcxx_pch = yes; then
1927     glibcxx_PCHFLAGS="-include bits/stdtr1c++.h"
1928   else
1929     glibcxx_PCHFLAGS=""
1930   fi
1931   AC_SUBST(glibcxx_PCHFLAGS)
1932 ])
1933
1934
1935 dnl
1936 dnl Check for atomic builtins.
1937 dnl See:
1938 dnl http://gcc.gnu.org/onlinedocs/gcc/Atomic-Builtins.html#Atomic-Builtins
1939 dnl
1940 dnl This checks to see if the host supports the compiler-generated
1941 dnl builtins for atomic operations. Note, this is intended to be an
1942 dnl all-or-nothing switch, so all the atomic operations that are used
1943 dnl should be checked.
1944 dnl
1945 dnl Note:
1946 dnl libgomp and libgfortran do this with a link test, instead of an asm test.
1947 dnl see: CHECK_SYNC_FETCH_AND_ADD
1948 dnl
1949 dnl Defines:
1950 dnl  _GLIBCXX_ATOMIC_BUILTINS if the compiler on this target supports atomics.
1951 dnl
1952 AC_DEFUN([GLIBCXX_ENABLE_ATOMIC_BUILTINS], [
1953   AC_MSG_CHECKING([for atomic builtins])
1954   AC_LANG_SAVE
1955   AC_LANG_CPLUSPLUS
1956
1957   # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1958     cat > conftest.$ac_ext << EOF
1959 [#]line __oline__ "configure"
1960 int main()
1961 {
1962   // NB: _Atomic_word not necessarily int.
1963   typedef int atomic_type;
1964   atomic_type c1;
1965   atomic_type c2;
1966   const atomic_type c3(0);
1967   if (__sync_fetch_and_add(&c1, c2) == c3)
1968     {
1969       // Do something.
1970     }
1971    return 0;
1972 }
1973 EOF
1974     old_CXXFLAGS="$CXXFLAGS"
1975     CXXFLAGS=-S
1976     if AC_TRY_EVAL(ac_compile); then
1977       if grep __sync_fetch_and_add conftest.s >/dev/null 2>&1 ; then
1978         enable_atomic_builtins=no
1979       else
1980       AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS, 1,
1981         [Define if builtin atomic operations are supported on this host.])
1982         enable_atomic_builtins=yes
1983         atomicity_dir=cpu/generic/atomicity_builtins
1984       fi
1985     fi
1986     CXXFLAGS="$old_CXXFLAGS"
1987     rm -f conftest*
1988
1989    # Now, if still generic, set to mutex.
1990   if test $atomicity_dir = "cpu/generic" ; then
1991         atomicity_dir=cpu/generic/atomicity_mutex
1992   fi
1993  AC_LANG_RESTORE
1994  AC_MSG_RESULT($enable_atomic_builtins)
1995 ])
1996
1997
1998 dnl
1999 dnl Check for exception handling support.  If an explicit enable/disable
2000 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
2001 dnl target may or may not support call frame exceptions.
2002 dnl
2003 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
2004 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
2005 dnl Neither one forces an attempt at detection.
2006 dnl
2007 dnl Defines:
2008 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
2009 dnl
2010 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
2011   AC_MSG_CHECKING([for exception model to use])
2012   AC_LANG_SAVE
2013   AC_LANG_CPLUSPLUS
2014   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
2015     [force use of builtin_setjmp for exceptions],
2016     [permit yes|no|auto])
2017
2018   if test $enable_sjlj_exceptions = auto; then
2019     # Botheration.  Now we've got to detect the exception model.  Link tests
2020     # against libgcc.a are problematic since we've not been given proper -L
2021     # bits for single-tree newlib and libgloss.
2022     #
2023     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
2024     cat > conftest.$ac_ext << EOF
2025 [#]line __oline__ "configure"
2026 struct S { ~S(); };
2027 void bar();
2028 void foo()
2029 {
2030   S s;
2031   bar();
2032 }
2033 EOF
2034     old_CXXFLAGS="$CXXFLAGS"
2035     CXXFLAGS=-S
2036     if AC_TRY_EVAL(ac_compile); then
2037       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
2038         enable_sjlj_exceptions=yes
2039       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
2040         enable_sjlj_exceptions=no
2041       elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
2042         enable_sjlj_exceptions=no
2043       fi
2044     fi
2045     CXXFLAGS="$old_CXXFLAGS"
2046     rm -f conftest*
2047   fi
2048
2049   # This is a tad weird, for hysterical raisins.  We have to map
2050   # enable/disable to two different models.
2051   case $enable_sjlj_exceptions in
2052     yes)
2053       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
2054         [Define if the compiler is configured for setjmp/longjmp exceptions.])
2055       ac_exception_model_name=sjlj
2056       ;;
2057     no)
2058       ac_exception_model_name="call frame"
2059       ;;
2060     *)
2061       AC_MSG_ERROR([unable to detect exception model])
2062       ;;
2063   esac
2064  AC_LANG_RESTORE
2065  AC_MSG_RESULT($ac_exception_model_name)
2066 ])
2067
2068
2069 dnl
2070 dnl Allow visibility attributes to be used on namespaces, objects, etc.
2071 dnl
2072 dnl --enable-visibility enables attempt to use visibility attributes.
2073 dnl --disable-visibility turns off all use of visibility attributes.
2074 dnl  +  Usage:  GLIBCXX_ENABLE_VISIBILITY[(DEFAULT)]
2075 dnl       Where DEFAULT is 'yes'.
2076 dnl
2077 AC_DEFUN([GLIBCXX_ENABLE_VISIBILITY], [
2078 GLIBCXX_ENABLE(visibility,$1,,[enables visibility safe usage])
2079
2080 if test x$enable_visibility = xyes ; then
2081   dnl all hail libgfortran
2082   dnl Check whether the target supports hidden visibility.
2083   AC_CACHE_CHECK([whether the target supports hidden visibility],
2084                  have_attribute_visibility, [
2085   save_CFLAGS="$CFLAGS"
2086   CFLAGS="$CFLAGS -Werror"
2087   AC_TRY_COMPILE([void __attribute__((visibility("hidden"))) foo(void) { }],
2088                  [], have_attribute_visibility=yes,
2089                  have_attribute_visibility=no)
2090   CFLAGS="$save_CFLAGS"])
2091   if test $have_attribute_visibility = no; then
2092     enable_visibility=no
2093   fi
2094 fi
2095
2096 GLIBCXX_CONDITIONAL(ENABLE_VISIBILITY, test $enable_visibility = yes)
2097 AC_MSG_NOTICE([visibility supported: $enable_visibility])
2098 ])
2099
2100
2101 dnl
2102 dnl Add version tags to symbols in shared library (or not), additionally
2103 dnl marking other symbols as private/local (or not).
2104 dnl
2105 dnl --enable-symvers=style adds a version script to the linker call when
2106 dnl       creating the shared library.  The choice of version script is
2107 dnl       controlled by 'style'.
2108 dnl --disable-symvers does not.
2109 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
2110 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
2111 dnl       choose a default style based on linker characteristics.  Passing
2112 dnl       'no' disables versioning.
2113 dnl
2114 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
2115
2116 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
2117   [enables symbol versioning of the shared library],
2118   [permit yes|no|gnu|gnu-versioned-namespace|darwin|darwin-export])
2119
2120 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
2121 # don't know enough about $LD to do tricks...
2122 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
2123
2124 # Turn a 'yes' into a suitable default.
2125 if test x$enable_symvers = xyes ; then
2126   if test $enable_shared = no || test "x$LD" = x || test x$gcc_no_link = xyes; then
2127     enable_symvers=no
2128   else
2129     if test $with_gnu_ld = yes ; then
2130       enable_symvers=gnu
2131     else
2132       case ${target_os} in
2133         darwin*)
2134           enable_symvers=darwin ;;
2135         *)
2136           enable_symvers=no ;;
2137       esac
2138     fi
2139   fi
2140 fi
2141
2142 # Check to see if 'darwin' or 'darwin-export' can win.
2143 if test x$enable_symvers = xdarwin-export ; then
2144     enable_symvers=darwin
2145 fi
2146
2147 # Check to see if 'gnu' can win.
2148 if test $enable_symvers = gnu || test $enable_symvers = gnu-versioned-namespace; then
2149   # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
2150   AC_MSG_CHECKING([for shared libgcc])
2151   ac_save_CFLAGS="$CFLAGS"
2152   CFLAGS=' -lgcc_s'
2153   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
2154   CFLAGS="$ac_save_CFLAGS"
2155   if test $glibcxx_shared_libgcc = no; then
2156     cat > conftest.c <<EOF
2157 int main (void) { return 0; }
2158 EOF
2159 changequote(,)dnl
2160     glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
2161                              -shared -shared-libgcc -o conftest.so \
2162                              conftest.c -v 2>&1 >/dev/null \
2163                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
2164 changequote([,])dnl
2165     rm -f conftest.c conftest.so
2166     if test x${glibcxx_libgcc_s_suffix+set} = xset; then
2167       CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
2168       AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
2169       CFLAGS="$ac_save_CFLAGS"
2170     fi
2171   fi
2172   AC_MSG_RESULT($glibcxx_shared_libgcc)
2173
2174   # For GNU ld, we need at least this version.  The format is described in
2175   # GLIBCXX_CHECK_LINKER_FEATURES above.
2176   glibcxx_min_gnu_ld_version=21400
2177
2178   # If no shared libgcc, can't win.
2179   if test $glibcxx_shared_libgcc != yes; then
2180       AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
2181       AC_MSG_WARN([=== you are not building a shared libgcc_s.])
2182       AC_MSG_WARN([=== Symbol versioning will be disabled.])
2183       enable_symvers=no
2184   elif test $with_gnu_ld != yes ; then
2185     # just fail for now
2186     AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
2187     AC_MSG_WARN([=== you are not using the GNU linker.])
2188     AC_MSG_WARN([=== Symbol versioning will be disabled.])
2189     enable_symvers=no
2190   elif test $glibcxx_gnu_ld_version -lt $glibcxx_min_gnu_ld_version ; then
2191     # The right tools, the right setup, but too old.  Fallbacks?
2192     AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
2193     AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
2194     AC_MSG_WARN(=== You would need to upgrade your binutils to version)
2195     AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
2196     AC_MSG_WARN([=== Symbol versioning will be disabled.])
2197     enable_symvers=no
2198   fi
2199 fi
2200
2201 # Everything parsed; figure out what file to use.
2202 case $enable_symvers in
2203   no)
2204     SYMVER_FILE=config/abi/pre/none.ver
2205     ;;
2206   gnu)
2207     SYMVER_FILE=config/abi/pre/gnu.ver
2208     AC_DEFINE(_GLIBCXX_SYMVER_GNU, 1,
2209               [Define to use GNU versioning in the shared library.])
2210     ;;
2211   gnu-versioned-namespace)
2212     SYMVER_FILE=config/abi/pre/gnu-versioned-namespace.ver
2213     AC_DEFINE(_GLIBCXX_SYMVER_GNU_NAMESPACE, 1,
2214               [Define to use GNU namespace versioning in the shared library.])
2215     ;;
2216   darwin)
2217     SYMVER_FILE=config/abi/pre/gnu.ver
2218     AC_DEFINE(_GLIBCXX_SYMVER_DARWIN, 1,
2219               [Define to use darwin versioning in the shared library.])
2220     ;;
2221 esac
2222
2223 if test x$enable_symvers != xno ; then
2224   AC_DEFINE(_GLIBCXX_SYMVER, 1,
2225          [Define to use symbol versioning in the shared library.])
2226 fi
2227
2228 AC_SUBST(SYMVER_FILE)
2229 AC_SUBST(port_specific_symbol_files)
2230 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS, test $enable_symvers != no)
2231 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU, test $enable_symvers = gnu)
2232 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU_NAMESPACE, test $enable_symvers = gnu-versioned-namespace)
2233 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_DARWIN, test $enable_symvers = darwin)
2234 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
2235
2236 # Now, set up compatibility support, if any.
2237 # In addition, need this to deal with std::size_t mangling in
2238 # src/compatibility.cc.  In a perfect world, could use
2239 # typeid(std::size_t).name()[0] to do direct substitution.
2240 AC_MSG_CHECKING([for size_t as unsigned int])
2241 ac_save_CFLAGS="$CFLAGS"
2242 CFLAGS="-Werror"
2243 AC_TRY_COMPILE(, [__SIZE_TYPE__* stp; unsigned int* uip; stp = uip;],
2244                  [glibcxx_size_t_is_i=yes], [glibcxx_size_t_is_i=no])
2245 CFLAGS=$ac_save_CFLAGS
2246 if test "$glibcxx_size_t_is_i" = yes; then
2247   AC_DEFINE(_GLIBCXX_SIZE_T_IS_UINT, 1, [Define if size_t is unsigned int.])
2248 fi
2249 AC_MSG_RESULT([$glibcxx_size_t_is_i])
2250
2251 AC_MSG_CHECKING([for ptrdiff_t as int])
2252 ac_save_CFLAGS="$CFLAGS"
2253 CFLAGS="-Werror"
2254 AC_TRY_COMPILE(, [__PTRDIFF_TYPE__* ptp; int* ip; ptp = ip;],
2255                  [glibcxx_ptrdiff_t_is_i=yes], [glibcxx_ptrdiff_t_is_i=no])
2256 CFLAGS=$ac_save_CFLAGS
2257 if test "$glibcxx_ptrdiff_t_is_i" = yes; then
2258   AC_DEFINE(_GLIBCXX_PTRDIFF_T_IS_INT, 1, [Define if ptrdiff_t is int.])
2259 fi
2260 AC_MSG_RESULT([$glibcxx_ptrdiff_t_is_i])
2261 ])
2262
2263
2264 dnl
2265 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
2266 dnl We must stage the required headers so that they will be installed
2267 dnl with the library (unlike libgcc, the STL implementation is provided
2268 dnl solely within headers).  Since we must not inject random user-space
2269 dnl macro names into user-provided C++ code, we first stage into <file>-in
2270 dnl and process to <file> with an output command.  The reason for a two-
2271 dnl stage process here is to correctly handle $srcdir!=$objdir without
2272 dnl having to write complex code (the sed commands to clean the macro
2273 dnl namespace are complex and fragile enough as it is).  We must also
2274 dnl add a relative path so that -I- is supported properly.
2275 dnl
2276 dnl Substs:
2277 dnl  glibcxx_thread_h
2278 dnl
2279 dnl Defines:
2280 dnl  HAVE_GTHR_DEFAULT
2281 dnl
2282 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
2283   AC_MSG_CHECKING([for thread model used by GCC])
2284   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
2285   AC_MSG_RESULT([$target_thread_file])
2286
2287   if test $target_thread_file != single; then
2288     AC_DEFINE(HAVE_GTHR_DEFAULT, 1,
2289               [Define if gthr-default.h exists
2290               (meaning that threading support is enabled).])
2291   fi
2292
2293   glibcxx_thread_h=gthr-$target_thread_file.h
2294
2295   dnl Check for __GTHREADS define.
2296   gthread_file=${toplevel_srcdir}/gcc/${glibcxx_thread_h}
2297   if grep __GTHREADS $gthread_file >/dev/null 2>&1 ; then
2298     enable_thread=yes
2299   else
2300    enable_thread=no
2301   fi
2302
2303   AC_SUBST(glibcxx_thread_h)
2304 ])
2305
2306
2307 # Check whether LC_MESSAGES is available in <locale.h>.
2308 # Ulrich Drepper <drepper@cygnus.com>, 1995.
2309 #
2310 # This file file be copied and used freely without restrictions.  It can
2311 # be used in projects which are not available under the GNU Public License
2312 # but which still want to provide support for the GNU gettext functionality.
2313 # Please note that the actual code is *not* freely available.
2314
2315 # serial 1
2316 AC_DEFUN([AC_LC_MESSAGES], [
2317   AC_CHECK_HEADER(locale.h, [
2318     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
2319       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
2320        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
2321     if test $ac_cv_val_LC_MESSAGES = yes; then
2322       AC_DEFINE(HAVE_LC_MESSAGES, 1,
2323                 [Define if LC_MESSAGES is available in <locale.h>.])
2324     fi
2325   ])
2326 ])
2327
2328 # Macros from the top-level gcc directory.
2329 m4_include([../config/tls.m4])
2330